         MACRO                                                          00020018
&NAME    IF    &A,&IS=,&ISNOT=,&GOTO=                                   00040018
         LCLB  &NOERR                                                   00060018
&NOERR   SETB  1                                                        00080018
         AIF   ('&A' NE '').SKIP                                        00100018
         MNOTE 'TEST  ADDRESS NOT SPECIFIED.'                           00120018
&NOERR   SETB  0                                                        00140018
.SKIP    AIF   ('&GOTO' NE '').SKIP2                                    00160018
         MNOTE 'BRANCH ADDRESS MISSING.'                                00180018
&NOERR   SETB  0                                                        00200018
.SKIP2   AIF   ('&IS' NE '' OR '&ISNOT' NE '').SKIP3                    00220018
         MNOTE 'TEST CONDITION NOT SPECIFIED.'                          00240018
&NOERR   SETB  0                                                        00260018
.SKIP3   AIF   (&NOERR).SKIP4                                           00280018
         MEXIT                                                          00300018
.SKIP4   AIF   ('&IS' EQ '').NOIS                                       00320018
***                                                                     00340018
&NAME    TM    &A,&IS                                                   00360018
         BO    &GOTO                                                    00380018
***                                                                     00400018
         MEXIT                                                          00420018
.NOIS    ANOP                                                           00440001
***                                                                     00460018
&NAME    TM    &A,&ISNOT                                                00480018
         BZ    &GOTO                                                    00500018
***                                                                     00520018
         MEND                                                           00540018
IGG019T2 CSECT                                                     UT18 00560018
         TITLE 'IGG019T2-EOB RTN, DA OUTPUT WITH TRK OVFLO,TOTALING'    00580018
*                                                                       00600018
*FUNCTION/OPERATION - DETERMINES WHETHER CURRENT RECORD TO BE WRITTEN * 00620018
*   OR READ(F STANDARD) WILL FIT ON CURRENT TRACK. THIS CALCULATION   * 00640018
*   ASSUMES THIS RECORD WILL BE LAST ON TRACK. IF RECORD WILL FIT,    * 00660018
*   SPACE REQUIRED IS RECALCULATED ASSUMING RECORD IS NOT THE LAST.   * 00680018
*   DCBTRACKBALANCE IS REDUCED BY THIS AMOUNT. IF RECORD WILL NOT FIT * 00700018
*   THE NEXT SEQUENTIAL TRACK IS FOUND. IF NONE EXISTS,AN EOV         * 00720018
*   CONDITION IS SIMULATED. FOR STANDARD F THE SEEK ADDRESS IN THE IOB* 00740018
*   IS INCEMENTED BY ONE SINCE SEARCH DIRECT IS USED.                 * 00760018
*                                                                     * 00780018
*          RELEASE 19 DELETIONS                                       * 00783018
*          RELEASE 20 DELETIONS                                       * 00786018
*2341094600                                                      A32558 00787020
*2341035400,055600,056600,090000,096200,135200,136600            S20201 00788020
*          RELEASE 21 DELETIONS                                       * 00789018
*                                                                XM4343 00799003
*STATUS CHANGE LEVEL 002                                                00807020
* ENTRY POINTS - IGG019T2 FROM ALL GET/PUT/READ/WRITE/MODULES      UT18 00810018
*               LA   2,DCB                                            * 00820018
*               LA   3,IOB                                            * 00840018
*               L    4,DCBOFFSR  OR DCBOFFSW                          * 00860018
*               L   15,76(2)    FOR WRITE(BSAM)                       * 00880018
*               L   15,92(2)    FOR QSAM                              * 00900018
*               BALR 14,15                                            * 00920018
*                                                                     * 00940018
*INPUT - IOB                                                          * 00960018
*         IOB+OFFSET - RECORD LENGTH IN CCW                           * 00980018
*        DCB                                                          * 01000018
*         DCBDVTBL - POINTS TO DEVICE ENTRY IN IECZDTAB               * 01020018
*         DCBDEB AD - DEBADDRESS                                      * 01040018
*         DCBTRBAL - BYTES REMAINING ON TRACK                         * 01060018
*         DCBFDAD  - POINTS TO LAST RECORD READ OR WRITTEN            * 01080018
*         DCBKEYLE - KEYLENGTH - ADDED TO BLKSIZE FOR TOTAL LENGTH    * 01100018
*         DCBCIND1 - VOL.FULL BIT ON - INDICATES PREVIOUS WRITE EOV   * 01120018
*        DEB                                                          * 01140018
*         DEBNMEXT - NUMBER OF EXTENTS IN DEB                         * 01160018
*         DEBOFLGS - X'04' MEANS SPLIT CYL EXTENTS                    * 01180018
*         DEBSTRCC AND DEBSTRHH - STARTING CCHH OF EXTENT             * 01200018
*         BEBENDCC AND DEBENDHH - ENDING CCHH OF EXTENT               * 01220018
*        IECZDTAB - I/O DEVICE TABLE                                  * 01240018
*                   LAST RECORD OV'HD                                 * 01260018
*                   NOT LAST RECORD OV'HD                             * 01280018
*                   KEY OV'HD                                         * 01300018
*                   MAX,TRACK LENGTH                                  * 01320018
*                   TOLERANCE                                         * 01340018
*                                                                     * 01360018
* OUTPUT - ECB - POSTED IN ERROR IF EOV .                               01380018
*        DCBTRBAL - UPDATED REMAING TRACK LENGTH                      * 01400018
*        DCBFDAD - UPDATED RECORD ADDRESS = LAST SEGMENT                01420018
*        IOBSEEK - RECORD ADDRESS = FIRST SEGMENT                       01440018
*        IOB+20   - UNIT EXCEP. IN CSW SET FOR EOV                    * 01460018
*                                                                     * 01480018
* EXTERNAL ROUTINES - SVC 25  ENTERED WITH THE TRACK OVERFLOW BIT IN    01500018
*                     DCBCIND2 SET- PURPOSE IS TO ERASE TO EOE.         01520018
*                                                                     * 01540018
*                    IF THE USER SPECIFIES THE USER TOTALING FACILIUT18 01550018
*                    (OPTCD=T) THEN IGG019AX WILL BE ACCESSED VIA AUT18 01560018
*                    'BALR R9,R10'                                 UT18 01570018
*EXITS/NORMAL - RETURN TO GET/PUT/WRITE/READ ROUTINE ON REG.14 AFTER  * 01580018
*               SCHEDULING I/O,OR POSTING ECB COMPLETE,ERROR IF EOV   * 01600018
*                                                                     * 01620018
*EXITS/ERROR - ABEND - CODE 00002000 - ISSUED IF-                     * 01640018
*          1.RECORD SIZE EXCEEDS 32,760                               * 01660018
*                                                                     * 01680018
*TABLES/WORK AREAS - ASSUMES USER REGS.2-8 SAVED.SAVES REGS.9-10 INTO * 01700018
*                    SAVE AREA + 64                                     01720018
*                                                                     * 01740018
*ATTRIBUTES - READONLY,REENTRANT,REUSABLE                             * 01760018
* REGISTER NAMES AND USAGE.                                             01780018
*                                                                       01800018
RALPHA   EQU   0                        WORK REG. ALPHA MAY NOT BE USED 01820018
*                                       AS AN ADDRESS REG.              01840018
R1       EQU   1                        THE NAME PRESERVES IDENTITY.    01860018
RDEB     EQU   1                        DEB ADDRESS LOADED IN THIS RTN. 01880018
RGAMMA   EQU   4                        WORK REG.                       01900018
RDELTA   EQU   5                        WORK REG.                       01920018
RSTEPPER EQU   RDELTA                   STEPS THRU COUNT FLD AND S.A.'S 01940018
RSIGMA   EQU   6                        WORK REG.                       01960018
RCPBASE  EQU   RSIGMA                   CP SEGMENT BASE REG.            01980018
*                                                                       02000018
RDCB     EQU   2                        HOLDS DCB ADDRESS UPON ENTRY.   02020018
RIOB     EQU   3                        HOLDS IOB ADDRESS UPON ENTRY.   02040018
ROFFSW   EQU   7                        HOLDS WRITE CCW OFFSET ON ENTRY 02060018
*              BUT WILL BE CLOBBERED, AND RESTORED FROM DCB PROIR TO    02080018
*              EXIT.  REG MUST BE X-PARENT FOR QSAM.                    02100018
ROVFLO   EQU   ROFFSW                   CCW OFFSET KNOWN. OVFLO =       02120018
*                                       LENGTH REMAINING TO BE WRITTEN. 02140018
RBETA    EQU   9                        SAVED FIRST, USED AS WORK REG.  02160018
RDEVTAB  EQU   10                       SAVED FIRST, DEVTABLE ADDRESS   02180018
*                                       LOADED.                         02200018
RSAVE    EQU   13                       USERS REGISTER SAVE AREA.       02220018
RRETN    EQU   14                       RETURN TO BSAM/QSAM RTN.        02240018
RBASE    EQU   15                       ENTRY-POINT/BASE REG.           02260018
*                                                                       02280018
DONTUSE8 EQU   8                        NOT SAVED. HOLDS USER CONTENTS. 02300018
OR11     EQU   11                       NOT SAVED. HOLDS USER CONTENTS. 02320018
OR12     EQU   12                       NOT SAVED. HOLDS USER CONTENTS. 02340018
*                                                                       02360018
*                                                                       02380018
UNITEXC  EQU   X'01'                    SETS IOBFLAG3.                  02400018
COMPWERR EQU   X'42'                    END OF EXTENT CONDITION HAS     02420018
*                                       BEEN ENCOUNTERED.               02440018
CPSEGLEN EQU   32                       LENGTH OF ONE CP SEGMENT.       02460018
D0       EQU   0                        DISPLACEMENT OF ZERO     S20201 02462020
B1       EQU   1                        BYTE COUNT OF ONE        S20201 02464020
B4       EQU   4                        BYTE COUNT OF FOUR       S20201 02466020
D8       EQU   8                        DISPLACEMENT OF EIGHT    S20201 02468020
D12      EQU   12                       DISPLACEMENT OF TWELVE   S20201 02470020
D16      EQU   16                       DISPLACEMENT OF SIXTEEN  S20201 02472020
D20      EQU   20                       DISPLACEMENT OF 20       S20201 02474020
TBOVHD   EQU   X'08'                    TWO BYTE OVHD INDICATOR  S20201 02476020
EIGHT    EQU   8                        LENGTH OF A COUNT FIELD         02480018
RLTV     EQU   32                       VECTOR OFFSET IN CVT.           02500018
CNVT     EQU   28                       VECTOR OFFSET IN CVT.           02520018
ZERO     EQU   0                        G.P. CONSTANT.                  02540018
TRKOVFLO EQU   X'80'                    T.O. INDICATOR IN DCBCIND1      02560018
NOERROR  EQU   X'7F'                    ECB MASK. ALL BITS ON = NOERROR 02580018
ANYZERO  EQU   14                       MASK FOR TESTING ANY SELECTED   02600018
*                                       BITS = ZERO.                    02620018
ONES     EQU   X'FF'                    G.P. CONSTANT.                  02640018
VOLFULL  EQU   X'20'                                                    02660018
IOBSIZE  EQU   48                       STANDARD IOB + BSAM/QSAM EXTEN. 02680018
VALCHK   EQU   X'80'                    WRITE VALIDITY CHECK BIT IN     02700018
*                                       DCBOPTCD.                       02720018
SPLIT    EQU   X'04'                                                    02740018
* COMMAND CODES FOR THE 2841 C.U.                                       02760018
*                                                                       02780018
SEEKCYL  EQU   X'0B'                    CYLINDER SEEK.                  02800018
SRCHEQMT EQU   X'B1'                    SEARCH EQ ID IN MULTI-TRACK.    02820018
WCKD     EQU   X'1D'                    WRITE COUNT, KEY AND DATA.      02840018
WSCKD    EQU   1                        WRITE SPECIAL OP CODE.          02860018
SETSC    EQU   X'23'                    SET SECTOR COMMAND       S20201 02862020
RDSC     EQU   X'22'                    READ SECTOR COMMAND      S20201 02864020
TIC      EQU   X'08'                    TIC CCW OP CODE          S20201 02866020
*                                                                       02868020
*                                                                       02870020
*                                                                       02872020
* CCW FLAGS                                                             02880018
CC       EQU   X'40'                    COMMAND CHAIN.                  02900018
*                                                                       02920018
R0       EQU   0                        PARAMETRIC ZERO            UT18 02922018
R2       EQU   2                        DCB REGISTER               UT18 02924018
R3       EQU   3                        WORK REG                   UT18 02926018
R4       EQU   4                        PARAMETRIC FOUR            UT18 02928018
R6       EQU   6                        WORK REG                   UT18 02930018
R9       EQU   9                        PARAMETRIC NINE            UT18 02932018
R10      EQU   10                       PARAMETRIC TEN             UT18 02934018
R13      EQU   13                       PARAMETRIC 13              UT18 02936018
R15      EQU   15                       WORK REG                   UT18 02938018
SAVR     EQU   RSAVE                    EQUATE TWO SYMBOLIC REFS   UT18 02940018
THREE6   EQU   36                       PARAMETRIC 36              UT18 02942018
UTFBIT   EQU   X'02'                    MASK FOR USER TOTALING TESTUT18 02944018
PERMERR  EQU   X'C0'                    PERM ERR POSTING IN DCB  XM4343 02944403
ONEIOB   EQU   X'01'                    ONE IOB INDICATOR        XM4343 02944803
ECBADDR  EQU   12                       OFFSET IN IOB TO ECB     XM4343 02945203
CSWSTAT  EQU   20                       OFFSET IN IOB TO CSW     XM4343 02945603
CSWSTAT1 EQU   21                          STATUS BYTES          XM4343 02945703
PGMCHK   EQU   X'20'                    PGM CHK INDICATOR        XM4343 02945803
ERROR    EQU   X'40'                    ECB ERROR POSTING        XM4343 02945903
*                                                                  UT18 02946018
         USING IGG019T2,RBASE           ESTABLISH BASE REGISTER         02948018
         USING  DEBB,RDEB               ESTABLISH BASEREG FOR DEB  UT18 02950018
         USING SAMSIOB,RIOB                                             02960018
         USING IHADCB,RDCB                                              02980018
*                                                                       03000018
*******************************************************************UT18 03002018
         L     RDEB,DCBDEBAD            GET THE DEB BASE ADDR.     UT18 03004018
         STM   RBETA,RDEVTAB,64(R13)    STORE REGS 9,10            UT18 03006018
         TM    DCBOPTCD,UTFBIT          TEST FOR USER TOTALING     UT18 03008018
         BZ    CONTINUE                 NOT SPECIFIED - SO BRANCH  UT18 03010018
*                                                                  UT18 03012018
         SR    R9,R9                    CLEAR THIS REGISTER        UT18 03014018
         SR    R10,R10                  CLEAR THIS REGISTER        UT18 03016018
         IC    R9,DEBNMEXT              GET NO OF EXTENTS          UT18 03018018
          IC   R10,DEBEXSCL             GET DEB EXTENT SCALE       UT18 03020018
         SLL   R9,ZERO(R10)             MULT TO GET LEN OF DEV DEP UT18 03022018
         L     R15,THREE6(RDEB,R9)      GET SAVE AREA ADDR         UT18 03024018
*                                                                  UT18 03026018
*  DEBR POINTS TO BEG. OF DEB +32 POINTS TO DEV DEP SECTION, R9    UT18 03028018
*        CONTAINS LEN OF DEV DEP SECTION, +4 POINTS TO SAVE AREA   UT18 03030018
*        POINTER.  SO R10 CONTAINS SAVE AREA ADDR                  UT18 03032018
*                                                                  UT18 03034018
         USING TOTSAVWA,R15             ESTAB BASE FOR TOT WRKAREA UT18 03036018
         STM   R3,R6,TOTREGSV           SAVE REGS FOR SAVE RTN     UT18 03038018
         L     R4,TOTSVPTR              GET ADDR OF SAVE ROUTINE   UT18 03040018
         BALR  R3,R4                    GO TO SAVE ROUTINE         UT18 03042018
         LM    R3,R6,TOTREGSV           RESTORE REGISTERS          UT18 03044018
*                                                                  UT18 03046018
CONTINUE EQU   *                                                   UT18 03048018
         BALR  R15,R0                   SET NEW BASE               UT18 03050018
         USING NEWBASE,R15              RE-ESTAB MODULE BASE REG   UT18 03052018
NEWBASE  EQU   *                                                   UT18 03054018
*******************************************************************UT18 03056018
         IF    DCBCIND1,IS=VOLFULL,GOTO=POSTECB                         03060018
*                                                                       03080018
*      FOR BSAM, INOUT OR OUTIN, AN INVALID I/O REQUEST MAY             03090003
*      HAVE BEEN ISSUED.  THIS ROUTINE CHECKS FOR AN INVALID            03092003
*      REQUEST AGAINST AN IOB AND POSTS IT IN ERROR.                    03094003
*                                                                       03096003
         TM    DCBIFLGS,PERMERR        DCB POSTED IN PERM ERR?   XM4343 03098003
         BZ    CONTIN                  NO - CONTINUE             XM4343 03098403
         CLI   DCBNCP,ONEIOB           ONE IOB PRESENT?          XM4343 03098803
         BNE   CONTIN                  NO - IOS WILL POST IN ERR XM4343 03099203
         L     RGAMMA,ECBADDR(RIOB)    GET ECB                   XM4343 03099603
         MVI   0(RGAMMA),ERROR         POST ECB IN ERROR         XM4343 03099703
         OI    CSWSTAT1(RIOB),PGMCHK   SET PROGRAM CHK IN CSW    XM4343 03099803
         MVI   CSWSTAT(RIOB),X'00'     CLEAR CSW FIRST BYTE      XM4343 03099903
         LM    RBETA,RDEVTAB,64(RSAVE) RESTORE USERS 9 AND 10    XM4343 03101903
         BR    RRETN                   RETURN TO USER            XM4343 03106603
CONTIN   EQU   *                                                 XM4343 03108603
         SR    RCPBASE,RCPBASE                                          03113303
         IC    RCPBASE,DCBWCPO          BUILD WRITE CHANNEL PGM         03120018
         AR    RCPBASE,RIOB             ADDRESSABILITY.                 03140018
         USING WCPMAP,RCPBASE                                           03160018
* WORK REG SIGMA IS IN USE AS 'RCPBASE'.                                03180018
         SR    RSTEPPER,RSTEPPER                                        03200018
         IC    RSTEPPER,DCBWCPL         NUMBER OF CCW'S BETWEEN IOB AND 03220018
*                                       FIRST COUNT FIELD.              03240018
         SLL   RSTEPPER,3               DBL WDS TO BYTES.               03260018
*                                                                       03280018
         AR    RSTEPPER,RCPBASE         CP START ADDR + ITS LENGTH      03300018
*                                       GIVES ADDRESSABILITY FOR COUNT  03320018
*                                       FIELDS AND S.A.'S. (THEY ARE    03340018
*                                       INTERLEAVED, WITH A COUNT FIELD 03360018
*                                       BEING FIRST, EACH IS A DBL WD). 03380018
         USING COUNTFLD,RSTEPPER                                        03400018
* WORK REG DELTA IS IN USE AS 'RSTEPPER'.                               03420018
         L     RDEVTAB,DCBDVTBL         ADDRESS OF DEV TABLE ENTRY FOR  03440018
*                                       THIS UNIT.                      03460018
         USING DEVTAB,RDEVTAB                                           03480018
*                                                                       03500018
         L     RDEB,DCBDEBAD            DEB ADDRESSABILITY.             03520018
*                                                                       03524020
* CHECK FOR RCD READY FEATURE BEING USED AND IF NOT ADJUST              03528020
* RCPBASE, IF YES, UPDATE SECTOR VALUE                                  03532020
*                                                                       03536020
         CLI   CHANPGM,SETSC            RCD READY CHP            S20201 03540020
         BNE   NOFET3                   BRANCH IF NO             S20201 03544020
         AH    RCPBASE,ATE8             ADJUST RCPBASE FOR RCD   S20201 03548020
*                                       READY FEAT                      03552020
NOFET3   EQU   *                                                 S20201 03556020
*                                                                       03560018
         L     ROVFLO,DATALEN-2         GET COMPOSITE KL+DL FROM CCW.   03580018
         LA    ROVFLO,0(ROVFLO)         CLEAR OUT THE FLAGS.            03600018
         LR    RBETA,ROVFLO             TEMP WORK REG.                  03620018
         SR    RALPHA,RALPHA                                            03640018
         IC    RALPHA,DCBKEYLE          TO REMOVE KL FROM KL+DL.        03660018
         SR    RBETA,RALPHA             BETA=DL.                        03680018
         CH    RBETA,DCBBLKSI           ABEND IF RECORD LENGTH          03700018
         BH    ABEND                    GREATER THAN BLKSIZE.           03720018
         LA    RBETA,7(RBETA)           MAKES POSSIBLE AN LTR FOR       03740018
*                                       DL GT 32760.                    03760018
         SLL   RBETA,16                 ALIGN FOR SIGN TEST.            03780018
         LTR   RBETA,RBETA              DL+7 MUST BE LESS THAN 32768.   03800018
         BM    ABEND                    BRANCH IF DL GT 32760           03820018
*                                                                       03840018
         LA    RALPHA,2                 LENGTH OF CCW LENGTH FIELD.     03860018
         LR    RBETA,RSTEPPER           COPY REG.                       03880018
         CLI   CHANPGM,SETSC            RCD READY CHP            S20201 03882020
         BNE   NOFET4                   BRANCH IF NO             S20201 03884020
         TM    DCBOPTCD,VALCHK          VALIDITY CHK USED        S20201 03886020
         BO    NOFET4                   BRANCH IF YES            S20201 03888020
         AH    RALPHA,ATE8              INCREMENT FOR RD SECTOR  S20201 03890020
NOFET4   EQU   *                                                 S20201 03892020
         SR    RBETA,RALPHA             BETA POINTS TO THE LAST CCW     03900018
*                                       LENGTH FIELD. (MAY OR MAY NOT   03920018
*                                       BE THE WRITE VALIDITY CHECK     03940018
*                                       SEGMENT).                       03960018
*                                                                       03980018
         STH   ROVFLO,0(RBETA)          USING THE LAST CCW LENGTH TO    04000018
*                                       SAVE THE OVFLO AMOUNT. USED TO  04020018
*                                       RECOVER AFTER GETTING A NEW     04040018
*                                       EXTENT,  IS ALSO  THE WRITE     04060018
*                                       VALIDITY CHECK LENGTH IF THE    04080018
*                                       VAL CHK CP EXISTS.              04100018
         MVC   TEMPSAVE(2),DCBTRBAL     PRESERVE THE ORIGINAL TRK BAL.  04120018
*                                       WILL BE RESTORED IF A RECORD    04140018
*                                       CANNOT BE WRITTEN.              04160018
SETFDAD  MVC   IOBFDAD(8),DCBFDAD       COPY FDAD INTO IOB.             04180018
RUPBY1   IC    RBETA,DCBFDAD+7          GET 'R'.                        04200018
         LA    RBETA,1(RBETA)           R=R+1.                          04220018
         STC   RBETA,DCBFDAD+7          PUT IT BACK.                    04240018
*                                                                       04260018
         MVC   CYLINDER(5),DCBFDAD+3    INITIALIZE THE ID PART OF THE   04280018
*                                       FIRST COUNT FIELD.              04300018
*                                                                       04320018
* END OF FIRST TIME LOGIC.                                              04340018
*                                                                       04360018
* BEGIN LOOP LOGIC.                                                     04380018
*                                                                       04400018
* CALCULATE THE SPACE REQUIRED TO WRITE THE DATA AS A LAST RECORD.      04420018
*                                                                       04440018
STRTLOOP SR    RBETA,RBETA                                              04460018
         SR    RALPHA,RALPHA                                            04480018
         IC    RBETA,OVERL              L = OVHD FOR LAST RECORD.       04500018
         TM    DEVFLAG,TBOVHD           TWO BYTE OVHD USED       S20201 04504020
         BNO   MZ0010                   BRANCH NO                S20201 04508020
         LH    RBETA,OVERI              GET TWO BYTE OVHD        S20201 04512020
MZ0010   EQU   *                                                 S20201 04516020
         IC    RALPHA,DCBKEYCN          KEYCN = EITHER 0 OR K (IF OR    04520018
*                                       IF NOT KEYS, RESPECTIVELY).     04540018
         LR    RGAMMA,ROVFLO            COPY THE AMOUNT REMAINING TO    04560018
*                                       BE WRITTEN (OVERFLOW).          04580018
         AR    RGAMMA,RBETA             OVFLO+L                         04600018
         SR    RGAMMA,RALPHA            OVFLO+L-KEYCN IS THE SPACE FOR  04620018
*                                       A LAST RECORD.                  04640018
*                                                                       04660018
         CH    RGAMMA,DCBTRBAL          WILL THIS TRACK HOLD THE RECORD 04680018
         BNH   FINAL                    YES. BRANCH TO DO FINAL LOGIC   04700018
*                                       FOR THE LAST CP SEGMENT.        04720018
*                                                                       04740018
* RECORD WILL NOT FIT AS A LAST RECORD. CALCULATE HOW MUCH WILL FIT AND 04760018
* TAILOR THE CURRENT CP SEGMENT TO WRITE THAT AMOUNT. AT LEAST ONE MORE 04780018
* RECORD SEGMENT WILL BE WRITTEN AFTER THIS ONE.                        04800018
* CCWLENGTH=TRBAL+KEYCN-L IS AMOUNT THAT WILL FIT.                      04820018
         LH    RGAMMA,DCBTRBAL          GET TRACK BAL.                  04840018
         AR    RGAMMA,RALPHA            TRBAL+KEYCN.                    04860018
         SR    RGAMMA,RBETA             TRBAL+KEYCN-L IN GAMMA.         04880018
MIDLOOP  MVC   DCBTRBAL,TRKCAP          RESET TRBAL TO DEVICE MAX.      04900018
         NI    TRACKFUL,ZERO            HOUSEKEEP TRACK FULL SWITCH.    04920018
         LTR   RGAMMA,RGAMMA            SEE IF ANY DATA CAN BE WRITTEN. 04940018
         BP    WILLFIT                  BRANCH IF ROOM FOR DATA.        04960018
         OI    TRACKFUL,ONES            SET TRACK FULL SWITCH. OCCURS   04980018
*                                       ONLY IF FIRST TRACK HAS NO ROOM 05000018
*                                       FOR DATA. ACTION REQ'D IS TO    05020018
*                                       ADVANCE TO NEXT TRACK.          05040018
         B     CONVERT                  NO ROOM FOR DATA. OVERHEAD      05060018
*                                       EXCEEDS TRK BAL.  GET A NEW     05080018
*                                       TRACK.                          05100018
WILLFIT  SR    ROVFLO,RGAMMA            REDUCE THE OVFLO FIGURE BY THE  05120018
*                                       CURRENT TRACK LENGTH.           05140018
*                                                                       05160018
         MVI   WRTOPCD,WSCKD            WRITE SPECIAL BECAUSE THIS IS   05180018
*                                       NOT THE LAST SEGMENT.           05200018
         MVI   NULLFLAG,CC              COMMAND CHAIN TO NEXT SEGMENT.  05220018
         STH   RGAMMA,DATALEN           PUT SEGMENT LENGTH IN WRT CCW.  05240018
         SR    RALPHA,RALPHA                                            05260018
         IC    RALPHA,KEYLENTH          KEY LENGTH FROM COUNT FIELD.    05280018
         SR    RGAMMA,RALPHA            DATA LEN= SEG LEN - KL.         05300018
         STH   RGAMMA,DLDL              PUT IT IN COUNT FLD DATA LENGTH 05320018
         AR    RGAMMA,RALPHA            RECONSTRUCT SEGMENT LENGTH.     05340018
*                                                                       05360018
         L     RBETA,DATAADDR           GET THE DATA ADDRESS            05380018
         LA    RBETA,0(RBETA)           CLEAR HI BYTE.                  05400018
         AR    RGAMMA,RBETA             ADDRESS+LENGTH=NEXT ADDRESS.    05420018
*                                                                       05440018
         LA    RCPBASE,CPSEGLEN(RCPBASE) ADVANCE CP BASE TO NEXT SEG.   05460018
         LA    RSTEPPER,EIGHT(RSTEPPER)  POINTS TO S.A. THE 'CCHHR' OF  05480018
*                                       THE COUNTFLD DSECT IS VALID.    05500018
         ST    RGAMMA,DATAADDR          THIS DATA ADDRESS = LAST + LEN. 05520018
         MVI   SRCHOPCD,SRCHEQMT        OP CODE SET FOR MULTI-TRACK     05540018
*                                                                       05548020
         CLI   CHANPGM,SETSC            RCD READY CHANNEL PROG   S20201 05556020
         BE    FEATX                    BRANCH IF YES            S20201 05564020
*                                                                       05572020
*                                                                       05580018
         IF    DCBOPTCD,ISNOT=VALCHK,GOTO=CONVERT                       05600018
* RECONSTRUCT THE FIRST CCW SEARCH ADDRESS. REASON- IT MAY HAVE BEEN    05620018
* CHANGED TO A TIC TO WRT CHK CP ON A PREVIOUS USE.                     05640018
*                                                                       05650020
FEATX    EQU   *                                                 S20201 05660020
*                                                                       05670020
         MVC   SRCHADDR+1(3),PARASITE+1 THE CORRECT SEARCH ADDRESS HAS  05680018
*                                       BEEN A PARASITE IN THE TIC CCW. 05700018
*                                                                       05720018
CONVERT  EQU   *                                                        05740018
* THE DCB FULL DISK ADDRESS MUST BE UPDATED TO THE ADDRESS OF THE NEXT  05760018
* TRACK, ON WHICH THE NEXT RECORD SEGMENT WILL BE WRITTEN. THE NEXT     05780018
* TRACK MAY BE ACCROSS A CYLINDER BOUNDARY, SO THE DISK ADDRESS IS      05800018
* UPDATED IN THE TTR FORM. THE CONVERT ROUTINE ALSO PROVIDES VALIDITY   05820018
* CHECKING OF THE NEW FDAD.                                             05840018
*                                                                       05860018
         LA    RGAMMA,FDADTTR           THIS IS A CONCEALED ENTRY TO A  05880018
*                                       CLOSED SUBROUTINE.              05900018
*********************************************************************** 05920018
*        THE FOLLOWING ROUTINE WILL DETERMINE THE NEXT TRACK ADDRESS. * 05940018
*        BY ADDING 1 TO THE CURRENT TT AND SENDING THIS VALUE TO THE  * 05960018
*      RESIDENT CONVERT ROUTINE, THE NEXT TRACK WILL BE DETERMINED. IF* 05980018
*      THE NUMBER OF TRACKS IN THE DEB ARE EXCEEDED, THE CONVERT ROU- * 06000018
*      TINE WILL PASS A RETURN CODE OF 4 IN REGISTER 15               * 06020018
*                                                                     * 06040018
*        REGISTER CONTENTS PRIOR TO BRANCHING TO THE CONVERT ROUTINES * 06060018
*      ARE:                                                           * 06080018
*        R0 ---NEXT TTR RETURNED BY IECPRTLV OR TTRN IF GOING TO THE  * 06100018
*              IECPCNVT ROUTINE. (TTR TO MBBCCHHR)                    * 06120018
*        R1 ---ADDRESS OF DEB                                         * 06140018
*        R2 ---ADDRESS OF USER MBBCCHHR                               * 06160018
*        R3 ---BASE REGISTER OF THIS MODULE                           * 06180018
*        R4 ---RETURN TO USER                                         * 06200018
*        R5 ---USER (11)                                              * 06220018
*        R6 ---USER (12)                                              * 06240018
*        R7 ---ADDRESS OF SAVE AREA                                   * 06260018
*        R8 ---TEMPORARY STORAGE OF TTRN FOR SPLIT CYLINDER USE.        06280018
*              R9 ---REGS 9 - 13 ARE                                    06300018
*        R10---USED           VO                                      * 06320018
*        R11--- BY              LA                                    * 06340018
*        R12---  CONVERT          TI                                  * 06360018
*        R13---   ROUTINES               LE                           * 06380018
*                                                                     * 06400018
*        R14---RETURN FOR CONVERT ROUTINE                             * 06420018
*              R15---ENTRY/ERROR CODE REG.                              06440018
*                                                                     * 06460018
*                                                                       06480018
*                                                                       06500018
*                                                                       06520018
*                                                                       06540018
*              IECPRLTV -ENTRY TO ROUTINE VIA A BALR THAT CONVERTS AN   06560018
*                        ABSOLUTE DIRECT ACCESS ADDRESS, MBBCCHHR, INTO 06580018
*                        ITS RELATIVE EQUIVALENT, TTR0. REGISTER        06600018
*                        CONVENTIONS UPON ENTRY AND UPON EXIT ARE AS    06620018
*                        FOLLOWS--                                      06640018
*                                                                       06660018
*                           REGISTER         ENTRY             EXIT     06680018
*                             0          IGNORED            TTR0 RESULT 06700018
*                             1          DEB ADDRESS        TRANSPARENT 06720018
*                             2          ADDRESS OF         TRANSPARENT 06740018
*                                          MBBCCHHR IN CORE             06760018
*                             3-8        IGNORED            TRANSPARENT 06780018
*                             9-13       IGNORED            DESTROYED   06800018
*                             14         RETURN ADDRESS     TRANSPARENT 06820018
*                             15         ENTRY ADDRESS      ZERO        06840018
*                                                                       06860018
*              IECPCNVT -ENTRY TO ROUTINE VIA A BALR THAT CONVERTS A    06880018
*                        RELATIVE DIRECT ACCESS ADDRESS AND             06900018
*                        CONCATENATION NUMBER, TTRN, INTO ITS ABSOLUTE  06920018
*                        EQUIVALENT, MBBCCHHR. REGISTER CONVENTIONS     06940018
*                        UPON ENTRY AND UPON EXIT ARE AS FOLLOWS--      06960018
*                                                                       06980018
*                           REGISTER         ENTRY             EXIT     07000018
*                             0          ACTUAL TTRN        DESTROYED   07020018
*                             1          DEB ADDRESS        TRANSPARENT 07040018
*                             2          ADDRESS OF 8 BYTE  TRANSPARENT 07060018
*                                          AREA FOR MBBCCHHR            07080018
*                             3-8        IGNORED            TRANSPARENT 07100018
*                             9-13       IGNORED            DESTROYED   07120018
*                             14         RETURN ADDRESS     TRANSPARENT 07140018
*                             15         ENTRY ADDRESS      ERROR CODE  07160018
*                                                                       07180018
*                        THE ERROR CODE FOR IECPCNVT WILL BE 0 FOR      07200018
*                        SUCCESSFUL CONVERSION, OR 4 IF VALUE OF TT     07220018
*                        EXCEEDS TOTAL EXTENTS ASSIGNED.                07240018
*                                                                       07260018
*                                                                     * 07280018
*********************************************************************** 07300018
*                                                                       07320018
REGMANIP EQU   *                        START OF A CLOSED SUBROUTINE    07340018
*                                       FOR REGISTER MAINIPULATION.     07360018
* THE FOLLOWING REGISTER MANIPULATIONS ARE REQUIRED IN ORDER TO USE     07380018
* THE CONVERT ROUTINES.                                                 07400018
* THE CURRENT CP SEGMENT S.A. AND COUNT FIELD (2 CONTIG. DBL WDS)       07420018
* PROVIDE A CONVENIENT PLACE TO SAVE SOME REGS. RSTEPPER HAS THIS ADDR. 07440018
*                                                                       07460018
         STM   RCPBASE,DONTUSE8,0(RSTEPPER)  SAVE REGS 6,7,8. HI BYTE   07480018
*                                            OF REG 7 MUST BE ZERO FOR  07500018
*                                            IT OVERLAYS R=0 OF THE SA. 07520018
         LR    DONTUSE8,RSTEPPER        REG 8 IS TRANSPARENT ACCROSS    07540018
*                                       CONVERT, CAN HOLD S.A. ADDRESS. 07560018
*                                       USERS CONTENTS OF 8 ARE SAVED   07580018
*                                       THERE.                          07600018
* MOVE USERS REGS 11, 12, 13, 14, AND EOB BASE 15, TO 5,6,7,4,3 RESPEC- 07620018
* TIVELY.                                                               07640018
         LR    RSTEPPER,OR11            11 TO 5.                        07660018
         LR    RCPBASE,OR12             12 TO 6.                        07680018
         LR    ROVFLO,RSAVE             13 TO 7.                        07700018
         LR    RSAVE,RGAMMA             SAVE THIS ROUTINE'S RETURN REG. 07720018
         LR    RGAMMA,RRETN             14 TO 4.                        07740018
         LR    RIOB,RBASE               15 TO 3.                        07760018
         DROP  RBASE                                                    07780018
         DROP  RIOB                                                     07800018
         USING NEWBASE,RIOB             ESTABLISH TEMP BASE REG    UT18 07820018
         LA    RDCB,DCBFDAD             POINT TO M OF FDAD.             07840018
         USING DCBFDAD,RDCB                                             07860018
         BR    RSAVE                    RETURN TO CALLER OF 'REGMANIP'. 07880018
FDADTTR  EQU   *                                                        07900018
         L     RBASE,16                 GET  CVT ADDRESS                07920018
         L     RBASE,RLTV(RBASE)        GET IECPRLTV ENTRY POINT.       07940018
         BALR  RRETN,RBASE              GO TO CONVERT MBBCCHHR TO TTR.  07960018
* ON RETURN, REG 0 HAS THE TTR, LEFT ADJUSTED.                          07980018
         SRL   RALPHA,16               TRUNCATE 'RZ' OF 'TTRZ'.         08000018
         AH    RALPHA,ONE               TT=TT+1.                        08020018
         L     RBETA,DCBIOBA            TEMPORARY IOB ADDRESSABILITY.   08040018
         USING SAMSIOB,RBETA                                            08060018
         STH   RALPHA,TTSAVE            SAVE TT FOR USE IN SPLIT TESTS. 08080018
         DROP  RBETA                                                    08100018
TTRFDAD  EQU   *                                                        08120018
         SLL   RALPHA,16               RE-ALIGN TO 'TT00'.              08140018
         L     RBASE,16                 GET CVT ADDR.                   08160018
         L     RBASE,CNVT(RBASE)        GET IECPCNVT ENTRY POINT.       08180018
         BALR  RRETN,RBASE              GO TO CONVERT TTR TO MBBCCHHR.  08200018
* ON RETURN, REG 15 HAS THE RETURN CODE.                                08220018
         LR    RALPHA,RBASE             SAVE THE RETURN CODE FOR LATER  08240018
*                                       INSPECTION.                     08260018
* REGISTER RECONSTRUCTION - PUT THEM BACK AS THEY WERE BEFORE CONVER-   08280018
* SION.                                                                 08300018
* MOVE REGS 5,6,7,4,3 BACK TO 11,12,13,14,15                            08320018
         LR    OR11,RSTEPPER            5 TO 11.                        08340018
         LR    OR12,RCPBASE             6 TO 12.                        08360018
         LR    RSAVE,ROVFLO             7 TO 13.                        08380018
         LR    RRETN,RGAMMA             4 TO 14.                        08400018
         LR    RBASE,RIOB               3 TO 15.                        08420018
*                                                                       08440018
         USING NEWBASE,RBASE            RE-ESTABLISH BASE REG      UT18 08460018
*                                                                       08480018
         LR    RSTEPPER,DONTUSE8        RESTORE REG # 5 FROM XPARENT 8. 08500018
         LM    RCPBASE,DONTUSE8,0(RSTEPPER) RESTORE 6,7,8.              08520018
         USING WCPMAP,RCPBASE                                           08540018
*                                                                       08560018
         LA    RBETA,5                  OFFSET OF DCBFDAD.              08580018
         SR    RDCB,RBETA               DCB ADDRESSABILITY REGAINED.    08600018
         USING IHADCB,RDCB                                              08620018
*                                                                       08640018
         L     RIOB,DCBIOBA             IOB ADDRESSABILITY REGAINED.    08660018
         USING SAMSIOB,RIOB                                             08680018
*                                                                       08700018
         L     RDEVTAB,DCBDVTBL         DEV TABLE ADDR. REGAINED.       08720018
         USING DEVTAB,RDEVTAB                                           08740018
*                                                                       08760018
* REGISTERS RECONSTRUCTED. ALPHA, BETA, GAMMA HAVE BEEN USED.           08780018
* RETURN CODE WAS SAVED IN ALPHA. TEST IT FOR VALID FDAD.               08800018
*                                                                       08820018
         LTR   RALPHA,RALPHA            COMPARE CODE TO ZERO.           08840018
         BZ    TSTSPLIT                 BRANCH IF ZERO. CODE INDICATES  08860018
*                                       A VALID FDAD, WITHIN THIS EXT.  08880018
* THE RETURN CODE NOT-ZERO INDICATES THE FDAD WAS OUTSIDE THIS EXTENT.  08900018
* ACTION REQUIRED IS TO ISSUE SVC 25, WHICH WILL USE THE CP PORTION     08920018
* THAT HAS BEEN CONSTRUCTED TO ERASE THE UNUSED REMAINDER OF THIS EX-   08940018
* TENT. AFTER RETURN FROM SVC 25, WILL REPAIR THE CP FOR RESTART BY EOV 08960018
ERASE    EQU   *                        ERASE THE CURRENT EXTENT.       08980018
         IF    TRACKFUL,IS=ONES,GOTO=CHECKEXT                      000D 09010018
*                                                                       09020018
         LA    RBETA,CPSEGLEN           RECOVER ADDRESSABILITY FOR THE  09040018
         SR    RCPBASE,RBETA            LAST WCP SEGMENT THAT FITS ON   09060018
*                                       THIS EXTENT.                    09080018
         MVI   NULLFLAG,ZERO            TERMINATE CP.                   09100018
         L     RBETA,COUNTADR           GET ADDRESS OF THE LAST COUNT   09120018
*                                       FIELD MADE UP.                  09140018
         MVC   DCBFDAD+3(5),0(RBETA)    RECONSTRUCT THE DCBFDAD TO      09160018
*                                       POINT TO LAST SEGMENT TO BE     09180018
*                                       ERASED. MAKES CORRECT STARTING  09200018
*                                       POINT IF ANOTHER EXTENT (SAY A  09220018
*                                       DISCONTIGUOUS PRIMARY) IS AVAIL 09240018
*                                       ABLE. ALSO NEEDED FOR SVC 25    09260018
*                                       INTERFACE.                      09280018
         MVC   DCBFDAD(1),IOBFDAD       KEEPS 'M' IN STEP WITH 'CCHHR'. 09300018
*                                                                       09304018
         LH    RALPHA,TEMPSAVE          GET ORIG. TRK BAL.         000D 09308018
         LR    RCPBASE,RALPHA     SAVE IT ACCROSS SVC 25.          000D 09312018
*                                                                       09316018
         OI    DCBCIND1,TRKOVFLO        SET THE DCB TRK OVFLO IND.      09320018
*                                       WHICH TELLS SVC 25 TO ERASE TO  09340018
*                                       END OF EXTENT.                  09360018
*                                                                       09380018
         LR    RGAMMA,RRETN             SAVE 14.                        09400018
         LR    RBETA,RBASE              SAVE 15.                        09420018
         DROP  RBASE                                                    09440018
         LA    R1,0(RDCB)               DEB REG HOLDS PARAM TO   A32558 09450020
*                                       SVC 25                          09460020
*                                                                       09480018
         SVC   25                       ERASE.                          09500018
*                                                                       09520018
         LR    RRETN,RGAMMA             RESTORE 14                      09540018
         LR    RBASE,RBETA              RESTORE 15.                     09560018
         USING NEWBASE,RBASE            RE-ESTABLISH BASE REG      UT18 09580018
         L     RDEB,DCBDEBAD            RECOVER DEB ADDRESSABILITY.     09600018
*                                                                       09640018
         STH   RCPBASE,TEMPSAVE   ORIG. TRK BAL SAVED ACCROSS      000D 09646018
*                                       SVC 25.                    000D 09652018
* RECOVER INITIAL CP AND COUNT FIELD ADDRESSABILITY.                    09660018
* REASON- NEED TO RESTORE THE TOTAL BLOCK LENGTH TO BE WRITTEN INTO     09680018
* THE WRITE CCW POINTED TO BY OFFSW.  THE TOTAL LENGTH HAS BEEN SAVED   09700018
* AT THE CCW JUST IN FRONT OF THE FIRST COUNT FIELD.                    09720018
         SR    RCPBASE,RCPBASE                                          09740018
         IC    RCPBASE,DCBWCPO                                          09760018
         AR    RCPBASE,RIOB             IOBA+WCPO                       09780018
         USING WCPMAP,RCPBASE                                           09800018
         SR    RSTEPPER,RSTEPPER                                        09820018
         IC    RSTEPPER,DCBWCPL                                         09840018
         SLL   RSTEPPER,3               DBL WDS TO BYTES.               09860018
         AR    RSTEPPER,RCPBASE         IOBA+WCPO+WCPL*8                09880018
* CP ADDRESS, S.A. AND COUNT FIELD ADRESS RESTORED TO INITIAL VALUES.   09900018
         LA    RALPHA,2                 LENGTH OF A CCW LENGTH FIELD.   09920018
         LR    RBETA,RSTEPPER           COPY FOR WORK.                  09940018
         CLI   CHANPGM,SETSC            RCD READY CHP            S20201 09941020
         BNE   NOFET19                  BRANCH IF NO             S20201 09942020
         AH    RCPBASE,ATE8             IF YES INCR BASE FOR SET S20201 09943020
*                                       SCT                      S20201 09944020
         TM    DCBOPTCD,VALCHK          VALIDITY CHK USED        S20201 09945020
         BO    NOFET19                  BRANCH IF YES            S20201 09946020
         AH    RALPHA,ATE8              INCR FOR RD SECTOR       S20201 09947020
*                                                                       09948020
NOFET19  EQU   *                                                 S20201 09949020
*                                                                       09950020
         USING DEBB,RDEB                                         S20201 09951020
         SR    RBETA,RALPHA             BETA POINTS TO WHERE THE        09960018
*                                       INITIAL CCW LENGTH WAS SAVED.   09980018
         LH    ROVFLO,0(RBETA)          RESET OVFLO TO ORIGINAL VALUE.  10000018
         STH   ROVFLO,DATALEN           WILL NEED THE FULL RECORD       10020018
*                                       LENGTH ON NEXT ENTRY TO EOB IF  10040018
*                                       CAN'T EXCP THIS TIME.           10060018
*                                                                       10062018
* DETERMINE IF ERASE HAD ANY ERRORS.                               000D 10064018
         L     RGAMMA,IOBECBPT           GET ECB ADDR.             000D 10066018
         TM    0(RGAMMA),NOERROR         IS THE ECB POSTED IN ERR. 000D 10068018
         BC    ANYZERO,RESTORE           BRANCH IF YES             000D 10070018
*                                                                       10072018
CHECKEXT EQU   *                                                   000D 10074018
*                                                                       10080018
* CHECK FOR ANOTHER EXTENT, DCBFDAD 'M'+1 MUST BE LESS THAN DEBNMEXT.   10100018
         SR    RBETA,RBETA              HOUSEKEEP                       10120018
         IC    RBETA,IOBFDAD            GET M                     M2057 10140018
         LA    RBETA,1(RBETA)           M=M+1.                          10160018
         STC   RBETA,IOBFDAD            TEMP WORK AREA.                 10180018
         CLC   IOBFDAD(1),DEBNMEXT      COMPARE M+1 TO NMBR OF EXTENTS. 10200018
         BL    EXTAVAIL                 BRANCH IF ANOTHER EXTENT.       10220018
         OI    DCBCIND1,VOLFULL         SET VOLUME FULL INDICATOR.      10240018
* REPAIR DCB FDAD AND TRK BAL TO THEIR VALUES AT ENTRY TO THIS MODULE.  10260018
         BCTR  RBETA,0                  DECREMENT THE M AND       M2057 10266018
         STC   RBETA,IOBFDAD            RESTORE THE IOB           M2057 10272018
         MVC   DCBFDAD(8),IOBFDAD       IOB INITIALIZED FROM THE FIRST  10280018
*                                       DCB VALUE.                      10300018
         MVC   DCBTRBAL(2),TEMPSAVE     TRK BAL SAVED IN IOB CSW.       10320018
         B     POSTECB                  MAKES EOV RE-SCHEDULE THIS IOB. 10340018
*                                                                       10360018
EXTAVAIL EQU   *                                                        10380018
*                                                                       10500018
* GET NEXT EXTENT FDAD FROM DEB TO DCB. DCBFDAD 'M' IN BETA IS CORRECT  10520018
* EXTENT NMBR (FROM M=M+1). 'M' TIMES THE EXTENT SCALE GIVES AN INDEX-  10540018
* ING FACTOR USED TO LOCATE THE DEVICE DEPENDENT EXTENT ENTRY.          10560018
*                                                                       10580018
         STC   RBETA,DCBFDAD            UPDATE 'M' TO NEXT EXTENT.      10600018
         SR    RGAMMA,RGAMMA                                            10620018
         IC    RGAMMA,DEBEXSCL          GET EXTENT SCALE(=4 FOR DA).    10640018
         SLL   RBETA,0(RGAMMA)          EXTENT NMBR TIMES SIZE.         10660018
         AR    RDEB,RBETA               BECAUSE MVC NOT INDEXABLE.      10680018
         MVC   DCBFDAD+3(4),DEBSTRCC    GET NEXT EXTENT FDAD.           10700018
         SR    RDEB,RBETA               TAKE OUT THE INDEXING FACTOR.   10720018
         MVI   DCBFDAD+7,ZERO           SET R=0.                        10740018
         B     SETFDAD                  START UP ON NEW EXTENT.         10760018
*                                                                       10780018
TSTSPLIT EQU   *                                                        10800018
* FOLLOWING CODE ENTERED WHEN IT HAS BEEN DETERMINED THAT AT LEAST ONE  10820018
* MORE RECORD SEGMENT WILL BE NEEDED AND A TRACK TO HOLD IT HAS BEEN    10840018
* FOUND.                                                                10860018
*                                                                       10880018
*                                                                       10900018
         SR    RGAMMA,RGAMMA                                            10920018
         IC    RGAMMA,DEBEXSCL          EXTENT SCALE(=4 FOR D.A.)       10940018
         SR    RBETA,RBETA                                              10960018
         IC    RBETA,IOBFDAD            GET CURRENT/LAST 'M'.           10980018
*                                       DCB HAS CURRENT/NEXT 'M' IN IT. 11000018
         SLL   RBETA,0(RGAMMA)          EXTENT NMBR TIMES SIZE.         11020018
*                                       KEEP RBETA FOR INDEXING DEB     11040018
*                                       BASE REG.                       11060018
* TEST FOR SPLIT ALLOCATION, WHICH IS ALLOWED ONLY ON THE PRIMARY.      11080018
         CLI   DCBFDAD,0                Q-FIRST EXTENT IF         M2057 11100018
*                                       FIRST IS NOT PRIMARY, DEBOFLGS  11120018
*                                       REFLECT A NON-SPLIT ALLOC.      11140018
         BNE   TESTPRIM                 BRANCH IF NOT ON FIRST EXTENT.  11160018
*                                       CANNOT BE SPLIT.                11180018
         TM    DEBOFLGS,SPLIT           IS IT SPLIT ALLOCATION.         11200018
         BZ    TESTPRIM                 BRANCH IF NO.                   11220018
*THE FDAD IN THE DCB IS 'VALID' (AS PER THE CONVERT ROUTINE ERROR CODE) 11240018
* AND THE ALLOCATION IS 'SPLIT'. NOW DETERMINE IF THE FDAD IS WITHIN    11260018
* THE LIMITS DEFINED BY THE STARTING AND ENDING HH'S IN THE DEB. IF     11280018
* NOT, THE NEXT PART OF THE SPLIT EXTENT (THERE MUST BE ONE FOR THE     11300018
* FDAD TO BE 'VALID') MAY BE FOUND BY-                                  11320018
*  TT(OF DCBFDAD) + MAXHH - (ENDHH - STRHH) -1                          11340018
* MAXHH IS THE NUMBER OF TRACKS IN A CYLINDER, AND IS THEREFORE DEVICE  11360018
* DEPENDENT.                                                            11380018
* ALPHA AND GAMMA ARE AVAILABLE WORK REGS.                              11400018
* REG BETA HOLDS THE INDEXING FACTOR BY WHICH RDEB HAS BEEN ADJUSTED.   11420018
         AR    RDEB,RBETA               BECAUSE SS INSTRUCTIONS NOT IN- 11440018
*                                       DEXABLE.                        11460018
         CLC   DCBFDAD+6(1),DEBSTRHH+1  IS IT BELOW STARTING HH.        11480018
         BL    OUTSIDE                  BRANCH IF YES.                  11500018
         CLC   DCBFDAD+6(1),DEBENDHH+1  IS IT ABOVE ENDING HH.          11520018
         BNH   FIXRDEB                  BRANCH IF NOT ABOVE. GO TO      11540018
*                                       REPAIR DEB REG.                 11560018
OUTSIDE  EQU   *                                                        11580018
* FDAD IS OUTSIDE THE SPLIT. ADVANCE TO THE NEXT PART OF THIS SPLIT     11600018
* EXTENT, USING THE ABOVE FORMULA.                                      11620018
         SR    RALPHA,RALPHA                                            11640018
         SR    RGAMMA,RGAMMA                                            11660018
         IC    RGAMMA,DEBENDHH+1        GET UPPER LIMIT, ENDHH.         11680018
         IC    RALPHA,DEBSTRHH+1        GET LOWER LIMIT, STRHH.         11700018
         SR    RGAMMA,RALPHA            ENDHH - STRHH                   11720018
         IC    RALPHA,MAXHH             MAXHH                           11740018
         SR    RALPHA,RGAMMA            MAXHH - (ENDHH - STRHH)         11760018
         BCT   RALPHA,*+4               MAXHH - (ENDHH - STRHH) -1      11780018
         AH    RALPHA,TTSAVE            TT+MAXHH-(ENDHH-STRHH)-1        11800018
         SR    RDEB,RBETA               REPAIR DEB REG.                 11820018
         BAL   RGAMMA,REGMANIP          GO TO REGISTER MANIPULATION     11840018
*                                       INTERFACE. REQ'D FOR USE OF     11860018
*                                       CONVERT ROUTINE.                11880018
         B     TTRFDAD                  WILL DO A CONVERT.              11900018
TESTPRIM EQU   *                                                        11920018
         AR    RDEB,RBETA               BECAUSE SS INSTRUCTIONS NOT IN- 11940018
*                                       DEXABLE.                        11960018
         CLC   DCBFDAD(1),IOBFDAD       CROSS AN EXTENT           M2057 11970018
         L     RDEB,DCBDEBAD            RESTORE DEB ADDRESS       M2057 11980018
         BH    ERASE                    THE VALID TTR LAST GIVEN TO     12000018
*                                       'CONVERT' PRODUCED AN FDAD      12020018
*                                       OUTSIDE THE CURRENT EXTENT.     12040018
*                                       IT MUST BE THE FDAD FOR THE     12060018
*                                       NEXT EXTENT OF A DISCONTIGUOUS  12080018
*                                       PRIMARY. ACTION- ERASE AND      12100018
*                                       CHECK FOR ANOTHER EXTENT.       12120018
*                                       RDEB HAS BEEN TAMPERED WITH.    12140018
FIXRDEB  EQU   *                                                        12160018
*                                                                       12200018
* IF THE OVERFLOW AMOUNT WILL FIT ON THE CURRENT TRACK, WILL EXIT THE   12220018
* LOOP TO DO FINAL LOGIC.  IF NOT, WILL SET UP TO RE-ENTER THE LOOP     12240018
* BUILDING C.P.'S.                                                      12260018
*                                                                       12280018
TESTFULL IF    TRACKFUL,ISNOT=ONES,GOTO=NOTFULL                         12300018
MOVEFDAD EQU   *                        FIRST TRACK HAD NO ROOM FOR     12320018
*                                       DATA. A NEW TRACK WAS GOTTEN    12340018
*                                       FOR THE FIRST RECORD SEGMENT.   12360018
         MVC   IOBFDAD(8),DCBFDAD       COPY NEW FDAD.                  12380018
         MVC   KEYLENTH,DCBKEYLE        RE-INIT KEYKENGTH. WAS OVERLAID 12400018
*                                       WITH A SAVED REG DURING CONVERT 12420018
         B     TESTOVFL                 SEE IF RECORD WILL FIT ON THIS  12440018
*                                       NEW TRACK.                      12460018
*                                                                       12480018
* RSTEPPER POINTS TO THE CURRENT S.A.                                   12500018
*                                                                       12520018
NOTFULL  MVC   CYLINDER(5),DCBFDAD+3    INIT CCHHR IN S.A.              12540018
         LA    RSTEPPER,EIGHT(RSTEPPER) POINT TO THE COUNT FIELD.       12560018
TESTOVFL LH    RGAMMA,TRKCAP            SET DL=MAX.                     12580018
         CR    ROVFLO,RGAMMA            COMPARE OVFLO TO DEVICE MAX.    12600018
         BNH   RUPBY1                   BRANCH IF OVFLO IS LT OR EQ TO  12620018
*                                       DEVICE MAX. (RECORD WILL FIT).  12640018
UPRBY1   EQU   *                                                        12660018
         IC    RBETA,DCBFDAD+7          GET 'R'.                        12680018
         LA    RBETA,1(RBETA)           R=R+1                           12700018
         STC   RBETA,DCBFDAD+7          PUT IT BACK.                    12720018
         MVC   CYLINDER(5),DCBFDAD+3    INIT CCHHR IN COUNT.            12740018
*                                                                       12760018
         B     MIDLOOP                  CLOSE THE BASIC BUILDING LOOP.  12780018
*                                                                       12800018
* FINAL LOGIC.  THE REMAINING LENGTH IN ROVFLO WILL FIT ON THE CURRENT  12820018
* TRACK. MUST CALCULATE THE SPACE REQUIRED AS A NOT-LAST RECORD, SET    12840018
* UP CP TO WRITE IT, ISSUE EXCP.                                        12860018
*                                                                       12880018
FINAL    STH   ROVFLO,DATALEN           PUT LENGTH IN WRITE CCW.        12900018
         SR    RBETA,RBETA                                              12920018
         IC    RBETA,KEYLENTH           KEY LENGTH FROM COUNT FIELD.    12940018
         SR    ROVFLO,RBETA             SEGMENT LENGTH - KL = DATA LEN. 12960018
         STH   ROVFLO,DLDL              GOES IN COUNT FIELD.            12980018
         AR    ROVFLO,RBETA             RECONSTRUCT SEGMENT LENGTH.     13000018
*                                                                       13020018
*CALCULATE SPACE FOR A NOT-LAST-RECORD, USING                           13040018
*   (SEGMENT LENGTH)*TOL/512 - DCBKEYCN + I                             13060018
*                                                                       13080018
* DEB NO LONGER NEEDED. WILL USE THE DEB REG UNDER THE ALIAS RALPHA+1   13100018
* TO INSURE CONTIGUOUS REGISTERS FOR THE MULTIPLY.                      13120018
*                                                                       13140018
         LR    RALPHA,ROVFLO            GET KL+DL                       13160018
         LH    RALPHA+1,TOLER           GET TOLERANCE                   13180018
         MR    RALPHA,RALPHA            (KL+DL)*TOL                     13200018
         SRDA  RALPHA,9                 (KL+DL)*TOL/512 IS IN RALPHA+1  13220018
         SR    RALPHA,RALPHA                                            13240018
         IC    RALPHA,OVERI             GET NOT-LAST-RECORD OVERHEAD.   13260018
         TM    DEVFLAG,TBOVHD           TWO BYTE OVHD USED       S20201 13264020
         BNO   MZ0020                   BRANCH NO                S20201 13268020
         LH    RALPHA,OVERI             GET TWO BYTE OVHD        S20201 13272020
MZ0020   EQU   *                                                 S20201 13276020
         AR    RALPHA+1,RALPHA          AOD IT.                         13280018
         SR    RALPHA,RALPHA            CLEAR REG                S20201 13290020
         IC    RALPHA,DCBKEYCN          GET KEY OVERHEAD CONSTANT.      13300018
         SR    RALPHA+1,RALPHA          (KL+DL)*TOL/512+I-DCBKEYCN IS   13320018
*                                       THE AMOUNT TO SUBTRACT FROM     13340018
*                                       TRACK BALANCE.                  13360018
         LH    RBETA,DCBTRBAL           GET TRK BALANCE.                13380018
         SR    RBETA,RALPHA+1           DETERMINE NEW BALANCE.          13400018
         STH   RBETA,DCBTRBAL           UPDATE THE DCB.                 13420018
*                                                                       13440018
* END OF TRACK LENGTH CALCULATIONS.                                     13460018
*                                                                       13480018
         MVI   WRTOPCD,WCKD             SET OP CODE OF THE FINAL WRITE. 13500018
*                                                                       13506020
         DROP  RDEB                                              S20201 13512020
         USING SAMSIOB,RIOB                                      S20201 13518020
         CLI   CHANPGM,SETSC            IS THIS RCD READY CHP    S20201 13524020
         BE    FEAT41                   GO AROUND NEXT INST      S20201 13530020
         IF    DCBOPTCD,ISNOT=VALCHK,GOTO=FLAGZERO                      13540018
*                                                                       13560018
*                                                                       13565020
FEAT41   EQU   *                                                 S20201 13570020
*                                                                       13575020
         MVI   NULLFLAG,CC              COMMAND CHAIN CCW4.             13580018
*                                                                       13600018
* ADVANCE CP BASE REG TO NEXT SEGMENT. IF IT IS NOT THE WRITE VALIDITY  13620018
* CHECK SEGMENT, OVERLAY THE FIRST CCW WITH A TIC TO THE VALIDITY       13640018
* CHECK SEGMENT. SAME FOR RCD READY.                                    13660020
*                                                                       13680018
         LA    RCPBASE,CPSEGLEN(RCPBASE) ADDRESS OF NEXT SEGMENT.       13700018
         USING VCMAP,RCPBASE                                            13720018
         CLI   SEEKOPCD,SEEKCYL         ONLY SEEK IS IN WRITE CHECK SEG 13740018
         BE    EXCP                     WRITE VALIDITY CHECK SEGMENT IS 13760018
*                                       CONTIGUOUS WITH LAST SEGMENT    13780018
*                                       MADE UP. DONT NEED A TIC TO IT. 13800018
         CLI   D0(RCPBASE),RDSC         IS THIS A READ SECTOR    S20201 13806020
         BE    EXCP                     IF YES BRANCH            S20201 13812020
         USING WCPMAP,RCPBASE                                           13820018
         SR    RBETA,RBETA                                              13840018
         IC    RBETA,DCBWCPO            BUILD ADDRESS OF WCP            13860018
         AR    RBETA,RIOB               BECAUSE MVC NOT INDEXABLE.      13880018
         CLI   CHANPGM,SETSC            IS THIS A RCD READY CHP  S20201 13882020
         BNE   NOFET27                  BRANCH IF NO             S20201 13884020
         LA    RBETA,EIGHT(RBETA)       INCREMENT FOR SET SECT   S20201 13886020
*                                       CMND                     S20201 13888020
*                                                                       13890020
NOFET27  EQU   *                                                 S20201 13892020
*                                                                       13894020
         MVC   SRCHCCW(4),12(RBETA)     OVERLAY THE SEARCH WITH         13900018
*                                       PARASITIC TIC FROM CCW2.        13920018
         B     EXCP                                                     13940018
FLAGZERO MVI   NULLFLAG,ZERO            TERMINATE CP CHAIN.             13960018
*                                                                       13980018
* PREPARE FOR EXCP. CP'S ALL BUILT.                                     14000018
*                                                                       14020018
EXCP     EQU   *                                                        14040018
         LA    R1,8(RIOB)              ADJUST POINTER FROM SAM'S TO     14060018
*                                      IOS' IOB.                        14080018
         EXCP  (1)                                                      14100018
*                                                                       14120018
RESTORE  LM    RBETA,RDEVTAB,64(RSAVE)  RESTORE USERS 9 AND 10.         14140018
         SR    ROFFSW,ROFFSW                                            14160018
         IC    ROFFSW,DCBOFFSW         QSAM NEEDS IT TO GET NEXT        14180018
*                                      BUFFER ADDRESS.                  14200018
*                                                                       14220018
         BR    RRETN                                                    14240018
POSTECB  L     RBETA,IOBECBPT           GET ECB ADDRESS.                14260018
         MVI   0(RBETA),COMPWERR        POST COMPLETE WITH ERROR.       14280018
UEX      OI    IOBSTAT0,UNITEXC         SET CSW STATUS BYTE 0 TO UEX.   14300018
         B     RESTORE                                                  14320018
ABEND    LA    R1,X'002'                RECORD TOO LARGE.               14340018
         SLL   R1,12                    ALIGN ABEND CODE.               14360018
         ABEND (1),DUMP                                                 14380018
ONE      DC    H'1'                                                     14400018
ATE8     DC    H'8'                     CCW LENGTH               S20201 14402020
         DC    C'IGGR'                  THIS CONSTANT IS TO      S20201 14404020
*                                       IDENTIFY THIS MODULE AS         14406020
*                                       BEING IGGR19T2, A               14408020
*                                       ROTATIONAL POSITION             14410020
*                                       SENSING MODULE.                 14412020
         CNOP  0,8                      PAD MODULE TO MULTIPLE OF       14420018
*                                       DOUBLE WORD LENGTH.             14440018
*                                                                       14460018
* FOLLOWING IS A MAP OF A WRITE CP SEGMENT.                             14480018
*                                                                       14500018
WCPMAP   DSECT                                                          14520018
*                                                                       14540018
*        SEARCH  (CCW1 OR 5)                                            14560018
*                                                                       14580018
SRCHCCW  EQU   *                                                        14600018
SRCHADDR DS    F                                                        14620018
SRCHOPCD EQU   SRCHADDR                 OP CODE IS HI ORDER BYTE.       14640018
SRCHFLAG DS    XL1                                                      14660018
         DS    CL2                                                      14680018
SRCHLEN  DS    XL1                      LENGTHS NORMALLY FIT IN 1 BYTE. 14700018
*                                                                       14720018
*        TIC   (CCW2 OR 6)                                              14740018
*                                                                       14760018
TICADDR  DS    F                                                        14780018
TICOPCD  EQU   TICADDR                                                  14800018
UNUSED   DS    F                        ONLY REQUIRES BITS 37-39 = 0.   14820018
PARASITE EQU   UNUSED                   BITS 37-39 =0 RESTRICTION ON    14840018
*                                       OP CODES, A PLACE FOR ADDRESSES 14860018
*                                                                       14880018
*        WRITE  (CCW3)                                                  14900018
*                                                                       14920018
COUNTADR DS    F                        COUNT FIELD ADDRESS.            14940018
WRTOPCD  EQU   COUNTADR                                                 14960018
WRTFLAG  DS    XL1                      FLAG FIELD.                     14980018
         DS    CL2                      SPACER.                         15000018
COUNTLEN DS    XL1                      COUNT FIELD LENGTH (NORMALLY 8) 15020018
*                                                                       15040018
*        NULL OP CODE  (CCW4)           OP PROPAGATED FROM WRITE CCW.   15060018
*                                                                       15080018
DATAADDR DS    F                        ADDRESS OF BLOCK OF DATA TO BE  15100018
*                                       WRITTEN.                        15120018
NULLOPCD EQU   DATAADDR                 USED AS A FLAG TO SIGNAL LAST   15140018
*                                       SEGMENT.                        15160018
NULLFLAG DS    XL1                                                      15180018
         DS    C                                                        15200018
DATALEN  DS    H                        DATA TO BE WRITTEN.             15220018
*                                                                       15240018
*                                                                       15260018
* FOLLOWING IS THE VALIDITY CHECK CP OVERLAY.                           15280018
*                                                                       15300018
VCMAP    DSECT                                                          15320018
*        SEEK  (CCW7)                                                   15340018
SEEKADDR DS    F                                                        15360018
SEEKOPCD EQU   SEEKADDR                                                 15380018
SEEKFLAG DS    XL1                                                      15400018
         DS    CL2                                                      15420018
SEEKLEN  DS    XL1                                                      15440018
*                                                                       15460018
*        SEARCH (CCW8)             LABELS PREFIXED BY 'VC' (VALIDITY    15480018
VCSRCH   EQU   *                        CHECK).                         15500018
VCSRCHAD DS    F                                                        15520018
VCSRCHOP EQU   VCSRCHAD                                                 15540018
VCSRCHFL DS    XL1                      FLAGS.                          15560018
         DS    CL2                                                      15580018
VCSRCHLE DS    XL1                      LENGTH.                         15600018
*                                                                       15620018
*        TIC   (CCW9)                                                   15640018
VCTICAD  DS    F                                                        15660018
VCTICOP  EQU   VCTICAD                                                  15680018
NOTUSED  DS    F                                                        15700018
*                                                                       15720018
*        READ DATA (CCW10)                                              15740018
VCRDAD   DS    F                                                        15760018
VCRDOP   EQU   VCRDAD                                                   15780018
VCRDFLAG DS    XL1                      NORMALLY SET FOR SKIP.          15800018
VCRDLEN  DS    FL3                                                      15820018
*                                                                       15840018
* FOLLOWING IS AN OVERLAY OF THE COUNT FIELD.                           15860018
*                                                                       15880018
COUNTFLD DSECT                                                          15900018
*                                                                       15920018
CYLINDER DS    H                        CYLINDER ADDRESS (CC).          15940018
HEAD     DS    H                        HEAD ADDRESS     (HH).          15960018
RECORD   DS    XL1                      RECORD NUMBER    (R).           15980018
KEYLENTH DS    XL1                      KEY LENGTH       (KL).          16000018
DLDL     DS    H                        DATA LENGTH      (DLDL).        16020018
*                                                                       16040018
* END COUNT FIELD. (CCHHRKDD)                                           16060018
*                                                                       16080018
*                                                                       16100018
* DIRECT ACCESS DEVICE TABLE OVERLAY                                    16120018
*                                                                       16140018
DEVTAB   DSECT                                                          16160018
DEVSIZE  DS    F                       MAX SIZ FOR DEVICE.              16180018
MAXHH    EQU   DEVSIZE+3                LO ORDER BYTE OF DEVICE SIZE IS 16200018
*                                       MAX HEAD ADDRESS.               16220018
TRKCAP   DS    H                       TRACK CAPACITY.                  16240018
OVERI    DS    XL1                     OVERHEAD FOR NOT-LAST RECORD.    16260018
OVERL    DS    XL1                     OVERHEAD FOR LAST RECORD.        16280018
OVERK    DS    XL1                     OVERHEAD REDUCTION FOR NON-KEY   16300018
*                                      RECORDS.                         16320018
DEVFLAG  DS    XL1                                                      16340018
TOLER    DS    H                       TOLERANCE/512 USED FOR VARIABLE  16360018
*                                       GAP LENGTH CALCULATIONS.        16380018
* END DEVTAB OVERLAY.                                                   16400018
*                                                                       16420018
*                                                                       16440018
         DCBD  DSORG=PS                                                 16460018
*                                                                       16480018
*                                                                       16500018
*                                                                       16520018
*                                                                       16540018
FORECORE DSECT                                                          16560018
DEBB     DSECT                         THIS DSECT DESCRIBES THE DEBUT18 16560318
DEBNMSUB DS    0CL1                    NO. OF SUB RTNS             UT18 16560618
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDR     UT18 16560918
DEBAMLNG DS    0CL1                    LENGTH OF ACCESS METHOD SEC UT18 16561218
DEBDEBAD DS    CL4                     ADDR OF NEXT DEB IN DEB CHAIUT18 16561518
DEBOFLGS DS    0CL1                    DEB OPEN FLAGS              UT18 16561818
DEBIRBAD DS    CL4                     ADDR OF THE IRB CONTROL BLOCUT18 16562118
DEBOPATB DS    0CL1                    OPEN ATRIBUTES              UT18 16562418
DEBSYSPG DS    CL4                     SYSTEM PURGE FIELD          UT18 16562718
DEBNMEXT DS    0CL1                    NUMBER OF EXTENTS IN DEB    UT18 16563018
DEBUSRPG DS    CL4                     USER PURGE FIELD            UT18 16563318
DEBPRIOR DS    0CL1                    INFO BYTE                   UT18 16563618
DEBECBAD DS    CL4                     EVENT CONTROL BLOCK ADDR    UT18 16563918
DEBPROTG DS    0CL1                    INFO BYTE                   UT18 16564218
DEBDEBID DS    0CL1                    INFO BYTE                   UT18 16564518
DEBDCBAD DS    CL4                     ADDR OF DCB                 UT18 16564818
DEBEXSCL DS    0CL1                    SCALING FACTOR OF DEB EXTENTUT18 16565118
DEBAPPAD DS    CL4                     APPENDAGE TABLE ADDR        UT18 16565418
DEBDVMOD DS    0CL1                    DEVICE MODIFIER BYTE        UT18 16565718
DEBUCBAD DS    CL4                     UNIT CTL BLOCK ADDR         UT18 16566018
DEBTVLSQ DS    0CL2                    VOL SEQ FOR TAPE            UT18 16566318
DEBBINUM DS    CL2                     BIN NUMBER                  UT18 16566618
DEBTVLNM DS    0CL2                    NO OF VOL FOR TAPE          UT18 16566918
DEBSTRCC DS    CL2                     START CYLINDER NUMBER       UT18 16567218
DEBSTRHH DS    CL2                     START HEAD NUMBER           UT18 16567518
DEBENDCC DS    CL2                     END CYLINDER NUMBER         UT18 16567818
DEBENDHH DS    CL2                     END HEAD NUMBER             UT18 16568118
DEBNMTRK DS    CL2                     NUMBER OF TRACKS            UT18 16568418
*  FOR ADDITIONAL EXTENT ON DIRECT ACCESS THE FOLLOWING FIELDS     UT18 16568718
*  WILL HAVE TO BE OFFSET ANOTHER 16 BYTES                         UT18 16569018
DEBVOLSQ DS    H                       VOL SEQUENCE NUMBER         UT18 16569318
DEBVOLNM DS    H                       VOLUME NUMBER               UT18 16569618
*  FOR EACH SUBROUTINE LOADED BUMP THIS OFFSET BY 2                UT18 16569918
DEBSUBID DS    H                       SUBROUTINE ID ( 2 BYTES )   UT18 16570218
TOTSAVWA DSECT                                                     UT18 16570518
*                                                                  UT18 16570818
*******************************************************************UT18 16571118
*  THIS DSECT ESTABLISHES THE SYMBOLIC REFERENCES FOR THE USER TOTAUT18 16571418
*        ING FACILITY SAVE WORKAREA.                               UT18 16571718
*******************************************************************UT18 16572018
TOTFLGBT DS    0CL1                     X'80' = NO SAVE FOR UTF    UT18 16572318
TOTSVPTR DS    F                        ADDR OF THE SAVE RTN       UT18 16572618
TOTCURNT DS    F                        ADDR OF CURRENT SAVE SEGMENUT18 16572918
TOTSTART DS    F                        BEGINNING ADDR OF SAVE SEGMUT18 16573218
TOTENDAD DS    F                        ADDR OF LAST SAVE SEGMENT  UT18 16573518
TOTSVLNG DS    F                        LENGTH OF THE USER'S SAVE AUT18 16573818
TOTUSRWA DS    F                        ADDR OF THE USERS TOT AREA UT18 16574118
TOTTOTLN DS    F                       TOTAL LEN OF GETMAIN        UT18 16574418
TOTEOVPT DS    F                        POINTER TO EOV SEG         UT18 16574718
TOTREGSV DS    D                        SAVE AREA FOR R11 & R12    UT18 16575018
         DS    D                       SAV AREA  FOR REG'S         UT18 16575318
         IECDSECT                                                       16580018
*                                                                       16600018
* IOB OVERLAY                                                           16620018
* THE FORECORE DSECT IOB OVERLAY IS USED WITH THE FOLOWING ADDITIONS-   16640018
*                                                                       16660018
* BSAM/BPAM/QSAM IOB EXTENSION-                                         16680018
LINK     EQU   DXIOB-8                  FORWARD CHAIN FIELD (TO NEXT    16700018
*                                       IOB).                           16720018
SAMSIOB  EQU   LINK                                                     16740018
FLAG     EQU   LINK                     HI BYTE OF LINK USED AS FLAG.   16760018
ECB      EQU   DXIOB-4                                                  16780018
* END EXTENSION DEFINITIONS                                             16800018
*                                                                       16820018
TRACKFUL EQU   IOBCSW+1                 CSW ADDRESS BYTE USED FOR       16840018
*                                       A TEMPORARY SWITCH.             16860018
TEMPSAVE EQU   IOBCSW+2                 PLACE TO KEEP THE ORIG. TRK BAL 16880018
*                                                                       16900018
*                                       IS OK BECAUSE IOB BEING PROCESS 16920018
*                                       -ED IS NOT IN ERROR, THEREFORE  16940018
*                                       CSW NOT NEEDED.                 16960018
TTSAVE   EQU   IOBCSW+6                 PLACE TO KEEP THE UPDATED TT    16980018
IOBFDAD  EQU   DXDAADDR                 FDAD IN FORECORE IOB.           17000018
CHANPGM  EQU   DXDAADDR+8               START OF CHANNEL PROGRAM.       17020018
*                                       LENGTH MAY VARY.                17040018
* END IOB DEFINITIONS.                                                  17060018
*                                                                       17080018
         END                                                            17280018
