 TITLE   'IGG019V2 - 1419 AND 1275 END-OF-BLOCK ROUTINE'                00300019
IGG019V2 CSECT                                                          00600019
*                                                                       00900019
*                                                                       01200019
*STATUS - CHANGE LVL 000   VERSION LVL 000   MODIFICATION LVL 000       01500019
*                                                                       01800019
*FUNCTION- END-OF-BLOCK ROUTINE FOR 1419 AND 1275.                      02100019
*                                                                       02400019
*           1-DETERMINE IF THE DEVICE IS ON-LINE.  IF NOT ON-LINE EXIT  02700019
*           2-DETERMINE IF A WTO MESSAGE NEEDS DELETING--IF ONE DOES    03000019
*             DELETE IT USING THE DOM MACRO                             03300019
*           3-UPDATE MICB POINTERS (READ AND PCI) SO THEY POINT         03600019
*             TO THE SAME MICB.                                         03900019
*           4-PUT THE ADDRESS OF THE SCU SENSE BYTE IN THE MSENSE CCW.  04200019
*             AND SET THE COMMAND CHAIN ON.                             04500019
*           5-PUT THE ADDRESS OF THE PCU SENSE BYTES IN THE MSENSE      04800019
*             COMMANDS FOR THE PCU CCW STRING.  ALSO THE DATA ADDRESS   05100019
*             IN THE MREAD COMMANDS.                                    05400019
*           6-SET THE FIRST COMMAND CODE IN THE PCU CCW STRING TO       05700019
*             ENGAGE.                                                   06000019
*           7-ISSUE AN EXCP (SVC 00) FOR THE PCU AND THE SCU.           06300019
*           8-RETURN TO READ ROUTINE                                    06600019
*                                                                       06900019
*ENTRY POINT - IGG019V2 FROM THE READ ROUTINE                           07200019
*                L 15,DCBEOBR          PICK UP ADDR OF EOB MODULE       07500019
*                BALR  14,15           BRANCH TO EOB MODULE             07800019
*                                                                       08100019
*INPUT - DCB (ADDRESS OF DCB IS PASSED FROM READ IN REGISTER 2)         08400019
*         DCBIOBAD-ADDRESS OF PCU IOB                                   08700019
*         DCBIOBA -ADDRESS OF MICB                                      09000019
*         DCBWTOID-BEFORE FIRST ENGAGE CONTAINS WTO ID NUMBER           09300019
*         DCBDEBAD- ADDR OF DEB                                         09600019
*         DCBMRIND-X'08'-CONTROL ROUTINE HAS BEEN ENTERED               09900019
*         DCBMRFLG-X'20'-SUPPORT OR USER REQUESTED DISENGAGE BIT        10200019
*                  X'88'-USED BY PCI APPENDAGE                          10500019
*                  X'02'-WTO MESSAGE PRESENT                            10800019
*         DCBBUFL-LENGTH OF EACH BUFFER                                 11100019
*        IOB (SCU)                                                      11400019
*         IOB+16-ADDRESS OF CCW STRING FOR SCU                          11700019
*        IOB (PCU)                                                      12000019
*         IOB+16-ADDRESS OF CCW STRING FOR PCU                          12300019
*        MICB                                                           12600019
*         MICBSENS-SCU SENSE BYTE                                       12900019
*         MICBSENS+1-PCU SENSE BYTES (2)                                13200019
*         MICBFLAG-X'20' FOLLOW-UP DOCUMENTS PROCESSED                  13500019
*                  X'10' FIRST MICB AFTER ENGAGE                        13800019
*         MICBDATA-ADDRESS OF DATA AREA                                 14100019
*         MICBNEXT-ADDRESS OF NEXT MICB                                 14400019
*        DEB                                                            14700019
*         DEBUCBAD- ADDR OF UCB                                         15000019
*        UCB                                                            15300019
*         UCBFL1-X'40'-DEVICE READY                                     15600019
*                                                                       15900019
*OUTPUT- DCB                                                            16200019
*         DCBAPPIN - SET TO ZERO                                        16500019
*         DCBMRIND-X'08'- CONTROL ROUTINE BIT SET TO ZERO               16800019
*         DCBMRFLG-X'10'-DISENGAGE BIT SET TO OFF                       17100019
*                  X'20'-USER REQUESTED DISENGAGE BIT SET OFF.          17400019
*                  X'88'-SET TO ZERO FOR PCI APPENDAGE                  17700019
*                  X'04'-SET TO ONE FOR PCI APPENDAGE                   18000019
*                  X'02'-WTO MESSAGE BIT SET TO ZERO                    18300019
*         DCBWTOID-AFTER FIRST ENGAGE CONTAINS MICB (PCI) ADDR          18600019
*        IOB (PCU)                                                      18900019
*         IOB+4-ECB IS SET TO ZEROES                                    19200019
*        IOB (SCU)                                                      19500019
*         IOB+4-ECB IS SET TO ZEROES                                    19800019
*        MICB-                                                          20100019
*         MICBECB - ECB IN CURRENT MICB SET TO ZEROES                   20400019
*         MICBFLAG-X'20'-ENGAGE THIS BUFFER BIT SET OFF                 20700019
*                  X'10'-FIRST MICB AFTER ENGAGE SET ON                 21000019
*        CHANNEL PROGRAM                                                21300019
*          MSENSE CCW (FOR SCU)-COMMAND CHAIN BIT SET ON                21600019
*                     ADDRESS OF SENSE BYTE IN MICB PLACED IN DATA      21900019
*                       ADDRESS OF CCW.                                 22200019
*          MSENSE CCW (FOR PCU)-ADDRESS OF PCU SENSE BYTES IN MICB      22500019
*                       PLACED IN DATA ADDRESS PORTION OF CCW'S         22800019
*          MREAD-DATA ADDRESS PLACED IN ADDRESS PORTION OF CCW'S        23100019
*          FIRST CCW SET TO ENGAGE                                      23400019
*          FOURTH CCW SET TO NO-OP                                      23700019
*          SEVENTH CCW SET TO NO-OP                                     24000019
*        BUFFERS                                                        24300019
*         THE BUFFER CORRESPONDING TO THE CURRENT MICB IS SET TO ZEROES 24600019
*         INTERVENTION REQUIRED BIT-X'08'-SET ON IF DEVICE NOT READY    24900019
*        WRITE DELAY BUFFER - SET TO ONES                               25200019
*                                                                       25500019
*EXTERNAL ROUTINES - SVC 00 (EXCP) FOR PCU AND SCU.                     25800019
*                                                                       26100019
*EXITS NORMAL - RETURN TO READ MODULE                                   26400019
*                                                                       26700019
*EXITS ERROR - NONE                                                     27000019
*                                                                       27300019
*TABLES/WORKAREAS - NONE                                                27600019
*                                                                       27900019
*ATTRIBUTES - REENTERABLE                                               28200019
*                                                                       28500019
*NOTES - NONE                                                           28800019
*                                                                       29100019
*                                                                       29400019
*                                                                       29700019
*                                                                       30000019
*        SYMBOLIC DEFINITIONS OF REGISTERS                              30300019
PARMREG  EQU   1                                                        30600019
R1       EQU   PARMREG                                                  30700019
DCBREG   EQU   2                       BASE REGISTER FOR DCB            30900019
MICBREG  EQU   4                       BASE REGISTER FOR MICB           31200019
PCUIOBR  EQU   5                       CONTAINS PCU IOB ADDRESS         31500019
SCUIOBR  EQU   6                       CONTAINS SCU IOB ADDRESS         31800019
WRKREG7  EQU   7                                                        32100019
CCWPNTR  EQU   8                       CCW STRING POINTER               32400019
WRKREG9  EQU   9                                                        32700019
WRKREG10 EQU   10                                                       33000019
BASEREG  EQU   11                      BASE REGISTER FOR THIS ROUTINE   33300019
RTNREG   EQU   14                      CONTAINS RETURN ADDRESS          33600019
ENTRYREG EQU   15                      ENTRY POINT REGISTER             33900019
*                                                                       34200019
*              SYMBOLIC DEFINITIONS FOR DISPLACEMENTS                   34500019
*                                                                       34800019
CCWADDR  EQU   24                      DISP TO CCW ADDR IN IOB          35100019
COMNDCHN EQU   4                       DISP TO COMMAND CHAIN BIT IN CCW 35400019
DEBUCBAD EQU   36                      DISP TO SCU UCB ADDR IN DEB      35700019
ECBDISP  EQU   4                       DISP TO ECB IN IOB               36000019
IOBDISP  EQU   8                       DISP TO IOB FROM IOB PREFIX      36300019
NXTCCW   EQU   8                       DISP TO NEXT CCW IN STRING       36600019
NXTSENS  EQU   24                      DISP TO NEXT MSENSE CCW          36900019
RITEDLAY EQU   152                     DISP TO WRITE DELAY BUFF         37200019
SCUCCW   EQU   80                      DISP TO SCU CCW FROM PCU CCW     37500019
SCUIOB   EQU   48                      DISP TO SCU IOB FROM PCU IOB     37800019
UCBFL1   EQU   6                       DISP TO UCB DEVICE STATUS BYTE   38100019
ZERODISP EQU   0                       DISP OF ZERO                     38400019
NOPDIS   EQU   16                 DISP TO NOP IN SCU CCW CHAIN          38500019
*                                                                       38700019
*              MISC DEFINITIONS                                         39000019
*                                                                       39300019
CCOFF    EQU   X'BF'                   SET COMMAND CHAIN BIT OFF        39600019
CMNDCHN  EQU   X'40'                   USED TO SET COMMAND CHAIN ON     39900019
CNTR     EQU   1                       COUNTER                          40200019
CONTROL  EQU   X'08'                   CONTROL ROUTINE BEEN ENTERED     40500019
DVICERDY EQU   X'40'                   DEVICE READY FOR PROCESSING      40800019
ENDCNT   EQU   3                       MAXIMUM TIMES THRU COUNTED LOOP  41100019
ENGAGE   EQU   X'7F'                   ENGAGE FOR THIS BUFFER BIT       41400019
ENGAGECC EQU   X'EF'                   ENGAGE COMMAND CODE              41700019
FOUR     EQU   4                                                        42000019
FRSTBUF  EQU   X'10'                   SET FIRST BUFFER AFTER ENGAGE    42300019
INITBITS EQU   X'67'                   REINITIALIZE DCBMRFLG            42600019
INTVRQD  EQU   X'08'                   BUFFER INTERVENTIN REQ BIT       42900019
MREADCC  EQU   X'4C'                   MODIFIED READ COMMAND CODE       43200019
MSENSECC EQU   X'24'                   MSENSE COMMAND CODE              43500019
NOPCC    EQU   X'03'                   NO-OP COMMAND CODE               43800019
ONE      EQU   1                                                        44100019
ONES     EQU   X'FF'                   SET WRITE DELAY BUFERR TO ONES   44400019
ONE27    EQU   127                     LENGTH OF WRITE DELAY BUFFER     44700019
PSTCMPLT EQU   X'7F'                   POST EVENT COMPLETE              45000019
SETBITON EQU   X'04'                   SET ON BIT IN DCB- REINITIALIZE  45300019
SETZERO  EQU   0                                                        45600019
WTOID    EQU   X'02'                                                    45900019
ZERO     EQU   0                                                        46200019
*                                                                       46500019
*                                                                       46800019
         USING IGG019V2,BASEREG                                         47100019
         USING IHADCB,DCBREG                                            47400019
         USING MICBENTR,MICBREG                                         47700019
         LR    BASEREG,ENTRYREG        ESTABLISH BASE REGISTER          48000019
         L     MICBREG,DCBIOBA         ESTABLISH BASE REG. FOR MICB     48300019
         L     WRKREG10,MICBDATA       PICK UP ADDR OF CURRENT BUFFER   48600019
         L     WRKREG9,DCBDEBAD        LOAD ADDR OF DEB                 48900019
         L     WRKREG9,DEBUCBAD(WRKREG9)   LOAD ADDR OF UCB             49200019
         TM    UCBFL1(WRKREG9),DVICERDY    IS THE DEVICE READY          49500019
         BZ    EOB010                  YES, BRANCH                      49800019
         TM    DCBMRIND,CONTROL        CONTROL ROUTINE CAUSE NOT-READY  50100019
         BZ    EOB010                  NO, BRANCH                       50400019
         XI    DCBMRIND,CONTROL        SET OFF CONTROL RTN BIT          50700019
         OI    ZERODISP(WRKREG10),INTVRQD      SET ON INTRVNTN REQ BIT  51000019
         MVI   MICBECB,PSTCMPLT        POST AS COMPLETE                 51300019
         B     EOB050                  BRANCH AND EXIT EOB              51600019
*                                                                       51900019
EOB010   EQU   *                                                        52200019
*                                                                       52500019
         TM    DCBMRFLG,WTOID          IS THERE A WTO MESSAGE           52800019
         BZ    EOB020                  NO MESSAGE - BRANCH              53100019
         L     PARMREG,DCBWTOID        LOAD WTO ID FOR DOM MACRO        53400019
         LA    PARMREG,ZERODISP(PARMREG)    CLEAR OUT GARBAGE           53500019
         DOM   MSG=(R1)                ISSUE DOM MACRO                  53600019
         XC    DCBWTOID(FOUR),DCBWTOID   ZERO THE WTO ID WORD IN DCB    53700019
         XI    DCBMRFLG,WTOID          SET THE WTO BIT TO ZERO          54000019
*                                                                       54300019
EOB020   EQU   *                                                        54600019
*                                                                       54900019
         ST    MICBREG,DCBWTOID        UPDATE MICB ADDRESS FOR PCI      55200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 55500019
*                                                                     * 55800019
* SET ECB'S IN SCUIOB AND PCUIOB AND CURRENT BUFFER TO ZERO BEFORE    * 56100019
* ISSUING AN ENGAGE.                                                  * 56400019
*                                                                     * 56700019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 57000019
         LH    WRKREG9,DCBBUFL         LOAD LENGTH OF BUFF N. (CURRENT) 57300019
         BCTR  WRKREG9,ZERO            DECREMENT LENGTH TO ZERO BUFF N  57600019
         EX    WRKREG9,CRNTBUFF        ZERO THE CURRENT BUFFER          57900019
         MVI   MICBECB,SETZERO         ZERO CURRENT MICB ECB            58200019
         L     PCUIOBR,DCBIOBAD        PICK UP THE PCU IOB ADDRESS      58500019
         XC    ECBDISP(FOUR,PCUIOBR),ECBDISP(PCUIOBR)  ZERO PCU IOB ECB 58800019
         LA    SCUIOBR,SCUIOB(PCUIOBR) COMPUTE ADDRESS OF SCUIOB        59100019
         XC    ECBDISP(FOUR,SCUIOBR),ECBDISP(SCUIOBR)  ZERO SCU IOB ECB 59400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 59700019
*                                                                     * 60000019
* THE FOLLOWING INSTRUCTIONS UPDATE THE CCW'S IN THE STRING FOR       * 60300019
* THE SCU SO AN ENGAGE CAN BE ISSUED TO START THE DEVICE.             * 60600019
*                                                                     * 60900019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 61200019
         L     CCWPNTR,CCWADDR(PCUIOBR)  PICK UP ADDR OF PCU CCW STRING 61500019
         LA    CCWPNTR,SCUCCW(CCWPNTR) COMPUTE ADDR OF SCU CCW STRING   61800019
         ST    CCWPNTR,CCWADDR(SCUIOBR)  STORE SCU CCW ADDR IN SCU IOB  62100019
         LA    WRKREG9,MICBSENS        PICK UP ADDR OF SCU SENSE BYTE   62400019
         ST    WRKREG9,ZERODISP(CCWPNTR)  UPDTE ADDR IN MSENSE CCW      62700019
         MVI   ZERODISP(CCWPNTR),MSENSECC  RESTORE  MSENSE COMMAND CODE 63000019
         MVI   NOPDIS(CCWPNTR),MREADCC  SET FOR COMMAND REJECT          63100019
         OI    COMNDCHN(CCWPNTR),CMNDCHN  SET COMMAND CHAIN  ON         63300019
         ST    WRKREG9,NXTSENS(CCWPNTR)    PUT SENSE ADDR IN MSENSE CCW 63600019
         MVI   NXTSENS(CCWPNTR),MSENSECC   RESTORE COMMAND CODE         63900019
         NI    NXTSENS+COMNDCHN(CCWPNTR),CCOFF   TURN OFF COMMAND CHAIN 64200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 64500019
*                                                                     * 64800019
* THE FOLLOWING INSTRUCTIONS UPDATE THE CCW'S IN THE STRING FOR       * 65100019
* THE PCU SO AN ENGAGE CAN BE ISSUED TO START THE DEVICE.             * 65400019
*                                                                     * 65700019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 66000019
         NI    MICBFLAG,ENGAGE         CLEAR ENGAGE FOR THIS BUFF BIT   66300019
         OI    MICBFLAG,FRSTBUF        SET FIRST BFR AFTER ENGAGE BIT   66600019
         L     CCWPNTR,CCWADDR(PCUIOBR)    PICK UP PCU CCW ADDR         66900019
         MVI   ZERODISP(CCWPNTR),ENGAGECC  SET COMMAND CODE TO ENGAGE   67200019
         LA    WRKREG10,CNTR           ESTABLISH LOOP COUNTER           67500019
         LA    WRKREG7,ENDCNT          ESTABLISH MAXIMUM TIME THRU LOOP 67800019
*                                                                       68100019
EOB030   EQU   *                                                        68400019
*                                                                       68700019
         LA    CCWPNTR,NXTCCW(CCWPNTR) INCREMENT CCW POINTER            69000019
         L     WRKREG9,MICBDATA        PICK UP ADDRESS OF BUFFER        69300019
         AH    WRKREG9,DCBBUFL         ADD BFR LNG TO POINT TO LAST     69600019
         BCTR  WRKREG9,ZERO            BYTE FOR READ BACKWARDS.         69900019
         ST    WRKREG9,ZERODISP(CCWPNTR)   PUT DATA ADDR IN MREAD CCW   70200019
         MVI   ZERODISP(CCWPNTR),MREADCC   RESTORE MREAD COMMAND CODE   70500019
         LA    CCWPNTR,NXTCCW(CCWPNTR) INCREMENT CCW POINTER            70800019
         LA    WRKREG9,MICBSENS+ONE    PICK UP ADDR OF PCU SENSE BYTES  71100019
         ST    WRKREG9,ZERODISP(CCWPNTR)   STORE ADDR IN MSENSE CCW     71400019
         MVI   ZERODISP(CCWPNTR),MSENSECC  RESTORE MSENSE COMMAND CODE  71700019
         CR    WRKREG10,WRKREG7        PROCESSED ALL CCW'S              72000019
         BE    EOB040                  YES, BRANCH                      72300019
         LA    CCWPNTR,NXTCCW(CCWPNTR) INCREMENT CCW POINTER            72600019
         MVI   ZERODISP(CCWPNTR),NOPCC SET COMMAND CODE TO NO-OP        72900019
         L     MICBREG,MICBNEXT        PICK UP ADDR OF NEXT MICB        73200019
         LA    WRKREG10,CNTR(WRKREG10) INCREMENT LOOP COUNTER           73500019
         B     EOB030                  BRANCH TO UPDATE NEXT 3 CCWS.    73800019
*                                                                       74100019
EOB040   EQU   *                                                        74400019
*                                                                       74700019
         L     CCWPNTR,CCWADDR(PCUIOBR)  LOAD PCU CCW ADDR              75000019
         LA    CCWPNTR,RITEDLAY(CCWPNTR)  COMPUTE ADDR OF WRITE BUFFER  75300019
         MVI   ZERO(CCWPNTR),ONES             *  SET THE WRITE DELAY  * 75600019
         MVC   ONE(ONE27,CCWPNTR),ZERO(CCWPNTR)   *  BUFFER TO ONES *   75900019
         LA    WRKREG9,IOBDISP         LOAD DISP TO IOB FROM PREFIX     76200019
         AR    PCUIOBR,WRKREG9         COMPUTE PCU IOB ADDR             76500019
         AR    SCUIOBR,WRKREG9         COMPUTE SCU IOB ADDR             76800019
         MVI   DCBAPPIN,SETZERO        SET DCBAPPIN TO ZEROES           77100019
         NI    DCBMRFLG,INITBITS       RE-INITIALIZE BITS IN THE DCB    77400019
         OI    DCBMRFLG,SETBITON       RE-INITIALIZE BITS IN THE DCB    77700019
         EXCP  (5)                     ISSUE EXCP FOR PCU               78000019
         EXCP  (6)                     ISSUE EXCP FOR SCU               78300019
*                                                                       78600019
EOB050   EQU   *                                                        78900019
*                                                                       79200019
         BR    RTNREG                  RETURN TO READ MODULE            79500019
*                                                                       79800019
*                                                                       80100019
* THE FOLLOWING INSTRUCTION IS USED TO ZERO THE CURRENT BUFFER          80400019
CRNTBUFF XC    ZERO(ZERO,WRKREG10),ZERO(WRKREG10)                       80700019
*                                                                       81000019
         DS    30C                     RESERVED FOR MODIFICATIONS       81300019
         DCBD  DSORG=BS,DEVD=MR                                         81600019
*        MICBD - DUMMY SECTION FOR THE MICB                             81650019
MICBENTR DSECT                                                          81700019
MICBNEXT DS    A                                                        81750019
MICBECB  DS    A                                                        81800019
MICBFLAG DS    AL1                                                      81850019
MICBSENS DS    AL3                                                      81900019
MICBECBA DS    A                                                        81950019
MICBNM7  DS    A                                                        82000019
MICBNM1  DS    A                                                        82050019
MICBDATA DS    A                                                        82100019
         END                                                            82200019
