 TITLE   'IGG019V3 - 1419 AND 1275 CHECK ROUTINE'                       00300019
IGG019V3 CSECT                                                          00600019
*                                                                       00900019
*                                                                       01200019
*STATUS - CHANGE LVL 000   VERSION LVL 000   MODIFICATION LVL 000       01500019
*                                                                       01800019
*FUNCTION - CHECK ROUTINE FOR 1419 AND 1275.                            02100019
*            1-ZERO OUT ECB IN DECB'S.                                  02400019
*            2-DETERMINE IF AN I/O OPERATION HAS BEEN POSTED COMPLETE   02700019
*              FOR ANY OF THE CHAINED DECB'S.                           03000019
*            3-IF NONE ARE POSTED-CONSTRUCT A PARAMETER LIST OF ECB     03300019
*              ADDRESSES TO BE PASSED TO WAIT.                          03600019
*            4-WAIT FOR AN I/O OPERATION TO BE POSTED.                  03900019
*            5-DETERMINE WHICH DECB IT WAS POSTED FOR.                  04200019
*            6-DETERMINE IF THE OPERATION COMPLETED WITHOUT AN ERROR    04500019
*            7-IF AN I/O ERROR OCCURRED THEN:                           04800019
*               A-DETERMINE IF IT WAS ON THE PCU OR SCU.                05100019
*               B-IF NO SYNAD IS PRESENT CALL EOV (SVC 55) TO ABEND     05400019
*               C-BRANCH TO USER'S SYNAD ROUTINE                        05700019
*               D-ZERO MICBECB SO COMPLETE BIT WILL BE OFF              06000019
*            8-IF THE I/O OPERATION COMPLETED SUCCESSFULLY THEN         06300019
*              UPDATE THE MICB(READ) POINTER.                           06600019
*                                                                       06900019
*ENTRY POINT - IGG019V3 FROM THE CHECK MACRO EXPANSION                  07200019
*              AN EXAMPLE OF THE EXPANSION IS:                          07500019
*                LA  1,DECB       LOAD ADDR OF DECB                     07800019
*                L   14,8(15)     PICK UP DCB ADDR                      08100019
*                L  15,52(14)     PICK UP MODULE ADDR                   08400019
*                BALR 14,15       BRANCH TO MODULE                      08700019
*                                                                       09000019
*INPUT - PARAMETER LIST OF DECB ADDRESSES                               09300019
*        DECB                                                           09600019
*         DECB+4 - POINTER TO NEXT DECB                                 09900019
*         DECB+8 - DCB ADDRESS                                          10200019
*        DCB                                                            10500019
*         DCBECBLT - ADDRESS OF ECB LIST AREA                           10800019
*         DCBIOBA - ADDRESS OF MICB                                     11100019
*         DCBIOBAD - ADDRESS OF IOB                                     11400019
*         DCBSYNAD - ADDRESS OF USER'S SYNAD ROUTINE                    11700019
*        MICB                                                           12000019
*         MICBNEXT - ADDRESS OF NEXT MICB                               12300019
*         MICBECB  - X'7F' - SUCCESSFUL I/O OPERATION                   12600019
*                    X'40' - ERROR ON THE I/O OPERATION                 12900019
*         MICBECB+3- X'01'  ERROR POSTED IS ON SCU                      13200019
*        BUFFER                                                         13500019
*         BYTE 0 - X'18' - UNIT EXCEPTION OR INTERVENTION REQUIRED      13800019
*                                                                       14100019
*OUTPUT - DECB                                                          14400019
*          DECB+0 - ECB POSTED                                          14700019
*         DCB                                                           15000019
*          DCBIOBA - ADDRESS OF MICB (UPDATED TO NEXT MICB)             15300019
*         MICB                                                          15600019
*          MICBECB - X'7F' SUCCESSFUL  I/O OPERATION (COMPLETION CODE)  15900019
*                    X'40' ERROR ON THE I/O OPERATION (COMPLETION CODE) 16200019
*                    X'01' LOW ORDER BIT IN ECB - ERROR ON SCU          16500019
*          MICBFLAG - X'80' ENGAGE NECESSARY FOR THIS BUFFER BIT SET ON 16800019
*                     X'10' - FIRST BUFFER AFTER ENGAGE BIT SET OFF     17100019
*         RETURN CODES                                                  17400019
*          X'00' - I/O OPERATION COMPLETED SUCCESSFULLY                 17700019
*          X'04' - ERROR ON I/O OPERATION                               18000019
*                                                                       18300019
*EXTERNAL ROUTINES - SVC 55 (EOV)                                       18600019
*                    SVC 01 (WAIT)                                      18900019
*                    USER'S SYNAD ROUTINE                               19200019
*                                                                       19500019
*EXITS NORMAL - RETURN TO USER.                                         19800019
*                                                                       20100019
*EXITS ERROR - ABEND 001 IF THE USER FAILS TO SPECIFY A SYNAD ROUTINE.  20400019
*                                                                       20700019
*TABLES/WORKAREAS - NONE                                                21000019
*                                                                       21300019
*ATTRIBUTES - REENTERABLE                                               21600019
*                                                                       21900019
*NOTES - THE USER CAN ONLY HAVE A MAXIMUM OF 16 DEVICES CONNECTED TO    22200019
*        ONE CPU.  HENCE IF MORE THAN 16 DECB'S ARE PRESENT ONLY THE    22500019
*        FIRST 16 WILL BE PROCESSED.                                    22800019
*                                                                       23100019
*                                                                       23400019
*                                                                       23700019
*              SYMBOLIC DEFINITIONS OF REGISTERS                        24000019
*                                                                       24300019
REGZERO  EQU   0                                                        24600019
PARMR    EQU   1                       CONTAINS ADDR OF FIRST DECB      24900019
DCBR     EQU   2                       DCB ADDRESS                      25200019
ECBR     EQU   3                       ADDRESS OF ECB PARAMETER LIST    25500019
BASER    EQU   4                       BASE REGISTER                    25800019
DECBR    EQU   5                       DECB ADDRESS                     26100019
INDEXR   EQU   6                       INDEX REGISTER                   26400019
MICBR    EQU   7                       MICB ADDRESS                     26700019
REG8     EQU   8                                                        27000019
REG9     EQU   9                                                        27300019
REG10    EQU   10                                                       27600019
SAVER    EQU   13                      ADDRESS OF SAVE AREA             27900019
RETURNR  EQU   14                      RETURN ADDRESS                   28200019
ENTRYR   EQU   15                      ENTRY POINT ADDR & RETURN CODES  28500019
*                                                                       28800019
*              SYMBOLIC DEFINITIONS FOR DISPLACEMENTS                   29100019
*                                                                       29400019
DECBADR  EQU   4                       DISP TO ADDR OF NEXT DECB        29700019
DECBDCB  EQU   8                       DISP TO DCB ADDR IN DECB         30000019
DECBIOB  EQU   16                      DISP TO IOB ADDR IN DECB         30300019
IOBSENS  EQU   20                      DISP TO CSW SENSE INFO IN IOB    30600019
REG1DSP  EQU   24                      DISP TO SAVE AREA OF REG 1       30900019
RTNDSP   EQU   16                      DISP TO SET RETURN CODE          31200019
SAVEDISP EQU   12                      DISP TO SAVE AREA                31500019
SCUIOB   EQU   48                      DISP OF SCU IOB FROM PCU IOB     31800019
SIXTY4   EQU   64                      DISP TO SAVE DECBR AND BASER     32100019
SVEPRMS  EQU   20                      DISP TO SAVE SVC PARAMETERS      32400019
TWNTY8   EQU   28                      DISP TO USER REGS FOR SYNAD      32700019
ZEROD    EQU   0                       ZERO DISPLACEMENT                33000019
*                                                                       33300019
*              MISC DEFINITIONS                                         33600019
*                                                                       33900019
BUFFMPTY EQU   X'18'                   UNIT EXCPTN OR INTRVNTN REQ      34200019
DCBALTER EQU   X'10'                   DCB ALTERED--SET ON FOR CLOSE    34500019
FOUR     EQU   4                                                        34800019
FRSTENG  EQU   X'EF'                   SET OFF FRST BUFF AFTER ENGAGE   35100019
IOERROR  EQU   X'41'                                                    35400019
INDXINCR EQU   4                       INDES REGISTER INCREMENT         35700019
LISTEND  EQU   X'80'                   END OF PARAMETER LIST            36000019
MAXDEVCE EQU   16                      MAXIMUM DEVICES SUPPORTED        36300019
NOSYNAD  EQU   X'01'                   ABEND COMPLETION CODE - NO SYNAD 36600019
PSTDCMPL EQU   X'40'                   ECB COMPLETE BIT ON              36900019
SCUERROR EQU   X'01'                   ECB - ERROR ON SCU               37200019
SETON    EQU   X'80'                   ENGAGE NECESSARY ON THIS BUFFER  37500019
SHIFT12  EQU   12                      SHIFT ABEND COMPLETION CODE      37800019
SIX4     EQU   64                                                       38100019
SYNDRTN  EQU   X'01'                                                    38400019
THREE    EQU   3                                                        38700019
UNITEXCP EQU   X'FE'                   UNIT EXCEPTION BIT TO 0 FOR EOV  39000019
X7FPSTD  EQU   X'7F'                   ECB - SUCCESSFUL COMPLETION      39300019
ZERO     EQU   0                                                        39600019
OFFREQ   EQU   X'DF'              TURN OFF USER REQUEST FLAG            39700019
*                                                                       39900019
*                                                                       40200019
         USING IGG019V3,BASER                                           40500019
         USING IHADCB,DCBR                                              40800019
         USING MICBENTR,MICBR                                           41100019
         STM   RETURNR,REG10,SAVEDISP(SAVER)  SAVE USER'S REGISTERS     41400019
         LR    BASER,ENTRYR            ESTABLISH BASE REGISTER          41700019
         SR    INDEXR,INDEXR           INITALIZE INDEX REGISTER         42000019
         LR    DECBR,PARMR             LOAD THE DECB ADDR               42300019
         LR    REG10,DECBR             SAVE THE ADDR OF THE FIRST DECB  42600019
         L     DCBR,DECBDCB(DECBR)     PICK UP ADDR OF DCB FROM DECB    42900019
         L     ECBR,DCBMRIND           PICK UP ADDR OF ECB LIST AREA    43200019
         XC    ZERO(SIX4,ECBR),ZERO(ECBR)   ZERO ECB LIST AREA          43500019
         SR    PARMR,PARMR             INITALIZE REGISTER               43800019
         LA    REG9,MAXDEVCE           MAXIMUM MICR DEVICES SUPPORTED   44100019
*                                                                       44400019
CHCK010  EQU   *                                                        44700019
*                                                                       45000019
         ST    PARMR,ZEROD(DECBR)      ZERO OUT ECB IN THE DECB         45300019
         L     MICBR,DCBIOBA           PICK UP ADDRESS OF MICB          45600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 45900019
*                                                                     * 46200019
* IF THE ECB IS NOT POSTED COMPLETE FOR THE MICB - PUT ITS ADDRESS    * 46500019
* IN THE ECB PARAMETER LIST AND WAIT FOR THE EVENT TO COMPLETE        * 46800019
*                                                                     * 47100019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 47400019
         TM    MICBECB,PSTDCMPL        EVENT POSTED COMPLETE            47700019
         BO    CHCK040                 YES, BRANCH                      48000019
         LA    REG8,MICBECB            NO, PICK UP MICB ECB ADDR        48300019
         ST    REG8,ZEROD(INDEXR,ECBR) PUT THIS ADDR IN ECB ADDR LIST   48600019
         C     PARMR,DECBADR(DECBR)    IS THIS THE LAST DECB            48900019
         BE    CHCK020                 YES,BRANCH                       49200019
         LA    INDEXR,INDXINCR(INDEXR) NO, UPDATE INDX FOR NEXT DECB    49500019
         L     DECBR,DECBADR(DECBR)    PICK UP ADDR OF NEXT DECB        49800019
         L     DCBR,DECBDCB(DECBR)     PICK UP DCB ADDR FROM DECB       50100019
         BCT   REG9,CHCK010            MORE THAN 16 DEVICES NO, BRANCH  50400019
*                                                                       50700019
CHCK020  EQU   *                                                        51000019
*                                                                       51300019
         AR    INDEXR,ECBR             COMPUTE ADDR OF LAST ECB ADDR    51600019
         MVI   ZEROD(INDEXR),LISTEND   SET HIGH-ORDER BIT TO ONE        51900019
         LR    PARMR,ECBR              PUT ECB PARMLIST ADDR IN REG 1   52200019
         WAIT  1,ECBLIST=(1)           WAIT FOR ONE EVENT TO COMPLETE   52500019
         SR    INDEXR,INDEXR           INITALIZE INDEX REGISTER         52800019
         LR    DECBR,REG10             LOAD ADDR OF FIRST DECB          53100019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 53400019
*                                                                     * 53700019
* DETERMINE WHICH ECB WAS POSTED COMPLETE                             * 54000019
*                                                                     * 54300019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 54600019
*                                                                       54900019
CHCK030  EQU   *                                                        55200019
*                                                                       55500019
         L     REG8,ZEROD(INDEXR,ECBR) PICK UP MICB ECB ADDR            55800019
         TM    ZEROD(REG8),PSTDCMPL    IS THIS ECB POSTED COMPLETE      56100019
         BO    CHCK040                 YES, BRANCH                      56400019
         LA    INDEXR,INDXINCR(INDEXR) NO, INCREMENT INDEX REGISTER AND 56700019
         L     DECBR,DECBADR(DECBR)    PICK UP ADDR OF NEXT DECB        57000019
         B     CHCK030                 BRANCH TO LOOK AT NEXT ECB       57300019
*                                                                       57600019
CHCK040  EQU   *                                                        57900019
*                                                                       58200019
         L     DCBR,DECBDCB(DECBR)     PICK UP DCB ADDR FROM DECB       58500019
         L     MICBR,DCBIOBA           PICK UP MICB ADDR                58800019
         NI    MICBFLAG,FRSTENG        SET OFF FIRST BUFF AFTER ENGAGE  59100019
         MVC   ZEROD(FOUR,DECBR),MICBECB  MOVE ECB TO DECB FROM MICB    59400019
         CLI   MICBECB,X7FPSTD         SUCCESSFULL COMPLETION POSTED    59700019
         BNE   CHCK050                 NO, BRANCH                       60000019
         L     REG9,MICBDATA           LOAD ADDR OF CURRENT BUFFER      60300019
         TM    ZEROD(REG9),BUFFMPTY    UNIT EXCEP OR INTERVENTION REQ   60600019
         BZ    CHCK041                 NO, BRANCH                       60900019
         NI    DCBMRFLG,OFFREQ    TURN OFF FLAG FOR USER DISEN REQUEST  61000019
         OI    MICBFLAG,SETON          SET ENGAGE NECESSARY BIT ON      61200019
         XC    MICBECB(FOUR),MICBECB   ZERO ECB IN MICB                 61500019
         B     CHCK042                 BRANCH TO SET RETURN CODE        61800019
*                                                                       62100019
CHCK041  EQU   *                                                        62400019
*                                                                       62700019
         L     REG8,MICBNEXT           PICK UP ADDR OF NEXT MICB        63000019
         ST    REG8,DCBIOBA            STORE IT IN THE DCB              63300019
*                                                                       63600019
CHCK042  EQU   *                                                        63900019
*                                                                       64200019
         SR    ENTRYR,ENTRYR                                            64500019
         ST    ENTRYR,RTNDSP(SAVER)    SET RETURN CODE - SUCCESSFUL     64800019
         B     CHCK090                 BRANCH TO LOAD THE REGS AND EXIT 65100019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 65400019
*                                                                     * 65700019
*  DETERMINE IF I/O ERROR WAS ON PCU OR SCU.  IF IT WAS ON THE SCU    * 66000019
*  CHANGE DCB AND DECB TO SCU IOB PREFIX ADDR AND SCU IOB ADDR.       * 66300019
*                                                                     * 66600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 66900019
*                                                                       67200019
CHCK050  EQU   *                                                        67500019
*                                                                       67800019
         OI    MICBFLAG,SETON          SET ENGAGE NECESSARY BIT ON      68100019
         LR    PARMR,DCBR              SET UP DCB PARAMETER FOR SVC     68400019
         L     REG8,DCBIOBAD           PICK UP PCU IOB ADDR             68700019
         CLI   MICBECB+THREE,SCUERROR  ERROR ON SCU                     69000019
         BNE   CHCK060                 NO, BRANCH ERROR IS ON PCU       69300019
         LA    REG8,SCUIOB(REG8)       COMPUTE SCU IOB PREFIX ADDR      69600019
         ST    REG8,DCBIOBAD           STORE SCU IOB PREFIX ADDR IN DCB 69900019
         L     REG9,DECBIOB(DECBR)     LOAD PCU IOB ADDR FROM DECB      70200019
         LA    REG9,SCUIOB(REG9)       COMPUTE SCU IOB ADDR             70500019
         ST    REG9,DECBIOB(DECBR)     STORE SCU IOB ADDR IN DECB       70800019
         OI    DCBMRIND,DCBALTER       SET BIT ON TO SHOW DCB ALTERED   71100019
*                                                                       71400019
CHCK060  EQU   *                                                        71700019
*                                                                       72000019
         CLI   DCBSYNAD+THREE,SYNDRTN  SYNAD ROUTINE PRESENT            72300019
         BNE   CHCK070                 YES, BRANCH                      72600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 72900019
*                                                                     * 73200019
*  IF NO SYNAD ROUTINE IS SPECIFIED GO TO EOV (SVC 55) TO ABNORMALLY  * 73500019
*  TERMINATE THE JOB.                                                 * 73800019
*                                                                     * 74100019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 74400019
         LA    REGZERO,NOSYNAD         SET UP REG FOR ABEND - NO SYNAD  74600019
         SLL   REGZERO,SHIFT12         SHIFT ABEND CODE 12 BITS FOR EOV 74800019
         NI    IOBSENS(REG8),UNITEXCP  SET UNIT EXCEPTION BIT OFF       75000019
         EOV   (1)                                                      75300019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 75600019
*                                                                     * 75900019
*  IF THE SYNAD IS SPECIFIED--SET UP PARAMTERS AND REGISTERS BEFORE   * 76200019
*  BRANCHING TO THE SYNAD ROUTINE.  RESTORE IF USER RETURNS CONTROL.  * 76500019
*                                                                     * 76800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 77100019
*                                                                       77400019
CHCK070  EQU   *                                                        77700019
*                                                                       78000019
         MVI   FOUR(REG8),IOERROR      POST IOB ECB FOR SYNAD           78300019
         LR    REGZERO,DECBR           DECB ADDR IN REG 0 FOR SYNAD     78600019
         L     REG9,INPUTBIT           PICK UP FLAG FOR PARM REG        78900019
         LR    PARMR,DCBR              DCB ADDR IN REG 1 FOR SYNAD      79200019
         LA    PARMR,ZEROD(PARMR)      CLEAR HIGH ORDER BYTE IN REG 1   79500019
         AR    PARMR,REG9              SET FLAGS ON IN HIGH ORDER BYTE  79800019
         STM   BASER,DECBR,SIXTY4(SAVER)   SAVE DECB ADDR AND BASE REG  80100019
         L     ENTRYR,DCBSYNAD         PICK UP ADDR OF SYNAD RTN        80400019
         LM    DCBR,REG10,TWNTY8(SAVER)   LOAD USER REGS                80700019
         BALR  RETURNR,ENTRYR          BRANCH TO USER SYNAD RTN         81000019
         STM   DCBR,REG10,TWNTY8(SAVER)    SAVE USER REGS               81300019
         LM    BASER,DECBR,SIXTY4(SAVER)   LOAD DECB ADDR AND BASE REG  81600019
         L     DCBR,DECBDCB(DECBR)     LOAD DCB ADDR FROM DECB          81900019
         TM    DCBMRIND,DCBALTER       ERROR ON SCU                     82200019
         BZ    CHCK080                 NO, BRANCH                       82500019
         L     REG8,DCBIOBAD           LOAD IOB PREFIX ADDR FRO  DCB    82800019
         LA    REG9,SCUIOB             LOAD DISP FROM PCU TO SCU IOB    83100019
         SR    REG8,REG9               COMPUTE ADDR OF PCU IOB          83400019
         ST    REG8,DCBIOBAD           STORE PCU IOB PREFIX ADDR IN DCB 83700019
         L     REG8,DECBIOB(DECBR)     LOAD IOB ADDR FROM DECB          84000019
         SR    REG8,REG9               COMPUTE IOB ADDR FOR DECB        84300019
         ST    REG8,DECBIOB(DECBR)     STORE PCU IOB ADDR IN DECB       84600019
         XI    DCBMRIND,DCBALTER       SET BIT OFF TO SHOW DCB RESTORED 84900019
*                                                                       85200019
CHCK080  EQU   *                                                        85500019
*                                                                       85800019
         L     MICBR,DCBIOBA           LOAD ADDRESS OF MICB             85900019
         XC    MICBECB(FOUR),MICBECB   ZERO ECB IN MICB                 86100019
         LA    ENTRYR,FOUR             LOAD RETURN CODE                 86400019
         ST    ENTRYR,RTNDSP(SAVER)    SET RETURN CODE                  86700019
*                                                                       87000019
CHCK090  EQU   *                                                        87300019
*                                                                       87600019
         ST    DECBR,REG1DSP(SAVER)    PUT DECB ADDR IN REG 1 SAVE AREA 87900019
         LM    RETURNR,REG10,SAVEDISP(SAVER)  LOAD THE USER'S REGS      88200019
         BR    RETURNR                 RETURN TO USER                   88500019
         DS    0F                                                       88800019
INPUTBIT DC    X'80000000'             INPUT ERROR BIT SET ON IN 1      89100019
         DS    34C                     RESERVED FOR MODIFICATIONS       89400019
         DCBD  DSORG=BS,DEVD=MR                                         89700019
*        MICBD - DUMMY SECTION FOR THE MICB                             89750019
MICBENTR DSECT                                                          89800019
MICBNEXT DS    A                                                        89850019
MICBECB  DS    A                                                        89900019
MICBFLAG DS    AL1                                                      89950019
MICBSENS DS    AL3                                                      90000019
MICBECBA DS    A                                                        90050019
MICBNM7  DS    A                                                        90100019
MICBNM1  DS    A                                                        90150019
MICBDATA DS    A                                                        90200019
         END                                                            90300019
