 TITLE   'IGG019V4 - 1419 AND 1275 CONTROL ROUTINE'                     00300019
IGG019V4 CSECT                                                          00600019
*                                                                       00900019
*                                                                       01200019
*STATUS  CHANGE LVL 000,  VERSION LVL 000,  MODIFICATION LVL 000        01500019
*                                                                       01800019
*FUNCTION - DISENGAGE AND POCKET LITE ROUTINES FOR 1419 AND 1275.       02100019
*        1- IF DISENGAGE IS REQUESTED THE ROUTINE SETS FLAGS IN THE     02400019
*           DCB SO THE PCI APPENDAGE CAN DISENGAGE THE DEVICE.          02700019
*        2- IF LITE IS REQUESTED THE ROUTINE:                           03000019
*           A- DETERMINES IF THE DEVICE IS DISENGAGED                   03300019
*           B- CHECKS THE TWO BYTE POCKET LITE BUCKET AREA TO           03600019
*              DETERMINE WHICH LIGHTS TO TURN ON                        03900019
*           C- STARTS THE CHANNEL PROGAM TO TURN THE LIGHTS ON.         04200019
*           D- CHECKS TO SEE THE CCW STRING EXECUTED SUCCESSFULLY.      04500019
*           E- IF AN ERROR OCCURRED BRANCH TO THE USER'S SYNAD          04800019
*              ROUTINE.  (IF NO SYNAD IS AVAILABLE AN ABEND IS ISSUED)  05100019
*ENTRY POINT - IGG019V4 FROM THE MACRO EXPANSION.                       05400019
*              AN EXAMPLE OF THE EXPANSION IS:                          05700019
*                BAL 1,*+12          LOAD ADDRESS OF PARAMETER LIST     06000019
*                DC  A(DCB)          DCB ADDRESS                        06300019
*                DC  A(LITE-BUCKET)  LITE-BUCKET ADDRESS                06600019
*                L  14,0(1,0)        LOAD DCB ADDRESS                   06900019
*                L  15,84(14,0)      LOAD ROUTINE ADDRESS               07200019
*                BALR 14,15 FOR LITE (BAL 14,4(15) FOR DESENGAGE)       07500019
*                                                                       07800019
*INPUT - DCB                                                            08100019
*         DCBMRIND - X'08' CONTROL ROUTINE ENTERED BIT SET ON           08400019
*         DCBIOBAD - PCU IOB ADDRESS                                    08700019
*         DCBSYNAD - SYNAD ROUTINE ADDRESS                              09000019
*        SCU IOB                                                        09300019
*         16(SCUIOBR) - SCU CCW STRING ADDRESS                          09600019
*         4(SCUIOBR) - SCU ECB ADDRESS                                  09900019
*        POCKET LITE BUCKET-                                            10200019
*         TWO BYTES SUPPLIED BY USER.  (CONTAINS BITS INDICATING        10500019
*         WHICH LITES ARE TO BE TURNED ON)                              10800019
*                                                                       11100019
*OUTPUT -DCB                                                            11400019
*         DCBMRFLG-X'30' - DISENGAGE REQUESTED BY USER                  11700019
*        POCKET LITE BUCKET-                                            12000019
*         BYTE 2, BIT 7 IS SET ON IF THE DEVICE IS NOT DISENGAGED       12300019
*         WHEN THE USER REQUESTS POCKET LIGHTS TO BE TURNED OR          12600019
*         IF AN ERROR OCCURRED IN THE CCW STRING TO TURN ON THE         12900019
*         LIGHTS.                                                       13200019
*        RETURN CODES                                                   13500019
*         X'00' - NORMAL COMPLETION-NO I/O ERRORS                       13800019
*         X'04' - I/O ERROR-SYNAD RETURNED TO CHECK                     14100019
*                                                                       14400019
*        LITE CCW STRING                                                14700019
*         THE COMMAND CODE CORRESPONDING TO THE POCKET LITE TO          15000019
*         BE TURNED ON IS OUTPUT FROM THE ROUTINE                       15300019
*                                                                       15600019
*EXTERNAL ROUTINES - EXCP (SVC 00)                                      15900019
*                    WAIT (SVC 01)                                      16200019
*                    EOV (SVC 55)                                       16500019
*                    USER'S SYNAD ROUTINE                               16800019
*                                                                       17100019
*EXITS NORMAL - RETURN TO USER VIA REGISTER 14                          17400019
*                                                                       17700019
*EXITS ERROR -  ABEND DUMP IF NO SYNAD ROUTINE IS SPECIFIED             18000019
*                                                                       18300019
*TABLES/WORK AREAS-- CALLERS SAVE AREA                                  18600019
*                  - POCKET LITE BUCKET (TWO BYTES)                     18900019
*                                                                       19200019
*ATTRIBUTES - REENTERABLE                                               19500019
*                                                                       19800019
*NOTES -  NONE                                                          20100019
*                                                                       20400019
*                                                                       20700019
*                                                                       21000019
*                                                                       21300019
*              SYMBOLIC DEFINITIONS OF REGISTERS                        21600019
*                                                                       21900019
ZEROR    EQU   0                                                        22200019
REG1     EQU   1                       WORK REGISTER                    22500019
PARMR    EQU   1                                                        22800019
DCBR     EQU   2                       DCB ADDRESS                      23100019
BCKETR   EQU   3                       POCKET LITE BUCKET ADDRESS       23400019
BASER    EQU   4                       BASE REGISTER                    23700019
PCKTR    EQU   5                       CONTAINS POCKET COMMAND CODE     24000019
EVENR    EQU   6                       REGS 6 & 7 ARE USED IN DETER-    24300019
ODDR     EQU   7                       MINING WHICH POCKET LITE         24600019
SAVER    EQU   13                      ADDRESS OF SAVE AREA             24900019
RETURNR  EQU   14                      RETURN ADDRESS                   25200019
SCUIOBR  EQU   14                      SCU IOB ADDRESS                  25500019
REG15    EQU   15                      WORK REGISTER                    25800019
ENTRYR   EQU   15                      ENTRY POINT ADDR AND RETRUN CODE 26100019
*                                                                       26400019
*              SYMBOLIC DEFINITIONS FOR DISPLACEMENTS                   26700019
*                                                                       27000019
BCKTADDR EQU   4                       DISP TO PCKT LITE BCKT ADDR      27300019
BCKTBYT1 EQU   1                       DISP TO PCKT LITE BYTE 1         27600019
CCWADDR  EQU   24                      DISP TO CCW ADDR IN IOB          27900019
DISP12   EQU   12                      DISP TO REG 14 SAVE AREA         28200019
DISP20   EQU   20                                                       28500019
DISP28   EQU   28                                                       28800019
DISP56   EQU   56                                                       29100019
IOBDISP  EQU   8                       DISP TO IOB FROM IOB PREFIX      29400019
IOBECB   EQU   4                       DISP TO ECB IN IOB               29700019
IOBECBAD EQU   12                      DISP TO ECB ADDR IN IOB          30000019
LITECC   EQU   8                       DISP TO CCW FOR LITE COMMAND CDE 30300019
LITECCW  EQU   136                     DISP FROM PCU CCW TO LITE CCW    30600019
RTNCDSP  EQU   16                      DISP TO STORE RETURN CODE        30900019
SCUIOB   EQU   48                      DISP FROM PCU IOB TO SCU IOB     31200019
UNITEXCP EQU   20                      DISP TO CSW IN IOB               31500019
ZEROD    EQU   0                       ZERO DISPLACEMENT                31800019
*                                                                       32100019
*              MISC DEFINITIONS                                         32400019
*                                                                       32700019
BITSAB   EQU   2                       SHIFT TO PROC BITS A & B LAST    33000019
DCBALTER EQU   X'10'                   DCB ALTERED--SET ON FOR CLOSE    33300019
ERBITOFF EQU   X'FE'                   SET ERROR BIT OFF                33600019
ERBITON  EQU   X'01'                   SET ERROR BIT ON                 33900019
EXCPISUD EQU   X'20'                                                    34200019
FOUR     EQU   4                                                        34500019
FRST6BTS EQU   X'04'                   FIRST 6 LITES PROCESSED          34800019
INITEXCP EQU   X'CF'                                                    35100019
LASTEXCP EQU   X'10'                   LAST EXCP INDICATOR              35400019
LFTJSTFY EQU   24                      SHIFT TO LEFT JUSTIFY            35700019
LST6BTS  EQU   6                       SHIFT FOR LAST SIX BITS          36000019
NOSYNAD  EQU   X'01'                   SYNAD ROUTINE PRESENT            36300019
SETLITE  EQU   X'F7'                   SET CC TO LITE COMMAND CODE      36600019
SETOFF   EQU   X'FE'                                                    36900019
SETON    EQU   X'0C'                   CONTROL RTN-LITES PRCSD BITS     37200019
SHFTOFF  EQU   4                       SHIFT OFF LOW-ORDER BITS         37500019
SHIFT12  EQU   12                      SHIFT ABEND COMPLETION CODE      37800019
TESTBIT  EQU   1                       TEST THIS BIT                    38100019
THREE    EQU   3                                                        38400019
USERDISN EQU   X'20'                   USER DISENGAGE BIT               38700019
X7FPSTD  EQU   X'7F'                   EVENT POSTED-SUCCESSFUL COMPLETE 39000019
*                                                                       39300019
*                                                                       39600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 39900019
*                                                                     * 40200019
* THIS BRANCH IS TAKEN WHEN LITE IS SPECIFIED IN THE MACRO EXPANSION  * 40500019
*                                                                     * 40800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 41100019
         USING *,ENTRYR                ESTABLISH BASE REGISTER          41400019
         B     CNTL010                 BRANCH TO LITE ROUTINE           41700019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 42000019
*                                                                     * 42300019
* THE DISENGAGE ROUTINE SETS BITS IN THE DCBMRFLG SO THE PCI APPENDAGE* 42600019
* CAN ENGAGE THE DEVICE                                               * 42900019
*                                                                     * 43200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 43500019
         USING IHADCB,PARMR            ESTABLISH BASE REGISTER FOR DCB  43800019
         OI    DCBMRFLG,USERDISN       SET ON DISENGAGE BIT (USER)      44100019
         BR    RETURNR                 RETURN CONTROL TO USER           44400019
*                                                                       44700019
CNTL010  EQU   *                                                        45000019
*                                                                       45300019
         DROP  ENTRYR                                                   45600019
         DROP  PARMR                                                    45900019
         USING IHADCB,DCBR                                              46200019
         USING IGG019V4,BASER                                           46500019
         ST    RETURNR,DISP12(SAVER)   SAVE RETURN ADDR                 46800019
         STM   DCBR,ODDR,DISP28(SAVER)   SAVE USER REGS                 47100019
         LR    BASER,ENTRYR            ESTABLISH BASE REGISTER          47400019
         L     DCBR,ZEROD(PARMR)       ESTABLISH BASE REGISTER FOR DCB  47700019
         L     BCKETR,BCKTADDR(PARMR)  PICK UP POCKET LITE BUCKET ADDR  48000019
         NI    BCKTBYT1(BCKETR),ERBITOFF   SET POCKET ERROR BIT TO ZERO 48300019
         NI    DCBMRFG,INITEXCP        INITIALIZE EXCP INDICATOR BITS   48600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 48900019
*                                                                     * 49200019
* IF THE DEVICE HAS BEEN DISENGAGED EACH BIT CORRESPONDING TO A POCKET* 49500019
* IS TESTED TO DETERMINE IF THE POCKET LIGHT IS TO BE TURNED ON       * 49800019
*                                                                     * 50100019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 50400019
         OI    DCBMRIND,SETON          SET CNTRL RTN-LITE PRCSD BTS ON  50700019
         LH    PCKTR,PCKTCC            LOAD REG WITH PCKT COMMAND CODE  51000019
         SR    EVENR,EVENR             ZERO REGISTER                    51300019
         SR    ODDR,ODDR               ZERO REGISTER                    51600019
         IC    ODDR,ZEROD(BCKETR)      PICK UP 1ST BYTE OF LITE BUCKET  51900019
         IC    EVENR,BCKTBYT1(BCKETR)  PICK UP 2ND BYTE OF LITE BUCKET  52200019
         SRL   EVENR,SHFTOFF           SHIFT OFF LOW ORDER BITS-BYTE 2  52500019
         SLL   ODDR,LFTJSTFY           LEFT-JUSTIFY BYTE 1              52800019
         SLDL  EVENR,BITSAB            PUT POCKET LITE BITS A&B IN EVEN 53100019
*                                                                       53400019
CNTL020  EQU   *                                                        53700019
*                                                                       54000019
         LTR   ODDR,ODDR               IS THIS BIT ONE (ON)             54300019
         BM    CNTL060                 YES, BRANCH TO TURN ON LIGHT     54600019
*                                                                       54900019
CNTL030  EQU   *                                                        55200019
*                                                                       55500019
         TM    DCBMRIND,FRST6BTS       FIRST 6 LITE BITS PROCESSED      55800019
         BO    CNTL040                 NO, BRANCH                       56100019
         L     REG1,SCNDTST            LOAD TEST REG FOR LAST 6 BITS    56400019
         B     CNTL050                 BRANCH TO SHIFT FOR NEXT BIT     56700019
*                                                                       57000019
CNTL040  EQU   *                                                        57300019
*                                                                       57600019
         LH    REG1,FIRSTST            LOAD TEST REG FOR FIRST 6 BITS   57900019
*                                                                       58200019
CNTL050  EQU   *                                                        58500019
*                                                                       58800019
         TM    DCBMRFG,EXCPISUD        EXCP BEEN ISSUED                 59100019
         BZ    CNTL051                 NO, BRANCH TO SHIFT NEXT BIT     59400019
         XI    DCBMRFG,EXCPISUD        YES, SET OFF INDICATOR           59700019
         B     CNTL052                 SKIP THE SHIFT                   60000019
*                                                                       60300019
CNTL051  EQU   *                                                        60600019
*                                                                       60900019
         SLL   ODDR,TESTBIT            SHIFT TO TEST THE NEXT BIT       61200019
*                                                                       61500019
CNTL052  EQU   *                                                        61800019
*                                                                       62100019
         AH    PCKTR,NXTPCKT           UPDATE COMMAND CODE REGISTER     62400019
         CR    PCKTR,REG1              FIRST 6 BITS TESTED              62700019
         BNE   CNTL020                 NO, BRANCH TO TEST ANOTHER ONE   63000019
         CL    REG1,SCNDTST            HAVE ALL LIGHT BITS BEEN PROCD   63300019
         BE    CNTL080                 YES, BRANCH TO EXIT THIS ROUTINE 63600019
         XI    DCBMRIND,FRST6BTS       SET OFF FIRST 6 BITS INDICATOR   63900019
         SRDL  EVENR,LST6BTS           LAST 6 BITS IN ODD REG TO PROC   64200019
         B     CNTL020                 BRANCH TO TEST LAST 6 BITS       64500019
*                                                                       64800019
CNTL060  EQU   *                                                        65100019
*                                                                       65400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 65700019
*                                                                     * 66000019
* THE FOLLOWING INSTRUCTIONS CAUSE THE LIGHTS TO BE TURNED ON         * 66300019
*                                                                     * 66600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 66900019
         XI    DCBMRFG,EXCPISUD        SET ON EXCP ISSUED BIT           67200019
         SLL   ODDR,TESTBIT            SHIFT TO TEST THE NEXT BIT       67500019
         LTR   ODDR,ODDR               ANY MORE POCKET LITES TO LITE    67800019
         BC    7,CNTL061               YES, BRANCH                      68100019
         LTR   EVENR,EVENR             ANY MORE POCKET LITES TO LITE    68400019
         BC    7,CNTL061               YES, BRANCH                      68700019
         XI    DCBMRFG,LASTEXCP        NO, SET LAST EXCP INDICATOR      69000019
*                                                                       69300019
CNTL061  EQU   *                                                        69600019
*                                                                       69900019
         L     SCUIOBR,DCBIOBAD        PICK UP PCU IOB PREFIX ADDRESS   70200019
         L     REG15,CCWADDR(SCUIOBR)  PICK UP PCU CCW STRING ADDR      70500019
         LA    REG15,LITECCW(REG15)    COMPUTE LITE CCW STRING ADDR     70800019
         LA    SCUIOBR,SCUIOB(SCUIOBR) COMPUTE SCU IOB PREFIX ADDRESS   71100019
         ST    REG15,CCWADDR(SCUIOBR)  PUT CCW ADDR IN SCU IOB          71400019
         STC   PCKTR,LITECC(REG15)     PUT COMMAND CODE IN CCW STRING   71700019
         NI    LITECC(REG15),SETLITE   SET OFF BATCH NUMBER UPDATE BIT  72000019
         XC    IOBECB(FOUR,SCUIOBR),IOBECB(SCUIOBR)  ZERO SCU IOB ECB   72300019
         LA    PARMR,IOBDISP(SCUIOBR)  COMPUTE SCU IOB ADDRESS          72600019
         EXCP  (1)                                                      72900019
         L     SCUIOBR,DCBIOBAD        PICK UP PCU IOB ADDRESS          73200019
         LA    SCUIOBR,SCUIOB(SCUIOBR) COMPUTE SCU IOB ADDRESS          73500019
         L     PARMR,IOBECBAD(SCUIOBR) LOAD ECB ADDR                    73800019
         WAIT  1,ECB=(1)                                                74100019
         L     SCUIOBR,DCBIOBAD        LOAD SCUIOB PREFIX ADDR          74400019
         LA    SCUIOBR,SCUIOB(SCUIOBR)   COMPUTE SCU IOB ADDR           74700019
         CLI   IOBECB(SCUIOBR),X7FPSTD EVENT SUCCESSFULLY COMPLETED     75000019
         BE    CNTL030                 YES, TEST THE NEXT BIT           75300019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 75600019
*                                                                     * 75900019
* IF AN ERROR OCCURS IN THE I/O OPERATION TO CAUSE THE LIGHT TO BE    * 76200019
* TURNED ON THE USER'S SYNAD ROUTINE IS BRANCHED TO.  IF THERE IS     * 76500019
* NO SYNAD ROUTINE THE JOB IS TERMINATED VIA EOV (SVC 55).            * 76800019
*                                                                     * 77100019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 77400019
         OI    BCKTBYT1(BCKETR),ERBITON    NO, SET ERROR BIT ON         77700019
         TM    DCBSYNAD+THREE,NOSYNAD  SYNAD ROUTINE PRESENT            78000019
         BZ    CNTL070                 YES, BRANCH                      78300019
         LA    ZEROR,NOSYNAD           SET UP REG FOR ABEND - NO SYNAD  78500019
         SLL   ZEROR,SHIFT12           SHIFT ABEND CODE 12 BITS FOR EOV 78700019
         NI    UNITEXCP(SCUIOBR),SETOFF   SET OFF UNIT EXCEPTION BIT    78900019
         EOV   (2)                                                      79200019
*                                                                       79500019
CNTL070  EQU   *                                                        79800019
*                                                                       80100019
         OI    DCBMRIND,DCBALTER       SET BIT ON TO SHOW DCB ALTERED   80400019
         ST    SCUIOBR,DCBIOBAD        STORE SCUIOB PREFIX ADDR IN DCB  80700019
         LR    PARMR,DCBR              SET UP PARAMETERS                81000019
         SR    ZEROR,ZEROR             FOR SYNAD                        81300019
         L     REG15,CNTRLBIT          LOAD CONTROL BIT FOR REG 1       81600019
         LA    PARMR,ZEROD(PARMR)      CLEAR HIGH-ORDER BYTE            81900019
         AR    PARMR,REG15             SET ON CONTROL BIT FOR SYNAD     82200019
         L     ENTRYR,DCBSYNAD         PICK UP SYNAD ADDRESS            82500019
         STM   DCBR,BCKETR,DISP20(SAVER)   SAVE REGS 2-3                82800019
         STM   BASER,ODDR,DISP56(SAVER)    SAVE REGS 4-7                83100019
         LM    DCBR,ODDR,DISP28(SAVER)     LOAD USER REGS               83400019
         BALR  RETURNR,ENTRYR          BRANC TO SYNAD ROUTINE           83700019
         STM   DCBR,ODDR,DISP28(SAVER)     SAVE USER REGS               84000019
         LM    DCBR,BCKETR,DISP20(SAVER)   LOAD REGS 2-3                84300019
         LM    BASER,ODDR,DISP56(SAVER)    LOAD REGS 4-7                84600019
         NI    BCKTBYT1(BCKETR),ERBITOFF   SET POCKET ERROR BIT TO ZERO 84900019
         LA    REG1,SCUIOB             LOAD DISP FROM PCU TO SCU IOB    85200019
         L     SCUIOBR,DCBIOBAD        LOAD SCU IOB PREFIX ADDR         85500019
         SR    SCUIOBR,REG1            COMPUTE PCU IOB PREFIX ADDR      85800019
         ST    SCUIOBR,DCBIOBAD        RESTORE DCB PCU IOB PREFIX ADDR  86100019
         XI    DCBMRIND,DCBALTER       SET BIT OFF TO SHOW DCB RESTORED 86400019
         LA    REG15,FOUR              LOAD RETURN CODE                 86700019
         ST    REG15,RTNCDSP(SAVER)    SET RETURN CODE                  87000019
         B     CNTL030                 BRANCH TO TEST THE NEXT BIT      87300019
*                                                                       87600019
CNTL080  EQU   *                                                        87900019
*                                                                       88200019
         LA    ENTRYR,FOUR             LOAD I/O ERROR RETURN CODE       88500019
         CL    ENTRYR,RTNCDSP(SAVER)   RETURN CODE POSTED               88800019
         BE    CNTL090                 YES, BRANCH                      89100019
         SR    ENTRYR,ENTRYR                                            89400019
         ST    ENTRYR,RTNCDSP(SAVER)   SET RETURN CODE                  89700019
*                                                                       90000019
CNTL090  EQU   *                                                        90300019
*                                                                       90600019
         LM    RETURNR,ODDR,DISP12(SAVER)   LOAD USER REGS              90900019
         BR    RETURNR                 RETURN TO USER                   91200019
         DS    0F                                                       91500019
CNTRLBIT DC    X'20000000'             SET THIS BIT IN REG 1 FOR SYNAD  91800019
SCNDTST  DC    XL4'000000CF'           USED TO FIND LAST BIT TO PROC    92100019
FIRSTST  DC    XL2'006F'               FIRST 6 BITS PROCESSED           92400019
PCKTCC   DC    XL2'000F'               INITIAL POCKET COMMAND CODE      92700019
NXTPCKT  DC    XL2'0010'               NEXT POCKET LITE COMMAND CODE    93000019
         DS    40C                     RESERVED FOR MODIFICATIONS       93300019
         DCBD  DSORG=BS,DEVD=MR                                         93600019
         END                                                            93900019
