* /* START OF SPECIFICATIONS ****                                       00050021
*                                                                       00052021
*01* MODULE-NAME = IGG019V5                                             00054021
*                                                                       00056021
*01* MODULE-TYPE = MODULE                                               00058021
*                                                                       00058421
*02* PROCESSER = ASSEMBLER                                              00058821
*                                                                       00059221
**** END OF SPECIFICATIONS ***/                                         00059621
         TITLE  '1419 APPENDAGES'                                       00060000
*********************************************************************** 00153321
*                                                                       00180000
*FUNCTION:                                                              00240000
*              THE APPENDAGES CONTAINED HEREIN MONITOR THE I/O          00300000
*              OPERATIONS OF THE 1419 MAGNETIC INK CHARACTER READER.    00360000
*              THE MAIN FUNCTION OF EACH APPENDAGE IS AS FOLLOWS:       00420000
*                                                                       00480000
*              1. PCI APPENDAGE-                                        00540000
*                                                                       00600000
*                   THIS ROUTINE HANDLES NORMAL POSTING OF BUFFERS      00660000
*                   AND THE UPDATING OF DATA ADDRESSES IN BOTH THE      00720000
*                   PCU AND SCU CCW STRINGS.  IT LINKS TO (OR SCHEDULES 00780000
*                   THE USERS STACKER SELECT ROUTINE AND PLUGS THE      00840000
*                   RETURNED COMMAND INTO THE SCU CCW STRING.           00900000
*                                                                       00960000
*              2. ABNORMAL END APPENDAGE-                               01020000
*                                                                       01080000
*                   THIS ROUTINE HANDLES UNIT CHECK CONDITIONS          01140000
*                   OCCURING ON EITHER THE PCU OR SCU.  IT SETS         01200000
*                   ERROR INDICATIONS IN THE BUFFERS AND POSTS          01260000
*                   I/O  OPERATIONS IN THE MICB ECB.                    01320000
*                                                                       01380000
*              3. CHANNEL END APPENDAGE-                                01440000
*                                                                       01500000
*                   THIS ROUTINE HANDLES CHANNEL END CONDITIONS         01560000
*                   ON THE SCU  AND CHANNEL END OR UNIT EXCEPTION       01620000
*                   ON THE PCU.  BUFFER STATUS INDICATORS ARE SET       01680000
*                   AND POSTING IS DONE IN THE MICB ECBS.               01740000
*                                                                       01800000
*                                                                       01860000
*                                                                       01920000
*ENTRIES:                                                               01980000
*                                                                       02040000
*              THE FOLLOWING FOUR ENTRY POINTS ARE USED.                02100000
*                                                                       02160000
*              1. PCIAPEN-                                              02220000
*                                                                       02280000
*                   THIS IS THE ENTRY POINT FOR THE PCI APPENDAGE.      02340000
*                   IT IS LINKED TO FROM IOS WHEN A PROGRAM CONTROLLED  02400000
*                   INTERRUPT OCCURS ON THE SCU CHANNEL PROGRAM.        02460000
*                                                                       02520000
*              2. ABNEND-                                               02580000
*                                                                       02640000
*                   THIS IS THE ENTRY POINT FOR THE ABNORMAL END        02700000
*                   APPENDAGE.  IT IS LINKED TO FROM IOS WHEN UNIT      02760000
*                   CHECK OR CHANNEL ERRORS OCCUR ON THE PCU OR SCU     02820000
*                                                                       02880000
*              3. CHANEND-                                              02940000
*                                                                       03000000
*                   THIS IS THE ENTRY POINT FOR THE CHANNEL END         03060000
*                   APPENDAGE.  IT IS LINKED TO FROM IOS WHEN           03120000
*                   CHANNEL END OR UNIT EXCEPTION OCCUR.                03180000
*                                                                       03240000
*              4. SCHEDSS-                                              03300000
*                                                                       03360000
*                   THIS IS THE ENTRY POINT FOR SCHEDULED STACKER       03420000
*                   SELECT ROUTINES. IT IS GIVEN CONTROL FROM THE       03480000
*                   DISPATCHER VIA A LPSW.                              03540000
*                                                                       03600000
*                                                                       03660000
*                                                                       03720000
*INPUT:                                                                 03780000
*                                                                       03840000
*              FOLLOWING IS THE INPUT TO THE APPENDAGES.                03900000
*                                                                       03960000
*                   GR1 CONTAINS THE ADDR OF THE REQUEST ELEMENT        04020000
*                   GR2 CONTAINS THE ADDR OF THE IOB                    04080000
*                   GR3 CONTAINS THE ADDR OF THE DEB                    04140000
*                   GR4 CONTAINS THE ADDR OF THE DCB                    04200000
*                   GR7 CONTAINS THE ADDR OF THE UCB                    04260000
*                   GR14  CONTAINS THE RETURN ADDR OF IOS               04320000
*                   GR15  CONTAINS THE ENTRY POINT ADDR                 04380000
*                                                                       04440000
*              FOLLOWING IS THE INPUT TO THE SCHEDULED SS ROUTINE.      04500000
*                                                                       04560000
*                   GR1 CONTAINS THE ADDR OF THE DCB                    04620000
*                   GR13 CONTAINS THE ADDR OF A REG SAVE AREA           04680000
*                   GR15 CONTAINS THE ENTRY POINT ADDR                  04740000
*                                                                       04800000
*                                                                       04860000
*                                                                       04920000
*OUTPUT:                                                                04980000
*              BUFFER STATUS INDICATORS ARE SET AND I/O OPERATIONS      05040000
*              ARE POSTED IN THE MICB ECBS.                             05100000
*                                                                       05160000
*                                                                       05220000
*                                                                       05280000
*EXTERNAL REFERENCES:                                                   05340000
*                                                                       05400000
*              THE USERS SS ROUTINE.                                    05460000
*                                                                       05520000
*                                                                       05580000
*ERROR CONDITIONS:                                                      05640000
*                                                                       05700000
*              NONE.                                                    05760000
*                                                                       05820000
*********************************************************************** 05880000
         EJECT                                                          05940000
IGG019V5 CSECT                                                          06000000
*          VS1-3.1 CHANGES                                     @XA03626 06000321
*A765094-765182,765995-766192  ALL SYSTEMS     YA03170 SA68154 @XA03626 06002321
*A568700-568792 CHANGE APPLICABLE TO ALL SYS   YA03143 SA67967 @XA03404 06004321
*A336500-336520  CHANGE APPLICABLE TO ALL SYSTEMS       XA03385/SA67198 06010321
*          RELEASE 21 DELETIONS                                         06050313
*A454100,889700  CHANGE APPLICABLE TO ALL SYSTEMS       SA58043/OX01515 06100313
*A525400,525420,528380,845900                                   SA60294 06150313
*C492598                                                        SA53204 06160313
*1022                                                            A46398 06170313
*1022                                                            A46625 06172313
*1022                                                            A41426 06174313
*1022                                                            A43711 06176313
*1022253200                                                      A43224 06178313
*1022001200                                                      A42476 06178713
*A525700                                                         A33935 06179113
*A829800                                                         A39662 06179513
*C717000                                                         A39662 06179913
*A270100-270400,525200-526000,528040-529120,845500-845800        A33924 06199913
*C913200                                                         A33924 06209913
*D525600,528600                                                  A33924 06219913
*                                                                       06226613
*REGISTER EQUATES-                                                      06228613
*                                                                       06233313
*                                                                       06240000
RQEREG   EQU   1                        ADDR OF RQE                     06300000
IOBREG   EQU   2                        ADDR OF IOB                     06360000
DEBREG   EQU   3                        ADDR OF DEB                     06420000
DCBREG   EQU   4                        ADDR OF DCB                     06480000
RTRNRG   EQU   14                      RETURN REG                       06540000
RTRNREG  EQU   14                       RETURN  REGISTER                06600000
BASE     EQU   15                       BASE REGISTER                   06660000
CCWREG   EQU   8                        ADDR CCW STRING                 06720000
GR5      EQU   5                        WORK REGISTER                   06780000
GR6      EQU   6                        WORK REGISTER                   06840000
GR7      EQU   7                        WORK REGISTER                   06900000
GR8      EQU   8                        WORK REGISTER                   06960000
GR9      EQU   9                       WORK REG                         07020000
GR10     EQU   10                      WORK REG                         07080000
CCREG    EQU   10                       COMPLETION CODE REGISTER        07140000
ECBADR   EQU   11                       ADDR ECB TO BE POSTED           07200000
ZERO     EQU   0                        PARM REG                        07260000
PARM1    EQU   1                        PARM REG                        07320000
PARM2    EQU   2                        PARM REG                        07380000
CMICB    EQU   7                        ADDR  CURRENT MICB              07440000
BAS3     EQU   11                      BASE FOR SCHEDULED ROUTINE       07500000
BRANREG  EQU   15                       BRANCH REGISTER                 07560000
SAVREG   EQU   13                       ADDR SAVE AREA                  07620000
BA12     EQU   12                       BASE REG                        07680000
GR12     EQU   12                      TCB ADDR FOR POST                07740000
CHANEND  B     CHANDIS(BASE)       GO TO CHANNEL END HANDLER            07800000
ABNEND   B     ABNDIS(BASE)        GO TO ABNORMAL END HANDLER           07860000
SCHEDSS  B     SCHEDIS(BASE)       GO TO SCHEDULED STACKER SELECT       07920000
SIOENTER B     SIODIS(BASE)        START I/O APPENDAGE           41426  07950021
PCIAPEN  EQU   *                   START OF PCI INTERRUPT HANDLER       07980000
         USING *,BA12              ESTABLISH ADDRESSABILITY             08040000
*                                                                       08100000
*********************************************************************** 08160000
*        THE PCI APPENDAGE IS ENTERED WHENEVER A PROGRAM CONTROLLED     08220000
*        INTERRUPT OCCURS ON THE SCU COMMAND CHAIN. THE PCI BIT IS      08280000
*        ON IN BOTH WRITE DELAY COMMANDS IN THE SCU CHAIN.              08340000
*          WHEN FUNCTIONING NORMALLY, A PCI INTERRUPT SHOULD OCCUR      08400000
*        SHORTLY AFTER THE CHANNEL STARTS EXECUTING A WRITE DELAY       08460000
*        COMMAND. THE APPENDAGE GETS CONTROL AND PERFORMS NECESSARY     08520000
*        HOUSEKEEPING THEN LINKS TO THE USERS STACKER SELECT ROUTINE    08580000
*        SO A POCKET MAY BE DETERMINED FOR THE DOCUMENT JUST READ.      08640000
*          THE USER LINKS BACK TO THE APPENDAGE WHICH THEN PLUGS        08700000
*        THE CHOSEN SS COMMAND CODE INTO THE NOP COMMAND IMMEDIATELY    08760000
*        FOLLOWING THE WRITE DELAY WHICH CAUSED THE INTERRUPT.  THE     08820000
*        DOCUMENT WILL THEN BE SELECTED INTO THE POCKET CHOSEN BY THE   08880000
*        USER.                                                          08940000
*                                                                       09000000
*********************************************************************** 09060000
         LR    BA12,BASE                                                09120000
         STM   ZERO,BASE,KRESAV    SAVE REGISTERS                       09180000
         USING IHADCB,DCBREG            ESTABLISH ADDRESSABILITY        09240000
         USING DXIOB,IOBREG             FOR BLOCKS                      09300000
         BAL   TRACRET,PCITRACE    ENTER TRACE AT PCI POINT      41426  09330021
*                                                                       09360000
         L     GR8,CSW                 GET COMMAND ADDRESS              09420000
         CLI   ZERO(GR8),MREAD         READ COMMAND, QQ                 09480000
         BNE   WRNGCOM                 NO, PCI ON WRONG COMMAND         09540000
         MVI   ZERO(GR8),NOP           NOP INVALID COMMAND              09600000
         MVI   WHICH,PCIINCTL           INDICATE PCI APPEN EXECUTING    09900000
         L     CCWREG,IOBSTART-ONE     GET ADDR SCU CCW CHAIN           09960000
*                                                                       10020000
         L     GR6,DCBIOBAD             GET PCU IOB ADDR                10080000
         L     GR5,CCWD(GR6)            GET ADDR PCU CCW CHAIN          10140000
         LR    GR10,GR5                SAVE ADDR PCU CHAIN              10200000
         TM    DCBMRFLG,ST2OR3          ARE WE IN STRING 2 OR 3,QQ      10260000
         BZ    ST1005                   NO, DONT BUMP POINTER           10320000
         TM    DCBMRFLG,ST1             IS IT STRING 3                  10380000
         BZ    ST2001                   NO, GO BUMP TO STRING2          10440000
         LA    GR5,STRNGLEN(0,GR5)      BUMP TO NEXT STRING             10500000
ST2001   LA    GR5,STRNGLEN(0,GR5)      DITTO                           10560000
ST1005   L     CMICB,DCBWTOID           PICK UP ADDR CURRENT MICB       10620000
         TM    MICBFLAG(CMICB),INITIAL  FIRST AFTER AN ENGAGE, QQ       10680000
         BZ    NFIRST                  NOT FIRST BUF                    10740000
         MVI   ZERO(GR10),NOP          SET ENGAGE TO NOP                10800000
         B     DONST006                CONTINUE PROCESSING              10860000
NFIRST   EQU   *                                                        10920000
         L     GR9,MICBNM1(0,CMICB)    GET ADDR OF ZEROS                10980000
         L     GR9,MICBECBA(GR9)       SET BUFFER                       11040000
         MVI   ZERO(GR9),XFF           TO                               11100000
         MVC   ONE(SEVEN,GR9),ZERO(GR9)  ONES                           11160000
DONST006 LA    GR9,EIGHT(CCWREG)       POINT AT FIRST WD COMMAND        11220000
         TM    DCBMRFLG,CHAIN2         IN 2ND SCU STRING, QQ            11280000
         BZ    DBMPT007                N/, DONT BUMP POI TER            11340000
         LA    GR9,TWEN4(0,GR9)        POINT AT SECOND WD COMMAND       11400000
DBMPT007 L     GR9,ZERO(0,GR9)         GET ADDR WD BUFFER               11460000
         LA    GR8,FOUR8(ZERO,GR9)      LIMITING BUF ADDR        A46625 11510021
         LA    GR9,SIX4(0,GR9)         POINT AT BUFFER END              11520000
         SH    GR9,CSW+SIX             SUBTRACT RESIDUAL COUNT          11580000
         CR    GR9,GR8                  IS CALC BUF ADDR PAST    A46625 11630021
*                                         LIMIT                  A46625 11632021
         BNH   USEGR9                   WITHIN 16 BYTES OF BUF   A46625 11634021
*                                                                A46625 11636021
         LR    GR9,GR8                  USE LIMITING ADDR        A46625 11638021
USEGR9   EQU   *                                                 A46625 11638421
         MVI   ZERO(GR9),ZERO          SET UP WD BUFFER                 11640000
         MVC   ONE(SEVEN,GR9),ZERO(GR9)  TO ZEROS                       11700000
         ST    GR9,MICBECBA(0,CMICB)   SAVE ADDR OF ZEROS               11760000
WRNGCOM  EQU   *                                                        11820000
         TM    CSW+FOUR,UCHKCHND       UNIT CHECK/CHANNEL END,QQ        11880000
         BC    NOTZ,RETXX              YES, RETURN TO IOS AND LET       11940000
*                                       CHANNEL END OR ABNORMAL END     12000000
*                                       APPENDAGE HANDLE THE SITUATION  12060000
*                                                                       12120000
         TM    CSW+FIVE,CHANER         ANY OTHER ERRORS,QQ              12180000
         BC    NOTZ,RETXX              YES, RETURN TO IOS               12240000
*                                                                       12300000
         L     GR8,CSW                 GET COMMAND ADDR                 12360000
         CLI   ZERO(GR8),NOP           HAS WRITE BEEN NOPPED            12420000
         BNE   RETXX                   NO, RETURN TO IOS                12480000
         TM    DCBAPPIN,SIT0            HAS THE PCU CHAIN STOPPED,QQ    12540000
         BZ    GADCP1                  NO,   HANDLE SITUATION           12600000
RETXX    EQU   *                                                        12660000
         LM    ZERO,BASE,KRESAV        RESTORE REGS                     12720000
         BR    RTRNREG                 YES, LET SCU CHANNEL END         12780000
*                                       APPENDAGE HANDLE THE SITUATION  12840000
GADCP1   L     GR8,MICBNEXT(0,CMICB)    GET ADDR CURRENT+1              12900000
         L     GR8,MICBNEXT(0,GR8)      GET ADDR CURRENT+2              12960000
         L     GR8,MICBNEXT(0,GR8)      GET ADDR CURRENT+3              13020000
         LA    GR6,MICBSENS+ONE(0,GR8) POINT AT PCU SENSE AREA          13080000
         ST    GR6,MSDIS(0,GR5)         PUT ADDR IN MSENSE COMMAND      13140000
         MVI   MSDIS(GR5),MSENS         PUT COMMAND BACK                13200000
         L     GR6,MICBDATA(0,GR8)      LOAD DATA ADDR                  13260000
         AH    GR6,DCBBUFL              POINT AT BUFFER END             13320000
         BCTR  GR6,0                   DECREMENT BY ONE                 13380000
         ST    GR6,MRDIS(0,GR5)         PUT ADDR IN MODIFIED READ       13440000
         MVI   MRDIS(GR5),MREAD        RESTORE COMMAND                  13500000
         TM    DCBMRFLG,DISIND         HAS DISENGAGE BEEN ISSUED        13560000
         BZ    SEIFSHUD                NO, SEE IF IT SHOULD BE          13620000
         SR    GR6,GR6                 CLEAR 6                          13680000
         IC    GR6,DCBMRIND            PICK UP BUFFER COU TER           13740000
         SH    GR6,H32CON              DECREMENT IT BY ONE              13800000
         STC   GR6,DCBMRIND            REPLACE IT.                      13860000
         SRA   GR6,FIVE                SHIFT OUT NOISE                  13920000
         BNZ   NODIS010                NOT ZERO, ALL IS WELL            13980000
         MVI   NOPDIS(GR5),INVALC      SET NOP TO AN INVALID            14040000
*                                      COMMAND, THUS FORCING A          14100000
*                                      COMMAND REJECT IF THE            14160000
*                                      DISENGAGE WAS LOST.              14220000
         B     NODIS010                DONT TEST FOR DISENGAGE          14280000
SEIFSHUD EQU   *                                                        14340000
*                                                                       14400000
*                                                                       14460000
         TM    MICBFLAG(GR8),OVERRUN    IS BUFFER OVERRUN IMMINENT      14520000
         BO    DISEN008                 YES, GO SET FOR DISENGAGE       14580000
*                                                                       14640000
         TM    DCBMRFLG,URQST           DID USER REQUEST DISENGAGE      14700000
         BZ    NODIS010                 NO, DONT SET FOR STOP.          14760000
*                                                                       14820000
DISEN008 MVI   NOPDIS(GR10),DISENG     DITTO                            14880000
         MVI   STRNGLEN(GR10),DISENG     DITTO                          14940000
         MVI   STRNGLEN+STRNGLEN(GR10),DISENG   DITTO                   15000000
         OI    DCBMRFLG,DISIND          INDICATE DISENGAGE SET          15060000
         OI    DCBMRIND,SETO5          SET BUFFER COUNTER SO WE CAN     15120000
*                                      FORCE COMMAND REJECT IF          15180000
*                                      DISENGAGE COMMAND IS LOST.       15240000
*                                                                       15300000
*                                                                       15360000
NODIS010 L     GR5,MICBNEXT(0,CMICB)    GET ADDR CURRENT+1 MICB         15420000
         ST    GR5,DCBWTOID             BUMP CURRENT POINTER            15480000
         LA    GR5,MICBSENS(0,GR5)      POINT AT SENSE LOCATION         15540000
         L     CCWREG,IOBSTART-ONE     GET ADDR SCU CCW CHAIN           15600000
         TM    DCBMRFLG,CHAIN2          ARE WE IN SECOND SCU STRING     15660000
         BO    SCSTR015                 YES, GO UPDATE FIRST STRING     15720000
         ST    GR5,ZERO(0,CCWREG)      PUT SENSE ADDR IN COMMAND        15780000
         MVI   ZERO(CCWREG),MSENS      PUT COMMAND CODE BACK            15840000
         MVI   FORTY(CCWREG),MREAD     SET UP REJECT COMMAND IN CASE    15900000
*                                      OF MISSED PCI                    15960000
         NI    FOUR(CCWREG),CHAINOFF   TURN CHAIN BIT OFF               16020000
         OI    TWEN8(CCWREG),CHAINON   TURN CHAIN BIT ON IN THIS STRNG  16080000
         B     SETSS020                 GO SET SS INFO IN BUFFER        16140000
*                                                                       16200000
*                                                                       16260000
SCSTR015 ST    GR5,TWEN4(0,CCWREG)     PUT SENS ADDR IN COMMAND         16320000
         MVI   TWEN4(CCWREG),MSENS     PUT COMMAND CODE BACK            16380000
         MVI   SIXTEEN(CCWREG),MREAD   SET UP REJECT COMMAND IN CASE    16440000
*                                      OF MISSED PCI                    16500000
         NI    TWEN8(CCWREG),CHAINOFF  TURN CHAIN BIT OFF               16560000
         OI    FOUR(CCWREG),CHAINON    TURN CHAIN BIT ON IN THIS STRNG  16620000
*                                                                       16680000
*                                                                       16740000
*                                                                       16800000
SETSS020 TM    MICBFLAG(CMICB),INITIAL  FIRST BUFFER AFTER ENGAGE       16860000
         BO    SETRD040                 YES, DONT SET SS INFO           16920000
*                                                                       16980000
         L     GR5,MICBNM1(0,CMICB)     GET ADDR CURRENT-1 MICB         17040000
         L     GR8,MICBDATA(0,GR5)      GET ADDR BUFFER                 17100000
         TM    MICBSENS(GR5),LATESS     LATE STACKER SELECT,QQ          17160000
         BZ    TSTAT025                 NO, TEST AUTO SELECT            17220000
         OI    THREE(GR8),SETLTSS      INDICATE LATE SS IN BUFFER       17280000
         MVI   FIVE(GR8),XREJCOM       PUT X'CF' IN BYTE 5              17340000
TSTAT025 TM    MICBSENS(GR5),AUTSEL     WAS DOCUMENT AUTO SELECTED      17400000
         BZ    DOPST030                 NO, GO POST AS COMPLETE         17460000
         MVI   FIVE(GR8),XREJCOM       PUT X'CF' IN BYTE 5              17520000
         OI    TWO(GR8),SETAUTS        INDICATE AUTO SELECT             17580000
*                                                                       17640000
*                                                                       17700000
DOPST030 TM    MICBECB(GR5),WAIT        DID USER WAIT                   17760000
         BZ    ILPST035                 NO, GO POST MYSELF              17820000
         L     CCREG,KCODCON            LOAD COMPLETION CODE            17880000
         LA    ECBADR,MICBECB(0,GR5)    GET ECB ADDR IN REG 11          17940000
         LR    GR5,BA12                SAVE BASE                        18000000
         L     BASE,CVTAD               GET ADDR CVT                    18060000
         L     BASE,CVTOPT01(0,BASE)    GET ADDR POST ROUTINE           18120000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  18180000
         BALR  RTRNREG,BASE             LINK TO POST ROUTINE            18240000
         LR    BA12,GR5                RESTORE BASE                     18300000
         B     SETRD040                 GO SET READ STATUS              18360000
*                                                                       18420000
*                                                                       18480000
*                                                                       18540000
ILPST035 IC    CCREG,KCODCON            PICK UP COMPLETION CODE         18600000
         STC   CCREG,MICBECB(0,GR5)     POST ECB                        18660000
*                                                                       18720000
*                                                                       18780000
SETRD040 L     GR5,MICBDATA(0,CMICB)    GET BUFFER ADDR                 18840000
         MVC   TWO(TWO,GR5),MICBSENS+ONE(CMICB)  SET READ STATUS        18900000
         NI    THREE(GR5),ZBIT2        ZERO BIT 2                       18960000
         XI    DCBMRFLG,CHAIN2          UPDATE STRING IND FOR SCU       19020000
         TM    DCBMRFLG,ST2OR3          STRING 2 OR 3, QQ               19080000
         BO    WHICH045                 GO SEE WHICH ONE                19140000
         NI    DCBMRFLG,OFFBIT5         TURN OFF BIT5                   19200000
         OI    DCBMRFLG,ONBIT4         TURN ON BIT 4                    19260000
         B     TSTAT055                 GO TEST FOR AUTO SELECT         19320000
*                                                                       19380000
*                                                                       19440000
WHICH045 TM    DCBMRFLG,ONBIT5          STRING 3, QQ                    19500000
         BZ    SETB5050                 NO, GO TURN ON BIT5             19560000
         NI    DCBMRFLG,OFFBIT4         TURN OFF BIT4                   19620000
SETB5050 OI    DCBMRFLG,ONBIT5          TURN ON BIT5                    19680000
*                                                                       19740000
*                                                                       19800000
TSTAT055 TM    TWO(GR5),AUTSEL+LATESS WAS DOC AUTO SELECTED             19860021
         MVI   FIVE(GR5),XREJCOM       PUT X'CF' IN BYTE FIVE           19920000
         LA    BAS3,STPRM085+TWO       SET UP NEW PASE                  19980000
         BNZ   EXIT0120                 YES, DONT DO STACKER SELECT     20040021
*                                                                       20100000
         TM    DCBMRFLG,DEBUG           IS USER IN DEBUG MODE           20160000
         BO    FDIRB060                 YES, PREPARE TO SCHEDULE SS     20220000
         LR    PARM1,DCBREG             PUT DCB ADDR IN PARM1           20280000
         B     STPRM085                 GO SET UP PARMS FOR USER        20340000
*                                                                       20400000
*                                                                       20460000
FDIRB060 L     GR6,DEBIRBAD(0,DEBREG)   GET ADDR IRB                    20520000
         TM    RBSTAB+ONE(GR6),ACTIVE  IS IRB ACTIVE                    20580000
         BO    STPIT065                 YES, GO CANCEL CURRENT REQUEST  20640000
*                                                                       20700000
         L     GR8,DEBTCBAD(0,DEBREG)  GET ADDR OF TCB                  20760000
         TM    TCBFLGS(GR8),CANI       CAN ASYNCHRONOUS EXITS BE        20820000
*                                      SCHEDULED, QQ                    20880000
         BZ    YSCHED                  YES, GO TO STAGE 2 EFFECTOR      20940000
LB3      LA    BAS3,STPRM085+TWO       SET UP NEW PASE                  21000000
         B     EXIT0120                GO GET OUT                       21060000
YSCHED   EQU   *                                                        21120000
         TM    DCBMRFG,IQESCHED        IS THE IQE ON THE EXIT QUEUE     21180000
         BO    LB3                     YES, PREPARE TO EXIT             21240000
         OI    DCBMRFG,IQESCHED        INDICATE IQE IS QUEUED           21300000
         LA    PARM1,RBIQE+FOUR(0,GR6)  GET ADDR IQE                    21360000
         XC    RBIQE(FOUR,GR6),RBIQE(GR6)  ZERO NEXT AVAILABLE          21420000
         LCR   PARM1,PARM1              PUT IT IN COMPLEMENT FORM FOR   21480000
*                                       STAGE 2 EFFECTOR                21540000
         LR    GR8,BASE                 SAVE BASE                       21600000
         L     BASE,CVTAD               GET ADDR OF CVT                 21660000
         L     BASE,CVT0EF00(0,BASE)    GET ADDR STAGE 2 EFFECTOR       21720000
         BALR  RTRNREG,BASE             GO PUT IQE ON LIST              21780000
         LR    BASE,GR8                 RESTORE BASE                    21840000
         LA    BAS3,STPRM085+TWO       SET UP NEW BASE                  21900000
         B     EXIT0120                 GO EXIT THIS ROUTINE            21960000
*                                                                       22020000
*                                                                       22080000
STPIT065 L     GR8,DEBTCBAD(0,DEBREG)   GET ADDR OF TCB                 22140000
         L     GR9,TCBRBP(0,GR8)        GET REQUEST BLOCK ADDR          22200000
         LA    GR6,0(0,GR6)             GET RID OF GARBAGE              22260000
         CR    GR9,GR6                  IS THIS THE ADDR OF MY IRB      22320000
         BE    CHTCB070                 YES, GO MODIFY TCB REGS         22380000
*                                                                       22440000
CHKAG070 L     GR8,RBLINK(0,GR9)       GET ADDR OF NEXT RB IN CHAIN     22500000
         LA    GR8,0(0,GR8)             GET RID OF GARBAGE              22560000
         CR    GR8,GR6                  IS IT MY IRB                    22620000
         BE    CHIRB075                 YES, GO SET REGS IN PRECEDING   22680000
*                                                                IRB    22740000
         LR    GR9,GR8                  BUMP 9 AND                      22800000
         B     CHKAG070                 GO SEE IF NEXT IS MINE          22860000
*                                                                       22920000
CHTCB070 L     GR5,CVTAD                GET ADDR CVT                    22980000
         CLI   CONFIG(GR5),MVT          ARE WE IN MVT                   23040000
         BNE   DOPCP072                 NO, USE PCP REG DISPLACEMENT    23100000
         ST    DCBREG,TCBGRS+MVTR1(0,GR8)    SAVE DCB ADDR IN TCB SAVAR 23160000
         MVC   TCBGRS+MVTR13(FOUR,GR8),ZERO(GR6) PUT S AREA ADDR IN 13  23220000
         MVC   TCBGRS+MVTR15(FOUR,GR8),RBEP(GR6) PUT EP ADDR IN SVAR    23280000
         B     CHPSW080                 GO CHANGE ADDR IN OLD PSW       23340000
*                                                                       23400000
*                                                                       23460000
*                                                                       23520000
*                                                                       23580000
DOPCP072 ST    DCBREG,TCBGRS+R1(0,GR8)  PUT DCB ADDR IN R1 SAVE AREA    23640000
         MVC   TCBGRS+R13(4,GR8),0(GR6) PUT SAVE AREA ADDR IN R13       23700000
         MVC   TCBGRS+R15(4,GR8),RBEP(GR6)  PUT E.P. ADDR IN R15        23760000
         B     CHPSW080                 GO CHANGE OLD PSW IN IRB        23820000
*                                                                       23880000
*                                                                       23940000
CHIRB075 ST    DCBREG,RBGSAV+RBR1(0,GR9)  PUT DCB ADDR IN RB R1 SAVE AR 24000000
         MVC   RBGSAV+RBR13(FOUR,GR9),ZERO(GR6)  PUT S AREA ADDR IN 13  24060000
         MVC   RBGSAV+RBR15(FOUR,GR9),RBEP(GR6)  PUT EP ADDR IN 15      24120000
CHPSW080 MVC   RBOPSW+FIVE(THREE,GR6),RBEP+ONE(GR6)  CHANGE OLD PSW     24180000
         LA    BAS3,STPRM085+TWO       SET UP NEW BASE                  24240000
         B     EXIT0120                      GO LEAVE ROUTINE           24300000
*                                                                       24360000
*                                                                       24420000
*********************************************************************** 24480000
*  FOLLOWING IS THE ENTRY POINT TO THE SCHEDULED STACKER SELECT         24540000
*  ROUTINE.  NOTE THAT IF THE SS ROUTINE IS NOT TO BE SCHEDULED THIS    24600000
*  ROUTINE IS USED AS IN-LINE CODE.                                     24660000
*********************************************************************** 24720000
*                                                                       24780000
*                                                                       24840000
SCEDSSX  EQU   *                                                        24900000
         DROP  BA12                     SWITCH                          24960000
STPRM085 BALR  BAS3,0                  BASE                             25020000
         USING *,BAS3                   REGISTERS                       25080000
         LR    DCBREG,PARM1             PUT ADDR DCB IN DCBREG          25140000
         L     PARM2,DCBIMAGE           GET IMAGE ADDR ADDR IN REG2     25200000
         L     PARM1,DCBWTOID           GET ADDR CURRENT MICB           25260000
         CLI   DCBAPPIN,SIT3       IS IT SIT. 3-BAD READ         A43224 25270021
         BNE   BACK                NO, BACK UP CURR. PTR.        A43224 25280021
         XI    DCBMRFLG,CHAIN2     UPDATE SCU STRING INDICATOR   A43224 25290021
         B     NOBACK              DONT BACK UP PTR.             A43224 25300021
BACK     L     PARM1,MICBNM1(0,PARM1) GET ADDR PREV. MICB        A43224 25310021
NOBACK   EQU   *                                                 A43224 25320021
         L     PARM1,MICBDATA(0,PARM1)  POINT AT BUFFER                 25380000
         TM    DCBMRFLG,DEBUG           WAS I SCHEDULED                 25440000
         BO    DNSTK090                YES, DONT TRY TO SET STORAGE KEY 25500000
*                                                                       25560000
         L     GR6,DCBDEBAD             GET ADDR  DEB                   25620000
*                                                     MACHINE CHECKS    25920000
         L     SAVREG,DCBIOBAD          GET ADDR PCU IOB                25980000
         LA    SAVREG,IOBLN+IOBLN(0,SAVREG)  POINT AT SAVE AREA         26040000
         PSWGEN IGG019V5A,GO095,(GR6,GR5,GR6)                           26140000
*                                       BRANCH TO G0095                 26340000
DNSTK090 L     SAVREG,DCBIOBAD          GET ADDR PCU IOB                26400000
         LA    SAVREG,IOBLN+IOBLN(0,SAVREG)     POINT AT SAVE AREA      26460000
*                                                                       26520000
GO095    L     BRANREG,DCBSSAD          GET ADDR SS ROUTINE             26580000
         LR    DEBREG,DCBREG           PUT DCB ADDR IN 3                26640000
         BALR  RTRNREG,BRANREG          GO TO  USER                     26700000
*                                                                       26760000
         L     PARM2,DCBIOBAD           GET ADDR PCU IOB                26820000
         L     PARM2,IOBLN+SCUSTRNG(0,PARM2)   GET ADDR SCU CCW STRING  26880000
         IC    GR7,FOUR(0,PARM1)       PICK UP USERS SS CODE            26940000
         STC   GR7,FIVE(0,PARM1)       PUT COMMAND IN BYTE 5            27000000
         CLI   FOUR(PARM1),SSC0        IS SS INDICATOR A X'0B'   A33924 27010020
         BNE   TESTBNU                 NO/GO TEST FOR BNU        A33924 27020020
         LA    GR7,CSS0                LOAD COMMAND CODE FOR 0   A33924 27030020
TESTBNU  EQU   *                                                 A33924 27040020
         TM    ONE(PARM1),BATCH        BATCH NO. UPDATE SPECIFIED       27060000
         BO    DNTOR100                YES,LEAVE BIT 4 IN COMMAND       27120000
         LA    GR8,NVAL                GET X'F7'                        27180000
         NR    GR7,GR8                 REMOVE BIT4                      27240000
*                                                                       27300000
DNTOR100 LA    GR8,MREAD               GET READ OP CODE                 27360000
         CR    GR7,GR8                 IS USER PLUGGING A READ          27420000
         BNE   SWCHAN                  NO,  CHECK WHICH CHAIN           27480000
         L     GR8,DCBWTOID            GET CURRENT MICB ADDR            27540000
         OI    MICBFLAG(GR8),BADCOMI   INDICATE USER HAS ISSUED READ    27600000
SWCHAN   TM    DCBMRFLG,CHAIN2         CHAIN2 INDICATED, QQ             27660000
         BO    SET10105                 YES, PUT COMMAND IN CHAIN1      27720000
         STC   GR7,SS2DIS(0,PARM2)      PUT COMMAND IN CHAIN2           27780000
         B     LEAVE110                 GET READY TO GET OUT            27840000
*                                                                       27900000
SET10105 STC   GR7,SS1DIS(0,PARM2)      PUT COMMAND IN CHAIN 1          27960000
*                                                                       28020000
LEAVE110 TM    DCBMRFLG,DEBUG           IN DEBUGE MODE,QQ               28080000
         BZ    RSPSW115                 NO, GO RESTORE PSW              28140000
         NI    DCBMRFG,IQEOFF          IQE WILL BE DEQUEUED             28200000
*                                                                       28260000
         SVC   EXIT                     EXIT FROM SCHEDULED ROUTINE     28320000
*                                                                       28380000
RSPSW115 L     SAVREG,DCBIOBAD          GET ADDR PCU IOB                28440000
         LA    SAVREG,IOBLN+IOBLN(0,SAVREG) GET ADDR SAVE AREA          28500000
         PSWGEN IGG019V5B,EXIT0120,(SAVREG,GR5,GR6)                     28590000
*                                                              EXIT0120 28680000
EXIT0120 CLI   WHICH,PCUABEND          ARE WE IN ABNEND APPENDAGE,QQ    28740000
         MVI   WHICH,ZERO              ZERO SWITCH                      28800000
         BE    TSTXERR                 YES, SEE WHY                     28860000
*                                                                       28920000
         LM    ZERO,BASE,KRESAV        RESTORE SUP REGS                 28980000
         BR    RTRNRG                  RETURN TO IOS                    29040000
TSTXERR  TM    ZERSAV,UNRECOV           CALL ERP, QQ                    29100000
         LM    ZERO,BASE,KRESAV         RESTOEE SUP REGS                29160000
         BZ    FOUR(RTRNREG)           NO                               29220000
         OI    DCBMRIND,X02             INDICATE ERP IS EXECUTING       29280000
         BR    RTRNREG                  ERP WILL EXECUTE                29340000
         DROP  BAS3                                                     29400000
         EJECT                                                          29460000
*********************************************************************** 29520000
*   FOLLOWING IS THE     ABNORMAL END APPENDAGE. IT IS LINKED TO        29580000
*   FROM IOS WHENEVER UNIT CHECK OR CHANNEL ERRORS  OCCUR  ON           29640000
*   THE     CCW CHAINS. THE APPENDAGE THEN SETS ERROR INFORMATION       29700000
*   IN THE BUFFERS AND POSTS THEM COMPLETE.  IF THE ERROR WAS ANYTHING  29760000
*   OTHER THAN INTERVENTION REQUIRED, THIS APPENDAGE SPECIFIES          29820000
*   THAT THE ERP SHOULD BE SCHEDULED WHEN IT RETURNS TO IOS.            29880000
*********************************************************************** 29940000
AEAPEN   EQU   *                                                        30000000
         USING PCIAPEN,BA12                                             30060000
         LA    BA12,PCIAPEN-ABNEND(0,BASE)   SET UP BASE                30120000
         L     GR10,DCBIOBAD                 GET ADDR PCU IOB           30180000
         LA    GR10,EIGHT(0,GR10)      BUMP OVER PREFIX                 30240000
         LA    IOBREG,ZERO(0,IOBREG)   CLEAR OUT GARBAGE                30300000
         CR    GR10,IOBREG              PCU ABNORMAL END, QQ            30360000
         BNE   SCUAB800                 NO GO HANDLE SCU ABNEND         30420000
         STM   ZERO,BASE,KRESAV         SAVE IOS REGS                   30480000
         BAL   TRACRET,TRACE       ENTER TRACE FOR BREAK IN      41426  30500021
*                                       CHAIN                    41426  30520021
         TM    DCBMRIND,X02            ERP JUST FINISHED, QQ            30540000
         BZ    GTCOM005                NO, GO GET COMMAND ADDR          30600000
         NI    DCBMRIND,XFD            TURN OFF ERP GOING BIT           30660000
         TM    DCBMRIND,X01            IS SCU ERP EXECUTING             30720000
         BO    GOGETOUT                YES, LET IT POST BUFFER          30780000
*                                                                       30840000
         TM    DCBMRFG,PCURR           CURRENT NEED POSTING             30900000
         BO    NPCURR                  YES, GO POST IT                  30960000
         TM    DCBMRFG,PCURRP1         CURR+1 NEEDS POSTING, QQ         31020000
         BO    NPCURRP1                YES, GO POST IT                  31080000
*                                                                       31140000
*   NOTHING NEEDS POSTING, GET OUT                                      31200000
*                                                                       31260000
GOGETOUT LM    ZERO,BASE,KRESAV        RESTORE REGS                     31320000
         B     FOUR(0,RTRNREG)         RETURN TO IOS                    31380000
*                                                                       31440000
NPCURR   NI    DCBMRFG,X7F             TURN OFF POST CURRENT FLAG       31500000
         L     GR5,DCBWTOID            GET ADDR CURRENT                 31560000
DIDEW    TM    MICBECB(GR5),WAIT       DID USER WAIT                    31620000
         BZ    EYPST                   NO, POST HERE                    31680000
         L     CCREG,KPCUER            LOAD COMPLETION CODE             31740000
         LA    ECBADR,MICBECB(0,GR5)    GET ECB ADDR                    31800000
         LR    GR6,BA12                SAVE BASE                        31860000
         L     BASE,CVTAD              GET CVT ADDR                     31920000
         L     BASE,CVTOPT01(0,BASE)   GET ADDR OF POST ROUTINE         31980000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  32040000
         BALR  RTRNREG,BASE            LINK TO POST ROUTINE             32100000
         LR    BA12,GR6                RESTORE BASE                     32160000
EYPST    MVC   MICBECB(FOUR,GR5),KPCUER   POST IT                       32220000
         CLI   IOBSIOCC,CC3            CONDITION CODE 3, QQ             32280000
         BNE   GOGETOUT                NO, GO RETURN                    32340000
         MVI   MICBECB(GR5),NORM       SET TO NORMAL COMPLETION         32400000
         B     GOGETOUT                GO RETURN TO IOS                 32460000
*                                                                       32520000
NPCURRP1 NI    DCBMRFG,XBF             TURN OFF POST FLAG               32580000
         L     GR5,DCBWTOID            GET ADDR OF CURRENT MICB         32640000
         L     GR5,MICBNEXT(GR5)       GET ADDR CURRENT+1               32700000
         B     DIDEW                   GO POST CURR+1                   32760000
*                                                                       32820000
GTCOM005 MVI   WHICH,PCUABEND           INDICATE THAT ABNEND APPENDAGE  32880000
*                                                   IS EXECUTING        32940000
         CLI   IOBSIOCC,CC3            DEVICE NOT OPERATIONAL,QQ        33240000
         L     CMICB,DCBWTOID          GET ADDR CURRENT MICB            33360000
         BNE   XCHKCOM                 NO, SEE WHERE WE BLEW            33410021
         B     CURR020                 GO HANDLE BLOW UP ON CURRENT     33420000
XCHKCOM  EQU   *                                                        33480000
         L     GR5,IOBCSW              PICK UP COMMAND ADDR             33540000
         LA    GR5,0(0,GR5)             GET RID OF GARBAGE              33600000
         LTR   GR5,GR5                 CSW IS ZERO              SA67198 33650021
         BZ    CURR020                 YES USE CURR BUFF        SA67198 33652021
         SH    GR5,KEIGHT               POINT AT COMMAND THAT BLEW      33660000
         CLI   ZERO(GR5),MREAD         IS IT A MOD READ                 33720000
         BNE   SEEIF010                 NO, CHECK  MSENSE               33780000
*                                                                       33840000
         LA    GR5,EIGHT(0,GR5)        POINT AT MSENSE                  33900000
         B     GSENS015                 GO PICK OUT SENSE ADDR          33960000
*                                                                       34020000
SEEIF010 CLI   ZERO(GR5),MSENS         IS IT A MOD SENSE                34080000
         BE    GSENS015                 YES, GO GET SENSE ADDR          34140000
*                                                                       34200000
         LA    GR5,SIXTEEN(0,GR5)      MUST BE ENGAGE OR DISENGAGE      34260000
*                                       BUMP BY 16 TO POINT AT MSENS    34320000
GSENS015 L     GR5,ZERO(0,GR5)         GET SENSE ADDR FROM COMMAND      34380000
         LA    GR5,ZERO(0,GR5)         GET RID OF GARBAGE               34440000
         SH    GR5,KTEN                 GR5 NOW POINTS AT THE MICB      34500000
*                                       WHICH CORRESPONDS TO THE        34560000
*                                       COMMAND CHAIN THAT BLEW UP      34620000
         L     CMICB,DCBWTOID           GET ADDR OF CURRENT MICB        34680000
         LA    CMICB,0(0,CMICB)         GET RID OF GARBAGE              34740000
         CR    GR5,CMICB                DID WE BLOW UP ON CURRENT STRNG 34800000
         BE    CURR020                  YES,GO PROCESS ERROR            34860000
         L     GR5,MICBNM1(0,GR5)       POINT AT CURRENT-1              34920000
         CR    GR5,CMICB                DID WE BLOW UP ON CURRENT+1     34980000
         BE    CURP1065                 YES, GO  PROCESS ERROR          35040000
*                                                                       35100000
         B     CURP2                    MUST HAVE BLOWN UP ON CURRENT+2 35160000
*                                                                       35220000
CURR020  TM    MICBFLAG(CMICB),INITIAL  FIRST BUFF ATER AN ENGAGE       35280000
         BZ    SCUBR035                 NO, GO SEE IF SCU STILL GOING   35340000
*                                                                       35400000
         L     GR5,MICBDATA(0,CMICB)    GET ADDR BUFFER                 35460000
         BAL   RTRNREG,SESTAT          GO SET BUFFER STATUS             35520000
*                                                                       35580000
TSSCU030 TM    DCBAPPIN,XF0             HAS SCU CHAIN BROKEN            35640000
         BNZ   CHKWT050                 YES,GO SEE IF USER WAITED       35700000
         MVI   DCBAPPIN,SITF            INDICATE  SITUATION F.          35760000
*                                       THIS INDICATES  TO THE SCU      35820000
*                                       APPENDAGES THAT ONLY THE        35880000
*                                       CURRENT BUFFER NEEDS TO BE      35940000
*                                       POSTED                          36000000
*                                                                       36060000
         B     TSTIR060                 GO CHECK FOR INTV REQUIRED      36120000
*                                                                       36180000
SCUBR035 TM    DCBAPPIN,XF0             HAS SCU CHAIN BEEN BROKEN       36240000
         BNZ   SETER040                 YES, SET ERROR INFO IN BUFFER   36300000
         MVI   DCBAPPIN,SIT2            INDICATE SITUATION 2 SO THAT    36360000
*                                       SCU APPENDAGES KNOW THAT        36420000
*                                       CURRENT-1  BUFFER MUST STILL    36480000
*                                       BE SET FOR SS AND POSTED.       36540000
SETER040 L     GR5,MICBDATA(0,CMICB)    GET ADDR BUFFER                 36600000
         BAL   RTRNREG,SESTAT          GO SET BUFFER STATUS             36660000
*                                                                       36720000
CHKWT050 TM    ZERSAV,UNRECOV           GOING TO ERP                    36780000
         BNZ   REDPOST                  YES GO INDICATE WE ARE READY TO 36840000
*                                       POST UPON COMPLETION OF ERP     36900000
         TM    DCBMRIND,X01             IS SCU ERP EXECUTING            36960000
         BO    REDPOST                  YES,INDICATE WE ARE READY       37020000
*                                       ANYTIME YOU ARE.                37080000
         TM    MICBECB(CMICB),WAIT      DID USER WAIT FOR BUFFER        37140000
         BZ    IPOST055                 NO I WILL POST IT               37200000
*                                                                       37260000
         L     CCREG,KCODCON            LOAD NORMAL COMPLETION CODE     37320000
         LA    ECBADR,MICBECB(0,CMICB)  GET ECBADDR                     37380000
         LR    GR5,BA12                SAVE BASE                        37440000
         L     BASE,CVTAD               GET ADDR CVT                    37500000
         L     BASE,CVTOPT01(0,BASE)    GET ADDR POST ROUTINE           37560000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  37620000
         BALR  RTRNREG,BASE             LINK TO POST ROUTINE            37680000
         LR    BA12,GR5                RESTORE BASE                     37740000
*                                                                       37800000
*                                                                       37860000
IPOST055 MVC   MICBECB(FOUR,CMICB),KCODCON  POST COMPLETE               37920000
         B     TSTIR060                 GO LEAVE                        37980000
REDPOST  OI    DCBMRFG,PCURR            SAY CURRENT MUST BE POSTED      38040000
TSTIR060 TM    ZERSAV,UNRECOV           ERRORS BESIDES I.R.             38100000
         BNZ   GO2ERP                   SET FOR ERP                     38160000
         CLI   IOBSIOCC,CC3             DEVICE NOT READY,QQ             38220000
         BE    GO2ERP                   SET FOR ERP                     38280000
         LM    ZERO,BASE,KRESAV         RESTORE SUPV ERGS               38340000
         B     FOUR(ZERO,RTRNREG)       DONT CALL ERP FOR I.R.          38400000
*                                                                       38460000
GO2ERP   OI    DCBMRIND,X02             INDICATE ERP IS EXECUTING FOR   38520000
*                                       PCU                             38580000
         LM    ZERO,BASE,KRESAV         RESTORE SUPV REGS               38640000
         BR    RTRNREG                  LET IOS SCHEDULE ERP            38700000
*                                                                       38760000
*********************************************************************** 38820000
*   THE FOLLOWING  CODE HANDLES  THE SITUATION WHEN  THE  PCU CHAIN     38880000
*   BLOWS UP ON CURRENT+1 BUFFER.                                       38940000
*********************************************************************** 39000000
CURP2    L     GR5,MICBNEXT(0,GR5)     POINT AT C+2 MICB                39060000
         L     GR5,MICBDATA(0,GR5)     POINT AT C+2 BUFFER              39120000
         LH    GR6,DCBBUFL             GET BUFFER LEN                   39180000
         BCTR  GR6,ZERO                DECREMENT FOR EXECUTE            39240000
         EX    GR6,CLR                 CLEAR C+2 BUFFER                 39300000
*                                                                       39360000
         B     CURP1065                GO HANDLE BLOW UP AS IF IT       39420000
*                                      OCCURRED ON C+1.                 39480000
*                                                                       39540000
CURP1065 TM    DCBAPPIN,XF0             HAS SCU CHAIN BROKEN            39600000
         BZ    SETSS090                 GO SET STACKER INFO IN C-1      39660000
*                                                                       39720000
         CLI   WHICH,PCUABEND           ARE WE IN CHAN END APPENDAGE    39780000
         BNE   CLRBUF75                 YES, GO CLEAR C+1  BUFFER       39840000
*                                                                       39900000
         L     GR5,MICBDATA(0,CMICB)   GET ADDR CURRENT BUFFER          39960000
         BAL   RTRNREG,SESTAT          GO SET BUFFER STATUS             40020000
*                                                                       40080000
CLRBUF75 L     GR5,MICBNEXT(0,CMICB)    GET ADDR C+1 MICB               40140000
         L     GR5,MICBDATA(0,GR5)      GET ADDR C+1 BUFFER             40200000
         LH    GR6,DCBBUFL              GET BUFFER LENGTH               40260000
         BCTR  GR6,ZERO                 DECREMENT FOR EXECUTE           40320000
         EX    GR6,CLR                  CLEAR C+1 BUFFER                40380000
*                                                                       40440000
*                                                                       40500000
         B     CHKWT050                 GO POST AND EXIT                40560000
*                                                                       40620000
*                                                                       40680000
*                                                                       40740000
*                                                                       40800000
*                                                                       40860000
*********************************************************************** 40920000
*                                                                       40980000
*        IF PCU CHAIN BLEW UP ON CURRENT+1 BUFFER AND THE SCU CHAIN     41040000
*        HAS NOT YET BROKEN, THE FOLLOWING CODE IS EXECUTED.            41100000
*********************************************************************** 41160000
*                                                                       41220000
*                                                                       41280000
SETSS090 TM    MICBFLAG(CMICB),INITIAL  FIRST AFTER AN ENGAGE           41340000
         BO    SWHCH105                GO SEE TO C+1                    41400000
         L     GR5,MICBNM1(0,CMICB)    GET ADDR C-1 MICB                41460000
         L     GR6,MICBDATA(0,GR5)      GET C-1 BUFFER ADDR             41520000
         TM    MICBSENS(GR5),LATESS     LATE STACKER SELECT,QQ          41580000
         BZ    TSTAT095                 NO, TEST AUTO SELECT            41640000
         MVI   FIVE(GR6),XREJCOM       PUT X'CF' IN BYTE 5              41700000
*                                                                       41760000
         OI    THREE(GR6),SETLTSS      SET LATE STACKER BIT             41820000
TSTAT095 TM    MICBSENS(GR5),AUTSEL     WAS DOCUMENT AUTO SELECTED      41880000
         BZ    DPOST095                                                 41940000
         OI    TWO(GR6),SETAUTS        INDICATE AUTO SELECT             42000000
         MVI   FIVE(GR6),XREJCOM       PUT X'CF' IN BYTE 5              42060000
*                                                                       42120000
DPOST095 TM    MICBECB(GR5),WAIT        DID USER WAIT                   42180000
         BZ    MPST100                  NO, POST MYSELF                 42240000
         L     CCREG,KCODCON           LOAD COMPLETION CODE             42300000
         LA    ECBADR,MICBECB(0,GR5)    GET ECB  ADDR                   42360000
         LR    GR5,BA12                SAVE BASE                        42420000
         L     BASE,CVTAD               GET ADDR CVT                    42480000
         L     BASE,CVTOPT01(0,BASE)    GET ADDR POST ROUTINE           42540000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  42600000
         BALR  RTRNREG,BASE             GO TO POST ROUTINE              42660000
         LR    BA12,GR5                RESTORE BASE                     42720000
         B     SWHCH105                 GO SEE WHICH APPENDAGE WERE IN  42780000
*                                                                       42840000
*                                                                       42900000
MPST100  MVC   MICBECB(FOUR,GR5),KCODCON  POST C-1 COMPLETE             42960000
SWHCH105 L     GR5,MICBNEXT(0,CMICB)    GET ADDR C+1 MICB               43020000
STERR110 L     GR6,MICBDATA(0,GR5)      GET ADDR C+1 BUFF               43080000
         ST    GR5,INTSAV              SAVE 5                           43140000
         LR    GR5,GR6                 SET 5 FOR SUBROUTINE             43200000
         BAL   RTRNREG,SESTAT          GO SET BUFFER STATUS             43260000
         L     GR5,INTSAV              RESTORE 5                        43320000
         TM    ZERSAV,UNRECOV           GOING TO ERP,QQ                 43380000
         BNZ   RPOST                    YES,INDICATE READY FOR POST     43440000
         TM    DCBMRIND,X01             IS SCU EXECUTING                43500000
         BO    RPOST                    YES,INDICATE READY FOR POST     43560000
         MVC   MICBECB(FOUR,GR5),KCODCON  POST NORMAL COMPLETION        43620000
         B     LEVALON                  GET READY FOR SS                43680000
RPOST    OI    DCBMRFG,PCURRP1          CURRENT+1 MUST BE POSTED        43740000
LEVALON  EQU   *                                                        43800000
*                                                                       43860000
         L     GR5,MICBDATA(0,CMICB)    PICK UP BUFFER ADDRESS          43920000
         MVC   TWO(TWO,GR5),MICBSENS+ONE(CMICB)  SET READ STATUS        43980000
         NI    THREE(GR5),ZBIT2        ZERO BIT 2                       44040000
*                                                                       44100000
         MVI   DCBAPPIN,SIT3            SET SITUATION INDICATOR FOR     44160000
*                                       SCU APPENDAGES.                 44220000
         B     TSTAT055                 GO AND PREPARE  FOR EXIT TO     44280000
*                                       USERS  SS  ROUTINE.             44340000
*                                                                       44400000
*                                                                       44460000
*  THE FOLLOWING SUBROUTINE SETS BUFFER STATUS INDICATORS               44520000
*                                                                       44580000
SESTAT   TM    IOBCSW+FOUR,ASC         ATTENTION,S MOD,OR CU END        44640000
         ST    CMICB,CSAV              SAVE CURRENT MICB                44700000
         BZ    OTHERR                  NO, SEE IF OTHER ERRORS          44760000
         OI    ZERO(GR5),UNRECOV      SET IO ERROR BIT                  44820000
OTHERR   TM    IOBCSW+FIVE,IPPCCIC     OTHER ERRORS ININ STATUS         44880000
         BZ    TSNS                    NO, TEST SENSE                   44940000
         OI    ZERO(GR5),UNRECOV       SET IO ERROR BIT                 45000000
TSNS     TM    IOSENS0,CMRJBOC         COMM REJECT OR BUS OUT CHECK     45060000
         BZ    CHKIRQ                  NO, CHECK I.R.                   45120000
         OI    ZERO(GR5),UNRECOV       SET IO ERROR BIT                 45180000
CHKIRQ   TM    IOSENS0,INTVR           IS I.R. BIT ON                   45240000
         BZ    SAVE0                   NO, GO SAVE BYTE 0               45300000
         OI    ZERO(GR5),IR            SET ON I.R. BIT                  45360000
         NI    ZERO(GR5),UEOFF        SET UE BIT OFF            OX01515 45410003
         L     GR7,DCBDEBAD            GET ADDR PCU DEB                 45420000
         L     BASE,DEBUCBAD(GR7)      GET ADDR PCU UCB                 45480000
         OI    UCBFL1(BASE),NOTREDY    SET PCU NOT READY                45540000
         CLI   WHICH,PCUABEND          PCU ABEND, QQ                    45600000
         BNE   STSCUNR                 NO, SET SCU NOT READY            45660000
         B     SAVE0                   DONT SET SCU NOT READY           45720000
STSCUNR  EQU   *                                                        45780000
         L     BASE,DEBUCBAD+FOUR(GR7)  GET ADDR SCU UCB                45840000
         OI    UCBFL1(BASE),NOTREDY    SET SCU NOT READY                45900000
SAVE0    MVC   ZERSAV(ONE),ZERO(GR5)   SAVE BYTE ZERO                   45960000
         L     CMICB,CSAV              RESTORE MICB POINTER             46020000
         BR    RTRNREG                 RETURN                           46080000
*                                                                       46140000
*                                                                       46200000
*********************************************************************** 46260000
*                                                                       46320000
*                                                                       46380000
*                                                                       46440000
         EJECT                                                          46500000
*********************************************************************** 46560000
*                                                                       46620000
*    FOLLOWING  IS  THE CHANNEL END APPENDAGE. IT IS ENTERED WHEN       46680000
*    CHANNEL END OCCURS ON  THE PCU OR SCU CCW  CHAINS.                 46740000
*********************************************************************** 46800000
*                                                                       46860000
*                                                                       46920000
CEAPEN   EQU   *                                                        46980000
         LA    BA12,PCIAPEN-CHANEND(0,BASE)   SET BASE  REGISTER        47040000
         L     GR10,DCBIOBAD                 GET ADDR PCU IOB           47100000
         LA    GR10,EIGHT(GR10)        BUMP OVER PREFIX                 47160000
         LA    IOBREG,0(IOBREG)        CLEAR OUT GARBAGE                47220000
         CR    GR10,IOBREG              PCU CHANNEL END. QQ             47280000
         STM   ZERO,BASE,KRESAV         NO,                             47340000
         BNE   SCUCE005                 GO HANDLE SCU CHAN END          47400000
         BAL   TRACRET,TRACE       ENTER TRACE FOR BREAK IN      41426  47420021
*                                       CHAIN                    41426  47440021
         MVI   WHICH,PCUCE              INDICATE PCU CHAN END APPENDAGE 47460000
*                                       IS BEING EXECUTED               47520000
         LA    GR5,IOBLN(GR10)    POINT TO SCU IOB                      47524000
         TM    TWO(GR5),OPATTN    TEST IF OP ATTN LAST TIME             47528000
         BZ    CECONT             NO/CONTINUE CHANNEL END PROCESSING    47534000
         L     GR5,DCBDEBAD       LOAD ADDR OF DEB                      47541000
         L     GR5,DEBUCBAD(GR5)  LOAD ADDR OF PCU UCB                  47548000
         OI    UCBFL1(GR5),NOTREDY  SET PCU UCB TO NOT READY TO KEEP    47555000
*                                    PCU IN SYNC WITH SCU               47562000
CECONT   EQU   *                                                        47569000
         L     CMICB,DCBWTOID           PICK UP ADDR CURRENT MICB       47580000
*                                                                       47640000
         TM    DCBAPPIN,XF0            HAS SCU STOPPED                  47700000
         BNZ   GETGONX                 YES, POST AND LEAVE              47760000
*                                                                       47820000
         L     GR5,IOBCSW              PICKUP COMMAND ADDR              47880000
         L     GR5,ZERO(0,GR5)         GET SENSE ADDR                   47940000
         LA    GR5,ZERO(0,GR5)         GET RID OF GARBAGE               48000000
         SH    GR5,KTEN                GR5 NOW POINTS AT THE MICB WHICH 48060000
*                                CORRESPONDS TO THE COMMAND STRING      48120000
*                                      THAT TERMINATED DUE TO UNIT EX.  48180000
         LA    CMICB,0(0,CMICB)        GET RID OF GARBAGE               48240000
         CR    GR5,CMICB               TERMINATE ON CURRENT             48300000
         BE    UEONC                   YES, GO HANDLE AS NORMAL         48360000
*                                                                       48420000
* UNIT EXCEPTION ON THE PCU HAS OCCURRED ON THE CURRENT+1 BUFFER.       48480000
*  THIS MEANS THAT IO ON THE SCU WAS NOT STARTED IN TIME TO PREVENT     48540000
*  THE PCU FROM TERMINATING. THIS SITUATION WILL BE TREATED AS A        48600000
*  LATE PCI.                                                            48660000
*                                                                       48720000
         MVI   DCBAPPIN,SIT5           INDICATE SITUATION 5             48780000
         B     GIT                     GO EXIT                          48840000
*                                                                       48900000
UEONC    EQU   *                                                        48960000
         L     GR5,MICBDATA(0,CMICB)   GET ADDR C BUFFER                49020000
         OI    ZERO(GR5),UEX           TURN ON UNIT EXCEPTION           49080000
         TM    MICBECB(CMICB),WAIT      HAS USER WAITED ON THIS  A46398 49250021
         BZ    LVTME009                                          A46398 49254021
         L     CCREG,KCODCON            PUT COMP. CODE INTO R10  A46398 49256021
         LA    ECBADR,MICBECB(0,CMICB)  GET ECB ADDR             A46398 49258021
         L     BASE,CVTAD                                        A46398 49258421
         L     BASE,CVTOPT01(0,BASE)    GET ADDR OF POST ROUT.   A46398 49258821
         LR    GR5,BA12                 SAVE BASE                A46398 49259221
         L     GR12,ZERO(DEBREG)        GET TCB ADDR             A46398 49259621
         BALR  RTRNREG,BASE             TO POST.                 A46398 49259721
         LR    BA12,GR5                 RESTORE BASE            SA53204 49259821
LVTME009 MVC   MICBECB(FOUR,CMICB),KCODCON POST MICB COMP.       A46398 49259921
         MVI   DCBAPPIN,SIT2           INDICATE C-1 MUST STILL BE       49300021
*                                      SET FOR SS AND POSTED            49320000
         B     GIT                                                      49380000
GETGONX  EQU   *                                                        49440000
         TM    DCBMRIND,X01             IS SCU EXECUTING                49500000
         BNZ   RPOST2                   YES INDICATED POST NEEDED       49560000
         TM    MICBECB(CMICB),WAIT      HAS USER WAITED ON THIS BUFFER  49620000
         BZ    LVTME010                 NO, DONT LINK TO POST ROUTINE   49680000
*        L     CCREG,KSCUER             PUT COMPLETION CODE IN R10      49740000
         LA    ECBADR,MICBECB(0,CMICB)  GET ECB ADDR                    49800000
         L     BASE,CVTAD               GET ADDR OF CVT                 49860000
         L     BASE,CVTOPT01(0,BASE)    GET ADDR OF POST ROUTINE        49920000
         LR    GR5,BA12                SAVE BASE                        49980000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  50040000
         BALR  RTRNREG,BASE             LINK TO  POST ROUTINE           50100000
         LR    BA12,GR5                RESTORE BASE                     50160000
LVTME010 MVC   MICBECB(FOUR,CMICB),KSCUER  POST COMPLETE WITH ERROR     50220000
GIT      EQU   *                                                        50280000
         LM    ZER0,BASE,KRESAV         RESTORE REGISTERS               50340000
         B     FOUR(0,RTRNREG)         RETURN TO IOS                    50400000
RPOST2   OI    DCBMRFG,PCURR            CURRENT NEEDS POSTING           50460000
         B     GIT                      GO RETURN TO IOS                50520000
*                                                                       50580000
*                                                                       50640000
*                                                                       50700000
         EJECT                                                          50760000
*********************************************************************** 50820000
*   THE FOLLOWING CODE  HANDLES CHANNEL  END CONDITIONS  ON  THE        50880000
*   SCU  CCW CHAIN.                                                     50940000
*********************************************************************** 51000000
*                                                                       51060000
*                                                                       51120000
*                                                                       51180000
*                                                                       51240000
SCUCE005 L     GR5,IOBSIOCC             GET COMMAND CHAIN ADDRESS       51300000
         BAL   TRACRET,TRACE       ENTER TRACE FOR BREAK IN      41426  51320021
*                                       CHAIN                    41426  51340021
         L     GR6,DCBIOBAD             GET ADDR PCU IOB                51360000
         L     GR6,CCWD(0,GR6)         GET ADDR OF PCU CCW STRING       51420000
         LA    GR6,XPCLEN(0,GR6)       POINT AT SCU STRING              51480000
         LA    GR5,0(0,GR5)             GET RID OF GARBAGE              51540000
         CR    GR5,GR6                  DID THE CE  OCCUR ON THE        51600000
*                                       POCKET LIGHT CHAIN              51660000
         BE    WHPCU010                 NO, GO HANDLE THE INTERRUPT     51720000
         TM    DCBMRFG,LITEL           LAST LIT COMMAND, QQ             51780000
         BZ    MTCOM                   NO, MORE TO COME                 51840000
         NI    DCBMRFG,OFFLITE         TURN OFF LIGHT SWITCH            51900000
*                                                                       51960000
         OI    UCBFL1(GR7),NOTREDY     SET DEVICE TO NOT READY          52020000
         L     GR7,DCBDEBAD            GET ADDR PCU DEB                 52080000
         L     GR7,DEBUCBAD(GR7)       GET ADDR PCU UCB                 52140000
         OI    UCBFL1(GR7),NOTREDY     SET PCU TO NOT READY             52200000
MTCOM    LM    ZERO,BASE,KRESAV        RESTORE REGS                     52260000
         BR    RTRNREG                 RETURN TO IOS                    52320000
WHPCU010 OI    DCBAPPIN,BDTCE           INDICATE BROKEN DUE TO CHAN END 52380000
         MVN   CHECKARE(1),DCBAPPIN     MOVE SITUATION INDICATOR        52440000
         CLI   CHECKARE,SIT5           LATE PCI, QQ                     52500000
         BNE   NEXTSIT                 NO/GO TEST NEXT SIT       A33924 52510020
         L     GR5,IOBCSW              LOAD ADDR OF FAILING CMND A33924 52520020
         LA    GR5,0(0,GR5)            GET RID OF GARBAGE        A33924 52530020
         CLI   ZERO(GR5),EASYONE       IF E1, PREV CCW IS MS    SA60294 52540021
         BE    MSBREAK                 DO SIT O PEOCESS         SA60294 52542021
         OI    DCBAPPIN,BDTUC          INDICATE BROKEN DUE TO UC A33935 52550020
         B     HNDLLPCI                GO HANDLE LATE PCI        A33924 52570020
NEXTSIT  EQU   *                                                 A33924 52590020
         CLI   CHECKARE,SITF            HAS SITUATION F BEEN INDICATED  52620000
         BE    GETIT2                  YES, CURRENT MUST BE POSTED      52680000
         CLI   CHECKARE,SIT2            SITUATION 2                     52740000
         BE    CHKFZ020                 GO POST C-1                     52800000
         CLI   CHECKARE,ZERO           IS IT SITUATION ZERO      A33924 52804020
         BNE   SIT3035                 NO/ASSUME SITUATION 3     A33924 52808020
*                                                                A33924 52812020
* SITUATION 0 CAN OCCUR AT THIS POINT IN TIME ONLY IF PRECEEDING A33924 52816020
* PCI CAME IN SO LATE THAT THE APPENDAGE DID NOT HAVE ADEQUATE   A33924 52820020
* TIME TO UPDATE THE FOLLOWING MS COMMAND BEFORE THE CHANNEL     A33924 52824020
* FETCHES IT.  CONSEQUENTLY THE SCU CHAIN BROKE AT THE MS        A33924 52828020
* COMMAND WITH CHANNEL END AND DEVICE END ONLY.  THIS            A33924 52832020
* SITUATION WILL BE HANDLED AS A MISSED PCI.                     A33924 52836020
MSBREAK  EQU   *                                                SA60294 52838021
         L     GR5,IOBCSW          LOAD ADDR OF LAST COMMAND     A33924 52840020
         LA    GR5,0(0,GR5)        GET RID OF GARBAGE            A33924 52844020
         L     GR6,IOBSTART-ONE    LOAD START ADDR SCU CHAN PGM  A33924 52848020
         LA    GR6,EIGHT(0,GR6)    POINT TO SECOND COMMAND       A33924 52852020
         CR    GR5,GR6             ARE WE ON 1ST OR 2ND MS       A33924 52856020
         BNE   SECMS               SECOND MS                     A33924 52860020
         LA    GR6,THIR2(0,GR6)    POINT TO ASSOC NOP/SS CCW     A33924 52864020
         B     UPDTCSW             GO MODIFY IOBCSW              A33924 52868020
SECMS    EQU   *                                                 A33924 52872020
         LA    GR6,EIGHT(0,GR6)    POINT TO ASSOC NOP/SS CCW     A33924 52876020
UPDTCSW  EQU   *                                                 A33924 52880020
         MVI   0(GR6),MREAD        SET NOP/SS TO MREAD COM       A33924 52884020
         LA    GR6,EIGHT(0,GR6)    POINT PAST COMMAND            A33924 52888020
         ST    GR6,IOBCSW          MODIFY LAST COMMAND ADDR      A33924 52892020
         OI    IOBCSW+4,UC         SET UNIT CHECK IN IOB         A33924 52896020
         OI    IOBFLAG1,UXFLG      SET EXCEPTION FLAG ON IN IOB  A33924 52900020
         MVI   DCBAPPIN,SIT5       SET SITUATION 5 IN DCB        A33924 52904020
         MVI   IOBSENS0,COMREJ     SET IOBSENS0 TO COMREJ        A33924 52908020
         B     REGCH810            GO HANDLE MISSED PCI          A33924 52912020
GETIT    L     GR5,DCBWTOID             GET ADDR CURRENT MICB           52920000
POSTT011 TM    MICBECB(GR5),WAIT        HAS USER WAITED FOR BUFFER      52980000
         BZ    IPSTT015                 NO, POST MYSELF                 53040000
*                                                                       53100000
         L     CCREG,KCODCON            LOAD COMPLETION CODE            53160000
         LA    ECBADR,MICBECB(0,GR5)    GET ADDR ECB                    53220000
HDFRPST  LR    GR6,BA12                SAVE BASE                        53280000
         L     BASE,CVTAD               GET ADDR CVT                    53340000
         L     BASE,CVTOPT01(0,BASE)    GET ADDR POST ROUTINE           53400000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  53460000
         BALR  RTRNREG,BASE             GO TO POST ROUTINE              53520000
         LR    BA12,GR6                RESTORE BASE                     53580000
*                                                                       53640000
BEGON012 EQU   *                                                        53700000
         TM    DCBAPPIN,BDTLTPCI       DID UNIT CHECK OCCUR             53760000
*                                      ON SCU DUE TO MISSED PCI.        53820000
*                                       IF SO (TAKE NOTE) WE ARE        53880000
*                                      IN THE ABNORMAL END APPENDAGE    53940000
         BO    STPCI030                YES, GO INDICATE SAME            54000000
         LM    ZERO,BASE,KRESAV         RESTORE REGISTERS               54060000
         B     FOUR(0,RTRNREG)         RETURN TO IOS                    54120000
*                                                                       54180000
GETIT2   L     GR5,DCBWTOID            GET ADDR CURRENT MICB            54240000
         L     GR6,MICBDATA(0,GR5)     GET BUFFER ADDR                  54300000
         TM    ZERO(GR6),UNRECOV       ERRORS BESIDESI.R.               54360000
         BO    NOTNORM                 YES, SEE IF POST IS NEEDED       54420000
         TM    DCBMRIND,X02            IS PCU ERP EXECUTING             54480000
         BZ    GETIT                   NO, GO POST NORMAL COMPLETION    54540000
GTPERR   OI    DCBMRFG,PCURR           INDICATE CURRENT NEEDS POSTING   54600000
SORTOL   LM    ZERO,BASE,KRESAV        RESTORE REGS                     54660000
         B     FOUR(0,RTRNREG)          RETURN TO IOS                   54720000
NOTNORM  TM    DCBMRIND,X02            IS PCU ERP EXECUTING, QQ         54780000
         BO    GTPERR                  YES, INDICATE CURRENT NEEDS PST  54840000
         TM    MICBECB(GR5),WAIT       HAS USER WAITED                  54900000
         BZ    HFTPERR                 NO, POST MYSELF                  54960000
         L     CCREG,KPCUER            GET COMPLETION CODE              55020000
         LA    ECBADR,MICBECB(0,GR5)   GET ECG ADDR                     55080000
         B     HDFRPST                 GO POST ABNORMAL COMPLETION      55140000
HFTPERR  MVC   MICBECB(ONE,GR5),KPCUER  POST COMPLETION                 55200000
         B     SORTOL                  GO EXIT                          55260000
IPSTT015 MVC   MICBECB(0,GR5),KCODCON   POST COMPLETE                   55320000
         B     BEGON012                 SEE  WHAT SIT WE RE  IN         55380000
CHKFZ020 L     CMICB,DCBWTOID           GET ADDR CURRENT MICB           55440000
         L     GR5,MICBNM1(0,CMICB)     GET ADDR C-1 MICB               55500000
         L     GR6,MICBDATA(0,GR5)      GET ADDR C-1 BUFFER             55560000
         TM    MICBFLAG(CMICB),INITIAL  FIRST BUFFER AFTER AN ENGAGE    55620000
         BO    BEGON012                 YES, LEAVE.                     55680000
*                                                                       55740000
CHKSS024 TM    MICBSENS(GR5),LATESS     LATE STACKER SELECT, QQ         55800000
         BZ    ISTAT025                 NO, CHECK FOR AUTO SELECT       55860000
         MVI   FIVE(GR6),XREJCOM       PUT X'CF' IN BYTE 5              55920000
         OI    THREE(GR6),SETLTSS      INDICATE LATE SS IN BUFFER       55980000
ISTAT025 TM    MICBSENS(GR5),AUTSEL     WAS DOCUMENT AUTO SELECTED      56040000
         BZ    POSTT011                 NO, GO POST COMPLETION,         56100000
         MVI   FIVE(GR6),XREJCOM       PUT X'CF' IN BYTE 5              56160000
         OI    TWO(GR6),SETAUTS        INDICATE AUTO SELECT             56220000
         B     POSTT011                 GO  POST AS COMPLETE            56280000
*                                                                       56340000
*                                                                       56400000
STPCI030 L     GR5,MICBDATA(0,CMICB)    GET CURRENT BUFFER ADDR         56460000
         OI    ZERO(GR5),PCIMISD       INDICATE PCI WAS MISSED          56520000
         LA    GR5,INDLEN(0,GR5)        BUMP OVER BUFFER STATUS         56580000
         LH    GR6,DCBBUFL              GET BUFFER LENGTH               56640000
         SH    GR6,KELEVN               DECREMENT FOR EXECUTE           56700000
         EX    GR6,CLR                  CLEAR  C+1 BUFFER               56760000
*                                                                       56820000
         L     GR5,MICBNEXT(0,CMICB)    GET NEXT MICB          @XA03626 56870021
         L     GR5,MICBDATA(0,GR5)      GET BUFFER ADDRESS     @XA03626 56872021
         TM    FIVE(GR5),XFF            HAS BUF BEEN PROCESSED @XA03626 56874021
         BNO   BUFOK                    NO,DONT NEED TO CLEAR  @XA03626 56876021
         LA    GR5,INDLEN(0,GR5)        BUMP OVER BUFFER STATUS@XA03626 56878021
         EX    GR6,CLR                  CLEAR BUFFER           @XA03626 56878421
*                                                              @XA03626 56878821
BUFOK    EQU   *                                               @XA03626 56879221
         CLI   CHECKARE,SIT5           HAS PCU QUIT                     56880000
         BNE   RESGO                   NO, GO EXIT                      56940000
         TM    DCBAPPIN,BDTUC           ARE WE GOING TO ERP             57000000
         BO    RPOST3                   YES, SET POST READY             57060000
*                                                                       57120000
         TM    MICBECB(CMICB),WAIT     HAS USER WAITED                  57180000
         BZ    DNGPST                  NO, POST MYSELF                  57240000
         L     CCREG,KSCUER            GET COMPLETION CODE              57300000
         LA    ECBADR,MICBECB(0,CMICB)    GET ECB ADDR                  57360000
         LR    GR6,BA12                SAVE BASE                        57420000
         L     BASE,CVTAD              GET ADDR CVT                     57480000
         L     BASE,CVTOPT01(0,BASE)   GET ADDR POST ROUTINE            57540000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  57600000
         BALR  RTRNREG,BASE            GO TO POST ROUTINE               57660000
         LR    BA12,GR6                RESTORE BASE                     57720000
DNGPST   MVC   MICBECB(FOUR,CMICB),KSCUER  POST COMPLETION              57780000
RESGO    TM    DCBAPPIN,BDTUC           ARE WE GOING TO ERP             57840000
         BZ    DSYES                    NO, BRANCH AROUND BIT SET       57900000
         OI    DCBMRIND,X01             INDICATE C SCU ERP EXECUTING    57960000
DSYES    LM    ZERO,BASE,KRESAV         RESTORE REGS                    58020000
         BR    RTRNREG                                                  58080000
*                                                                       58140000
RPOST3   OI    DCBMRFG,PCURR            CURRENT NEEDS POSTING           58200000
         B    RESGO                    GO GET OUT                       58260000
*                                                                       58320000
*                                                                       58380000
SIT3035  L     GR5,DCBWTOID             GET ADDR CURRENT                58440000
         L     GR6,MICBDATA(0,GR5)      GET ADDR BUFFER                 58500000
         B     CHKSS024                 GO SET SS INFO                  58560000
*                                                                       58620000
*                                                                       58680000
*                                                                       58740000
         EJECT                                                          58800000
*                                                                       58860000
*********************************************************************** 58920000
*   THE  FOLLOWING CODE IS  EXECUTED IF  ABNORMAL END  OCCURS  ON       58980000
*   THE SCU CCW  CHAIN.                                                 59040000
*********************************************************************** 59100000
*                                                                       59160000
SCUAB800 STM   ZERO,BASE,KRESAV         SAVE REGS                       59220000
         BAL   TRACRET,TRACE       ENTER TRACE FOR BREAK IN      41426  59240021
*                                       CHAIN                    41426  59260021
         MVI   WHICH,SCUAB             INDICATE SCU ABEND GOING         59280000
         TM    DCBMRIND,X01            ERP JUST FINISH, QQ              59340000
         BZ    CHKCN805                NO, CONTINUE                     59400000
*                                                                       59460000
         NI    DCBMRIND,XFE            TURN OFF ERP GOING               59520000
         TM    DCBMRIND,X02            IS PCU ERP GOING                 59580000
         BO    NWGO                    YES, LET IT POST BUFFER          59640000
*                                                                       59700000
         TM    DCBMRFG,PCURR           CURRENT NEED POSTING, QQ         59760000
         BO    XPCURR                  YES, GO DO IT                    59820000
         TM    DCBMRFG,PCURRP1         CURR+1 NEED POSTING, QQ          59880000
         BO    XPCURRP1                YES, GO DO IT                    59940000
*                                                                       60000000
*  NOTHING NEEDS POSTING.  GET OUT                                      60060000
*                                                                       60120000
NWGO     LM    ZERO,BASE,KRESAV        RESTORE REGS                     60180000
         B     FOUR(0,RTRNREG)         RETURN TO IOS                    60240000
*                                                                       60300000
XPCURR   NI    DCBMRFG,X7F             TURN OFF POST CURRENT FLAG       60360000
         L     GR5,DCBWTOID            GET ADDR CURRENT MICB            60420000
XDIDEW   TM    MICBECB(GR5),WAIT       DID USER WAIT, QQ                60480000
         BZ    XEYPOST                 NO, POST HERE                    60540000
         L     CCREG,KSCUER            LOAD COMPLETION CODE             60600000
         LA    ECBADR,MICBECB(0,GR5)   GET ECB ADDR                     60660000
         LR    GR6,BA12                SAVE BASE                        60720000
         L     BASE,CVTAD              GET CVT ADDR                     60780000
         L     BASE,CVTOPT01(0,BASE)   GET ADDR POST ROUTINE            60840000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  60900000
         BALR  RTRNREG,BASE            GO POST COMPLETION               60960000
         LR    BA12,GR6                RESTORE BASE                     61020000
XEYPOST  MVC   MICBECB(FOUR,GR5),KSCUER  POST COMPLETE                  61080000
         B     NWGO                    GO GET OUT                       61140000
*                                                                       61200000
XPCURRP1 NI    DCBMRFG,XBF             TURN OFF POST FLAG               61260000
         L     GR5,DCBWTOID            GET ADDR CURRENT MICB            61320000
         L     GR5,MICBNEXT(0,GR5)     GET ADDR CURR+1                  61380000
         B     XDIDEW                  GO POST                          61440000
*                                                                       61500000
CHKCN805 L     GR5,IOBSIOCC             GET COMMAND CHAIN ADDRESS       61560000
         L     GR6,DCBIOBAD             GET ADDR PCU IOB                61620000
         L     GR6,CCWD(0,GR6)         GET ADDR OF PCU CCW STRING       61680000
         LA    GR6,XPCLEN(0,GR6)       POINT AT SCU STRING              61740000
         LA    GR5,0(0,GR5)             GET RID OF GARBAGE              61800000
         CR    GR5,GR6                  ARE WE ON POCKET LIGHT CHAIN    61860000
         BE    REGCH810                 NO, GO HANDLE INTERRUPT         61920000
         TM    DCBMRFG,LITEL           LAST LITE COMMAND, QQ            61980000
         BZ    MTCOM2                  NO, MORE TO COME                 62040000
         NI    DCBMRFG,OFFLITE         TURN OFF LITE SW                 62100000
*                                                                       62160000
         OI    UCBFL1(GR7),NOTREDY     SET DEVICE TO NOT READT          62220000
         L     GR7,DCBDEBAD            GET ADDR PCU DEB                 62280000
         L     GR7,DEBUCBAD(GR7)       GET ADDR PCU UCB                 62340000
         OI    UCBFL1(GR7),NOTREDY     SET PCU TO NOT READY             62400000
MTCOM2   LM    ZERO,BASE,KRESAV        RESTORE REGS                     62460000
         BR    RTRNREG                 RETURN                           62520000
*                                                                       62580000
*                                                                       62640000
REGCH810 OI    DCBAPPIN,BDTUC           INDICATE SCU CHAIN BROKEN DUE   62700000
*                                                                       62760000
         MVN   CHECKARE(1),DCBAPPIN     ISOLATE SITUATION               62820000
         CLI   CHECKARE,SIT5           LATE PCI, QQ                     62880000
         BE    HNDZR815                YES,GO HANDLE IT                 62940000
         CLI   CHECKARE,SITF            IS IT SITUATION  F              63000000
         BE    HNDF3820                 YES, GO HANDLE IT               63060000
         CLI   CHECKARE,SIT3            IS IT SITUATION 3               63120000
         BE    HNDSIT3                  YES, HANDLE IT                  63180000
         CLI   CHECKARE,ZER0           IS IT SITUTATION 0               63240000
         BE    HNDZR815                 YES HANDLE                      63300000
         CLI   CHECKARE,SIT2            SITUATION 2                     63360000
         BE    HNDST855                 YES, HANDLE IT                  63420000
HNDZR815 L     GR5,IOBCSW              PICK UP COMMAND ADDR             63480000
         LA    GR5,0(0,GR5)             GET RID OF GARBAGE              63540000
         SH    GR5,KEIGHT               POINT AT FAILING COMMAND        63600000
*                                                                       63660000
         CLI   ZERO(GR5),MREAD         IS IT A READ COMMAND             63720000
         BNE   RGUCK875                NO, GO HANDLE REGULAR UNIT CHECK 63780000
         TM    IOSENS0,COMREJ          COMMAND REJECT, QQ               63840000
         BZ    RGUCK875                NO, HANDLE AS REGULAR ERROR      63900000
         L     CMICB,DCBWTOID          GET CURRENT MICB ADDR            63960000
         TM    MICBFLAG(CMICB),BADCOMI   DID USER ISSUE THIS COMMAND    64020000
         BZ    MSPCI                   NO.  ITS A MISSED PCI            64080000
         NI    MICBFLAG(CMICB),BADOFF  TURN OFF BAD COMMAND BIT         64140000
         B     RGUCK875                HANDLE AS COMMAND REJECT         64200000
MSPCI    EQU   *                                                        64260000
         NI    IOSENS0,REJOFF          TURN OFF COMMAND REJECT          64320000
         OI    IOSENS0,LLS        SET ON LATE SS SENSE                  64380000
*                                                                       64440000
*   COMMAND REJECT HAS OCCURRED ON A READ COMMAND TO THE                64500000
*   SCU.  THIS MEANS THAT THE PCI INTERRUPT WAS NOT ACCEPTED            64560000
*   IN TIME TO RESET THE COMMAND TO A NOP                               64620000
*                                                                       64680000
HNDLLPCI EQU   *                                                        64740000
         OI    DCBAPPIN,BDTLTPCI       INDICATE SCU CHAIN BROKEN DUE    64800000
*                                      TO LATE PCI.                     64860000
         CLI   EIGHT(GR5),TIC     IS IT A TIC COMMAND                   64920000
         BNE   GSENS              NO/GO PICK UP SENSE AREA ADDR         64980000
         S     GR5,FORTY8         YES/POINT TO FIRST SENSE COMMAND      65040000
GSENS    L     GR5,EIGHT(GR5)     POINT TO SENSE COMMAND                65100000
         LA    GR5,ZERO(0,GR5)         GET RID OF GARBAGE               65160000
         SH    GR5,KNINE               POINT AT ASSOCIATED MICB         65220000
         L     CMICB,DCBWTOID          GET CURRENT POINTER              65280000
         CR    GR5,CMICB               DID THE PCI INTERRUPT OCCUR      65340000
*                                      SO LATE THAT WE STILL GOT        65400000
*                                      COMMAND REJECT ON THE WRITE.     65460000
         BE    CHKFZ020                NO, GO SET PCI MISSED IN         65520000
*                                      CURRENT AND POST C-1.            65580000
         ST    GR5,DCBWTOID            YES, BACK UP CURRENT POINTER     65640000
         LR    CMICB,GR5               DITTO                            65700000
         B     STPCI030                GO SET PCI MISSED IN CURRENT     65760000
*                                                                       65820000
*                                                                       65880000
HNDF3820 L     CMICB,DCBWTOID           GET ADDR C MICB                 65940000
         L     GR5,MICBDATA(0,CMICB)    GET BUFFER ADDR                 66000000
         BAL   RTRNREG,SESTAT          GO SET BUFFER STATUS             66060000
         TM    ZERSAV,UNRECOV          UNRECOVERABLE ERROR, QQ          66120000
         BZ    NONTALL                 NO, CONTINUE                     66180000
         NI    ZERO(GR5),OFFERR        TURN OFF BIT 2                   66240000
         OI    ZERO(GR5),UNRECVSS       TURN ON UNRECOV SS ERROR        66300021
NONTALL  EQU   *                                                        66360000
*                                                                       66420000
*                                                                       66480000
*                                                                       66540000
*                                                                       66600000
*                                                                       66660000
*                                                                       66720000
XPSTT835 TM    ZERSAV,UNRECOV          GOING TO ERP, QQ                 66780000
         BO    RPOST4                  YES, INDICATE POST NEEDED        66840000
         TM    DCBMRIND,X02            IS PCU ERP EXECUTING             66900000
         BO    RPOST4                  YES, INDICATE POST NEEDED        66960000
         TM    MICBECB(CMICB),WAIT      HAS USER WAITED, QQ             67020000
         BZ    IPOST840                 NO, POST IT MYSELF              67080000
*                                                                       67140000
         L     CCREG,KCODCON           GET NORMAL COMPLETION CODE       67200000
         LA    ECBADR,MICBECB(0,CMICB)  GET ECB ADDR.                   67260000
         L     BRANREG,CVTAD            GET ADDR CVT                    67320000
         L     BRANREG,CVTOPT01(0,BRANREG)  GET ADDR POST ROUTINE       67380000
         LR    GR5,BA12                SAVE BASE                        67440000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  67500000
         BALR  RTRNREG,BRANREG          GO POST ECB                     67560000
         LR    BA12,GR5                RESTORE BASE                     67620000
*                                                                       67680000
*                                                                       67740000
IPOST840 MVC   MICBECB(FOUR,CMICB),KCODCON  POST COMPLETE               67800000
*                                                                       67860000
XIT0850  TM    ZERSAV,UNRECOV          ERRORS BESIDES   I.R.            67920000
         LM    ZERO,BASE,KRESAV         RESTORE REGS                    67980000
         BZ    FOUR(0,RTRNREG)         DONT HAVE ERP SCHEDULED          68040000
         OI    DCBMRIND,X01            INDICATE SCU ERP EXECUTING       68100000
         CLI   CHECKARE,SIT5      PCU DOWN,MISSED PCI,43711      A43711 68110021
         BNE   ERPRET                                            A43711 68120021
         OI    DCBMRFG,PCURR      CURR MICB NEEDS POSTING        A43711 68130021
ERPRET   EQU   *                                                 A43711 68140021
         BR    RTRNREG                 HAVE ERP SCHEDULED               68160000
*                                                                       68220000
RPOST4   OI    DCBMRFG,PCURR           CURRENT NEEDS POSTING            68280000
         B     XIT0850                 GO GET OUT                       68340000
*                                                                       68400000
HNDST855 L     CMICB,DCBWTOID           GET ADDR CURRENT MICB           68460000
         TM    MICBFLAG(CMICB),INITIAL  FIRST BUFFER AFTER AN ENGAGE    68520000
         BZ    SXTSS860                 NO, SET SS INFO IN C-1          68580000
         NI    MICBFLAG(CMICB),TURNOFF  SET OFF INITIAL SWITCH          68640000
         B     HNDF3820                 GO SET ERR INFO IN CURRENT      68700000
*                                                                       68760000
SXTSS860 L     GR5,MICBNM1(0,CMICB)     GET ADDR C-1 MICB               68820000
         L     GR8,MICBDATA(0,GR5)      GET ADDR BUFFER                 68880000
         TM    MICBSENS(GR5),LATESS     LATE STACKER SELECT, QQ         68940000
         BZ    NTSTA865                 NO, TEST AUTO SELECT            69000000
         MVI   FIVE(GR8),XREJCOM       PUT X'CF' IN BYTE 5              69060000
         OI    THREE(GR8),SETLTSS      SET LATE SS BIT                  69120000
NTSTA865 TM    MICBSENS(GR5),AUTSEL     AUTO SELECT, QQ                 69180000
         BZ    NPSTT870                 NO, GO POST COMPLETE            69240000
         MVI   FIVE(GR8),XREJCOM       PUT X'CF' IN BYTE 5              69300000
         OI    TWO(GR8),SETAUTS        SET AUTO SELECT BIT              69360000
*                                                                       69420000
NPSTT870 TM    MICBECB(GR5),WAIT        DID USER WAIT                   69480000
         BZ    NLPST872                 NO, POST MYSELF                 69540000
*                                                                       69600000
         L     CCREG,KCODCON            LOAD NORMAL COMPLETION CODE     69660000
         LA    ECBADR,MICBECB(0,GR5)    GET ECB ADDR                    69720000
         L     BRANREG,CVTAD            GET ADDR CVT                    69780000
         L     BRANREG,CVTOPT01(0,BRANREG)  GET ADDR POST ROUTINE       69840000
         LR    GR5,BA12                SAVE BASE                        69900000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  69960000
         BALR  RTRNREG,BRANREG          GO TO POST ROUTINE              70020000
         LR    BA12,GR5                RESTORE BASE                     70080000
         B     HNDF3820                 GO SET ERR INFO IN CURRENT      70140000
*                                                                       70200000
NLPST872 MVC   MICBECB(0,GR5),KCODCON   POST BUFFER                     70260000
         B     HNDF3820                 GO SET ERR INFO                 70320000
RGUCK875 L     GR6,IOBSIOCC             GET ADDR SCU CHAIN              70380000
         LA    GR6,0(0,GR6)             GET RID OF GARBAGE              70440000
         CR    GR5,GR6                  BLOW IN STRING2                 70500000
         BE    BINTW880                 YES, SEE IF THATS CURRENT       70560000
*                                                                       70620000
         LA    GR6,THIR2(0,GR6)        POINT AT STRING 2                70680000
         CR    GR5,GR6                  BLOW IN STRING2                 70740000
         BNL   BINTW880                 YES SEE IF THATS  CURRENT       70800000
*                                                                       70860000
         TM    DCBMRFLG,CHAIN2          CHAIN2  CURRENT                 70920000
         BO    BKUPT885                 YES, WE BLEW IN C-1             70980000
         B     STPSS890                 BLEW UP IN CURRENT              71040000
BINTW880 TM    DCBMRFLG,CHAIN2          IS CHAIN2 CURRENT               71100000
         BO    STPSS890                 YES, WE BLEW IN CURRENT         71160000
*                                                                       71220000
* BLEW UP IN C-1 CHAIN. SET SS INFO AND POST C-1 THEN SET ERR           71280000
*  INFO IN CURRENT.                                                     71340000
BKUPT885 L     CMICB,DCBWTOID          GET ADDR C MICB                  71400000
         L     GR5,MICBNM1(0,CMICB)    GET ADDR C-1 MICB                71460000
         L     GR5,MICBDATA(0,GR5)      GET BUFFER ADDR                 71520000
         TM    IOBCSW+FIVE,CPCHECK     PROGRAM CHECK, QQ                71580000
         BO    MCF                     YES, SET BUFFER INFO             71640000
         TM    IOSENS0,COMRLTSS        COMMAND REJ - LATE SS     A39662 71700020
         BZ    NOTESA                  NO, TEST AUTO SELECT             71760000
MCF      EQU   *                                                        71820000
         MVI   FIVE(GR5),XREJCOM       PUT X'CF' IN BYTE 5              71880000
         OI    THREE(GR5),SETLTSS      SET LATE STACKER BIT             71940000
NOTESA   TM    IOSENS0,AUTSEL          WAS IT AUTO SELECTED, QQ         72000000
         BZ    NXGO                    NO DONT SET BIT                  72060000
         OI    TWO(GR5),SETAUTS        INDICATE AUTO SELECT             72120000
         MVI   FIVE(GR5),XREJCOM       PUT X'CF' IN BYTE 5              72180000
*                                                                       72240000
NXGO     L     GR5,MICBNM1(0,CMICB)    GO AND POST C-1                  72300000
         B     PSTIT900                AND SET C.                       72360000
*                                                                       72420000
*                                                                       72480000
STPSS890 L     CMICB,DCBWTOID           GET ADDR CMICB                  72540000
         L     GR5,MICBNM1(0,CMICB)     GET ADDR C-1                    72600000
         L     GR6,MICBDATA(0,CMICB)    GET BUFFER ADDR                 72660000
         TM    MICBSENS(GR5),LATESS     LATE STACKER SELECT,QQ          72720000
         BZ    TSTAT895                 NO, TEST FOR AUTO SELECT        72780000
         MVI   FIVE(GR6),XREJCOM       PUT X'CF' IN BYTE 5              72840000
         OI    THREE(GR6),LATESS       SET LATE SS BIT                  72900000
TSTAT895 TM    MICBSENS(GR5),AUTSEL     AUTO  SELECT,QQ                 72960000
         BZ    PSTIT900                 NO , GO  POST                   73020000
         OI    TWO(GR6),SETAUTS        SET AUTO SELECT BIT              73080000
         MVI   FIVE(GR6),XREJCOM       PUT X'CF' IN BYTE 5              73140000
*                                                                       73200000
PSTIT900 TM    MICBECB(GR5),WAIT        DID USER WAIT                   73260000
         BZ    PMYSF                    NO, POST IT MYSELF              73320000
         L     CCREG,KCODCON            LOAD  NORMAL COMPLETION CODE    73380000
         LA    ECBADR,MICBECB(0,GR5)    GET ECB ADDR                    73440000
         L     BRANREG,CVTAD            GET CVT  ADDR                   73500000
         L     BRANREG,CVTOPT01(0,BRANREG)   GET ADDR POST ROUTINE      73560000
         LR    GR6,BA12                SAVE BASE                        73620000
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  73680000
         BALR  RTRNREG,BRANREG               GO  POST ECB               73740000
         LR    BA12,GR6                RESTORE BASE                     73800000
PMYSF    MVC   MICBECB(FOUR,GR5),KCODCON    POST COMPLETE               73860000
*                                                                       73920000
STERR905 L     CMICB,DCBWTOID           GET CURRENT MICB ADDR           73980000
         L     GR5,MICBDATA(0,CMICB)    GET BUFFER ADDR.                74040000
         BAL   RTRNREG,SESTAT          GO SET BUFFER STATUS             74100000
         TM    ZERSAV,UNRECOV          ERRORS BESIDES I.R.              74160000
         BZ    NONTALL1                NO, CONTINUE                     74220000
         NI    ZERO(GR5),OFFERR        TURN OFF BIT 2                   74280000
         OI    ZERO(GR5),UNRECVSS       TURN ON UNRECOVERALBE ERROR     74340021
NONTALL1 EQU   *                                                        74400000
         B     XIT0850                                                  74460000
*                                                                       74520000
*                                                                       74580000
*                                                                       74640000
*                                                                       74700000
HNDSIT3  L     CMICB,DCBWTOID          GET ADDR C MICB                  74760000
         L     GR5,MICBDATA(0,CMICB)   GET BUFFER ADDR                  74820000
         TM    IOSENS0,LATESS          LATE STACKER SELRCT, ,QQ         74880000
         BZ    TESATX                  NO, TEST AUTO SELECT             74940000
         OI    THREE(GR5),SETLTSS       SET LATE STACKER BIT            75000000
         MVI   FIVE(GR5),XREJCOM       PUT X'CF' IN BYTE 5              75060000
*                                                                       75120000
TESATX   TM    IOSENS0,AUTSEL          WAS DOCUMENT AUTO SELECTED       75180000
         BZ    NOWPS                   NO, POST AS COMPLETE             75240000
         MVI   FIVE(GR5),XREJCOM       PUT X'CF' IN BYTE 5              75300000
         OI    TWO(GR5),SETAUTS        INDICATE AUTO SELECT             75360000
NOWPS    LR    GR5,CMICB               GET ADDR C IN 5                  75420000
         TM    MICBECB(CMICB),WAIT     HAS USER WAITED                  75480000
         BZ    XYPOST                  NO, POST MYSELF                  75540000
         L     CCREG,KCODCON           LOAD NORMAL COMPLETION CODE      75600000
         LA    ECBADR,MICBECB(CMICB)   LOAD ECB ADDR                    75660000
         L     BRANREG,CVTAD           GET CVT ADDR                     75720000
         L     BRANREG,CVTOPT01(BRANREG)   GET ADDR POST ROUTINE        75780000
         LR    GR5,GR12      SAVE BASE REGISTER                  A42476 75810021
         L     GR12,ZERO(DEBREG)       GET TCB ADDRESS                  75840000
         BALR  RTRNREG,BRANREG          GO POST COMPLETION              75900000
         LR    GR12,GR5      RESTORE BASE REGISTER               A42476 75930021
XYPOST   MVC   MICBECB(FOUR,CMICB),KCODCON      POST COMPLETION         75960000
         L     GR5,MICBNEXT(0,CMICB)     GET ADDR C+1 MICB              76020000
         L     GR5,MICBDATA(0,GR5)     GET ADDR C+1 BUFFER              76080000
         BAL   RTRNREG,SESTAT          GO SET BUFFER STATUS             76140000
         TM    ZERSAV,UNRECOV          ERRORS BESIDES I.R.              76200000
         BZ    NONTALL2                NO, CONTINUE                     76260000
         NI    ZERO(GR5),OFFERR        TURN OFF BIT 2                   76320000
         OI    ZERO(GR5),UNRECVSS          TURN ON UNRECOV              76380021
NONTALL2 EQU   *                                                        76440000
         B     XIT0850                 GET OUT                          76500000
SIOTRAC  EQU   *                                                 41426  76501021
         DROP  BA12                FORCE USE OF BASE REG 15      41426  76502021
         USING SIOENTER,BASE       SAVE REGS BEFORE USING 12     41426  76503021
         STM   0,15,KRESAV         STORE IOS REGISTERS           41426  76504021
         DROP  BASE                RETURN TO BASE REG 12         41426  76505021
         USING PCIAPEN,BA12        RETURN TO BASE REG 12         41426  76506021
         LA    BA12,PCIAPEN-SIOENTER(0,BASE)  EST.               41426  76507021
*                                       ADDRESSIBILITY           41426  76508021
         MVI   WHAT,SIOENTRY       SET SWITCH                    41426  76509021
         CH    WORKA,DEBUCBAD+2(DEBREG) IS THIS PRI SIO        @XA03404 76509421
         BE    PRISIO                   YES GO TEST SEC UNIT   @XA03404 76509821
         CH    WORKA,DEBUCBAD+6(DEBREG) IS THIS SEC SIO        @XA03404 76509921
         BNE   TRACE                    NEITHER TRACE AND GET  @XA03404 76512121
         LH    WORKB,DEBUCBAD+2(DEBREG) IS SEC GET PRI UCB     @XA03404 76514121
         TM    UCBFL1(WORKB),UCBPOST    IS UNIT STARTED        @XA03404 76516621
         BO    TRACE                    YES GO AHEAD           @XA03404 76516721
         L     WORKA,IOBSIOCC           GET COMMAND ADDRESS    @XA03404 76516821
         CLI   0(WORKA),MSENS           SENSE OR PKT LITE      @XA03404 76517221
         BNE   TRACE                    PKT LITE DONT SET NRDY @XA03404 76517321
         NI    UCBFL1(WORKA),XFF-NOTREDY SET THIS UNIT READY   @XA03404 76517621
         MVI   WHICH,SIR                INDICATE INTERV REQ    @XA03404 76517721
         B     TRACE                                           @XA03404 76517821
PRISIO   LH    WORKB,DEBUCBAD+6(DEBREG) GET SEC UCB ADDR       @XA03404 76517921
         NI    UCBFL1(WORKB),XFF-NOTREDY SET SEC UCB READY     @XA03404 76518021
         B     TRACE                    CONTINUE               @XA03404 76518221
PCITRACE MVI   WHAT,PCIENTRY      SET PCI TRACE SWITCH           41426  76518821
TRACE    EQU   *                                                 41426  76521021
         L     TTPTR,DCBIOBAD      POINTER TO PCU IOB            41426  76523221
         LA    TTPTR,TRCEDSP(TTPTR) INCREMENT POINTER TO         41426  76525421
*                                       TRACETABLE               41426  76527621
         SR    WORKA,WORKA         ZERO REGISTER                 41426  76529821
         IC    WORKA,0(TTPTR)      LOAD INDEX VALUE              41426  76532021
         SRA   WORKA,ONE           ALIGN AS MULIIPLE OF 8        41426  76534221
         LA    TTPTR,TABLE(WORKA,TTPTR) POSITION POINTER,NEXT    41426  76536421
*                                       ENTRY                    41426  76538621
         CLI   WHAT,PCIENTRY       TEST ENTRY SWITCH             41426  76540821
         BNE   NOTPCI                                            41426  76543021
         MVC   0(8,TTPTR),CSW      STORE CSW IN THE TABLE        41426  76545221
         B     ADD                                               41426  76547421
NOTPCI   CLI   WHAT,SIOENTRY       TEST ENTRY SWITCH             41426  76549621
         BNE   NOTSIO                                            41426  76551821
         L     WORKB,IOBSIOCC      GET POINTER TO FIRST CCW      41426  76554021
         MVC   0(ONE,TTPTR),0(WORKB)  STORE COMMAND CODE         41426  76556221
         MVC   FOUR(FOUR,TTPTR),KRESAV+28 STORE UCB ADDRESS      41426  76558421
         B     ADD                                               41426  76560621
NOTSIO   MVC   0(8,TTPTR),8(2)     STORE CSW FROM IOB TO TABLE   41426  76562821
         MVC   0(ONE,TTPTR),2(2)   STORE SENSE BYTE 0 IN TABLE   41426  76565021
ADD      AH    WORKA,KEIGHT        INCREMENT INDEX BY ONE        41426  76567221
         SLA   WORKA,ONE           SHIFT OUT HIGH ORDER UNWANTED 41426  76569421
*                                       BIT                      41426  76571621
         L     TTPTR,DCBIOBAD      STORE PCU IOB POINTER         41426  76573821
         LA    TTPTR,TRCEDSP(TTPTR) INCREMENT POINTER TO INDEX   41426  76576021
         STC   WORKA,0(TTPTR)                                    41426  76578221
         L     WORKA,KRESAV+28     REPLACE UCB POINTER IN        41426  76580421
*                                       REGISTER                 41426  76582621
         CLI   WHAT,SIOENTRY       TEST ENTRY SWITCH             41426  76584821
         MVI   WHAT,RESTORE        RESET SWITCH                  41426  76587021
         BE    SIORET              GO DIRECTLY TO IOS            41426  76589221
         BR    TRACRET             GO TO IN LINE CODE            41426  76591421
SIORET   EQU   *                                               @XA03404 76599521
         CLI   WHICH,SIR                WAS ONE UNIT NOT READY @XA03404 76601821
         LM    0,15,KRESAV         RESTORE REGISTERS             41426  76605921
         BNER  RTRNREG                                         @XA03404 76611621
*********************************************************************** 76611721
*                                                              @XA03404 76612021
* THE FOLLOWING ROUTINE WILL INSURE THAT THE PRIMARY UNIT IS            76612421
* BEFORE THE SECONDARY.                                                 76612821
*   1 THE CHANNEL MASK IS SET TO TELL IOS TO RESTART CHANNEL 0          76613221
*   2 THE CONDITION CODE IS SET TO 2 TO TELL IOS THAT THE               76613321
*      DEVICE IS BUSY. IOS WILL THEN QUEUE THE REQUEST.                 76613421
*   3 RETURN TO IOS IS VIA REG 12 INSTEAD OF REG15 THIS WILL            76613521
*      ALLOW IOS TO QUEUE THE REQUEST AND RESTART THE CHANNEL.          76614321
*                                                                       76614721
*********************************************************************** 76615121
         L     GR10,CVTAD               GET CVT POINTER        @XA03404 76616021
         L     GR10,CVTIXAVL            GET RQE POINTER        @XA03404 76616821
         OI    CHANMSK(GR10),CHANZERO SET CHAN ZERO TO RESTART @XA03404 76617621
         LTR   GR7,GR7                  SET COND CODE TWO      @XA03404 76618421
         BR    BA12                     RETURN TO IOS          @XA03404 76619221
TABLE    EQU   8         TABLE BEGINS 8 BYTES FROM INDEX         41426  76620021
WORKA    EQU   7                                                 41426  76623021
TRCEDSP  EQU   168       DISPLACEMENT OF TRACE TABLE FROM IOB    41426  76628721
TTPTR    EQU   6                                                 41426  76634421
PCIENTRY EQU   X'01'                                             41426  76640121
SIOENTRY EQU   X'02'    SIGNAL FOR START I/O ENTRY               41426  76645821
WORKB    EQU   10                                                41426  76651521
RESTORE  EQU   X'00'                                             41426  76657221
TRACRET  EQU   11                                                41426  76662921
*                                                                       76668621
*                                                                       76674321
*  DISPLACEMENT EQUATES:                                                76680000
*                                                                       76740000
*  FOR MICB-                                                            76800000
*                                                                       76860000
MICBNEXT EQU   0                        ADDR  OF NEXT MICB              76920000
MICBECB  EQU   4                        EMBEDDED EVENT CONTROL BLOCK    76980000
MICBFLAG EQU   8                        FLAG  BITS                      77040000
MICBSENS EQU   9                        SENSE INFORMATION               77100000
MICBECBA EQU   12                       ADDR OF ECB                     77160000
MICBNM7  EQU   16                       ADDR OF CURRENT - 7             77220000
MICBNM1  EQU   20                       ADDR OF CURRENT - 1             77280000
MICBDATA EQU   24                       ADDR OF BUFFER                  77340000
*                                                                       77400000
*                                                                       77460000
*  FOR DEB-                                                             77520000
*                                                                       77580000
DEBUCBAD EQU   32                      DISP TO UCB ADDR                 77640000
DEBIRBAD EQU   8                        ADDR OF IRB                     77700000
DEBTCBAD EQU   0                        ADDR OF TCB                     77760000
*                                                                       77820000
*                                                                       77880000
*  FOR TCB-                                                             77940000
*                                                                       78000000
TCBRBP   EQU   0                        ADDR FIRST REQUEST BLOCK        78060000
TCBGRS   EQU   48                       REGISTER SAVE AREA              78120000
R1       EQU   28                       R1 SAVE AREA IN PCP AND MFT     78180000
R13      EQU   12                       R13 SAVE AREA IN PCP AND MFT    78240000
R15      EQU   20                       R15 SAVE AREA IN PCP AND MFT    78300000
MVTR1    EQU   4                        R1  SAVE AREA IN MVT            78360000
MVTR13   EQU   52                       R13 SAVE AREA IN MVT            78420000
MVTR15   EQU   60                       R15 SAVE AREA IN MVT            78480000
TCBPKE   EQU   28                       PROTECTION KEY                  78540000
TCBFLGS  EQU   29                      DISP TO FLAG BYTES               78600000
*                                                                       78660000
*                                                                       78720000
*                                                                       78780000
* FOR CVT-                                                              78840000
*                                                                       78900000
CVTAD    EQU   16                                                       78960000
CVT0EF00 EQU   4                        ADDR  STAGE 2 EFFECTOR          79020000
CVTOPT01 EQU   152                      ADDR POST ROUTINE               79080000
CONFIG   EQU   116                      O.S.  CONFIGURATION             79140000
CVTIXAVL EQU   124                      OFFSET TO NEXT RQE PTR          79190021
CHANMSK  EQU   20                       OFFSET OF CHAN MASK FROM        79192021
*                                       RQE POINTER                     79200021
*                                                                       79260000
*                                                                       79320000
*                                                                       79380000
* FOR IRB-                                                              79440000
*                                                                       79500000
RBLINK   EQU   28                       ADDR NEXT REQUEST BLOCK         79560000
RBIQE    EQU   X'60'                   DISP TO IQE ADDR                 79620000
CANI     EQU   X'01'                   TO TEST IF ASYNCHRONOUS EXIT     79680000
*                                      ROUTINES CAN  BE SCHEDULED       79740000
LITEL    EQU   X'10'                   TO SEE IF ITS LAST LITE          79800000
OFFLITE  EQU   X'EF'                   TO TURN OFF LIGHT SW             79860000
IQESCHED EQU   X'08'                   TO INDICATE IQE IS ON EXIT LIST  79920000
IQEOFF   EQU   X'F7'                   TO TURN OFF IQESCHED             79980000
ONE      EQU   1                       DISP OF 1                        80040000
SEVEN    EQU   15                      FOR LENGTH IN MOVE               80100000
EIGHT    EQU   8                       DISP OF 8                        80160000
TWEN4    EQU   24                      DISP OF 24                       80220000
SIX4     EQU   64                      DISP OF 64                       80280000
SIX      EQU   6                       DISP OF 6                        80340000
FIVE     EQU   5                       DISP OF 5                        80400000
TWEN8    EQU   28                      DISP OF 28                       80460000
THREE    EQU   3                       DISP OF 3                        80520000
FOUR8    EQU   48                       DISP OF 48               A46625 80570021
TWO      EQU   2                       DISP OF 2                        80580000
SIXTEEN  EQU   16                      DISP OF  16                      80640000
THIR2    EQU   32                      DISP OF 32                       80700000
RBOPSW   EQU   16                       OLD  PSW                        80760000
RBGSAV   EQU   32                       GEN REG SAVE AREA               80820000
RBEP     EQU   12                       E.P. OF  ASYNCHRONOUS ROUTINE   80880000
RBSTAB   EQU   10                       FLAG BITS                       80940000
RBR1     EQU   4                        REGISTER 1                      81000000
RBR13    EQU   52                       REGISTER 13                     81060000
RBR15    EQU   60                       REGISTER 15                     81120000
*  FOLLOWING ARE EQUATES  FOR  IMMEDIATE DATA AND MASKS                 81180000
*                                                                       81240000
CHANZERO EQU   X'80'                 MASK TO RESTART CHAN ZERO          81290021
NOTZ     EQU   7                        MASK FOR BR NOT ZEROES          81300000
UCHKCHND EQU   X'0A'                   MASK FOR TESTING UNIT CHECK AND  81360000
*                                                         CHANNEL  END  81420000
XFF      EQU   X'FF'                                                    81480000
FORTY    EQU   40                      DISP OF 40                       81540000
REJOFF   EQU   X'7F'                   TO TURN OFF COMMAND REJECT       81600000
BADCOMI  EQU   X'08'                   TO INDICATE USER HAS ISSUED      81660000
*                                      REJECT COMMAND                   81720000
BADOFF   EQU   X'F7'                   TO TURN OFF BADCOMI              81780000
CHANER   EQU   X'0F'                    MASK FOR TESTING CHANNEL ERRORS 81840000
SIT0     EQU   X'0F'                    MASK FOR TESTING WHATS          81900000
*                                       HAPPENING IN THE APPENDAGES     81960000
NOP      EQU   X'03'                    NO-OP COMMAND                   82020000
ST2OR3   EQU   X'08'                    TEST FOR STRING 2 OR 3 ON PCU   82080000
AMWP     EQU   X'04'                    AMWP FOR USERS PSW              82140000
ST1      EQU   X'04'                    FOR TESTING STRING 1 BIT        82200000
MSENS    EQU   X'24'                    MOD SENSE COMMAND CODE          82260000
OVERRUN  EQU   X'40'                    FOR TESTING IF BUFFER OVERRUN   82320000
*                                                     IS IMMINENT       82380000
URQST    EQU   X'20'                    FOR TESTING IF USER REQUESTED   82440000
*                                       DISENGAGE                       82500000
DISENG   EQU   X'DF'                    DISENGAGE COMMAND               82560000
DISIND   EQU   X'10'                    DISENGAGE INDICATOR             82620000
CHAIN2   EQU   X'80'                    FOR TESTING WHICH SCU CHAIN IS  82680000
*                                       BEING EXECUTED                  82740000
CHAINOFF EQU   X'BF'                    TO TURN OFF COMMAND CHAINING    82800000
CHAINON  EQU   X'40'                    TO TURN ON COMMAND CHAINING     82860000
INITIAL  EQU   X'10'                    TO SEE IF ENGAGE JUST ISSUED    82920000
LATESS   EQU   X'04'                    FOR CHECKING LATE  SS           82980000
COMRLTSS EQU   X'84'                   COMMAND REJECT - LATE SS  A39662 83010020
SETLTSS  EQU   X'20'                   FOR SETTING LATE SS IN BUFFER    83040000
X02      EQU   X'02'                   TO INDICATE ERP IS EXECUTING     83100000
X01      EQU   X'01'                   TO INDICATE SCU ERP EXECUTING    83160000
FOUR     EQU   4                       BRANCH DISPLACEMENT              83220000
PCURR    EQU   X'80'                   TO INDICATE POST CURRENT         83280000
PCURRP1  EQU   X'40'                   TO INDICATE POST CURR+1          83340000
XFD      EQU   X'FD'                   TO TURN OFF X02                  83400000
X7F      EQU   X'7F'                   TO TURN OFF PCURR                83460000
XBF      EQU   X'BF'                   TO TURN OFF PCURRP1              83520000
XFE      EQU   X'FE'                   TO TURN OFF X01                  83580000
AUTSEL   EQU   X'02'                    FOR CHECKING AUTO SELECT BIT    83640000
SETAUTS  EQU   X'80'                    FOR SETTING AUTO SEL IN BUFFER  83700000
WAIT     EQU   X'80'                    TO CHECK WAIT BIT IN ECB        83760000
ZBIT2    EQU   X'DF'                    FOR ZEROING DOC UNDER READ      83820000
*                                                           HEAD BIT    83880000
ONBIT4   EQU   X'08'                    FOR TURNING ON BIT4 OF DCBMRFLG 83940000
OFFBIT5  EQU   X'FB'                    FOR TURNING OFF BIT5            84000000
ONBIT5   EQU   X'04'                    TO TURN ON BIT5                 84060000
OFFBIT4  EQU   X'F7'                    TO TURN OFF BIT4                84120000
DEBUG    EQU   X'40'                    TO SEE IF WERE IN DEBUG MODE    84180000
ACTIVE   EQU   X'40'                    TO SEE IF IRB IS ACTIVE         84240000
MVT      EQU   X'10'                    TO SEE IF CONFIGURATON IS MVT   84300000
BATCH    EQU   X'80'                    TO TEST FOR BATCH NO. UPDATE    84360000
ORVAL    EQU   X'08'                    TO TURN ON BATCH BIT IN COMMAND 84420000
EXIT     EQU   3                        SVC NO. FOR LEAVING SS ROUTINE  84480000
PCUABEND EQU   X'AB'                    TO TEST 'WHICH'  SWITCH         84540000
SSC0     EQU   X'0B'               SS IND FOR POCKET 0 2ND GROUP A33924 84550020
CSS0     EQU   X'DB'               SS CMD FOR POCKET 0 2ND GROUP A33924 84560020
UC       EQU   X'02'               MASK FOR UNIT CHECK           A33924 84570020
UXFLG    EQU   X'04'               MASK FOR EXCEPTION FLAG IOB   A33924 84580020
EASYONE  EQU   X'E1'             CODE FOR WRITE DELAY COMMAND   SA60294 84590021
*                                                                       84600000
PCIINCTL EQU   X'01'                    TO SET  'WHICH'  SWITCH         84660000
NOTEQ    EQU   7                        MASK  FOR  BCR NOT EQUAL        84720000
SETO5    EQU   X'A0'                   TO SET BUFFER COUNTER            84780000
TOURQST  EQU   X'DF'                   SETS OFF URQST BIT               84840000
INVALC   EQU   X'FF'                   TO FORCE COMMAND REJECT          84900000
MREAD    EQU   X'4C'                    MREAD BACKWARDS COMMAND         84960000
CMRJBOC  EQU   X'A1'                   TO TEST COM REJ,BOC,AND OP ATT   85020000
UNRECOV  EQU   X'20'                    TO SET UNRECOV I/O ERROR        85080000
INTVR    EQU   X'41'              MASK TO TEST INTVR REQ/OPR ATTN       85120000
OPATTN   EQU   X'01'              MASK TO TEST SENS FOR OPR ATTN        85160000
SCUAB    EQU   X'BB'                   TO SAY SCU ABEND GOING           85200000
IR       EQU   X'08'                    TO SET INTV REQ BIT IN BUFFER   85260000
XF0      EQU   X'F0'                    FOR TESTING IF SCU HAS BROKEN   85320000
SITF     EQU   X'0F'                    FOR SETTING SITUATION F         85380000
SIT2     EQU   X'02'                    FOR SETTING SITUATION 2         85440000
CC3      EQU   X'70'                   FOR CHECKING CC=3                85500000
UEX      EQU   X'10'                    FOR SETTING UNIT EXCEPTION BIT  85560000
SIT3     EQU   X'03'                    FOR SETTING SITUATION 3         85620000
PCUCE    EQU   X'F0'                    TO SAY PCU C.E. APPEN IS EXCTNG 85680000
UNEXEP   EQU   X'01'                    FOR CHECKING UNIT EXCEPTION     85740000
NVAL     EQU   X'F7'                   FOR REMOVING BIT4 IN SS COMM     85800000
NWDUCHK  EQU   X'F0'                    TO INDICATE  SCU HAS STOPPED    85860000
*                                       DUE TO REG UNIT CHECK.          85920000
PCIMISD  EQU   X'04'                    TO INDICATE PCI MISSED          85980000
INDLEN   EQU   10                       LENGTH OF BUFFER STATUS         86040000
CMPLETE  EQU   X'40'                    TO TEST COMPLETE BIT            86100000
SVLN     EQU   64                       SAVE AREA LEN                   86160000
PCULN    EQU   80                       LEN OF PCU CHAIN                86220000
BDTCE    EQU   X'40'                    TO SAY BROKEN DUE TO CHAN END   86280000
ERRORS   EQU   X'A0'                    TO SEE IF SCU HAS ERRS          86340000
WDELAY   EQU   X'E1'                    WRITE DELAY COMMAND CODE        86400000
COMREJ   EQU   X'80'                    FOR TESTING COMMAND REJ ON SCU  86460000
LLS      EQU   X'04'              MASK TO SET ON LATE SS SENSE          86580000
SIR      EQU   X'40'                    TO CHECK INTV REQUIRED          86640000
BOC      EQU   X'20'                    TO TEST BUS OUT CHECK           86820000
CPCHECK  EQU   X'20'                   TO TEST CSW FOR PROGRAM CHECK    86880000
NOTIR    EQU   X'A0'                    TO TEST B.O. CHECK OR COM REJ   86940000
TURNOFF  EQU   X'EF'                    TO TURN OFF INITIAL BIT         87000000
XREJCOM  EQU   X'CF'                   REJECT POCKET                    87060000
BDTUC    EQU   X'20'                   USED TO INDICATE IN DCBAPPIN     87120000
*                                      THAT THE SCU HAS BROKEN DUE      87180000
*                                      TO UNIT CHECK.                   87240000
BDTLTPCI EQU   X'80'                   USED TO SET DCBAPPIN TO          87300000
*                                      INDICATE THE SCU HAS             87360000
*                                      BROKEN DUE TO LATE PCI.          87420000
UNRECVSS  EQU   X'40'                   MASK TO TURN ON UNRECOVERABLE   87470021
*                                      ERR0R FLAG                       87472000
*  FOLLOWING ARE EQUATES FOR ABSOLUTE ADDRESSES                         87480000
*                                                                       87540000
CSW      EQU   64                                                       87600000
*  FOLLOWING ARE EQUATES FOR VARIOUS  DISPLACEMENTS AND LENGTHS         87660000
*                                                                       87720000
SS1DIS   EQU   16                       DISP TO FIRST SS COMMAND IN THE 87780000
*                                                          SCU CHAIN    87840000
SS2DIS   EQU   40                       DISP TO  2ND  SS COMMAND        87900000
OFFERR   EQU   X'DF'                   TO TURN OFF UNRECOV              87960000
IPPCCIC  EQU   X'7F'                   TO TEST ERRORS IN CSW            88020000
ASC      EQU   X'E0'                   TO TEST ATTENTION,S MOD,CU END   88080000
UCBFL1   EQU   6                       DISP TO UCB FLAG                 88140000
NOTREDY  EQU   X'40'                   TO SET UCBFL1 FLAG               88200000
UCBPOST  EQU   X'20'                   MSK SEE IF DEV STARTED           88250021
NORM     EQU   X'7F'                   NORMAL COMPLETION CODE           88260000
CCWD     EQU   24                      DISP OF CCW ADDR IN IOB          88320000
IOBLN    EQU   48                      LENGTH OF PCU OR SCU IOB         88380000
XPCLEN   EQU   80                      LEN OF PCU CHAIN                 88440000
SIT5     EQU   X'05'                   SITUATION 5 INDICATOR            88500000
ZER0     EQU   0                                                        88560000
SCUSTRNG EQU   24                      DISP OF CCW ADDR IN IOB          88620000
STRNGLEN EQU   24                       LENGTH OF EACH PCU STRING       88680000
MSDIS    EQU   16                       DISP TO MSENS IN EACH STRING    88740000
MRDIS    EQU   8                        DISP TO MREAD IN EACH STRING    88800000
NOPDIS   EQU   0                        DISP TO NOP IN   EACH STRING    88860000
TIC      EQU   X'08'              TIC COMMAND CODE                      88920000
UEOFF    EQU   X'EF'              MASK FOR BIT 3                OX01515 88970000
* FOLLOWING ARE CONSTANTS AND WORKAREAS USED BY THE APPENDAGES          88980000
*                                                                       89040000
*                                                                       89100000
         DS    0D                       FOR ALIGNMENT                   89160000
*                                                                       89820000
CSAV     DC    F'0'                    SAVE AREA FOR CMICB              89880000
KRESAV   DS    16F                      FOR SAVING SUPVS REGISTERS      89940000
*                                                                       90000000
KCODCON  DS    0F                       SUCCESSFUL                      90060000
         DC    X'7F000000'              COMPLETION CODE                 90120000
*                                                                       90180000
WHAT     DC    X'00'               CODE, TYPE ENTRY FROM IOS     41426  90210021
WHICH    DC    X'00'                    INDICATES WHICH APPENDAGE       90240000
CHECKARE DC    X'00'                   FOR ISOLATING SITUATION          90300000
*                                       IS EXECUTING AT ANY GIVEN TIME  90360000
KEIGHT   DC    H'8'                     CONSTANT OF 8                   90420000
H32CON   DC    H'32'                   TO DECREMENT BUFF COUNTER        90480000
KTEN     DC    H'10'                    CONSTANT OF 10                  90540000
KPCUER   DS    0F                       ERROR COMPLETION CODE           90600000
         DC    X'41000000'                                              90660000
*                                                                       90720000
CLR      XC    0(0,GR5),0(GR5)          EXECUTED FOR ZEROING BUFFERS    90780000
*                                                                       90840000
KSCUER   DS    0F                       ERROR  COMPLETION CODE FOR SCU  90900000
         DC    X'41000001'                                              90960000
KELEVN   DC    H'11'                    CONSTANT 11                     91020000
KNINE    DC    H'9'                    CONSTANT NINE                    91080000
INTSAV   DC    F'0'                    SAVE AREA                        91140000
FORTY8   DC    F'48'              CONSTANT OF 48                        91200000
ZERSAV   DC    X'00'                   FOR SAVING BUFFER STATUS         91260000
         DC    52F'0'              PATCH AREA                    A33935 91320020
*  FOLLOWING ARE DUMMY  SECTIONS                                        91380000
         DCBD  DSORG=BS,DEVD=MR                                         91440000
*                                                                       91500000
*                                                                       91560000
NAME     DSECT                                                          91620000
DXIOB    DS    0CL32                                                    91680000
IOBFLAG1 DC    X'00'                                                    91740000
IOBFLAG2 DC    X'00'                                                    91800000
IOBSENSE DS    0H                                                       91860000
IOBSENS0 DS    CL1                                                      91920000
IOBSENS1 DS    CL1                SENSE BYTE 1                          91980000
IOBECBPT DS    XL1                                                      92040000
         DC    AL3(0)                                                   92100000
IOBCSW   DS    0D                                                       92160000
IOBCOMAD DC    X'00000000'        KEY,0000,COMMAND ADDRESS              92220000
IOBSTAT0 DC    X'00'              STATUS BYTE 0                         92280000
IOBSTAT1 DC    X'00'              STATUS BYTE 1                         92340000
IOBCNT   DC    X'0000'            COUNT                                 92400000
IOBSIOCC DS    XL1                                                      92460000
IOBSTART DC    AL3(0)                                                   92520000
IOBWGHT  DS    XL1                                                      92580000
IOBDCBPT DC    AL3(0)                                                   92640000
         DS    XL1                                                      92700000
         DS    XL3                                                      92760000
IOBINCAN DC    X'0000'                                                  92820000
IOBERRCT DS    XL2                                                      92880000
CHANDIS  EQU   CEAPEN-CHANEND                                           92940000
ABNDIS   EQU   AEAPEN-ABNEND                                            93000000
SCHEDIS  EQU   SCEDSSX-SCHEDSS                                          93060000
SIODIS   EQU   SIOTRAC-SIOENTER                                  41426  93090021
IOSENS0  EQU   IOBSENS0                                                 93120000
IOBECBCC EQU   IOBECBPT                                                 93180000
         END                                                            93240000
