         TITLE 'IGG0201D CLOSE EXECUTOR 1419'                           00200000
IGG0201D CSECT                                                          00400000
*D316000,318000,320000,322000,324000                            SA60237 00410002
*D312000                                                        SA60756 00420002
*1022245000,246000,424000,427000-429000                          A48612 00430000
*A245000-246000,427000-429000                                    A33928 00460020
*D246000,428000                                                  A33928 00530020
*                                                               SA62501 00580002
* STATUS CHANGE LEVEL 001                                               00600000
*FUNCTION/OPERATION-THE FOLLOWING IS A CLOSE EXECUTOR FOR 1419 DATA     00800000
*                   SETS.CLOSE FUNCTIONS WILL BE PERFORMED ON THOSE     01000000
*                   DCBS WHERE DCBDSORG FIELD SPECIFIES PS AND THE      01200000
*                   DCBDEUT FIELD SPECIFIES MR.THE SUPPORT WILL         01400000
*                   PERFORM THE FOLLOWING FUNCTIONS:                    01600000
*                                                                       01800000
*                   1.THE AEQ,RB,AND LOGICAL CHANNEL QUEUES ARE         02000000
*                     PURGED FOR BOTH THE PCU AND SCU                   02200000
*                                                                       02400000
*                   2.STORAGE FOR THE FOLLOWING ITEMS IS FREED FOR      02600000
*                     EACH DCB:                                         02800000
*                        A.CHANNEL PROGRAMS FOR PCU AND SCU             03000000
*                        B.BUFFERS FOR THE WRITE DELAY COMMAND          03200000
*                        C.IOB FOR THE PCU                              03400000
*                        D.IOB FOR THE SCU                              03600000
*                        E.MICB TABLE                                   03800000
*                        F.REGISTER SAVE AREA                           04000000
*                        G.ECB LIST                                     04200000
*                        H.BUFFER POOL IF OPEN ACQUIRED BUFFERS         04400000
*                   3.THE FOLLOWING VECTORS IN THE DCB ARE RESTORED     04600000
*                     TO THEIR PRE-OPEN VALUES:                         04800000
*                        A.DCBSSID-USER STACKER SELECT NAME             05000000
*                        B.DCBIOBAD-ADDRESS OF IOB                      05200000
*                        C.DCBCHECK-ADDRESS OF CHECK MODULE             05400000
*                        D.DCBIOBA-MICB READ ADDRESS                    05600000
*                        E.DCBNCP-NUMBER OF CHANNEL PROGRAMS            05800000
*                        F.DCBEOBR-END-OF-BLOCK MODULE ADDRESS          06000000
*                        G.DCBCNTRL-CONTROL MODULE ADDRESS              06200000
*                        H.DCBMRIND-INDICATOR BYTE                      06400000
*                        I.DCBECBLT-ECB LIST ADDRESS                    06600000
*                        J.DCBIOBL-IOB LENGTH                           06800000
*                        K.DCBMRFLG,DCBAPPIN-INDICATOR BYTES            07000000
*                        L.DCBBUFCB,DCBBUFL-IF OPEN ACQUIRED BUFFERS    07200000
*                   4.THE USER'S STACKER SELECT ROUTINE,LOADED BY       07400000
*                     OPEN,IS DELETED.                                  07600000
*                                                                       07800000
*ENTRY-ENTRY TO MODULE IS AT IGG0201D.CONTROL IS RECEIVED FROM          08000000
*      IGG0200A OR IGG0200Z VIA XCTL.                                   08200000
*                                                                       08400000
*INPUT-PARM LIST CONTAINING DCBS TO BE CLOSED,RELATED DEBS,AND THE      08600000
*      WTG TABLE(SEE DESCRIPTION OF REGISTERS).                         08800000
*                                                                       09000000
*OUTPUT-NONE                                                            09200000
*                                                                       09400000
*EXTERNAL REFERENCES-DCB ADDRESSES WHICH ARE PASSED TO THIS ROUTINE     09600000
*                    AS INPUT PARAMETERS                                09800000
*EXIT NORMAL-XCTL TO IGG0200B,IGG0200G                                  10000000
*                                                                       10200000
*EXIT ERROR-N/A                                                         10400000
*                                                                       10600000
*TABLES/WORK AREAS-WHERE-TO-GO TABLE                                    10800000
*                                                                       11000000
*                   BYTE 0-7  NAME                                      11200000
*                   BYTE 8-10 RELATIVE DISK ADDRESS(TTR) FIRST RECORD   11400000
*                   BYTE 11   CONCATENATION NUMBER                      11600000
*                   BYTE 12   ZERO                                      11800000
*                   BYTE 13   ALIAS INDICATOR,USER DATA FIELD DESCRIPTR 12000000
*                   BYTE 14-16 TTR FIRST TEXT RECORD                    12200000
*                   BYTE 17   ZERO                                      12400000
*                   BYTE 18-19TTR OF NOTE LIST OR SCATTER LIST          12600000
*                   BYTE 20   TRANSLATION TABLE                         12800000
*                   BYTE 21   ZERO OR NO. OF ENTRIES IN NOTE LIST       13000000
*                   BYTE 22-23ATTRIBUTES                                13200000
*                   BYTE 24-26TOTAL CONTIGUOUS MAIN STORAGE FOR MODULE  13400000
*                   BYTE 27-28LENGTH OF FIRST TEXT RECORD               13600000
*                   BYTE 29   LENGTH OF WTG TABLE(IN DOUBLE WORDS)      13800000
*                   BYTE 30-31PATH THROUGH ROUTINES                     14000000
*                   BYTE 32-36IDTTR OF EXECUTOR FOR FIRST DCB           14200000
*                   BYTE 37-39WORKAREA ADDRESS FOR FIRST DCB            14400000
*                   BYTE 40-  TABLE OF IDTTR'S                          14600000
*                   BYTE 32+N(8)   IDTTR OF EXECUTOR FOR NTH DCB        14800000
*                                  WORKAREA ADDRESS FOR NTH DCB         15000000
*              FORCORE DSECT(SEE DSECT IN LISTING)                      15200000
*                                                                       15400000
*ATTRIBUTES-REENTRANT,REUSEABLE                                         15600000
*                                                                       15800000
*NOTES-THIS ROUTINE ISSUES A WAIT MACRO                                 16000000
*                                                                       16200000
*********************************************************************** 16400000
         EJECT                                                          16600000
*********************************************************************** 16800000
*                                                                       17000000
*********                GENERAL REGISTER USAGE               ********* 17200000
*                                                                       17400000
RPARM0   EQU   0                   PARM LIST POINTER/WORK REGISTER      17600000
RPARM1   EQU   1                   PARM LIST POINTER/WORK REGISTER      17800000
RDCB     EQU   2                   ADDR OF DCB                          18000000
RBASE    EQU   3                   BASE REGISTER FOR CSECT              18200000
RCORE    EQU   4                   ADDR OF CLOSE WORK AREA FOR DCB      18400000
RPARM    EQU   5                   POINTER TO START OF PARM LIST        18600000
RWTG     EQU   6                   POINTER TO START OF WTG TABLE        18800000
RPARMC   EQU   7                   POINTER TO CURRENT ENTRY IN PARMLIST 19000000
RWTGC    EQU   8                   POINTER TO CURRENT ENTRY IN WTG TAB  19200000
RIOB     EQU   9                   POINTER TO PCU IOB                   19400000
RUCB     EQU   10                  UCB ADDRESS POINTER                  19600000
RDEB     EQU   11                  POINTER TO DEB                       19800000
RWRK1    EQU   12                  WORK REGISTER                        20000000
RWRK2    EQU   13                  WORK REGISTER                        20200000
RPARME   EQU   14                  PARM LIST POINTER/WORK REGISTER      20400000
RPARMF   EQU   15                  PARM LIST POINTER/WORK REGISTER      20600000
*                                                                       20800000
*********************************************************************** 21000000
         EJECT                                                          21200000
*********************************************************************** 21400000
*                                                                       21600000
*********                     CONSTANT EQUATES                ********* 21800000
*                                                                       22000000
LENTRACE EQU   136                TRACE TABLE LEN.               A48612 22050021
FULWRD   EQU   X'01'              BFALN MASK FOR FULL WRD        A48612 22060000
BUFCBD   EQU   6                  DISP. TO ADJ. BUF. LEN.        A48612 22120000
SCUIOBIN EQU   X'10'               MASK TO TEST DCBMRIND FOR SCU IOB    22200000
PIOBLNGH EQU   48                  LENGTH OF PCU IOB                    22400000
SIOBLNGH EQU   48                  LENGTH OF SCU IOB                    22600000
PCHANPGM EQU   80                  LENGTH OF PCU CHANNEL PROGRAM        22800000
SCHANPGM EQU   72                  LENGTH OF SCU CHANNEL PROGRAM        23000000
MICBLNGH EQU   28                  LENGTH OF MICB TABLE ENTRY           23200000
WDBUFL   EQU   128                 LENGTH OF WRITE DELAY BUFFERS        23400000
ECBLSTLG EQU   64                  LENGTH OF ECB LIST                   23600000
EXTONE   EQU   X'01'               NUMBER OF EXTENTS FOR DEB            23800000
IOBSTRT  EQU   24                  DISP TO ADDR OF PCU CP IN IOB        24000000
SAVEAR   EQU   72                  LENGTH OF REGISTER SAVE AREA         24200000
BUFACQIN EQU   X'08'               MASK TO TEST BUFFER ACQUISTION TECH. 24400000
BUFCBL   EQU   8                   NORMAL CONTROL BLOCK LENGTH   A48612 24500000
RSTRVAL  EQU   X'01'               RESTORE VALUE FOR DCB VECTORS        24800000
RSTRBAB  EQU   X'F7'               MASK TO SET OFF BUF ACQ. BIT         25000000
NULL     EQU   X'00'               NULL MASK                            25200000
WGOFF    EQU   8                   LENGTH OF WTG TABLE ENTRY            25400000
PARMOFF  EQU   4                   LENGTH OF DCB ENTRY IN PARM LIST     25600000
WAOFF    EQU   32                  DISP TO IDTTR ENTRIES IN WTG TAB     25800000
PURGMSK  EQU   X'A0'               MASK TO SET PURGE OPTIONS            26000000
SPNUMBER EQU 250                  SUBPOOL NUMBER                        26006000
SHIFTNO  EQU   24                 NUMBER BITS TO SHIFT SP NUMBER        26012000
UNCOND   EQU   15                  MASK FOR UNCONDITIONAL BRANCH        26018000
KZERO    EQU   0                   CONSTANT OF ZERO                     26024000
DZERO    EQU   0                   DISP OF ZERO                         26030000
KWTGWK   EQU   4                   DISP TO DCB WORK AREA IN WTG ADDR    26036000
DEBUCBL  EQU   4                   LENGTH OF UCB ADDR IN DEB            26042000
DEBSUCBA EQU   36                  DISP TO SECOND UCB ADDR IN DEB       26048000
DBBUFCBL EQU   3                   LENGTH OF DCBBUFCB FIELD IN DCB      26054000
KONE     EQU   1                   CONSTANT OF ONE                      26060000
KTHREE   EQU   3                   CONSTANT OF THREE                    26066000
DBBUFLL  EQU   2                   LENGTH OF DCBBUFL FIELD IN DCB       26072000
DBSSIDL  EQU   8                   LENGTH OF DCBSSID FIELD IN DCB       26078000
DBCHECKL EQU   3                   LENGTH OF DCBCHECK FIELD IN DCB      26084000
DBECBLTL EQU   4                   LENGTH OF DCBECBLT FIELD IN DCB      26090000
ROUTIDL  EQU   2                   LENGTH OF ROUTINE ID                 26096000
EQUAL    EQU   8                   MASK FOR BRANCH EQUAL                26102000
LOW      EQU   4                   MASK FOR BRANCH LOW                  26108000
HIGH     EQU   2                   MASK FOR BRANCH HIGH                 26114000
NE       EQU   7                   MASK FOR BRANCH NOT EQUAL            26120000
DID      EQU   6                   DISP IN MOD NAME TO ID               26126000
DTTR     EQU   14                  DISP TO TTR IN XCTL ENTRY            26132000
LTTR     EQU   3                   LENGTH OF TTR                        26138000
KTWO     EQU   2                   CONSTANT OF TWO                      26144000
PURGLST  EQU   12                  LENGTH OF PURGE PARM LIST            26150000
DLKFLD   EQU   8                   DISP TO LINK FIELD PURGE LIST        26156000
DECBPURG EQU   4                   DISP TO ECB PURGE LIST               26162000
ORGTTR   EQU   1000               DISP TO TTR TABLE FROM START OF MOD   26168000
         USING IHADCB,RDCB                                              26200000
         USING IGGD0100,RBASE                                           26400000
         USING DEBD0100,RDEB                                            26600000
         USING FORCORE,RCORE                                            26800000
         BALR  RBASE,KZERO         SET UP CSECT BASE                    27000000
IGGD0100 EQU   *                                                        27200000
         L     RDCB,DZERO(RPARMC)  LOAD ADDR OF DCB TO BE CLOSED        27400000
         L     RDEB,DCBDEBAD       LOAD ADDR OF RELATED DEB             27600000
         L     RCORE,KWTGWK(RWTGC) LOAD ADDR OF DCB WORK AREA           27800000
* THE FOLLOWING WILL TEST A BIT IN THE INDICATOR DCBMRIND TO DETERMINE  28000000
* IF THE ADDR IN DCBIOBAD POINTS TO THE PCU IOB OR SCU IOB-IF TO THE    28200000
* SCU IOB,THE FIELD IS UPDATED TO POINT TO THE PCU IOB.                 28400000
*                                                                       28600000
         L     RIOB,DCBIOBAD       LOAD IOB ADDRESS                     28800000
         TM    DCBMRIND,SCUIOBIN   TEST IF ADDR FOR PCU OR SCU          29000000
         BZ    IGGD0200            PCU/GO PURGE QUEUES                  29200000
         LA    RWRK1,PIOBLNGH      LOAD LENGHT OF PCU IOB               29400000
         LA    RIOB,KZERO(RIOB)    CLEAR HIGH ORDER BITS                29600000
         SR    RIOB,RWRK1          CALCULATE PCU IOB ADDR               29800000
         ST    RIOB,DCBIOBAD       UPDATE IOB ADDR IN DCB               30000000
*                                                                       30200000
* THE FOLLOWING WILL PURGE THE QUEUES FOR THE PCU AND SCU VIA           30400000
* THE INTERNAL SUBROUTINE PURG0000                                      30600000
IGGD0200 EQU   *                                                        30800000
         LA    RWRK2,PURG0000      LOAD ADDR OF PURGE SUBROUTINE        31000000
         BALR  RWRK1,RWRK2         GO PURGE PCU QUEUES                  31400000
         EJECT                                                          32600000
************************ FREE STORAGE ROUTINES ************************ 32800000
*                                                                       33000000
* THE FOLLOWING ROUTINE WILL FREE STORAGE FOR THE FOLLOWING:            33200000
*        1.CHANNEL PROGRAMS FOR THE PCU AND SCU                         33400000
*        2.BUFFERS FOR THE WRITE DELAY COMMAND                          33600000
* FREEMAIN IS ISSUED IN THE INTERNAL SUBROUTINE FREE0000                33800000
*                                                                       34000000
         LA    RWRK2,FREE0000      LOAD ADDR OF FREE0000 SUBROUTINE     34200000
         L     RPARM1,IOBSTRT(RIOB) LOAD ADDR OF START OF PCU CP        34400000
         LA    RPARME,PCHANPGM     LOAD LENGTH OF PCU CP                34600000
         LA    RPARME,SCHANPGM(RPARME)  ADD LENGTH OF SCU CP            34800000
         LA    RPARM0,WDBUFL(RPARME)    ADD LENGTH OF WD BUFFERS        35000000
         BALR  RWRK1,RWRK2         GO FREE CP'S AND WD BUFFERS          35200000
*                                                                       35400000
* THE FOLLOWING ROUTINES WILL FREE STORAGE FOR THE FOLLOWING:           35600000
*        1.IOB'S FOR PCU AND SCU                                        35800000
*        2.MICB TABLE                                                   36000000
*        3.REGISTER SAVE AREA                                           36200000
* FREEMAIN IS ISSUED IN THE INTERNAL SUBROUTINE FREE0000                36400000
*                                                                       36600000
         LR    RPARM1,RIOB         LOAD ADDR OF PCU IOB                 36800000
         SR    RPARMF,RPARMF       ZERO WORK REGISTER                   37000000
         IC    RPARMF,DCBBUFNO     INSERT NUMBER OF BUFFERS             37200000
         LA    RWRK1,MICBLNGH      LOAD LENGTH OF MICB TABLE ENTRY      37400000
         MR    RPARME,RWRK1        CALCULATE LENGTH MICB TABLE          37600000
         LA    RPARMF,PIOBLNGH(RPARMF)  ADD LENGTH OF PCU IOB           37800000
         LA    RPARMF,SIOBLNGH(RPARMF)  ADD LENGTH OF SCU IOB           38000000
         LA    RPARMF,LENTRACE(RPARMF)  ADD LEN. OF TRACE TABLE  A48612 38050021
         LA    RPARM0,SAVEAR(RPARMF)    ADD LENGTH OF REG SAVE AREA     38200000
         BALR  RWRK1,RWRK2         FREE IOBS,MICB TABLE,SAVE AREA       38400000
*                                                                       38600000
* THE FOLLOWING ROUTINE WILL FREE THE ECB LIST-FREEMAIN IS ISSUED       38800000
* IN THE INTERNAL SUBROUTINE FREE0000.                                  39000000
*                                                                       39200000
         L     RPARM1,DCBECBLT     LOAD ADDR OF ECB LIST                39400000
         LA    RPARM0,ECBLSTLG     LOAD LENGTH                          39600000
         BALR  RWRK1,RWRK2         GO FREE ECB LIST                     39800000
         EJECT                                                          40000000
************************ FREE BUFFER POOL ROUTINE ********************* 40200000
*                                                                       40400000
* THE FOLLOWING WILL FREE THE BUFFER POOL IF OPEN ACQUIRED THE BUFFERS. 40600000
* IN ADDITION,SEVERAL VECTORS IN THE DCB-DCBBUFCB,DCBBUFL-ARE RESTORED  40800000
* TO THEIR PRE-OPEN VALUES IF OPEN ACQUIRED THE BUFFERS.                41000000
*                                                                       41200000
         TM    DCBCIND2,BUFACQIN   DID OPEN ACQUIRE BUFFERS             41400000
         BZ    IGGD0300            NO/GO CLEAR VECTOR FIELDS            41600000
         L     RPARM1,DCBBUFCB     LOAD ADDRESS OF BUFFER CNTRL BLK     41800000
         SR    RPARMF,RPARMF       ZERO WORK REGISTER                   42000000
         IC    RPARMF,DCBBUFNO     INSERT NUMBER OF BUFFERS             42200000
         LH    RWRK1,BUFCBD(RPARM1) LOAD ADJ. BUF. LEN.          A48612 42400000
         MR    RPARME,RWRK1        CALCULATE LENGTH BUFFER POOL         42600000
         TM    DCBBFALN,FULWRD    TEST FULL WORD NOT DOUBLE      A48612 42700000
         LA    RPARM0,BUFCBL(RPARMF) ASSUME USUAL ALIGNMENT      A48612 42760000
         BZ    BUFPOOL1           FULL WORD BIT IS OFF           A48612 42820000
         LA    RPARM0,BUFCBL+8(RPARMF)  EXTRA 8 FOR FULL WORD    A48612 42880000
BUFPOOL1 EQU   *                                                 A48612 42940000
         BALR  RWRK1,RWRK2         GO FREE BUFFER POOL                  43000000
         XC    DCBBUFCB+KONE(DBBUFCBL),DCBBUFCB+KONE  CLEAR BUFCB ADDR  43200000
         OI    DCBBUFCB+KTHREE,RSTRVAL  RESTORE TO PRE-OPEN VALUE       43400000
         XC    DCBBUFL(DBBUFLL),DCBBUFL RESTORE BUFFER LENGTH           43600000
         NI    DCBCIND2,RSTRBAB    SET BUFFER ACQUISITION BIT OFF       43800000
         EJECT                                                          44000000
************************ RESTORE DCB VECTOR ROUTINE ******************* 44200000
*                                                                       44400000
* THE FOLLOWING ROUTINE WILL RESTORE THE FOLLOWING VECTORS TO THEIR     44600000
* PRE-OPEN VALUES:                                                      44800000
*        1.DCBSSID                                                      45000000
*        2.DCBIOBAD                                                     45200000
*        3.DCBCHECK                                                     45400000
*        4.DCBIOBA                                                      45600000
*        5.DCBNCP                                                       45800000
*        6.DCBEOBR                                                      46000000
*        7.DCBCNTRL                                                     46200000
*        8.DCBMRIND                                                     46400000
*        9.DCBECBLT                                                     46600000
*       10.DCBIOBL                                                      46800000
*       11.DCBMRFLG                                                     47000000
*       12.DCBAPPIN                                                     47200000
*                                                                       47400000
IGGD0300 EQU   *                                                        47600000
         MVC   DCBSSID(DBSSIDL),DEBSSID MOVE SS ID BACK INTO DCB        47800000
         LA    RWRK1,RSTRVAL       LOAD RESTORE VALUE INTO REG          48000000
         ST    RWRK1,DCBIOBAD      RESTORE IOB ADDRESS                  48200000
         XC    DCBCHECK+KONE(DBCHECKL),DCBCHECK+KONE   CLEAR CHECK      48300000
*                                                 MODULE ADDRESS        48400000
         OI    DCBCHECK+KTHREE,RSTRVAL  RESTORE TO PRE-OPEN VALUE       48500000
         ST    RWRK1,DCBIOBA       RESTORE MICB READ ADDR               48800000
         ST    RWRK1,DCBNCP        RESTORE NCP TO ZERO                  49000000
*                                  AND EOB MODULE ADDR TO 1             49200000
         ST    RWRK1,DCBCNTRL      RESTORE CONTROL MODULE ADDR          49400000
         XC    DCBECBLT(DBECBLTL),DCBECBLT  RESTORE ECB LIST ADDR       49500000
*                                           AND DCBMRIND INDICATORS     49600000
         NI    DCBIOBL,NULL        ZERO IOB LENGTH                      49800000
         NI    DCBMRFLG,NULL       ZERO INDICATOR                       50000000
         NI    DCBAPPIN,NULL       ZERO INDICATOR                       50200000
         EJECT                                                          50400000
************************ DELETE USER SS ROUTINE *********************** 50600000
*                                                                       50800000
* THE FOLLOWING WILL DELETE THE USER'S STACKER SELECT ROUTINE           51000000
*                                                                       51200000
         LA    RPARM0,DCBSSID      LOAD ADDR OF USER'S SS ID IN DCB     51400000
         DELETE EPLOC=(0)          DELETE USER'S SS ROUTINE             51600000
*                                                                       51800000
         MVI   DZERO(RWTGC),NULL   DEACTIVATE THIS ENTRY                52000000
*                                                                       52200000
************************ WTG TABLE SEARCH ***************************** 52400000
*                                                                       52600000
* THE FOLLOWING ROUTINE WILL SEARCH THE WTG TABLE FOR THE NEXT ENTRY    52800000
* WHICH REQUIRES THIS EXECUTOR OR FOR END OF TABLE THEN EXIT VIA XCTL   53000000
IGGD0400 EQU   *                                                        53200000
         LA    RWTGC,WGOFF(RWTGC)  INCREMENT TO NEXT WTG TABLE ENTRY    53400000
         LA    RPARMC,PARMOFF(RPARMC) INCREMENT TO NEXT PARM ENTRY      53600000
         CLC   DZERO(ROUTIDL,RWTGC),ROUTNID  NEXT DCB REQUIRE THIS MOD  53800000
         BCR   EQUAL,RBASE         YES/RECURSE THROUGH MODULE           54000000
         CLC   DZERO(ROUTIDL,RWTGC),CLLDB    IS THIS END OF TABLE       54200000
         BC    LOW,IGGD0400        NO-GO INCREMENT TO NEXT ENTRY        54400000
         CLC   DZERO(ROUTIDL,RWTGC),CLLDG    IS THIS END OF TABLE       54600000
         BC    HIGH,IGGD0400       NO-GO INCREMENT TO NEXT ENTRY        54800000
         LR    RPARMC,RPARM        RESTORE TO START OF PARM LIST        55000000
         LA    RWTGC,WAOFF(RWTG)   POINT TO FIRST IDTTR IN WTG TABLE    55200000
IGGD0500 EQU   *                                                        55400000
         CLI   DZERO(RWTGC),NULL   IS THIS ENTRY ACTIVE                 55600000
         BC    NE,IGGD0600         YES/GO TRANSFER CONTROL              55800000
         LA    RWTGC,WGOFF(RWTGC)  INCREMENT TO NEXT ENTRY              56000000
         LA    RPARMC,PARMOFF(RPARMC) INCREMENT TO NEXT ENTRY           56200000
         B     IGGD0500            GO TEST NEXT ENTRY                   56400000
IGGD0600 EQU   *                                                        56600000
         MVC   DID(ROUTIDL,RWTG),DZERO(RWTGC)  MOVE ID INTO NAME        56800000
         MVC   DTTR(LTTR,RWTG),KTWO(RWTGC)     MOVE TTR IN              57000000
         XCTL  DE=(RWTG),SF=(E,DXCCW12)      TRANSFER CONTROL           57200000
ROUTNID  DC    C'1D'               ID OF THIS ROUTINE                   57400000
         EJECT                                                          57600000
************************ PURGE ROUTINE ******************************** 57800000
*                                                                       58000000
* THE FOLLOWING ROUTINE WILL BUILD THE PURGE LIST IN THE DCB WORK AREA  58200000
* AND THEN ISSUE A PURGE MACRO TO PURGE THE QUEUES FOR THE PCU OR SCU.  58400000
* THE PURGE OPTIONS WHICH ARE SET ARE                                   58600000
*        1.PURGE ONLY THE REQUEST ELEMENTS ASSOCIATED WITH DEB          58800000
*        2.DO NOT POST THE PURGE REQUEST                                59000000
*        3.HALT THE I/O OPERATION                                       59200000
*        4.PURGE ALL REQUESTS                                           59400000
*        5.PURGE AEQ,RB,AND LOGICAL CHANNEL QUEUES                      59600000
*        6.PURGE BY DEB                                                 59800000
*                                                                       60000000
PURG0000 EQU   *                                                        60200000
         XC    DXCCW6(PURGLST),DXCCW6   CLEAR AREA FOR PURGE LIST       60400000
         ST    RDEB,DXCCW6         STORE DEB ADDR IN LIST               60600000
         MVI   DXCCW6,PURGMSK      SET PURGE OPTIONS                    60800000
         LA    RPARM1,DEBUSRPG     LOAD ADDR OF USER'S LINK FIELD       61000000
         ST    RPARM1,DXCCW6+DLKFLD     STORE LINK FIELD ADDR INTO LIST 61200000
         LA    RPARM1,DXCCW6       LOAD ADDR OF PURGE LIST              61400000
         PURGE (1)                 PURGE                                61600000
         LA    RPARM1,DXCCW6+DECBPURG   LOAD ADDR ECB FOR PURGE         61800000
         WAIT  ECB=(1)             WAIT FOR PURGE                       62000000
         BCR   UNCOND,RWRK1        RETURN TO MAINLINE                   62200000
         EJECT                                                          62400000
************************ FREE STORAGE ROUTINE ************************* 62600000
*                                                                       62800000
* THE FOLLOWING IS AN INTERNAL SUBROUTINE WHICH WILL ISSUE A FREEMAIN   63000000
* TO FREE STORAGE BEFORE THIS ROUTINE IS ENTERED,REGISTER 0 MUST BE     63200000
* LOADED WITH THE LENGTH OF THE AREA TO BE FREED AND REGISTER 1 WITH    63400000
* THE STARTING ADDRESS OF THE AREA TO BE FREED.                         63600000
FREE0000 EQU   *                                                        63800000
         LA    RPARMF,SPNUMBER    LOAD SUBPOOL NUMBER                   63850000
         SLL   RPARMF,SHIFTNO     SHIFT SP NO TO HI ORDER BITS          63900000
         OR    RPARM0,RPARMF      PUT SUBPOOL NUMBER IN REG             63950000
         FREEMAIN R,LV=(0),A=(1)   FREE STORAGE                         64000000
         BCR   UNCOND,RWRK1        RETURN TO MAINLINE                   64200000
*********************************************************************** 64400000
*                                                                       64600000
************************ TABLE OF IDTTRL FOR NEXT MODULES ***********   64800000
*                                                                       65000000
         ORG   IGG0201D+ORGTTR                                          65200000
CLLDB    DC    C'0B    '          IDTTRL                                65400000
CLLDG    DC    C'0G    '          IDTTRL                                65600000
         DC    H'0'               END OF TABLE MARKER                   65800000
         DC    H'0'               FILLER                                66000000
         DC    F'0'               FILLER                                66200000
         DC    C'020'             CLOSE SVC CODE                        66400000
         DC    AL1(125)           DOUBLE WORD DISP TO ID TABLE          66600000
         EJECT                                                          66800000
************************ DSECT DEFINITION ***************************** 67000000
*                                                                       67200000
* THE FOLLOWING ARE DSECTS REQUIRED BY THIS EXECUTOR                    67400000
*                                                                       67600000
FORCORE  DSECT                                                          67800000
         IECDSECT                                                       68000000
DEBD0100 DSECT                                                          68200000
DEBNMSUB DS    0CL1                                                     68400000
DEBTCBAD DS    CL4                                                      68600000
DEBAMLNG DS    0CL1                                                     68800000
DEBDEBAD DS    CL4                                                      69000000
DEBOFLGS DS    0CL1                                                     69200000
DEBIRBAD DS    CL4                                                      69400000
DEBOPATB DS    0CL1                                                     69600000
DEBSYSPG DS    CL4                                                      69800000
DEBNMEXT DS    0CL1                                                     70000000
DEBUSRPG DS    CL4                                                      70200000
DEBPRIOR DS    0CL1                                                     70400000
DEBECBAD DS    CL4                                                      70600000
DEBPROTG DS    0CL1                                                     70800000
DEBDEBID DS    0CL1                                                     71000000
DEBDCBAD DS    CL4                                                      71200000
DEBEXSCL DS    0CL1                                                     71400000
DEBAPPAD DS    CL4                                                      71600000
DEBDVMOD DS    0CL1                                                     71800000
DEBUCBAD DS    CL4                                                      72000000
DEBUCBA2 DS    CL4                                                      72200000
DEBSUBID DS    CL8                                              SA62501 72400002
DEBSSID  DS    CL8                                                      72600000
         DCBD  DSORG=BS,DEVD=MR                                         72800000
         END                                                            73000000
