         TITLE 'IGG0210A - SECOND LOAD OF BPAM STOW ROUTINE'            00100021
         COPY  LCGASMSW                                                 00150001
IGG0210A CSECT                                                          00200021
         SPACE                                                          00300021
*********************************************************************** 00400021
*                                                                     * 00500021
         AIF   ('&LIB' EQ 'LIB1').OS    CHECK TYPE OF ENVIRONMENT       00550001
*          VS2 RELEASE 01 DELETIONS                                   * 00700001
*D365000                                                         YM0943 00750001
*          VS1 RELEASE 01 DELETIONS                                   * 00800001
*                                                                XM5415 00810001
*          VS1 RELEASE 02 DELETIONS                                   * 00810402
*                                                                XM9034 00812002
*          VS1 RELEASE 03 DELETIONS                                     00814003
* SEE CODE FLAGGED SA66881 FOR APAR XA03384                             00814421
*                                                               XA02999 00816003
*                                                               XA01664 00818003
*                                                               XA02388 00818403
.OS      ANOP                                                           00820001
*          RELEASE 21 DELETIONS                                       * 00850021
*                                                                 M0965 00900021
*                                                                     * 01000021
* STATUS -                                                            * 01100021
*    CHANGE LEVEL 09                                                  * 01200001
*    THIS MODULE WAS REWRITTEN FOR RELEASE 21.  THE FOLLOWING APARS   * 01300021
*    WERE CORRECTED.  28169, 33374, 35322, 42484, AND 43923.          * 01400021
*                                                                     * 01500021
*                                                                     * 01600021
* FUNCTION -                                                          * 01700021
*    WRITES AN EOD MARKER FOLLOWING THE LAST MEMBER WRITTEN IF THE    * 01800021
*    FOLLOWING CONDITIONS ARE MET.                                    * 01900021
*    1 - THE FUNCTION REQUESTED IS AN ADD OR A REPLACE.               * 02000021
*    2 - THE ENTRY BEING ADDED OR REPLACED IS NOT AN ALIAS.           * 02100021
*    3 - THE USER'S DCB IS NOT OPEN FOR RDBACK OR UPDATE.             * 02200021
*    4 - THE LAST I/O OPERATION PERFORMED BY THE USER WAS A WRITE.    * 02300021
*                                                                     * 02400021
*    RETURNS, TO THE USER, THE TTR OF THE LAST MEMBER WRITTEN IF THE  * 02500021
*    FOLLOWING CONDITIONS ARE MET.                                    * 02600021
*    1 - THE FUNCTION REQUESTED IS AN ADD OR A REPLACE.               * 02700021
*    2 - THE ENTRY BEING ADDED OR REPLACED IS NOT AN ALIAS.           * 02800021
*                                                                     * 02900021
*    BUILDS, IN THE STOW WORK AREA, THE CHANNEL PROGRAM USED BY THE   * 03000021
*    THIRD LOAD (IGG021AB) TO PERFORM THE I/O OPERATIONS ON THE       * 03100021
*    DIRECTORY NECESSARY TO ACCOMPLISH THE FUNCTION REQUESTED.        * 03200021
*                                                                     * 03300021
*                                                                     * 03400021
* ENTRY POINTS -                                                      * 03500021
*    IGG0210A - ENTERED VIA AN XCTL FROM IGC0002A.                    * 03600021
*                                                                     * 03700021
*                                                                     * 03800021
* INPUT -                                                             * 03900021
*    THE FOLLOWING PARAMETERS ARE PASSED WHEN CONTROL IS RECEIVED AS  * 04000021
*    DESCRIBED ABOVE.                                                 * 04100021
*    REGISTER 10 - CONTAINS THE ADDRESS OF STOW'S WORK AREA.          * 04200021
*    REGISTER 11 - CONTAINS THE ADDRESS OF THE USER'S DCB.            * 04300021
*                                                                     * 04400021
*                                                                     * 04500021
* OUTPUT -                                                            * 04600021
*    SAME REGISTERS AS INPUT.                                         * 04700021
*                                                                     * 04800021
*    FOR THE FUNCTIONS OF ADD OR REPLACE WITHOUT THE ALAIS OPTION,    * 04900021
*    THE BEGINNING RELATIVE ADDRESS (TTR) OF THE MEMBER ADDED OR      * 05000021
*    REPLACED IS RETURNED WITHIN THE TTR FIELD OF THE PARAMETER LIST  * 05100021
*    PASSED TO STOW.                                                  * 05200021
*                                                                     * 05300021
*                                                                     * 05400021
* EXTERNAL REFERENCES -                                               * 05500021
*    IECPRLTV - USED TO CONVERT AN ABSOLUTE DIRECT ACCESS ADDRESS,    * 05600021
*    MBBCCHHR, TO ITS RELATIVE EQUIVALENT, TTRN.                      * 05700021
*                                                                     * 05800021
*    IECPCNVT - CONVERTS A RELATIVE DIRECT ACCESS ADDRESS AND         * 05900021
*    CONCATENATION NUMBER, TTRN, TO ITS ABSOLUTE EQUIVALENT,          * 06000021
*    MBBCCHHR.                                                        * 06100021
*                                                                     * 06200021
*    SVC 55 - END OF VOLUME.  USED TO EXTEND THE DATA SET WHEN THE    * 06300021
*    CURRENT EXTENT DOES NOT CONTAIN SUFFICIENT SPACE TO WRITE AN EOD * 06400021
*    MARKER.                                                          * 06500021
*                                                                     * 06600021
*    EXCP AND WAIT ARE USED TO PERFORM I/O OPERATIONS.                * 06700021
*                                                                     * 06800021
*    FREEMAIN IS USED TO FREE STOW'S WORK AREA IN THE EVENT OF AN I/O * 06900021
*    ERROR.                                                           * 07000021
*                                                                     * 07100021
*                                                                     * 07200021
* EXITS, NORMAL -                                                     * 07300021
*    EXITS VIA AN XCTL TO MODULE IGG021AB.                            * 07400021
*                                                                     * 07500021
*                                                                     * 07600021
* EXITS, ERROR -                                                      * 07700021
*    RETURNS TO THE USER VIA SVC 3 IF AN I/O ERROR OCCURS WHILE       * 07800021
*    WRITING AN EOD MARKER.  REGISTER 15 WILL CONTAIN AN ERROR CODE   * 07900021
*    OF 16.                                                           * 08000021
*                                                                     * 08100021
*                                                                     * 08200021
* TABLES/WORK AREAS -                                                 * 08300021
*    THIS MODULE USES THE STOW WORK AREA, THE FORMAT AND CONTENTS OF  * 08400021
*    WHICH ARE DESCRIBED IN THE DSECTS AT THE END OF THE LISTING.     * 08500021
*                                                                     * 08600021
*                                                                     * 08700021
* ATTRIBUTES -                                                        * 08800021
*    REENTRANT, ENABLED, PRIVILEGED.                                  * 08900021
*                                                                     * 09000021
*                                                                     * 09100021
* CHARACTER CODE DEPENDENCY -                                         * 09200021
*    NONE                                                             * 09300021
*                                                                     * 09400021
*                                                                     * 09500021
* NOTES -                                                             * 09600021
*                                                                     * 09700021
*********************************************************************** 09800021
         EJECT                                                          09900021
*********************************************************************** 10000021
****                                                               **** 10100021
****     REGISTER EQUATES                                          **** 10200021
****                                                               **** 10300021
*********************************************************************** 10400021
         SPACE                                                          10500021
R0       EQU   0                        WORK/PARAMETER REGISTER         10600021
R1       EQU   1                        WORK/PARAMETER REGISTER         10700021
RDEB     EQU   R1                       DEB ADDRESS                     10800021
R2       EQU   2                        WORK REGISTER                   10900021
R3       EQU   3                        WORK REGISTER                   11000021
RCVT     EQU   R3                       CVT ADDRESS                     11100021
R4       EQU   4                        WORK REGISTER                   11200021
RDEVTBL  EQU   R4                       ADDR OF DEVICE CHAR TABLE       11300021
R5       EQU   5                        WORK REGISTER                   11400021
RAREA    EQU   6                        POINTER TO WORK AREA            11500021
RDCB     EQU   7                        POINTER TO THE USER'S DCB       11600021
RBASE    EQU   8                        BASE REGISTER                   11700021
R9       EQU   9                        WORK REGISTER                   11800021
RWORK1   EQU   R9                       WORK REGISTER                   11900021
R10      EQU   10                       WORK REGISTER                   12000021
R11      EQU   11                       WORK REGISTER                   12100021
R12      EQU   12                       WORK REGISTER                   12200021
R13      EQU   13                       WORK REGISTER                   12300021
RWORK2   EQU   R13                      WORK REGISTER                   12400021
R14      EQU   14                       RETURN ADDR/WORK REGISTER       12500021
R15      EQU   15                       RETURN CODE/WORK REGISTER       12600021
         EJECT                                                          12700021
*********************************************************************** 12800021
****                                                               **** 12900021
****     MASKS, DISPLACEMENTS, AND OTHER EQUATES                   **** 13000021
****                                                               **** 13100021
*********************************************************************** 13200021
         SPACE                                                          13300021
ZERO     EQU   X'00'                    BYTE OF ZEROS                   13400021
RCDZERO  EQU   X'00'                    USED TO SET TTR TO IND RECORD 0 13500021
RCDONE   EQU   X'01'                    USED TO SET TTR TO IND RECORD 1 13600021
IOERROR  EQU   X'10'                    I/O ERROR CODE                  13700021
EXCPBKCT EQU   X'84'                    USED TO IND EXCP AND USER       13800021
EOVCLS   EQU   X'04'                    IND. EOV ENTERED DURING CLOSE   13810003
*                                       AND THAT CLOSE MUST RE-READ     13820003
*                                       THE FORMAT 1 DSCB       XA02388 13830003
VRFIX    EQU   X'01'                    TESTS FOR V=R REQUEST   XA01664 13850003
VRRQST   EQU   X'80'                    PAGE FIX LENGTH         XA01664 13860003
*                                       MAINTAINING ACCURATE BLK COUNT  13900021
EXIT     EQU   3                        EXIT SVC NUMBER                 14000021
EXTLNGTH EQU   16                       LENGTH OF A DASD DEB EXTENT     14100021
EOV      EQU   55                       EOV SVC NUMBER                  14200021
         EJECT                                                          14300021
****                                                                    14400021
****     ESTABLISH ADDRESSABILITY                                       14500021
****                                                                    14600021
         BALR  RBASE,R0                 INITIALIZE BASE REGISTER        14700021
         USING *,RBASE                  ESTABLISH ADDRESSABILITY        14800021
         LR    RAREA,R10                CHANGE WORK AREA BASE REGISTER  14900021
         LR    RDCB,R11                 CHANGE DCB BASE REGISTER        15000021
         USING STWAREA,RAREA            ESTABLISH WORK AREA BASE REG    15100021
         USING IHADCB,RDCB              ESTABLISH DCB BASE REGISTER     15200021
         L     RDEB,STWDEBPT            GET ADDRESS OF COPIED DEB       15300021
         USING DEBBASIC,RDEB            ESTABLISH DEB BASE REGISTER     15400021
         L     RCVT,CVTPTR              GET CVT ADDRESS                 15500021
         USING CVT,RCVT                 ESTABLISH CVT BASE REGISTER     15600021
         SPACE 2                                                        15700021
****                                                                    15800021
****     IF THE FUNCTION IS ADD OR REPLACE, DETERMINE IF AN END OF DATA 15900021
****     MARKER MUST BE WRITTEN AFTER THE ASSOCIATED MEMBER.            16000021
****                                                                    16100021
         TM    STWFLAG1,STWCHNG+STWDEL  IS FUNCT CHANGE OR DELETE       16200021
         BNZ   BLDCHPGM                 YES, GO TO BUILD CHANNEL PGM    16300021
         TM    STWCTTRN,STWALIAS        IS NEW ENTRY AN ALIAS           16400021
         BO    BLDCHPGM                 YES, GO TO BUILD CHANNEL PGM    16500021
         TM    DEBOPATB,DEBACCS-X'05'   IS DATA SET OPEN FOR INPUT,     16600021
*                                       RDBACK, OR UPDATE               16700021
         BZ    RETRNTTR                 YES, GO TO RETURN TTR TO USER   16800021
         TM    STWFLAG1,STWDCBWR        WAS LAST OPERATION ON USER'S    16900021
*                                       DCB A WRITE                     17000021
         BNO   RETRNTTR                 NO, GO TO RETURN TTR TO USER    17100021
         SPACE 2                                                        17200021
****                                                                    17300021
****     CHECK THE VOLUME AND THE CURRENT TRACK TO DETERMINE IF SPACE   17400021
****     IS AVAILABLE TO WRITE THE EOD MARKER.                          17500021
****                                                                    17600021
SPACECHK EQU   *                                                        17700021
         L     RDEVTBL,DCBDVTBL         GET ADDR OF DEVICE CHAR TABLE   17800021
         USING DEVTABLE,RDEVTBL         ESTABLISH DEVICE TABLE BASE REG 17900021
         SR    RWORK1,RWORK1            CLEAR REGISTER                  18000021
         IC    RWORK1,DEVOVHDL          GET OVERHEAD FOR KEYED RECORD   18100021
*                                       WHICH IS LAST ON TRACK          18200021
         TM    DEVFLAG,DEV2BOVH         USING TWO BYTE OVERHEAD         18300021
         BNO   NOT2BYT1                 NO, CONT SIZE CALCULATION       18400021
         LH    RWORK1,DEVOVHDI          GET TWO BYTE OVERHEAD           18500021
         SPACE                                                          18600021
NOT2BYT1 EQU   *                                                        18700021
         SR    RWORK2,RWORK2            CLEAR REGISTER                  18800021
         IC    RWORK2,DEVOVHDK          OVERHEAD FOR RECORD KEY         18900021
         SR    RWORK1,RWORK2            SUBTRACT KEY OVERHEAD           19000021
         LA    RWORK1,1(,RWORK1)        OVERHEAD FOR KEY AND DATA       19100021
*                                       LENGTH OF ZERO                  19200021
         CH    RWORK1,DCBTRBAL          WILL TRACK HOLD EOD RECORD      19300021
         BNH   UPTRKBAL                 YES, GO TO UPDATE TRACK BALANCE 19400021
         SPACE 2                                                        19500021
*********************************************************************** 19600021
****                                                               **** 19700021
****     THE FOLLOWING ROUTINE IS USED TO DETERMINE THE NEXT TRACK **** 19800021
****     ADDRESS.  THIS IS DONE BY ADDING 1 TO THE CURRENT TT AND  **** 19900021
****     SENDING THIS VALUE TO THE RESIDENT CONVERT ROUTINE.  IF   **** 20000021
****     THE NUMBER OF TRACKS IN THE DEB IS EXCEEDED, THE CONVERT  **** 20100021
****     ROUTINE WILL RETURN A CODE OF 4 IN REGISTER 15.  INPUT TO **** 20200021
****     AND OUTPUT FROM THE RESIDENT CONVERT ROUTINE IS AS        **** 20300021
****     FOLLOWS.                                                  **** 20400021
****                                                               **** 20500021
****     IECPRLTV - CONVERTS AN ABSOLUTE DIRECT ACCESS ADDRESS,    **** 20600021
****                MBBCCHHR, TO ITS RELATIVE EQUIVALENT, TTRN.    **** 20700021
****                                                               **** 20800021
****                INPUT REGISTERS -                              **** 20900021
****                  1  - ADDRESS OF DEB                          **** 21000021
****                  2  - ADDRESS OF MBBCCHHR IN CORE             **** 21100021
****                  14 - ENTRY ADDRESS                           **** 21200021
****                  15 - ENTRY ADDRESS                           **** 21300021
****                                                               **** 21400021
****                OUTPUT REGISTERS -                             **** 21500021
****                  0  - TTR0 RESULT                             **** 21600021
****                  1-8  TRANSPARENT                             **** 21700021
****                  9-13 DESTROYED                               **** 21800021
****                  14 - TRANSPARENT                             **** 21900021
****                  15 - ZERO                                    **** 22000021
****                                                               **** 22100021
****     IECPCNVT - CONVERTS A RELATIVE DIRECT ACCESS ADDRESS AND  **** 22200021
****                CONCATENATION NUMBER, TTRN, TO ITS ABSOLUTE    **** 22300021
****                EQUIVALENT, MBBCCHHR.                          **** 22400021
****                                                               **** 22500021
****                INPUT REGISTERS -                              **** 22600021
****                  0  - ACTUAL TTRN                             **** 22700021
****                  1  - ADDRESS OF DEB                          **** 22800021
****                  2  - ADDRESS OF 8 BYTE AREA FOR MBBCCHHR     **** 22900021
****                  14 - RETURN ADDRESS                          **** 23000021
****                  15 - ENTRY ADDRESS                           **** 23100021
****                                                               **** 23200021
****                OUTPUT REGISTERS -                             **** 23300021
****                  0  - DESTROYED                               **** 23400021
****                  1-8  TRANSPARENT                             **** 23500021
****                  9-13 DESTROYED                               **** 23600021
****                  14 - TRANSPARENT                             **** 23700021
****                  15 - ERROR CODE                              **** 23800021
****                                                               **** 23900021
****                THE ERROR CODE FOR IECPCNVT WILL BE 0 FOR      **** 24000021
****                SUCCESSFUL CONVERSION, OR 4 IF THE VALUE OF TT **** 24100021
****                EXCEEDS THE TOTAL EXTENTS ASSIGNED.            **** 24200021
****                                                               **** 24300021
*********************************************************************** 24400021
         LA    R2,DCBFDAD               GET ADDRESS OF MBBCCHHR         24500021
         L     R15,CVTPRLTV             GET ENTRY PT IN CONVERT ROUTINE 24600021
*                                       TO CONVERT MBBCCHHR TO TTRN     24700021
         BALR  R14,R15                  GO TO CONVERT ROUTINE           24800021
         LR    RWORK1,R0                SAVE TTRN                       24900021
         AL    R0,CON10000              CALC NEXT RELATIVE TRACK ADDR   25000021
         AH    RWORK1,CON00100          CALC NEXT RCD ON CURRENT TRACK  25100021
         CL    RWORK1,DCBRELAD          IS NEXT RECORD FIRST IN MEMBER  25200021
         BNE   CONVRTTR                 NO, GO TO CONVERT TTR           25300021
         ST    R0,DCBRELAD              SET DCBRELAD TO FIRST RECORD    25400021
*                                       OF NEXT TRACK                   25500021
         MVI   DCBRELAD+2,RCDONE        INDICATE FIRST RECORD OF TRACK  25600021
         MVC   STWTTR,DCBRELAD          UPDATE ENTRY TTR FIELD          25700021
         SPACE                                                          25800021
CONVRTTR EQU   *                                                        25900021
         LR    R5,R0                    SAVE UPDATED TTR                26000021
         L     R15,CVTPCNVT             GET ENTRY PT IN CONVERT ROUTINE 26100021
*                                       TO CONVERT TTR TO MBBCCHHR      26200021
         BALR  R14,R15                  GO TO CONVERT ROUTINE           26300021
         LTR   R15,R15                  DOES IT EXCEED EXTENTS IN DEB   26400021
         BZ    SETRCD0                  NO, GO TO RESET RECORD NUMBER   26500021
*                                       AND TRACK BALANCE               26600021
         SPACE 2                                                        26700021
****                                                                    26800021
****     GO TO EOV TO GET SPACE FOR THE EOD MARKER.                     26900021
****                                                                    27000021
         DROP  RDEB                     DROP DEB BASE REIGISTER         27100021
         L     R9,DCBDEBAD              GET ADDRESS OF THE USER'S DEB   27200021
         USING DEBBASIC,R9              EST BASE FOR DEB BASIC SECTION  27300021
         SR    R10,R10                  CLEAR REGISTER                  27400021
         IC    R10,DEBNMEXT             GET NUMBER OF EXTENTS IN DEB    27500021
         SLL   R10,4                    MULTIPLY EXTENTS BY SIXTEEN     27600021
         DROP  R9                       DROP BASE FOR DEB BASIC SECTION 27700021
         LA    R9,DEBBASND-DEBBASIC(R10,R9)  POINT TO ACCESS METHOD     27800021
*                                       SECTION OF THE USER'S DEB       27900021
         USING DEBACSMD,R9              EST ACCESS METHOD SECTION BASE  28000021
         L     R11,DEBVOLSQ             SAVE CONTENTS OF FIRST WORD     28100021
         MVC   DEBVOLSQ,VOLSEQNO        SET CURRENT AND TOTAL NUMBER    28200021
*                                       OF VOLUMES TO ONE FOR EXCP      28300021
         DROP  R9                       DROP ACCESS METHOD SECTION BASE 28400021
         LH    R9,DCBMACRF              SAVE USER'S ACCESS METHOD FLAGS 28500021
         MVI   DCBMACRF,EXCPBKCT        IND EXCP AND ACCURATE BLOCK CNT 28600021
         MVI   DCBMACRF+1,ZERO          CLEAR SECOND BYTE               28700021
         LR    R1,RDCB                  GET DCB ADDRESS                 28800021
         SVC   EOV                      ISSUE EOV SVC                   28900021
         TM    DCBCIND2,DCBCNCLO        DID CLOSE ISSUE STOW     XM9034 28950002
         BNO   NOTCLOSE                 CONTINUE IF NOT          XM9034 28960002
         OI    DCBOFLGS,DCBOFIOF        RESET DCB BUSY BIT       XM9034 28970002
         L     RDEB,DCBDEBAD            LOAD NEW DEB ADDR       XA02388 28972003
         USING DEBBASIC,RDEB            ESTABLISH ADDR.         XA02388 28974003
         OI    DEBFLGS1,EOVCLS          EOV ISSUED DURING CLOSE XA02388 28976003
         DROP  RDEB                     DROP ADDRESSABILITY     XA02388 28978003
         SPACE                                                          28980002
NOTCLOSE EQU   *                                                 XM9034 28990002
         STH   R9,DCBMACRF              RESTORE USER'S FLAGS            29000021
         L     R9,DCBDEBAD              GET ADDR OF THE USER'S NEW DEB  29100021
         L     RDEB,STWDEBPT            RESTORE ADDR OF COPIED DEB      29200021
         USING DEBBASIC,RDEB            EST BASE FOR DEB BASIC SECTION  29300021
         SR    R12,R12                  CLEAR FOR NO. EXTENTS   XA02999 29310003
         IC    R12,DEBNMEXT-DEBBASIC(R9)  EXTENTS IN USER DEB   XA02999 29320003
         STC   R12,DEBNMEXT             PUT IN STOW'S DEB       XA02999 29330003
         LA    R9,DEBBASND-DEBBASIC(R10,R9) POINT TO NEW EXTENT XA02999 29340003
*                                       IN USER'S DEB           XA02999 29342003
         LA    RWORK2,DEBBASND-DEBBASIC(R10,RDEB) POINT TO LOCATION     29344003
*                                       FOR NEW EXT.            XA02999 29346003
         SLL   R12,4                    EXT SIZE OF USER DEB    XA02999 29350003
         SR    R12,R10                  ACT SIZE OF NEW EXT     XA02999 29400003
         BCTR  R12,0                    PREP FOR EXECUTE INST   XA02999 29410003
         EX    R12,MVDEBXT              NEW EXTENT TO WORKAREA  XA02999 29420003
         USING DEBDASD,R9               ADDR. DA PORTION OF DEB XA02999 29430003
         SRL   R10,4                    EXTENT NO. FOR EOF      XA02999 29440003
         STC   R10,DCBFDAD              PUT IN DCB FDAD         XA02999 29442003
         MVC   DCBFDAD+1(L'DCBFDAD-2),DEBBINUM  NEW SEARCH ARG. XA02999 29444003
         DROP  R9                                               XA02999 29446003
         LA    R9,1(R12,R9)             POINT PAST EXTENT FIELD XA02999 29496003
         USING DEBACSMD,R9              EST. ADDRESSABILITY     XA02999 29546003
         ST    R11,DEBVOLSQ             RESTORE USER'S DEB      XA02999 29596003
         DROP  R9                                               XA02999 29646003
         SPACE 2                                                        30900021
****                                                                    31000021
****     SINCE THE NEXT RECORD WILL BE WRITTEN ON A NEW TRACK, THE      31100021
****     DCBFDAD FIELD MUST BE UPDATED TO INDICATE RECORD 0 OF THE NEW  31200021
****     TRACK, AND DCBTRBAL MUST BE RESET TO MAXIMUM TRACK CAPACITY.   31300021
****                                                                    31400021
SETRCD0  EQU   *                                                        31500021
         MVI   DCBFDAD+7,RCDZERO        SET RECORD TO ZERO              31600021
         MVC   DCBTRBAL,DEVTRKLN        SET TRACK BALANCE TO MAX.       31700021
         SPACE 2                                                        31800021
****                                                                    31900021
****     CALCULATE AMOUNT OF TRACK WHICH WILL BE USED TO WRITE THE EOD  32000021
****     MARKER AND UPDATE THE DCBTRBAL FIELD.                          32100021
****                                                                    32200021
UPTRKBAL EQU   *                                                        32300021
         SR    RWORK2,RWORK2            CLEAR REGISTER                  32400021
         IC    RWORK2,DEVOVHDI          GET OVERHEAD FOR KEYED RECORD   32500021
*                                       WHICH IS NOT LAST ON TRACK      32600021
         TM    DEVFLAG,DEV2BOVH         USING TWO BYTE OVERHEAD         32700021
         BNO   NOT2BYT2                 NO, CONTINUE OVERHEAD CALC      32800021
         LH    RWORK2,DEVOVHDI          GET TWO BYTE OVERHEAD           32900021
         SPACE                                                          33000021
NOT2BYT2 EQU   *                                                        33100021
         LA    RWORK2,1(,RWORK2)        OVERHEAD FOR KEY AND DATA       33200021
*                                       LENGTH OF ZERO                  33300021
         SR    RWORK1,RWORK1            CLEAR REGISTER                  33400021
         IC    RWORK1,DEVOVHDK          GET OVERHEAD FOR RECORD KEY     33500021
         SR    RWORK2,RWORK1            SUBTRACT KEY OVERHEAD           33600021
         LH    RWORK1,DCBTRBAL          GET CURRENT TRACK BALANCE       33700021
         SR    RWORK1,RWORK2            CALCULATE NEW BALANCE           33800021
         STH   RWORK1,DCBTRBAL          UPDATE DCBTRBAL FIELD           33900021
         SPACE 2                                                        34000021
****                                                                    34100021
****     UPDATE DCBFDAD FIELD TO POINT TO END OF DATA MARKER.           34200021
****                                                                    34300021
         MVC   IOBSEEK,DCBFDAD          PUT NEW MBBCCHHR IN IOB         34400021
         SR    RWORK1,RWORK1            CLEAR REGISTER                  34500021
         IC    RWORK1,DCBFDAD+7         GET RECORD NUMBER               34600021
         LA    RWORK1,1(,RWORK1)        UPDATE RECORD NUMBER BY ONE     34700021
         STC   RWORK1,DCBFDAD+7         UPDATE DCBFDAD FIELD            34800021
         SPACE 2                                                        34900021
****                                                                    35000021
****     BUILD AND EXECUTE THE CHANNEL PROGRAM TO WRITE THE EOD MARKER. 35100021
****                                                                    35200021
         LM    R9,R14,EODCHPGM          GET SKELETON CHANNEL PROGRAM    35300021
         AR    R9,RAREA                 ESTABLISH SEARCH ADDRESS        35400021
         AR    R11,RAREA                ESTABLISH TIC ADDRESS           35500021
         AR    R13,RAREA                ESTABLISH BUFFER ADDRESS        35600021
         STM   R9,R14,STWWRDCP          CREATE CHANNEL PGM IN WORK AREA 35700021
         ST    R11,IOBSTART             PUT CHANNEL PGM ADDRESS IN IOB  35800021
         USING BUFFER,R13               ESTABLISH BUFFER BASE REGISTER  35900021
         MVC   BUFCNT,DCBFDAD+3         MOVE CCHHR TO BUFFER COUNT FLD  36000021
         XC    BUFCNT+5(3),BUFCNT+5     SET KEY AND DATA LENGTH TO ZERO 36100021
         DROP  RDEB                     DROP DEB BASE REIGISTER         36200021
         IC    RWORK1,IOBCSW+3          SAVE HI-ORDER BYTE OF    M0965  36250021
*                                       CSW STATUS FIELD         M0965  36260021
         EXCP  IOBSTDRD                 EXECUTE CHANNEL PROGRAM         36300021
         WAIT  ECB=ECBCC                WAIT FOR I/O TO COMPLETE        36400021
         TM    ECBCC,ECBNORM            DID I/O COMPLETE NORMALLY       36600021
         BNO   ERROR                    NO, RETURN TO THE USER          36700021
         STC   RWORK1,IOBCSW+3          RESTORE HI-ORDER BYTE OF M0965  36750021
*                                       CSW STATUS FIELD         M0965  36760021
         SPACE 2                                                        36800021
****                                                                    36900021
****     UPDATE THE DCBRELAD FIELD FOR NEXT MEMBER TO BE WRITTEN.       37000021
****                                                                    37100021
         L     RDEB,STWDEBPT            RESTORE ADDRESS OF COPIED DEB   37200021
         USING DEBBASIC,RDEB            ESTABLISH DEB BASE REGISTER     37300021
         LA    R2,DCBFDAD               GET ADDRESS OF MBBCCHHR         37400021
         L     R15,CVTPRLTV             GET ENTRY PT IN CONVERT ROUTINE 37500021
*                                       TO CONVERT MBBCCHHR TO TTRN     37600021
         BALR  R14,R15                  GO TO CONVERT ROUTINE           37700021
         AH    R0,CON00100              UPDATE TTRN TO NEXT RECORD      37800021
         ST    R0,DCBRELAD              UPDATE DCBRELAD FIELD           37900021
         SPACE 2                                                        38000021
****                                                                    38100021
****     RESTORE THE EXTENT NUMBER IN THE IOBSEEK FIELD TO REFLECT THE  38200021
****     FIRST EXTENT OF THE DATA SET.                                  38300021
****                                                                    38400021
         MVI   IOBM,ZERO                INDICATE FIRST EXTENT           38500021
         SPACE 2                                                        38600021
****                                                                    38700021
****     IF THE FUNCTION IS ADD OR REPLACE AND THE MEMBER IS NOT AN     38800021
****     ALAIS, RETURN THE TTR OF THE MEMBER TO THE USER.               38900021
****                                                                    39000021
RETRNTTR EQU   *                                                        39100021
         L     RWORK1,STWPARM           GET ADDR OF USER'S PARM AREA    39200021
         USING USENEWNM,RWORK1          ESTABLISH BASE FOR USER'S AREA  39300021
         MVC   USETTR,STWTTR            RETURN TTR TO USER              39400021
         DROP  RWORK1                   DROP BASE FOR USER'S PARM AREA  39500021
         SPACE 2                                                        39600021
****                                                                    39700021
****     CREATE THE WRITE/READ CHANNEL PROGRAM USED BY THE THIRD LOAD   39800021
****     AND XCTL TO THE THIRD LOAD TO PROCESS THE USER'S REQUEST.      39900021
****                                                                    40000021
BLDCHPGM EQU   *                                                        40100021
         DROP  RDEB                     DROP DEB BASE REGISTER          40200021
         LM    R9,R2,WRDCHPGM           GET SKELETON OF THE WRITE/READ  40300021
*                                       CHANNEL PROGRAM                 40400021
         AR    R11,RAREA                ESTABLISH TIC ADDRESS           40500021
         STM   R9,R2,STWWRDCP           CREATE WRITE/READ CHANNEL       40600021
*                                       PROGRAM IN STOW'S WORK AREA     40700021
         LR    R10,RAREA                RESTORE WORK AREA REGISTER      40800021
         LR    R11,RDCB                 RESTORE DCB REGISTER            40900021
         MVC   STWXID,THRDLOAD          MOVE THIRD LOAD ID TO XCTL AREA 41000021
         MVC   STWXTTR,THRDLOAD+2       MOVE THIRD LOAD TTR TO XCTL     41100021
*                                       AREA                            41200021
         LA    R15,STWXPTR              SET UP XCTL AREA POINTER        41300021
         XCTL  DE=(RAREA),SF=(E,(15))   ISSUE XCTL                      41400021
         SPACE 2                                                        41500021
****                                                                    41600021
****     PUT THE RETURN CODE IN REGISTER 15, FREE THE GOTTEN CORE, AND  41700021
****     RETURN TO THE USER.                                            41800021
****                                                                    41850002
ERROR   EQU   *                                                         41900002
         AIF   ('&LIB' EQ 'LIB1').NSVS1                                 41950002
         TM    STWFLAG1,VRFIX          V=R REQUEST?             XA01664 42020003
         BNO   NOPGFREE                BRANCH IF NOT            XA01664 42030003
         L     R1,STWPARM              STARTING ADDR            XA01664 42040003
         LA    R2,VRRQST(R1)           ENDING ADDR              XA01664 42042003
         TM    STWFLAG1,STWCHNG+STWADD CHANGE REQUEST?          XA01664 42044003
         BNO   PGREL                   BRANCH IF NOT            XA01664 42046003
         L     R1,STWHIGH              STARTING ADDR            XA01664 42048803
         LA    R2,VRRQST(R1)           ENDING ADDR              XA01664 42098803
PGREL    EQU   *                                                XA01664 42099203
         PGRLSE  LA=(1),HA=(2)                                  XA01664 42099603
NOPGFREE EQU   *                                                XA01664 42099703
.NSVS1   ANOP                                                           42099802
         LH    R0,STWGMSZ               SIZE OF GOTTEN CORE             42100021
         LR    R1,RAREA                 ADDRESS OF GOTTEN CORE          42200021
         FREEMAIN R,LV=(0),A=(1)        FREE GOTTEN CORE                42300021
         LA    R15,IOERROR              IND AN I/O ERROR OCCURED YM0943 42350001
         SVC   EXIT                     RETURN TO USER                  42400021
         EJECT                                                          42500021
*********************************************************************** 42600021
****                                                               **** 42700021
****     SKELETON CHANNEL PROGRAMS                                 **** 42800021
****                                                               **** 42900021
*********************************************************************** 43000021
         SPACE                                                          43100021
WRDCHPGM DS    0F                       THIS CHANNEL PROGRAM IS         43200021
*                                       USED BY IGG021AB FOR WRITING    43300021
*                                       AND READING DIRECTORY BLOCKS    43400021
WRDSRHID DC    X'31'                    SEARCH ID EQUAL                 43500021
         DC    AL3(0)                   POINTER TO SEARCH ARGUMENT      43600021
         DC    X'4000'                  COMMAND CHAINING                43700021
         DC    X'0005'                  NUMBER OF BYTES                 43800021
WRDTIC   DC    X'08'                    TRANSFER CONTROL TO SEARCH ID   43900021
         DC    AL3(STWSRCH2-STWAREA)    ADDRESS OF SEARCH ID            44000021
         DC    XL4'00'                  NOT USED BUT REQUIRED           44100021
WRDWRCKD DC    X'0D'                    WRITE KEY AND DATA              44200021
         DC    AL3(0)                   ADDRESS OF KEY AND DATA         44300021
         DC    X'5000'                  COMMAND CHAIN AND SUPPRESS DATA 44400021
*                                       TRANSFER WHEN CCW IS CHANGED    44500021
*                                       TO A WRITE                      44600021
         DC    X'0108'                  NO. OF BYTES TO BE TRANSFERED   44700021
WRDRCKD1 DC    X'9E'                    READ COUNT, KEY, AND DATA       44800021
         DC    AL3(STWBUF3-STWAREA)     ADDR OF COUNT, KEY, AND DATA    44900021
         DC    X'5000'                  SUPRESS DATA TRANSFER           45000021
         DC    X'0110'                  NO. OF BYTES TO BE TRANSFERED   45100021
WRDRCKD2 DC    X'9E'                    READ COUNT, KEY, AND DATA       45200021
         DC    AL3(STWBUF3-STWAREA)     ADDR OF COUNT, KEY, AND DATA    45300021
         DC    X'0000'                  FLAGS                           45400021
         DC    X'0110'                  NO. OF BYTES TO BE TRANSFERED   45500021
         SPACE 2                                                        45600021
EODCHPGM DS    0F                       THIS CHANNEL PROGRAM IS USED TO 45700021
*                                       WRITE THE EOD MARKER FOLLOWING  45800021
*                                       A MEMBER                        45900021
EODSRHID DC    X'31'                    SEARCH ID EQUAL                 46000021
         DC    AL3(IOBSEEK+3-STWAREA)   POINTER TO SEARCH ARGUMENT      46100021
         DC    X'4000'                  COMMAND CHAINING                46200021
         DC    X'0005'                  NUMBER OF BYTES                 46300021
EODTIC   DC    X'08'                    TRANSFER CONTROL TO SEARCH ID   46400021
         DC    AL3(STWSRCH2-STWAREA)    ADDRESS OF SEARCH ID            46500021
         DC    XL4'00'                  NOT USED BUT REQUIRED           46600021
EODWRCKD DC    X'1D'                    WRITE COUNT, KEY, AND DATA      46700021
         DC    AL3(STWBUF3-STWAREA)     ADDRESS OF COUNT FIELD          46800021
         DC    X'0000'                  FLAGS                           46900021
         DC    X'0008'                  NO. OF BYTES TO BE TRANSFERED   47000021
         EJECT                                                          47100021
*********************************************************************** 47200021
****                                                               **** 47300021
****     CONSTANTS                                                 **** 47400021
****                                                               **** 47500021
*********************************************************************** 47600021
         SPACE                                                          47700021
MVDEBXT  MVC   0(0,RWORK2),0(R9)        USED TO MOVE EXTENT     XA02999 47750003
*                                       FROM USER'S TO STOW'S DEB       47760003
CON10000 DC    F'65536'                 USED TO ADD 1 TO REL TRACK NO.  47800021
CON00100 DC    H'256'                   USED TO ADD 1 TO REL RECORD NO. 47900021
VOLSEQNO DC    X'00010001'              USED TO SET CURRENT AND TOTAL   48000021
*                                       NUMBER OF VOLUMES TO ONE        48100021
         SPACE                                                          48200021
         XCTLTABL ID=(THRDLOAD,AB),SVC=021                              48300021
         EJECT                                                          48400021
STWAREA  DSECT                                                          48500021
         SPACE 2                                                        48600021
*********************************************************************** 48700021
****                                                               **** 48800021
****     THIS DSECT MAPS THE WORK AREA USED BY THE STOW MODULES    **** 48900021
****                                                               **** 49000021
*********************************************************************** 49100021
         SPACE 2                                                        49200021
****                                                                    49300021
****     XCTL AREA USED BY FIRST AND SECOND LOAD MODULES OF STOW        49400021
****                                                                    49500021
STWXAREA DS    0CL32                    XCTL AREA                       49600021
STWXNAME DS    0CL8                     MODULE NAME                     49700021
STWXCOMN DS    CL6                      COMMON PORTION OF MODULE NAME   49800021
STWXID   DS    CL2                      ID PORTION OF MODULE NAME       49900021
         DS    XL6                      UNUSED - MUST BE ZEROS          50000021
STWXTTR  DS    XL3                      TTR OF MODULE                   50100021
         DS    XL5                      UNUSED - MUST BE ZEROS          50200021
STWXATTB DS    XL2                      ATTRIBUTES OF ALL LOADS         50300021
STWXMODL DS    XL3                      MAIN STORAGE REQUIRED    XM5415 50400021
STWXTXTL DS    XL2                      LENGTH OF FIRST TEXT RCD XM5415 50500021
         DS    XL3                      UNUSED - MUST BE ZEROS          50600021
STWXPTR  DS    2A                       POINTER TO XCTL AREA AND DCB    50700021
*                                       (DCB PTR IS ZEROS FOR SVCLIB)   50800021
         SPACE 2                                                        50900021
****                                                                    51000021
****     POINTERS AND USER DATA SAVE AREA                               51100021
****                                                                    51200021
STWPARM  DS    A                        ADDR OF USER SUPPLIED ENTRY     51300021
*                                       NAME (LOWER OF 2 FOR CHANGE)    51400021
STWHIGH  DS    A                        ADDR OF HIGHER OF 2 USER SUPP-  51500021
*                                       LIED ENTRY NAMES (CHANGE ONLY)  51600021
STWDEBPT DS    A                        ADDR OF DEB IN WORK AREA        51700021
STWGMSZ  DS    H                        SIZE OF CORE GOTTEN FOR WORK    51800021
*                                       AREA                            51900021
STWOFFLW DS    H                        OFFSET TO ADD, REPLACE, OR      52000021
*                                       DELETE LOCATION IN LOW BLOCK    52100021
STWOLDNM DS    CL8                      NAME OF ENTRY BEING DELETED     52200021
STWNEWNM DS    CL8                      NAME OF NEW ENTRY               52300021
STWTTR   DS    AL3                      MEMBER'S RELATIVE ADDRESS       52400021
STWCTTRN DS    XL1                      ALIAS BIT, NUMBER OF TTRNS,     52500021
*                                       AND LENGTH OF USER DATA         52600021
STWALIAS EQU   X'80'                    THIS MEMBER NAME IS AN ALIAS    52700021
STWDATA  DS    CL62                     USER DATA FOR ENTRY             52800021
         SPACE 2                                                        52900021
****                                                                    53000021
****     FLAG, CONDITION, AND SWITCH BYTES                              53100021
****                                                                    53200021
STWFLAG1 DS    B                        FIRST FLAG BYTE                 53300021
*                       BIT DEFINITIONS                                 53400021
*        BIT   7                        RESERVED                        53500021
STWCHNG  EQU   X'80'                    CHANGE FUNCTION, USED IN COMBI- 53600021
*                                       NATION WITH STWADD AND STWDEL   53700021
STWDEL   EQU   X'40'                    DELETE FUNCTION                 53800021
STWREPL  EQU   X'20'                    REPLACE FUNCTION                53900021
STWADD   EQU   X'10'                    ADD FUNCTION                    54000021
STWDRYRN EQU   X'08'                    DRY RUN BEING MADE ON DIRECTORY 54100021
STWFLOW  EQU   X'04'                    USED TO CONTROL PROGRAM FLOW    54200021
STWDCBWR EQU   X'02'                    LAST DCB OPERATION WAS A WRITE  54300021
*                                                                       54400021
STWRTN   DS    CL1                      RETURN CODE SAVE AREA           54500021
*                                                                       54600021
STWFLGLN EQU   *-STWAREA                LENGTH OF SAVE AND FLAG AREAS   54700021
         EJECT                                                          54800021
****                                                                    54900021
****     CONTROL BLOCKS FOR STOW'S CHANNEL PROGRAMS                     55000021
****                                                                    55100021
         IHAECB  DSECT=NO                                               55200021
         ORG   *-16                     SET STANDARD IOB BEHIND ECB     55300021
         IEZIOB  DSECT=NO                                               55400021
         SPACE 2                                                        55500021
****                                                                    55600021
****     STOW'S CHANNEL PROGRAMS                                        55700021
****                                                                    55800021
         ORG   IOBR+1                   PLACE CHANNEL PROGRAMS          55900021
*                                       BEHIND THE IOB SEEK FIELD       56000021
STWINCP  DS    0D                       THIS CHANNEL PROGRAM READS THE  56100021
*                                       INITIAL TWO DIRECTORY BLOCKS    56200021
STWSRCH1 DS    2F                       SEARCH ID EQUAL                 56300021
STWTIC11 DS    2F                       TRANSFER CONTROL TO SEARCH ID   56400021
STWRDCT1 DS    2F                       READ COUNT                      56500021
STWSRKY1 DS    XL1                      SEARCH ON KEY EQUAL OR HIGH     56600021
STWKYAD1 DS    AL3                      KEY ADDRESS                     56700021
         DS    XL4                      FLAGS AND BYTE COUNT            56800021
STWTIC12 DS    2F                       TRANSFER CONTROL TO READ COUNT  56900021
STWRDAT1 DS    2F                       READ DATA                       57000021
STWRCKD1 DS    2F                       READ COUNT KEY DATA             57100021
         SPACE                                                          57200021
STWWRDCP DS    0D                       THIS CHANNEL PROGRAM WRITES     57300021
*                                       AND READS DIRECTORY BLOCKS      57400021
STWSRCH2 DS    XL1                      SEARCH ID EQUAL                 57500021
STWIDAD2 DS    AL3                      ID ADDRESS                      57600021
         DS    XL4                      FLAGS AND BYTE COUNT            57700021
STWTIC2  DS    2F                       TRANSFER CONTROL TO SEARCH ID   57800021
STWWRKD1 DS    XL1                      WRITE KEY AND DATA              57900021
STWWRAD2 DS    AL3                      WRITE ADDRESS                   58000021
STWWFLG2 DS    B                        FLAGS                           58100021
STWCMDCH EQU   X'40'                    COMMAND CHAIN TO NEXT CCW       58200021
         DS    XL3                      BYTE COUNT                      58300021
STWRCKD2 DS    XL1                      READ COUNT KEY DATA             58400021
STWRDAD2 DS    AL3                      READ ADDRESS                    58500021
         DS    XL4                      FLAGS AND BYTE COUNT            58600021
STWRCKD3 DS    XL1                      READ COUNT KEY DATA             58700021
STWRDAD3 DS    AL3                      READ ADDRESS                    58800021
         DS    XL4                      FLAGS AND BYTE COUNT            58900021
         SPACE 2                                                        59000021
****                                                                    59100021
****     COMMAND CODE EQUATES FOR CHANNEL PROGRAMS                      59200021
****                                                                    59300021
STWIDEQ  EQU   X'31'                    SEARCH ON IDENTIFIER EQUAL      59400021
STWWRKD  EQU   X'0D'                    WRITE KEY AND DATA              59500021
STWRDKD  EQU   X'8E'                    READ KEY AND DATA               59600021
STWRDCKD EQU   X'9E'                    READ COUNT, KEY, AND DATA       59700021
         SPACE 2                                                        59800021
****                                                                    59900021
****     STOW'S INPUT - OUTPUT BUFFERS.  FOR DETAILS SEE THE            60000021
****     BUFFER DSECT.                                                  60100021
****                                                                    60200021
STWBUF1  DS    0F                       INITIALLY CONTAINS THE FIRST    60300021
         DS    CL276                    OF TWO DIRECTORY BLOCKS READ    60400021
STWBUF2  DS    0F                       INITIALLY CONTAINS THE SECOND   60500021
         DS    CL276                    OF TWO DIRECTORY BLOCKS READ    60600021
STWBUF3  DS    0F                       INITIALLY USED AS THE FIRST     60700021
         DS    CL276                    OUTPUT BUFFER                   60800021
STWBUF4  DS    0F                       USED AS AN INPUT BUFFER SA66881 60850021
         DS    CL272                    IN LAST LOAD OF STOW    SA66881 60860021
STWDEB   DS    0F                       LOCATION OF COPIED DEB          60900021
STWEND   EQU   *                        END OF WORK AREA                61000021
CORESIZE EQU   STWEND-STWAREA           SIZE OF STOW'S WORK AREA        61100021
         EJECT                                                          61200021
BUFFER   DSECT                                                          61300021
         SPACE                                                          61400021
*********************************************************************** 61500021
****                                                               **** 61600021
****     THIS DSECT MAPS STOW'S INPUT - OUTPUT BUFFERS             **** 61700021
****                                                               **** 61800021
*********************************************************************** 61900021
         SPACE                                                          62000021
BUFCNT   DS    CL8                      COUNT FIELD CONTAINING          62100021
*                                       ABSOLUTE DISK ADDRESS           62200021
BUFKEY   DS    CL8                      KEY FIELD (HIGHEST MEMBER NAME) 62300021
BUFDATA  DS    0CL256                   DATA AREA                       62400021
BUFN     DS    H                        NUMBER OF BYTES USED IN         62500021
*                                       THIS DIRECTORY BLOCK            62600021
BUFENTRY DS    CL254                    DIRECTORY ENTRIES               62700021
BUFADDR  DS    A                        USED TO CHAIN THE BUFFERS       62800021
BUFPREFX EQU   L'BUFCNT+L'BUFKEY+L'BUFN  OFFSET TO BUFFER ENTRY AREA    62900021
         SPACE 4                                                        63000021
DEVTABLE DSECT                                                          63100021
         SPACE                                                          63200021
*********************************************************************** 63300021
****                                                               **** 63400021
****     THIS DSECT MAPS THE DEVICE CHARACTERISTICS TABLE          **** 63500021
****                                                               **** 63600021
*********************************************************************** 63700021
         SPACE                                                          63800021
DEVNOCC  DS    H                        NUMBER OF CYLINDERS ON DEVICE   63900021
DEVNOHH  DS    H                        NUMBER OF TRACKS PER CYLINDER   64000021
DEVTRKLN DS    H                        MAXIMUM TRACK LENGTH            64100021
DEVOVHDI DS    X                        BLOCK OVERHEAD - FOR KEYED      64200021
*                                       BLOCK OTHER THAN LAST ON TRACK  64300021
DEVOVHDL DS    X                        BLOCK OVERHEAD - FOR KEYED      64400021
*                                       BLOCK WHICH IS LAST ON TRACK    64500021
DEVOVHDK DS    X                        NO. OF BYTES TO BE SUBTRACTED   64600021
*                                       FR OVERHEAD IF BLOCK NOT KEYED  64700021
DEVFLAG  DS    B                        FLAGS                           64800021
DEV2BOVH EQU   X'08'                    USE TWO BYTE OVERHEAD           64900021
DEVTOLNC DS    H                        TOLERANCE FACTOR                65000021
         EJECT                                                          65100021
USERPARM DSECT                                                          65200021
         SPACE                                                          65300021
*********************************************************************** 65400021
****                                                               **** 65500021
****     THIS DSECT MAPS THE USER PARAMETER FIELD                  **** 65600021
****                                                               **** 65700021
*********************************************************************** 65800021
         SPACE                                                          65900021
USEOLDNM DS    CL8                      OLD NAME FOR DELETE OR CHANGE   66000021
USENEWNM DS    CL8                      NEW NAME FOR ADD, REPLACE, OR   66100021
*                                       CHANGE                          66200021
USETTR   DS    XL3                      RELATIVE ADDRESS OF MEMBER      66300021
USECTTRN DS    XL1                      ALIAS AND LENGTH OF USER DATA   66400021
USEDATA  DS    CL62                     USER DATA                       66500021
USELNGMV EQU   L'USENEWNM+L'USECTTRN+L'USETTR  LENGTH OF NAME AND TTRC  66600021
         EJECT                                                          66700021
CVT      DSECT                                                          66800021
         SPACE                                                          66900021
         CVT   SYS=MIN                                                  67000021
         EJECT                                                          67100021
         DCBD  DSORG=PO                                                 67200021
         EJECT                                                          67300021
         IEZDEB                                                         67400021
         END   IGG0210A                                                 67500021
*                                  NUMBER OF BYTES USED IN THIS         67600000
*                                  DIRECTORY BLOCK AND STORE IT         67800000
         STH   R15,16(OUT)         IN THE FIRST TWO BYTES OF THE        68000000
*                              DIRECTORY BLOCK. THESE TWO BYTES         68200000
*                                  ARE INCLUDED IN THIS COUNT           68400000
         MVI   0(OUT),255                                               68600000
         SR    COUNT,WORK1         SUBTRACT THE LENGTH OF THE LAST      68800000
*                                  ENTRY FROM THE COUNT TO OBTAIN       69000000
*                                  THE NAME OF THAT ENTRY. THIS IS      69200000
         MVC   8(8,OUT),0(COUNT)   USED AS THE KEY FOR THIS             69400000
*                                    DIRECTORY                          69600000
         LA    WORK1,BUFF4                                              69800000
         CLR   WORK1,OUT                                                70000000
         LR    WORK1,OUT                                                70200000
         LA    OUT,272(OUT)                                             70400000
         BNE   GO                       Q. USE NEXT BUFFER              70600000
         LA    OUT,BUFF1                                                70800000
GO       STM   R0,R11,TEMPSAVE                                          71000000
         LR    R11,OUT                                                  71200000
         LA    R10,8(WORK1)                                             71400000
         LR    R15,WORK1                                                71600000
         SH    R15,N272            BACK UP TO PRECEEDING BUFFER         71800000
         LA    WORK1,BUFF1                                              72000000
         CLR   R15,WORK1           Q. BEYOND FIRST BUFFER               72200000
         BC    10,PTROK            NO - THIS POINTER OK                 72400000
         LA    R15,BUFF4           POINT TO BUFFER 4                    72600000
PTROK    EQU   *                                                        72800000
         MVC   CCHHR,0(R11)             SET SEEK ADDR                   73000000
         LM    R0,R9,WRANDRD            RELOCATE CHAN PROG              73200000
         ALR   R0,R11                   SEARCH EQUAL ID                 73400000
         ALR   R6,R11                   SEARCH EQUAL ID                 73600000
         AR    R2,RGAREA                TIC                             73800000
         AR    R8,RGAREA                TIC                             74000000
         ALR   R4,R10                   WRITE KEY AND DATA              74200000
         STM   R0,R9,CCW1                                               74400000
         LM    R0,R5,WRCCW6                                             74600000
         ALR   R4,R15                                                   74800000
         STM   R0,R5,CCW2                                               75000000
         LM    R0,R11,TEMPSAVE                                          75200000
         CLI   DCBDIRCT+1,X'00'    DRY RUN?                       22828 75250018
         BE    EXCP                BRANCH IF NOT                  22828 75300018
         MVI   CCW1+16,X'0E'        CHANGE WRITE TO READ         A26019 75330019
         OI    CCW1+20,X'30'        TURN ON SKIP, SLI BITS       A26019 75360019
EXCP     EXCP  IOB                                                      75400000
CHECK    WAIT  1,ECB=ECB                                                75600000
         TM    ECB,X'20'                CHECK FOR I/O ERROR             75800000
         BCR   1,WORK2                  Q. NO ERROR                     76000000
         TM    IOB+12,X'01'                                             76200000
         BCR   1,WORK2                  Q. EOD INSTEAD OF ERROR         76400000
IOERR    LA    R2,X'10'                 SET ERROR CODE                  76600000
         B     RETURN                                                   76800000
*                                                                       77000000
*                                                                       77200000
LNTHCALC LR    WORK1,LENGTH        SAVE PREVIOUS LENGTH                 77400000
         LH    LENGTH,10(POINT)    LOAD RC PORTION FROM TTRC            77600000
         N     LENGTH,MASK         AND MASK TO REMOVE THE R             77800000
         LA    LENGTH,12(LENGTH,LENGTH)      SINCE THE C PORTION        78000000
*                                  IS THE NUMBER OF HALF WORDS,         78200000
*                                  THIS INSTRUCTION IS DOUBLING         78400000
*                                  THE C TO OBTAIN THE NUMBER OF        78600000
*                              USER BYTES AND ADDING 12 FOR             78800000
*                                  THE 8 BYTE NAME AND 4 BYTE TTRC      79000000
*                                  TO OBTAIN THE TOTAL ENTR LENGTH      79200000
*                                                                       79400000
CKOUTFIT LA    WORK2,272(OUT)      POINT TO END OF OUTPUT BUFFER+1      79600000
         SR    WORK2,COUNT         CALC NUMBER OF BYTES REMAINING       79800000
         CR    WORK2,LENGTH        SET COMPARE COND FOR FIT             80000000
         BR    RGRET               RETURN TO CALLER                     80200000
MOVE1    MVC   0(1,COUNT),0(POINT)                                      80400000
MOVE2    MVC   NEWNAME+8(1),8(POINT)                                    80600000
         DS    0F                                                       80800000
SEARCH   DS    0F      CH PROG TO SEARCH DIRECTORY                      81000000
SCCW1    DC    X'1A'               READ HA                              81200000
         DC    AL3(0+BUFF1-AREA)                                        81400000
         DC    X'4000'                                                  81600000
         DC    H'5'                                                     81800000
SCCW2    DC    X'92'                    READ COUNT                      82000000
         DC    AL3(0+BUFF1-AREA)                                        82200000
         DC    X'4000'                                                  82400000
N8       DC    H'8'                                                     82600000
SCCW3    DC    X'E9'                    SEARCH HI/EQUAL KEY             82800000
         DC    AL3(0)                                                   83000000
         DC    X'4000'                                                  83200000
         DC    H'8'                                                     83400000
SCCW4    DC    X'08'                    TIC TO SCCW2                    83600000
         DC    AL3(8+CCW1-AREA)    TIC TO SCCW2                         83800000
ZERO     DC    F'0'                                                     84000000
SCCW5    DC    X'86'                    READ DATA                       84200000
         DC    AL3(16+BUFF1-AREA)                                       84400000
         DC    X'4000'                                                  84600000
N256     DC    H'256'                                                   84800000
SCCW6    DC    X'9E'                    READ COUNT,KEY AND DATA         85000000
         DC    AL3(0+BUFF2-AREA)                                        85200000
         DC    H'0'                                                     85400000
N272     DC    H'272'                                                   85600000
WRANDRD  DS    0F                       CH PROG TO WRITE AND READ       85800000
WRCCW1   DC    X'31'                    SEARCH EQUAL ID (NOT M/T)       86000000
         DC    AL3(0)                   BUFF1                           86200000
         DC    X'4000'                                                  86400000
         DC    H'5'                                                     86600000
WRCCW2   DC    X'08'                   TIC TO WRCCW1                    86800000
         DC    AL3(0)                                                   87000000
MASK     DC    X'0000001F'                                              87200000
WRCCW3   DC    X'0D'                    WRITE KEY AND DATA              87400000
         DC    AL3(0)                   BUFF3+8                         87600000
         DC    X'4000'                                                  87800000
         DC    H'264'                                                   88000000
WRCCW4   DC    X'31'                    SEARCH EQUAL ID                 88200000
         DC    AL3(0)                                                   88400000
         DC    X'4000'                                                  88600000
         DC    H'5'                                                     88800000
WRCCW5   DC    X'08'                    TIC TO WRCCW4                   89000000
         DC    AL3(24+CCW1-AREA)   TIC TO WCCW4                         89200000
SYSMASK  DC    X'FF'               SYSTEM MASK TO ENABLE INTERRUPT      89400000
         DC    X'00'                                                    89600000
N9       DC    H'9'                                                     89800000
WRCCW6   DC    X'8E'                    READ KEY AND DATA               90000000
         DC    AL3(0)                   BUFF3+8                         90200000
         DC    X'5000'                                                  90400000
         DC    H'264'                                                   90600000
WRCCW7   DC    X'8E'                    READ KEY AND DATA               90800000
         DC    AL3(0)                                                   91000000
         DC    X'7000'      SKIP DATA TO POSITION THE DISK              91200000
         DC    H'264'                                                   91400000
WRCCW8   DC    X'9E'                    READ CKD                        91600000
         DC    AL3(0)                   BUFF3                           91800000
         DC    F'272'                                                   92000000
         ORG   IGG0210A+1016                                      7M545 92040000
         DC    F'0'                                               7M545 92080000
         DC    C'021'                                             7M545 92120000
         DC    X'7F'                                              7M545 92160000
         END                                                            92200000
