         TITLE 'IGG021AB - THIRD LOAD OF BPAM STOW ROUTINE'             00100021
         COPY  LCGASMSW                                                 00150001
IGG021AB CSECT                                                          00200021
         SPACE                                                          00300021
*********************************************************************** 00400021
*                                                                     * 00500021
         AIF   ('&LIB' EQ 'LIB1').OS    CHECK TYPE OF ENVIRONMENT       00550001
*          VS2 RELEASE 01 DELETIONS                                   * 00600001
*                                                                YM0943 00650001
*          VS1 RELEASE 01 DELETIONS                                   * 00700001
*                                                                XM5415 00750001
*          VS1 RELEASE 03 DELETIONS                                     00752003
* SEE CODE FLAGGED SA66881 FOR VS1 APAR XA03384                         00754021
*                                                               XA02065 00756003
*                                                               XA01664 00758003
.OS      ANOP                                                           00760001
*          RELEASE 21 DELETIONS                                       * 00800021
* A538500,552500,552600,793500,793600                           SA66881 00810021
* R539000                                                       SA66881 00820021
*      FIX FOR APAR 56252 APPEARS UNDER THE FLAG OF OX00801             00850021
*                                                                 M1088 00900021
*                                                                     * 01000021
* STATUS -                                                            * 01100021
*    CHANGE LEVEL 10                                                  * 01200002
*    THIS MODULE IS NEW FOR RELEASE 21.  THE FOLLOWING APARS WERE     * 01300021
*    CORRECTED.  28169, 33374, 35322, 42484, AND 43923.               * 01400021
*                                                                     * 01500021
*                                                                     * 01600021
* FUNCTION -                                                          * 01700021
*    MAINTAINS PARTITIONED DATA SET DIRECTORIES IN ASCENDING ORDER OF * 01800021
*    THE BINARY VALUES OF THE NAMES OF THE MEMBERS.  THIS IS          * 01900021
*    ACCOMPLISHED BY ADDING, REPLACING, CHANGING THE NAME OF, OR      * 02000021
*    DELETING DIRECTORY ENTRIES.  IF THE FUNCTION REQUESTED IS ADD,   * 02100021
*    REPLACE, OR CHANGE, AND IF THERE ARE NO UNUSED DIRECTORY BLOCKS, * 02200021
*    THEN A DRY RUN WILL BE MADE AGAINST THE DIRECTORY TO DETERMINE   * 02300021
*    IF SUFFICIENT SPACE IS AVAILABLE IN WHICH TO PERFORM THE         * 02400021
*    REQUESTED FUNCTION.  FOLLOWING THE DRY RUN, OR IN THE CASE WHERE * 02500021
*    A DRY RUN IS NOT REQUIRED, THE DIRECTORY WILL BE ALTERED BY      * 02600021
*    EXPANDING AND/OR COMPRESSING THE DIRECTORY IN ORDER TO PERFORM   * 02700021
*    THE REQUESTED FUNCTION.                                          * 02800021
*                                                                     * 02900021
*                                                                     * 03000021
* ENTRY POINTS -                                                      * 03100021
*    IGG021AB - ENTERED VIA AN XCTL FROM IGG0210A.                    * 03200021
*                                                                     * 03300021
*                                                                     * 03400021
* INPUT -                                                             * 03500021
*    THE FOLLOWING PARAMETERS ARE PASSED WHEN CONTROL IS RECEIVED AS  * 03600021
*    DESCRIBED ABOVE.                                                 * 03700021
*    REGISTER 10 - CONTAINS THE ADDRESS OF STOW'S WORK AREA.          * 03800021
*    REGISTER 11 - CONTAINS THE ADDRESS OF THE USER'S DCB.            * 03900021
*                                                                     * 04000021
*                                                                     * 04100021
* OUTPUT -                                                            * 04200021
*    REGISTER 15 - CONTAINS THE RETURN CODE.                          * 04300021
*                                                                     * 04400021
*                                                                     * 04500021
* EXTERNAL REFERENCES -                                               * 04600021
*    EXCP AND WAIT ARE USED TO PERFORM I/O OPERATIONS.                * 04700021
*                                                                     * 04800021
*    FREEMAIN IS USED TO FREE STOW'S WORK AREA PRIOR TO EITHER A      * 04900021
*    NORMAL OR AN ERROR EXIT.                                         * 05000021
*                                                                     * 05100021
*                                                                     * 05200021
* EXITS, NORMAL -                                                     * 05300021
*    RETURNS TO THE USER VIA SVC 3 WITH ONE OF THE FOLLOWING RETURN   * 05400021
*    CODES IN REGISTER 15.                                            * 05500021
*    0 - INDICATES NORMAL COMPLETION OF THE USER'S REQUEST.           * 05600021
*    8 - INDICATES THAT THE ENTRY TO BE REPLACED COULD NOT BE FOUND,  * 05700021
*        BUT HAS BEEN ADDED TO THE DIRECTORY.                         * 05800021
*                                                                     * 05900021
*                                                                     * 06000021
* EXITS, ERROR -                                                      * 06100021
*    RETURNS TO THE USER VIA SVC 3 WITH ONE OF THE FOLLOWING RETURN   * 06200021
*    CODES IN REGISTER 15.                                            * 06300021
*    12 - INDICATES THERE IS NOT SUFFICIENT SPACE REMAINING IN THE    * 06400021
*         DIRECTORY TO PERFORM THE ADD, REPLACE, OR CHANGE FUNCTION   * 06500021
*         REQUESTED.                                                  * 06600021
*    16 - INDICATES AN I/O ERROR OCCURED WHILE WRITING OR READING     * 06700021
*         DIRECTORY BLOCKS.                                           * 06800021
*                                                                     * 06900021
*                                                                     * 07000021
* TABLES/WORK AREAS -                                                 * 07100021
*    THIS MODULE USES THE STOW WORK AREA, THE FORMAT AND CONTENTS OF  * 07200021
*    WHICH ARE DESCRIBED IN THE DSECTS AT THE END OF THE LISTING.     * 07300021
*                                                                     * 07400021
*                                                                     * 07500021
* ATTRIBUTES -                                                        * 07600021
*    REENTRANT, ENABLED, PRIVILEGED.                                  * 07700021
*                                                                     * 07800021
*                                                                     * 07900021
* CHARACTER CODE DEPENDENCY -                                         * 08000021
*    THIS MODULE IS DEPENDENT ON THE FOLLOWING EBCDIC CHARACTERS.     * 08100021
*    X'FFFFFFFF' - INDICATES THE LAST ENTRY IN A DIRECTORY.           * 08200021
*                                                                     * 08300021
*                                                                     * 08400021
* NOTES -                                                             * 08500021
*                                                                     * 08600021
*********************************************************************** 08700021
         EJECT                                                          08800021
*********************************************************************** 08900021
****                                                               **** 09000021
****     REGISTER EQUATES                                          **** 09100021
****                                                               **** 09200021
*********************************************************************** 09300021
         SPACE                                                          09400021
R0       EQU   0                        WORK/PARAMETER REGISTER         09500021
R1       EQU   1                        WORK/PARAMETER REGISTER         09600021
RWORK1   EQU   R1                       WORK REGISTER                   09700021
R2       EQU   2                        WORK REGISTER                   09800021
RIBFR    EQU   R2                       POINTER TO INPUT BFR            09900021
R3       EQU   3                        WORK REGISTER                   10000021
RMOVE    EQU   R3                       PTR TO NEXT ELEMENT TO BE MOVED 10100021
R4       EQU   4                        WORK REGISTER                   10200021
REMAIN   EQU   R4                       AMOUNT OF DATA IN INPUT BFR     10300021
R5       EQU   5                        WORK REGISTER                   10400021
ROBFR    EQU   R5                       POINTER TO OUTPUT BFR           10500021
R6       EQU   6                        WORK REGISTER                   10600021
RFILL    EQU   R6                       PTR TO NEXT SPACE IN OUTPUT BFR 10700021
R7       EQU   7                        WORK REGISTER                   10800021
RSPACE   EQU   R7                       UNUSED SPACE IN OUTPUT BFR      10900021
R8       EQU   8                        WORK REGISTER                   11000021
RSIZE    EQU   R8                       AMOUNT OF DATA TO BE MOVED      11100021
R9       EQU   9                        WORK REGISTER                   11200021
RWORK2   EQU   R9                       WORK REGISTER                   11300021
RAREA    EQU   10                       POINTER TO WORK AREA            11400021
RDCB     EQU   11                       POINTER TO THE USER'S DCB       11500021
RBASE    EQU   12                       BASE REGISTER                   11600021
R13      EQU   13                       WORK REGISTER                   11700021
R14      EQU   14                       RETURN ADDR/WORK REGISTER       11800021
R15      EQU   15                       RETURN CODE/WORK REGISTER       11900021
         EJECT                                                          12000021
*********************************************************************** 12100021
****                                                               **** 12200021
****     MASKS, DISPLACEMENTS, AND OTHER EQUATES                   **** 12300021
****                                                               **** 12400021
*********************************************************************** 12500021
         SPACE                                                          12600021
RCDZERO  EQU   X'00'                    USED TO INDICATE RECORD ZERO    12700021
NOTLAST  EQU   X'00'                    USED TO CHK STATUS OF DIRECTORY 12800021
UNITEXPT EQU   X'01'                    MASK FOR UNIT EXCEPTION         12900021
NOROOM   EQU   X'0C'                    NO ROOM IN DIRECTORY ERROR CODE 13000021
VRFIX    EQU   X'01'                    TESTS V=R REQUEST       XA01664 13050003
VRRQST   EQU   X'80'                    ENDING ADDR DISPLACEMENTXA01664 13060003
IOERROR  EQU   X'10'                    I/O ERROR CODE                  13100021
STOWPERF EQU   X'80'                    USED TO INDICATE STOW    M1088  13150021
*                                       HAS BEEN PERFORMED       M1088  13160021
OFF      EQU   X'FF'                    USED TO RESET STATUS BITS       13200021
ONES     EQU   1                        COND CODE MASK FOR ALL ONES     13300021
EXIT     EQU   3                        EXIT SVC NUMBER                 13400021
LOW      EQU   4                        COND CODE MASK FOR LOW          13500021
ZEROS    EQU   8                        COND CODE MASK FOR ALL ZEROS    13600021
         EJECT                                                          13700021
****                                                                    13800021
****     ESTABLISH ADDRESSABILITY                                       13900021
****                                                                    14000021
         BALR  RBASE,R0                 INITIALIZE BASE REGISTER        14100021
         USING *,RBASE                  ESTABLISH ADDRESSABILITY        14200021
         USING STWAREA,RAREA            ESTABLISH WORK AREA BASE REG    14300021
         USING IHADCB,RDCB              ESTABLISH DCB BASE REGISTER     14400021
         SPACE 2                                                        14500021
****                                                                    14600021
****     IF THE FIRST LOAD HAS OVERLAID THE TWO DIRECTORY BLOCKS WHICH  14700021
****     CONTAIN THE ONLY OR LOWER OF TWO ARGUMENTS, THEY MUST BE       14800021
****     RE-READ AT THIS TIME.                                          14900021
****                                                                    15000021
         TM    STWFLAG1,STWFLOW         HAS FIRST LOAD OVERLAID FIRST   15100021
*                                       DIRECTORY BLOCKS READ           15200021
         BNO   INITPTRS                 NO, GO TO INIT BUFFER POINTERS  15300021
         SPACE 2                                                        15400021
****                                                                    15500021
****     RE-READ ORIGINAL DIRECTORY BLOCKS.                             15600021
****                                                                    15700021
INITBFRS EQU   *                                                        15800021
         NI    STWFLAG1,OFF-STWFLOW     RE-SET FUNCTION FLOW INDICATOR  15900021
         LA    RWORK1,STWINCP           GET ADDR OF BUFFER INITIALI-    16000021
*                                       ZATION CHANNEL PROGRAM          16100021
         ST    RWORK1,IOBSTART          SET UP CHANNEL PROG ADDR IN IOB 16200021
         L     R1,STWDEBPT              GET ADDRESS OF COPIED DEB       16300021
         USING DEBBASIC,R1              ESTABLISH DEB BASE REGISTER     16400021
         MVC   IOBCC(4),DEBBASND+(DEBSTRCC-DEBDASD)  GET DATA SET       16500021
*                                       STARTING CCHH FROM THE DEB      16600021
         MVI   IOBR,RCDZERO             SET SEARCH TO BEGIN AT RECORD 0 16700021
         DROP  R1                       DROP DEB BASE REGISTER          16800021
         MVC   STWKYAD1,STWPARM+1       SET KEY TO READ ORIGINAL BLOCKS 16900021
         BAL   R13,EXCP                 GO ISSUE EXCP                   17000021
         SPACE 2                                                        17100021
****                                                                    17200021
****     INITIALIZE INPUT BUFFER, OUTPUT BUFFER, AND CHANNEL PROGRAM    17300021
****     POINTERS.                                                      17400021
****                                                                    17500021
INITPTRS EQU   *                                                        17600021
         LA    RIBFR,STWBUF1            INIT INPUT PTR TO FIRST BUFFER  17700021
         LA    RWORK1,STWBUF2           GET ADDRESS OF SECOND BUFFER    17800021
         LA    ROBFR,STWBUF3            INIT OUTPUT PTR TO THIRD BFR    17900021
         USING BUFFER,ROBFR             ESTABLISH BASE FOR THIRD BUFFER 18000021
         ST    RIBFR,BUFADDR            CHAIN FIRST BUFFER TO THIRD     18100021
         DROP  ROBFR                    DROP THIRD BUFFER BASE REG      18200021
         USING BUFFER,RWORK1            ESTABLISH BASE FOR SECOND BFR   18300021
         ST    ROBFR,BUFADDR            CHAIN THIRD BUFFER TO SECOND    18400021
         DROP  RWORK1                   DROP SECOND BUFFER BASE REG     18500021
         USING BUFFER,RIBFR             ESTABLISH INPUT BFR BASE REG    18600021
         ST    RWORK1,BUFADDR           CHAIN SECOND BUFFER TO FIRST    18700021
         LH    RWORK2,STWOFFLW          GET OFFSET TO ADD OR DELETE     18800021
*                                       POSITION WITHIN INPUT BUFFER    18900021
         AR    RWORK2,RIBFR             CALC ADDRESS OF SAME            19000021
         LH    REMAIN,BUFN              GET USED SPACE IN INPUT BLOCK   19100021
         SH    REMAIN,COUNTSZ           CALCULATE SIZE OF ENTRIES       19200021
         LA    RWORK1,STWWRDCP          GET ADDR OF WRITE/READ CHANNEL  19300021
*                                       PROGRAM                         19400021
         ST    RWORK1,IOBSTART          SET UP CHANNEL PROG ADDR IN IOB 19500021
         SPACE 2                                                        19600021
****                                                                    19700021
****     MOVE THE DIRECTORY ENTRIES PRECEDING THE ADD OR DELETE         19800021
****     LOCATION TO THE OUTPUT BUFFER.                                 19900021
****                                                                    20000021
         LA    RMOVE,BUFENTRY           INIT MOVE POINTER TO THE FIRST  20100021
*                                       ENTRY IN THE INPUT BUFFER       20200021
         LR    R15,RWORK2               CALCULATE SIZE OF ENTRIES PRE-  20300021
         SR    R15,RMOVE                CEDING THE ADD LOCATION         20400021
         DROP  RIBFR                    DROP INPUT BFR BASE REG         20500021
         USING BUFFER,ROBFR             ESTABLISH OUTPUT BFR BASE REG   20600021
         LA    RFILL,BUFENTRY           INIT FILL PTR WITHIN OUTPUT BFR 20700021
         MVC   BUFCNT,BUFCNT-BUFFER(RIBFR)  MOVE COUNT FIELD TO         20800021
*                                       OUTPUT BUFFER                   20900021
         LA    RSPACE,L'BUFENTRY        INIT UNUSED SPACE IN OUTPUT BFR 21000021
         BAL   R14,MOVEMANY             MOVE ENTRIES TO OUTPUT BFR      21100021
         DROP  ROBFR                    DROP OUTPUT BFR BASE REG        21200021
         SPACE 2                                                        21300021
****                                                                    21400021
****     DETERMINE THE FUNCTION TO BE PERFORMED.                        21500021
****                                                                    21600021
         TM    STWFLAG1,STWADD+STWREPL+STWCHNG   IS FUNCTION DELETE     21700021
         BZ    DELETE                   YES, GO DO DELETE               21800021
         CLI   DCBDIRCT+1,NOTLAST       ARE THERE ANY ENTRIES IN THE    21900021
*                                       LAST DIRECTORY BLOCK            22000021
         BE    ADDCHECK                 NO, NO NEED FOR A DRY RUN       22100021
         XI    STWFLAG1,STWDRYRN        SET DRY RUN SWITCH              22200021
         SPACE                                                          22300021
ADDCHECK EQU   *                                                        22400021
         TM    STWFLAG1,STWADD+STWREPL  IS FUNCTION ADD, ADD-DELETE     22500021
*                                       CHANGE, OR REPLACE              22600021
         BZ    DELETE                   NO, GO DO DELETE-ADD CHANGE     22700021
         SPACE 2                                                        22800021
****                                                                    22900021
****     PERFORM INITIALIZATION FOR ADD, ADD-DELETE CHANGE, AND REPLACE 23000021
****     FUNCTIONS.  ALSO DETERMINE WHETHER THE ENTRY TO BE ADDED WILL  23100021
****     FIT IN THE FIRST OUTPUT BLOCK.                                 23200021
****                                                                    23300021
         TM    STWFLAG1,STWREPL         IS FUNCTION REPLACE             23400021
         BNO   FITCHK                   NO, GO CHECK NEW ENTRY FIT      23500021
         BAL   R13,CALCSIZE             GO CALC SIZE OF REPLACED ENTRY  23600021
         SR    REMAIN,RSIZE             DECR AMOUNT IN INPUT BUFFER     23700021
         LA    RWORK2,0(RSIZE,RWORK2)   INCR REMAINING ENTRIES POINTER  23800021
*                                       PAST ENTRY BEING REPLACED       23900021
         SPACE                                                          24000021
FITCHK   EQU   *                                                        24100021
         LA    RMOVE,STWNEWNM           POINT TO ENTRY TO BE ADDED      24200021
         BAL   R13,CALCSIZE             GO CALC SIZE OF NEW ENTRY       24300021
         LA    REMAIN,0(RSIZE,REMAIN)   ADD NEW ENTRY SIZE TO AMOUNT    24400021
*                                       OF DATA IN THE INPUT BUFFER     24500021
         TM    STWFLAG1,STWCHNG+STWDEL  IS FUNCTION DELETE-ADD CHANGE   24600021
         BO    ADD                      YES, BYPASS DRY RUN AND FIT CHK 24700021
         TM    STWFLAG1,STWDRYRN        IS THIS A DRY RUN               24800021
         BNO   ADD                      NO, GO TO ADD NEW ENTRY         24900021
         CR    REMAIN,RSPACE            CAN NEW ENTRY BE ADDED TO FIRST 25000021
*                                       INPUT BLOCK                     25100021
         BH    ADD                      NO, GO TO BEGIN MOVING DATA     25200021
         NI    STWFLAG1,OFF-STWDRYRN    TURN OFF DRY RUN SWITCH         25300021
         SPACE 2                                                        25400021
****                                                                    25500021
****     IF SPACE IS AVAILABLE, MOVE THE ENTRY TO BE ADDED INTO THE     25600021
****     CURRENT OUTPUT BUFFER.  OTHERWISE, WRITE THE OUTPUT BUFFER,    25700021
****     READ IN ANOTHER BLOCK, AND CONSTRUCT A NEW OUTPUT BUFFER AND   25800021
****     MOVE THE ENTRY TO BE ADDED INTO IT.                            25900021
****                                                                    26000021
ADD      EQU   *                                                        26100021
         LR    R15,RSIZE                AMOUNT OF DATA TO BE MOVED      26200021
         BAL   R14,MOVEONE              MOVE NEW ENTRY TO OUTPUT BFR    26300021
         LTR   R15,R15                  WAS MOVE SUCCESSFUL             26400021
         BZ    MOVEREST                 YES, CONT FILLING OUTPUT BFR    26500021
         TM    IOBCSW+3,UNITEXPT        DID UNIT EXCEPTION OCCUR FOR    26600021
*                                       LAST READ ISSUED                26700021
         BO    NOTROOM                  YES, IND NO ROOM IN DIRECTORY   26800021
         BAL   R14,WR1RD1               GO WRITE OUTPUT BFR AND READ    26900021
*                                       ANOTHER BLOCK INTO IT           27000021
         USING BUFFER,ROBFR             ESTABLISH OUTPUT BFR BASE REG   27100021
         L     RWORK1,BUFADDR           GET ADDR OF NEXT BLOCK READ     27200021
         MVC   BUFCNT,BUFCNT-BUFFER(RWORK1)  SET UP COUNT FIELD FOR     27300021
*                                       NEXT WRITE                      27400021
         B     ADD                      MOVE NEW ENTRY INTO OUTPUT BFR  27500021
         SPACE 2                                                        27600021
****                                                                    27700021
****     MOVE THE ENTRIES REMAINING IN THE INPUT BUFFER, WHICH FOLLOW   27800021
****     THE ADD OR REPLACE LOCATION, TO THE OUTPUT BUFFER.             27900021
****                                                                    28000021
MOVEREST EQU   *                                                        28100021
         LR    RMOVE,RWORK2             RESTORE MOVE POINTER TO ENTRIES 28200021
*                                       FOLLOWING THE ADD OR REPL LOC   28300021
         B     EXPAND                   BR TO COMPLETE DIRECTORY        28400021
         SPACE 2                                                        28500021
****                                                                    28600021
****     EXPAND THE DIRECTORY TO COMPENSATE FOR THE ENTRY JUST ADDED.   28700021
****                                                                    28800021
BYPASS   EQU   *                                                        28900021
         LA    RMOVE,0(RSIZE,RMOVE)     INCR MOVE PTR PAST ENTRY TO BE  29000021
*                                       DELETED FOR ADD-DELETE CHANGE   29100021
         SR    REMAIN,RSIZE             DECR DATA REMAINING BY DELETED  29200021
*                                       ENTRY SIZE                      29300021
         OI    STWFLAG1,STWFLOW         IND CHANGE SWITCH PERFORMED     29400021
         SPACE                                                          29500021
EXPAND   EQU   *                                                        29600021
         LTR   REMAIN,REMAIN            ANY MORE ENTRIES IN INPUT BFR   29700021
         BZ    ADDENDCK                 NO, GO CHK IF BOTH BFRS HAVE    29800021
*                                       BEEN PROCESSED                  29900021
         BAL   R13,CALCSIZE             GET SIZE OF NEXT ENTRY          30000021
CHKDELET EQU   *                                                XA02065 30050003
         TM    STWFLAG1,STWCHNG+STWADD  IS FUNCTION ADD-DELETE CHANGE   30100021
         BNO   MOVENTRY                 NO, GO TO MOVE ENTRY            30200021
         USING ENTRY,RMOVE              ESTABLISH ENTRY BASE REGISTER   30300021
         CLC   ENTNAME,STWOLDNM         IS THIS ENTRY TO BE DELETED     30400021
         BE    BYPASS                   YES, GO TO GET NEXT ENTRY       30500021
         DROP  RMOVE                    DROP ENTRY BASE REGISTER        30600021
         SPACE                                                          30700021
MOVENTRY EQU   *                                                        30800021
         LR    R15,RSIZE                SIZE OF ENTRY TO BE MOVED       30900021
         BAL   R14,MOVEONE              GO MOVE ENTRY INTO OUTPUT BFR   31000021
         LTR   R15,R15                  WAS MOVE SUCCESSFUL             31100021
         BZ    EXPAND                   YES, GO GET NEXT ENTRY          31200021
         SPACE 2                                                        31300021
****                                                                    31400021
****     WRITE COMPLETED OUTPUT BUFFER AND READ IN ANOTHER DIRECTORY    31500021
****     BLOCK.                                                         31600021
****                                                                    31700021
         TM    IOBCSW+3,UNITEXPT        DID UNIT EXCEPTION OCCUR FOR    31800021
*                                       LAST READ ISSUED                31900021
         BO    NOTROOM                  YES, IND NO ROOM IN DIRECTORY   32000021
         SPACE                                                          32100021
CONTADD  EQU   *                                                        32200021
         BAL   R14,WR1RD1               GO TO WRITE/READ ROUTINE        32300021
         L     RWORK1,BUFADDR           GET ADDR OF NEXT BLOCK READ     32400021
         MVC   BUFCNT,BUFCNT-BUFFER(RWORK1)  SET UP COUNT FIELD FOR     32500021
*                                       NEXT WRITE                      32600021
         B     CHKDELET                 CHECK TO DELETE ENTRY   XA02065 32700003
         SPACE 2                                                        32800021
****                                                                    32900021
****     DETERMINE IF THE NEXT TO THE LAST BLOCK READ HAS BEEN          33000021
****     PROCESSED.                                                     33100021
****                                                                    33200021
ADDENDCK EQU   *                                                        33300021
         CLC   BUFKEY,HIGHKEY           HAS LAST ENTRY BEEN PROCESSED   33400021
         BNE   BFRCHECK                 NO, GO TO CHECK INPUT BFRS      33500021
         TM    STWFLAG1,STWDRYRN        IS THIS A DRY RUN               33600021
         BO    INITBFRS                 YES, GO TO END DRY RUN          33700021
         B     UPDTEDCB                 GO TO UPDATE DCBDIRCT FIELD     33800021
         SPACE                                                          33900021
BFRCHECK EQU   *                                                        34000021
         LR    RWORK1,RIBFR             SAVE PTR FOR LATER COMPARISON   34100021
         DROP  ROBFR                    DROP OUTPUT BUFFER BASE REG     34200021
         USING BUFFER,RIBFR             ESTABLISH INPUT BUFFER BASE REG 34300021
         L     RIBFR,BUFADDR            GET ADDR OF NEXT BLOCK READ     34400021
         LH    REMAIN,BUFN              GET USED SPACE IN INPUT BLOCK   34500021
         SH    REMAIN,COUNTSZ           CALCULATE SIZE OF ENTRIES       34600021
         LA    RMOVE,BUFENTRY           INIT MOVE PTR TO FIRST ENTRY    34700021
         CR    RWORK1,ROBFR             HAS NEXT TO LAST BLOCK READ     34800021
*                                       BEEN PROCESSED                  34900021
         BE    EXPAND                   NO, CONT EXPANDING DIRECTORY    35000021
         SPACE 2                                                        35100021
****                                                                    35200021
****     IF THIS IS A DRY RUN, RETURN TO THE BEGINNING OF THE PROGRAM   35300021
****     TO MAKE THE ALTERATION RUN ON THE DIRECTORY.                   35400021
****                                                                    35500021
         TM    STWFLAG1,STWDRYRN        IS THIS A DRY RUN               35600021
         BO    INITBFRS                 YES, GO TO END DRY RUN          35700021
         SPACE 2                                                        35800021
****                                                                    35900021
****     DETERMINE IF THE DELETE FUNCTION REMAINS TO BE PERFORMED FOR   36000021
****     ADD-DELETE CHANGE.                                             36100021
****                                                                    36200021
DELETECK EQU   *                                                        36300021
         TM    STWFLAG1,STWCHNG+STWADD  IS FUNCT ADD-DELETE CHANGE      36400021
         BNO   SWTODEL                  NO, GO CHK FOR SWITCH TO DELETE 36500021
         BAL   R13,CALCSIZE             CALC SIZE OF FIRST ENTRY IN BFR 36600021
         TM    STWFLAG1,STWFLOW         HAS BLOCK WITH ENTRY TO BE      36700021
*                                       DELETED BEEN PROCESSED          36800021
         BNO   CONTADD                  NO, CONT READING AND WRITING    36900021
*                                       UNTIL BLOCK IS FOUND            37000021
         SPACE 2                                                        37100021
****                                                                    37200021
****     IF THE FUNCTION BEING PERFORMED IS CHANGE OR REPLACE, GO TO    37300021
****     THE DELETE ROUTINE TO ENSURE THAT THE DIRECTORY HAS BEEN       37400021
****     COMPRESSED.                                                    37500021
****                                                                    37600021
SWTODEL  EQU   *                                                        37700021
         TM    STWFLAG1,STWCHNG+STWREPL IS FUNCT CHANGE OR REPLACE      37800021
         BNZ   COMPRESS                 YES, GO TO COMPRESS DIRECTORY   37900021
         B     WRLAST                   NO, GO TO WRITE LAST BLOCK      38000021
         SPACE 2                                                        38100021
****                                                                    38200021
****     DELETE THE DIRECTORY ENTRY FOR THE FUNCTIONS OF DELETE OR      38300021
****     ADD-DELETE CHANGE.                                             38400021
****                                                                    38500021
DELETE   EQU   *                                                        38600021
         BAL   R13,CALCSIZE             CALC SIZE OF ENTRY TO BE        38700021
*                                       DELETED                         38800021
         SR    REMAIN,RSIZE             DECR DATA SIZE BY DELETED ENTRY 38900021
         LA    RMOVE,0(RSIZE,RMOVE)     INCR NEXT ENTRY PTR PAST ENTRY  39000021
         SPACE 2                                                        39100021
****                                                                    39200021
****     COMPRESS THE REMAINING ENTRIES IN THE DIRECTORY TO COMPENSATE  39300021
****     FOR THE SPACE LEFT BY THE DELETED ENTRY.                       39400021
****                                                                    39500021
COMPRESS EQU   *                                                        39600021
         LTR   REMAIN,REMAIN            ANY MORE ENTRIES IN INPUT BFR   39700021
         BZ    DELENDCK                 NO, GO TO CHK FOR LAST ENTRY    39800021
         TM    STWFLAG1,STWCHNG+STWDEL  IS FUNCT DELETE-ADD CHANGE      39900021
         BNO   COMPMOVE                 NO, CONT COMPRESSING DIRECTORY  40000021
         TM    STWFLAG1,STWFLOW         HAS CHANGE SW BEEN PERFORMED    40100021
         BO    COMPMOVE                 YES, CONT COMPRESSING DIRECTORY 40200021
         USING ENTRY,RMOVE              ESTABLISH ENTRY BASE REGISTER   40300021
         CLC   ENTNAME,STWNEWNM         IS THIS THE LOCATION FOR THE    40400021
*                                       NEW ENTRY                       40500021
         BH    SWTOADD                  YES, GO TO SWITCH TO ADD MODE   40600021
         DROP  RMOVE                    DROP ENTRY BASE REGISTER        40700021
         SPACE                                                          40800021
COMPMOVE EQU   *                                                        40900021
         BAL   R13,CALCSIZE             GET SIZE OF NEXT ENTRY          41000021
         LR    R15,RSIZE                SIZE OF ENTRY TO BE MOVED       41100021
         BAL   R14,MOVEONE              GO MOVE ENTRY INTO OUTPUT BFR   41200021
         LTR   R15,R15                  WAS MOVE SUCCESSFUL             41300021
         BZ    COMPRESS                 YES, GO GET NEXT ENTRY          41400021
         LA    RWORK1,L'BUFN(,REMAIN)   INCR SIZE OF ENTRIES LEFT IN    41500021
*                                       INPUT BFR BY SIZE FIELD LENGTH  41600021
         CH    RWORK1,BUFN              HAVE ANY ENTRIES BEEN MOVED     41700021
*                                       FROM THE INPUT BFR              41800021
         BNE   CONTCOMP                 YES, CONTINUE COMPRESSING       41900021
         TM    STWFLAG1,STWCHNG+STWDEL  IS FUNCT DELETE-ADD CHANGE      42000021
         BNO   WRLAST                   NO, GO TO WRITE OUT LAST BLOCK  42100021
*                                       PROCESSED                       42200021
         TM    STWFLAG1,STWFLOW         HAS CHANGE SW BEEN PERFORMED    42300021
         BO    WRLAST                   YES, GO TO WRITE OUT LAST BLOCK 42400021
*                                       PROCESSED                       42500021
         SPACE 2                                                        42600021
****                                                                    42700021
****     WRITE COMPLETED OUTPUT BUFFER AND READ IN ANOTHER DIRECTORY    42800021
****     BLOCK.                                                         42900021
****                                                                    43000021
CONTCOMP EQU   *                                                        43100021
         BAL   R14,WR1RD1               GO TO WRITE/READ ROUTINE        43200021
         DROP  RIBFR                    DROP INPUT BFR BASE REGISTER    43300021
         USING BUFFER,ROBFR             ESTABLISH OUTPUT BFR BASE REG   43400021
         MVC   BUFCNT,BUFCNT-BUFFER(RIBFR)  MOVE COUNT FIELD TO OUTPUT  43500021
*                                       BUFFER                          43600021
         B     COMPMOVE                 CONT COMPRESSING DIRECTORY      43700021
         SPACE 2                                                        43800021
****                                                                    43900021
****     DETERMINE IF THE LAST DIRECTORY ENTRY HAS BEEN PROCESSED.  IF  44000021
****     SO, GO TO UPDATE THE DCBDIRCT FIELD.  OTHERWISE, CONTINUE      44100021
****     COMPRESSING THE DIRECTORY.                                     44200021
****                                                                    44300021
DELENDCK EQU   *                                                        44400021
         CLC   BUFKEY,HIGHKEY           HAS LAST ENTRY BEEN PROCESSED   44500021
         BE    UPDTEDCB                 YES, GO TO UPDATE DCBDIRCT FLD  44600021
         DROP  ROBFR                    DROP OUTPUT BFR BASE REGISTER   44700021
         USING BUFFER,RIBFR             ESTABLISH INPUT BFR BASE REG    44800021
         L     RIBFR,BUFADDR            GET ADDR OF NEXT INPUT BFR      44900021
         CR    RIBFR,ROBFR              INPUT AND OUTPUT BUFFER OX00801 44902002
*                                       POINTERS THE SAME       OX00801 44904402
         BNE   BYWRTBLK                 IF NOT, BRANCH AROUND   OX00801 44906002
         BAL   R14,WR1RD1               GO TO READ/WRITE RTN    OX00801 44916002
         L     RIBFR,BUFADDR            GET ADDR OF NEXT BUFFER OX00801 44918002
         L     RIBFR,BUFADDR            GET ADDR OF NEXT BUFFER OX00801 44920002
         DROP  RIBFR                    DROP INPUT BUFFER BASE  OX00801 44922002
         USING BUFFER,ROBFR             EST. OUTPUT BFR BASE    OX00801 44932002
         MVC   BUFCNT,BUFCNT-BUFFER(RIBFR) MOVE COUNT FIELD TO  OX00801 44934002
*                                       OUTPUT BUFFER           OX00801 44936002
         DROP  ROBFR                    DROP OUTPUT BFR BASE    OX00801 44946002
         USING BUFFER,RIBFR             EST. INPUT BUFFER BASE  OX00801 44956002
         L     RIBFR,BUFADDR            POINT TO INIT. BUFFER   OX00801 44958002
BYWRTBLK EQU   *                                                OX00801 44968002
         LH    REMAIN,BUFN              GET USED SPACE IN INPUT BLOCK   45000021
         SH    REMAIN,COUNTSZ           CALCULATE SIZE OF ENTRIES       45100021
         LA    RMOVE,BUFENTRY           INIT MOVE PTR TO FIRST ENTRY    45200021
         B     COMPRESS                 CONT COMPRESSING DIRECTORY      45300021
         DROP  RIBFR                    DROP INPUT BFR BASE REGISTER    45400021
         SPACE 2                                                        45500021
****                                                                    45600021
****     GO TO THE ADD ROUTINE TO ADD THE NEW ENTRY FOR THE DELETE-ADD  45700021
****     CHANGE FUNCTION.                                               45800021
****                                                                    45900021
SWTOADD  EQU   *                                                        46000021
         OI    STWFLAG1,STWFLOW         IND CHANGE SWITCH HAS BEEN      46100021
*                                       PERFORMED                       46200021
         LR    RWORK2,RMOVE             INIT MOVE PTR FOR ADD ROUTINE   46300021
         B     FITCHK                   GO TO ADD NEW ENTRY             46400021
         SPACE 2                                                        46500021
****                                                                    46600021
****     IF UNIT EXCEPTION OCCURED WHILE ATTEMPTING TO READ ANOTHER     46700021
****     BLOCK, WHICH IS REQUIRED TO EXPAND THE DIRECTORY, RETURN TO    46800021
****     THE USER WITH A 'NO ROOM' ERROR CODE.                          46900021
****                                                                    47000021
NOTROOM  EQU   *                                                        47100021
         LA    R9,NOROOM                SET NO ROOM ERROR CODE   YM0943 47200001
         B     ERROR                    GO TO RETURN ROUTINE            47300021
         SPACE 2                                                        47400021
****                                                                    47500021
****     IF THE LAST BLOCK OF THE DIRECTORY WAS USED, STORE INTO THE    47600021
****     DCBDIRCT FIELD ONE LESS THAN THE NUMBER OF BYTES USED IN THE   47700021
****     BLOCK.  OTHERWISE, SET THE DCBDIRCT FIELD TO ZEROS.            47800021
****                                                                    47900021
UPDTEDCB EQU   *                                                        48000021
         SR    RWORK1,RWORK1            INIT REG TO IND NOT LAST BLOCK  48100021
         TM    IOBCSW+3,UNITEXPT        DID UNIT EXCEPTION OCCUR ON     48200021
*                                       LAST BLOCK READ                 48300021
         BNO   STDIRCT                  NO, GO TO STORE NOT LAST INDR   48400021
         LA    RWORK1,L'BUFDATA-1       GET BUFFER DATA LENGTH MINUS 1  48500021
         SR    RWORK1,RSPACE            CALC ONE LESS THAN USED SPACE   48600021
         SPACE                                                          48700021
STDIRCT  EQU   *                                                        48800021
         STC   RWORK1,DCBDIRCT+1        UPDATE DCBDIRCT FIELD           48900021
         SPACE 2                                                        49000021
****                                                                    49100021
****     WRITE THE LAST DIRECTORY BLOCK PROCESSED.                      49200021
****                                                                    49300021
WRLAST   EQU   *                                                        49400021
         NI    STWWFLG2,OFF-STWCMDCH    SUPPRESS THE READ OPERATIONS    49500021
         BAL   R14,WR1RD1               GO TO WRITE LAST BLOCK          49600021
         OI    DCBCIND2,STOWPERF        INDICATE STOW PERFORMED  M1088  49650021
         SPACE 2                                                        49700021
****                                                                    49800021
****     PUT THE RETURN CODE IN REGISTER 15, FREE THE GOTTEN CORE, AND  49900021
****     RETURN TO THE USER.                                            50000021
****                                                                    50100021
         SR    R9,R9                    CLEAR REGISTER           YM0943 50200001
         IC    R9,STWRTN                GET RETURN CODE SAVED BY YM0943 50300001
*                                       THE FIRST LOAD           YM0943 50400001
         SPACE                                                          50500021
ERROR    EQU   *                                                        50600021
         AIF   ('&LIB' EQ 'LIB1').NSVS1                                 50610021
         TM    STWFLAG1,VRFIX          PAGE FREE REQUIRED?      XA01664 50612003
         BNO   NOPGFREE                BRANCH IF NOT            XA01664 50614003
         L     R1,STWPARM              STARTING ADDR            XA01664 50616003
         LA    R2,VRRQST(R1)           ENDING ADDR              XA01664 50618003
         TM    STWFLAG1,STWCHNG+STWADD CHANGE REQUEST?          XA01664 50618403
         BNO   PGREL                   BRANCH IF NOT            XA01664 50618803
         L     R1,STWHIGH              STARTING ADDR            XA01664 50629603
         LA    R2,VRRQST(R1)           ENDING ADDR              XA01664 50639603
PGREL    EQU   *                                                XA01664 50649603
         PGRLSE  LA=(1),HA=(2)                                  XA01664 50649703
NOPGFREE EQU   *                                                XA01664 50649803
.NSVS1   ANOP                                                           50649902
         LH    R0,STWGMSZ               SIZE OF GOTTEN AREA             50700021
         LR    R1,RAREA                 ADDRESS OF GOTTEN AREA          50800021
         FREEMAIN  R,LV=(0),A=(1)       FREE GOTTEN AREA                50900021
         LR    R15,R9                   GET THE RETURN CODE      YM0943 50950001
         SVC   EXIT                     RETURN TO USER                  51000021
         EJECT                                                          51100021
*********************************************************************** 51200021
****                                                               **** 51300021
****     THIS SUBROUTINE IS USED TO COMPLETE THE OUTPUT BUFFER,    **** 51400021
****     SET UP THE CHANNEL PROGRAM TO WRITE THE OUTPUT BUFFER AND **** 51500021
****     READ ANOTHER DIRECTORY BLOCK INTO THE SAME BUFFER, AND    **** 51600021
****     INITIALIZE A NEW OUTPUT BUFFER.                           **** 51700021
****                                                               **** 51800021
****     INPUT REGISTERS -                                         **** 51900021
****           RIBFR  - ADDRESS OF THE INPUT BUFFER                **** 52000021
****           ROBFR  - ADDRESS OF THE OUTPUT BUFFER               **** 52100021
****           RSPACE - UNUSED SPACE IN THE OUTPUT BUFFER          **** 52200021
****           R14    - RETURN ADDRESS                             **** 52300021
****                                                               **** 52400021
****     OUTPUT REGISTERS -                                        **** 52500021
****           RIBFR  - SAME AS ENTRY                              **** 52600021
****           ROBFR  - ADDRESS OF NEW OUTPUT BUFFER               **** 52700021
****           RSPACE - INITIALIZED TO BUFFER ENTRY AREA SIZE      **** 52800021
****           RFILL  - ADDRESS OF OUTPUT BUFFER ENTRY AREA        **** 52900021
****                                                               **** 53000021
*********************************************************************** 53100021
WR1RD1   EQU   *                                                        53200021
         LA    RWORK1,L'BUFDATA         GET SIZE OF BUFFER DATA AREA    53300021
         SR    RWORK1,RSPACE            CALC USED SPACE IN OUTPUT BFR   53400021
         USING BUFFER,ROBFR             ESTABLISH OUTPUT BFR BASE REG   53500021
         STH   RWORK1,BUFN              PUT USED SPACE INTO OUTPUT BFR  53600021
         ST    ROBFR,STWIDAD2-1         SET UP SEARCH ID ADDRESS        53700021
         MVI   STWSRCH2,STWIDEQ         RESTORE SEARCH ID EQUAL COMMAND 53800021
         LA    RWORK1,STWBUF4           POINT TO INPUT BUFFER   SA66881 53850021
         ST    RWORK1,STWRDAD3-1        SET UP C/K/D ADDRESS    SA66881 53900021
         MVI   STWRCKD3,STWRDCKD        RESTORE READ C/K/D COMMAND      54000021
         LA    RWORK1,BUFKEY            GET ADDRESS OF KEY AREA         54100021
         ST    RWORK1,STWWRAD2-1        SET UP WRITE KEY/DATA ADDRESS   54200021
         MVI   STWWRKD1,STWWRKD         RESTORE WRITE KEY/DATA COMMAND  54300021
         TM    STWFLAG1,STWDRYRN        IS THIS A DRY RUN               54400021
         BNO   GOTOEXCP                 NO, GO TO ISSUE EXCP            54500021
         MVI   STWWRKD1,STWRDKD         REPLACE WRITE COMMAND WITH A    54600021
*                                       READ IN ORDER TO SUPPRESS DATA  54700021
*                                       TRANSFER FOR THE WRITE CCW      54800021
         SPACE                                                          54900021
GOTOEXCP EQU   *                                                        55000021
         MVC   IOBCC(5),0(ROBFR)        SET UP CCHHR OF IOBSEEK FIELD   55100021
         BAL   R13,EXCP                 GO ISSUE EXCP                   55200021
         MVC   0(L'BUFCNT+L'BUFKEY,ROBFR),STWBUF4 MOVE C/K FLDS SA66881 55250021
         MVC   16(L'BUFDATA,ROBFR),STWBUF4+16 MOVE DIR.BLOCK    SA66881 55260021
* THE COUNT/KEY/DATA FIELDS ARE NOT READ DIRECTLY INTO THE      SA66881 55270021
* BUFFER WHICH WAS JUST WRITTEN OUT. DOING SO COULD PREVENT     SA66881 55280021
* SUCCESSFUL ERROR RESTART OF THE CHANNEL PROGRAM               SA66881 55290021
         L     ROBFR,BUFADDR            INIT OUTPUT BFR POINTER         55300021
         LA    RFILL,BUFENTRY           INIT FILL POINTER               55400021
         LA    RSPACE,L'BUFENTRY        INIT UNUSED SPACE IN OUTPUT BFR 55500021
         DROP  ROBFR                    DROP OUTPUT BFR BASE REG        55600021
         BR    R14                      RETURN TO CALLER                55700021
         EJECT                                                          55800021
*********************************************************************** 55900021
****                                                               **** 56000021
****     THIS SUBROUTINE IS USED TO MOVE AN ENTRY OR ENTRIES FROM  **** 56100021
****     THE INPUT BUFFER TO THE OUTPUT BUFFER AND UPDATE THE KEY  **** 56200021
****     FIELD OF THE OUTPUT BUFFER FOLLOWING EACH MOVE.  THERE    **** 56300021
****     ARE TWO ENTRY POINTS TO THIS SUBROUTINE.  THE FIRST IS    **** 56400021
****     USED TO MOVE ONE OR MORE ENTRIES OF UNKNOWN SIZE AND THE  **** 56500021
****     SECOND TO MOVE ONE ENTRY OF KNOWN SIZE.                   **** 56600021
****                                                               **** 56700021
****     INPUT REGISTERS -                                         **** 56800021
****           RMOVE  - ADDRESS DATA IS TO BE MOVED FROM           **** 56900021
****           RFILL  - ADDRESS DATA IS TO BE MOVED TO             **** 57000021
****           RSIZE  - SIZE OF ENTRY (SECOND ENTRY ONLY)          **** 57100021
****           REMAIN - AMOUNT OF DATA REMAINING IN INPUT BUFFER   **** 57200021
****           RSPACE - AMOUNT OF UNUSED SPACE IN OUTPUT BUFFER    **** 57300021
****           ROBFR  - ADDRESS OF OUTPUT BUFFER                   **** 57400021
****           R15    - AMOUNT OF DATA TO BE MOVED (EQUAL TO RSIZE **** 57500021
****                    FOR SECOND ENTRY)                          **** 57600021
****           R14    - RETURN ADDRESS                             **** 57700021
****                                                               **** 57800021
****     OUTPUT REGISTERS -                                        **** 57900021
****           RMOVE  - INCREMENTED BY AMOUNT OF DATA MOVED        **** 58000021
****           RFILL  - INCREMENTED BY AMOUNT OF DATA MOVED        **** 58100021
****           RSIZE  - AMOUNT OF DATA REMAINING TO BE MOVED       **** 58200021
****           REMAIN - AMOUNT OF DATA REMAINING IN INPUT BUFFER   **** 58300021
****           RSPACE - AMOUNT OF UNUSED SPACE IN OUTPUT BUFFER    **** 58400021
****           ROBFR  - SAME AS INPUT                              **** 58500021
****           R15    - AMOUNT OF DATA UNABLE TO MOVE              **** 58600021
****                                                               **** 58700021
*********************************************************************** 58800021
MOVEMANY EQU   *                                                        58900021
         LTR   R15,R15                  HAS ALL DATA BEEN MOVED         59000021
         BCR   ZEROS,R14                YES, RETURN TO CALLER           59100021
         BAL   R13,CALCSIZE             GO GET SIZE OF NEXT ENTRY       59200021
         SPACE                                                          59300021
MOVEONE  EQU   *                                                        59400021
         CR    RSPACE,RSIZE             WILL ENTRY FIT IN OUTPUT BFR    59500021
         BCR   LOW,R14                  NO, RETURN TO CALLER            59600021
         SR    R15,RSIZE                CALC AMOUNT LEFT TO BE MOVED    59700021
         SR    REMAIN,RSIZE             DECR DATA LEFT IN INPUT BFR     59800021
         SR    RSPACE,RSIZE             DECR UNUSED SPACE IN OUTPUT BFR 59900021
         USING BUFFER,ROBFR             ESTABLISH OUTPUT BFR BASE REG   60000021
         USING ENTRY,RMOVE              ESTABLISH ENTRY BASE REG        60100021
         MVC   BUFKEY,ENTNAME           UPDATE OUTPUT BFR KEY FIELD     60200021
         DROP  ROBFR,RMOVE              DROP BASE REGISTERS             60300021
         BCTR  RSIZE,R0                 DECR REG FOR CORRECT MOVE LNTH  60400021
         EX    RSIZE,MOVEIT             MOVE ENTRY TO OUTPUT BFR        60500021
         LA    RMOVE,1(RSIZE,RMOVE)     INCR MOVE PTR PAST MOVED ENTRY  60600021
         LA    RFILL,1(RSIZE,RFILL)     INCR FILL PTR PAST MOVED ENTRY  60700021
         B     MOVEMANY                 CONTINUE MOVING ENTRIES         60800021
         SPACE                                                          60900021
MOVEIT   EQU   *                                                        61000021
         MVC   0(0,RFILL),0(RMOVE)      MOVE FOR EXECUTE INSTRUCTION    61100021
         SPACE 2                                                        61200021
*********************************************************************** 61300021
****                                                               **** 61400021
****     THIS SUBROUTINE IS USED TO CALCULATE THE SIZE OF A        **** 61500021
****     DIRECTORY ENTRY AND RETURN IT IN REGISTER R15.            **** 61600021
****                                                               **** 61700021
****     INPUT REGISTERS -                                         **** 61800021
****           RMOVE - ADDR OF ENTRY WHOSE SIZE IS TO BE CALCULATED**** 61900021
****           R13   - RETURN ADDRESS                              **** 62000021
****                                                               **** 62100021
****     OUTPUT REGISTERS -                                        **** 62200021
****           RMOVE - SAME AS INPUT                               **** 62300021
****           RSIZE - SIZE OF ENTRY                               **** 62400021
****                                                               **** 62500021
*********************************************************************** 62600021
CALCSIZE EQU   *                                                        62700021
         USING ENTRY,RMOVE              ESTABLISH ENTRY BASE REGISTER   62800021
         IC    RSIZE,ENTCTTRN           GET USER DATA SIZE              62900021
         SLL   RSIZE,27                 SHIFT OFF ALAIS BIT AND NUMBER  63000021
*                                       OF TTRN'S                       63100021
         SRL   RSIZE,26                 REPOSITION DATA SIZE AND CON-   63200021
*                                       VERT HALFWORDS TO BYTES         63300021
         LA    RSIZE,ENTPREFX(,RSIZE)   CALCULATE TOTAL SIZE OF ENTRY   63400021
         DROP  RMOVE                    DROP ENTRY BASE REGISTER        63500021
         BR    R13                      RETURN TO USER                  63600021
         SPACE 2                                                        63700021
*********************************************************************** 63800021
****                                                               **** 63900021
****     THIS SUBROUTINE IS USED TO EXECUTE A CHANNEL PROGRAM AND  **** 64000021
****     CHECK THE STATUS FOLLOWING COMPLETION.                    **** 64100021
****                                                               **** 64200021
****     INPUT REGISTERS -                                         **** 64300021
****           R13 - RETURN ADDRESS                                **** 64400021
****                                                               **** 64500021
****     OUTPUT REGISTERS - NONE                                   **** 64600021
****                                                               **** 64700021
*********************************************************************** 64800021
EXCP     EQU   *                                                        64900021
         EXCP  IOBSTDRD                 EXECUTE CHANNEL PROGRAM         65000021
         WAIT  ECB=ECBCC                WAIT FOR I/O TO COMPLETE        65100021
         TM    ECBCC,ECBNORM            DID I/O COMPLETE NORMALLY       65200021
         BCR   ONES,R13                 YES, RETURN TO CALLER           65300021
         TM    IOBCSW+3,UNITEXPT        DID UNIT EXCEPTION OCCUR        65400021
         BCR   ONES,R13                 YES, RETURN TO CALLER           65500021
         LA    R9,IOERROR               IND AN I/O ERROR OCCURED YM0943 65600001
         B     ERROR                    GO TO RETURN TO USER            65700021
         EJECT                                                          65800021
*********************************************************************** 65900021
****                                                               **** 66000021
****     CONSTANTS                                                 **** 66100021
****                                                               **** 66200021
*********************************************************************** 66300021
         SPACE                                                          66400021
COUNTSZ  DC    Y(L'BUFN)                SIZE OF DIRECTORY BLOCK DATA    66500021
*                                       COUNT FIELD                     66600021
HIGHKEY  DC    8X'FF'                   KEY OF HIGHEST DIRECTORY ENTRY  66700021
         ORG   IGG021AB+1024            FORCE MODULE LENGTH TO 1024     66800021
         EJECT                                                          66900021
STWAREA  DSECT                                                          67000021
         SPACE 2                                                        67100021
*********************************************************************** 67200021
****                                                               **** 67300021
****     THIS DSECT MAPS THE WORK AREA USED BY THE STOW MODULES    **** 67400021
****                                                               **** 67500021
*********************************************************************** 67600021
         SPACE 2                                                        67700021
****                                                                    67800021
****     XCTL AREA USED BY FIRST AND SECOND LOAD MODULES OF STOW        67900021
****                                                                    68000021
STWXAREA DS    0CL32                    XCTL AREA                       68100021
STWXNAME DS    0CL8                     MODULE NAME                     68200021
STWXCOMN DS    CL6                      COMMON PORTION OF MODULE NAME   68300021
STWXID   DS    CL2                      ID PORTION OF MODULE NAME       68400021
         DS    XL6                      UNUSED - MUST BE ZEROS          68500021
STWXTTR  DS    XL3                      TTR OF MODULE                   68600021
         DS    XL5                      UNUSED - MUST BE ZEROS          68700021
STWXATTB DS    XL2                      ATTRIBUTES OF ALL LOADS         68800021
STWXMODL DS    XL3                      MAIN STORAGE REQUIRED    XM5415 68900021
STWXTXTL DS    XL2                      LENGTH OF FIRST TEXT RCD XM5415 69000021
         DS    XL3                      UNUSED - MUST BE ZEROS          69100021
STWXPTR  DS    2A                       POINTER TO XCTL AREA AND DCB    69200021
*                                       (DCB PTR IS ZEROS FOR SVCLIB)   69300021
         SPACE 2                                                        69400021
****                                                                    69500021
****     POINTERS AND USER DATA SAVE AREA                               69600021
****                                                                    69700021
STWPARM  DS    A                        ADDR OF USER SUPPLIED ENTRY     69800021
*                                       NAME (LOWER OF 2 FOR CHANGE)    69900021
STWHIGH  DS    A                        ADDR OF HIGHER OF 2 USER SUPP-  70000021
*                                       LIED ENTRY NAMES (CHANGE ONLY)  70100021
STWDEBPT DS    A                        ADDR OF DEB IN WORK AREA        70200021
STWGMSZ  DS    H                        SIZE OF CORE GOTTEN FOR WORK    70300021
*                                       AREA                            70400021
STWOFFLW DS    H                        OFFSET TO ADD, REPLACE, OR      70500021
*                                       DELETE LOCATION IN LOW BLOCK    70600021
STWOLDNM DS    CL8                      NAME OF ENTRY BEING DELETED     70700021
STWNEWNM DS    CL8                      NAME OF NEW ENTRY               70800021
STWTTR   DS    AL3                      MEMBER'S RELATIVE ADDRESS       70900021
STWCTTRN DS    XL1                      ALIAS BIT, NUMBER OF TTRNS,     71000021
*                                       AND LENGTH OF USER DATA         71100021
STWALIAS EQU   X'80'                    THIS MEMBER NAME IS AN ALIAS    71200021
STWDATA  DS    CL62                     USER DATA FOR ENTRY             71300021
         SPACE 2                                                        71400021
****                                                                    71500021
****     FLAG, CONDITION, AND SWITCH BYTES                              71600021
****                                                                    71700021
STWFLAG1 DS    B                        FIRST FLAG BYTE                 71800021
*                       BIT DEFINITIONS                                 71900021
*        BIT   7                        RESERVED                        72000021
STWCHNG  EQU   X'80'                    CHANGE FUNCTION, USED IN COMBI- 72100021
*                                       NATION WITH STWADD AND STWDEL   72200021
STWDEL   EQU   X'40'                    DELETE FUNCTION                 72300021
STWREPL  EQU   X'20'                    REPLACE FUNCTION                72400021
STWADD   EQU   X'10'                    ADD FUNCTION                    72500021
STWDRYRN EQU   X'08'                    DRY RUN BEING MADE ON DIRECTORY 72600021
STWFLOW  EQU   X'04'                    USED TO CONTROL PROGRAM FLOW    72700021
STWDCBWR EQU   X'02'                    LAST DCB OPERATION WAS A WRITE  72800021
*                                                                       72900021
STWRTN   DS    CL1                      RETURN CODE SAVE AREA           73000021
*                                                                       73100021
STWFLGLN EQU   *-STWAREA                LENGTH OF SAVE AND FLAG AREAS   73200021
         EJECT                                                          73300021
****                                                                    73400021
****     CONTROL BLOCKS FOR STOW'S CHANNEL PROGRAMS                     73500021
****                                                                    73600021
         IHAECB  DSECT=NO                                               73700021
         ORG   *-16                     SET STANDARD IOB BEHIND ECB     73800021
         IEZIOB  DSECT=NO                                               73900021
         SPACE 2                                                        74000021
****                                                                    74100021
****     STOW'S CHANNEL PROGRAMS                                        74200021
****                                                                    74300021
         ORG   IOBR+1                   PLACE CHANNEL PROGRAMS          74400021
*                                       BEHIND THE IOB SEEK FIELD       74500021
STWINCP  DS    0D                       THIS CHANNEL PROGRAM READS THE  74600021
*                                       INITIAL TWO DIRECTORY BLOCKS    74700021
STWSRCH1 DS    2F                       SEARCH ID EQUAL                 74800021
STWTIC11 DS    2F                       TRANSFER CONTROL TO SEARCH ID   74900021
STWRDCT1 DS    2F                       READ COUNT                      75000021
STWSRKY1 DS    XL1                      SEARCH ON KEY EQUAL OR HIGH     75100021
STWKYAD1 DS    AL3                      KEY ADDRESS                     75200021
         DS    XL4                      FLAGS AND BYTE COUNT            75300021
STWTIC12 DS    2F                       TRANSFER CONTROL TO READ COUNT  75400021
STWRDAT1 DS    2F                       READ DATA                       75500021
STWRCKD1 DS    2F                       READ COUNT KEY DATA             75600021
         SPACE                                                          75700021
STWWRDCP DS    0D                       THIS CHANNEL PROGRAM WRITES     75800021
*                                       AND READS DIRECTORY BLOCKS      75900021
STWSRCH2 DS    XL1                      SEARCH ID EQUAL                 76000021
STWIDAD2 DS    AL3                      ID ADDRESS                      76100021
         DS    XL4                      FLAGS AND BYTE COUNT            76200021
STWTIC2  DS    2F                       TRANSFER CONTROL TO SEARCH ID   76300021
STWWRKD1 DS    XL1                      WRITE KEY AND DATA              76400021
STWWRAD2 DS    AL3                      WRITE ADDRESS                   76500021
STWWFLG2 DS    B                        FLAGS                           76600021
STWCMDCH EQU   X'40'                    COMMAND CHAIN TO NEXT CCW       76700021
         DS    XL3                      BYTE COUNT                      76800021
STWRCKD2 DS    XL1                      READ COUNT KEY DATA             76900021
STWRDAD2 DS    AL3                      READ ADDRESS                    77000021
         DS    XL4                      FLAGS AND BYTE COUNT            77100021
STWRCKD3 DS    XL1                      READ COUNT KEY DATA             77200021
STWRDAD3 DS    AL3                      READ ADDRESS                    77300021
         DS    XL4                      FLAGS AND BYTE COUNT            77400021
         SPACE 2                                                        77500021
****                                                                    77600021
****     COMMAND CODE EQUATES FOR CHANNEL PROGRAMS                      77700021
****                                                                    77800021
STWIDEQ  EQU   X'31'                    SEARCH ON IDENTIFIER EQUAL      77900021
STWWRKD  EQU   X'0D'                    WRITE KEY AND DATA              78000021
STWRDKD  EQU   X'8E'                    READ KEY AND DATA               78100021
STWRDCKD EQU   X'9E'                    READ COUNT, KEY, AND DATA       78200021
         SPACE 2                                                        78300021
****                                                                    78400021
****     STOW'S INPUT - OUTPUT BUFFERS.  FOR DETAILS SEE THE            78500021
****     BUFFER DSECT.                                                  78600021
****                                                                    78700021
STWBUF1  DS    0F                       INITIALLY CONTAINS THE FIRST    78800021
         DS    CL276                    OF TWO DIRECTORY BLOCKS READ    78900021
STWBUF2  DS    0F                       INITIALLY CONTAINS THE SECOND   79000021
         DS    CL276                    OF TWO DIRECTORY BLOCKS READ    79100021
STWBUF3  DS    0F                       INITIALLY USED AS THE FIRST     79200021
         DS    CL276                    OUTPUT BUFFER                   79300021
STWBUF4  DS    0F                       USED AS AN INPUT BUFFER SA66881 79350021
         DS    CL272                    IN LAST LOAD OF STOW    SA66881 79360021
STWDEB   DS    0F                       LOCATION OF COPIED DEB          79400021
STWEND   EQU   *                        END OF WORK AREA                79500021
CORESIZE EQU   STWEND-STWAREA           SIZE OF STOW'S WORK AREA        79600021
         EJECT                                                          79700021
BUFFER   DSECT                                                          79800021
         SPACE                                                          79900021
*********************************************************************** 80000021
****                                                               **** 80100021
****     THIS DSECT MAPS STOW'S INPUT - OUTPUT BUFFERS             **** 80200021
****                                                               **** 80300021
*********************************************************************** 80400021
         SPACE                                                          80500021
BUFCNT   DS    CL8                      COUNT FIELD CONTAINING          80600021
*                                       ABSOLUTE DISK ADDRESS           80700021
BUFKEY   DS    CL8                      KEY FIELD (HIGHEST MEMBER NAME) 80800021
BUFDATA  DS    0CL256                   DATA AREA                       80900021
BUFN     DS    H                        NUMBER OF BYTES USED IN         81000021
*                                       THIS DIRECTORY BLOCK            81100021
BUFENTRY DS    CL254                    DIRECTORY ENTRIES               81200021
BUFADDR  DS    A                        USED TO CHAIN THE BUFFERS       81300021
BUFPREFX EQU   L'BUFCNT+L'BUFKEY+L'BUFN  OFFSET TO BUFFER ENTRY AREA    81400021
         SPACE 4                                                        81500021
ENTRY    DSECT                                                          81600021
         SPACE                                                          81700021
*********************************************************************** 81800021
****                                                               **** 81900021
****     THIS DSECT MAPS A DIRECTORY ENTRY                         **** 82000021
****                                                               **** 82100021
*********************************************************************** 82200021
         SPACE                                                          82300021
ENTNAME  DS    CL8                      ENTRY NAME                      82400021
ENTTTR   DS    AL3                      MEMBER'S RELATIVE ADDRESS       82500021
ENTCTTRN DS    XL1                      ALAIS BIT, NUMBER OF TTRNS,     82600021
*                                       AND LENGTH OF USER DATA         82700021
ENTALAIS EQU   X'80'                    THIS MEMBER NAME IS AN ALAIS    82800021
ENTDATA  DS    CL62                     USER DATA FOR ENTRY             82900021
ENTPREFX EQU   L'ENTNAME+L'ENTTTR+L'ENTCTTRN  SIZE OF AREA PRECEDING    83000021
*                                       USER DATA AREA                  83100021
         EJECT                                                          83200021
         DCBD  DSORG=PO                                                 83300021
         EJECT                                                          83400021
         IEZDEB                                                         83500021
         END   IGG021AB                                                 83600021
