*                                                                       00003020
         COPY  LCGASMSW                                                 00006002
*                                                                       00009020
*                                                                       00015020
 TITLE ' IGG0325G - DADSM - DADSM RECORD UPDATE MODULE'                 00020000
IGG0325G CSECT                                                          00021021
*TITLE - DADSM RECORD UPDATE MODULE                                     00022021
*                                                                       00022402
*          VS1 RELEASE 2.6 DELETION/CHANGES                             00022802
*0000018100,068600                                               XM2969 00022902
*                                                                       00026002
*                                                                       00030402
*          RELEASE 17 DELETIONS                                         00033502
*0092000400,                                                          * 00036602
*          RELEASE 18 DELETIONS                                         00039702
*          RELEASE 19 DELETIONS                                         00042802
*          RELEASE 20 DELETIONS                                         00045902
*2412044000                                                      A37231 00049002
*          RELEASE 21 DELETIONS                                         00052102
*1199017400-017600,018000-018200,044800,087600,089000,092800     A37199 00055202
*1199000230,015600,024800-025400,087200,087600,089000,110600     S21042 00058302
*          RELEASE 22 DELETIONS                                         00061402
*          RELEASE 23 DELETIONS                                         00064502
*          RELEASE 24 DELETIONS                                         00067602
*          RELEASE 25 DELETIONS                                         00070702
*STATUS CHANGE LEVEL 003                                                00073802
*FUNCTION/OPERATION: TO REDUCE THE FORMAT 5 DSCB'S -DADSM - BY THE    * 00076902
*   SPACE ALLOCATED AND TO ELIMINATE ALL HOLES IN THE FORMAT 5 DSCB'S.* 00080000
*                                                                     * 00100000
*ENTRY POINTS:                                                        * 00120000
*        IGG0325G - ENTRY IS MADE FROM IGG0325F ON SPLIT CYLINDER     * 00140000
*   REQUESTS, AND FROM IGG0325E ON ALL OTHER TYPE SPACE REQUESTS.     * 00160000
*   ZERO QUANTITY REQUESTS DO NOT EXECUTE THIS MODULE.                * 00180000
*                                                                     * 00200000
*INPUT: UPON ENTRY TO THIS MODULE THE WORK AREA WILL CONTAIN THE DATA * 00220000
*   PORTION OF THE FORMAT 4 DSCB, AND THE ABSOLUTE ADDRESSES OF THE   * 00240000
*   FORMAT 4 DSCB AND THE FIRST FORMAT 5 DSCB.  THE DADSM TABLE WILL  * 00260000
*   CONTAIN THE NUMBER OF EXTENTS AND THE ACTUAL SPACE ALLOCATED.     * 00280000
*   THE KEY/DATA OF THE FIRST F5 MAY ALSO BE IN CORE, IF SO THE       * 00300000
*   'FIRST FORMAT 5 IN CORE SWITCH' WILL BE ON.   THE WORK AREA WILL  * 00320000
*   ALSO CONTAIN A DEB, AN IOB, AN ECB, AND A CHANNEL PROGRAM TO      * 00340000
*   SEARCH FOR HOLES AND TO READ AND WRITE DADSM RECORDS.             * 00360000
*   REGISTER 11 WILL POINT TO THE FIRST JFCB.                         * 00380000
*   REGISTER 13 WILL POINT TO THE WORK AREA.                          * 00400000
*                                                                     * 00420000
*OUTPUT: UPON TRANSFER VIA AN XCTL THE WORK AREA REGISTERS WILL BE AS * 00440000
*   AT INPUT.  NEW/UPDATED FORMAT 5 DSCB'S WILL BE WRITTEN OUT.       * 00460000
*                                                                     * 00480000
*EXTERNAL ROUTINES:                                                   * 00500000
*        EXCP(0) - READ FROM OR WRITE TO DIRECT ACCESS DEVICE         * 00520000
*        WAIT(1) - WAIT ON EVENT CONTROL BLOCK                        * 00540000
*        XCTL(7) - TRANSFER CONTROL TO ANOTHER MODULE BY XCTL BY 'TTR'* 00560000
*                                                                     * 00580000
*EXITS-NORMAL: XCTL TO IGG0325H TO WRITE OUT AN UPDATED FORMAT 4 DSCB * 00600000
*   AND TO WRITE OUT A ZERO RECORD IF REQUIRED.  ERROR CODE PASS      * 00620000
*   REGISTER WILL CONTAIN A ZERO.                                     * 00640000
*   -ERROR: XCTL TO IGG0325H WITH CODE IN ERROR CODE PASS REGISTER.   * 00660000
*                                                                     * 00680000
*   ERROR CODES THAT CAN BE ISSUED BY 'DADSM RECORD UPDATE MODULE'    * 00700000
*                                                                     * 00720000
*   0C - PERMANENT I/O ERROR                                          * 00740000
*                                                                     * 00760000
*TABLES/WORK AREAS: DADSM WORK AREA DESCRIBED BY DSECT 'DSCBWKAR'     * 00780000
*                                                                     * 00800000
*              ***************************************                * 00820000
*              *             DADSM TABLE             *                * 00840000
*              ***************************************                * 00860000
*                                                                     * 00880000
*              ***************************************                * 00900000
*              *        *         *                  *                * 00920000
*              *  TYPE  *  NO OF  *     USED HOLE    *                * 00940000
*              *  FLAG  * ENTRIES *      COUNTER     *                * 00960000
*              *        *         *                  *                * 00980000
*              ***************************************                * 01000000
*              *                  *                  *                * 01020000
*              *       RTA        *      RTA+1       *                * 01040000
*              *                  *                  *                * 01060000
*              ***************************************                * 01080000
*              *                  *                  *                * 01100000
*              *       RTA        *      RTA+1       *                * 01120000
*              *                  *                  *                * 01140000
*              ***************************************                * 01160000
*              *                  *                  *                * 01180000
*              *       RTA        *      RTA+1       *                * 01200000
*              *                  *                  *                * 01220000
*              ***************************************                * 01240000
*              *                  *                  *                * 01260000
*              *       RTA        *      RTA+1       *                * 01280000
*              *                  *                  *                * 01300000
*              ***************************************                * 01320000
*              *                  *                  *                * 01340000
*              *       RTA        *      RTA+1       *                * 01360000
*              *                  *                  *                * 01380000
*              ***************************************                * 01400000
*                                                                     * 01420000
*              TYPEFLG  =  02 - BPAM DIRECTORIES REQUESTED.           * 01440000
*                                                                     * 01460000
*                       =  40 - USER LABELS REQUESTED                 * 01464021
*                                                                     * 01468021
*                       =  80 - SET MUST COMPLETE IS ACTIVE           * 01472021
*                                                                     * 01476021
*              NO OF ENTRIES = NUMBER OF ENTRIES WITHIN DADSM TABLE.  * 01480000
*                                                                     * 01500000
*              RTA = THE STARTING TRACK OF THE ALLOCATED EXTENT.      * 01520000
*                                                                     * 01540000
*              RTA+1 = THE STARTING TRACK OF THE NEXT AVAILABLE EXTENT* 01560021
*                                                                     * 01580000
*ATTRIBUTES: REENTRANT,TRANSIENT                                      * 01600000
*                                                                     * 01620000
*NOTES:                                                               * 01640000
*   OTHER MACROS USED                                                 * 01660000
*   IECSDSL1 - BUILD DSCB'S                                           * 01680000
*   IEFJFCBN - BUILD JFCB                                             * 01700000
*                                                                     * 01720000
*   NO EXTERNALLY DEFINED SYMBOLS IN THIS MODULE                      * 01780000
*                                                                     * 01790021
*STORAGE: PROGRAM CODE - 1024 BYTES                                   * 01800021
*   WORK AREA - 704 BYTES                                        XM2969 01832002
*                                                                     * 01840000
*                                                                       01860000
*REGISTER NAMES-                                                        01880000
*                                                                       01900000
R0       EQU   0                        CHNL PRG START PTR AND WORK REG 01920000
R1       EQU   1                        WORK REGISTER                   01940000
RCNT     EQU   1                        DADSM ENTRY COUNT REG           01960000
RTAB     EQU   2                        DADSMTBL POINTER                01980000
RIN      EQU   3                        INPUT POINTER                   02000000
R4       EQU   4                        OUTPUT POINTER                  02020000
ROUT     EQU   4                        OUTPUT POINTER                  02040000
R5       EQU   5                        CONVERTED OUTPUT POINTER        02060000
ROEND    EQU   5                        END OF OUTPUT POINTER           02080000
R6       EQU   6                        CONVERT ROUTINE WORK REGISTER   02100000
R7       EQU   7                        CONVERT ROUTINE WORK REGISTER   02120000
R8       EQU   8                        CONVERT ROUTINE WORK REGISTER   02140000
RERRPASS EQU   8                        ERROR PASS REGISTER             02160000
R9       EQU   9                        CONVERT ROUTINE WORK REGISTER   02180000
RA       EQU   10                       CONVERT ROUTINE LOOP COUNTER    02200000
RB       EQU   11                       I/O LINK REGISTER               02220000
RJFCB    EQU   11                       JFCB POINTER                    02240000
RBASE    EQU   12                       BASE REGISTER                   02260000
RWKA     EQU   13                       WORK AREA POINTER.              02280000
RBAK     EQU   14                       RETURN REGISTER                 02300000
RWRK     EQU   15                       WORK REGISTER                   02320000
RERR     EQU   15                       ERROR CODE REGISTER             02340000
RF       EQU   15                       INPUT CONVERT LOOP COUNTER      02360000
*                                                                       02380000
* * * * * * * * * * * * *                                               02400000
*                                                                       02420000
*                                                                       02440000
* * * * * * * * * * * * *                                               02460000
*                                                                       02560000
*REGISTER USAGE-                                                        02580000
*                                                                       02600000
         BALR  RBASE,0                                                  02620000
         USING DADSMSTR,RBASE                                           02640000
         USING WORKAREA,RWKA                                            02660000
         USING JFCBFLD,RJFCB                                            02680000
*                                                                       02700000
* INITIALIZE DADSM OUTPUT RECORD, DADSM INPUT AND OUTPUT ADDRESSES,     02720000
* AND SWITCHES.  SAVE JFCB POINTER, PICK UP THE NUMBER OF ENTRIES IN    02740000
* THE DADSM TABLE, AND INITIALIZE POINTERS.                             02760000
*                                                                       02780000
DADSMSTR MVC   DS1DSNAM(4),FIVES        MOVE IN F5 NAME                 02800000
         MVC   IDAREA(5),FMTOUTAD       SET UP SRCH/ID FOR FIRST F5     02820000
         MVC   FMTINAD(5),FMTOUTAD      SET UP CURRENT F5 ADDRESS       02840000
         NI    SWITCH,FRSTF5            CLEAR ALL BUT 1ST F5 SWITCH     02860000
         OI    SWITCH,OUTBYP            SET READ/WRITE SWITCH           02880000
         ST    RJFCB,SAVEREGB           SAVE JFCB POINTER               02900000
         SR    RCNT,RCNT                                                02920000
         IC    RCNT,ENTRYNUM            GET NBR OF DADSMTBL ENTRIES     02940000
         LA    ROEND,F5OUT+108          LOAD END OF OUTPUT POINTER.     02960000
         LA    RTAB,ENTRIES             LOAD PTR TO 1ST DADSMTBL ENTRY  02980000
RESTOUT  LA    ROUT,F5OUT+4             LOAD PTR TO START OF OUTPUT     03000000
RESTORE  XC    DS1DSNAM+4(136),DS1DSNAM+4  CLEAR OUTPUT AREA            03020000
*                                                                       03040000
* TEST FOR FIRST DADSM RECORD IN CORE.  IF FIRST F5 IS IN CORE GO       03060000
* CONVERT IT TO RTA-RTA+1.  IF FIRST F5 IS NOT IN CORE GO READ          03080000
* IT IN AND CONVERT IT.                                                 03100000
*                                                                       03120000
         TM    SWITCH,FRSTF5            IS THE 1ST F5 STILL IN CORE     03140000
         BZ    SETFSTRD                 BRANCH IF 1ST F5 NOT IN CORE    03160000
         BAL   RBAK,CONVF5              GO CONVERT THIS F5              03180000
         B     DUELOOP                                                  03200000
SETFSTRD OI    SWITCH,FRSTF5            SET FIRST F5 IN CORE SWITCH     03220000
FSTRD    BAL   RBAK,READF5              GO READ AND CONVERT 1ST F5      03240000
*                                                                       03260000
* THIS SECTION DETERMINES WHEN THE DADSM TABLE EXTENTS SHOULD BE        03280000
* MERGED INTO THE OUTPUT FORMAT 5                                       03300000
*                                                                       03320000
DUELOOP  CLR   ROEND,ROUT               IS OUTPUT AREA FULL.            03340000
         BNH   TEST1                    BRANCH IF OUTPUT IS FULL        03360000
COMZE    CLC   0(4,RIN),ZEROS           IS THIS INPUT EXTENT ZERO       03380000
         BE    CHEND                    BRANCH IF YES                   03400000
         LTR   RCNT,RCNT                IS DADSMTBL EMPTY               03420000
         BZ    MOVEOUT                  BRANCH IF EMPTY                 03440000
         LH    R0,2(RTAB)               GET THIS ENTRY RTA+1       UL17 03442000
         CH    R0,4(RTAB)               IS IT EQ TO NEXT ENTRY RTA UL17 03444000
         BNE   CMPSPACE                 BRANCH IF NO               UL17 03446000
         LH    R0,0(RTAB)               GET FIRST ENTRY RTA        UL17 03448000
         STH   R0,4(RTAB)              MERGE THIS WITH NEXT ENTRY  UL17 03450000
         LA    RTAB,4(RTAB)             STEP POINTER TO NEXT ENTRY UL17 03452000
         BCTR  RCNT,0                  DECREMENT ENTRIES COUNTER   UL17 03454000
         B     DUELOOP                  REPEAT MERGE LOOP          UL17 03456000
CMPSPACE EQU   *                                                   UL17 03458000
         CLC   2(2,RTAB),2(RIN)         IS THIS SPACE ALLOCATED.        03460000
         BL    ALTEREX                  CHECK FOR MIDDLE OR FRONT       03480000
*                                       ALLOCATION IF LOW               03500000
         BE    TOTALL                   CHECK FOR TOTAL OR REAR         03520000
*                                       ALLOCATION IF EQUAL             03540000
*                                                                       03560000
* MOVE FORMAT 5 DSCB EXTENTS TO OUTPUT AREA                             03580000
*                                                                       03600000
MOVEOUT  TM    SWITCH,DADBYP            IS WRITE DADSM PENDING          03620000
         BO    CHEXTRTN                 BRANCH IF YES                   03640000
         MVC   0(4,ROUT),0(RIN)         MOVE INPUT TO OUTPUT            03660000
INPUT    BCT   RWRK,UPDATEPT            BRANCH IF INPUT NOT EMPTY       03680000
         LA    ROUT,4(ROUT)             STEP OUTPUT POINTER             03700000
         OI    SWITCH,PRCNTL            SET PROCESS CONTROL SWITCH      03720000
*                                                                       03740000
* TEST FOR MULTIPLE FORMAT 5 RECORDS                                    03760000
*                                                                       03780000
CHECHAIN TM    DS5PTRDS+4,X'FF'         IS INPUT RECORD CHAINED.        03800000
         BZ    CHECALT                  NO - CHECK IF RECORD ALTERED    03820000
         MVC   SAVCCHHR(5),IDAREA       SAVE CCHHR               XM2969 03832002
         TM    SWITCH,RCDALT            WAS DADSM RECORD ALTERED        03840000
         BC    1,BRTORDF5               BRANCH IF YES                   03860000
         XI    SWITCH,OUTBYP            FLIP/FLOP READ/WRITE SWITCH     03880000
*                                                                       03900000
* OUTPUT DADSM RECORD IS THE SAME AS THE INPUT DADSM RECORD.  BYPASS    03920000
* WRITE DADSM AND CLEAR THE OUTPUT AREA.                                03940000
*                                                                       03960000
TSTPROC  EX    0,RESTORE                CLEAR OUTPUT AREA               03980000
         LA    ROUT,F5OUT+4             RESET OUTPUT POINTER            04000000
         NI    SWITCH,X'DF'             CLEAR PROCESS CONTROL SWITCH    04020000
*                                                                       04040000
* LINK TO READ THE NEXT FORMAT 5 DSCB.                                  04060000
*                                                                       04080000
BRTORDF5 BAL   RBAK,SAVEID              GO READ IN NEXT F5              04100000
         B     DUELOOP                                                  04120000
*                                                                       04140000
* TEST IF LAST DADSM OUTPUT RECORD WAS ALTERED.  IF ALTERED WRITE       04160000
* DADSM, IF NOT ALTERED BYPASS THE WRITE DADSM.                         04180000
*                                                                       04200000
CHECALT  TM    SWITCH,RCDALT            WAS DADSM RECORD ALTERED        04220000
         BZ    EXIT1                    BRANCH IF NOT ALTERED           04240000
WRITEFNL OI    SWITCH,WRTFNL            SET WRITE FINAL RECORD SWITCH   04260000
         XC    REGSAVEA+12(5),REGSAVEA+12  CLEAR CHAIN ADDRESS          04280000
         BAL   RBAK,WRITEF5             WRITING FINAL RECORD.           04300000
*                                                                       04320000
* SET UP TO XCTL TO THE NEXT LOAD.                                      04340000
*                                                                       04360000
EXIT1    SR    RERRPASS,RERRPASS        CLEAR ERROR PASS REGISTER       04380000
ERREXIT  EQU   *                                                 A37231 04384020
         TM    SWITCH,NEWF5             TEST IF NEW F5 WAS       A37231 04388020
*                                       CREATED                  A37231 04392020
         BNO   NONEWF5                  BRANCH IF NOT            A37231 04396020
         NI    SWITCH,CLWRZERO          CLEAR WRITE ZERO RECORD  A37231 04400020
*                                       BIT                      A37231 04404020
NONEWF5  EQU   *                                                 A37231 04408020
         L     RJFCB,SAVEREGB           RESTORE JFCB POINTER     A37231 04412020
         MVC   XCTLID(2),ALLOCD2        MOVE IN LAST ALLOC LOAD ID      04420000
         MVC   TTR(3),TTRD2             MOVE IN LAST ALLOC LOAD TTR     04440000
*                                                                       04460000
         XCTL  DE=TTRAREA,SF=(E,XCTLPTR)                         A37199 04480021
*                                                                       04500000
* TEST IF OTHER THAN THE FIRST DADSM RECORD HAS BEEN READ IN.           04520000
*                                                                       04540000
TEST1    TM    SWITCH,PRCNTL            IS PROCESS CONTROL SWITCH ON    04560000
         BZ    TSTCH                    BRANCH IF NO                    04580000
         TM    SWITCH,OUTBYP            IS WRITE BEFORE READ            04600000
         BZ    TSTCH                    BRANCH IF YES                   04620000
         MVC   REGSAVEA+12(5),FMTOUTAD  SET UP OUTPUT RCD CHAIN ADDR    04640000
         B     BRTOWR5                  GO TO WRITE F5 ROUTINE          04660000
*                                                                       04680000
* TEST IF ANOTHER DADSM RECORD EXISTS                                   04700000
*                                                                       04720000
TSTCH    TM    DS5PTRDS+4,X'FF'         IS INPUT DADSM RECORD CHAINED   04740000
         BZ    CHEXT                    NO-CHECK FOR ZERO INPUT EXTENT  04760000
WRITE1   MVC   REGSAVEA+12(5),DS5PTRDS  INSERT CHAIN ADDRESS            04780000
BRTOWR5  BAL   RBAK,WRITEF5             GO WRITE OUT F5                 04800000
         B     DUELOOP                                                  04820000
*                                                                       04840000
* TEST IF THE FIRST DADSM RECORD IS STILL IN CORE.                      04860000
*                                                                       04880000
CHEND    TM    SWITCH,FRSTF5            IS THE 1ST DADSM RCD IN CORE    04900000
         BO    WRITEFNL                 BRANCH IF YES                   04920000
*                                                                       04940000
* TEST IF THERE HAS BEEN MORE INPUT DADSM RECORDS THAN OUTPUT DADSM     04960000
* RECORDS.  IF SO THEN SET UP TO ZERO OUT THE LAST INPUT DADSM RECORD.  04980000
*                                                                       05000000
TSTZERO  TM    SWITCH,OUTBYP            IS NBR OF WRTS EQUAL TO NBR RDS 05020000
         BO    WRITEZER                 BRANCH IF NO                    05040000
         MVC   IDAREA(5),FMTOUTAD       NO - SET UP SRCH/ID ADDRESS     05060000
         B     WRITEFNL                 GO WRITE LAST F5                05080000
WRITEZER OI    SWITCH,WRZERO            SET WRITE ZERO RECORD SWITCH    05100000
         MVC   FMTINAD(5),FMTOUTAD      SET UP ZERO RECORD ADDRESS      05120000
         B     WRITEFNL                 GO WRITE THE LAST F5            05140000
*                                                                       05160000
* THIS SECTION MERGES DADSM TABLE ENTRIES WITH F5 DSCB                  05180000
*                                                                       05200000
ALTEREX  OI    SWITCH,RCDALT            SET DADSM RECORD ALTERED SWITCH 05220000
*                                                                       05240000
* TEST IF A WRITE DADSM IS PENDING                                      05260000
*                                                                       05280000
         TM    SWITCH,DADBYP            IS DADSM WRITE BYPASS SWITCH ON 05300000
         BO    CHEXTRTN                 BRANCH IF YES                   05320000
         CLC   0(2,RTAB),0(RIN)         TEST FOR MIDDLE OR FRONT ALLOC  05340000
         BNE   MIDDLE                   LOW OR NOT EQUAL - MIDDLE ALLOC 05360000
FRONT    MVC   0(2,ROUT),2(RTAB)        FRONT ALLOC-INSERT NEW LOW RTA  05380000
         MVC   2(2,ROUT),2(RIN)         KEEP OLD UPPER RTA              05400000
*                                                                       05420000
* UPDATE POINTERS AND COUNTERS                                          05440000
*                                                                       05460000
DECRMNT  BCTR  RCNT,0                   DECREMENT TABLE ENTRY COUNTER   05480000
         LA    RTAB,4(RTAB)             STEP PTR TO NEXT DADSMTBL ENTRY 05500000
         B     INPUT                    GO CHECK FOR INPUT EMPTY        05520000
UPDATEPT LA    ROUT,4(ROUT)             UPDATE OUTPUT POINTER.          05540000
UPDATIN  LA    RIN,4(RIN)               UPDATE INPUT  POINTER.          05560000
         B     DUELOOP                                                  05580000
*                                                                       05600000
*                                                                       05620000
MIDDLE   MVC   0(2,ROUT),0(RIN)         MIDDLE ALLOC-INSERT OLD LOW RTA 05640000
         MVC   2(2,ROUT),0(RTAB)        INSERT NEW UPPER RTA            05660000
         LA    ROUT,4(ROUT)             UPDATE OUTPUT AREA POINTER      05680000
         CLR   ROEND,ROUT               IS OUTPUT AREA FULL             05700000
         BH    FRONT                    NO - INSERT NEXT EXTENT         05720000
         MVC   0(2,RIN),2(RTAB)         SAVE NEW LOW RTA IN INPUT       05740000
         LA    RTAB,4(RTAB)             STEP DADSMTBL POINTER           05760000
         BCTR  RCNT,0                   DECREMENT DADSMTBL ENTRY COUNT  05780000
         B     TEST1                    GO SET UP THIS DADSM WRITE      05800000
TOTALL   OI    SWITCH,RCDALT            SET DADSM RECORD ALTERED SWITCH 05820000
         CLC   0(2,RIN),0(RTAB)         IS ENTIRE EXTENT ALLOCATED.     05840000
         BNE   NOTALL                   NO - GO INSERT OLD LOW RTA      05860000
         SH    ROUT,FOUR                COMPENSATE FOR OUTPUT PTR STEP  05880000
         B     DECRMNT                  GO UPDATE POINTERS              05900000
NOTALL   TM    SWITCH,DADBYP            IS A WRITE DADSM PENDING        05920000
         BO    CHEXTRTN                 BRANCH IF YES                   05940000
         MVC   0(2,ROUT),0(RIN)          INSERT LOW OLD RTA             05960000
         MVC   2(2,ROUT),0(RTAB)        INSERT NEW UPPER RTA            05980000
         B     DECRMNT                  GO STEP POINTERS                06000000
*                                                                       06020000
* IS ALL OF DADSM PROCESSED                                             06040000
*                                                                       06060000
CHEXT    CLC   0(4,RIN),ZEROS           IS NEXT INPUT EXTENT ZERO       06080000
         BE    WRITEFNL                 BRANCH IF YES                   06100000
*                                                                       06120000
* THIS ROUTINE SEARCHES FOR HOLE IN VTOC TO WRITE NEW DSCB              06140000
*                                                                       06160000
SEARCH   MVC   FMTINAD(5),IDAREA        SAVE IDAREA                     06180000
         MVC   IDAREA(5),VTOCADR        START SEEK/SRCH AT F4 DSCB      06200000
         LA    R0,CCW1                  START CHANNEL PROG AT CCW1      06220000
         MVI   CCW5+4,X'30'             STOP CHANNEL PROG AFTER CCW5    06240000
         BAL   RB,CHANNLGO              GO SEARCH FOR A HOLE            06260000
         LH    R0,DS4DSREC              GET NUMBER OF AVAIL HOLES       06280000
         BCTR  R0,0                     DECREMENT COUNT BY ONE          06300000
         STH   R0,DS4DSREC              RESET NUMBER OF AVAIL HOLES     06320000
         MVC   REGSAVEA+12(5),IDAREA    SAVE HOLE ADDRESS               06340000
         MVC   IDAREA(5),FMTINAD        RESTORE IDAREA                  06360000
AFTERSRH BAL   RBAK,WRITEF5             GO WRITE THIS DADSM RECORD      06380000
         MVC   IDAREA(5),REGSAVEA+12    SET UP NEXT OUTPUT DADSM ADDR   06400000
         MVC   FMTOUTAD(5),REGSAVEA+12  SET UP NEXT OUTPUT DADSM ADDR   06420000
         OI    SWITCH,NEWF5             SET NEW F5 CREATED BIT   A37231 06430020
         B     DUELOOP                                                  06440000
*                                                                       06460000
* THIS CONVERTS DADSM ENTRIES FROM RTA-RTA+1 BACK TO XXYYZ BEFORE       06480000
* WRITING THE FORMAT 5 DSCB.                                            06500000
*                                                                       06520000
WRITEF5  LA    ROUT,F5OUT+4             LOAD POINTER TO OUTPUT AREA     06540000
         TM SWITCH,WRTFNL               IS WRITE FINAL RECORD SW ON     06560000
         BO    CHEXTRT                  BRANCH IF YES                   06580000
         ST    RBAK,PDLIST5             SAVE RETURN                     06600000
         OI    SWITCH,DADBYP            SET DADSM WRITE PENDING SW      06620000
         B     DUELOOP                  GO PROCESS DADSM                06640000
CHEXTRTN L     RBAK,PDLIST5             RELOAD RETURN                   06660000
CHEXTRT  STM   R4,R5,REGSAVEA           SAVE REGISTERS                  06680000
         LA    R5,DS1DSNAM+5            LOAD POINTER TO CONVERTED AREA  06700000
         LA    RA,26                    SET TO MAXIMUN NBR OF EXTENTS   06720000
         LH    R0,DS4DEVSZ+2            GET NBR OF TRKS/CYL             06740000
NEXTEXT  SR    R6,R6                    CLEAR HIGH DIVIDEND REGISTERS   06760000
         SR    R8,R8                                                    06780000
         SR    R9,R9                    CLEAR FULL CYLINDER REGISTER    06800000
         LH    R7,0(ROUT)               GET EXTENT RTA                  06820000
         LTR   R7,R7                    IS THIS EXTENT ZERO             06840000
         BNZ   NONZEROS                 BRANCH IF NOT ZERO       XM2969 06844002
         CH    RA,K26                   TEST FOR 26 EXTENTS      XM2969 06850002
         BNE   STORE                    BRANCH IF NOT EQUAL      XM2969 06852002
         OI    ZEROINDC,OUTBYP          SET BIT TO INDICATE      XM2969 06854002
*                                       26 ZERO EXTENTS          XM2969 06854402
         B     STORE                    CONTINUE                 XM2969 06856002
NONZEROS EQU   *                                                        06856402
         LH    R9,2(ROUT)               GET EXTENT RTA+1                06880000
         DR    R6,R0                    CONVERT RTA TO CYL/TRK          06900000
         DR    R8,R0                    CONVERT RTA+1 TO CYL/TRKS       06920000
         SR    R9,R7                    CALCULATE CYL DIFFERENCE        06940000
         SR    R8,R6                    CALCULATE TRK DIFFERENCE        06960000
         LTR   R9,R9                    IS CYL DIFFERENCE ZERO          06980000
         BZ    STORE                    BRANCH IF YES                   07000000
         LTR   R6,R6                    IS RTA TRK REMAINDER ZERO       07020000
         BZ    STORE                    BRANCH IF YES                   07040000
         AR    R8,R0                    ADD TRK CONSTANT TO TRK DIFF    07060000
         BCTR  R9,0                     DECREMENT NBR OF CYLS           07080000
STORE    STH   R9,2(ROUT)               STORE NBR OF FULL CYLINDERS     07100000
         MVC   0(4,R5),0(ROUT)          MOVE RTA AND CYLS TO OUTPUT     07120000
         STC   R8,4(R5)                 STORE NBR OF EXCESS TRKS        07140000
         LA    R5,5(R5)                 STEP CONVERTED AREA POINTER     07160000
         LA    ROUT,4(ROUT)             STEP OUTPUT POINTER             07180000
         BCT   RA,NEXTEXT               BRANCH IF MORE OUTPUT TO PROC   07200000
         MVC   DS1PTRDS(5),REGSAVEA+12  INSERT CHAIN ADDRESS            07220000
INSERTF5 MVC   DS1DSNAM+4(40),DS1DSNAM+5  OPEN F5 HOLE                  07240000
         MVI   DS1FMTID,X'F5'           INSERT FORMAT ID                07260000
         LM    R4,R5,REGSAVEA           RESTORE REGISTERS               07280000
         MVI   CCW11+4,X'10'            SET SKIP FLAG FOR WRITE CHECK   07300000
         LA    R0,CCW6                  START CHANNEL PROG AT CCW6      07320000
         BAL   RB,CHANNLGO              GO WRITE THIS DADSM RECORD      07340000
         MVC   IDAREA(5),DS1PTRDS       SET UP NEXT OUTPUT DADSM ADDR   07360000
         EX    0,RESTORE                CLEAR OUTPUT AREA               07380000
         XI    SWITCH,OUTBYP            FLIP/FLOP READ/WRITE SWITCH     07400000
WRTRTN   NI    SWITCH,X'FD'             CLEAR WRT PENDING (DADBYP) SW   07420000
         BR    RBAK                                                     07440000
*                                                                       07460000
* THIS SECTION READS IN FORMAT 5 (DADSM) DSCB AND CONERTS ENTRIES       07480000
* FROM XXYYZ TO RTA-RTA+1 FOR PROCESSING                                07500000
*                                                                       07520000
SAVEID   MVC   FMTINAD(5),IDAREA        SAVE IDAREA                     07540000
         MVC   FMTOUTAD(5),DS5PTRDS     SET UP NEXT OUTPUT DADSM ADDR   07560000
         NI    SWITCH,CLRF5S            CLEAR FIRST F5 IN CORE SWITCH   07580000
         MVC   IDAREA(5),DS5PTRDS       SET UP NEXT INPUT DADSM ADDR    07600000
READF5   LA    R0,CCW9                  START CHANNEL PROG AT CCW9      07620000
         MVI   CCW11+4,X'00'            CLEAR READ CCW FLAGS            07640000
         BAL   RB,CHANNLGO              GO READ A DADSM RECORD          07660000
         MVC   DS5KEYID+44(90),DS5KEYID+45   REMOVE FORMAT ID           07680000
CONVF5   LA    RIN,DS5AVEXT             RESET INPUT POINTER             07700000
         LR    R8,RIN                   SET UP PTR TP CONVERTED EXTENTS 07720000
         LA    RWRK,26                  SET TO MAX NUMBER OF EXTENTS    07740000
         SR    R6,R6                    CLEAR PICK UP REGISTER          07760000
TEST0    CLC   0(2,RIN),ZEROS           IS THIS EXTENT ZERO             07780000
         BE    INCRIN                   BRANCH IF YES                   07800000
         MVC   SAVEREGB+4(4),0(RIN)     ALIGN RTA AND NBR OF CYLS       07820000
         LH    R7,SAVEREGB+6            LOAD NBR OF CYLS                07840000
         MH    R7,DS4DEVSZ+2            MULTIPLY BY TRACK CONSTANT      07860000
         IC    R6,4(RIN)                GET ODD TRACKS                  07880000
         AR    R7,R6                    ADD ODD TRACKS FOR TOAL TRACKS  07900000
         AH    R7,SAVEREGB+4            ADD RTA                         07920000
         STH   R7,2(R8)                 STORE RTA+1 IN INPUT CONV AREA  07940000
         MVC   0(2,R8),SAVEREGB+4       MOVE RTA TO INPUT CONV AREA     07960000
         LA    R8,4(R8)                 UPDATE POINTER TO NEXT SPACE.   07980000
INCRIN   LA    RIN,5(RIN)               INCREMENT INPUT POINTER         08000000
         BCT   RF,TEST0                 BRANCH IF MORE EXTENTS          08020000
         LA    RIN,DS5AVEXT             RESET INPUT POINTER.            08040000
         XC    0(26,R8),0(R8)           CLEAR EXCESS BITS               08060000
         LA    RWRK,26                  RESET COUNT OF EXTENTS.         08080000
         XI    SWITCH,OUTBYP            FLIP/FLOP READ/WRITE SWITCH     08100000
         BZ    RETNBACK                 BRANCH IF READ BEFORE WRITE     08120000
         MVC   IDAREA(5),FMTINAD        SET UP NEXT OUTPUT WRT ADDR     08140000
RETNBACK BR    RBAK                                                     08160000
*                                                                       08180000
* EXECUTE CHANNEL PROGRAM TO READ OR WRITE F5                           08200000
*                                                                       08220000
CHANNLGO MVC   SEEK+3(4),IDAREA         INSERT SEEK ADDRESS FOR IOS.    08240000
         STM   RF,R1,REGSAVEA           SAVE REGISTERS                  08260000
         ST    R0,IOB+16                STORE STARTING CCW INTO IOB.    08280000
         MVI   ECB,X'00'                CLEAR STATUS BYTE OF ECB.       08300000
         EXCP  IOB                      EXECUTE CHHNNEL PROGRAM.        08320000
         WAIT  ECB=ECB                  WAIT FOR I/O COMPLETION         08340000
         LM    RF,R1,REGSAVEA           RESTORE REGISTERS               08360000
         TM    ECB,X'20'                TEST FOR PERM IO ERROR          08380000
         BCR   5,RB                     NO - CONTINUE PROCESSING        08400000
*                                                                       08420000
* ERROR - PERMANENT I/O ERROR                                           08440000
*                                                                       08460000
         LA    RERRPASS,X'0C'           SET ERROR CODE 'PERM I/O ERROR  08480000
         B     ERREXIT                                                  08500000
*                                                                       08520000
* * * * * * * * * * * * *                                               08540000
*                                                                       08560000
***   CONSTANTS                                                         08580000
*                                                                       08600000
* * * * * * * * * * * * *                                               08620000
*                                                                       08640000
FOUR     DC    H'4'                                                     08660000
FIVES    DC    X'05050505'                                              08680000
K26      DC    H'26'                    HALFWORD OF 26           XM2969 08692002
*                                                                       08700000
* XCTL BY TTR TABLE                                                     08720021
*                                                                       08740000
         DS    0D                       DOUBLE WORD BOUNDARY     A37199 08760021
TTRTABLE EQU   *                                                        08780000
ALLOCD2  DC    C'5H'                    ID OF LAST ALLOC LOAD           08800000
TTRD2    DC    X'00000000'              TTR OF LAST ALLOC LOAD          08820000
         DC    X'0000'                  LAST TABLE ENTRY CODE           08840000
MODLNGTH EQU   *                                                 S21042 08850021
         ORG   IGG0325G+1020                                            08860000
UNUSED   EQU   *-MODLNGTH                                        S21042 08870021
         DC    C'032'                   SPACE ALLOCATE SVC CODE         08880000
         DC    AL1((TTRTABLE-IGG0325G)/8) DOUBLE WORD POINTER TO S21042 08890021
*                                       THE XCTL TABLE           S21042 08900021
*                                                                       08920000
* * * * * * * * * * * * *                                               08940000
*                                                                       08960000
***   WORKAREA                                                          08980000
*                                                                       09000000
* * * * * * * * * * * * *                                               09020000
*                                                                       09040000
WORKAREA DSECT                                                          09060000
FIRST    EQU   *                                                        09080000
         IECSDSL1  (4)                                                  09100000
F5OUT    EQU   *+30                     UNCONVERTED OUTPUT AREA         09120000
         IECSDSL1  (1)                                                  09140000
         IECSDSL1  (5)                                                  09160000
DADSMTBL DS    0CL24                    DADSM TABLE FLAGS AND ENTRIES   09180000
TYPEFLG  DS    CL1                      '02' - DIRECTORY REQUEST        09200000
SMCDONE  EQU   X'80'               INDICATOR FOR SET MUST COMP.    UL17 09205000
USRLBL   EQU   X'40'               INDICATOR FOR USER LABEL REQ.   UL17 09210000
DIRREQ   EQU   X'02'               INDICATOR FOR DIRECTORY REQ.    UL17 09215000
ENTRYNUM DS    CL1                      NUMBER OF ENTRIES IN TABLE      09220000
UHOLECTR DS    CL2                                                      09240000
ENTRIES  DS    5F                       SPACE ALLOCATED                 09260000
PDLIST   EQU   ENTRIES+4                SPACE SEARCH ENTRIES            09300000
PDLIST5  DS    F                        LAST PUSH DOWN LIST ENTRY       09320000
ECB      DS    F                        EVENT CONTROL BLOCK             09340000
IOB      DS    8F                       INPUT/OUTPUT BLOCK              09360000
SEEK     DS    2F                       SEEK ADDRESS                    09380000
CCW1     DS    2F                       CHANNEL PROGRAN - 11 CCW'S USED 09400000
CCW2     DS    2F                                                       09420000
CCW3     DS    2F                                                       09440000
CCW4     DS    2F                                                       09460000
ZEROS    EQU   CCW4+4                   4 BYTES OF ZEROS                09480000
CCW5     DS    2F                                                       09500000
CCW6     DS    2F                                                       09520000
CCW7     DS    2F                                                       09540000
CCW8     DS    2F                                                       09560000
CCW9     DS    2F                                                       09580000
CCW10    DS    2F                                                       09600000
CCW11    DS    2F                                                       09620000
CCW12    DS    2F                                                       09640000
REGSAVEA EQU   CCW12                    REGISTER SAVE AREA              09660000
XCTLPTR  EQU   CCW12                    POINTER TO XCTL WROKAREA TABLE  09680000
CCW13    DS    2F                                                       09700000
CCW14    DS    2F                                                       09720000
FULLWORD EQU   CCW14                    BOUNDRY ALIGN AREA              09740000
SLOWCCHH EQU   FULLWORD+4               DIRECTORY REQUEST LOW CCHH      09760000
CCW15    DS    2F                                                       09780000
SAVEREGB EQU   CCW15                    SAVE AREA                       09800000
MBBCCHHR EQU   SAVEREGB                 ADDRESS CONVERSION AREA         09820000
TTRLL    DS    CL5                      REL TRK ADDR AND BYTES REMAIN   09840000
CCHHR    EQU   TTRLL               CCHHR OF F1 DSCB              S21042 09850021
SWITCH   DS    CL1                      CONTROL SWITCHES                09860000
*                                                                       09880000
*  BIT 0 = WRITE ZERO RECORD INDICATOR                                  09900000
*                                                                       09920000
*  BIT 1 = DSCB FORMAT 5 ALTERED INDICATOR                              09940000
*                                                                       09960000
*  BIT 2 = PROCESS CONTROL SWITCH                                       09980000
*                                                                       10000000
*  BIT 3 = WRITE FINAL RECORD INDICATOR                                 10020000
*                                                                       10040000
*  BIT 4 = FIRST DSCB FORMAT 5 IN CORE INDICATOR                        10060000
*                                                                       10080000
*  BIT 5 = DIRECTORY EXTENT FOUND                                       10100000
*                                                                       10120000
*  BIT 6 = UPDATE DADSMTBL POINTER BYPASS                               10140000
*                                                                       10160000
*  BIT 7 = UPDATE OUTPUT POINTER BYPASS                                 10180000
*                                                                       10200000
***  SWITCH EQUATES                                                     10220000
*                                                                       10240000
WRZERO   EQU   X'80'                                                    10260000
RCDALT   EQU   X'40'                                                    10280000
PRCNTL   EQU   X'20'                                                    10300000
WRTFNL   EQU   X'10'                                                    10320000
FRSTF5   EQU   X'08'                                                    10340000
NEWF5    EQU   X'04'                    NEW F5 DSCB CREATED      A37231 10350020
DIREXT   EQU   X'04'                                                    10360000
DADBYP   EQU   X'02'                                                    10380000
OUTBYP   EQU   X'01'                                                    10400000
CLRF5S   EQU   X'F7'                                                    10420000
CLCNTL   EQU   X'DC'                                                    10440000
CLRCDA   EQU   X'BF'                                                    10460000
CLWRZERO EQU   X'7B'                    CLEAR WRZERO & NEWF5     A37231 10470020
*                                                                       10480000
SAVEADR  DS    0CL28                    DEVICE ADDRESS SAVE AREA        10500000
VTOCADR  DS    CL5                      VTOC ADDRESS (F4)               10520000
DADSMADR DS    CL5                      FIRST DADSM ADDRESS (F5)        10540000
IDAREA   DS    CL8                      SEARCH/ID AREA                  10560000
FMTINAD  DS    CL5                      F5 SAVE ADDRESS AREA            10580000
FMTOUTAD DS    CL5                      F5 SAVE ADDRESS AREA            10600000
SPARE    DS    CL2                      USER COUNT - SPLIT REQUEST      10620000
TTRAREA  DS    0CL32                    XCTL AREA                       10640000
XCTLNM   DS    CL6                      COMMON BYTES OF ALLOCATE NAME   10660000
XCTLID   DS    CL2                      ID OF SPACE ALLOC MODULE        10680000
         DS    CL6                                                      10700000
TTR      DS    CL3                      TTR OF SPACE ALLOC MODULE       10720000
         DS    CL5                                                      10740000
TTRATTB  DS    CL2                      ATTRIBUTES OF SPACE ALLOC LOAD  10760000
TTRCREQ  DS    CL3                      CORE REQ OF SPACE ALLOC LOAD    10780000
TTRLNGTH DS    CL2                      LENGTH OF SPACE ALLOC LOAD      10800000
         DS    CL3                                                      10820000
DEB      DS    12F                      DATA EXTENT BLOCK               10840000
DEBPTR   DS    F                        POINTER TO DEB                  10860000
MIELNAME DS    CL6                      MINOR RESOURCE NAME      A37199 10870021
SAVCCHHR DS    XL5                      CCHHR HOLD AREA          XM2969 10874002
ZEROINDC DS    XL1                      ZERO EXTENT INDICATOR    XM2969 10876002
         DS    XL4                                               XM2969 10878002
LAST     DS    0H                                                       10880000
*                                                                       10900000
* * * * * * * * * * * * *                                               10920000
*                                                                       10940000
*                                                                       10960000
* * * * * * * * * * * * *                                               10980000
*                                                                       11000000
JFCBFLD  DSECT                                                          11020000
         IEFJFCBN                                                       11040000
         END   IGG0325G                                          S21042 51040021
