IGG0552E CSECT                                                          00200019
*                                                                       00400019
*          RELEASE 20 DELETIONS                                         00600019
*          RELEASE 21 DELETIONS                                         00800019
*          RELEASE 22 DELETIONS                                         01000019
*          RELEASE 23 DELETIONS                                         01200019
*          RELEASE 24 DELETIONS                                         01400019
*          RELEASE 25 DELETIONS                                         01600019
*          RELEASE 26 DELETIONS                                         01800019
*          RELEASE 27 DELETIONS                                         02000019
*          RELEASE 28 DELETIONS                                         02200019
*                                                                       02400019
*STATUS CHANGE LEVEL 000                                                02600019
*                                                                       02800019
*FUNCTION/OPERATION - OPEN/CLOSE/EOV AND DATA MANAGEMENT WTP MESSAGE    03000019
*          ROUTINE. WILL WRITE A ONE OR TWO LINE MESSAGE ON SYSOUT DATA 03200019
*          SET.                                                         03400019
*          WILL ABEND AFTER PRINTING MESSAGE, IF CALLER REQUESTS, OR    03600019
*          WILL RETURN, VIA XCTL.                                       03800019
*          THE FIRST LINE OF MESSAGE WILL CONTAIN ABEND CODE, RETURN    04000019
*          CODE, JOBNAME, STEPNAME, DDNAME, AND DSNAME.                 04200019
*          THE 2ND LINE WILL CONTAIN A MESSAGE PASSED BY CALLING PROG.  04400019
*ENTRY POINT - IGG0552E VIA XCTL ISSUED BY CALLING PROGRAM.             04600019
*INPUT - REG1 POINTS TO PARAMETER AREA CONSTRUCTED AS FOLLOWS:          04800019
*          BYTES 0 & 1 CONTAIN ABEND CODE IN HEX.                       05000019
*          BYTE 2 CONTAINS RETURN CODE TO BE PRINTED IN MESSAGE.        05200019
*              IF EITHER OF THE ABOVE IS ZERO, IT WILL NOT BE PRINTED.  05400019
*              BYTE3 IS UNUSED                                          05600019
*              BYTES 4-7 CONTAIN A POINTER TO THE CALLING ROUTINE'S     05800019
*                  8 BYTE ID, IF RETURN IS REQUESTED. ELSE ZEROES.      06000019
*              BYTES 8-11 CONTAIN A POINTER TO THE CALLING ROUTINE'S    06200019
*                  FORMATTED MESSAGE IF A 2ND LINE IS REQUESTED.        06400019
*                  ELSE ZEROES. THE 2ND LINE SHOULD BE SET AS A         06600019
*                  RECFM=V RECORD.                                      06800019
*        REG2 CONTAINS ADDRESS OF DCB ON WHICH ERROR OCCURRED.          07000019
*        REG4 CONTAINS PTR TO OPEN/CLOSE/EOV WKAREA OR ZEROES. IF       07200019
*              ZEROES, THE CALLER'S MSG AREA WILL BE DESTROYED.         07400019
*OUTPUT - ONE OR TWO LINE MESSAGE. ABEND IF REQUESTED, ELSE RETURN,     07600019
*              WITH ZEROES IN REG2                                      07800019
*                                                                       08000019
*EXTERNAL ROUTINES - N/A                                                08200019
*                                                                       08400019
*EXITS - RETURN TO CALLER VIA XCTL OR ABEND.                            08600019
*                                                                       08800019
*ERROR CONDITIONS - NONE                                                09000019
*                                                                       09200019
*TABLES/WORK AREA - THE FORMAT AND CONTENTS OF WORK AREAS USED ARE      09400019
*              DESCRIBED BY DSECTS AT END OF LISTING.                   09600019
*                                                                       09800019
*ATTRIBUTES - REENTRANT, ENABLED, PRIVILEGED, AND OPERATES FROM         10000019
*              TRANSIENT AREA.                                          10200019
*                                                                       10400019
*                                                                       10600019
*                                                                       10800019
*                                                                       11000019
*                                                                       11200019
RE       EQU   0                   WORK/PARAMETER                       11400019
RF       EQU   1                   WORK/PARAMETER                       11600019
RDCB     EQU   2                   USER DCB ADDR                        11800019
RBASE    EQU   3                   BASE                                 12000019
RCORE    EQU   4                   WORK AREA                            12200019
RPAR     EQU   5                   PARAMETER LIST                       12400019
RWTG     EQU   6                   START OF WTG                         12600019
RPARC    EQU   7                   CURRENT ENTRY IN PARLST              12800019
RWTGC    EQU   8                   CURRENT ENTRY IN WTG                 13000019
RTIOT    EQU   9                   TIOT PTR                             13200019
RUCB     EQU   10                  UCB                                  13400019
RA       EQU   11                  CURRENT WK AREA                      13600019
RB       EQU   12                  WORK                                 13800019
RC       EQU   13                  WORK                                 14000019
RD       EQU   14                  WORK/PARAMETER                       14200019
RJ       EQU   15                  WORK/PARAMETER                       14400019
FOUR3    EQU   43                                                       14600019
FIFTY5   EQU   55                                                       14800019
TWELVE   EQU   12                                                       15000019
FORTYFOR EQU   44                                                       15200019
READ     EQU   6                                                        15400019
CMDCHN   EQU   X'40'                                                    15600019
TIC      EQU   8                                                        15800019
SRCHID    EQU   X'31'                                                   16000019
EIGHTY   EQU   X'80'                                                    16200019
FOUR     EQU   4                                                        16400019
EIGHT    EQU   8                                                        16600019
UCBPTR   EQU   32                                                       16800019
FIVE     EQU   5                                                        17000019
SIX      EQU   6                                                        17200019
ZERO     EQU   0                                                        17400019
TWO      EQU   2                                                        17600019
MTDA     EQU   X'A0'                                                    17800019
THREE    EQU   3                                                        18000019
ONE      EQU   1                                                        18200019
SEVEN    EQU   7                                                        18400019
DA       EQU   X'20'                                                    18600019
FIFTYSIX EQU   56                                                       18800019
CORE     EQU   108                                                      19000019
BLANK    EQU   64                                                       19200019
         BALR  RBASE,0                                                  19400019
         USING *,RBASE                                                  19600019
         USING FORCORE,RCORE                                            19800019
         USING UCBOB,RUCB                                               20000019
         USING CVT,RJ                                                   20200019
         USING TIOT,RTIOT                                               20400019
         USING IHADCB,RDCB                                              20600019
         USING MESSAGEB,RPARC                                           20800019
         L     RJ,CVTPTR                PTR TO CVT                      21000019
         L     RJ,0(RJ)                 PTR TO TCB ADDRESSES            21200019
         L     RJ,4(RJ)                 PTR TO CURRENT TCB              21400019
         L     RD,12(RJ)                PTR TO TIOT                     21600019
         L     RJ,0(RJ)                 PTR TO SVRB                     21800019
         STM   RDCB,RC,96(RJ)           SAVE REGS                       22000019
         LR    RTIOT,RD                 SAVE TIOT PTR                   22200019
         LR    RA,RJ                    SAVE SVRB PTR                   22400019
         LR    RB,RF                    SAVE PARM LIST ADDR             22600019
         LA    RE,CORE                                                  22800019
         GETMAIN R,LV=(0)               WORKAREA TO BUILD MESSAGE       23000019
         LR    RPARC,RF                 ESTABLISH BASE                  23200019
          XC    MESSAGEB(FOUR),MESSAGEB  ZERO CONTROL FIELD             23400019
         MVI   MESSAGEB+2,EIGHTY        SET MCSFLAGS                    23600019
         LA    RWTG,MESSAGEB+FOUR       INITIALIZE LOCATION POINTER     23800019
         NC    EIGHT(FOUR,RB),EIGHT(RB) 2ND LINE REQUESTED?             24000019
*                                       IF THERE IS A 2ND LINE, USE     24200019
*                                       THE MESSAGE ID PASSED IN        24400019
*                                       THE 2ND LINE                    24600019
         BZ    OWNID                    NO                              24800019
         L     RF,EIGHT(RB)             GET ADDR OF 2ND LINE            25000019
         MVC   ZERO(EIGHT,RWTG),FOUR(RF) PUT ID IN MSG                  25200019
         LA    RWTG,EIGHT(RWTG)         UPDATE LOCATION PTR             25400019
         B     GETABCOD                                                 25600019
OWNID    MVC   ZERO(EIGHT,RWTG),MSGID   MOVE ID TO MESSAGE              25800019
         LA    RWTG,EIGHT(RWTG)         UPDATE LOCATION PTR             26000019
GETABCOD EQU   *                                                        26200019
         NC    ZERO(TWO,RB),ZERO(RB)    ABEND CODE?                     26400019
         BZ    JOBN                    NO                               26600019
         UNPK  ZERO(THREE,RWTG),ZERO(TWO,RB) PUT ABEND CODE IN MESSAGE  26800019
         OI    TWO(RWTG),X'F0'          CONVERT SIGN                    27000019
         TR    ZERO(THREE,RWTG),ABTBLE-240   CONVERT TO PRINT           27200019
         MVI   3(RWTG),C'-'                                      M4503  27400019
         LA    RWTG,FOUR(RWTG)          UPDATE LOCATION PTR             27600019
         CLI   TWO(RB),ZERO             RETURN CODE?                    27800019
         BE    JOBN                     NO                              28000019
         MVC   ZERO(ONE,RWTG),TWO(RB)   MOVE RET CODE TO MSG            28200019
         OI    ZERO(RWTG),X'F0'         CONVERT SIGN                    28400019
         MVI   ONE(RWTG),X'6B'          MOVE COMMA TO MESSAGE           28600019
         LA    RWTG,TWO(RWTG)           UPDATE LOCATION PTR             28800019
JOBN     MVC   ZERO(EIGHT,RWTG),TIOCNJOB  MOVE JOB NAME TO MSG          29000019
         LA    RWTG,SEVEN(RWTG)         UPDATE LOCATION PTR             29200019
         BAL   RF,SQUEEZE                                               29400019
         MVC   ZERO(EIGHT,RWTG),TIOCSTP MOVE STEP NAME TO MSG           29600019
         LA    RWTG,SEVEN(RWTG)        UPDATE LOCATION PTR              29800019
         BAL   RF,SQUEEZE                                               30000019
         NC    DCBTIOT(TWO),DCBTIOT    TIOT ENTRY FOR DATA SET?         30200019
         BZ    NODD                    NO                               30400019
         AH    RTIOT,DCBTIOT            POINT TO DD ENTRY IN TIOT       30600019
         MVC   ZERO(EIGHT,RWTG),FOUR(RTIOT)  MOVE DDNAME TO MSG         30800019
         LA    RWTG,SEVEN(RWTG)         UPDATE LOCATION PTR             31000019
         BAL   RF,SQUEEZE                                               31200019
         B    UNITNAME                                                  31400019
NODD     EQU   *                                                        31600019
         MVC   ZERO(EIGHT,RWTG),DCBDDNAM       MOVE DDNAME TO MSG       31800019
         LA    RWTG,SEVEN(RWTG)        UPDATE LOCATION PTR              32000019
         BAL   RF,SQUEEZE                                               32200019
         B     GETLEN                                                   32400019
UNITNAME EQU   *                                                        32600019
         L     RUCB,DCBDEBAD            PTR TO DEB                      32800019
         TM    DCBDSORG,X'80'           ISAM?                           33000019
          BO    ISAMDS                  YES                             33200019
         L     RUCB,32(RUCB)            PTR TO UCB                      33400019
         B     MOVEUCBN                                                 33600019
ISAMDS   L     RUCB,48(RUCB)                                            33800019
MOVEUCBN EQU   *                                                        34000019
         MVC   ZERO(THREE,RWTG),UCBNAME      MOVE UNIT NAME TO MSG      34200019
         TM    UCBTYP+TWO,DA            DIRECT ACCESS?                  34400019
         BNO   UNITEND                  NO                              34600019
         TM    UCBTYP+3,FIVE            DATA CELL?                      34800019
         BO    DATACELN                 YES                             35000019
UNITEND  EQU   *                                                        35200019
         MVI   THREE(RWTG),X'6B'        MOVE COMMA TO MSG               35400019
         LA    RWTG,FOUR(RWTG)          UPDATE LOCATION PTR             35600019
         TM    UCBTYP+TWO,MTDA          TAPE OR DA?                     35800019
         BZ    GETLEN                   NO                              36000019
         MVC   0(SIX,RWTG),SRTEVOLI     MOVE VOLSER TO MSG              36200019
         LA    RWTG,FIVE(RWTG)         UPDATE LOCATION PTR              36400019
VOLBACK  EQU   *                                                        36600019
         BAL   RF,SQUEEZE                                               36800019
*                                       NOW GO TO RESIDENT ROUTINE TO   37000019
*                                       CONVERT TTR TO MBBCCHHR IN      37200019
*                                       ORDER TO READ JFCB.             37400019
         STM   ZERO,RJ,DXCCW1           SAVE REGS                       37600019
         LA    RDCB,DXDAADDR            RESULT FIELD IN REG2            37800019
         L     RE,12(RTIOT)             PUT TTRN OF JFCB IN REG0        38000019
         SH    RTIOT,DCBTIOT            RESET TIOT PTR                  38200019
         L     RJ,CVTPTR                PTR TO CVT                      38400019
         L     RJ,CVTJOB                ADDR OF T. S. DCB               38600019
         L     RJ,44(RJ)                ADDR OF T. S. DEB               38800019
         MVC   DXDEB(48),0(RJ)                                          39000019
         LA    RF,DXDEB                 PTR TO DEB                      39200019
         L     RJ,CVTPTR                PTR TO CVT                      39400019
         L     RJ,CVTPCNVT              PUT ADDR OF CONVERT RTN IN REG  39600019
         BALR  RD,RJ                    GO TO CONVERT ROUTINE           39800019
         LM    RE,RJ,DXCCW1            RESTORE REGS                     40000019
         LA    RD,DXDCB                 GET DUMMY DCB ADDR              40200019
         ST    RD,IOBDCBPT-ONE          PUT DCB ADDR IN IOB             40400019
         ST    RD,DXDEBDCB              PUT DCB ADDR IN DEB             40600019
         LA    RD,DXECB                 GET ADDR OF ECB                 40800019
         ST    RD,IOBECBPT              STORE IN IOB                    41000019
         LA    RD,DXDEB                 ADDR OF DEB                     41200019
         ST    RD,DXDCBDEB              SAVE IN DUMMY DCB               41400019
         OI    IOBFLAG1,CMDCHN+TWO      COMMAND CHAINING                41600019
         LA    RD,DXCCW2                ADDR OF FIRST CCW               41800019
         ST    RD,IOBSTART-1                                            42000019
         LA    RD,DXDAADDR+THREE        ADDR OF CCHHR                   42200019
         ST    RD,DXCCW2                                                42400019
         MVI   DXCCW2,SRCHID            SEARCH ID EQ                    42600019
          MVC   DXCCW2+4(4),SEARCH      COMMAND CHAINING, SILI, COUNT   42800019
         LA    RD,DXCCW2                ADDR OF SEARCH PROG             43000019
         ST    RD,DXCCW3                                                43200019
         MVI   DXCCW3,TIC               TIC                             43400019
         LA    RD,DXJBF                 DATA ADDR                       43600019
         ST    RD,DXCCW4                                                43800019
         MVI   DXCCW4,READ              READ DATA                       44000019
         MVC   DXCCW4+4(4),READLEN                                      44200019
         EXCP  DXIOB                    READ SFCB                       44400019
         WAIT  ,ECB=DXECB                                               44600019
         TM    DXECB,X'7F'              SUCCESSFUL?                     44800019
         BNO   GETLEN                   NO, SKIP DSNAME                 45000019
         LR    RPAR,RWTG                                                45200019
         MVC   ZERO(FORTYFOR,RWTG),JFCBDSNM MOVE DSN TO MSG             45400019
         LA    RWTG,FOUR3(RWTG)         UPDATE LOCATION PTR             45600019
         BAL   RF,SQUEEZE                                               45800019
GETLEN   EQU   *                                                        46000019
         BCTR  RWTG,0                                                   46200019
         MVC   0(4,RWTG),DESRTCOD       SET DESC AND ROUT CODES         46400019
         LA    RE,MESSAGEB              GET ADDR OF BEGINNING OF MSG    46600019
         SR    RWTG,RE                  GET LENGTH OF MSG               46800019
         CH    RWTG,CON72               LONGER THAN 72 BYTES            47000019
         BH    TOOLONG                  YES                             47200019
         MVI   DXCCW,0                  NO CONTINUATION                 47400019
SAVLEN   EQU   *                                                        47600019
          STH   RWTG,MESSAGEB           STORE LENGTH                    47800019
WRITMSG  LA    RF,MESSAGEB              GET ADDR OF MSG                 48000019
         WTO   MF=(E,(1))                                               48200019
         CLI   DXCCW,1                  TEST FOR CONTINUATION           48400019
         BNZ   CHKNEXT                  YES                             48600019
         MVC   MESSAGEB+TWELVE(FORTYFOR),JFCBDSNM  MOVE DSN TO MSG      48800019
         LA    RWTG,MESSAGEB+FIFTY5     UPDATE LOCATION PTR             49000019
         BAL   RF,SQUEEZE                                               49200019
         B     GETLEN                                                   49400019
TOOLONG  EQU   *                                                        49600019
         LR    RWTG,RPAR               BACK UP TO END OF PRECEDING FLD  49800019
         MVC   0(4,RWTG),DESRTCOD       SET DESC AND ROUT CODES         50000019
         LA    RE,MESSAGEB              BEGINNING OF MSG                50200019
         SR    RWTG,RE                  CALCULATE LENGTH                50400019
         MVI   DXCCW,1                  INDICATE CONTINUATION           50600019
         B     SAVLEN                                                   50800019
CHKNEXT  EQU   *                                                        51000019
         LR    RF,RPARC                 ADDR OF WKAREA                  51200019
         LA    RE,CORE                  LENGTH                          51400019
         FREEMAIN R,LV=(0),A=(1)        FREE WK AREA                    51600019
         NC    EIGHT(FOUR,RB),EIGHT(RB) 2ND LINE REQUESTED?             51800019
         BZ    ENDJOB                   NO                              52000019
         L     RWTG,EIGHT(RB)           POINT TO 2ND LINE               52200019
         LR    RPAR,RWTG                                                52400019
         MVI   2(RPAR),EIGHTY           SET MCSFLAGS                    52600019
         AH    RPAR,0(RPAR)             POINT TO END OF MSG             52800019
         MVC   0(4,RPAR),DESRTCOD       SET DESC AND ROUT CODES         53000019
WRITE2   WTO   MF=(E,(RWTG))                                            53200019
ENDJOB   EQU   *                                                        53400019
         NC    FOUR(FOUR,RB),FOUR(RB)   ABEND REQUESTED?                53600019
         BZ    ABEND                    YES                             53800019
         LR    RF,RB                                                    54000019
         LR    RJ,RA                    SVRB PTR                        54200019
         LM    RDCB,RC,96(RJ)           RESTORE REGS                    54400019
         L     RD,FOUR(RF)              PT TO CALLING RTN ID            54600019
         SR    RDCB,RDCB                SET RETURN INDICATOR            54800019
XCTLOUT  L     RJ,DXCCW7                                                55000019
XCTL     XCTL  EPLOC=(RD),SF=(E,(15))                                   55200019
ABEND    EQU   *                                                        55400019
         LH    RF,ZERO(RB)              GET ABEND CODE                  55600019
         SLL   RF,8                                                     55800019
         ABEND (1),DUMP                                                 56000019
DATACELN EQU   *                                                        56200019
*                                       THIS ROUTINE WILL INSERT        56400019
*                                       BIN NUMBER OF DATA CELL         56600019
*                                       INTO MESSAGE.                   56800019
*                                                                       57000019
*                                                                       57200019
         L     RE,UCBSKA                PUT MBBC IN REG                 57400019
         SRL   RE,EIGHT                 MOVE BB TO RIGHT HALF           57600019
         MVI   THREE(RWTG),X'61'        MOVE '/' TO MSG                 57800019
         STC   RE,FOUR(RWTG)            STORE BIN NO. IN MSG            58000019
         OI    FOUR(RWTG),X'F0'         CONVERT TO DECIMAL              58200019
         MVI   FIVE(RWTG),X'6B'         MOVE COMMA TO MSG               58400019
         LA    RWTG,SIX(RWTG)           UPDATE LOCATION PTR             58600019
         B     DATACELV                                                 58800019
*         *         *         *         *         *         *         * 59000019
SQUEEZE  EQU   *                                                        59200019
*                                       THIS ROUTINE WILL REMOVE        59400019
*                                       BLANKS FROM VARIABLE LENGTH     59600019
*                                       FIELDS IN THE MESSAGE, SUCH     59800019
*                                       AS DDNAME, JOBNAME, ETC.        60000019
*                                                                       60200019
*                                                                       60400019
         CLI   0(RWTG),64               IS BLANK CHAR?                  60600019
         BNE   ENDSQUEZ                 NO, BRANCH                      60800019
         BCT   RWTG,SQUEEZE             POINT TO PRECEDING CHARACTER    61000019
*                                       AND BRANCH TO CHECK IT          61200019
ENDSQUEZ EQU   *                                                        61400019
         MVI   ONE(RWTG),X'6B'          MOVE COMMA TO MSG               61600019
         LA    RWTG,TWO(RWTG)           UPDATE LOCATION PTR             61800019
         BR    RF                       RETURN                          62000019
*         *         *         *         *         *         *         * 62200019
DATACELV EQU   *                                                        62400019
*                                       WHEN DEVICE IS A DATA CELL,     62600019
*                                       THIS ROUTINE WILL MOVE          62800019
*                                       VOLUME SERIAL NO. FROM BIN      63000019
*                                       TO THE MESSAGE.                 63200019
*                                                                       63400019
*                                                                       63600019
         SR    RE,RE                    ZERO WORK REG                   63800019
         IC    RE,UCBSKA+2              INSERT BIN NO. TO REG           64000019
         SLL   RE,FOUR                  MULTIPLY BY 16                  64200019
         LA    RF,FIFTYSIX(RUCB)        POINT REG TO 1ST SUB-UCB        64400019
         AR    RF,RE                    RF POINTS TO PROPER SUB-UCB     64600019
         MVC   ZERO(SIX,RWTG),FOUR(RF)  MOVE VOLSER TO MESSAGE          64800019
         LA    RWTG,FIVE(RWTG)          UPDATE LOCATION PTR             65000019
         B     VOLBACK                  RETURN                          65200019
*         *         *         *         *         *         *         * 65400019
MSGID    DC    C'IECXXXI '                                              65600019
ABTBLE   DC    C'0123456789ABCDEF'                                      65800019
CON72    DC    H'72'                                                    66000019
SEARCH   DC    X'60000005'                                              66200019
READLEN  DC    X'000000B0'                                              66400019
DESRTCOD DC    X'04000020'                                              66600019
         ORG   IGG0552E+1016                                            66800019
         DC    XL7'00'                                                  67000019
         DC    XL1'7F'                                                  67200019
         DCBD  DSORG=(BS,DA,IS,LR,PO,PS,QS,GS)                          67400019
FORCORE  DSECT                                                          67600019
         IECDSECT                                                       67800019
SRT      DSECT                                                          68000019
         IEFUCBOB                                                       68200019
CVT      DSECT                                                          68400019
         CVT                                                            68600019
TIOT     DSECT                                                          68800019
TIOCNJOB DS    CL8                                                      69000019
TIOCSTP  DS    CL8                                                      69200019
MESSAGEB DSECT                                                          69400019
         DS    CL104                                                    69600019
IGG0552E CSECT                                                          69800019
         END   IGG0552E                                                 70000019
