         TITLE 'IGG0559D - END OF VOLUME REPOSITIONING MOUNT - 2321'    00200019
*********************************************************************** 00400019
*                                                                     * 00600019
*          RELEASE 20 DELETIONS                                       * 01000019
*          RELEASE 21 DELETIONS                                       * 01200019
*          RELEASE 22 DELETIONS                                       * 01400019
*          RELEASE 23 DELETIONS                                       * 01600019
*          RELEASE 24 DELETIONS                                       * 01800019
*          RELEASE 25 DELETIONS                                       * 02000019
*          RELEASE 26 DELETIONS                                       * 02010019
*          RELEASE 27 DELETIONS                                       * 02020019
*          RELEASE 28 DELETIONS                                       * 02030019
*                                                                     * 02040019
*STATUS CHANGE LEVEL 000                                              * 02200019
*                                                                     * 02400019
*FUNCTION/OPERATION - THIS MODULE WAS CREATED TO SUPPORT USASI COBOL  * 02600019
*                     SPAN VOLUME RECORD REPOSITIONING.  THIS MODULE  * 02800019
*                     RECEIVES CONTROL FROM IGG0552D WHEN 2321 DEVICE * 03000019
*                     IS BEING USED.  IT DECREMENTS THE DATA          * 03200019
*                     MANAGEMENT COUNT ON THE CURRENT VOLUME AND      * 03400019
*                     SEES THAT THE PREVIOUS VOLUME IS MOUNTED AND    * 03600019
*                     POSITIONED AT THE BEGINNING OF THE SPAN RECORD. * 03800019
*                     EXIT IS THEN MADE VIA XCTL TO IGG0551A.           04000019
*                                                                     * 04200019
*ENTRY POINTS - IGG0559D ENTRY VIA XCTL FROM IGG0552D                 * 04400019
*                                                                     * 04600019
*INPUT - THE FOLLOWING REGISTERS HAVE BEEN SET UP UPON ENTRY          * 04800019
*        REGISTER 2 - ADDRESS OF USER'S DCB                           * 05000019
*        REGISTER 4 - ADDRESS OF WORK AREA (SEE BELOW)                * 05200019
*        REGISTER 5 - ADDRESS OF THE USER'S DEB                       * 05400019
*        REGISTER 6 - ADDRESS OF MAIN UCB                             * 05600019
*        REGISTER 9 - CURRENT ENTRY IN THE TIOT                       * 05800019
*        REGISTER 10- ADDRESS OF SUB UCB                              * 06000019
*        REGISTER 11- NUMBER OF UNITS IN TIOT FOR THIS ENTRY          * 06200019
*        REGISTER 12- ADDRESS IN THE JFCB OF THE VOLUME SERIAL NUMBER * 06400019
*                     OF THE VOLUME WHICH HAS REACHED THE END OF      * 06600019
*                     VOLUME CONDITION.                               * 06800019
*        UPON ENTRY,IT IS ALSO ASSUMED THAT THE WORK AREA CONTROL     * 07000019
*        BLOCKS (DCB,DEB,AND IOB) ARE SET UP.  ALSO THE JFCB HAS BEEN * 07200019
*        READ INTO THE WORK AREA.                                     * 07400019
*                                                                     * 07600019
*OUTPUT - NONE OF THE INPUT REGISTERS SPECIFIED UNDER INPUT ABOVE HAVE* 07800019
*         BEEN MODIFIED.  THE CORRECT VOLUME TO BE NEXT PROCESSED HAS * 08000019
*         BEEN MOUNTED IF THIS IS NECESSARY.                          * 08200019
*                                                                     * 08400019
*EXTERNAL ROUTINE - IECPRLTV - MBBCCHHR TO TTR CONVERSION             * 08600019
*                                                                     * 08800019
*                   THE FOLLOWING SVC'S MAY ALSO BE ISSUED            * 09000019
*                        WTO -  MOUNTING MESSAGES                     * 09200019
*                        EXCP - READ THE VOLUME LABEL                 * 09400019
*                        WAIT - WAIT FOR COMPLETION OF READ           * 09600019
*                        ABEND -ABNORMALLY TERMINATE (SEE EXITS ERROR)* 09800019
*                        XCTL - TRANSFER CONTROL TO NEXT EOV MODULE   * 10000019
*                                                                     * 10200019
*EXITS - NORMAL  XCTL TO IGG0551A - SAM EXECUTOR TO CONTINUE          * 10400019
*                                   PROCESSING                        * 10600019
*      - ERROR - ABEND ISSUED WITH ERROR CODES                        * 10800019
*                        F37 - I/O ERROR WHILE READING VOLUME LABEL   * 11000019
*                                                                     * 11200019
*TABLES/WORK AREAS - A 536 BYTE WORK AREA IS USED TO PERFORM READING  * 11400019
*                    OF VOLUME LABELS.  INCLUDED IN THE AREA ARE A    * 11600019
*                    SKELETON DCB,DEB,IOB,CCW'S,ETC..  CONSULT THE    * 11800019
*                    DSECT LABELED FORCORE FOR FURTHER DETAIL.        * 12000019
*                                                                     * 12200019
*ATTRIBUTES - REENTRANT,REUSABLE,PRIVILEGED,ENABLED.                  * 12400019
*********************************************************************** 12600019
IGG0559D CSECT                                                          12800019
*                                                                     * 13000019
***** EOV REGISTER ASSIGNMENTS                                    ***** 13200019
*                                                                     * 13400019
RE       EQU   0                        WK REG                          13600019
RF       EQU   1                        WK REG                          13800019
RDCB     EQU   2                        POINTS TO DCB                   14000019
RBASE    EQU   3                        BASE REGISTER                   14200019
RCORE    EQU   4                        POINTS TO GOT CORE AREA         14400019
RDEB     EQU   5                        POINTS TO DEB                   14600019
RWTG     EQU   6                        POINTS TO 'WHERE-TO-GO' TABLE   14800019
RMUCB    EQU   6                        POINTS TO MAIN UCB              15000019
RG       EQU   7                        WK REG                          15200019
RH       EQU   8                        WK REG (POINTS TO V(N-1))       15400019
RTIOT    EQU   9                        POINTS TO TIOT                  15600019
RNTRY    EQU   9                        POINTS TO TIOT ENTRY            15800019
RUCB     EQU   10                       POINTS TO SUB UCB FOR 2321      16000019
RA       EQU   11                       WK REG (PASS NUMBER OF UNITS)   16200019
RB       EQU   12                       WK REG (POINTS TO V(N))         16400019
RC       EQU   13                       WK REG                          16600019
RD       EQU   14                       WK REG                          16800019
RJ       EQU   15                       WK REG                          17000019
RTCB     EQU   15                       POINTS TO TCB                   17200019
*                                                                     * 17400019
***** CONSTANTS                                                   ***** 17600019
*                                                                     * 17800019
COLI0000 EQU   0                        CONSTANT FOR ZERO               18000019
COLI0001 EQU   1                        CONSTANT FOR ONE                18200019
COLI0002 EQU   2                        CONSTANT FOR TWO                18201019
COLI0003 EQU   3                        CONSTANT FOR THREE              18210019
COLI0004 EQU   4                        CONSTANT FOR FOUR               18400019
COLI0005 EQU   5                        CONSTANT FOR FIVE               18401019
COLI0006 EQU   6                        CONSTANT FOR SIX                18402019
COLI0007 EQU   7                        CONSTANT FOR SEVEN              18410019
COLI0008 EQU   8                        CONSTANT FOR EIGHT              18420019
COLI0010 EQU   10                       CONSTANT FOR TEN                18430019
COLI0012 EQU   12                       CONSTANT FOR 12                 18600019
COLI0014 EQU   14                       CONSTANT FOR 14                 18601019
COLI0022 EQU   22                       CONSTANT FOR 22                 18610019
COLI0024 EQU   24                       CONSTANT FOR 24                 18620019
COLI0218 EQU   218                      CONSTANT FOR 218                18621019
COLI0242 EQU   242                      CONSTANT FOR 242                18630019
SRCHID   EQU   X'31'                    SEARCH ID COMMAND CODE          18800019
CHAR80   EQU   X'50'                    80 CHARACTERS                   19000019
RDDATA   EQU   X'06'                    READ DATA OP CODE               19200019
MSGLTHDC EQU   26                       LENGTH OF DATA CELL MSG         19400019
F37      EQU   X'F37'                   ABEND CODE                      19600019
ACE      EQU   C'A'                     TEST MOUNT MSG ISSUED           19610019
FOXES    EQU   X'FF'                    TURN ON DOM INDICATOR           19620019
COMMA    EQU   C','                                                     19630019
SLASH    EQU   C'/'                     SLASH FOR MSG                   19640019
HEXBIN   EQU   X'F0'                    CHANGE BIN NO TO HEX            19650019
*                                                                     * 19800019
***** MASKS                                                       ***** 20000019
*                                                                     * 20200019
MASKEXCP EQU   X'7F'                                                    20400019
MASKNMON EQU   X'7F'                                                    20600019
MASKNORY EQU   X'40'                                                    20800019
P1       EQU   1                        CONSTANT                        21000019
P2       EQU   2                        CONSTANT                        21200019
P4       EQU   4                        CONSTANT                        21400019
P6       EQU   6                        CONSTANT                        21600019
P12      EQU   12                       CONSTANT                        21800019
*                                                                     * 22000019
***** INITIALIZE EOV REGISTERS                                    ***** 22200019
*                                                                     * 22400019
         BALR  RBASE,0                  ESTABLISH ADDRESSABILITY        22600019
         USING FORECORE,RCORE                                           22800019
         USING TIOENTRY,RTIOT                                           23000019
         USING DEB,RDEB                                                 23200019
         USING IHADCB,RDCB                                              23400019
         USING *,RBASE                                                  23600019
         USING CVT,RJ                                                   23800019
         USING DATACELL,RUCB                                            24000019
         USING UCBOB,RMUCB                                              24200019
         LTR   RDCB,RDCB                IS CALL FROM 552B               24400019
         BE    MKRET                    YES,BRANCH                      24600019
*                                                                     * 24800019
***** SET UP WORK AREA DEB FOR DATA CELL                          ***** 25000019
*                                                                     * 25200019
         BAL   RJ,MAINUCB               SET RUCB POINTER TO MAIN UCB    25400019
         BAL   RJ,SETWKDEB              SET UP WORK AREA DEB            25600019
         MVC   DXDEBSCC(COLI0010),COLCDUEX                              25800019
*                                       CREATE DUMMY EXTENT IN WORK DEB 25810019
*                                                                     * 26000019
***** DECREMENT DATA MANAGEMENT COUNT ON CURRENT VOLUME - 2321    ***** 26200019
*                                                                     * 26400019
         SR    RF,RF                    PICK UP DATA MANAGEMENT COUNT   26600019
         SSM   *+COLI0001               SET SYSTEM MASK                 26800019
         IC    RF,DCELDMCT              (NUMBER OF DATA SETS CURRENTLY  27000019
         BCTR  RF,COLI0000              USING VOLUMED AND REDUCE        27200019
         STC   RF,DCELDMCT              CURRENT NUMBER OF USERS OF THIS 27400019
         SSM   INTRPS                   VOLUME BY ONE                   27600019
*                                                                     * 27800019
***** IS THERE ONLY ONE DEVICE AVAILABLE                          ***** 28000019
*                                                                     * 28200019
         LA    RF,COLI0006                                              28400019
         LA    RG,COLI0000                                              28600019
         LA    RH,COLI0218(RCORE)       LOAD JFCBVOLS ADDRESS           28800019
LOOP     LA    RG,COLI0001(RG)          INCREMENT COUNT                 29000019
         CLC   COLI0000(COLI0006,RB),COLI0000(RH)                       29200019
*                                       IS THIS VOL JUST PROCESSED      29210019
         BE    FOUND                    YES, BRANCH                     29400019
         CL    RG,FIVEVOL               HAVE 5 VOSERNOS BEEN CHECKED    29600019
         BE    SWITCH                   YES, BRANCH                     29800019
         LA    RH,COLI0006(RH)          INCREMENT VOLSERNO POINTER      30000019
         B     LOOP                     CONTINUE SEARCH                 30200019
SWITCH   LA    RH,DXLBL+COLI0004        POINT TO VOLSERNO IN EXTENSION  30400019
         B     LOOP                     CONTINUE SEARCH                 30600019
POINT    LA    RH,COLI0242(RCORE)       BACKSPACE TO PREVIOUS VOLSERNO  30800019
         B     GO                       CONTINUE PROCESSING             31000019
FOUND    CR    RG,RF                    IS THIS FIRST VOL OF EXTENSION  31200019
         BE    POINT                    YES, BRANCH                     31400019
         SR    RH,RF                    BACKSPACE TO PREVIOUS VOLSERNO  31600019
GO       EQU   *                                                        31800019
         LA    RF,COLI0001              SET COUNT REGISTER TO ONE       32000019
         LA    RG,COLI0000                                              32200019
TESTUNIT EQU   *                                                        32400019
         L     RUCB,TIOESTTB(RG)        UPDATE UCB REGISTER             32600019
         BAL   RJ,MAINUCB               SET RMUCB POINT TO MAIN UCB     32800019
         CLC   DCELVOLI(COLI0006),COLI0000(RH)                          33000019
*                                       COMPARE SRT AND JFCB VOL SERNO  33010019
         BE    FOUNDCEL                 GO TO VOL FOUND ON SRT(L)       33200019
         CR    RA,RF                    IS THERE ONLY ONE UNIT          33400019
         BE    ONEUNIT                  YES BRANCH                      33600019
         LA    RF,COLI0001(COLI0000,RF) ADD 1 TO COUNT                  33800019
         LA    RG,COLI0004(COLI0000,RG) ADD 4 TO INDEX                  34000019
         B     TESTUNIT                 GO CHECK NEXT DEVICE            34200019
ONEUNIT  OI    UCBFL2,MASKNORY          INDICATE UNIT IS NOT READY      34400019
FOUNDCEL SR    RD,RD                    CLEAR WORK REGISTER             34600019
         SSM   *+COLI0001                                               34800019
         IC    RD,DCELDMCT              PICK UP CURRENT NO. OF USERS OF 35000019
         LA    RD,COLI0001(COLI0000,RD) THIS VOLUME AND ADD 1 TO        35200019
         STC   RD,DCELDMCT              REFLECT THAT THIS DCB IS USING  35400019
         SSM   INTRPS                   THIS UNIT                       35600019
         L     RF,TIOESTTB              PICK UP THE PREVIOUS UNIT       35800019
         ST    RF,TIOESTTB(RG)          STORE SRT(1) ON SRT(L)          36000019
         ST    RUCB,TIOESTTB            STORE SRT(L) ON SRT(1)          36200019
         BAL   RJ,MAINUCB               UPDATE RMUCB                    36400019
         BAL   RJ,SETWKDEB              SET UP WORK AREA DEB            36600019
         CLC   DCELVOLI(COLI0006),COLI0000(RH)                          36800019
*                                       COMPARE SRT AND JFCB VOL SERNO  36810019
         BE    GOTO1A                   GOTO IGG0551A                   37000019
         MVC   MCSFLAGS(P12),FLAG1      MOVE IN BASIC KEEP MSG.         37200019
         MVC   MSGVOLSR+COLI0002,DCELVOLI                               37400019
*                                       VOLUME SERIAL NO. TO MESSAGE    37410019
WRMSG    MVC   MSGUN,UCBNAME            PICK UP UNIT NAME               37600019
         MVC   MSGUN+COLI0004(COLI0001),DCELBBNR+COLI0001               37800019
*                                       PICK UP BB                      37810019
         OI    MSGUN+COLI0004,HEXBIN    CHANGE BIN NO. TO HEX           38000019
         MVI   MSGUN+COLI0003,SLASH     SLASH FOLLOWS BIN NUMBER        38200019
         MVI   MSGUN+COLI0005,COMMA     MOVE IN COMMA AFTER BIN NO.     38400019
         LR    RG,RUCB                  SAVE UCB PTR                    38600019
         LR    RUCB,RMUCB               CORRECT UCB PTR                 38800019
         LR    RC,RDCB                  SAVE DCB PTR                    39000019
         L     RA,MCSDESC1              MCS CODES FOR USE IN 552B       39200019
         LA    RF,MSGLSTSZ              MSG PTR                         39400019
         MVC   DXCCW9(P2),LOADID+P1     EOV ID                          39600019
         MVC   DXCCW9+P2(P6),V9D9D      ID AND TTR OF MODULE            39800019
         LA    RDCB,DXCCW9              PTR FOR WTO RETURN              40000019
         MVC   DXXCTL+COLI0014(COLI0002),V9D2B                          40200019
*                                       PTR TO ID AND TTR OF 552B       40210019
         MVC   DXXCTL+COLI0022(COLI0003),V9D2B+COLI0002                 40400019
         B     GOTOMOD                  GO TO NEXT MODULE               40600019
MKRET    LR    RDCB,RC                  RESTORE DCB PTR                 40800019
         LR    RUCB,RG                  RESTORE UCB PTR                 41000019
         CLI   MSGSERLO+P1,ACE          WAS A MOUNT ISSUED              41200019
         BE    READSCB                  YES,READ DSCB                   41400019
*                                                                     * 41600019
***** ISSUE MOUNT MESSAGE TO MOUNT THE NEXT VOLUME FOR 2321       ***** 41800019
*                                                                     * 42000019
REWTO    MVC   MCSFLAGS(P12),FLAG2      MOUNT MESSAGE                   42200019
         MVC   MSGVOLSR+COLI0002,COLI0000(RH)                           42400019
*                                       VOL SER NO IN MESSAGE           42410019
         OI    UCBFL2,MASKNORY          SET UCB NOT READY               42600019
         B     WRMSG                    GO TO WRITE MSG                 42800019
*                                                                     * 43000019
***** READ THE VOLUME LABEL - 2321                                ***** 43200019
*                                                                     * 43400019
READSCB  MVI   DXCCW9,FOXES             TURN ON DOM INDICATOR           43600019
         MVC   DXDAADDR(COLI0008),COLCVTOC                              43800019
*                                       MOVE ID INTO DUMMY ID ADDR      43810019
         MVC   DXDAADDR+COLI0001(COLI0002),DCELBBNR                     44000019
         XC    DXCCW(COLI0024),DXCCW1   CLEAR 3 CCW'S                   44200019
         LA    RE,DXDAADDR+COLI0003     ADDRESS OF IOBDADAD+3           44400019
         ST    RE,DXCCW1                SEARCH ADDR IN CCW1             44600019
         LA    RE,DXCCW1                ADDR SEARCH CCW                 44800019
         ST    RE,DXCCW2                PUT ADDR IN CCW2                45000019
         ST    RCORE,DXCCW3             WORKAREA ADDR IN CCW3           45200019
         MVI   DXCCW1,SRCHID            SEARCH ID COMMAND CODE          45400019
         MVC   DXCCW1+COLI0004(COLI0005),ACCW1                          45600019
*                                       REST OF CCW1 AND TIC COMMAND    45610019
         MVI   DXCCW3+COLI0007,CHAR80   80 CHARACTERS                   45800019
         MVI   DXCCW3,RDDATA            READ DATA OPERATION CODE        46000019
*                                                                     * 46200019
***** EXECUTE THE READ CHANNEL PROGRAM                            ***** 46400019
*                                                                     * 46600019
         EXCP  DXIOB                    EXECUTE CHANNEL PROGRAM         46800019
         WAIT  ,ECB=DXECB               WAIT FOR COMPLETION             47000019
         LA    RA,REPLY+P4                                              47200019
         DOM   MSGLIST=(11)                                             47400019
         CLI   DXECB,MASKEXCP           WAS THERE AN I/O ERROR          47600019
         BE    GOODRD                   READ SUCCESSFULL, BRANCH        47800019
         LA    RD,F37                   LOAD ABEND CODE - F37           48000019
         SLL   RD,COLI0012              ADJUST ERROR CODE               48200019
         ABEND (RD),DUMP                                                48400019
GOODRD   CLC   COLI0000(COLI0006,RH),VOLSERNO                           48600019
*                                       VOLSER IN LABEL CORRECT         48610019
         BNE   REWTO                    NO,GO TO REISSUE MOUNT MESSAGE  48800019
         MVC   DCELVOLI(COLI0006),VOLSERNO                              49000019
*                                       PUT VOL SERNO IN UCB            49010019
*                                                                     * 49200019
***** CONVERTING THE VTOC ADDRESS IN VOL LABEL TO TTR FOR DATA CELL *** 49400019
*                                                                     * 49600019
         ST    RDCB,DXCCW7              SAVE DCB ADDRESS                49800019
         STM   RTIOT,RC,DXCCW8          SAVE REGISTERS                  50000019
*                                                                     * 50200019
***** SET MBBCCHHR                                                ***** 50400019
*                                                                     * 50600019
         MVI   DXCCW5,COLI0000          SET M=0                         50800019
         MVC   DXCCW5+COLI0003(COLI0005),VOLVTOC                        51000019
*                                       SET UP CCHHR OF THE VTOC        51010019
         LA    RF,DXDEB                 ADDR OF WORK DEB TO PARM REG    51200019
         LA    RDCB,DXCCW5              LOAD MBBCCHHR ADDRESS           51400019
         L     RJ,CVTPTR                ADDRESS OF CVT                  51600019
         L     RJ,CVTPRLTV-CVT(COLI0000,RJ)                             51800019
*                                       ENTRY FROM MBBCCHHR TO TTR CONV 51810019
         BALR  RD,RJ                    GOTO MBBCCHHR TO TTR CONVERT RT 52000019
*                                                                     * 52200019
***** PUT VTOC TTR INTO UCB - 2321                                ***** 52400019
*                                                                     * 52600019
         L     RDCB,DXCCW7              RESET RDCB                      52800019
         LM    RTIOT,RC,DXCCW8          RESET REGISTERS                 53000019
         IC    RE,DCELUSER              PICK UP NO. OF USER'S           53200019
         ST    RE,DCELVTOC              PLACE TTR OF VTOC INTO UCB      53400019
         NI    DCELDMCT,MASKNMON        RESET MOUNT INDICATOR           53600019
         CLC   COLI0000(COLI0006,RH),DCELVOLI                           53800019
*                                       CORRECT VOLUME SERIAL NUMBER    53810019
         BNE   REWTO                    GO TO ISSUE ANOTHER MESSAGE     54000019
GOTO1A   MVC   DXXCTL+COLI0014(COLI0002),VJLD1A                         54200019
         MVC   DXXCTL+COLI0022(COLI0003),VJLD1A+COLI0002                54400019
*                                       TTR OF 551A                     54410019
GOTOMOD  LA    RJ,DXXCTL                WORK AREA FOR XCTL MACRO EXPAND 54600019
         XCTL  DE=DXXCTL+8,SF=(E,(15))  XCTL TO NEXT EOV LOAD           54800019
*                                                                     * 55000019
***** SET UP RMUCB TO POINT TO MAIN UCB                           ***** 55200019
*                                                                     * 55400019
MAINUCB  EQU   *                                                        55600019
         LH    RMUCB,DCELBBNR           PICK UP BB                      55800019
         SLA   RMUCB,COLI0004           TIMES 16                        56000019
         LA    RMUCB,DATACELL-UCBOB(RMUCB)                              56200019
*                                       16(BB)+MAIN UCB LENGTH          56400019
         LCR   RMUCB,RMUCB              NEGATE                          56600019
         AR    RMUCB,RUCB               MAIN UCB ADDRESS                56800019
         BR    RJ                       RETURN                          57000019
SETWKDEB ST    RMUCB,DXCCW11                                            57200019
         MVC   DXDEBUCB+COLI0001(COLI0003),DXCCW11+COLI0001             57400019
         MVC   DXDEBBIN(COLI0002),DCELBBNR                              57600019
         BR    RJ                       RETURN                          57800019
*                                                                     * 58000019
***** MOUNT MESSAGE CONSTANTS                                     ***** 58200019
*                                                                     * 58400019
         DS    0F                                                       58600019
INTRPS   DC    X'FF'                    MASK TO ALLOW PGM INTERUPTS     58800019
ACCW1    DC    X'6000000508'            SILI,COMMAND CHAIN,5 CHAR,TIC   59000019
COLCDUEX DC    X'0000000000C700097FFF'  CONSTANT                        59200019
MCSDESC1 DC    X'4000'                  MCS DESCRIPTER CODE             59400019
MCSROUT1 DC    X'1000'                  MCS ROUTING CODE                59600019
FLAG1    DC    X'8000'                  FLAG                            59800019
MESKEEP  DC    C'IEC002I K '            KEEP DATA CELL VOLUME MESSAGE   60000019
FLAG2    DC    X'8000'                  FLAG                            60200019
MOUNTCEL DC    C'IEC001A M '            MOUNT DATA CELL VOLUME MESSAGE  60400019
COLCVTOC DC    X'0000000000000003'      CONSTANT                        60600019
FIVEVOL  DC    F'5'                     TEST FOR FIVE VOLSERNOS SEARCH  60800019
CONST36  DC    H'36'                    CONSTANT 36                     61000019
*                                                                     * 61200019
***** IGG0559D XCTL TABLE                                         ***** 61400019
*                                                                     * 61600019
        ORG   IGG0559D+1000             ORG                             61800019
VJLD1A   DC    C'1A'                    IGG0551A                        62000019
         DC    X'00000000'              TTRL                            62200019
V9D2B    DC    C'2B'                    IGG0552B                        62400019
         DC    X'00000000'              TTRL                            62600019
V9D9D    DC    C'9D'                    MODULE ID                       62800019
         DC    X'00000000'              TTRL                            63000019
         DC    X'0000'                  FILLER                          63200019
         ORG   IGG0559D+1020            ORG                             63400019
LOADID   DC    C'055'                   LOAD MODULE ID                  63600019
         DC    X'7D'                    END OF XCTL TABLE               63800019
FORECORE DSECT                                                          64000019
         IECDSECT                                                       64200019
*                                                                     * 64400019
***** EOV ADDITIONAL WORK AREA                                    ***** 64600019
*                                                                     * 64800019
DXXCTL   DS    0CL37                                                    65000019
DXXCTLWA DS    CL37                     EOV WORK AREA                   65200019
OPCLSW   DS    CL1                      EOV SWITCH                      65400019
DXXCTLNM EQU   DXXCTL+40                MODULE NAME FOR XCTL            65600019
CVT      DSECT                                                          65800019
         CVT   SYS=MIN                                                  66000019
DEB      DSECT                                                          66200019
DEBNMSUB DS    0BL1                     NO. OF SUBR. LOADED BY OPEN     66400019
DEBTCBAD DS    A                        ADDR OF THE TCB FOR DEB         66600019
DEBAMDEP DS    0BL1                     NO OF BYTES IN ACCESS MTHD DPDT 66800019
DEBDEBAD DS    A                        ADDR OF PREVIOUS DEB IN TASK    67000019
DEBOFLGS DS    0XL1                     DATA SET STATUS FLAGS           67200019
DEBIRBAD DS    A                        IRB ADDR                        67400019
DEBOPATB DS    0XL1                     TYPE OF FILES                   67600019
DEBSYSPC DS    A                        ADDR OF 1ST IOB IN SYS PURGE    67800019
DEBNMEXT DS    0BL1                     NO OF EXTENTS SPECIFIED IN DSCB 68000019
DEBUSRPG DS    A                        ADDR OF 1ST IOB IN USER PURGE   68200019
DEBPRIOR DS    0BL1                     ALWAYS ZERO                     68400019
DEBECBAD DS    A                        ECB ADDR FOR SVC PURGE REQUEST  68600019
DEBPROTG DS    0XL1                     RESERVED FOR SVC PURGE REQUEST  68800019
DEBIDENT DS    0XL1                     HEX 'F' TO IDENTIFY BLK AS DEB  69000019
DEBDCBAD DS    A                        ADDR OF DCB ASSOC WITH DEB      69200019
DEBSCALE DS    0BL1                     EXTENT SCALE                    69400019
DEBAPPAD DS    A                        ADDR OF I/O APNDGE VECTOR TAB   69600019
DEBMODIF DS    0CL1                     DEV MODIFIER FILE MASK          69800019
DEBUCBAD DS    A                        ADDR OF UCB ASSOC WITH DATA EXT 70000019
DEBBINUM DS    CL2                      RES FOR FUTURE USE-ALWAYS ZERO  70200019
DEBSTRCC DS    CL2                      STARTING CYL NO FOR EXT         70400019
DEBSTRHH DS    CL2                      STARTING HEAD NO FOR EXT        70600019
DEBENDCC DS    CL2                      ENDING CYL NO FOR EXTENT        70800019
DEBENDHH DS    CL2                      ENDING HEAR NO FOR EXTENT       71000019
DEBNMTRK DS    CL2                      NO OF TRKS ALLOC TO EXTENT      71200019
DEBVOLSQ DS    CL2                      DEB VOL SEQ NO                  71400019
DEBVOLNM DS    CL2                      DEB VOLUME NO                   71600019
DEBSUBRT DS    CL2                      DEB SUBROUTINE                  71800019
UCB      DSECT                                                          72000019
         IEFUCBOB                                                       72200019
TIOT     DSECT                                                          72400019
         IEFTIOT1                                                       72600019
         DCBD  DSORG=(PS),DEVD=(DA)                                     72800019
         END                                                            73000019
