         TITLE 'READPSWD/OPEN, EOV, SCRATCH, RENAME - PASSWORD READING X00200021
               MODULE'                                                  00400021
         GBLC  &LIB                     DEFINE GLOBAL CHAR VARIABLE     00600021
&LIB     SETC  'LIB1'                   SET VALUE FOR OS /360           00800021
READPSWD CSECT                                                          01000021
*********************************************************************** 01200021
*                                                                     * 01400021
*                                                                     * 01600021
*          RELEASE 25 DELETIONS/CHANGES                               * 01800021
*          RELEASE 24 DELETIONS/CHANGES                               * 02000021
*          RELEASE 23 DELETIONS/CHANGES                               * 02200021
*          RELEASE 22 DELETIONS/CHANGES                               * 02400021
*          RELEASE 21 DELETIONS/CHANGES                               * 02600021
*                                                                S21042 02800021
*0000652000-664000                                              SA53227 02850001
*                                                                     * 03000021
* STATUS CHANGE LEVEL 000                                             * 03200021
*                                                                     * 03400021
* FUNCTION -                                                          * 03600021
*    THIS MODULE CONTAINS THE FUNCTION(S) OR PART(S) OF FUNCTION(S)-- * 03800021
*    OPEN SECURITY READ PASSWORD (READPSWD) FUNCTION                  * 04000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)' FOR DETAILS.         * 04200021
*                                                                     * 04400021
* ENTRY POINTS -                                                      * 04600021
*         READPSWD                                                    * 04800021
*                                                                     * 05000021
* INPUT -                                                             * 05200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 05400021
*                                                                     * 05600021
* OUTPUT -                                                            * 05800021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 06000021
*                                                                     * 06200021
* EXTERNAL REFERENCES -                                               * 06400021
*         REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                * 06600021
*                                                                     * 06800021
* EXITS, NORMAL -                                                     * 07000021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07200021
*                                                                     * 07400021
* EXITS, ERROR -                                                      * 07600021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 07800021
*                                                                     * 08000021
* TABLES/WORK AREAS -                                                 * 08200021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 08400021
*                                                                     * 08600021
* ATTRIBUTES -                                                        * 08800021
*    REENTRANT, REFRESHABLE, READ-ONLY, ENABLED, PRIVILEGED           * 09000021
*                                                                     * 09200021
* CHARACTER CODE DEPENDENCY -                                         * 09400021
*    CLASS ONE CHARACTER CODE DEPENDENCY - THE EBCDIC CHARACTER CODE  * 09600021
*    WAS USED FOR ASSEMBLY.  THE MODULE MUST BE REASSEMBLED IF A      * 09800021
*    DIFFERENT CHARACTER SET IS USED FOR EXECUTION.                   * 10000021
*                                                                     * 10200021
* NOTES -                                                             * 10400021
*    REFER TO THE FOLLOWING 'FUNCTION PROLOG(S)'.                     * 10600021
*                                                                     * 10800021
*********************************************************************** 11000021
         EJECT                                                          11200021
*********************************************************************** 11400021
*                                                                     * 11600021
*                          FUNCTION PROLOG                            * 11800021
*                                                                     * 12000021
*********************************************************************** 12200021
*                                                                     * 12400021
* FUNCTION NAME -                                                     * 12600021
*    OPEN SECURITY READ PASSWORD (READPSWD) FUNCTION                  * 12800021
*                                                                     * 13000021
* (STATUS) -                                                          * 13200021
*    NOT APPLICABLE                                                   * 13400021
*                                                                     * 13600021
* FUNCTION -                                                          * 13800021
*    WRITE MESSAGE IEC301A TO THE OPERATOR OR A TSO TERMINAL          * 14000021
*    REQUESTING THE PASSWORD FOR A DATA SET.  ACCEPT THE EIGHT        * 14200021
*    CHARACTER PASSWORD AND XCTL TO THE NEXT MODULE TO CHECK          * 14400021
*    IT AGAINST THE PASSWORD DATA SET.                                * 14600021
*                                                                     * 14800021
* ENTRY POINTS -                                                      * 15000021
*         READPSWD                                                    * 15200021
*                                                                     * 15400021
* INPUT -                                                             * 15600021
*    MYCODE1 INDICATES INITIAL ENTRY -                                * 15800021
*       00 FROM OPEN                                                  * 16000021
*       01 FROM EOV                                                   * 16200021
*       02 FROM RENAME                                                * 16400021
*       03 FROM SCRATCH                                               * 16600021
*    MYCODE2 INDICATES RETRY COUNT ACTIONS -                          * 16800021
*       00 INITIAL ENTRY.                                             * 17000021
*       01 TSO DSE TTR NOT PRESENT OR FAILED AND LOGON PASSWORD       * 17200021
*          NOT AVAILABLE.  GET PASSWORD FROM TERMINAL.                * 17400021
*       02 TSO WITH LOGON PW FAIL, GET PW FROM TERMINAL.              * 17600021
*       03 FIRST PASSWORD SUPPLIED WAS WRONG, ONE MORE TRY.           * 17800021
*       04 N/A HERE. SECOND PASSWORD SUPPLIED WAS WRONG.              * 18000021
*       05 N/A HERE. TSO DSE TTR WORKED.                              * 18200021
*       08 N/A HERE. TERMINAL SUPPLIED PW LONGER THAN 8 CHAR.         * 18400021
*       09 N/A HERE. I/O ERROR WHILE UPDATING RECORD READ             * 18600021
*          BY TSO DSE TTR.                                            * 18800021
*    AN EIGHT CHARACTER PASSWORD IS READ INTO MYREPLY.                * 19000021
*                                                                     * 19200021
*    NONE.                                                            * 19400021
* OUTPUT -                                                            * 19600021
*    MESSAGE IEC301A WRITTEN TO THE OPERATOR OR                       * 19800021
*    MESSAGE IEC113A, IEC115I, IEC116A, OR IEC117I WRITTEN            * 20000021
*    TO TSO TERMINAL.                                                 * 20200021
*                                                                     * 20400021
* EXTERNAL REFERENCES -                                               * 20600021
*                                                                     * 20800021
* EXITS, NORMAL -                                                     * 21000021
*   *XCTL TO IFG0195U IF ENTERED BY OPEN OR EOV.                      * 21200021
*   *XCTL TO SECLOADA IF ENTERED BY RENAME OR SCRATCH.                * 21400021
*                                                                     * 21600021
* EXITS, ERROR -                                                      * 21800021
*                                                                     * 22000021
* TABLES/WORK AREAS -                                                 * 22200021
*    THE FORMAT AND CONTENTS OF THE WORK AREAS USED ARE DESCRIBED BY  * 22400021
*    THE DSECTS AT THE END OF THE LISTING.                            * 22600021
*                                                                     * 22800021
* ATTRIBUTES -                                                        * 23000021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 23200021
*                                                                     * 23400021
* CHARACTER CODE DEPENDENCY -                                         * 23600021
*    REFER TO THE PRECEEDING MODULE PROLOG.                           * 23800021
*                                                                     * 24000021
* NOTES -                                                             * 24200021
*    FOR TSO TERMINALS, A BYPASS PRINT CHARACTER IS SENT JUST BEFORE  * 24400021
*    THE USER ENTERS HIS PASSWORD.  THIS PREVENTS THE PASSWORD FROM   * 24600021
*    PRINTING AT HIS TERMINAL WHEN HE KEYS IT IN.  THIS THEN PREVENTS * 24800021
*    ANYONE FROM FINDING OUT HIS PASSWORD FROM HIS TERMINAL LOG.      * 25000021
*                                                                     * 25200021
*********************************************************************** 25400021
         EJECT                                                          25600021
         IECDSECS CVT,TCB,JSCB,PSCB,    DEFINE DESIRED DSECTS TO BE    X25800021
               UPT,TIOT,UCB,            EXPANDED AT THE END            X26000021
               SECCORE,WTG                                              26200021
*                                                                       26400021
         IECEQU ,                       DEFINE EQUATES                  26600021
*                                                                       26800021
         USING WTG,RWTG                 DEFINE BASE TO XCTL/WTG TABLE   27000021
         USING TIOENTRY,RTIOT           DEFINE BASE TO TIOT DD ENTRY    27200021
         USING UCBOB,RUCB               DEFINE BASE TO MAIN UCB         27400021
         USING SECCORE,RD               DEFINE BASE TO SECURITY WK AREA 27600021
*                                                                       27800021
         BALR  RBASE,0                  ESTABLISH BASE REGISTER         28000021
         USING *,RBASE                  DEFINE BASE REGISTER            28200021
*                                                                       28400021
*        CHECK TRY COUNT FOR ENTRY CODE                                 28600021
*                                                                       28800021
         LTR   RUCB,RUCB                IS THIS INITAL ENTRY FROM       29000021
         BZ    OSQ40400                 RENAME/SCRATCH, BR IF NO        29200021
*                                                                       29400021
         XC    K4(K4,RCORE),K4(RCORE)   CLEAR XCTL DCB ADDR             29600021
         MVC   K8(K8,RCORE),OSQ4810K    SET MODULE NAME TO SECLOADA     29800021
         XCTL  EPLOC=K8(RCORE),SF=(E,(RCORE))  XCTL BY NAME TO SECLOADA 30000021
*                                                                       30200021
**********************************************************************  30400021
*                                                                       30600021
OSQ40400 EQU   *                                                        30800021
         CLI   MYCODE2,K1               IS TRY COUNT 1                  31000021
         BE    OSQ44000                 BR IF YES                       31200021
         CLI   MYCODE2,K2               IS TRY COUNT 2                  31400021
         BE    OSQ44000                 TRY COUNT WAS 2                 31600021
         BH    OSQ45000                 TRY COUNT WAS 3                 31800021
*                                       TRY COUNT WAS 0                 32000021
*        TRY COUNT 0 ACTION FOLLOWS                                     32200021
*                                                                       32400021
         MVI   MYCODE2,K3               SET TRY COUNT TO 3              32600021
*                                                                       32800021
*********************************************************************** 33000021
*                                                                       33200021
*  CONSTRUCT 'IEC301A S JOB JOBNAMEX,STEP STEPNAME,DDNAME DDNAMEXX'     33400021
*  MESSAGE WITH OPTIONAL ',CONC000' IF CONCATENATED.                    33600021
*                                                                       33800021
OSQ41000 EQU   *                                                        34000021
         MVC   MYMCSFLG(OSQ4830L),OSQ4830K  TURN ON MCS FLAG IN MSG AND 34200021
*                                       MOVE 'IEC301A S JOB ' TO MSG    34400021
*                                                                       34600021
         CLI   MYCODE1,K1               SCRATCH OR RENAME               34800021
         BH    OSQ42000                 BR IF YES                       35000021
*                                                                       35200021
         L     R1,CVTPTR                GET CVT ADDR                    35400021
         L     R1,CVTTCBP-CVT(,R1)      GET ADDR TCB POINTERS           35600021
         L     R1,K4(,R1)               GET CURRENT TCB ADDR            35800021
         L     R1,TCBTIO-TCB(,R1)       GET TIOT ADDRESS                36000021
         MVC   MYMJOBN,TIOCNJOB-TIOT(R1)  JOB NAME TO MESSAGE           36200021
         MVC   MYMSTEP,OSQ4835K         ',STEP ' TO MESSAGE             36400021
         MVC   MYMSTEPN,TIOCSTEP-TIOT(R1)  JOB STEP TO MESSAGE          36600021
         MVC   MYMDDNM,OSQ4840K         ',DDNAME ' TO MESSAGE           36800021
*                                                                       37000021
         CLI   TIOEDDNM,BLANK           IS DD NAME PRESENT              37200021
         BE    OSQ41200                 BRANCH IF NO                    37400021
*                                                                       37600021
         MVC   MYMDDNMN,TIOEDDNM        DD NAME TO MESSAGE              37800021
         LA    R1,MYMDDNMN+K7           POINT TO LAST CHAR OF DDNAME    38000021
         B     OSQ42200                 BR TO REMOVE TRAILING BLANKS    38200021
*                                                                       38400021
OSQ41200 EQU   *                                                        38600021
         LA    R1,TIOENTRY-TIOT(,R1)    BYPASS JOB AND STEP NAMES       38800021
         SR    RF,RF                    CLEAR REG TO GET ENTRY LENGTH   39000021
*                                                                       39200021
OSQ41400 EQU   *                                                        39400021
         MVC   MYMDDNMN,TIOEDDNM-TIOENTRY(R1)  CURRENT DDAME TO MSG     39600021
         LA    R0,K1                    SET CONCATENATION CTR TO 1      39800021
*                                                                       40000021
OSQ41600 EQU   *                                                        40200021
         CR    RTIOT,R1                 CHECK IF CURRENT ENTRY          40400021
         BE    OSQ41800                 BR IF YES                       40600021
         IC    RF,TIOELNGH-TIOENTRY(,R1)  TIOT ENTRY LENGTH             40800021
         AR    R1,RF                    STEP TO NEXT ENTRY              41000021
         CLI   TIOEDDNM-TIOENTRY(R1),C' '  IS DDNAME PRESENT            41200021
         BNE   OSQ41400                 BRANCH IF NO                    41400021
         AH    R0,OSQ4800K              INCR CONCATENATION CTR BY 1     41600021
         B     OSQ41600                 BR TO CHECK NEXT ENTRY          41800021
*                                                                       42000021
OSQ41800 EQU   *                                                        42200021
         CVD   R0,MYCVDWA               CONVERT CONCAT NO. TO DECIMAL   42400021
         UNPK  MYMCONCN,MYCVDWA         CONCAT NO. TO MESSAGE AREA      42600021
         OI    MYMCONCN+K2,ZONEOF       REMOVE SIGN BITS                42800021
         MVC   MYMCONC,OSQ4845K         ',CONC' TO MESSAGE              43000021
         LA    R1,MYMCONCN+K2           POINT TO LAST CHAR OF CONC000   43200021
         B     OSQ42400                 BR TO ADD LENGTH AND MCS CODES  43400021
*                                                                       43600021
*********************************************************************** 43800021
*                                                                       44000021
*  CONSTRUCT  'IEC301A S DSNAME DSNAMEXX'  MSG FOR SCRATCH/RENAME.      44200021
*                                                                       44400021
OSQ42000 EQU   *                                                        44600021
         MVC   MYMDSN(K7),OSQ4855K      'DSNAME ' TO MESSAGE            44800021
         MVC   MYMDSNN(K44),0(RB)       DSNAME FOR SCRATCH/RENAME       45000021
         LA    R1,MYMDSNN+K43           POINT TO LAST CHAR OF DSNAME    45200021
*                                                                       45400021
OSQ42200 EQU   *                                                        45600021
         CLI   0(R1),BLANK              IS IT NON-BLANK                 45800021
         BNE   OSQ42400                 BR IF YES                       46000021
         BCT   R1,OSQ42200              REPEAT IF NON-BLANK NOT FOUND   46200021
*                                                                       46400021
OSQ42400 EQU   *                                                        46600021
         MVC   K1(K4,R1),OSQ4850K       MOVE IN DESC & ROUT CODES       46800021
         LA    RF,MYMSIZE-K1            ADDR START OF MSG-1             47000021
         SR    R1,RF                    CALCULATE MESSAGE LENGTH        47200021
         STH   R1,MYMSIZE               STORE MESSAGE LENGTH            47400021
*                                                                       47600021
*********************************************************************** 47800021
*********************************************************************** 48000021
*********************************************************************** 48200021
*********************************************************************** 48400021
*********************************************************************** 48600021
***                                                                 *** 48800021
***THE SECTION OF CODE BELOW, ENCLOSED BY COMMENTS, IS THE ONLY     *** 49000021
***SECTION OF THIS MODULE (READPSWD) WHICH CAN BE REPLACED BY THE   *** 49200021
***USER IN ORDER TO ENTER A PASSWORD FOR A SECURITY-PROTECTED DATA  *** 49400021
***SET. THE REPLACED CODE BELOW ENTERS THE PASSWORD FROM THE CONSOLE*** 49600021
***USING A WTOR. THE SECURITY WORK AREA DEFINED BY THE              *** 49800021
***DSECT SECCORE CONTAINS THE MESSAGE IEC301A S JOB..... FORMATTED  *** 50000021
***PROPERLY FOR OPEN,EOV,SCRATCH OR RENAME AND THE FIELDS WITHIN THIS** 50200021
***MESSAGE MAY BE USED AS REQUIRED. NOTE THAT WHEN THE FOLLOWING    *** 50400021
***CODE IS REPLACED, THE SYSTEM MESSAGE IEC301A..... NO LONGER      *** 50600021
***APPEARS ON THE CONSOLE. SAVE AND RESTORE REGISTERS, IF WORK      *** 50800021
***REGISTERS ARE NEEDED. GET/FREEMAIN NEEDED CORE, IF ADDITIONAL    *** 51000021
***WORK AREA IS REQUIRED. THE NET RESULT OF THIS REPLACED CODE IS   *** 51200021
***THAT THE 8-CHARACTER PASSWORD, LEFT-JUSTIFIED AND PADDED WITH    *** 51400021
***BLANKS, MUST BE PLACED IN LOCATION MYREPLY IN THE DSECT SECCORE. *** 51600021
***                                                                 *** 51800021
         LA    R1,MYREPLY               PUT ADDRESS OF REPLY            52000021
         ST    R1,MYRPLADR              INTO MYRPLADR                   52200021
         MVI   MYRPLLTH,L'MYREPLY       SET REPLY LENGTH TO 8           52400021
         LA    R1,MYLOGFLD              PUT ECB ADDRESS                 52600021
         ST    R1,MYRPLECB              INTO MYRPLECB                   52800021
         XC    MYLOGFLD(K4),MYLOGFLD    CLEAR ECB FIELD                 53000021
         MVI   MYREPLY,C' '             SET REPLY                       53200021
         MVC   MYREPLY+K1(K7),MYREPLY   AREA TO BLANKS                  53400021
*                                                                       53600021
         WTOR  MF=(E,MYRPLLTH)          WRITE MESSAGE TO OPERATOR       53800021
*                                                                       54000021
         WAIT  ECB=MYLOGFLD             WAIT FOR REPLY                  54200021
***                                                                 *** 54400021
***THE ABOVE SECTION OF CODE IS THE ONLY SECTION IN THIS MODULE     *** 54600021
***WHICH CAN BE REPLACED.                                           *** 54800021
***                                                                 *** 55000021
*********************************************************************** 55200021
*********************************************************************** 55400021
*********************************************************************** 55600021
*********************************************************************** 55800021
*********************************************************************** 56000021
*                                                                       56200021
OSQ43000 EQU   *                                                        56400021
         XC    MYXCTL+K4(K4),MYXCTL+K4  ZERO XCTL HIARCHY AND DCB ADDR  56600021
*                                                                       56800021
         CLI   MYCODE1,K1               IS ENTRY FROM OPEN OR EOV       57000021
         BH    OSQ43200                 BR IF NO, FROM RENAME/SCRATCH   57200021
*                                                                       57400021
         MVC   WTGMODNM,OSQ4820K        SET WTG MODULE NAME TO IFG0195U 57600021
         XCTL  EPLOC=(RWTG),SF=(E,MYXCTL)  XCTL BY NAME TO IFG0195U     57800021
*                                                                       58000021
OSQ43200 MVC   MYMODNM,OSQ4810K         SET MODULE NAME TO SECLOADA     58200021
         XCTL  EPLOC=MYMODNM,SF=(E,MYXCTL)  XCTL BY NAME TO SECLOADA    58400021
*                                                                       58600021
*********************************************************************** 58800021
*                                                                       59000021
*        TRY COUNT 3 ACTION FOLLOWS                                     59200021
*        TPUT MESSAGE IEC113A TO TSO USER FOR PASSWORD                  59400021
*                                                                       59600021
*        ENTRY - TSO AND TRY COUNT WAS 1 OR 2                           59800021
*                                                                       60000021
OSQ44000 EQU   *                                                        60200021
         MVI   MYCODE2,K3               SET TRY COUNT TO 3              60400021
         L     R1,CVTPTR                GET CVT ADDR                    60600021
         L     R1,CVTTCBP-CVT(,R1)      GET ADDR TCB POINTERS           60800021
         L     R1,K4(,R1)               GET CURRENT TCB ADDR            61000021
         L     R1,TCBJSCB-TCB(,R1)      GET JSCB ADDRESS                61200021
         L     R1,JSCBPSCB-IEZJSCB(,R1)  GET PSCB ADDR                  61400021
         USING PSCB,R1                                                  61600021
         LA    R1,0(R1)                 CLEAR HIGH ORDER BYTE   SA53227 61650001
         LTR   R1,R1                    IS PSCB PRESENT         SA53227 61700001
         BZ    OSQ44100                 NO, INCLUDE ID          SA53227 61750001
         L     RET,PSCBUPT              GET UPT ADDR                    61800021
         DROP  R1                                                       62000021
         USING UPT,RET                                                  62200021
         LA    RET,0(RET)               CLEAR HIGH ORDER BYTE   SA53227 62250001
         LTR   RET,RET                  IS UPT PRESENT          SA53227 62300001
         BZ    OSQ44100                 NO, INCLUDE ID          SA53227 62350001
         TM    UPTSWS,UPTMID            IS ID REQUIRED          SA53227 62360001
         BO    OSQ44100                 YES, INCLUDE ID         SA53227 62370001
         LA    R1,MYMIEC+K8             MSG BUFR TO EXCLUDE ID  SA53227 62380001
         DROP RET                                               SA53227 62390001
         B     OSQ44150                 SET UP MSG              SA53227 62392001
OSQ44100 EQU   *                                                SA53227 62394001
         LA    R1,MYMIEC                MSG BUFR TO INCLUDE ID  SA53227 62396001
OSQ44150 EQU   *                                                SA53227 62398001
*                                                                       62400021
         MVC   MYMIEC(L'OSQ4860K),OSQ4860K  SET MESSAGE ID AND BODY     62600021
         MVC   MYMIEC+K36(K44),0(RB)    MOVE DSNAME TO MESSAGE          62800021
*                                                                       63000021
*    SCAN FOR END OF DSNAME FIELD                                       63200021
*                                                                       63400021
         LA    RF,MYMIEC+K35+K44        POINT TO LAST CHAR OF DSNAME    63600021
*                                                                       63800021
OSQ44200 CLI   0(RF),BLANK              IS THIS NON-BLANK               64000021
         BNE   OSQ44400                 BR IF YES                       64200021
         BCT   RF,OSQ44200              REPEAT IF NON-BLANK NOT FOUND   64400021
*                                                                       64600021
OSQ44400 MVI   K1(RF),X'24'             INSERT PRINT BYPASS CHAR        64800021
         LA    R0,K2(RF)                ADDR END OF MESSAGE + 1         65000021
*                                                                       66600021
OSQ44600 SR    R0,R1                    CALC LENGTH OF MESSAGE          66800021
         BAL   RDCB,OSQ46000            GET PASSWORD FROM TERMINAL      67000021
*                                                                       67200021
         CLI   MYRPLLTH,X'0C'           WAS REPLY TOO LONG              67400021
         BNE   OSQ43000                 BR IF NO TO CHECK PASSWORD      67600021
*                                                                       67800021
         TCLEARQ INPUT                  CLEAR INPUT QUEUE               68000021
*                                                                       68200021
*********************************************************************** 68400021
*                                                                       68600021
*        TRY COUNT 4 ACTION FOLLOWS                                     68800021
*        REPEAT MSG IEC301A TO OPERATOR FOR BATCH WITH WTOR             69000021
*        OR                                                             69200021
*        TPUT MSG 'IEC115I INVALID PASSWORD' TO TERMINAL USER           69400021
*        TPUT MSG 'IEC116A REENTER-' TO REPROMPT TERMINAL USER          69600021
*        LAST TRY IN EITHER CASE                                        69800021
*                                                                       70000021
*        ENTRY - TRY COUNT WAS 3                                        70200021
*                                                                       70400021
OSQ45000 EQU   *                                                        70600021
         MVI   MYCODE2,K4               SET LAST TRY COUNT TO 4         70800021
*                                                                       71000021
         L     R1,CVTPTR                GET ADDR OF CVT                 71200021
         TM    CVTDCB-CVT(R1),CVT4MS1   IS THIS MVT                     71400021
         BZ    OSQ41000                 BR IF NO                        71600021
*                                                                       71800021
         L     R1,CVTTCBP-CVT(,R1)      GET ADDR TCB POINTERS           72000021
         L     R1,K4(,R1)               GET CURRENT TCB ADDR            72200021
         TM    TCBTSFLG-TCB(R1),TCBTSTSK  IS THIS A TSO TASK            72400021
         BZ    OSQ41000                 BR IF NO                        72600021
*                                                                       72800021
         L     R1,TCBJSCB-TCB(,R1)      GET JSCB ADDR                   73000021
         USING IEZJSCB,R1               DEFINE BASE TO JSCB             73200021
         NC    JSCBTJID,JSCBTJID        CHECK IF TJID IS ZERO           73400021
         BZ    OSQ41000                 BR IF ZERO, NOT TSO TERMINAL    73600021
*                                                                       73800021
*        REPROMPT FOR PASSWORD FOR TSO                                  74000021
*                                                                       74200021
         L     R1,JSCBPSCB              GET PSCB                        74400021
         USING PSCB,R1                                                  74600021
         LA    R1,0(R1)                 CLEAR HIGH ORDER BYTE   SA53227 74650001
         LTR   R1,R1                    IS PSCB PRESENT         SA53227 74700001
         BZ    OSQ45900                 NO, INCLUDE ID          SA53227 74750001
         L     RET,PSCBUPT              GET UPT ADDR                    74800021
         DROP  R1                                                       75000021
         USING UPT,RET                                                  75200021
         LA    RET,0(RET)               CLEAR HIGH ORDER BYTE   SA53227 75250001
         LTR   RET,RET                  IS UPT PRESENT          SA53227 75300001
         BZ    OSQ45900                 NO, INCLUDE ID          SA53227 75350001
*                                                                       75400021
*        GENERATE MESSAGE ID                                            75600021
*                                                                       75800021
         MVC   MYMIEC(L'OSQ4870K),OSQ4870K  SET MESSAGE ID AND BODY     76000021
         LA    R0,L'OSQ4870K            SET LENGTH TO INCL ID           76200021
         LA    R1,MYMIEC                POINT MSG BUFR TO INCL ID       76400021
*                                                                       76600021
         TM    UPTSWS,UPTMID            IS MESSAGE ID REQUIRED          76800021
         BO    OSQ45600                 BR IF YES                       77000021
*                                                                       77200021
         LA    R0,L'OSQ4870K-K8         SET LENGTH TO EXCLUDE ID        77400021
         LA    R1,MYMIEC+K8             POINT MSG BUFR PAST ID          77600021
*                                                                       77800021
OSQ45600 EQU   *                                                        78000021
         BAL   RDCB,OSQ46400            GO SEND MESSAGE TO TERMINAL     78200021
*                                                                       78400021
         MVC   MYMIEC(L'OSQ4880K),OSQ4880K  SET MESSAGE ID AND BODY     78600021
         LA    R1,MYMIEC                SET BUFR ADDR TO INCLUDE ID     78800021
         LA    R0,L'OSQ4880K            SET LENGTH TO INCLUDE ID        79000021
*                                                                       79200021
         TM    UPTSWS,UPTMID            IS MESSAGE ID REQUIRED          79400021
         BO    OSQ45800                 BR IF YES                       79600021
*                                                                       79800021
         LA    R1,MYMIEC+K8             POINT BUFR PAST ID              80000021
         LA    R0,L'OSQ4880K-K8         SET LENGTH TO EXCLUDE ID        80200021
         DROP  RET                                                      80400021
*                                                                       80600021
OSQ45800 EQU   *                                                        80800021
         BAL   RDCB,OSQ46000            GET PASSWORD FROM TERMINAL      81000021
*                                                                       81200021
         CLI   MYRPLLTH,X'0C'           WAS REPLY TOO LONG              81400021
         BNE   OSQ43000                 BR IF NO TO CHECK PASSWORD      81600021
*                                                                       81800021
         MVI   MYCODE2,K8               PUT ERROR CODE 8 IN MYCODE2     82000021
         TCLEARQ INPUT                  CLEAR INPUT QUEUE               82200021
         B     OSQ43000                 BR TO NEXT MODULE               82400021
OSQ45900 EQU   *                                                SA53227 82450001
         MVC   MYMIEC(L'OSQ4870K),OSQ4870K  SET MSG ID AND BODY SA53227 82500001
         LA    R0,L'OSQ4870K            SET LENGTH TO INCL ID   SA53227 82550001
         LA    R1,MYMIEC                MSG BUFR TO INCL ID     SA53227 82560001
         BAL   RDCB,OSQ46400            SEND MSG TO TERMINAL    SA53227 82570001
         MVC   MYMIEC(L'OSQ4880K),OSQ4880K  SET MSG ID AND BODY SA53227 82580001
         LA    R1,MYMIEC                MSG BUFR TO INCL ID     SA53227 82590001
         LA    R0,L'OSQ4880K            SET LENGTH TO INCL ID   SA53227 82592001
         B     OSQ45800                 GET PASSWORD            SA53227 82594001
*                                                                       82600021
*********************************************************************** 82800021
*                                                                       83000021
OSQ46000 EQU   *                                                        83200021
         O     R1,OSQ4892K              SET TPUT ASIS OPTION            83400021
         TPUT  (1),(0),R                ISSUE TPUT                      83600021
*                                                                       83800021
         LA    R0,L'MYREPLY             SET MAX REPLY LENGTH TO 8       84000021
         LA    R1,MYREPLY               POINT TO REPLY ADDRESS          84200021
         O     R1,OSQ4894K              SET TGET WAIT OPTION            84400021
         TGET  (1),(0),R                ISSUE TGET                      84600021
         STC   RF,MYRPLLTH              SAVE TGET RETURN CODE           84800021
         OC    MYREPLY,OSQ4890K         FOLD REPLY TO UPPER CASE        85000021
*                                                                       85200021
         MVI   MYMAREA,X'14'            PUT RESTORE CHAR IN BUFR        85400021
         LA    R0,K1                    SET MESSAGE LENGTH              85600021
         LA    R1,MYMAREA               POINT TO MESSAGE ADDRESS        85800021
*                                                                       86000021
OSQ46400 EQU   *                                                        86200021
         O     R1,OSQ4892K              SET TPUT ASIS OPTION            86400021
         TPUT  (1),(0),R                ISSUE TPUT                      86600021
         BR    RDCB                     RETURN TO MAINLINE              86800021
*                                                                       87000021
*********************************************************************** 87200021
*                                                                       87400021
*        CONSTANTS                                                      87600021
*                                                                       87800021
OSQ4800K DC    H'1'                     CONSTANT 1                      88000021
OSQ4810K DC    C'SECLOADA'              SCRATCH/RENAME PSWD CHECK MOD   88200021
OSQ4820K DC    C'IFG0195U'              OPEN/EOV PSWD CHECK MODULE      88400021
*                                                                       88600021
OSQ4830K DC    X'8000'                  MCS MESSAGE FLAG                88800021
         DC    C'IEC301A S JOB '        FIXED PART OF MESSAGE           89000021
OSQ4830L EQU   *-OSQ4830K               LENGTH OF PART OF MSG           89200021
OSQ4835K DC    C',STEP '                FIXED PART OF MESSAGE           89400021
OSQ4840K DC    C',DDNAME '              FIXED PART OF MESSAGE           89600021
OSQ4845K DC    C',CONC'                 FIXED PART OF MESSAGE           89800021
OSQ4850K DC    X'40000080'              DESCRIPTOR, ROUTING CODES       90000021
OSQ4855K DC    C'DSNAME '               FIXED PART OF MESSAGE           90200021
*                                                                       90400021
OSQ4860K DC    C'IEC113A ENTER PASSWORD FOR DATA SET '  TSO MESSAGE     90600021
OSQ4870K DC    C'IEC115I INVALID PASSWORD'  TSO INVALID PASSWORD MSG   90800021
*              NOTE THAT THE LAST CHARACTER IS X'15' - NEW LINE         91000021
OSQ4880K DC    C'IEC116A REENTER-'     TSO REPROMT FOR PASSWORD MSG    91200021
*              NOTE THAT THE LAST CHARACTER IS X'24' - BYPASS PRINT     91400021
*                                                                       91600021
OSQ4890K DC    X'4040404040404040'      USED TO FOLD TSO REPLY TO       91800021
*                                       UPPER CASE                      92000021
OSQ4892K DC    0F'0',X'01000000'        TPUT W/ASIS OPTION              92200021
OSQ4894K DC    0F'0',X'80000000'        SVC 93 TGET OPTION              92400021
*                                                                       92600021
*  AUTOMATIC PATCH AREA EXPANDS TO FILL AREA AVAILABLE.  IT WILL        92800021
*  NOT EXCEED 100 BYTES, NOR CAUSE MODULE TO EXCEED 1024 BYTES.         93000021
*                                                                       93200021
PATCSWD0 EQU   *-READPSWD               LENGTH BEFORE PATCH AREA        93400021
PATCSWD1 EQU   (2049-2*PATCSWD0)/(2048-2*PATCSWD0)*(1024-PATCSWD0)      93600021
PATCSWD2 EQU   (1849-2*PATCSWD0)/(1848-2*PATCSWD0)*(0924-PATCSWD0)      93800021
PATCHSWD EQU   PATCSWD1-PATCSWD2        LENGTH OF PATCH AREA            94000021
         DC    (PATCSWD1-PATCSWD2)X'00'  ZEROED PATCH AREA              94200021
         DC    0D'0'                    PAD MODULE TO DOUBLE WORD       94400021
*                                                                       94600021
         IECDSECS EXPAND=YES            EXPAND DESIRED DSECTS HERE      94800021
*                                                                       95000021
         END                                                            95200021
