         TITLE 'IGC0005C -- RELEASE EXCLUSIVE CONTROL (RELEX) SVC.'     00003001
         COPY  LCGASMSW                                                 00013001
IGC0005C CSECT                                                          00020000
*          RELEASE 21 DELETIONS                                         00030021
*7030012400,021000,022400,023000,024600                          A35339 00032021
*                                                               SA53131 00036021
*                                                               SA55595 00040002
*                                                               SA62454 00050021
*                                                                XM2975 00052002
* THE FIX FOR SA63754 IS FLAGGED XM2975                         SA63754 00054021
*                                                               SA69157 00056021
* THE FIX FOR YA03633 IS FLAGGED SA69157                        YA03633 00058021
* THE FIX FOR XA04482 IS FLAGGED SA69157                        XA04482 00058421
*STATUS - CHANGE LEVEL 5   10/26/73                                     00060021
*                                                                     * 00080000
*FUNCTIONS - THIS ROUTINE IS ENTERED WHEN THE PROBLEM PROGRAM ISSUES  * 00100000
*    AN SVC 53 (VIA THE RELEX MACRO). THE ROUTINE SETS UP FOR ENTRY   * 00120000
*    TO THE BDAM READ EXCLUSIVE MODULE BY CONVERTING THE ADDRESS      * 00140000
*    OF THE RECORD PASSED,TO AN ACTUAL DISK ADDRESS AND PLACING THIS  * 00160000
*    ACTUAL ADDRESS IN A DUMMY IOB FOR THE READ EXCLUSIVE MODULE      * 00180000
*                                                                     * 00200000
*ENTRY POINT - WHEN AN SVC 53 IS ISSUED THIS ROUTINE IS READ INTO THE * 00220000
*    TRANSIENT AREA AND GIVEN CONTROL AT ITS ENTRY POINT 'IGC0005C'.  * 00240000
*                                                                     * 00260000
*INPUT - INPUTS TO THIS ROUTINE ARE                                   * 00280000
*    REGISTER 0 - ADDRESS OF THE DISK ADDRESS(ACTUAL,RELATIVE TRACK,OR* 00300000
*                 RELATIVE BLOCK) OF THE RECORD BEING RELEASED.       * 00320000
*    REGISTER 1 - DCB ADDRESS                                         * 00340000
*    REGISTER 4 - TCB ADDRESS (LOADED BY SUPERVISOR)                  * 00350021
*                                                                     * 00360000
*OUTPUT - THIS ROUTINE SETS UP FOR ENTRY TO THE BDAM ADDRESS          * 00380000
*    CONVERSION ROUTINES(IF NECESSARY) ACCORDING TO THEIR NEEDS.      * 00400000
*    THIS ROUTINE ALSO SETS UP A DUMMY IOB FOR THE READ EXCLUSIVE     * 00420000
*    MODULE OF BDAM.                                                  * 00440000
*                                                                     * 00460000
*EXTERNAL ROUTINES - 'IGG019KC' CONVERT RELATIVE TRACK ADDRESS (TTR)  * 00480000
*    TO AN ACTUAL ADDRESS                                             * 00500000
*                                                                     * 00520000
*    'IGG019KE' CONVERT RELATIVE BLOCK ADDRESS TO AN ACTUAL ADDRESS   * 00540000
*                                                                     * 00560000
*    'IGG019KF' CONVERT RELATIVE BLOCK ADDRESS TO AN ACTUAL ADDRESS   * 00580000
*    FOR OVERFLOW RECORDS                                             * 00600000
*                                                                     * 00620000
*    'IGG019LG' RELEASE EXCLUSIVE CONTROL OF THE RECORD PASSED        * 00640000
*                                                                     * 00660000
*EXITS - AN 'SVC EXIT' IS ISSUED AFTER RETURN FROM THE BDAM READ      * 00680000
*    EXCLUSIVE ROUTINE                                                * 00700000
*                                                                     * 00720000
*    'ERRTRN' IS AN ERROR RETURN IF THE RELATIVE (TRACK OR BLOCK)     * 00740000
*    ADDRESS PASSED IS NOT WITHIN THE LIMITS OF THE DATA SET          * 00760000
*                                                                     * 00780000
*TABLES/WORK AREAS - A 104 BYTE GETMAIN IS ISSUED TO OBTAIN CORE FOR  * 00800000
*    A DUMMY IOB WHICH IS USED AS AN IOB AND WORKAREA.                * 00820000
*                                                                     * 00840000
*ATTRIBUTES - THIS ROUTINE IS REENTRANT AND IS EXECUTED DISABLED,     * 00860000
*    PRIVILEGED, AND WITH THE SUPERVISOR'S PROTECT KEY.               * 00880000
*                                                                     * 00900000
*                                                                     * 00920000
*                                                                     * 00940000
         EJECT                                                          00960000
PARREG0  EQU   0              ADDRESS OF THE BLOCK REFERENCE            00980000
PARREG1  EQU   1              ADDRESS OF THE DCB                        01000000
DEBREG   EQU   3              ADDRESS OF THE DEB FOR CONVERT ROUTINES   01020000
DCBREG   EQU   4              ADDRESS OF THE DCB FOR CONVERT ROUTINES   01040000
TASKERR  EQU   12       RETURN CODE FOR WRONG TASK ISSUING SVC   A35339 01046021
TCBREG   EQU   4              ADDR OF ISSUING TASK'S TCB         A35339 01052021
DECBREG  EQU   5              ADDRESS OF THE DECB FOR CONVERT ROUTINES  01060000
WKREG1   EQU   6              WORK REGISTER                             01080000
IOBREG   EQU   7              ADDRESS OF THE IOB FOR CONVERT ROUTINES   01100000
RETURN   EQU   9              RETURN REGISTER FROM READ EXCLUSIVE MOD.  01120000
RDXBASE  EQU   10             BASE REGISTER FOR READ EXCLUSIVE MODULE   01140000
FDNBASE  EQU   11             BASE ADDRESS FOR FOUNDATION MODULE(FAKE)  01160000
RDXIOBRG EQU   12             IOB REGISTER FOR THE READX MODULE         01180000
BASEREG  EQU   13             BASE REGISTER FOR THIS MODULE             01200000
RETREG   EQU   14             RETURN REGISTER FROM OTHER MODULES        01220000
DXBASE   EQU   15                      BASE FOR ROUTINES BR TO   A35339 01240021
SKPHIBYT EQU   1                  SKIP HIGH BYTE OF FIELD               01250001
CPEND    EQU   X'58'          OFFSET END OF CHAN PGM            SA69157 01252021
UNAVAL   EQU   X'FF'          UNAVAILABLE FLAG FOR IOB          SA69157 01254021
LENIOB   EQU   X'9C'          LEN OF IOB                        SA69157 01256021
LENCORE  EQU   X'C0'          TOTAL CORE OBTAINED               SA69157 01258021
UNRLCC   EQU   X'42'          FLAG FOR IOB                      SA69157 01258421
NOPCCW   EQU   X'03'          NOP COMMAND CODE                  SA69157 01258821
SILIBIT  EQU   X'20'          SILI BIT FOR CCW                  SA69157 01259221
COUNTCCW EQU   X'57'          OFFSET COUNT FIELD OF CCW         SA69157 01259621
BADRELX  EQU   X'01'          BAD RETURN CODE FROM RELEASE      SA69157 01259721
ERADOFT  EQU   X'A8'          ERROR ROUTINE ADDR                SA69157 01259821
ACTEXCL  EQU   X'0A'          ACTUAL ADDR, EXCLUSIVE CONTROL    SA69157 01259921
FLGCCW   EQU   X'54'          OFFSET CCW FLAG FIELD             SA69157 01266621
         USING RELEXSVC,BASEREG                                         01273321
         USING IHADCB,PARREG1                                           01280000
         USING DECBDEF,DECBREG                                          01300000
         USING IOBDEF,IOBREG                                            01320000
*                                                                       01340000
         EJECT                                                          01360000
         BALR  BASEREG,0               SET BASE REGISTER                01380000
RELEXSVC EQU   *                                                        01400000
         TM    DCBDSORG,BDAM           IS THIS RELEX FORBDAM            01420000
         BO    DAMSETUP                YES- GO SET UP FOR ENTRY TO BDAM 01440000
*                                                                       01460000
*              ISAM SECTION GOES HERE                                   01480000
*                                                                       01500000
DAMSETUP EQU   *                                                        01520000
         AIF   ('&LIB' NE 'LIB1').LIB1AA                                01520501
         SSM   ENABLE                   ENABLE ALL INTERRUPTS    A35339 01521021
.LIB1AA  ANOP                                                           01521501
*                       TEST WHETHER ISSUING TASK OPENED THIS           01522021
*                        DCB (DOES DEB POINT TO ISSUER'S TCB?).         01523021
*                        IF NOT, RETURN WITH R15 = 12.                  01524021
*                                                                       01525021
         L     DEBREG,DCBDEBAD          GET DEB ADDR FROM DCB    A35339 01526021
         USING DEBBASIC,DEBREG          ESTABLISH DEB            A35339 01527021
*                                       ADDRESSABILITY           A35339 01528021
         L     WKREG1,DEBTCBAD          GET TCB ADDR FROM DEB    A35339 01529021
         LA    WKREG1,0(WKREG1)         CLEAR HI-ORDER BYTE      A35339 01530021
         CR    WKREG1,TCBREG            DID CALLER OPEN DCB?     A35339 01531021
         BE    RELEX2                    BRANCH IF YES           A35339 01532021
         LA    DXBASE,TASKERR            ELSE LOAD ERROR CODE    A35339 01533021
         SVC   EXIT                      AND RETURN              A35339 01534021
         DROP  DEBREG                                            A35339 01535021
*                                                                       01536021
RELEX2   EQU   *                                                 A35339 01537021
         DROP  PARREG1                                                  01540000
         USING IHADCB,DCBREG                                            01560000
         LR    WKREG1,PARREG0          SAVE BLKREF ADDRESS              01580000
         LR    DCBREG,PARREG1          MOVE DCB ADDRESS TO DCBREG       01600000
         LA    PARREG1,250              GET SUBPOOL NUMBER       A35339 01606021
         SLL   PARREG1,24               MOVE TO HIGH ORDER BYTE  A35339 01612021
         LA    PARREG0,LENCORE          LOAD LENGTH             SA69157 01620021
         OR    PARREG0,PARREG1          SET UP REG 0 FOR GETMAIN A35339 01626021
*                                       LV                       A35339 01632021
         GETMAIN R,LV=(0)                                               01640000
         L     DEBREG,DCBDEBAD         GET DEB ADDRESS                  01660000
         LR    IOBREG,PARREG1          PUT ADDRESS OF GOTTEN CORE       01680000
         XC    0(LENCORE,IOBREG),0(IOBREG)  CLEAR  AREA         SA69157 01700021
         LA    FDNBASE,LENIOB           LOAD LENGTH OF IOB      SA69157 01720021
         STH   FDNBASE,IOBDIOBS         STORE LENGTH IN IOB             01740000
         LA    DECBREG,LENIOB(IOBREG)   ADDR OF ECB             SA69157 01760021
         LA    FDNBASE,ERADOFT(IOBREG)  ADDR OF ERROR ROUTINE   SA69157 01780021
         ST    WKREG1,DECRECPT         STORE BLKREF ADDRESS IN DECB     01800000
         LA    DXBASE,ERRTRN           GET ERROR RETURN ADDRESS AND     01820000
         ST    DXBASE,20(0,FDNBASE)    STORE IN DUMMY FOUNDATION        01840000
* THE NEXT INSTRUCTIONS WILL SET UP AN IOB AND DECB TO ISSUE    SA69157 01850021
* AN I/O REQUEST SO THAT RELEX                                  SA69157 01852021
* PROCESSING WILL OCCUR UNDER THE IRB TO PREVENT SIMULTANEOUS   SA69157 01860021
* UPDATING OF THE VARIOUS QUEUES.  THE ASI MODULE WILL TREAT    SA69157 01870021
* THE REQUEST AS A WRITE DIX WITH ACTUAL ADDRESSING AND WILL    SA69157 01880021
* BRANCH TO THE EXCLUSIVE CONTROL MODULE IGG019LG WHICH WILL    SA69157 01882021
* REALIZE IT IS A RELEX REQUEST AND TREAT IT AS SUCH. IGG019LG  SA69157 01884021
* WILL THEN RETURN CONTROL TO THE ASI MODULE, WHICH WILL POST   SA69157 01886021
* THE DECB AND EXIT.  THIS MODULE WILL THEN REGAIN CONTROL      SA69157 01888021
* AND RETURN TO THE ISSUER OF THE RELEX MACRO.                  SA69157 01888421
         MVI   DECTYPE,ACTEXCL         ACTUAL ADDR,EXCLUSIVE    SA69157 01890021
         MVI   IOBDTYPE,ACTEXCL        INDICATE ACTUAL ADDR AND SA69157 01890421
*                                      WRITE RELEASE TO THE ASI SA69157 01890821
*                                      MODULE                   SA69157 01891221
         MVI   IOBDAVLI,UNAVAL         IOB UNAVAILABLE          SA69157 01892021
         ST    DCBREG,IOBDCBPT         DCB ADDR IN IOB          SA69157 01894021
         ST    DECBREG,IOBECBPT        DECB ADDR IN IOB         SA69157 01896021
         ST    IOBREG,DECIOBPT         IOB ADDR IN DECB         SA69157 01898021
         LA    PARREG0,IOBCP           START OF CH PGM          SA69157 01898421
         ST    PARREG0,IOBSTART        INTO IOB                 SA69157 01898821
         MVI   IOBFLAG1,UNRLCC         UNRELATED & COMM CHAIN   SA69157 01899221
         L     DXBASE,DCBREAD          GET FOUNDATION ADDRESS           01913321
         TM    DCBOPTCD,FEEDBACK       IS FEEDBACK SPECIFIED IN DCB     01920000
         BZ    ACTUAL                  NO,FEEDBACK WAS ACTUAL FOR READX 01940000
         TM    DCBOPTCD,RELREC         IS ADDRESS(HENCE ALSO FEEDBACK)  01960000
         BO    RELBLK                   BY RELATIVE BLOCK BRANCH        01980000
         TM    DCBOPTCD,ACTAD          IS ADDRESSING (HENCE ALSO FEED-  02000000
         BO    ACTUAL                  BACK) BY ACTUAL ADDRESS BRANCH   02020000
TTR      EQU   *                                                        02040000
         XC    IOBDCPND(4),IOBDCPND        ZERO OUT CPND FIELD  SA69157 02060021
         L     DXBASE,RTAD(0,DXBASE)   GET RELATIVE TRACK CONVERT ADDR  02080000
         MVI   IOBDTYPE+1,DRELEX       SET IOB TYPE TO RELEX     A35339 02090021
         SYNCH (DXBASE)                BR TO CONVERT RTNE IN PP  XM5406 02100001
*                                       STATE                           02110001
         LTR   DXBASE,DXBASE            IS TTR VALID            SA55595 02112002
         BNZ   ERRTRN                   IF NO, BR TO ERROR RTN  SA55595 02114002
*                                                                       02116002
WRITXRTN EQU   *                                                        02120000
         XC    IOBDNRCF(32),IOBDNRCF  CLEAR MODULE WORK AREA    SA69157 02122021
         MVI   IOBCP,NOPCCW            NOP COMMAND              SA69157 02130021
         MVI   FLGCCW(IOBREG),SILIBIT  SILI BIT INTO CCW        SA69157 02132021
         MVI   COUNTCCW(IOBREG),1      COUNT OF 1               SA69157 02134021
         LA    PARREG0,CPEND(IOBREG)   END OF CHAN PGM          SA69157 02136021
         ST    PARREG0,IOBDCPND        INTO IOB                 SA69157 02138021
         LR    RDXIOBRG,IOBREG         PUT IOB AND DCB ADDRESSES INTO   02140000
         MVI   IOBDTYPE+SKPHIBYT,DRELEX       SET IOB TYPE TO RELEX     02180001
         MVC   IOBDNRCF+SKPHIBYT(6),IOBSEEK+2 MOVE ACUAL ADDR OF        02190021
*                                             RECORD                    02200021
         MVC   IOBUPLIM(8),IOBSEEK     UPPER LIMIT ADDR         SA69157 02230021
         EXCP  (IOBREG)                ISSUE EXCP               SA69157 02230421
         WAIT  ECB=(DECBREG)           WAIT FOR COMPLETION      SA69157 02230821
         TM    DECSDECB+1,BADRELX      BAD COMPLETION?          SA69157 02231221
         BZ    GOODRET                 BR IF NO                 SA69157 02231621
         LA    DECBREG,4               SET RETURN CODE          SA69157 02231721
         B     SETREG0                 GO FREE CORE             SA69157 02231821
GOODRET  SR    DECBREG,DECBREG         GOOD RET CODE            SA69157 02231921
SETREG0  EQU   *                                                 XM2975 02232002
         LA    PARREG1,250              GET SUBPOOL NUMBER       A35339 02235021
         SLL   PARREG1,24               MOVE TO HIGH ORDER BYTE  A35339 02240021
         LA    PARREG0,LENCORE          LOAD LENGTH              A35339 02245021
         OR    PARREG0,PARREG1          SET UP REG0 FOR FREEMAIN A35339 02250021
         LR    PARREG1,RDXIOBRG        GET ADDRESS OF IOB               02260000
FREECORE EQU   *                                                        02280000
         FREEMAIN R,LV=(0),A=(1)                                        02320000
         LR    DXBASE,DECBREG          GET RETURN CODE INTO RET. REG.   02340000
         SVC   EXIT                                                     02360000
ACTUAL   MVC   IOBSEEK(8),0(WKREG1)    MOVE ADDRESS TO SEEK FIELD       02380000
         B     WRITXRTN                GO TO READ EXCLUSIVE RTN         02400000
RELBLK   XC    IOBCSW(4),IOBCSW          ZERO OUT IOBCSW         SM0209 02420021
         TM    DCBRECFM,OVERFLOW       IS RECFM OVERFLOW        SA53131 02422021
         BZ    NOTOVFLO                IF NOT, LOAD 19KE FROM   SA53131 02424021
*                                      FRONT OF FOUNDATION MODULE       02426021
         L     DXBASE,TROVAD(0,DXBASE) ELSE,LOAD 19KF FROM 19KA SA53131 02428021
         B     SYNCH                   BRANCH TO SYNCH          SA53131 02430021
NOTOVFLO EQU   *                                                SA53131 02432021
         L     DXBASE,RRAD(0,DXBASE)   GET RELATIVE BLOCK ADDRESS AND   02440000
SYNCH    EQU   *                                                SA53131 02445021
         MVI   IOBDTYPE+1,DRELEX       RELEX ENTRY TO MODULE    SA62454 02447021
         SYNCH (DXBASE)           BRANCH TO REL BLK ADRS IN PP   A35339 02450021
*                                       STATE                    A35339 02460021
         LTR   DXBASE,DXBASE           GOOD ADDR CONVERSION?    SA62454 02470021
         BNZ   ERRTRN                  BR IF NOT                SA62454 02472021
         B     WRITXRTN                GO TO READ EXCLUSIVE ROUTINE     02480000
ERRTRN   LA    DECBREG,8               PICK UP ERROR CODE               02500000
         LR    RDXIOBRG,IOBREG         GET  ADDRESS OF THE IOB   XM2975 02520002
         B     SETREG0                 GO FREE THE IOB CORE      XM2975 02540002
ENABLE   DC    X'FF'                    ENABLE ALL INTERRUPTS    A35339 02550021
         DCBD  DSORG=(IS,DA)                                            02560000
         EJECT                                                          02580000
*                                                                       02600000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       02620000
         DS    0F                                                       02640000
DECBDEF  DSECT                                                          02660000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        02680000
DECTYPE  DS    CL2            TYPE FIELD                                02700000
DECLNGTH DS    CL2            DATA LENGTH                               02720000
DECDCBAD DS    CL4            ADDRESS OF DCB                            02740000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      02760000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        02780000
DECKYADR DS    CL4            ADDRESS OF KEY                            02800000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               02820000
*                                                                       02840000
*              STANDARD IOB                                             02860000
         DS    0F                                                       02880000
IOBDEF   DSECT                                                          02900000
IOBFLAG1 DS    CL1            STATUS FLAG                               02920000
IOBFLAG2 DS    CL1            ERROR FLAG                                02940000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       02960000
IOBECBPT DS    CL4            ECB POINTER                               02980000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       03000000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           03020000
         DS    CL1                                                      03040000
         DS    CL3                                                      03060000
IOBCSWST DS    CL2            STATUS BYTES                              03080000
IOBCSWCT DS    CL2            REMAINING COUNT                           03100000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   03120000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        03140000
         DS    CL3                                                      03160000
IOBDCBPT DS    0CL4           DCB POINTER                               03180000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            03200000
         DS    CL3                                                      03220000
IOBRESTR DS    0CL4           RESTART POINTER                           03240000
         DS    CL1                                                      03260000
         DS    CL3                                                      03280000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              03300000
IOBERRCT DS    CL2            ERROR COUNTER                             03320000
IOBSEEK  DS    CL8            SEEK ADDRESS                              03340000
*        BDAM EXTENDED IOB                                              03360000
*                                                                       03380000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  03400000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          03420000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     03440000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                03460000
         DS    CL3                                                      03480000
IOBDTYPE DS    CL2            TYPE FIELD                                03500000
IOBDSTAT DS    CL2            IOB STATUS                                03520000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        03540000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                03560000
         DS    CL2                                                      03580000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               03600000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        03620000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                03640000
IOBCP    DS    CL8            FIRST CCW IN CHANNEL PROGRAM              03660000
         EJECT                                                          03662021
*                                                                       03664021
*                       DATA EXTENT BLOCK (DEB)                         03666021
*                                                                       03668021
         IEZDEB                                                         03670021
*                  * * * * * * * * * *                                  03672021
FEEDBACK EQU   X'10'    FEEDBACK BIT IN DCB                             03680000
RELREC   EQU   X'01'    RELATIVE RECORD BIT IN DCB                      03700000
ACTAD    EQU   X'08'    ACTUAL ADDRESSING BIT IN DCB                    03720000
RTAD     EQU   8        OFFSET IN FOUNDATION MODULE TO RELATIVE TRACK   03740000
RRAD     EQU   4        OFFSET IN FOUNDATION MODULE TO RELATIVE BLOCK   03760000
BDAM     EQU   X'20'    BDAM DSORG INDICATOR IN THE DCB                 03780000
DRELEX   EQU   X'01'    RELEX INDICATOR                                 03800000
EXIT     EQU   3                                                        03820000
TROVAD   EQU   32                      OFFSET IN FOUNDATION MOD SA53131 03825021
*                                      FOR REL BLK CONVERSION-OVERFLOW  03830021
OVERFLOW EQU   X'20'                   TRK OVERFLO BIT IN DCB+ X'24'    03835021
         END                                                            03840000
