         TITLE 'IGG0193A  BDAM OPEN EXECUTOR NO. 1'                     00010021
         COPY  LCGASMSW                                                 00022000
IGG0193A CSECT                                                          00026000
*70300513                                                          0419 00030013
*          RELEASE 17 DELETIONS                                         00035000
*1647000400-000800                                                 UL17 00040000
*          RELEASE 18 DELETIONS                                         00045000
*2480                                                             MCS   00047018
*2480033040-033160,050640-050760                                  22833 00048018
*          RELEASE 19 DELETIONS                                         00050000
*1021033400                                                      A28200 00052019
*          RELEASE 20 DELETIONS                                         00055000
*0286029200                                                      M6362  00055520
*0286024700-025350                                               M6121  00056020
*0286024800                                                      A31739 00057020
*          RELEASE 21 DELETIONS                                         00060000
*1344017600-018000,021800,027200,029100-031000,036600-037000,    A35339 00061021
*1344039800-041200,089800                                        A35339 00062021
*                                                               SA53239 00065002
*                                                               SA67607 00075021
*STATUS CHANGE LEVEL 011     10/18/73                                   00090021
*FUNCTION/OPERATION- THIS ROUTINE IS THE FIRST OPEN EXECUTOR CALLED   * 00100000
*   DURING THE OPEN PROCESSING OF A DCB WITH DSORG=DA.                * 00120000
*   THIS ROUTINE DETERMINES THE PROTECTED CORE REQUIRED FOR AN IOS    * 00140000
*   APPENDAGE LIST AND THE DEB THEN EXECUTES A GETMAIN FOR THE CORE.  * 00160000
*   THIS ROUTINE THEN CONSTRUCTS THE DEB AND ATTACHES AS MANY EXTENTS * 00180000
*   AS ARE PRESENT IN THE DSCB(S).                                    * 00200000
*                                                                     * 00220000
*ENTRY POINT- ENTRY IS TO THE FIRST BYTE OF THE MODULE BY EXECUTING   * 00240000
*   AN XCTL TO IGG0193A.                                              * 00260000
*                                                                     * 00280000
*INPUT- THE REGISTERS 5,6,7,8 ARE INPUT AS FOLLOWS,                   * 00300000
*   5 - BEGINNING OF THE DCB PARAMETER LIST                           * 00320000
*   6 - BEGINNING OF THE WHERE-TO-GO TABLE (WTG)                      * 00340000
*   7 - ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST        * 00360000
*   8 - ADDRESS OF THE CURRENT ENTRY IN THE WTG                       * 00380000
*                                                                     * 00400000
*OUTPUT- THIS ROUTINE CONSTRUCTS A DEB COMPLETE EXCEPT FOR (1)THE     * 00420000
*   SUBROUTINE ID'S WHICH ARE STORED BY IGG0193C AND (2) THE RELATIVE * 00440000
*   EXTENTS(FOR RELATIVE BLOCK ADDRESSING) WHICH ARE CONSTRUCTED BY   * 00460000
*   IGG0193E.                                                         * 00480000
*   THE REGISTERS 5,6 ARE LEFT UNCHANGED, REGISTERS 7,8 ARE POSITIONED* 00500000
*   TO THE NEXT ENTRY THAT IS NOT COMPLETED.                          * 00520000
*                                                                     * 00540000
*EXTERNAL ROUTINE- N/A                                                * 00560000
*                                                                     * 00580000
*EXIT-NORMAL- THIS ROUTINE SCANS THE WTG FOR A NON-ZERO ENTRY AND     * 00600000
*   EXECUTES AN XCTL TO THAT ROUTINE. THE SCAN BEGINS AT 'SCAN4EQ'.   * 00620000
*                                                                     * 00640000
*EXIT-ERROR- AN ABEND WILL BE EXECUTED IF THE DCB MACRF PARAMETER     * 00660000
*   HAS SPECIFIED NO TYPE (I/K/A). THE ABEND IS LABELED 'ERREXIT'.    * 00680000
*                                                                     * 00700000
*TABLES/WORK AREAS- 1.DCB PARAMETER LIST IS THE ADDRESS OF EACH DCB   * 00720000
*   SPECIFIED IN THE OPEN MACRO INSTRUCTION. THE HI-ORDER BYTE        * 00740000
*   CONTAINS A CODE INDICATING THE MODE (INPUT, OUTPUT, UPDATE).      * 00760000
*   2.WHERE-TO-GO TABLE CONTAINS THE ID AND TTR OF THE ROUTINE WHICH  * 00780000
*   IS TO PROCESS THE CORRESPONDING DCB AND THE ADDRESS OF A WORK AREA* 00800000
*   ASSIGNED TO THAT DCB.                                             * 00820000
*   3.WORK AREA IS A TEMPORARY 464 BYTE AREA USED BY THIS ROUTINE ONLY* 00840000
*   AS A REGISTER SAVE AREA.                                          * 00860000
*   4.COMMUNICATION VECTOR TABLE IS A RESIDENT VECTOR LIST USED TO    * 00880000
*   LOCATE THE CONVERT ROUTINE, AND THE TASK CONTROL BLOCK.           * 00900000
*                                                                     * 00920000
*ATTRIBUTES- THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AND IS    * 00940000
*   DISABLED, PRIVILEGED, AND REUSABLE.                               * 00960000
*                                                                     * 00980000
*NOTES- THIS EXECUTOR IS THE FIRST ROUTINE NAMED FOR A DCB WITH       * 01000000
*   DSORG=DA AND WILL PLACE THE ID AND TTR OF IGG0193C IN THE WTG AS  * 01020000
*   THE SECOND EXECUTOR TO BE CALLED FOR THIS DCB.                    * 01040000
*                                                                       01060000
*   IF AN EXTENT IS ALLOCATED AS A USER LABEL EXTENT (EXTENT TYPE  UL17 01066000
*   CODE = X'40') IT WILL NOT BE REFLECTED IN THE DEB EXTENTS.     UL17 01072000
*   THE USER LABEL EXTENT IS NOT INCLUDED IN F1 EXTENT COUNT            01076018
*                                                                       01080000
*                                                                       01100000
*                                                                       01120000
         USING STEPONE,RBASE                                            01140000
         USING DEB,RDEB                                                 01160000
         USING IHADCB,RDCB                                              01180000
         USING TCB,RC                                                   01200000
         USING FORCORE,RCORE                                            01220000
         AIF   ('&LIB' EQ 'LIB1').OS001                                 01222002
         USING PDS2,RWTG                                         XM8332 01230002
.OS001   ANOP                                                           01232002
*                                                                       01240000
*  REGISTER USAGE                                                       01260000
*                                                                       01280000
RE       EQU   0         WORK REGISTER                                  01300000
RF       EQU   1         WORK REGISTER                                  01320000
RDCB     EQU   2         CURRENT DCB ADDRESS                            01340000
RBASE    EQU   3         BASE OF THIS ROUTINE                           01360000
RCORE    EQU   4         WORK AREA ADDRESS                              01380000
RPAR     EQU   5         PARAMETER LIST ADDRESS                         01400000
RWTG     EQU   6         FRONT OF WHERE-TO-GO TABLE                     01420000
RPARC    EQU   7         CURRENT ENTRY IN PARAMETER LIST                01440000
RWTGC    EQU   8         CURRENT ENTRY IN WTG                           01460000
RTIOT    EQU   9         TIOT ADDRESS                                   01480000
R9       EQU   9         WORK REGISTER                                  01500000
RUCB     EQU   10        CURRENT UCB ADDRESS                            01520000
RDEB     EQU   11        DEB ADDRESS                                    01540000
RB       EQU   12        WORK REGISTER                                  01560000
RC       EQU   13        WORK REGISTER                                  01580000
RD       EQU   14        WORK REGISTER                                  01600000
RJ       EQU   15        WORK/PARAMETER REGISTER                        01620000
*  MASKS AND OTHER EQUATES                                      SA67607 01630021
DXTBITS  EQU   X'B9'     TURN OFF DYN BUF, READX, AND TRK OFL   SA67607 01632021
*                                                                       01640000
         EJECT                                                          01660000
*                                                                       01680000
*  DETERMINE THE AMOUNT OF PROTECTED CORE REQUIRED                      01700000
*                                                                       01720000
*    1. FOR MODULE ID'S IN DEB                                          01740000
*    2. FOR APPENDAGE VECTOR LIST                                       01760021
*    3. FOR IRB                                                         01790021
*                                                                       01820000
*                                                                       01840000
*                                                                       01860000
         BALR  RBASE,0                 ESTABLISH BASE FOR THIS ROUTINE  01880000
STEPONE  L     RDCB,0(0,RPARC)         LOAD DCB BASE ADDRESS            01900000
         L     RCORE,4(0,RWTGC)        SET WORK AREA POINTER            01920000
         AIF   ('&LIB' EQ 'LIB1').OS002                                 01922002
         NI    PDS2INDC,X'FF'-PDS2LUSR SET LOW-ORDER 5 BITS TO   XM8332 01930002
         OI    PDS2INDC,BIT4           8 HALFWORDS OF USER DATA  XM8332 01932002
*                                      IN THE LOAD PARM LIST     XM8332 01934002
.OS002   ANOP                                                           01936002
*                                                                       01940000
         TM    DCBRECFM,X'C0'          IF RECORD FORMAT HAS NOT BEEN    01960000
         BC    7,*+8                   SPECIFIED AS F, V, OR U          01980000
         OI    DCBRECFM,X'C0'           ASSUME U                        02000000
*                                                                       02020000
         TM    DCBMACRF,VALIDRD        IS READ TYPE ID AND/OR KEY       02040000
         BC    5,CLRREGS                YES, DCB IS OK                  02060000
         TM    DCBMACRF+1,VALIDWRT     IS WRITE TYPE ID/KEY/ADD         02080000
         BC    5,CLRREGS                YES, DCB IS OK                  02100000
         L     RF,ABCODE               GET ABEND CODE AND DUMP OPTION   02120000
ERREXIT  ABEND (1)                                                      02140000
*                                                                       02160000
*                       GET CORE (80 BYTES) FOR READ EXCLUSIVE          02180021
*                        LIST IN SUBPOOL 0 IF DCB SPECIFIES             02180621
*                        EXCLUSIVE READ OR WRITE ADD AND FORMAT         02181221
*                        U OR V RECORDS.                                02181821
*                                                                       02182421
CLRREGS  EQU   *                                                 A35339 02183021
         NI    DCBOPTCD,DXTBITS        TURN OFF DYN BUF,        SA67607 02183621
*                                      TRACK OVERFLOW, AND      SA67607 02184021
*                                      READ EXCLUSIVE OPTIONS           02184221
*                                      IN CASE MERGED FROM DSCB         02184821
         TM    DCBMACRF,READX     DID USER SPECIFY EXCLUSIVE     A35339 02185421
*                                       READ                     A35339 02186021
         BO    ORRDX               CAPABILITY? BRANCH IF YES.    A35339 02186621
         TM    DCBRECFM,X'40'     IF RECORD IS FIXED LENGTH      A35339 02187221
         BZ    CLRREGS2            BRANCH (PREFORMAT FOR ADD).   A35339 02187821
         TM    DCBMACRF+1,ADD     DID USER SPECIFY WRITE ADD?    A35339 02188421
         BZ    CLRREGS2            BRANCH IF NO.                 A35339 02189021
ORRDX    OI    DCBOPTCD,READX      SET EXCLUSIVE OPTION          A35339 02189621
         LA    RE,250             REQUEST SUBPOOL 250 TO GET 0   A35339 02190221
         SLL   RE,24              SUBPOOL TO HI-ORDER BYTE       A35339 02190821
         LA    RF,RDXSZ           AMT OF CORE TO GET             A35339 02191421
         OR    RE,RF                   OR TOGETHER SIZ AND SP    A35339 02192021
         GETMAIN R,LV=(0)              GET CORE FOR READX LIST   A35339 02192621
         XC    0(RDXSZ,RF),0(RF)  CLEAR CORE FOR XLIST           A35339 02193221
         ST    RF,0(0,RF)         ST XLIST ADRS IN XLIST         A35339 02193821
         MVI   0(RF),RDXCNT       MV INTO LIST MAX NO. ENTRIES   A35339 02194421
         ST    RF,DCBXARG         STORE LIST ADDR IN DCB         A35339 02195021
         MVI   DCBXCNT,RDXCNT     MV INTO DCB MAX NO. XLIST      A35339 02195621
*                                       ENTRIES                  A35339 02196221
CLRREGS2 EQU   *                                                 A35339 02196821
         LA    RE,2               INSERT CONSTANT OF 2 BYTES     A35339 02197421
         LR    RTIOT,RE                EXTENDED SEARCH MODULE INCREMENT 02200000
         LA    RF,6                    CORE FOR FDN., SIO, CE-XCE ID'S  02220000
         TM    DCBMACRF,TYPID          IS ID                            02240000
         BC    1,ADD1                  MODULE                           02260000
         TM    DCBMACRF+1,TYPID          NEEDED                         02280000
         BC    8,TKEY                   NO, TRY KEY TYPE                02300000
ADD1     AR    RF,RE                    YES, ADD TWO TO DEB SIZE        02320000
TKEY     TM    DCBMACRF,TYPK           IS KEY                           02340000
         BC    1,ADD1A                  MODULE                          02360000
         TM    DCBMACRF+1,TYPK           NEEDED                         02380000
         BC    8,TADD                   NO, TRY ADD TYPE                02400000
ADD1A    AR    RF,RE                    YES, ADD TWO BYTES              02420000
         AR    RTIOT,RE                ALLOW FOR EXTENDED SEARCH MODULE 02440000
TADD     TM    DCBMACRF+1,ADD          IS ONE OF THE FORMAT MODULES     02460000
         BC    8,TACT                  NEEDED, NO, GO TEST       M6121  02470020
*                                       ADDRESSING               M6121  02480020
         AR    RF,RE                   YES, ADD FOR MODULE ID    M6121  02490020
         AR    RTIOT,RE                AND POSSIBLE EXTENDED MOD M6121  02500020
*                                       ID                       M6121  02510020
TACT     TM    DCBOPTCD,ACTAD          IF ACTUAL ADDRESSING IS USED     02540000
         BC    1,TDYN                   NO ADDITIONAL MODULES ARE REQ.  02560000
         TM    DCBOPTCD,RELRD+FEEDB    IS RELATIVE BLOCK/FEEDBACK SPEC  02580000
         BC    12,ADD2                  IF ONE OR NEITHER, GO ADD TWO   02600000
         AR    RF,RE                    IF BOTH, ALLOW FOR ONE ID AND   02620000
ADD2     AR    RF,RE                   ALLOW FOR ONE ID                 02640000
TDYN     TM    DCBMACRF,DYNB           IS DYNAMIC BUFFER MODULE         02660000
         BC    8,TVER                   NEEDED                          02680000
         OI    DCBOPTCD,DYNB           MOVE OPTION BIT TO OPTCD         02700000
TVER     TM    DCBOPTCD,VERIFY         IS VERIFY NEEDED                 02740000
         BC    8,TCHK                   NO, TRY NEXT OPTION             02760000
         AR    RF,RE                    YES, ADD TWO BYTES              02780000
TCHK     TM    DCBMACRF,CHECK          IS THE CHECK OPTION BEING USED   02800000
         BC    8,TES                    NO, TRY NEXT OPTION             02820000
         AR    RF,RE                    YES, ADD TWO BYTES              02840000
TES      TM    DCBOPTCD,EXSCH          IF EXTENDED SEARCH,              02860000
         BC    8,TRDX                   ALLOW FOR                       02880000
         AR    RF,RTIOT                  EXTENDED MODULES               02900000
TRDX     TM    DCBOPTCD,READX     EXCLUSIVE ROUTINE NEEDED?      A35339 02910021
         BZ    SETSZ               BRANCH IF NO                  A35339 02980021
         AR    RF,RE               ADD 2 BYTES TO DEB SIZE.      A35339 03050021
SETSZ    LA    RF,APPSZ+BASESZ(0,RF)   ALLOW FOR APPENDAGE LIST         03120000
*                                           AND DEB BASE                03140000
*                                                                       03160000
*   BDAM DEB CONSTRUCTION ROUTINE                                       03180000
*                                                                       03200000
*                                                                       03220000
         IC    RTIOT,DSCNOEXT          FIRST DSCB NUMBER OF EXTENTS     03240000
        CLI    JFCBVOLS+NEXTVOL,BLANK   IS DS MULTIVOLUME       SA53239 03243002
         BNE   MULTIVOL                YES, OPEN INITIALIZED EXT        03246002
*                                       FIELD                   SA53239 03249002
         MVI   DCBDRDX,EQU0             NO, ZERO OUT DCB EXT    SA53239 03252002
MULTIVOL EQU   *                                                SA53239 03255002
         IC    RE,DCBDRDX              PLUS TOTAL NO. OF EXTENTS FROM   03260000
         AR    RTIOT,RE                OTHER DSCB'S GIVE TOTAL NO. OF   03280000
*                                      EXTENTS FOR THE DATA SET         03300000
         TM    DCBRECFM,OVERFL         ARE OVERFLOW RECORDS PRESENT     03320000
         BC    8,NOOVFLOW              NO,CONTINUE               A28200 03340019
         OI    DCBOPTCD,OFLOW          OR IN OVERFLOW BIT IN OPTCD      03360000
NOOVFLOW LTR   RTIOT,RTIOT             TEST FOR ZERO EXTENTS     A28200 03364019
         BC    7,OBDAM018              BR IF NOT ZERO EXTENTS    A28200 03368019
         L     RF,ABCODE               GET ABEND CODE            A28200 03372019
         BC    15,ERREXIT              BRANCH TO ABEND           A28200 03376019
*                                                                       03380000
OBDAM018 EQU   *                                                        03400000
         LR    RC,RTIOT                SAVE NO. OF EXTENTS              03420000
         SLL   RC,4                    MULTIPLY NO. OF EXTENTS          03440000
         AR    RF,RC                      BY 16, ADD TO CORE SIZE       03460000
         TM    DCBOPTCD,RELRD          IF NOT RELATIVE RECORD           03480000
         BC    8,OBDAM020               ADDRESSING, GO TO NEXT ROUTINE  03500000
         SRL   RC,2                    MULTIPLY NO. OF EXTENTS BY 4     03520000
         AR    RF,RC                     TO ALLOW FOR RELATIVE EXTENTS  03540000
         TM    DCBRECFM,OVERFL         ARE OVERFLOW RECORDS PRESENT     03560000
         BZ    OBDAM020                NO GO ON                         03580000
         LA    RF,OFLINCR(0,RF)        YES ADD ON OVERFLOW SIZE         03600000
*                                                                       03620000
*  REGISTER RF NOW CONTAINS NO.OF BYTES OF PROTECTED CORE REQUIRED FOR  03640000
*    1. APPENDAGE VECTOR LIST                                           03660021
*    2. DEB (BASE + VARIABLE NO. OF EXTENTS AND SUBROUTINE ID'S)        03690021
*                                                                       03720000
OBDAM020 EQU   *                                                        03740000
         LA    RF,7(RF)                ROUND TO NEXT HIGHEST DOUBLE     03760000
         SRL   RF,3                     WORD FOR GETMAIN                03780000
         LR    RB,RF                   SAVE DOUBLE WORD COUNT           03800000
         SLL   RF,3                    RF NOW CONTAINS BYTES NEEDED     03820000
*                                                                       03840000
         LA    RE,254                  COMBINE THE GETMAIN PARAMETERS   03860000
         SLL   RE,24                    (SUBPOOL NUMBER                 03880000
         OR    RE,RF                     AND SIZE).                     03900000
         GETMAIN R,LV=(0)                                               03920000
*                                                                       03940000
         LA    RJ,0(RF)                 INITIALIZE POINTER REGISTER     03960000
         LR    RD,RJ                    LOAD APPENDAGE LIST POINTER     04140000
         LA    RJ,APPSZ(0,RJ)           STEP PTR TO DEB PREFIX AREA     04160000
         LA    RDEB,16(0,RJ)           SET POINTER TO BASE OF DEB       04180000
         XC    0(48,RJ),0(RJ)          CLEAR ALL OF DEB TO EXTENTS      04200000
*                                                                       04220000
*   CONSTRUCT THE DEB BASE                                              04240000
*                                                                       04260000
         STC   RB,12(0,RJ)             STORE DOUBLE WORD COUNT          04280000
         MVC   3(5,RJ),DXCCW7          SAVE DSCB CCHHR ADDRESS          04300000
         STC   RTIOT,DEBNMEXT          STORE NO. OF EXTENTS             04320000
         ST    RD,DEBAPPAD              APPENDAGE LIST ADDRESS          04340000
         L     RD,CVTPTR(0,0)          USE COMM. VECTOR TABLE TO        04360000
         L     RC,CVTTCBP-CVTDEF(0,RD)       LOCATE THE CURRENT TCB     04380000
         L     RC,4(0,RC)               ADDRESS FOR A BASE              04400000
         ST    RC,DEBTCBAD             TCB ADDRESS                      04420000
         ST    RDCB,DEBDCBAD           DCB ADDRESS                      04440000
         MVC   DEBPROTG(1),TCBMSS+4    PROTECTION TAG OF THE TCB        04460000
         OI    DEBDEBID,OPMDEBID       DED ID                           04480000
         MVC   DEBPRIOR(1),TCBDSP      PRIORITY INDICATOR               04500000
         MVC   DEBOPATB(1),OPPATRUB(RPARC) OPEN ATTRIBUTES              04520000
         NI    DEBOPATB,X'7F'                                           04540000
         MVI   DEBEXSCL,OPMEXSCL       EXTENT SIZE SCALE                04560000
         MVC   DEBDEBAD+1(3),TCBDEBAD+1 CHAIN THIS DEB TO               04580000
         ST    RDEB,TCBDEBAD            THE TASK CONTROL BLOCK          04600000
*                                                                       04620000
         MVC   DCBDEBAD+1(3),TCBDEBAD+1  PUT DEB ADDRESS IN THE DCB     04660000
         AIF   ('&LIB' EQ 'LIB1').DEBCK10                        Y01021 04662000
         DEBCHK (RDCB),TYPE=ADD,AM=BDAM  ADD DEB TO DEB TABLE    Y01021 04670000
         LR    RDEB,RF                  LOAD DEBCHK DEB ADDRESS  Y01021 04670400
         ST    RDEB,DXPDEBAD            STORE DEB IN WORKAREA    Y01021 04672400
.DEBCK10 ANOP                                                    Y01021 04674000
         LR    RJ,RTIOT                 SET TOTAL EXTENT COUNTER Y01021 04676000
         L     RTIOT,TCBTIO            USE TIOT ADDRESS PLUS DCB        04680000
         AH    RTIOT,DCBTIOT            TIOT OFFSET TO FIND UCB ADDR.   04700000
         LR    RD,RCORE                SET DSCB INDEX SO ROUTINE CAN    04720000
         SH    RD,OPCON44               UTILIZE A LOOP                  04740000
         LA    RB,DEBUCBAD             SET DEB EXTENT INDEX TO EXTENT 1 04760000
         MVI   DEBOFLGS,X'C0'                                           04780000
         NC    DEBOFLGS,JFCBIND2       OPEN OLD OR NEW                  04800000
         CLI   DSCEXTYP,X'80'          CHECK FOR SPLIT CYLINDER         04820000
         BC    7,OBDAM060              NO- BRANCH                       04840000
         OI    DEBOFLGS,X'04'          SET INDICATOR IN DEB             04860000
*                                                                       04880000
*   BUILD DEB EXTENT                                                    04900000
*     DEVICE MODIFIER-UCB ADDRESS                                       04920000
OBDAM060 EQU   *                                                        04940000
         LR    RDCB,RD                 SAVE CURRENT DSCB ADDRESS        04960000
         SR    RF,RF                   ZERO M COUNTER                   04980000
         SR    RUCB,RUCB                                                05000000
         ST    RUCB,DXCCW4             SET TOTAL TT CTR TO ZERO         05020000
OBDAM180 STH   RUCB,4(0,RB)            ZERO BB FOR NOW                  05040000
         IC    RUCB,59(0,RD)           GET NO. OF EXTENTS FOR THIS DSCB 05060000
         LTR   RUCB,RUCB               CHECK FOR ZERO                   05080000
         BC    7,OBDAM190              NO BRANCH                        05100000
         LA    RUCB,1                  FORM DUMMY EXTENT                05120000
         LA    RJ,1                    SET TOTAL EXTENTS EQUAL ONE 0419 05130013
OBDAM190 LA    RD,105(0,RD)            POINT TO FIRST EXTENT OF DSCB    05140000
         L     RC,TIOEFSRT(0,RTIOT)    GET UCB POINTER                  05160000
         USING UCBOB,RC                                                 05180000
         CLI   UCBID,X'FF'              IS THIS A MAIN UCB              05200000
         BE    MAINUCB                  BRANCH IF YES                   05220000
*                                                                       05240000
* SUB UCB ADDRESSING FOR 2321 SUB UCB'S                                 05260000
*                                                                       05280000
         LH    RE,DBBNR(RC)             PICK UP BB                      05300000
         STH   RE,4(RB)                 STORE BB IN DEB EXTENT FIELD    05320000
         SLL   RE,4                     TIMES 16                        05340000
         SR    RC,RE                    SUBUCB POINTER MINUS BB'S       05360000
         LA    RE,DCELL                 GET LENGTH OF MAIN UCB          05380000
         SR    RC,RE                    POINTER MINUS MAIN UCB LENGTH   05400000
MAINUCB  ST    RC,0(0,RB)               UCB ADDRESS                     05420000
         LA    RC,16                    GET DEB                         05440000
         LNR   RC,RC                         PREFIX                     05460000
         AR    RC,RDEB                            ADDRESS               05480000
         MVC   1(2,RC),DEBBINUM         MOVE BB TO PREFIX               05500000
         MVI   0(RB),X'50'             INHIBIT WRITE PERMIT ALL SEEKS   05520000
         TM    0(RPARC),X'0F'          CHECK FOR INPUT                  05540000
         BC    8,OBDAM210              BRANCH IF YES                    05560000
         MVI   0(RB),X'10'             PERMIT ALL WRITES AND SEEKS      05580000
OBDAM210 SR    RE,RE                   SET FORMAT 3 SWITCH OFF          05600000
         LA    RC,3                    MAXIMUM 3 EXTENTS FOR FORMAT 1   05620000
         CLI   OFF105(RDCB),ULEXTYP     TEST, BR IF 1ST EXTNT NOT  UL17 05624000
         BC    7,OBDAM220              A USER LABEL TRACK          UL17 05628000
         BCTR  RC,0                    DECREMENT NO OF EXTENTS     UL17 05632000
         LA    RD,10(0,RD)             POINT TO NEXT DSCB EXTENT   UL17 05636000
OBDAM220 MVC   6(8,RB),2(RD)           SET UP ONE EXTENT. CCHH TO CCHH  05640000
         NI    0(RB),X'50'             PERMIT HEAD SEEKS                05660000
         CLI   0(RD),X'81'             CHECK FOR CYLINDER BOUNDARY      05680000
         BC    8,OBDAM224              YES  BRANCH                      05700000
         OI    0(RB),X'08'             INHIBIT ALL SEEKS                05720000
OBDAM224 EQU   *                                                        05740000
         STM   RE,RJ,DXCCW5             SAVE ALL REGS                   05760000
         LR    RPAR,RB                  SAVE DEB EXTENT POINTER         05780000
         STC   RF,DXDAADDR              SET CONST M FOR CONVERT         05800000
         MVC   DXDAADDR+1(2),4(RB)     BB                               05820000
         MVC   DXDAADDR+3(4),10(RB)    END CCHH IN EXTENT               05840000
*                                                                       05860000
*        USE CONVERT ROUTINE                                            05880000
*                                                                       05900000
         LR    RF,RDEB                  SET A POINTER TO THE DEB        05920000
         LA    RDCB,DXDAADDR           POINT TO CONSTANT FOR CONVERT    05940000
*                                      ROUTINE                          05960000
         L     RJ,CVTPTR                GET ADDRESS OF CVT              05980000
         L     RJ,CVTPRLTV-CVTDEF(0,RJ) CONVERT RTNE                    06000000
         BALR  RD,RJ                                                    06020000
*                                                                       06040000
         LR    RF,RE                   MOVE TTRC TO REG. RF             06060000
         SRL   RF,16                    USE TT ONLY                     06080000
         LA    RF,1(0,RF)               ADD ONE TO TT                   06100000
         LR    RE,RF                   SAVE NO. OF TOTAL TRACKS         06120000
         SH    RF,DXCCW4                SUBTRACT TT OF LAST EXTENT      06140000
         STH   RF,14(0,RPAR)            STORE NO. OF TRACKS IN THIS     06160000
*                                        EXTENT                         06180000
         STH   RE,DXCCW4                                                06200000
         LM    RE,RJ,DXCCW5             RESTORE ALL REGS                06220000
*                                                                       06240000
         LA    RF,1(0,RF)              ADD ONE TO M COUNTER. NEXT EXT.  06260000
         BCT   RJ,OBDAM260             ANY MORE EXTENTS (TOTAL)         06280000
         AIF   ('&LIB' NE 'LIB1').LIB1AA                                06290001
         BAL   RE,FREECORE             GO TO FREE THE DSCB CORE         06300000
.LIB1AA  ANOP                                                           06310001
         BC    15,OBDAMOUT              NO, ALL EXTENTS ARE BUILT       06320000
*                                                                       06340000
*                                                                       06360000
OBDAM260 BCT   RUCB,OBDAM280           TEST MORE EXTENTS IN THIS DSCB   06380000
         L     RD,NEXTCORE(0,RDCB)     NEXT DSCB ADDRESS                06400000
         AIF   ('&LIB' NE 'LIB1').LIB1AB                                06410001
         BAL   RE,FREECORE             GO TO FREE THE DSCB CORE         06420000
.LIB1AB  ANOP                                                           06430001
         SH    RD,OPCON44              SUBTRACT KEY WHICH ISN'T IN CORE 06440000
         LR    RDCB,RD                 NEXT SET OF EXTENTS              06460000
         LA    RTIOT,4(0,RTIOT)        POINT TO NEXT ENTRY              06480000
         LA    RB,16(0,RB)             NEXT DEB EXTENT                  06500000
         BC    15,OBDAM180                                              06520000
*                                                                       06540000
*        MORE EXTENTS FOR CURRENT DATA SET CONTROL BLOCK                06560000
*                                                                       06580000
OBDAM280 LA    RD,10(0,RD)             UPDATE DSCB POINTER              06600000
         BCT   RC,OBDAM300             BRANCH IF MORE EXTENTS FOR       06620000
*                                      CURRENT FORMAT                   06640000
         LA    RD,1(0,RD)               NO, INCREMENT DSCB POINTER      06660000
         LTR   RE,RE                   IS IT WORKING ON FORMAT 3        06680000
         BC    7,OBDAM320              BRANCH IF YES                    06700000
         L     RD,4(0,RD)              GET ADDRESS OF FORMAT 3 DSCB     06720000
         AIF   ('&LIB' NE 'LIB1').LIB1AC                                06730001
         BAL   RE,FREECORE             GO TO FREE THE DSCB CORE         06740000
.LIB1AC  ANOP                                                           06750001
         LR    RDCB,RD                 SAVE CURRENT DSCB ADDRESS        06760000
         LA    RD,4(0,RD)              GO TO FIRST EXTENT FIELD         06780000
         LA    RC,4                    SET LIMIT TO 4 EXTENTS IN KEY    06800000
         LR    RE,RC                   TURN ON FORMAT 3 SWITCH          06820000
*                                                                       06840000
OBDAM300 MVC   16(6,RB),0(RB)          MOD,UCB,AND BB FOR NEXT EXTENT   06860000
         LA    RB,16(0,RB)             NEXT DEB EXTENT                  06880000
         BC    15,OBDAM220                                              06900000
*                                                                       06920000
*                                                                       06940000
OBDAM320 LA    RC,9                    RESET EXTENT COUNT TO 9          06960000
         SR    RE,RE                   FORMAT 3 SWITCH OFF              06980000
         BC    15,OBDAM300                                              07000000
*                                                                       07020000
OBDAMOUT EQU   *                                                        07040000
*                                                                       07060000
*        STORE TOTAL TRACKS IN THE DATA SET, INTO THE DCB               07080000
*                                                                       07100000
         AIF   ('&LIB' NE 'LIB1').LIB1AD                                07110001
         XC    DSCCORE,DSCCORE         CLEAR OUT POINTER TO FORMAT 3    07120000
.LIB1AD  ANOP                                                           07130001
         LH    RC,DXCCW4               LOAD TOTAL TRACKS IN DATA SET    07140000
         L     RDCB,0(0,RPARC)          RESTORE DCB BASE                07160000
STDCBREL IC    RE,DCBKEYLE             STORE TOTAL SIZE OF DATA SET     07180000
         ST    RC,DCBKEYLE              (IN TRACKS) IN THE DCB,         07200000
         STC   RE,DCBKEYLE              SAVING KEY LENGTH               07220000
*                                                                       07240000
*                                                                       07260000
*                                                                       07280000
         MVC   0(5,RWTGC),DAM2ID       NAME BDAM EXECUTOR 2 AS NEXT     07300000
*                                                                       07320000
*                                                                       07340000
*  ROUTINE TO SCAN DCB LIST FOR OTHER DCBS REQUIRING THIS EXECUTOR.     07360000
*  IF NONE ARE FOUND, CONTROL IS TRANSFERED TO THE NEXT EXECUTOR OF THE 07380000
*  FIRST DCB WHICH IS NOT COMPLETED.                                    07400000
*                                                                       07420000
*                                                                       07440000
SCAN4EQ  LA    RWTGC,WGOFF(0,RWTGC)    INCREMENT WHERE TO GO INDEX      07460000
         LA    RPARC,PAROFF(0,RPARC)     ''   ''   DCB PARAMETER INDEX  07480000
         CLC   0(2,RWTGC),AMIDCNST     DOES TABLE NAME THIS EXECUTOR    07500000
         BCR   8,RBASE                  YES, BRANCH TO ENTRY POINT      07520000
         CLC   0(2,RWTGC),OPIDCNST      NO, IS THIS END OF TABLE?       07540000
         BC    7,SCAN4EQ                NO, LOOP TO INCREMENT STEPS.    07560000
*                                                                       07580000
         LR    RPARC,RPAR              RESTORE BOTH INDEX REGISTERS TO  07600000
         LA    RWTGC,32(0,RWTG)         THEIR INITIAL VALUES            07620000
SCAN4ANY CLI   0(RWTGC),0              IS THIS DCB COMPLETED?           07640000
         BC    7,XCTLRTN                IF NOT, GO TO NAMED EXECUTOR.   07660000
         LA    RWTGC,WGOFF(0,RWTGC)    INCREMENT BOTH INDEX REGISTERS   07680000
         LA    RPARC,PAROFF(0,RPARC)    TO THE NEXT ENTRIES.            07700000
         BC    15,SCAN4ANY             LOOP TO CHECK COMPLETION         07720000
*                                                                       07740000
XCTLRTN  EQU   *                                                        07760000
         MVC   6(2,RWTG),0(RWTGC)      MOVE EXECUTOR ID TO PARAM LIST   07780000
         MVC   14(3,RWTG),2(RWTGC)      MOVE TTR                        07800000
         LA    RJ,DXCCW12               POINT TO DOUBLE WORD            07820000
*                                                                       07840000
         XCTL  DE=(RWTG),SF=(E,(15))                                    07860000
FREECORE EQU   *                                                        07880000
         AIF   ('&LIB' NE 'LIB1').LIB1AE                                07890001
         STM   RD,RF,DXCCW5            SAVE REGISTERS 14-1              07900000
         LA    RE,144                  SET COUNT TO FORMAT THREE LENGTH 07920000
         TM    44(RDCB),X'F3'          IS THIS A FORMAT THREE DSCB      07940000
         BO    FORMAT3                 YES, SKIP OVER FORMAT 1 PART     07960000
         AH    RDCB,OPCON44            ADD KEY LENGTH BACK ON           07980000
         CR    RDCB,RCORE              COMPARE TO SEE IF THIS IS FIRST  08000000
         BE    AFTERFRM                FORMAT ONE. YES,DON'T FREEMAIN   08020000
         SH    RE,OPCON44              SUBTRACT KEY LENGTH FROM COUNT   08040000
FORMAT3  EQU   *                                                        08060000
         LR    RF,RDCB                 GET AREA ADDRESS INTO REG 1      08080000
         FREEMAIN R,LV=(0),A=(1)       FREEMAIN                         08100000
AFTERFRM LM    RD,RF,DXCCW5            RESTORE REGISTERS                08120000
         LR    RDCB,RE                 GET RETURN ADDRESS INTO A        08140000
         BR    RDCB                    VALID REGISTER AND RETURN        08160000
.LIB1AE  ANOP                                                           08170001
*                                                                       08180000
*                                                                       08200000
*                                                                       08220000
AMIDCNST DC    C'3A'                   THIS EXECUTOR'S ID               08240000
OPIDCNST DC    C'0S'                   FINAL WTG TABLE ENTRY (OPEN ID)  08260000
RDXCNT   EQU   9                  MAX NO. ENTRIES IN XLIST SEG   A35339 08270021
WGOFF    EQU   8                       OFFSET IN WHERE TO GO TABLE      08280000
PAROFF   EQU   4                       OFFSET IN DCB PARAMETER LIST     08300000
OPCON44  DC    H'44'     CONSTANT 44                                    08320000
TEN      DC    H'10'                    CONSTANT OF TEN                 08340000
         DS    0F                                                       08360000
ABCODE   DC    AL1(128)  DUMP OPTION                                    08380000
         DC    XL3'020000' ABENDT CODE-NO TYPE SPECIFIED IN DCBMACRF    08400000
VALIDRD  EQU   X'18'     READ-ID,KEY BITS                               08420000
VALIDWRT EQU   X'1A'     WRITE-ID,KEY,ADD BITS                          08440000
*                                                                       08460000
OPMINPUT EQU   X'7F'     DCB OPENED FOR INPUT                           08480000
OPMEXSCL EQU   4         DEB EXTENT SIZE SCALE                          08500000
OPPATRUB EQU   0         OFFSET TO ATTRIBUTE BYTE                       08520000
OPMDEBID EQU   X'0F'     IDENTIFIER FOR A DEB                           08540000
*                                                                       08560000
TYPID    EQU   X'08'     TYPE ID                                        08580000
NEXTCORE EQU   140       NEXT DSCB ADDRESS OFFSET                       08600000
TYPK     EQU   X'10'     TYPE KEY                                       08620000
ADD      EQU   X'02'     TYPE WRITE ADD                                 08640000
EXSCH    EQU   X'20'     EXTENDED SEARCH                                08660000
RELRD    EQU   X'01'     RELATIVE BLOCK ADDRESSING                      08680000
FEEDB    EQU   X'10'     FEEDBACK                                       08700000
ACTAD    EQU   X'08'     ACTUAL ADDRESSING                              08720000
DYNB     EQU   X'04'     DYNAMIC BUFFERING                              08740000
VERIFY   EQU   X'80'     WRITE VERIFY                                   08760000
READX    EQU   X'02'     READ EXCLUSIVE                                 08780000
OVERFL   EQU   X'20'     TRACK OVERFLOW                                 08800000
OFLOW    EQU   X'40'     TRACK OVERFLOW BIT IN DCB OPTCD FIELD          08820000
CHECK    EQU   X'01'                   CHECK MACRO BEING USED           08840000
*                                                                       08860000
DBBNR    EQU   0                        BB DISPLACEMENT IN SUB UCB      08880000
DCELL    EQU   X'38'                    LENGTH OF MAIN UCB              08900000
BASESZ   EQU   48        BASE SIZE OF DEB                               08920000
IRBSZ    EQU   64        INTERRUPT REQUEST BLOCK SIZE                   08940000
RDXSZ    EQU   80        READ EXCLUSIVE LIST SIZE                       08960000
APPSZ    EQU   20        APPENDAGE LIST SIZE                            09000000
OFLINCR  EQU   8         EXTRA SIZE FOR OVERFLOW RECORDS                09020000
ULEXTYP  EQU   X'40'     DSCB EXTENT-TYPE CODE FOR USER LABEL TRK  UL17 09024000
OFFTEN   EQU   10                       LENGTH OF EXTENT IN DSCB   UL17 09028000
EQU0     EQU   0                        ZERO                       UL17 09032000
OFF105   EQU   105            OFFSET IN F1 DSCB TO FIRST EXTENT    UL17 09036000
NEXTVOL  EQU   6                        OFFSET INTO JFCB FOR VOL NO     09037002
*                                                               SA53239 09038002
BLANK    EQU   X'40'                    HEX FOR BLANK           SA53239 09039002
*                                                                       09040000
*                                                                       09060000
         ORG   IGG0193A+1008                                            09080000
DAM2ID   DC    C'3C    ' ID OF BDAM 2ND EXECUTOR, TTR, LENGTH           09100000
         DC    H'0'      END OF TABLE MARKER                            09120000
         DC    F'0'        FILLER                                       09140000
         DC    C'019'    OPEN SVC CODE                                  09160000
         DC    AL1(126)  DOUBLE WORD OFFSET TO ID TABLE                 09180000
*                                                                       09200000
*                                                                       09220000
****************** CONTROL BLOCK DEFINITIONS *************************  09240000
*                                                                       09260000
UCBTYPCD EQU   19        OFFSET TO DEVICE TYPE IN UCB                   09280000
*                                                                       09300000
TIOEFSRT EQU   16        OFFSET TO THE UCB-SRT ADDRESS IN THE TIOT      09320000
*                                                                       09340000
*                                                                       09360000
*      DATA EXTENT BLOCK (DEB) DEFINITION                               09380000
*                                                                       09400000
         DS    0F                                                       09420000
DEB      DSECT                                                          09440000
DEBNMSUB DS    0CL1                    COUNT OF ROUTINES LOADED         09460000
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDRESS       09480000
DEBAMLNG DS    0CL1                    WORD CNT OF BDAM ADDED CORE      09500000
DEBDEBAD DS    CL4                     DEB CHAIN ADDRESS                09520000
DEBOFLGS DS    0CL1                    OPEN FLAGS                       09540000
DEBIRBAD DS    CL4                     IRB ADDRESS                      09560000
DEBOPATB DS    0CL1                    DATA SET ATTRIBUTES              09580000
DEBSYSPG DS    CL4                                                      09600000
DEBNMEXT DS    0CL1                    COUNT OF EXTENTS                 09620000
DEBUSRPG DS    CL4                                                      09640000
DEBPRIOR DS    0CL1                                                     09660000
DEBECBAD DS    CL4                                                      09680000
DEBPROTG DS    0CL1                                                     09700000
DEBDEBID DS    0CL1                                                     09720000
DEBDCBAD DS    CL4                     DCB ADDRESS                      09740000
DEBEXSCL DS    0CL1                    EXTENT SIZE SCALE                09760000
DEBAPPAD DS    CL4                     IOS APPENDAGE LIST ADDRESS       09780000
DEBDVMOD DS    0CL1                    FILE MASK CODE                   09800000
DEBUCBAD DS    CL4                     UCB ADDRESS                      09820000
DEBBINUM DS    CL2                     BIN NUMBER (BB)                  09840000
DEBSTRCC DS    CL2                     STARTING CYLINDER NUMBER         09860000
DEBSTRHH DS    CL2                     STARTING TRACK NUMBER            09880000
DEBENDCC DS    CL2                     ENDING CYLINDER NUMBER           09900000
DEBENDHH DS    CL2                     ENDING TRACK NUMBER              09920000
DEBNMTRK DS    CL2                     NO. OF TRACKS IN THIS EXTENT     09940000
DEBSUBID EQU   0         SUBROUTINE ID'S                                09960000
*                                                                       09980000
*                                                                       10000000
TCB      DSECT                                                          10020000
TCBRBP   DS    F                       POINTER TO EXECUTING RB          10040000
TCBPIE   DS    F                       POINTER TO PROG. INTERRUPT EL.   10060000
TCBDEBAD DS    F                       POINTER TO DEB QUEUE             10080000
TCBTIO   DS    F                       POINTER TO TIOT                  10100000
TCBCMP   DS    F                       TASK COMPLETION CODE             10120000
TCBTRN   DS    F                       TESTRAN FIELD                    10140000
TCBMSS   DS    F                       DATA BLOCK QUEUE ELEMENT POINTER 10160000
         DS    CL1                                                      10180000
TCBFLGS  DS    FL5                     FLAG BYTES                       10200000
TCBLMP   DS    CL1                     LIMIT PRIORITY                   10220000
TCBDSP   DS    CL1                     DISPATCHING PRIORITY             10240000
TCBLLS   DS    F                       POINTER TO LOAD LIST             10260000
TCBJLB   DS    F                       POINTER TO JOBLIB DCB            10280000
TCBJSE   DS    F                       LIST OF INACTIVE PROGRAMS ADDR.  10300000
TCBGRS   DS    CL64                    GENERAL REGISTER SAVE AREA       10320000
TCBIDF   DS    CL1                     TCB IDENTIFIER FIELD             10340000
TCBFSA   DS    CL3                     POINTER TO 1ST PROB. PROG.SAVEAR 10360000
TCBTCB   DS    F                       NEXT TCB ON READY QUEUE POINTER  10380000
TCBTME   DS    F                       POINTER TO TIMER ELEMENT         10400000
CVTDEF   DSECT                                                          10420000
         CVT                                                            10440000
         AIF   ('&LIB' EQ 'LIB1').OS003                                 10442002
*    DEFINITION OF PDS DIRECTORY PASSED TO LOAD                  XM8332 10450002
         IHAPDS                                                         10452002
.OS003   ANOP                                                           10454002
         EJECT                                                          10460000
*                                                                       10480000
         DCBD  DSORG=DA                                                 10500000
*                                                                       10520000
         EJECT                                                          10540000
*      DEFINITION OF CORE WORK AREA FOR EACH DCB                        10560000
FORCORE  DSECT                                                          10580000
         IECDSECT                                                       10600000
UCB      DSECT                                                          10620000
         IEFUCBOB                                                       10640000
         END                                                            10660000
