         TITLE 'IGG0193C - BDAM OPEN EXECUTOR NO. 2'                    00010000
IGG0193C CSECT                                                          00020000
*          RELEASE 16 DELETIONS                                         00027000
*7030030000                                                       13883 00030016
*          RELEASE 17 DELETIONS                                         00034000
*          RELEASE 18 DELETIONS                                         00041000
*1091                                                             MCS   00044018
*          RELEASE 19 DELETIONS                                         00048000
*0954001600-002400,005400-005600,009600-010600,024400,037000,    S19015 00049019
*0954038200,039600-057000,057400-057800,058000-058200,068800,    S19015 00050019
*0954078000,080600,082600,083200,083600                          S19015 00051019
*          RELEASE 20 DELETIONS                                         00055000
*          RELEASE 21 DELETIONS                                         00062000
*          RELEASE 22 DELETIONS                                         00069000
*          RELEASE 23 DELETIONS                                         00076000
*          RELEASE 24 DELETIONS                                         00083000
*STATUS CHANGE LEVEL 006                                                00093019
*FUNCTION/OPERATION- THIS ROUTINE IS BROUGHT INTO CORE AND GIVEN      * 00120000
*   CONTROL WHEN SOME OPEN EXECUTOR ISSUES 'XCTL' TO IGG0193C.        * 00140000
*   THIS ROUTINE LOADS SOME OF THE REQUIRED BDAM MODULES AS           * 00160019
*   SPECIFIED IN THE DCB FIELDS, MACRF, RECFM, OPTCD, BUFTEK, AND     * 00180019
*   STORES THE MODULE ID AND A COUNT OF MODULES LOADED INTO THE       * 00200019
*   DEB.                                                              * 00220019
*                                                                     * 00260000
*ENTRY POINT- ENTRY WILL BE TO THE FIRST BYTE OF THE MODULE BY AN     * 00280000
*   'XCTL' TO IGG0193C.                                               * 00300000
*                                                                     * 00320000
*INPUT- THE REGISTERS 5,6,7,8 ARE THE INPUT AS FOLLOWS,               * 00340000
*   5 - BEGINNING OF THE DCB PARAMETER LIST                           * 00360000
*   6 - BEGINNING OF THE WHERE-TO-GO TABLE                            * 00380000
*   7 - ADDRESS OF THE CURRENT ENTRY IN THE PARAMETER LIST            * 00400000
*   8 - ADDRESS OF THE CURRENT ENTRY IN THE WHERE-TO-GO TABLE         * 00420000
*                                                                     * 00440000
*OUTPUT- THE REGISTERS 7,8 WILL BE POSITIONED TO THE NEXT UNFINISHED  * 00460000
*   ENTRY, AN IRB WILL BE CONSTRUCTED IN PROTECTED CORE, AND THE      * 00480000
*   REQUIRED BDAM MODULES LOADED INTO CORE.                           * 00500000
*                                                                     * 00520000
*EXTERNAL ROUTINES- NONE.                                             * 00550019
*                                                                     * 00580000
*EXIT-NORMAL- THIS ROUTINE TERMINATES BY LOCATING THE NEXT NON-ZERO   * 00600000
*   ENTRY IN THE WHERE-TO-GO TABLE AND EXECUTING AN XCTL TO THAT      * 00620000
*   ROUTINE. THE SCAN OF THE TABLE BEGINS AT 'SCAN4EQ'.               * 00640000
*                                                                     * 00660000
*TABLES/WORK AREAS- 1.DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH * 00680000
*   DCB SPECIFIED INTHE OPEN MACRO INSTRUCTION.  2.WHERE-TO-GO TABLE  * 00700000
*   CONTAINS THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE      * 00720000
*   DCB WHICH CORRESPONDS TO THIS ENTRY AND THE ADDRESS OF A WORK AREA* 00740000
*   FOR THE DCB.  3.WORK AREA IS A 464 BYTE AREA ASSIGNED TO THIS DCB * 00760000
*   TEMPORARILY AND USED BY IGG0193C AS A REGISTER SAVE AREA.  4.THE  * 00780000
*   COMMUNICATION VECTOR TABLE IS A RESIDENT VECTOR LIST USED TO      * 00800000
*   LOCATE THE IOS APPENDAGE LIST, ROUTINE TO BUILD AN IRB, AND THE   * 00820000
*   SVC LIBRARY DCB.                                                  * 00840000
*                                                                     * 00860000
*ATTRIBUTES- THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AS        * 00880000
*   DISABLED, PRIVILEGED, AND REUSABLE.                               * 00900000
*                                                                     * 00920000
*NOTES- THIS ROUTINE IS THE SECOND OPEN EXECUTOR FOR A BDAM DCB AND   * 00940000
*   THE ID AND TTR OF IGG0193G ARE PLACED IN THE WHERE-TO-GO TABLE AS * 00970019
*   THE NEXT EXECUTOR TO BE CALLED TO COMPLETE PROCESSING FOR THIS    * 01000019
*   DCB.                                                              * 01030019
*                                                                       01080000
*                                                                       01100000
*                                                                       01120000
         USING STEPONE,RBASE                                            01140000
         USING DEB,RDEB                                                 01160000
         USING IHADCB,RDCB                                              01180000
         USING FORCORE,RCORE                                            01200000
*                                                                       01220000
*  REGISTER USAGE                                                       01240000
*                                                                       01260000
*                                                                       01280000
RE       EQU   0         WORK REGISTER                                  01300000
RF       EQU   1         WORK REGISTER                                  01320000
RDCB     EQU   2         USER'S DCB ADDRESS                             01340000
RBASE    EQU   3         BASE REGISTER                                  01360000
RCORE    EQU   4         WORK AREA ADDRESS                              01380000
RPAR     EQU   5         PARAMETER LIST ADDRESS                         01400000
RWTG     EQU   6         FRONT OF WHERE-TO-GO TABLE                     01420000
RPARC    EQU   7         CURRENT ENTRY IN PARAMETER LIST                01440000
R7       EQU   7         DEB SUBROUTINE ID INDEX                        01460000
RWTGC    EQU   8         CURRENT ENTRY IN WTG                           01480000
RTIOT    EQU   9         TIOT ADDRESS                                   01500000
R9       EQU   9         RETURN FOR MODULE LOAD ROUTINE                 01520000
RUCB     EQU   10        CURRENT UCB ADDRESS                            01540000
MODLOADR EQU   10        ADDRESS OF MODULE LOAD ROUTINE                 01560000
RDEB     EQU   11        DEB BASE REGISTER                              01580000
RB       EQU   12        WORK REGISTER                                  01600000
RC       EQU   13        WORK REGISTER                                  01620000
RD       EQU   14        WORK REGISTER                                  01640000
RJ       EQU   15        WORK/PARAMETER REGISTER                        01660000
*                                                                       01680000
         EJECT                                                          01700000
*                                                                       01720000
         BALR  RBASE,0                 ESTABLISH BASE FOR THIS ROUTINE  01740000
STEPONE  L     RDCB,0(0,RPARC)         LOAD THE DCB BASE REGISTER       01760000
         L     RCORE,4(0,RWTGC)        SET POINTER TO DCB WORK AREA     01780000
         STM   RPAR,RUCB,DXCCW4        SAVE OPEN'S REGISTERS            01800000
         L     RDEB,DCBDEBAD           LOAD THE DEB BASE                01820000
*                                                                       01840000
         MVI   DEBNMSUB,0              INITIALIZE NO. OF SUBROUTINES    01860000
         TM    DCBOPTCD,RELRD          IS ADDRESSING BY RELATIVE BLOCK  01880000
         BC    8,FIXAPP                 NO, SKIP NEXT STEP              01900000
         MVC   DEBAMLNG(1),DEBNMEXT    SET BDAM LENGTH TO WORD COUNT OF 01920000
         TM    DCBOPTCD,OVEROPT        IS OVERFLOW BEING USED           01940000
         BZ    FIXAPP                   NO- BRANCH                      01960000
         IC    RJ,DEBAMLNG             GET SIZE OF ACCESS METHOD SECT.  01980000
         LA    RJ,2(0,RJ)              INCREMENT WORD COUNT BY TWO      02000000
         STC   RJ,DEBAMLNG             STORE BACK INTO DEB              02020000
*                                        RELATIVE EXTENTS               02040000
FIXAPP   EQU   *                                                        02060000
         L     RJ,DEBAPPAD             LOCATE BDAM APPENDAGE LIST       02080000
         L     RC,CVTPTR(0,0)          LOCATE IOS APPENDAGE LIST        02100000
         L     RC,CVTXAPG-CVTDEF(0,RC)  AND MOVE IT  TO OUR APPENDAGE   02120000
         MVC   0(20,RJ),0(RC)            LIST                           02140000
         LA    R7,DEBDVMOD             ESTABLISH A POINTER TO THE       02160000
         SR    RF,RF                    SUBROUTINE ID AREA OF THE DEB   02180000
         IC    RF,DEBNMEXT              BY OFFSETTING FOR               02200000
         SLL   RF,4                     NO. OF EXTENTS X 16             02220000
         AR    R7,RF                    AND                             02240000
         SR    RF,RF                                                    02260000
         IC    RF,DEBAMLNG              ACCESS METHOD LENGTH (WORD      02280000
         SLL   RF,2                      COUNT FOR RELATIVE EXTENTS)    02300000
         AR    R7,RF                    TIMES 4                         02320000
         LA    MODLOADR,MODLOAD        SET POINTER TO LOAD ROUTINE      02340000
*                                                                       02360000
*                                                                       02380000
         TM    DCBBFTEK,RBFTKMSK        TEST FOR BUFTEK=R        S19015 02381019
         BZ    LOADS                    BRANCH TO LOAD KA IF NOT S19015 02382019
*                                       R                        S19015 02383019
         TM    DCBRECFM,VSMASK          IS RECFM=VS              S19015 02384019
         BO    VBOK                     YES,BRANCH               S19015 02385019
ROFF     NI    DCBBFTEK,OFFRMASK        TURN OFF BUFTEK=R BIT    S19015 02386019
         B     LOADS                    LOAD NON VRE MODULES     S19015 02387019
VBOK     TM    DCBRECFM,BMASK           TEST FOR RECFM=VBS       S19015 02388019
         BO    ROFF                     BRANCH IF YES            S19015 02389019
         LA    RB,VREKJ                 INITIALIZE POINTER TO KJ S19015 02390019
         MVC   C6(C2,RWTG),C0(RB)       MOVE ID AS LAST 2 BYTES  S19015 02391019
*                                       OF NAM                   S19015 02392019
         L     RF,CVTPTR(C0,C0)         SET POINTER TO SVC DCB   S19015 02393019
         L     RF,CVTSVDCB-CVTDEF(C0,RF)                         S19015 02394019
         LOAD  EPLOC=(6),DCB=(1)        LOAD THE FOUNDATION      S19015 02395019
*                                       MODULE KJ                S19015 02396019
         LA    R9,RTPT                  LOAD RETURN POINT        S19015 02397019
*                                       ADDRESS                  S19015 02398019
         B     MVRT                     GO TO MOVE ROUTINE       S19015 02399019
LOADS    LA    RB,MODIDTBL             INITIALIZE THE ID TABLE INDEX    02400000
         BALR  R9,MODLOADR             LOAD THE FOUNDATION MODULE       02420000
RTPT     IC    RC,DCBOFLGS              SAVE OPEN FLAGS          S19015 02440019
         ST    RE,DCBREAD               STORE FOUNDATION MODULE ADDR    02460000
         STC   RC,DCBOFLGS              RESTORE OPEN FLAGS              02480000
         LR    RC,RE                   SAVE FOUNDATION MODULE ADDRESS   02500000
         L     RE,ASIAD(0,RC)           LOAD OFFSET OF ASI ROUTINE      02520000
         CR    RE,RC                    HAS IT ALREADY BEEN RELOCATED   02540000
         BH    LDADDRM                  YES-SKIP RELOCATION             02560000
         AR    RE,RC                    NO-ADD OFFSET TO BASE ADDRESS   02580000
         ST    RE,ASIAD(0,RC)           STORE ADCON                     02600000
         L     RE,ERROFF(0,RC)         REPEAT FOR                       02620000
         AR    RE,RC                     INVALID REQUEST                02640000
         ST    RE,ERROFF(0,RC)           ERROR ROUTINE                  02660000
*                                                                       02680000
*   THE NEXT ROUTINE SELECTS THE ADDRESSING MODULE IF RELATIVE ADDRESS  02700000
*    IS TO BE USED. IF RELATIVE BLOCK, CHECK FOR FEEDBACK OPTION.       02720000
*                                                                       02740000
LDADDRM  EQU   *                                                        02760000
         TM    DCBOPTCD,ACTAD          TEST ACTUAL ADDRESSING OPTION    02780000
         BC    1,UPTOKEY                IF YES, NO MODULE IS NEEDED     02800000
         TM    DCBOPTCD,RELRD          TEST RELATIVE BLOCK ADDRESSING   02820000
         BC    1,LDRRMOD                IF YES, GO LOAD                 02840000
         BALR  R9,MODLOADR             LOAD RELATIVE TRACK ADDRESSING   02860000
         ST    RE,RTAD(0,RC)            MODULE, PUT ADDR IN FOUNDATION  02880000
         BC    15,UPTOKEY              GO TEST TYPE                     02900000
LDRRMOD  EQU   *                                                        02920000
         TM    DCBRECFM,X'20'          IS TRACK OVERFLOW PRESENT        02940000
         BO    TRKOV                    YES--BRANCH               13883 02960016
         LA    RB,6(0,RB)               NO--INDEX TO THAT MODULE  13883 02980016
         BALR  R9,MODLOADR              LOAD THAT MODULE AND            03020000
         ST    RE,RRAD(0,RC)            PUT IT'S ADDRESS IN FOUNDATION. 03040000
         B     FEEDBTST                 CONTINUE                  13883 03043016
TRKOV    LA    RB,18(0,RB)              INDEX TO MODULE           13883 03046016
         BALR  R9,MODLOADR              LOAD TRK OVFLOW MODULE    13883 03049016
         ST    RE,RROVAD(0,RC)          PUT ADDR IN FOUNDATION    13883 03052016
FEEDBTST EQU   *                                                  13883 03055016
         TM    DCBOPTCD,FEEDB          TEST NEED FOR THE RELATIVE BLOCK 03060000
         BC    8,UPTOKEY                FEEDBACK MODULE,                03080000
         BALR  R9,MODLOADR              LOAD IT IF REQUIRED AND         03100000
         ST    RE,DCBDFBK               STORE THE ADDRESS IN THE DCB.   03120000
UPTOKEY  LA    RB,IDTBLKEY             INCREMENT INDEX TO KEY ENTRY     03140000
         TM    DCBBFTEK,RBFTKMSK        TEST FOR BUFTEK=R        S19015 03144019
         BZ    TKEY                     BRANCH IF BUFTEK IS NOT  S19015 03148019
*                                       R                        S19015 03152019
         LA    RB,VREKR                 INITIALIZE POINTER TO KR S19015 03156019
*                                                                       03160000
*   THE NEXT ROUTINE SELECTS THE CHANNEL PROGRAM GENERATOR MODULES FOR  03180000
*    THE TYPES SPECIFIED.                                               03200000
*                                                                       03220000
TKEY     TM    DCBMACRF,KEY            READ KEY BEING USED              03240000
         BC    1,LDKEY                  IF YES, GO LOAD KEY ROUTINE     03260000
         TM    DCBMACRF+1,KEY          WRITE KEY BEING USED             03280000
         BC    8,UPX2                   IF NO, GO UP INDEX              03300000
LDKEY    BALR  R9,MODLOADR             LOAD THE KEY MODULE AND          03320000
         ST    RE,24(0,RC)             STORE ADDRESS IN FOUNDATION MOD  03340000
         TM    DCBOPTCD,EXSCH          SEE IF THE EXTENDED KEY MODULE   03360000
         BC    8,UPX2                   IS REQUIRED                     03380000
         BALR  R9,MODLOADR              IF SO, LOAD IT AND STORE ITS    03400000
         L     RD,24(0,RC)             ADDRESS IN THE                   03420000
         ST    RE,4(0,RD)               KEY MODULE AND                  03440000
         OI    DCBIOBAD,EOEBIT          SET A BIT SO END OF EXTENT      03460000
*                                       APPENDAGE IS LOADED LATER.      03480000
UPX2     LA    RB,IDTBLID              INCREMENT TO ID ENTRY IN TABLE   03500000
         TM    DCBBFTEK,RBFTKMSK        TEST FOR BUFTEK=R        S19015 03504019
         BZ    TID                      BRANCH IF BUFTEK IS NOT  S19015 03508019
*                                       R                        S19015 03512019
         LA    RB,VREKR                 INITIALIZE POINTER TO KR S19015 03516019
TID      TM    DCBMACRF,ID             TEST READ BY ID                  03520000
         BC    1,LDID                                                   03540000
         TM    DCBMACRF+1,ID           TEST WRITE BY ID                 03560000
         BC    8,NOID                                                   03580000
LDID     BALR  R9,MODLOADR             LOAD THE ID MODULE AND           03600000
         ST    RE,28(0,RC)             STORE ADDRESS IN FOUNDATION MOD  03620000
NOID     LA    RB,IDTBLSF              INCREMENT PAST ID ENTRY          03640000
TADD     TM    DCBMACRF+1,ADD          WRITE ADD MODULE REQUIRED        03660000
         BC    8,NOADD                  BRANCH NO                       03680000
         TM    DCBBFTEK,RBFTKMSK        TEST FOR BUFTEK=R        S19015 03683019
         BZ    LDFMTMOD                 BRANCH IF BUFTEK IS NOT  S19015 03686019
*                                       R                        S19015 03689019
         LA    RB,VREKN                 INITIALIZE POINTER TO KN S19015 03692019
         BALR  R9,MODLOADR              LOAD MODULE KN           S19015 03695019
         ST    RE,DCBDFOR               STORE THE ADDRESS IN DCB S19015 03698019
         LA    RB,IDKY                  INITIALIZE POINTER TO KY S19015 03701019
         B     HERE                     GO LOAD MODULE KY        S19015 03704019
LDFMTMOD TM    DCBRECFM,FIXED           IS DATA SET              S19015 03707019
*                                       PRE-FORMATTED            S19015 03710019
         BC    8,PREFM                  YES, GO INCREMENT ID TBL INDEX  03720000
LDADD    BALR  R9,MODLOADR             LOAD FORMAT MODULE AND           03740000
         ST    RE,DCBDFOR               STORE THE ADDRESS IN THE DCB    03760000
         TM    DCBOPTCD,EXSCH          SEE IF EXTENDED MODULE IS ALSO   03780000
         BC    8,NOADD                  NEEDED.                         03800000
HERE     BALR  R9,MODLOADR              IF YES, LOAD IT AND      S19015 03820019
         L     RD,DCBDFOR               STORE THE ADDRESS IN            03840000
         ST    RE,4(0,RD)               THE FORMAT MODULE.              03860000
         OI    DCBIOBAD,EOEBIT         SET END OF EXTENT INDICATION     03880000
         BC    15,NOADD                                                 03900000
PREFM    LA    RB,12(0,RB)             INCREMENT TO PRE-FORMAT TABLE    03920000
         BC    15,LDADD                 ENTRIES AND GO LOAD MODULE.     03940000
NOADD    LM    RPAR,RUCB,DXCCW4         RESTORE OPEN'S REGISTERS S19015 04740019
         MVC   22(7,RWTG),CONATB       RESTORE XCTL ATTRIBUTES, LENGTH  05720000
         MVC   C0(C5,RWTGC),DAM3G       GO TO NEXT BDAM EXECUTOR S19015 05760019
*                                                                       05840000
*                                                                       05860000
*                                                                       05880000
*  ROUTINE TO SCAN DCB LIST FOR OTHER DCBS REQUIRING THIS EXECUTOR.     05900000
*  IF NONE ARE FOUND, CONTROL IS TRANSFERED TO THE NEXT EXECUTOR OF THE 05920000
*  FIRST DCB WHICH IS NOT COMPLETED.                                    05940000
*                                                                       05960000
*                                                                       05980000
SCAN4EQ  LA    RWTGC,WGOFF(0,RWTGC)    INCREMENT WHERE TO GO INDEX      06000000
         LA    RPARC,PAROFF(0,RPARC)    AND DCB PARAMETER LIST INDEX    06020000
         CLC   0(2,RWTGC),AMIDCNST     DOES TABLE NAME THIS EXECUTOR    06040000
         BCR   8,RBASE                  YES, BRANCH TO ENTRY POINT      06060000
         CLC   0(2,RWTGC),OPIDCNST      NO, IS THIS END OF TABLE?       06080000
         BC    7,SCAN4EQ                NO, LOOP TO INCREMENT STEPS.    06100000
*                                                                       06120000
         LR    RPARC,RPAR              RESTORE BOTH INDEX REGISTERS TO  06140000
         LA    RWTGC,32(0,RWTG)         THEIR INITIAL VALUES            06160000
SCAN4ANY CLI   0(RWTGC),0              IS THIS DCB COMPLETED?           06180000
         BC    7,XCTLRTN                IF NOT, GO TO NAMED EXECUTOR.   06200000
         LA    RWTGC,WGOFF(0,RWTGC)    INCREMENT BOTH INDEX REGISTERS   06220000
         LA    RPARC,PAROFF(0,RPARC)    TO THE NEXT ENTRIES.            06240000
         BC    15,SCAN4ANY             LOOP TO CHECK COMPLETION         06260000
*                                                                       06280000
XCTLRTN  EQU   *                                                        06300000
         MVC   6(2,RWTG),0(RWTGC)      MOVE EXECUTOR ID TO PARAM LIST   06320000
         MVC   14(3,RWTG),2(RWTGC)      MOVE TTR                        06340000
         LA    RJ,DXCCW12              POINT TO WORK AREA               06360000
         XCTL  DE=(RWTG),SF=(E,(15))                                    06380000
*                                                                       06400000
*    THIS ROUTINE LOADS ALL BDAM MODULES AS REQUIRED.                   06420000
*                                                                       06440000
MODLOAD  EQU   *                                                        06460000
         MVC   6(2,RWTG),0(RB)         MOVE ID AS LAST 2 BYTES OF NAME  06480000
         MVC   14(3,RWTG),2(RB)         MOVE TTR FROM TABLE             06500000
         SR    RE,RE                                                    06520000
         IC    RE,5(0,RB)              CONVERT DOUBLE-WORD COUNT TO     06540000
         SLL   RE,3                     BYTES,                          06560000
         ST    RE,24(0,RWTG)            STORE INTO PARAMETER LIST.      06580000
         MVC   25(2,RWTG),26(RWTG)     MOVE LENGTH TO BOTH SLOTS        06600000
         MVC   27(2,RWTG),25(RWTG)      IN THE PARAMETER LIST.          06620000
         MVI   22(RWTG),ATBL           SET ATTRIBUTES                   06640000
         CH    RE,MAXSZ                TEXT GREATER THAN 1024           06660000
         BNH   SKIPMVC                  NO                              06680000
         MVC   27(2,RWTG),MAXSZ         YES, REDUCE TO MAXIMUM          06700000
         NI    22(RWTG),X'CA'           SET ATTRIBUTES TO INDICATE      06720000
*                                       MULTIPLE TEXT RECORDS           06740000
SKIPMVC  EQU   *                                                        06760000
*                                                                       06780000
         LR    RE,RWTG                 SET POINTER TO MODULE NAME       06800000
         L     RF,CVTPTR(0,0)                SET POINTER TO THE         06820000
         L     RF,CVTSVDCB-CVTDEF(0,RF)      SVC DCB                    06840000
         LOAD  DE=(0),DCB=(1)                                           06860000
MVRT     MVC   DEBSUBID(C2,C7),C0(RB)   MOVE ROUTINE ID TO THE   S19015 06870019
*                                       DEB                      S19015 06880019
         LA    7,2(0,7)                INCREMENT DEB ID INDEX           06900000
         LA    RB,6(0,RB)                        MODULE NAME INDEX      06920000
         IC    RF,DEBNMSUB                       DEB COUNT OF           06940000
         LA    RF,1(0,RF)                               SUBROUTINES     06960000
         STC   RF,DEBNMSUB                                              06980000
         BCR   15,R9                   RETURN TO DECISIONS              07000000
*                                                                     * 07001019
***** MASKS AND CONSTANTS                                         ***** 07002019
*                                                                     * 07003019
RBFTKMSK EQU   X'20'                    TEST IF BUFTK = R        S19015 07004019
SEGWKARS EQU   X'04'                    TEST IF SWA IS PRESENT   S19015 07005019
VSMASK   EQU   X'48'                    TEST FOR RECFM=VS        S19015 07006019
BMASK    EQU   X'10'                    TEST FOR RECFM=VBS       S19015 07007019
OFFRMASK EQU   X'DF'                    TURN OFF BUFTEK=R BIT    S19015 07008019
*                                                                       07009019
C0       EQU   0                        CONSTANT FOR ZERO        S19015 07010019
C2       EQU   2                        CONSTANT FOR TWO         S19015 07011019
C5       EQU   5                        CONSTANT FOR FIVE        S19015 07012019
C6       EQU   6                        CONSTANT FOR SIX         S19015 07013019
C7       EQU   7                        CONSTANT FOR SEVEN       S19015 07014019
*                                                                       07015019
*                                                                       07020000
AMIDCNST DC    C'3C'                   THIS EXECUTOR'S ID               07040000
OPIDCNST DC    C'0S'                   LAST WTG TABLE ENTRY             07060000
CONH24   DC    H'24'                   CONSTANT 24                      07080000
MAXSZ    DC    H'1024'                 MAXIMUM LENGTH OF A TEXT RECORD  07100000
CONATB   DC    X'C3780004000400'       XCTL ATTRIBUTES AND LENGTHS      07120000
ATBL     EQU   X'CB'                   LOAD ATTRIBUTES                  07140000
WGOFF    EQU   8                       OFFSET IN WHERE TO GO TABLE      07160000
PAROFF   EQU   4                       OFFSET IN DCB PARAMETER LIST     07180000
*                                                                       07200000
ID       EQU   X'08'     TYPE ID                                        07220000
KEY      EQU   X'10'     TYPE KEY                                       07240000
ADD      EQU   X'02'     TYPE ADD                                       07260000
EXSCH    EQU   X'20'     EXTENDED SEARCH                                07280000
RELRD    EQU   X'01'     RELATIVE BLOCK ADDRESSING                      07300000
FEEDB    EQU   X'10'     FEEDBACK                                       07320000
ACTAD    EQU   X'08'     ACTUAL ADDRESSING                              07340000
DYNB     EQU   X'04'     DYNAMIC BUFFERING                              07360000
VERIFY   EQU   X'80'     WRITE VERIFY                                   07380000
READX    EQU   X'02'     READ EXCLUSIVE                                 07400000
*                                                                       07420000
FIXED    EQU   X'40'     TEST RECORD FORMAT FIXED                       07440000
EOEBIT   EQU   8         INDICATOR THAT END OF EXTENT IS TO BE LOADED   07460000
SIOBIT   EQU   4         INDICATOR THAT START I/O IS TO BE LOADED       07480000
RDXCNT   EQU   9         NUMBER OF ENTRIES IN READX LIST(MAXIMUM)       07500000
*                                                                       07520000
*                                                                       07540000
RRAD     EQU   4         OFFSET TO RELATIVE BLOCK CONVERSION MOD ADDR   07560000
RTAD     EQU   8         OFFSET TO RELATIVE TRACK CONVERSION MOD ADDR   07580000
VERAD    EQU   12        OFFSET TO VERIFY MODULE ADDRESS                07600000
ASIAD    EQU   16        OFFSET TO ASYNCHRONOUS INTERRUPT ROUTINE ADDR  07620000
ERROFF   EQU   20        OFFSET TO INVALID REQUEST ERROR ROUTINE        07640000
RROVAD   EQU   32        OFFSET TO REL BLK CONV/TRK OFLO MOD ADDR 13883 07650016
OVERBLK  EQU   X'20'     OVERFLOW INDICATOR IN DCB FIELD  RECFM         07660000
OVEROPT  EQU   X'40'     OVERFLOW INDICATOR IN DCB FIELD  OPTCD         07680000
CHECK    EQU   X'01'                   CHECK MACRO BEING USED BIT       07700000
*                                                                       07720000
*                                                                       07740000
*                                                                       07760000
*                                                                       07780000
         ORG   IGG0193C+856             BEGINNING OF XCTL TABLE  S19015 07800019
MODIDTBL DS    0D            TABLE OF MODULE IDS, TTR, LENGTH           07820000
*                                                                       07840000
         DC    C'KA    '     FOUNDATION                                 07860000
         DC    C'KC    '     RELATIVE TRACK                             07880000
         DC    C'KE    '     RELATIVE BLOCK                             07900000
         DC    C'KG    '     FEEDBACK-RELATIVE BLOCK                    07920000
         DC    C'KF    '     RELATIVE BLOCK WITH TRACK OVERFLOW         07940000
         DC    C'KH    '     FEEDBACK-RELATIVE BLOCK WITH OVERFLOW      07960000
IDTBLKEY DC    C'KI    '     KEY                                        07980000
         DC    C'KW    '     KEY-EXTENDED SEARCH                        08000000
IDTBLID  DC    C'KK    '     ID                                         08020000
IDTBLSF  DC    C'KM    '     SELF FORMAT                                08040000
IDKY     DC    C'KY    '                SELF FORMAT-EXTENDED     S19015 08050019
*                                       SRCH                     S19015 08060019
         DC    C'KO    '     PRE FORMAT                                 08080000
         DC    C'LA    '     PRE FORMAT-EXTENDED SEARCH                 08100000
IDTBLOPS DC    C'KQ    '     VERIFY                                     08120000
IDTBLCHK DC    C'LI    '     CHECK                                      08140000
IDTBLRDX DC    C'LG    '     READ EXCLUSIVE                             08160000
IDTBLDYN DC    C'LE    '     DYNAMIC BUFFERING                          08180000
IDTBLSIO DC    C'KS    '     START I/O APPENDAGE                        08200000
IDTBLEOE DC    C'LC    '     END-OF-EXTENT APPENDAGE                    08220000
IDTBLCE  DC    C'KU    '     CHANNEL END APPENDAGES                     08240000
DAM3G    DC    C'3G    '                BDAM 3RD EXECUTOR        S19015 08245019
VREKJ    DC    C'KJ    '                VRE FOUNDATION           S19015 08250019
         DC    C'KC    '                RELATIVE TRACK           S19015 08255019
VREKR    DC    C'KR    '                VRE REPLACES KI OR KK    S19015 08260019
         DC    C'KW    '                KEY EXTENDED SEARCH      S19015 08265019
VREKN    DC    C'KN    '                SELF-FORMAT              S19015 08270019
VREDB    DC    C'KL    '                RELATIVE BLOCK           S19015 08275019
*                                                                       08280000
         DC    H'0'          END OF TABLE MARKER                        08300000
         ORG   IGG0193C+1020            ORG TO MODULE END        S19015 08320019
         DC    C'019'        SVC OF OPEN                                08340000
         DC    AL1(107)                 DOUBLE WD OFFSET TO ID   S19015 08350019
*                                       TAB                      S19015 08360019
         EJECT                                                          08380000
FORCORE  DSECT                                                          08400000
         IECDSECT                                                       08420000
CVTDEF   DSECT                                                          08440000
         CVT                                                            08460000
*                                                                       08480000
DEB      DSECT                                                          08500000
         DS    0F                                                       08520000
DEBNMSUB DS    0CL1      NO. OF SUBR. LOADED BY OPEN                    08540000
DEBTCBAD DS    CL4       ADDRESS OF THE TCB FOR THIS DEB                08560000
DEBAMLNG DS    0CL1      NO. OF BYTES IN THE ACCESS MTHD. DPDT. SECTION 08580000
DEBDEBAB DS    CL4       ADDRESS OF THE PREVIOUS DEB IN THE SAME TASK   08600000
DEBOFLGS DS    0CL1      DATA SET STATUS FLAGS                          08620000
DEBIRBAD DS    CL4       IRB ADDRESS                                    08640000
DEBOPATB DS    0CL1      TYPE OF FILES                                  08660000
DEBSYSPG DS    CL4       ADDRESS OF FIRST IOB IN THE SYSTEM PURGE CHAIN 08680000
DEBNMEXT DS    0CL1      NUMBER OF EXTENTS SPECIFIED IN THE DSCB        08700000
DEBUSRPG DS    CL4       ADDRESS OF FIRST IOB IN THE USER PURGE CHAIN   08720000
DEBPRIOR DS    0CL1      ALWAYS ZERO                                    08740000
DEBECBAD DS    CL4       ECB ADDRESS FOR SVC PURGE REQUEST              08760000
DEBPROTG DS    0CL1      RESERVED FOR FUTURE USE (FIRST 4 BITS)         08780000
DEBDEBID DS    0CL1      HEX 'F' TO IDENTIFY THIS BLOCK AS A DEB        08800000
DEBDCBAD DS    CL4       ADDRESS OF THE DCB ASSOCIATED WITH THIS DEB    08820000
DEBEXSCL DS    0CL1      EXTENT SCALE                                   08840000
DEBAPPAD DS    CL4       ADDRESS OF I/O APPENDAGE VECTOR TABLE          08860000
DEBDVMOD DS    0CL1      DEVICE MODIFIER FILE MASK                      08880000
DEBUCBAD DS    CL4       ADDR OF UCB ASSOCIATED WITH THIS DATA EXTENT   08900000
DEBBINUM DS    CL2       RESERVED FOR FUTURE USE-ALWAYS ZERO            08920000
DEBSTRCC DS    CL2       STARTING CYLINDER NUMBER FOR EXTENT            08940000
DEBSTRHH DS    CL2       STARTING HEAD NUMBER FOR EXTENT                08960000
DEBENDCC DS    CL2       ENDING CYLINDER NUMBER FOR EXTENT              08980000
DEBENDHH DS    CL2       ENDING HEAD NUMBER FOR EXTENT                  09000000
DEBNMTRK DS    CL2       NUMBER OF TRACKS ALLOCATED TO A GIVEN EXTENT   09020000
DEBSUBID EQU   0         SUBROUTINE ID'S                                09040000
*                                                                       09060000
*                                                                       09080000
         DCBD  DSORG=DA                                                 09100000
         END                                                            09120000
