         TITLE 'IGG0193E - BDAM PHASE THREE OPEN EXECUTOR'       S20201 00010020
         COPY  LCGASMSW                                                 00012001
IGG0193E CSECT                                                          00020000
*                                                                       00022000
*          RELEASE 18 DELETIONS                                         00028000
*2750                                                             MCS   00029018
*2750074600                                                       8M647 00030018
*          RELEASE 19 DELETIONS                                         00031000
*1996                                                            A25965 00032019
*          RELEASE 20 DELETIONS                                         00034000
*3521041680,041760,041840,041920                                 A37852 00034520
*3521                                                            S20201 00035020
*          RELEASE 21 DELETIONS                                         00037000
*D080560                                                         SM4356 00037121
*D028200,042000,043200,044800                                   SA49438 00037221
*0931013400-013600,016200                                        M0024  00037521
*0931013400-013600,016200,073200,073600-073800,074400-074600,    S21042 00038021
*0931080600-081200,081600-081800                                 S21042 00039021
*                                                               SA55468 00049021
*                                                               SA53843 00059021
*D028100                                                        XA01256 00059421
*            THE FIX FOR   SM5482 IS FLAGGED XA01256             SM5482 00059821
*                                                               SA60608 00059902
*   THE FIX FOR XM2972 IS FLAGGED SA60608                        XM2972 00066602
* VS1 RELEASE 030 DELETIONS                                             00068603
*D027620-027760                                                  XM4346 00070603
*                                                                     * 00073302
*STATUS CHANGE LEVEL 012   08/07/73                                     00080003
*                                                                     * 00090021
*FUNCTION/OPERATION- THIS ROUTINE IS BROUGHT INTO CORE AND GIVEN      * 00100000
*   CONTROL WHEN SOME OPEN EXECUTOR ISSUES AN 'XCTL' TO IGG0193E.     * 00120000
*   IF RELATIVE BLOCK ADDRESSING IS SPECIFIED, THE RELATIVE EXTENTS   * 00140000
*   WILL BE APPENDED TO THE DEB WHICH HAS ALREADY BEEN CONSTRUCTED    * 00160000
*   BY IGG0193A. THE FORMAT OF THESE RELATIVE EXTENTS IS,             * 00180000
*    BLOCKS PER TRACK - ONE BYTE                                      * 00200000
*    BLOCKS PER EXTENT- THREE BYTES.                                  * 00220000
*   IF TRACK OVERFLOW IS ALSO SPECIFIED TWO ADDITIONAL FIELDS ARE     * 00240000
*   INSERTED BETWEEN THE RELATIVE AND ACTUAL EXTENTS. THESE ARE       * 00260000
*   (1) TRACKS PER PERIOD AND (2) RECORDS PER PERIOD                  * 00280000
*   IF DYNAMIC BUFFERING IS SPECIFIED THIS ROUTINE WILL CALCULATE     * 00300000
*   AND OBTAIN(BY A GETMAIN) THE NUMBER OF BYTES REQUIRED FOR THE     * 00320000
*   BUFFERS AND FOR A BUFFER CONTROL BLOCK. IT WILL DIVIDE THE        * 00340000
*   ACQUIRED AREA INTO  A  BUFFER CONTROL BLOCK AND THE SPECIFIED     * 00360000
*   NUMBER OF BUFFERS.                                                * 00380000
*                                                                     * 00400000
*ENTRY POINT- ENTRY WILL BE TO THE FIRST BYTE OF THE MODULE BY AN     * 00420000
*   'XCTL' TO IGG0193E.                                               * 00440000
*                                                                     * 00460000
*INPUT- REGISTERS 5,6,7,8 ARE INPUT AS FOLLOWS,                       * 00480000
*   5 - BEGINNING OF THE DCB PARAMETER LIST                           * 00500000
*   6 - BEGINNING OF THE WHERE-TO-GO TABLE                            * 00520000
*   7 - ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST        * 00540000
*   8 - ADDRESS OF THE CURRENT ENTRY IN THE WHERE-TO-GO TABLE         * 00560000
*                                                                     * 00580000
*OUTPUT- REGISTERS 7 AND 8 WILL BE POSITIONED TO THE NEXT UNFINISHED  * 00600000
*   ENTRY, CORE WILL BE ACQUIRED FOR BUFFERS AND A BCB IF REQUESTED,  * 00620000
*   AND THE DEB WILL BE COMPLETED IF NECESSARY.                       * 00640000
*                                                                     * 00660000
*EXTERNAL ROUTINES-N/A                                                * 00680000
*                                                                     * 00700000
*EXIT-NORMAL- THIS ROUTINE TERMINATES BY LOCATING THE NEXT NON-ZERO   * 00720000
*   ENTRY IN THE WHERE-TO-GO TABLE AND EXECUTING AN 'XCTL' TO THAT    * 00740000
*   ROUTINE. THE SCAN OF THE TABLE BEGINS AT 'SCAN4EQ'.               * 00760000
*EXIT-ERROR - XCTL TO PROB DET (IGG0196M) FOR WTP AND 013 ABEND         00770021
*                                                                     * 00780000
*TABLES/WORK AREAS- 1. DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH* 00800000
*   DCB SPECIFIED IN THE OPEN MACRO INSTRUCTION. 2. WHERE-TO-GO TABLE * 00820000
*   CONTAINS THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE      * 00840000
*   DCB WHICH CORRESPONDS TO THIS ENTRY AND THE ADDRESS OF A WORK AREA* 00860000
*   FOR THE DCB. 3. THE WORK AREA IS A 464 BYTE AREA ASSIGNED TO THIS * 00880000
*   DCB 4. COMMUNICATION VECTOR TABLE IS A RESIDENT VECTOR LIST USED  * 00900000
*   TO LOCATE THE DIRECT ACCESS DEVICE TABLE.                         * 00920000
*   5.DIRECT ACCESS DEVICE TABLE(DADT) CONTAINS AN ENTRY FOR EACH     * 00940000
*   DIRECT ACCESS DEVICE WHICH DEFINES THE  PHYSICAL CHARACTERISTICS  * 00960000
*   OF EACH DEVICE SUCH AS TRACK LENGTH,OVERHEAD,TOLERANCE,ETC.       * 00980000
*                                                                     * 01000000
*ATTRIBUTES- THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA  AND IS   * 01020000
*   DISABLED, PRIVILEGED, AND REUSABLE                                * 01040000
*                                                                     * 01060000
*NOTES- THIS ROUTINE COMPLETES THE BDAM PROCESSING THAT IS TO BE DONE * 01080000
*   FOR THIS DCB SO THE WHERE-TO-GO TABLE ENTRY WILL BE SET TO ZERO   * 01100000
*                                                                     * 01120000
*                                                                       01140000
*  REGISTER USAGE                                                       01160000
*                                                                       01180000
*                                                                       01200000
WKREG0   EQU   0                                                        01220000
LRREG    EQU   0                       LENGTH OF A LAST RECORD          01240000
RE       EQU   0                       WORK REGISTER                    01260000
RF       EQU   1                       WORK REGISTER                    01280000
DEBREG   EQU   1                                                        01300000
REXREG   EQU   2                       POINTER TO PERIOD IN THE DEB     01320000
TCBREG   EQU   2                       POINTER TO TCB                   01330001
RCORE    EQU   3                        ADDR OF OPEN WORK AREA   M0024  01340021
WKREG1   EQU   4                        WORK REGISTER            M0024  01360021
WKREG2   EQU   5                       WORK REGISTER                    01380000
RPAR     EQU   5                       PARAMETER LIST ADDRESS           01400000
RWTG     EQU   6                       FRONT OF THE WHERE-TO GO-TABLE   01420000
TABREG   EQU   6                       POINTER TO TABLE ENTRY FOR TYPE  01440000
REXREG2  EQU   6                       POINTER TO CURRENT REL. EXTENT   01460000
CTOVREG  EQU   7                       COUNT(COUNT+OVERHEAD)            01480000
RPARC    EQU   7                       CURRENT ENTRY IN PARAMETER LIST  01500000
RWTGC    EQU   8                       CURRENT ENTRY IN WTG             01520000
RD       EQU   8                       WORK REGISTER FOR DYNAMIC BUF.   01540000
CTKY1REG EQU   8                       COUNT+KEY+ONE DATA BYTE LENGTH   01560000
WKREG3   EQU   9                                                        01580000
R9       EQU   9                       RETURN FOR MODULE LOAD ROUTINE   01600000
FDNBASE  EQU   10                       BASE REGISTER            M0024  01620021
NRCDREG  EQU   11                      NUMBER OF RECORDS/PERIOD         01640000
NTRKREG  EQU   12                      NUMBER OF TRACKS/PERIOD          01660000
RB       EQU   12                      WORK REGISTER                    01680000
DSSZREG  EQU   13                                                       01700000
RC       EQU   13                      WORK REGISTER FOR DYNAMIC BUF.   01720000
DCBREG   EQU   14                                                       01740000
RJ       EQU   14                      WORK REGISTER                    01760000
RRREG    EQU   15                      LENGTH OF A REGULAR RECORD       01780000
OABD051  EQU   51                                                S21042 01790021
MINDATA  EQU   1                       MIN DATA ON ONE TRACK    SA53843 01792021
*                                                                       01800000
*                                                                       01820000
*                                                                       01840000
         USING DEB,DEBREG                                               01860000
         USING IHADCB,DCBREG                                            01880000
         USING FORCORE,RCORE                                            01900000
         USING BEGIN,FDNBASE                                            01920000
*                                                                       01940000
*                                                                       01960000
*                                                                       01980000
         IEZBITS                                                        01990001
         EJECT                                                          02000000
         BALR  FDNBASE,0                                                02020000
BEGIN    EQU   *                                                        02040000
         L     RCORE,4(0,RWTGC)        SET POINTER TO DCB WORKAREA      02060000
         MVI   DXCCW10,X'00'           ZERO BYTE USED LATER      A49438 02070021
         STM   WKREG0,R9,DXCCW4        SAVE OPEN'S REGISTERS            02080000
         L     DCBREG,0(0,RPARC)       LOAD DCB BASE REGISTER           02100000
         TM    DCBOPTCD,RELRD          RELATIVE BLOCK ADDRESSING        02120000
         BZ    DYNBUFIN                NO, GO CHECK FOR DYN. BUF.       02140000
         IC    WKREG2,DCBKEYLE         SAVE THE ADDRESS OF THE WORK     02160000
         ST    RCORE,DCBKEYLE          AREA IN THE DCB SAVING THE       02180000
         STC   WKREG2,DCBKEYLE         KEY LENGTH                       02200000
         SR    DSSZREG,DSSZREG         SET DATA SET SIZE TO ZERO        02220000
         AIF   ('&LIB' NE 'LIB1').DEBCK10  TEST FOR LIB1(OS)     YM0890 02230001
         L     DEBREG,DCBDEBAD         GET DEB ADDRESS                  02240000
.DEBCK10 ANOP                                                    Y01021 02250000
         AIF   ('&LIB' EQ 'LIB1').DEBCK20  TEST FOR LIB1(OS)     Y01021 02252000
         L     DEBREG,DXPDEBAD          LOAD PROTECTED DEB ADDR  Y01021 02254000
.DEBCK20 ANOP                                                    Y01021 02256000
         SR    WKREG3,WKREG3           CLEAR NUMBER OF EXTENTS REGISTER 02260000
         IC    WKREG3,DEBNMEXT         GET NUMBER OF EXTENTS            02280000
         LA    REXREG,32(0,DEBREG)                                      02300000
EXTLOOP  LA    REXREG,EXTSZ(0,REXREG)  ADD ON EXTENT SIZE AS MANY TIMES 02320000
         BCT   WKREG3,EXTLOOP          AS THERE ARE EXTENTS             02340000
         IC    WKREG3,DEBNMEXT         GET NUMBER OF EXTENTS            02360000
NEWEXT   EQU   *                                                        02380000
         L     WKREG2,CVTPTR(0,0)      GET A POINTER TO THE DIRECT      02400000
         L     WKREG2,CVTZDTAB-CVTDEF(0,WKREG2) ACCESS DEVICE TABLE     02420000
         L     TABREG,DEBUCBAD         LOCATE DEVICE TYPE TO MATCH UCB  02440000
         SR    WKREG1,WKREG1                                            02460000
         IC    WKREG1,UCBTYPCD(0,TABREG) IN THE TABLE USING TYPE CODE   02480000
         LA    TABREG,15               SET THE MASK                     02500000
         NR    WKREG1,TABREG            CLEAR ALL BUT LOW ORDER 4 BITS  02520000
         IC    WKREG1,0(WKREG1,WKREG2)  IN FRONT OF THE TABLE           02540000
         LA    TABREG,0(WKREG1,WKREG2) TABREG POINTS TO THE TABLE ENTRY 02560000
*                                                                       02580000
         SR    RRREG,RRREG             CLEAR OUT WORK REGISTERS         02600000
         SR    WKREG1,WKREG1                                            02620000
         SR    LRREG,LRREG                                              02640000
         IC    RRREG,DCBKEYLE          IF THERE ARE NO KEYS, THE        02660000
         LTR   RRREG,RRREG              OVERHEAD FACTOR WILL BE REDUCED 02680000
         BC    7,*+8                    BY OVERHEAD FOR KEYS            02700000
         IC    WKREG1,OVERK(0,TABREG)                                   02720000
         IC    LRREG,OVERL(0,TABREG)                                    02740000
         TM    BYTEDEV(TABREG),TBOVHD   FOR 2305-1 & 2305-2      S20201 02744020
         BNO   MZ0010                   A TWO OVERHEAD IS        S20201 02748020
         LH    LRREG,OVERI(TABREG)      FOR CALCULATING          S20201 02752020
MZ0010   EQU   *                                                 S20201 02756020
         SR    LRREG,WKREG1            LRREG HAS OVERHEAD FACTOR        02760000
         LR    CTKY1REG,LRREG          GET COUNT + KEY IN REG           02780000
         AR    CTKY1REG,RRREG                                           02800000
         LA    CTKY1REG,1(0,CTKY1REG)  ADD 1 DATA BYTE          OS60608 02810002
         AH    RRREG,DCBBLKSI          KL+DL IN RRREG                   02840000
         AR    LRREG,RRREG             LRREG HAS LAST RECORD LENGTH     02860000
         MH    RRREG,TOLER(0,TABREG)   CALCULATE 1.049(KL+DL)+OVERHEAD  02880000
         SRL   RRREG,9                                                  02900000
         SR    WKREG2,WKREG2           DEVELOP OVERHEAD FOR             02920000
         IC    WKREG2,OVERI(0,TABREG)   INTERMEDIATE RECORDS            02940000
         TM    BYTEDEV(TABREG),TBOVHD   DEV CHAR TABL WILL       S20201 02944020
         BNO   MZ0020                   HAVE TWO BYTE OVERHEAD   S20201 02948020
         LH    WKREG2,OVERI(TABREG)       FOR SOME DEVICES       S20201 02952020
MZ0020   EQU   *                                                 S20201 02956020
         SR    WKREG2,WKREG1            (REDUCE IF NO KEYS PRESENT)     02960000
         AR    RRREG,WKREG2            RRREG HAS SIZE OF REGULAR RECORD 02980000
         TM    DCBRECFM,OVERFL         OVERFLOW RECORDS PRESENT         03000000
         BZ    RECTRK                  NO, BRANCH                       03020000
         SR    CTOVREG,CTOVREG                                          03040000
         IC    CTOVREG,OVERI(0,TABREG) GET OVERHEAD FOR REGULAR RECORDS 03060000
         TM    BYTEDEV(TABREG),TBOVHD   (TWO BYTES ARE NECESSARY S20201 03064020
         BNO   MZ0030                    FOR A 2305-1 OR 2305-2) S20201 03068020
         LH    CTOVREG,OVERI(TABREG)                             S20201 03072020
MZ0030   EQU   *                                                 S20201 03076020
         IC    WKREG1,OVERK(0,TABREG)  KEY OVERHEAD TO SUBTRACT  XM4346 03086003
         SR    CTOVREG,WKREG1          GET COUNT AND ITS OVERHEAD.      03100000
         LH    WKREG1,TRKL(0,TABREG)   GET AND STORE THE TRACK          03120000
         ST    WKREG1,DXCCW9           LENGTH                           03140000
         LH    WKREG1,TOLER(0,TABREG)  GET TOLERANCE FACTOR             03160000
         STH   WKREG1,DXCCW10+2                                         03180000
         MVI   DXCCW10+4,X'FF'         MAKE SURE INITIAL COMPARE FAILS  03200000
NEXTEXT  EQU   *                                                        03220000
         SR    NTRKREG,NTRKREG         CLEAR OUT FOR TRACKS/PERIOD      03240000
         SR    NRCDREG,NRCDREG         CLEAR OUT FOR RECORDS/PERIOD     03260000
         C     LRREG,DXCCW9            COMPARE RECORD LENGTH TO TRACK L 03280000
         BH    BIGRECRD                IF HIGH IT'S MORE THAN ONE TRACK 03300000
         L     WKREG2,DXCCW9           GET TRACK LENGTH                 03320000
LOOP     SR    WKREG1,WKREG1           CLEAR OUT REGISTER FOR DIVISION  03340000
         DR    WKREG1,RRREG            DIVIDE LENGTH OF TRACK BY        03360000
*                                      REGULAR RECORD LENGTH WKREG2=    03380000
*                                      QUOTIENT,WKREG1= REMAINDER       03400000
         LA    NTRKREG,1(0,NTRKREG)    ADD ONE TO TRACK COUNT           03420000
         AR    NRCDREG,WKREG2          ADD QUOTIENT TO NO. OF RECORDS   03440000
         TM    DXCCW10,SECOND          TEST FOR SECOND PASS             03460000
         BZ    *+12                    IF NOT GO ON                     03480000
         C     NTRKREG,DXCCW10+4       COMPARE TRACKS TO TOTAL TRACKS   03500000
         BE    FINI2                   IF EQUAL GO TO CALCULATE SIZE    03520000
         ST    WKREG1,DXCCW9+4         SAVE THE REMAINDER               03540000
         LR    WKREG2,WKREG1           GET REMAINDER AGAIN, DIVIDE BY   03560000
         SR    WKREG1,WKREG1           RECORD LENGTH                    03580000
         DR    WKREG1,LRREG            QUOTIENT=WKREG2                  03600000
         AR    NRCDREG,WKREG2          ADD QUOTIENT TO RECORD COUNT     03620000
         LTR   WKREG2,WKREG2           TEST TO SEE IF A LAST(FULL)      03640000
         BC    7,FINI                  RECORD WILL FIT.YES GO OUT       03660000
         L     WKREG2,DXCCW9+4         GET REMAINDER AGAIN AND          03680000
         SR    WKREG2,CTKY1REG         SUBTRACT MINIMUM OVERFLOW PIECE  03700000
         BM    FINI                    IF DOES NOT FIT, END OF  SA60608 03720002
*                                       PERIOD                   A49438 03730021
         LA    NRCDREG,1(0,NRCDREG)    IF YES UPDATE RECORD COUNT       03740000
         LA    WKREG2,1(0,WKREG2)      SIZE OF DATA FIELD        XM4346 03750003
         LH    WKREG1,DCBBLKSI         AND SUBTRACT FROM IT THE AMOUNT  03780000
         SR    WKREG1,WKREG2           OF DATA THAT FIT ON THE LAST     03800000
         MH    WKREG1,DXCCW10+2        TRACK,THEN MULTIPLY THIS BY THE  03820000
         SRL   WKREG1,9                OVERHEAD FACTOR.                 03840000
         L     WKREG2,DXCCW9           GET TRACK LENGTH AND SUBTRACT    03860000
         SR    WKREG2,CTOVREG          CT AND ITS OVERHEAD FROM IT AND  03880000
         SR    WKREG2,WKREG1           THEN SUBTRACT DATA+ALL OVERHEAD  03900000
         B     LOOP                    GO BACK FOR NEXT TRACK           03920000
BIGRECRD EQU   *                                                        03940000
         LA    NTRKREG,1(0,NTRKREG)    ADD ONE TO TRACK COUNT           03960000
         LR    WKREG1,LRREG            GET RECORD LENGTH AND            03980000
         S     WKREG1,DXCCW9           SUBTRACT LENGTH OF TRACK FROM IT 04000000
LOOP2    EQU   *                                                        04020000
LOOP3    EQU   *                                                        04040000
         TM    DXCCW10,SECOND          TEST FOR SECOND PASS             04060000
         BZ    *+12                    IF NOT GO ON                     04080000
         C     NTRKREG,DXCCW10+4       COMPARE TRACKS TO TOTAL TRACKS   04100000
         BE    FINI2                   IF EQUAL GO TO CALCULATE SIZE    04120000
         LA    NTRKREG,1(0,NTRKREG)    ADD ONE TO TRACK COUNT           04140000
         AR    WKREG1,CTOVREG          OVERHEAD FOR MID SEGMENT  XM4346 04160003
*                                      ON INTERMEDIATE TRACK    SA60608 04210002
         S     WKREG1,DXCCW9           SUBTRACT TRACK LENGTH     XM4346 04212003
         BP    LOOP3                   POSITIVE YES LOOP BACK           04220000
LASTTRK  EQU   *                                                        04240000
         LA    NRCDREG,1(0,NRCDREG)    ADD ONE TO RECORD COUNT          04260000
         LTR   WKREG1,WKREG1           TEST WKREG1                      04280000
         BZ    FINI                    IF ZERO THAT'S IT                04300000
         L     WKREG2,DXCCW9           GET TRACK LENGTH AND             04360000
         AR    WKREG1,WKREG2           ADD LEN OF TRK            XM4346 04365003
*                                      BACK ON                  SA60608 04367002
         SR    WKREG1,CTOVREG          SUBTRACT OHD ADDED BEFORE XM4346 04377003
         SR    WKREG2,CTOVREG          SUBTRACT COUNT FROM IT AND THEN  04380000
         MH    WKREG1,DXCCW10+2        MULTIPLY REMAINING DATA BYTES    04400000
         SRL   WKREG1,9                BY THE OVERHEAD FACTOR AND       04420000
         SR    WKREG2,WKREG1           SUBTRACT IT FROM THE RESULT AND  04440000
         CR    WKREG2,CTKY1REG         COMPARE RESULT TO COUNT+KEY+1    04460000
         BL    FINI                    IF NOT HIGH, NO OVERFLO  SA60608 04480002
*                                       FITS                     A49438 04490021
         LR    WKREG1,LRREG            GET LENGTH OF RECORD AND         04500000
         SR    WKREG1,WKREG2           SUBTRACT AMOUNT OF BYTES LEFT ON 04520000
         B     LOOP2                   THIS TRACK AND GO BACK TO START  04540000
FINI     EQU   *                                                        04560000
         ST    NRCDREG,4(0,REXREG)     SAVE RECORD COUNT                04580000
         ST    NTRKREG,0(0,REXREG)     SAVE TRACK COUNT                 04600000
         LA    REXREG2,8(0,REXREG)     INCREMENT EXTENT ADDR BY SIZE    04620000
EACHEXT  EQU   *                                                        04640000
         SR    WKREG1,WKREG1           CLEAR OUT THE WORK REGISTER      04660000
         SR    NRCDREG,NRCDREG         CLEAR OUT RECORD COUNT           04680000
         LH    WKREG2,DEBNMTRK         DIVIDE NUMBER OF TRACKS BY THE   04700000
         D     WKREG1,0(0,REXREG)      PERIOD                           04720000
         LTR   WKREG1,WKREG1            TEST WKREG1. IF IT IS ZERO AN   04740000
         BZ    FINI2                   EVEN AMOUNT OF PERIODS FIT       04760000
         ST    WKREG1,DXCCW10+4        STORE TRACKS IN WORKAREA         04780000
         OI    DXCCW10,SECOND          INDICATE SECOND PASS             04800000
         B     NEXTEXT                 GO FOR SECOND PASS               04820000
FINI2    EQU   *                                                        04840000
         NI    DXCCW10,F7              TURN OFF SECOND BIT              04860000
         SR    WKREG1,WKREG1           DIVIDE NUMBER OF TRACKS BY THE   04880000
         LH    WKREG2,DEBNMTRK         PERIOD                           04900000
         D     WKREG1,0(0,REXREG)      DIVIDE BY TRACKS/PERIOD          04920000
         M     WKREG1,4(0,REXREG)      MULTIPLY NO. OF PERIODS BY       04940000
         AR    WKREG2,NRCDREG          RECORDS/PERIOD AND ADD ON EXTRA  04960000
*                                      RECORDS                          04980000
         AR    DSSZREG,WKREG2          ADD EXTENT SIZE TO DS SIZE       05000000
         ST    WKREG2,0(0,REXREG2)     STORE RECORDS/EXTENT IN EXTENT   05020000
         LA    REXREG2,4(0,REXREG2)    UPDATE TO NEXT EXTENT            05040000
         LA    DEBREG,EXTSZ(0,DEBREG)  INCREMENT DEB ADDR BY EXTENTSIZE 05060000
         BCT   WKREG3,EACHEXT          LOOP FOR EACH EXTENT             05080000
         L     RCORE,DCBKEYLE          RESTORE THE ADDRESS OF THE WORK  05100000
*                                      AREA FROM OPEN                   05120000
         B     STDCBREL                GO STORE DATA SET SIZE           05140000
RECTRK   EQU   *                                                        05160000
         SR    8,8                     CLEAR FOR RECORDS/TRACK          05180000
         SR    NRCDREG,NRCDREG         CLEAR FOR RECORDS/EXTENT         05200000
         LH    RB,TRKL(0,TABREG)       LOAD TRACK LENGTH IN BYTES       05220000
COMPLNG  CR    RB,LRREG                COMPARE TO A LAST RECORD SIZE    05240000
         BC    4,RECEXT                 BRANCH IF TRACK IS FULL         05260000
         SR    RB,RRREG                DECREMENT BY INTERMEDIATE SIZE   05280000
         LA    8,1(0,8)                 ADD ONE TO RECORDS/TRACK        05300000
         B     COMPLNG                 LOOP                             05320000
RECEXT   EQU   *                                                        05340000
         LR    NRCDREG,8               MULTIPLY RECORDS PER TRACK       05360000
         MH    NRCDREG,DEBNMTRK         BY TRACKS PER EXTENT            05380000
         ST    NRCDREG,0(0,REXREG)     STORE RECORDS PER EXTENT         05400000
         STC   8,0(0,REXREG)           STORE RECORDS PER TRACK          05420000
         AR    DSSZREG,NRCDREG         ADD TO DATA SET SIZE             05440000
         LA    REXREG,4(0,REXREG)      INCREMENT BOTH                   05460000
         LA    DEBREG,16(0,DEBREG)      EXTENT POINTERS                 05480000
         BCT   WKREG3,RECTRK           TEST FOR LAST EXTENT IN DEB      05500000
*                                                                       05520000
*        STORE TOTAL BLOCKS IN THE DATA SET, INTO THE DCB               05540000
*                                                                       05560000
STDCBREL EQU   *                                                        05580000
         IC    WKREG2,DCBKEYLE         STORE TOTAL SIZE OF THE          05600000
         ST    DSSZREG,DCBKEYLE        DATA SET IN THE DCB SAVING       05620000
         STC   WKREG2,DCBKEYLE         THE KEY LENGTH                   05640000
DYNBUFIN EQU   *                                                        05660000
         TM    DCBOPTCD,DYNB           WAS DYNAMIC BUFFERING REQUESTED  05680000
         BZ    RESTREGS                NO RESTORE REGISTERS AND RETURN  05700000
*                                                                       05720000
*        CONSTRUCT BUFFERS FOR DYNAMIC BUFFERING OPTION                 05740000
*                                                                       05760000
*        DETERMINE CORE REQUIRED AND ISSUE GETMAIN                      05780000
*                                                                       05800000
         SR    R9,R9                   DEVELOP IN REGISTER R9           05820000
         IC    R9,DCBBUFNO              THE NUMBER OF                   05840000
         LTR   R9,R9                     BUFFERS NEEDED,                05860000
         BP    *+8                     IF THE USER OMITTED THIS         05880000
         LA    R9,2                    PARAMETER ASSUME TWO BUFFERS.    05900000
         AIF   ('&LIB' EQ 'LIB1').LIB1AA                                05905001
         LR    WKREG1,R9          SAVE # OF BUFFERS                     05910001
.LIB1AA  ANOP                                                           05915001
         LH    RC,DCBBUFL              LOAD SPECIFIED LENGTH            05920000
         LTR   RC,RC                   TEST FOR ZERO BUFFER LENGTH      05940000
         BZ    NOBUFL                  IF SO ABEND                      05960000
         TM    DCBBUFL+1,7               AND CHECK THAT IT IS A         05980000
         BZ    OKALN                       DOUBLE WORD MULTIPLE.        06000000
         SRL   RC,3                    IF NOT                           06020000
         SLL   RC,3                      CLEAR THE 1-7 VALUE            06040000
         LA    RC,8(0,RC)                  AND ADD EIGHT.               06060000
OKALN    MR    RD,RC                   MULTIPLY LENGTH X NO. OF BUFFERS 06080000
         AIF   ('&LIB' EQ 'LIB1').LIB1AB                                06100001
         L     TCBREG,DCBDEBAD    GET DEB ADDRESS                       06101001
         USING DEB,TCBREG                                               06102001
         L     TCBREG,DEBTCBAD    GET TCB ADDRESS                       06103001
         USING TCB,TCBREG                                               06104001
         TM    TCBFLGS6,TCBRV     TEST IF ADDRSPCE IS REAL              06105001
         BO    NOBCBSFX           BRANCH IF SO, NO BCB SUFFIX           06106001
*                                 CORE NEEDED= UNSCHEDULED LIST         06107001
*                                 LENGTH + BUFFER CONTROL BLOCK         06108001
*                                 LENGTH + BUFFER SUFFIX OF 1           06109001
*                                 BYTE PER BUFFER + 7 FOR ROUND         06110001
         LA    RB,FIRSTUSL+BCBLENTH+RNDFCTOR(WKREG1,R9)                 06111001
         TM    DCBBFALN,FWDALN    IF BUFFER ALIGNMENT IS FULL-WD        06112001
         BZ    ROUND1              (NOT DOUBLE WD),                     06113001
         LA    RB,FOURBYTS(RB)       THEN ADD 4 BYTES                   06114001
ROUND1   SRL   RB,3               ROUNDED TO A MULTIPLE OF 8            06115001
         SLL   RB,3               RESET                                 06116001
         B     GETCORE            GO TO GET CORE FOR BCB                06117001
NOBCBSFX EQU   *                                                        06118001
.LIB1AB  ANOP                                                           06119001
         LA    RB,BCBLENTH+FOURBYTS(R9)  ADD LENGTH OF BCB, ALIGNMENT   06120001
GETCORE  LA    RE,250             SUBPOOL = 0                           06121001
         SLL   RE,24                                                    06140000
         OR    RE,RB                                                    06160000
         AIF   ('&LIB' NE 'LIB1').LIB1AC                                06162001
*HIARCHY TEST PRIOR TO GETMAIN. DETERMINE WHETHER CORE WILL BE     DM0E 06164000
*GOTTEN FROM HI SPEED STORAGE OR LCS.                              DM0E 06168000
         SR    RF,RF                    HOUSEKEEP PARM REG 1.      DM0E 06172000
         TM    DCBBFTEK,HIARCHY    TEST FOR HI SPEED STORAGE OR LCSDM0E 06176000
         BO    GETH1                    GET CORE FOR LCS REQUEST   DM0E 06180000
         GETMAIN R,LV=(0),HIARCHY=0                                DM0E 06184000
         B     SAVSIZ                                              DM0E 06188000
GETH1    EQU   *                                                   DM0E 06192000
         GETMAIN R,LV=(0),HIARCHY=1                                DM0E 06196000
         AGO   .LIB1AD                                                  06200001
.LIB1AC  ANOP                                                           06200301
         GETMAIN R,LV=(0)                                               06200601
         TM    TCBFLGS6,TCBRV     IF ADDRSPCE IS REAL,                  06200901
         BO    SAVSIZ               BRANCH                              06201201
*                                                                       06201501
*                     INITIALIZE THE UNSCHEDULED LIST                   06201801
*                                                                       06202101
         USING USL,RF                                                   06202401
         XC    USL(FIRSTUSL),USL  CLEAR THE LIST                        06202701
         MVI   USLSIZE+1,FIRSTUSL INITIALIZE SIZE FIELD                 06203001
         OI    USLFLAGS,USLCURNT  TURN ON 'CURRENT' BIT                 06203301
         LA    WKREG2,USL+FIRSTUSL-L'USLSLOT1  ADDRESS LAST USL SLOT    06203601
         USING USLSLOT,WKREG2                                           06203901
         OI    USLSLTFL,USLENDL   TURN ON END-OF-LIST INDICATOR         06204201
         DROP  WKREG2                                                   06204501
         ST    RF,DCBDYNB         STORE POINTER TO USL                  06204801
*                                                                       06205101
*                       INITIALIZE BUFFER CONTROL BLOCK                 06205401
*                                                                       06205701
         LA    RF,FIRSTUSL(RF)    POINT TO BUFFER CONTROL BLOCK         06206001
         USING BCBDEF,RF                                                06206301
         ST    RB,BCBTBRS         TOTAL SIZE GETMAIN AREA               06206601
         ST    RC,BCBBUFL         LENGTH OF EACH BUFFER                 06206901
*                                                                       06207201
*                                 CALCULATE ADDR OF 1ST BUFFER          06207501
         LA    WKREG2,BCBSUFFX(WKREG1) ADDR END OF BUFFER SUFFIX        06207801
         SR    RC,RC                                                    06208101
         TM    DCBBFALN,FWDALN    IF FULL WORD ALIGNMENT FOR            06208401
         BZ    ROUND2              BUFFERS, ADD 4 BEFORE ROUND          06208701
         LA    RC,4                PUT 4 IN REG 13                      06209001
ROUND2   LA    WKREG2,RNDFCTOR(RC,WKREG2)     BUMP ADDRESS TO NEXT      06209301
         SRL   WKREG2,3                DOUBLE WORD BOUNDARY             06209601
         SLL   WKREG2,3           RESET                                 06209901
         SR    WKREG2,RC          IF FULL WORD ALIGNMENT,               06210201
*                                 SUBTRACT 4.                           06210501
         ST    WKREG2,BCBBUF1     ADDRESS OF FIRST BUFFER               06210801
*                                 INITIALIZE AVAILABLE BUFFER           06211101
*                                 CHAIN.                                06211401
         MVI   BCBBFAVL,ONE      FIRST AVAILABLE = #1.                  06211701
         LA    WKREG2,ONE(WKREG1)   # OF BUFFERS + 1 = COMPARAND        06212001
         LA    WKREG1,ONE           INCREMENT = 1                       06212301
         LA    RC,2               NEXT BUFFER FOR BUFFER #1 = #2        06212601
*                                 (OPERAND)                             06212901
STORENXT STC   RC,BCBSUFFX-2(RC)  CHAIN TO NEXT AVAILABLE               06213201
         BXLE  RC,WKREG1,STORENXT LOOP ONCE FOR EACH BUFFER             06213501
*                                 POINT TO LAST CHAIN ELEMENT           06213801
         LA    WKREG1,BCBSUFFX-3(RC)   INITIALIZED.                     06214101
         MVI   0(WKREG1),0        NO MORE BUFFERS                       06214401
*                                                                       06214701
         STCM  RF,ADDR,DCBBUFCB+ONE   STORE PTR TO BCB                  06215001
         DROP  RF                                                       06215301
         B     RESTREGS           GO RESTORE REGISTERS                  06215601
.LIB1AD  ANOP                                                           06215901
*                                                                       06216201
*        DIVIDE AREA INTO A BUFFER CONTROL BLOCK (BCB) AND THE          06220000
*        SPECIFIED NO. OF BUFFERS. LINK ALL TO NEXT AVAILABLE FIELD     06240000
*        IN THE BUFFER CONTROL BLOCK.                                   06260000
*                                                                       06280000
         USING BCBDEF,RF                                                06290001
SAVSIZ   LR    R9,RB                   SAVE SIZE OF AREA           DM0E 06300000
         ST    RB,BCBTBRS              STORE SIZE IN THE BCB            06320001
         IC    RB,DCBBUFNO             STORE THE RETURNED CORE ADDRESS  06340000
         ST    RF,DCBBUFNO              AS BCB ADDRESS IN THE DCB       06360000
         STC   RB,DCBBUFNO                                              06380000
*                                      CLEAR QUEUE POINTERS             06400001
         XC    BCBFRQT(L'BCBFRQT+L'BCBFRQB),BCBFRQT                     06410001
         LA    RB,16(0,RF)             DEVELOP THE ADDRESS OF BUFFER 1  06420000
         TM    DCBBFALN,FWDALN          (ALIGN TO A WORD BOUNDARY THATS 06440000
         BZ    *+8                     NOT A DOUBLE WORD BOUNDARY IF    06460000
         LA    RB,4(0,RB)              SO SPECIFIED)                    06480000
         ST    RB,BCBNABFR             AND STORE AS NEXT AVAILABLE BFR  06500001
         DROP  RF                                                       06510001
         SH    R9,CONH20               SUBTRACT FROM SIZE- BCB,  SM4366 06520021
         SR    R9,RC                   FIRST BUFFER,ALIGNMENT FACTOR.   06540000
         LR    RF,RB                   POINT RF TO NEXT BUFFER LOCATION 06560000
BFRLOOP  AR    RF,RC                   (BUFFER 1 + BUFFER LENGTH)       06580000
         SR    R9,RC                   REDUCE TOTAL SIZE BY BUFL        06600000
         BM    FNDLAST                 IF MINUS ALL BUFFERS ARE LINKED  06620000
         ST    RF,0(0,RB)              LINK BFR. 2 TO BFR. 1 ETC.       06640000
         LR    RB,RF                   INCREMENT THE TWO BFR. POINTERS  06660000
         B     BFRLOOP                  AND LOOP                        06680000
FNDLAST  SR    RF,RF                   ZERO THE                         06700000
         ST    RF,0(0,RB)               END BUFFER LINK ADDRESS         06720000
RESTREGS EQU   *                                                        06740000
         LM    WKREG0,R9,DXCCW4        RESTORE OPEN'S REGISTERS         06760000
         MVI   0(RWTGC),0              INDICATE THIS DCB FINISHED       06780000
*                                                                       06800000
*                                                                       06820000
*                                                                       06840000
*  ROUTINE TO SCAN DCB LIST FOR OTHER DCBS REQUIRING THIS EXECUTOR.     06860000
*  IF NONE ARE FOUND, CONTROL IS TRANSFERED TO THE NEXT EXECUTOR OF THE 06880000
*  FIRST DCB WHICH IS NOT COMPLETED.                                    06900000
*                                                                       06920000
*                                                                       06940000
SCAN4EQ  LA    RWTGC,WGOFF(0,RWTGC)    INCREMENT WHERE TO GO INDEX      06960000
         LA    RPARC,PAROFF(0,RPARC)    AND DCB PARAMETER LIST INDEX    06980000
         CLC   0(2,RWTGC),AMIDCNST     DOES TABLE NAME THIS EXECUTOR    07000000
         BCR   8,FDNBASE               YES,BRANCH TO ENTRY POINT        07020000
         CLC   0(2,RWTGC),OPIDCNST      NO, IS THIS END OF TABLE?       07040000
         BC    7,SCAN4EQ                NO, LOOP TO INCREMENT STEPS.    07060000
*                                                                       07080000
         LR    RPARC,RPAR              RESTORE BOTH INDEX REGISTERS TO  07100000
         LA    RWTGC,32(0,RWTG)         THEIR INITIAL VALUES            07120000
SCAN4ANY CLI   0(RWTGC),0              IS THIS DCB COMPLETED?           07140000
         BC    7,XCTLRTN                IF NOT, GO TO NAMED EXECUTOR.   07160000
         LA    RWTGC,WGOFF(0,RWTGC)    INCREMENT BOTH INDEX REGISTERS   07180000
         LA    RPARC,PAROFF(0,RPARC)    TO THE NEXT ENTRIES.            07200000
         BC    15,SCAN4ANY             LOOP TO CHECK COMPLETION         07220000
*                                                                       07240000
XCTLRTN  EQU   *                                                        07260000
         MVC   6(2,RWTG),0(RWTGC)      MOVE EXECUTOR ID TO PARAM LIST   07280000
         MVC   14(3,RWTG),2(RWTGC)      MOVE TTR                        07300000
         AIF   ('&LIB' EQ 'LIB1').LIB1BB                                07310001
         MVC   24(5,RWTG),XCTLCON+2                                     07312001
.LIB1BB  ANOP                                                           07314001
         LA    15,DXXCTL                SET UP FOR XCTL          S21042 07320021
         XCTL  DE=(RWTG),SF=(E,(15))                                    07340000
NOBUFL   EQU   *                                                 S21042 07346021
         LM    WKREG0,R9,DXCCW4         RESTORES REGS FOR XCTL  SA55468 07349021
         L     R9,CVTPTR                POINT TO CVT             S21042 07352021
         L     R9,CVTTCBP-CVTDEF(R9)    POINT TO TCB DBL WDS     S21042 07358021
         L     R9,4(R9)                 POINT TO TCB             S21042 07364021
         L     R9,TCBTIO-TCB(R9)        POINT TO TIOT FOR P. D.  S21042 07370021
         DMABCOND OABD051,PDLOAD,RETURN=NONE,RES=NO,REGSAVE=YES  S21042X07376021
                                        CALL PROBLEM DETERMINATION      07382021
         LR    WKREG1,RCORE             WORK AREA FOR PROB DET   M0024  07385021
         B     XCTLRTN                                           S21042 07388021
*                                                                       07400000
HIARCHY  EQU   X'80'               TEST DCBBFTEK FOR WHICH STORAGE DM0E 07406000
*                                       BOX, HI SPEED OR LCS.      DM0E 07412000
         DS    0F                                                       07420000
AMIDCNST DC    C'3E'                   THIS EXECUTOR'S ID               07480000
OPIDCNST DC    C'0S'                   LAST WTG TABLE ENTRY             07500000
XCTLCON  DC    X'C378'                 EXCTL ATTR.-REENT.,REUSEABLE     07510001
*                                        NOT IN OV'LAY,NOT TEST,NOT     07512001
*                                        ONLY LOADABLE,BLOCK FORMAT,    07514001
*                                        EXECUTABLE,1 TEXT,COMPAT.,     07516001
*                                        ORIGIN AT 0,ENTRY PT.0,NO RLD  07518001
         DC    X'000400'                TOTAL LENGTH                    07518401
         DC    X'0400'                  TEXT LENGTH                     07518801
CONH20   DC    H'20'                   CONSTANT 20               SM4366 07520021
MAXSZ    DC    H'1024'                 MAXIMUM LENGTH OF A TEXT RECORD  07540000
ATBL     EQU   X'CB'                   LOAD ATTRIBUTES                  07560000
WGOFF    EQU   8                       OFFSET IN WHERE TO GO TABLE      07580000
PAROFF   EQU   4                       OFFSET IN DCB PARAMETER LIST     07600000
*                                                                       07620000
TBOVHD   EQU   X'08'                    DEV TYPE MASK            S20201 07626020
RNDFCTOR EQU   X'07'              FACTOR USED FOR ROUNDING              07628001
FOURBYTS EQU   X'04'              USED FOR ADDING 4 BYTES TO AN ADDR    07630001
ONE      EQU   X'01'                                                    07630401
BYTEDEV  EQU   9                        DEV TYPE OFFSET          S20201 07632020
FWDALN   EQU   X'01'                   ALIGN BUFFERS TO FULL WORD WHICH 07780000
*                                      IS NOT A DOUBLE WORD BOUNDARY    07800000
RELRD    EQU   X'01'                   RELATIVE BLOCK ADDRESSING        07820000
OVERFL   EQU   X'20'                   OVERFLOW                         07840000
DYNB     EQU   X'04'                   DYNAMIC BUFFERING                07860000
EXTSZ    EQU   16                                                       07880000
TRKL     EQU   4                                                        07900000
OVERI    EQU   6                                                        07920000
OVERL    EQU   7                                                        07940000
OVERK    EQU   8                                                        07960000
TOLER    EQU   10                                                       07980000
UCBTYPCD EQU   19                                                       08000000
SECOND   EQU   8                                                        08020000
F7       EQU   X'F7'                                                    08040000
         AIF   ('&LIB' EQ 'LIB1').LIB1AE                                08044001
ADDR     EQU   B'0111'       MASK FOR STORING 24-BIT ADDRESS            08048001
FIRSTUSL EQU   64            SIZE OF UNSCHEDULED LIST                   08052001
         XCTLTABL ID=(PDLOAD,6M),SVC=019,LENGTH=1128                    08090001
.LIB1AE  ANOP                                                           08100000
         AIF  ('&LIB' NE 'LIB1').LIB1AR                         SM4356  08102021
         XCTLTABL  ID=(PDLOAD,6M),SVC=019                       SM4356  08110000
.LIB1AR  ANOP                                                   SM4356  08120021
         EJECT                                                          08140000
         IECDSECS MAIN,TCB,EXPAND=YES                            S21042 08170021
CVTDEF   DSECT                                                          08200000
         CVT                                                            08220000
*                                                                       08240000
DEB      DSECT                                                          08260000
         DS    0F                                                       08280000
DEBNMSUB DS    0CL1      NO. OF SUBR. LOADED BY OPEN                    08300000
DEBTCBAD DS    CL4       ADDRESS OF THE TCB FOR THIS DEB                08320000
DEBAMLNG DS    0CL1      NO. OF BYTES IN THE ACCESS MTHD. DPDT. SECTION 08340000
DEBDEBAB DS    CL4       ADDRESS OF THE PREVIOUS DEB IN THE SAME TASK   08360000
DEBOFLGS DS    0CL1      DATA SET STATUS FLAGS                          08380000
DEBIRBAD DS    CL4       IRB ADDRESS                                    08400000
DEBOPATB DS    0CL1      TYPE OF FILES                                  08420000
DEBSYSPG DS    CL4       ADDRESS OF FIRST IOB IN THE SYSTEM PURGE CHAIN 08440000
DEBNMEXT DS    0CL1      NUMBER OF EXTENTS SPECIFIED IN THE DSCB        08460000
DEBUSRPG DS    CL4       ADDRESS OF FIRST IOB IN THE USER PURGE CHAIN   08480000
DEBPRIOR DS    0CL1      ALWAYS ZERO                                    08500000
DEBECBAD DS    CL4       ECB ADDRESS FOR SVC PURGE REQUEST              08520000
DEBPROTG DS    0CL1      RESERVED FOR FUTURE USE (FIRST 4 BITS)         08540000
DEBDEBID DS    0CL1      HEX 'F' TO IDENTIFY THIS BLOCK AS A DEB        08560000
DEBDCBAD DS    CL4       ADDRESS OF THE DCB ASSOCIATED WITH THIS DEB    08580000
DEBEXSCL DS    0CL1      EXTENT SCALE                                   08600000
DEBAPPAD DS    CL4       ADDRESS OF I/O APPENDAGE VECTOR TABLE          08620000
DEBDVMOD DS    0CL1      DEVICE MODIFIER FILE MASK                      08640000
DEBUCBAD DS    CL4       ADDR OF UCB ASSOCIATED WITH THIS DATA EXTENT   08660000
DEBBINUM DS    CL2       RESERVED FOR FUTURE USE-ALWAYS ZERO            08680000
DEBSTRCC DS    CL2       STARTING CYLINDER NUMBER FOR EXTENT            08700000
DEBSTRHH DS    CL2       STARTING HEAD NUMBER FOR EXTENT                08720000
DEBENDCC DS    CL2       ENDING CYLINDER NUMBER FOR EXTENT              08740000
DEBENDHH DS    CL2       ENDING HEAD NUMBER FOR EXTENT                  08760000
DEBNMTRK DS    CL2       NUMBER OF TRACKS ALLOCATED TO A GIVEN EXTENT   08780000
DEBSUBID EQU   0         SUBROUTINE ID'S                                08800000
*                                                                       08820000
*                                                                       08840000
         DCBD  DSORG=DA                                                 08860000
*                                                                       08860401
*                       BUFFER CONTROL BLOCK FORMAT                     08860801
*                                                                       08861201
BCBDEF   DSECT                                                          08861601
         AIF   ('&LIB' EQ 'LIB1').LIB1AF                                08862001
*                       FORMAT FOR TASKS IN REAL ADDRSPCE.              08862401
.LIB1AF  ANOP                                                           08862801
BCBFRQT  DS    A        FIRST IOB WAITING FOR A BUFFER                  08863201
BCBFRQB  DS    A        LAST IOB WAITING FOR A BUFFER                   08863601
BCBNABFR DS    A        ADDRESS OF NEXT AVAILABLE BUFFER                08864001
BCBTBRS  DS    F        TOTAL CORE SIZE OF BUFFERS, CTL BLOCKS          08864401
BCBLENTH EQU   *-BCBDEF      SIZE OF BASIC SECTION OF BCB               08864801
         AIF   ('&LIB' EQ 'LIB1').LIB1AG                                08865201
*                       FORMAT FOR TASKS IN VIRTUAL ADDRSPCE            08865601
         ORG   BCBDEF                                                   08866001
BCBBUF1  DS    A        ADDRESS OF FIRST BUFFER IN POOL                 08866401
BCBBUFL  DS    F        LENGTH OF EACH BUFFER                           08866801
BCBBFAVL DS    FL1      BUFFER # OF NEXT AVAILABLE BUFFER               08867201
BCBRAOFS DS    FL3      OFFSET OF RECORD AREA IN BUFFER (VRE)           08867601
         DS    F        BCBTBRS, INCLUDES USL LENGTH                    08868001
BCBSUFFX EQU   *        BUFFER SUFFIX, 1 BYTE PER BUFFER, USED          08868401
*                       AS AVAILABLE CHAIN.                             08868801
         SPACE 3                                                        08869201
USL      DSECT          UNSCHEDULED LIST FORMAT                         08869601
USLSIZE  DS    H        SIZE OF CURRENT LIST IN BYTES                   08870001
         DS    H        UNUSED                                          08870401
USLFLAGS DS    0BL1                                                     08870801
USLCURNT EQU   BIT0     IF ON, THIS IS THE CURRENT LIST                 08871201
USLBFRQT DS    A        PTR TO ADDR OF IOB ON TOP OF BUFFER Q           08871601
USLBFRQB DS    A        PTR TO ADDR OF IOB LAST ON BUFFER Q             08872001
USLCHAIN DS    A        ADDR OF PRIOR COPY OF LIST (0 FOR 1ST)          08872401
USLSLOT1 DS    A        TOP SLOT ON QUEUE                               08872801
         SPACE 3                                                        08873201
USLSLOT  DSECT          FORMAT OF EACH SLOT ON USL                      08873601
USLSLTFL DS    0BL1     FLAGS                                           08874001
USLENDL  EQU   BIT0     IF ON, SLOT IS LAST IN USL                      08874401
USLINUSE EQU   BIT1     IF ON, SLOT IS BEING USED                       08874801
USLIOBA  DS    A        IF SLOT IS BEING USED, ADDR OF IOB ON Q         08875201
USLNXT   DS    A        NEXT SLOT                                       08875601
*                                                                       08876001
.LIB1AG  ANOP                                                           08876401
         END                                                            08880000
