         TITLE 'IGG0193F-OPEN EXECUTOR FOR BDAM VRE BUFFER POOL'        00200019
         COPY  LCGASMSW                                                 00250001
IGG0193F CSECT                                                          00400019
*                                                                       00600019
*          RELEASE 20 DELETIONS                                       * 00800019
*          RELEASE 21 DELETIONS                                       * 01000019
*3574220000-222000,258000,266000-324000,672000                   A44855 01100021
*3574286000                                                      M1795  01150021
*                                                                YM3693 01162002
*          RELEASE 22 DELETIONS                                       * 01200019
*          RELEASE 23 DELETIONS                                       * 01400019
*          RELEASE 24 DELETIONS                                       * 01600019
*          RELEASE 25 DELETIONS                                       * 01800019
*          RELEASE 26 DELETIONS                                       * 01810019
*          RELEASE 27 DELETIONS                                       * 01820019
*          RELEASE 28 DELETIONS                                       * 01830019
*                                                                     * 02000019
*STATUS CHANGE LEVEL 001                 16OCT72                      * 02200002
*                                                                     * 02400019
*FUNCTION/OPERATION - THIS ROUTINE IS BROUGHT INTO CORE AND GIVEN     * 02600019
*   CONTROL WHEN SOME OPEN EXECUTOR ISSUES AN 'XCTL' TO IGG0193F.     * 02800019
*   IF DYNAMIC BUFFERING IS SPECIFIED THIS ROUTINE WILL CALCULATE     * 03000019
*   AND OBTAIN (BY A GETMAIN) THE NUMBER OF BYTES REQUIRED FOR THE    * 03200019
*   BUFFERS AND FOR THE BUFFER CONTROL BLOCK.  IT WILL DIVIDE THE     * 03400019
*   AQUIRED AREA INTO A BUFFER CONTROL BLOCK AND THE SPECIFIED NUMBER * 03600019
*   OF BUFFERS.                                                       * 03800019
*   IF DYNAMIC BUFFERING IS NOT SPECIFIED THIS ROUTINE WILL CACULATE  * 04000019
*   AND OBTAIN (BY A GETMAIN) THE NUMBER OF BYTES REQUIRED FOR A      * 04200019
*   SEGMENT WORK AREA POOL.  IT WILL DIVIDE THE AREA INTO A BUFFER    * 04400019
*   CONTROL BLOCK AND THE SPECIFIED NUMBER OF BUFFERS.                * 04600019
*                                                                     * 04800019
*ENTRY POINT - ENTRY WILL BE TO THE FIRST BYTE OF THE MODULE BY AN    * 05000019
*   'XCTL' TO IGG0193F.                                               * 05200019
*                                                                     * 05400019
*INPUT - REGISTERS 5,6,7,8 ARE INPUT AS FOLLOWS,                      * 05600019
*   5 - BEGINNING OF THE DCB PARAMETER LIST                           * 05800019
*   6 - BEGINNING OF THE WHERE-TO-GO TABLE                            * 06000019
*   7 - ADDRESS OF THE CURRENT ENTRY IN THE DCB PARAMETER LIST        * 06200019
*   8 - ADDRESS OF THE CURRENT ENTRY IN THE WHERE-TO-GO TABLE         * 06400019
*                                                                     * 06600019
*OUTPUT - REGISTER 7 AND 8 WILL BE POSITIONED TO THE NEXT UNFINISHED  * 06800019
*   ENTRY, CORE WILL BE ACQUIRED FOR BUFFERS AND A BCB.               * 07000019
*                                                                     * 07200019
*EXTERNAL ROUTINES - N/A                                              * 07400019
*                                                                     * 07600019
*EXITS - NORMAL - THIS ROUTINE TERMINATES BY LOCATING THE NEXT        * 07800019
*   NON-ZERO ENTRY IN THE WHERE-TO-GO TABLE AND EXECUTING AN 'XCTL' TO* 08000019
*   THE ROUTINE.  THE SCAN OF THE TABLE BEGINS AT 'SCAN4EQ'.          * 08200019
*                                                                     * 08400019
*TABLES/WORK AREAS - 1. DCB PARAMETER LIST CONTAINS THE ADDRESS OF    * 08600019
*   EACH DCB SPECIFIED IN THE OPEN MACRO INSTRUCTION.  2. WHERE-TO-GO * 08800019
*   TABLE CONTAINS THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE* 09000019
*   DCB WHICH CORRESPONDS TO THIS ENTRY AND THE ADDRESS OF A WORK AREA* 09200019
*   FOR THE DCB.  3. THE WORK AREA IS A 464 BYTE AREA ASSIGNED TO THIS* 09400019
*   DCB.  4. COMMUNICATION VECTOR TABLE IS A RESIDENT VECTOR LIST USED* 09600019
*   TO LOCATE THE DIRECT ACCESS DEVICE TABLE.  5. DIRECT ACCESS DEVICE* 09800019
*   TABLE(DADT) CONTAINS AN ENTRY FOR EACH DIRECT ACCESS DEVICE WHICH * 10000019
*   DEFINES THE PHYSICAL CHARACTERISTICS OF EACH DEVICE SUCH AS TRACK * 10200019
*   LENGTH, OVERHEAD, TOLERANCE, ETC.                                 * 10400019
*                                                                     * 10600019
*ATTRIBUTES - THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AND IS   * 10800019
*   DISABLED, PRIVILEGED, AND REUSABLE.                               * 11000019
*                                                                     * 11200019
*NOTES - THIS ROUTINE COMPLETES THE BDAM PROCESSING THAT IS TO BE DONE* 11400019
*   FOR THIS DCB SO THE WHERE-TO-GO TABLE ENTRY WILL BE SET TO ZERO.  * 11600019
*                                                                     * 11800019
*********************************************************************** 12000019
*                                                                       12200019
***** REGISTER USAGE                                                    12400019
*                                                                       12600019
WKREG0   EQU   0                                                        12800019
RE       EQU   0                        WORK REGISTER                   13000019
RF       EQU   1                        WORK REGISTER                   13200019
DEBREG   EQU   2                                                        13400019
RCORE    EQU   3                        ADDRESS OF THE OPEN WORKAREA    13600019
WKREG1   EQU   4                        WORK REGISTER                   13800019
WKREG2   EQU   5                        WORK REGISTER                   14000019
RPAR     EQU   5                        PARAMETER LIST ADDRESS          14200019
RWTG     EQU   6                        FRONT OF THE WHERE-TO-GO-TABLE  14400019
RTCB     EQU   6                        ADDRESS OF TCB           A44855 14460021
WKREG6   EQU   6                        EVEN WORK REG            A44855 14520021
RJ       EQU   7                        WORK REGISTER                   14600019
RPARC    EQU   7                        CURRENT ENTRY IN PARAMETER LIST 14800019
WKREG7   EQU   7                        ODD WORK REGISTER        A44855 14900021
RWTGC    EQU   8                        CURRENT ENTRY IN WTG            15000019
RD       EQU   8                        WORK REGISTER FOR DYNAMIC BUF.  15200019
R9       EQU   9                        RETURN FOR MODULE LOAD ROUTINE  15400019
FDNBASE  EQU   10                       BASE REGISTER FOR THIS MODULE   15600019
RA       EQU   11                       WORK REGISTER                   15800019
RB       EQU   12                       WORK REGISTER                   16000019
RC       EQU   13                       WORK REGISTER FOR DYNAMIC BUF.  16200019
DCBREG   EQU   14                                                       16400019
WKREG3   EQU   15                       WORK REGISTER                   16410019
*                                                                       16600019
*                                                                       16800019
         IEZBITS                                                        16900021
*                                                                       17000019
         USING DEB,DEBREG                                               17200019
         USING IHADCB,DCBREG                                            17400019
         USING FORECORE,RCORE                                           17600019
         USING BEGIN,FDNBASE                                            17800019
*                                                                       18000019
*                                                                       18200019
*                                                                       18400019
         EJECT                                                          18600019
         BALR  FDNBASE,0                ESTABLISH BASE                  18800019
BEGIN    EQU   *                                                        19000019
         L     RCORE,PAROFF(NULL,RWTGC) SET POINTER TO DCB WORKAREA     19200019
         STM   WKREG0,R9,DXCCW4         SAVE OPEN'S REGISTERS           19400019
         L     DCBREG,NULL(NULL,RPARC)  LOAD DCB BASE REGISTER          19600019
         L     DEBREG,DEBOFF(DCBREG)    LOAD DEB ADDRESS                19800019
*                                                                       20000019
*****  CONSTRUCT BUFFERS FOR VRE OPTION                                 20200019
*                                                                       20400019
         SR    R9,R9                    * DEVELOP IN REGISTER 9         20600019
         IC    R9,DCBBUFNO              * THE NUMBER OF BUFFERS         20800019
         LTR   R9,R9                    * NEEDED, IF USER OMITTED       21000019
         BP    FINDLNTH                 * THIS PARAMETER ASSUME 2       21200019
         LA    R9,TWO                   * BUFFERS                       21400019
FINDLNTH L     RC,C32(DEBREG)           LOAD UCB ADDRESS                21600019
         L     WKREG1,CVTPTR(NULL,NULL) LOAD CVT ADDRESS                21800019
         USING CVT,WKREG1                                        A44855 22000021
         L     WKREG1,CVTZDTAB          LOAD DEVICE TABLE ADDR   A44855 22100021
         DROP  WKREG1                                            A44855 22200021
         IC    WKREG2,TYPCD(RC)         LOAD DEVICE CODE FROM UCB       22400019
         N     WKREG2,LASTFOUR          CLEAR ALL BUT LOW 4 BITS        22600019
         IC    WKREG2,NULL(WKREG2,WKREG1)  FIND ENTRY OFFSET            22800019
         LA    RA,PAROFF(WKREG2,WKREG1) POINT TO ENTRY TRACK LNGTH      23000019
         TM    DCBOPTCD,DYNB            DYNAMIC BUFFERING REQUIRED      23200019
         BZ    GETSWA                   NO,BRANCH                       23400019
*                                                                     * 23600019
***** CONSTRUCT BUFFERS FOR DYNAMIC BUFFERING OPTION WITH VRE     ***** 23800019
*                                                                     * 24000019
         SR    RC,RC                    CLEAR WORK REGISTER             24200019
         IC    RC,DCBKEYLE              LOAD KEY LENGTH                 24400019
         AH    RC,DCBBLKSI              ADD BLKSIZE                     24600019
         CH    RC,NULL(RA)              COMPARE MAXIMUM LOGICAL RECORD  24800019
*                                       LENGTH + KEY LENGTH AND TRACK   25000019
*                                       SIZE                            25200019
         BNH   ADD                      RECORD LENGTH IS LOW            25400019
         LH    RC,NULL(RA)              USE TRACK LENGTH                25600019
*                   ADD LENGTH OF CONTROL FIELDS                        25800021
ADD      LA    RC,L'BUFNXT+L'BUFRAPTR+L'BUFBI+L'BUFBFPTR(RC)     A44855 25900021
*                                                                     * 26000019
***** ROUND TO FULLWORD OR DOUBLE WORD ALIGNMENT FOR RECORD AREA  ***** 26200019
*                                                                     * 26400019
         AIF   ('&LIB' EQ 'LIB1').LIB1AA                                26410001
         LA    RD,1               LOOP CONTROL                          26420001
         LR    WKREG3,RC          SAVE VALUE BEFORE ROUNDING            26430001
         SR    RA,RA              ASSUME NO BUFFER SUFFIX               26440001
         L     RTCB,DEBTCBAD      GET TCB ADDRESS                       26450001
         USING TCB,RTCB                                                 26460001
         TM    TCBFLGS6,TCBRV     IS ADDRESS SPACE REAL?                26470001
         BO    RALNTH1            BRANCH IF YES                         26480001
         LA    RA,THREERND(R9)    GET NUMBER OF BUFFERS ROUNDED         26490001
         N     RA,RNDFULL          TO A MULTIPLE OF FOUR                26500001
RALNTH1  EQU   *                                                        26510001
.LIB1AA  ANOP                                                           26520001
         SR    WKREG1,WKREG1            ASSUME FULLWORD,NOT      A44855 26600021
*                                       DOUBLEWORD ALIGNMENT OF RECORD  27100021
         TM    DCBBFALN,FWDALN          TEST SPECIFIED ALIGNMENT A44855 27600021
         BZ    DOUBLEWD                 BR IF DOUBLEWORD         A44855 28100021
         LA    WKREG1,4                                                 28150001
DOUBLEWD LA    RC,RNDFCTOR(WKREG1,RC)    ADD FOR BUFFER ALIGNMENT       28600001
         AIF   ('&LIB' EQ 'LIB1').LIB1AB                                28700001
         AR    RC,RA              INCLUDE BUFFER SUFFIX                 28800001
.LIB1AB  ANOP                                                           28900001
         N     RC,RNDDBL               ROUND TO DOUBLE WORD      M1795  29200021
*                                       BOUNDARY                 M1795  29300021
         SR    RC,WKREG1               THEN TO A FULLWORD IF     M1795  29400021
*                                       SPECIFIED                M1795  29500021
         AIF   ('&LIB' EQ 'LIB1').LIB1AC                                29500101
         SR    RC,RA              OFFSET TO RECORD AREA                 29600101
.LIB1AC  ANOP                                                           29700001
*                                       ADD LENGTH OF RECORD AREA       29710001
         SR    RB,RB                                                    29750001
         IC    RB,DCBKEYLE              RECORD AREA=KEY LENGTH   A44855 30100021
         AH    RB,DCBBLKSI              PLUS BLOCKSIZE           A44855 30600021
         LA    RB,RNDFCTOR(RC,RB)    ROUND ENTIRE BUFFER LENGTH TO      31400001
         N     RB,RNDDBL                    A MULTIPLE OF 8             31450001
         AIF   ('&LIB' EQ 'LIB1').LIB1AD                                31820001
         TM    TCBFLGS6,TCBRV     IS ADDRESS SPACE REAL?                31840001
         BO    NOXLNGTH           BRANCH IF YES                         31860001
*                                                                       31880001
*                       INSURE THAT BUFFER FORMAT USES                  31900001
*                       MINIMUM PADDING.                                31920001
*                                                                       31940001
         LTR   RD,RD              IS THIS THE FIRST TRIAL CALC?         31960001
         BZ    CHKRESLT           BRANCH IF NO.                         31980001
*                                 SAVE RESULTS OF THIS TRIAL, &         32000001
*                                 SEE WHAT WOULD HAPPEN IF THE          32020001
*                                 BUFFER WERE ALIGNED ON THE NEXT       32040001
*                                 FULL-WORD.                            32060001
         LR    RE,RC              SAVE RECORD AREA OFFSET               32080001
         LR    RF,RB              SAVE BUFFER LENGTH                    32100101
         LR    RC,WKREG3          RESTORE PRE-ROUNDING VALUE            32120001
         LA    RA,4(RA)           TRY NEXT FULL WORD BOUNDARY           32140001
         BCT   RD,DOUBLEWD        LOOP TO CALC BUFFER SIZE AGAIN        32160001
*                                                                       32180001
CHKRESLT CR    RB,RF              IS THIS WAY SMALLER?                  32200001
         BL    NOXLNGTH           BRANCH IF YES                         32220001
*                                 ELSE USE RESULTS OF FIRST CALC        32240001
         LR    RC,RE              RESTORE RECORD AREA OFFSET            32260001
         LR    RB,RF              RESTORE BUFFER LENGTH                 32280001
         S     RA,FOUR            RESTORE BUFFER SUFFIX LENGTH          32300001
.LIB1AD  ANOP                                                           32320001
NOXLNGTH LA    WKREG1,NULL                                              32600019
         LR    WKREG2,RB                                                32800019
         MR    WKREG1,R9                CALCULATE BUFFER POOL SIZE      33000019
         LA    WKREG2,C16(WKREG2)       ADD BUFFER CONTROL BLOCK        33200019
         AIF   ('&LIB' EQ 'LIB1').LIB1BA                                33204001
         TM    TCBFLGS6,TCBRV     TEST FOR REAL ADDRESS SPACE           33208001
         BO    GETREAL            BRANCH IF SO                          33212001
*                                 ALLOW FOR UNSCHEDULED LIST &          33216001
         LA    WKREG2,FIRSTUSL+RNDFCTOR(RA,WKREG2) BUFFER SUFFIX, &     33220001
         N     WKREG2,RNDDBL      ROUND TO MULTIPLE OF 8.               33224001
*                                                                       33228001
         BAL   RJ,GETCORE         GET MAIN STORAGE                      33232001
*                                                                       33236001
*                       INITIALIZE THE UNSCHEDULED LIST.                33240001
*                                                                       33244001
         USING USL,RF                                                   33248001
         XC    USL(FIRSTUSL),USL  CLEAR THE LIST                        33252001
         MVI   USLSIZE+1,FIRSTUSL INITIALIZE SIZE FIELD                 33256001
         OI    USLFLAGS,USLCURNT  TURN ON 'CURRENT' BIT                 33260001
         LA    WKREG1,USL+FIRSTUSL-L'USLSLOT1  ADDRESS LAST USL SLOT    33264001
         USING USLSLOT,WKREG1                                           33268001
         OI    USLSLTFL,USLENDL   TURN ON END-OF-LIST INDICATOR         33272001
         DROP  WKREG1                                                   33276001
         ST    RF,DCBDYNB         STORE POINTER TO USL                  33280001
*                                                                       33284001
*                       INITIALIZE BUFFER CONTROL BLOCK                 33288001
*                                                                       33292001
         LA    RF,FIRSTUSL(RF)    POINT TO BUFFER CONTROL BLOCK         33296001
         USING BCBDEF,RF                                                33300001
         ST    WKREG2,BCBTBRS     TOTAL SIZE OF GETMAIN AREA            33304001
         ST    RB,BCBBUFL         LENGTH OF EACH BUFFER                 33308001
         STCM  RC,ADDR,BCBRAOFS   RECORD AREA OFFSET IN BUFFER          33312001
         LA    RD,BCBLENTH(RA,RF) GET ADDRESS OF FIRST BUFFER           33316001
         ST    RD,BCBBUF1         STORE IT IN BCB                       33320001
         STCM  RF,ADDR,DCBBUFCB+1 STORE ADDRESS OF BCB                  33324001
*                                                                       33328001
*                       INITIALIZE AVAILABLE BUFFER CHAIN               33332001
*                                                                       33336001
         MVI   BCBBFAVL,1         FIRST AVAILABLE = #1                  33340001
         LA    WKREG7,1(R9)       # OF BUFFERS + 1 = COMPARAND          33344001
         DROP  RTCB                                                     33348001
         LA    WKREG6,1           INCREMENT = 1.                        33352001
         LA    WKREG2,2           NEXT BUFFER FOR BUFFER #1 = #2.       33356001
*                                 (OPERAND)                             33360001
STORENXT STC   WKREG2,BCBSUFFX-2(WKREG2)    CHAIN TO NEXT AVAIL         33364001
         BXLE  WKREG2,WKREG6,STORENXT       LOOP ONCE FOR EACH          33368001
*                                           BUFFER                      33372001
         LA    WKREG6,BCBSUFFX-3(WKREG2)    POINT TO LAST CHAIN         33376001
*                                           ELEMENT INITIALIZED.        33380001
         MVI   0(WKREG6),0        NO MORE BUFFERS                       33384001
         B     INITBUFS                                                 33388001
GETREAL  EQU   *                                                        33392001
.LIB1BA  ANOP                                                           33396001
         BAL   RJ,GETCORE               GET MAIN STORAGE                33400019
         IC    RE,DCBBUFNO              SAVE BUFFER NUMBER              33600019
         ST    RF,DCBBUFCB              STORE POINTER TO BUFCB          33800019
         STC   RE,DCBBUFNO              RESTORE BUFNO IN DCB            34000019
*                                                                     * 34200019
***** INITIALIZE THE BUFFER CONTROL BLOCK  - FORMAT DESCRIPTION   ***** 34400019
*                                                                     * 34600019
*                -------------------------------------                * 34800019
*                I00000000I00000000IBUF1ADDRICORESIZEI                * 35000019
*                -------------------------------------                * 35200019
*                  4 BYTES  4 BYTES  4 BYTES  4 BYTES                 * 35400019
*                                                                     * 35410019
         XC    NULL(WGOFF,RF),NULL(RF)  * CLEAR FIRST 2 WORDS OF        35800019
*                                       * BUFFER CONTROL BLOCK          36000019
         ST    WKREG2,C12(RF)           INITIALIZE BUFFER POOL SZ       36200019
         LA    RD,C16(RF)               POINT TO FIRST BUFFER           36400019
         ST    RD,WGOFF(RF)             INITIALIZE POINTER TO BUFS      36600019
INITBUFS EQU   *                                                 A44855 36660021
         S     RC,FOUR                  OFFSET TO SWA POINTER    A44855 36720021
         LR    WKREG2,RD                INCREMENT BUFFER POINTER        36800019
         AR    RD,RB                    POINT TO NEXT BUFFER            37000019
         LA    RJ,ONE                   SET BUFFER COUNT TO 1           37200019
*                                                                     * 37400019
***** INITIALIZE BUFFER CHAIN AND RECORD AREA POINTER IN BUFFERS  ***** 37600019
*                                                                     * 37800019
         USING BUFFERA,WKREG2                                    A44855 37900021
CHAIN    CR    RJ,R9                    ARE ALL BUFFERS CHAINED         38000019
         BE    LASTBUF                  YES, BRANCH                     38200019
         LA    RJ,ONE(RJ)               INCREMENT BUFFER COUNT          38400019
         ST    RD,NULL(WKREG2)          SET POINTER TO NEXT BUFFER      38600019
         LA    WKREG1,PAROFF(RC,WKREG2) CALCULATE REC AREA POINTER      38800019
         ST    WKREG1,PAROFF(WKREG2)    SET POINTER TO REC AREA         39000019
         LA    WKREG1,NULL(RC,WKREG2)   GET ADDR OF SWA ADDR FIELD      39200019
         ST    WKREG2,NULL(WKREG1)      STORE ADDR OF SWA               39400019
         XC    BUFBI,BUFBI              CLEAR WORKING OFFSET     A44855 39460021
*                                       FIELD                    A44855 39520021
         LR    WKREG2,RD                UPDATE BUFFER POINTER           39600019
         AR    RD,RB                    UPDATE NEXT BUFFER POINTER      39800019
         B     CHAIN                    LOOP                            40000019
LASTBUF  XC    NULL(PAROFF,WKREG2),NULL(WKREG2)                         40200019
*                                       CLEAR LAST BUFFER POINTER       40210019
         XC    BUFBI,BUFBI              CLEAR OFFSET FIELD       YM3693 40260002
         LA    WKREG1,PAROFF(RC,WKREG2) CALCULATE REC AREA POINTER      40400019
         ST    WKREG1,PAROFF(WKREG2)    SET POINTER TO REC AREA         40600019
         LA    WKREG1,NULL(RC,WKREG2)   GET ADDR OF SWA ADDR FIELD      40800019
         ST    WKREG2,NULL(WKREG1)      STORE ADDR OF SWA               41000019
         B     RESTREGS                 CONTINUE PROCESSING             41200019
*                                                                       41400019
*****  CONSTRUCT SEGMENT WORK AREA FOR VRE OPTION WITHOUT DYNAMIC       41600019
*                             BUFFERING                                 41800019
*                                                                       42000019
GETSWA   CLC   DCBBLKSI(TWO),NULL(RA)   COMPARE MAXIMUM LOGICAL         42200019
*                                       RECORD LENGTH + TRACK SIZE      42400019
         BNH   LOWBLKSI                 BRANCH IF MAXIMUM LOGICAL       42600019
*                                       RECORD LENGTH IS LOW            42800019
         LH    RC,NULL(RA)              USE TRACK LENGTH                43000019
         B     ADDCNTL                  BRANCH TO ADD CONTROL BYTE      43200019
LOWBLKSI LH    RC,DCBBLKSI              USE MAX LOGICAL REC LENGTH      43400019
ADDCNTL  LA    RC,C10(RC)               ADD CONTROL BYTES               43600019
*                                                                       43800019
***** ROUND TO FULLWORD ALIGNMENT FOR SEGMENT WORK AREA                 44000019
*                                                                       44200019
         LR    WKREG2,RC                                                44400019
         LA    WKREG1,NULL              CLEAR EVEN REGISTER             44600019
         D     WKREG1,FOUR              DIVIDE BY FOUR                  44800019
         LTR   WKREG1,WKREG1            IS REMAINDER ZERO               45000019
         BZ    CALSWA                   BRANCH IF YES                   45200019
         N     RC,RNDFULL               CLEAR LAST TWO BITS             45400019
         LA    RC,PAROFF(RC)            ADD FOUR                        45600019
*                                                                       45800019
***** CALCULATE TOTAL SEGMENT WORK AREA LENGTH + GET MAIN STORAGE       46000019
*                                                                       46200019
CALSWA   LA    WKREG1,NULL              CLEAR EVEN REGISTER             46400019
         LR    WKREG2,RC                                                46600019
         MR    WKREG1,R9                CALCULATE TOTAL SWA SIZE        46800019
         LA    WKREG2,WGOFF(WKREG2)     ADD BUFCB SIZE                  47000019
         BAL   RJ,GETCORE               GET MAIN STORAGE                47200019
         ST    RF,DCBDYNB               PUT BUFCB POINTER IN DCB        47400019
*                                                                       47600019
***** INITIALIZE THE SEGMENT WORK AREA CONTROL BLOCK                    47800019
*                                                                       48000019
         LA    RB,WGOFF(RF)             POINT TO FIRST BUFFER           48200019
         ST    RB,NULL(RF)              PUT POINTER TO BUF1 IN DCB      48400019
         STH   R9,PAROFF(RF)            PUT SWA BUFNO IN-BCB            48600019
         STH   RC,SIX(RF)               PUT SWA BUF LNGTH IN BCB        48800019
         LA    RJ,ONE                   INITIALIZE COUNT REGISTER       49000019
*                                                                       49200019
**** INITIALIZE SEGMENT WORK AREA POOL CHAIN                            49400019
*                                                                       49600019
         LR    RD,RC                                                    49800019
         AR    RD,RB                    INITIALIZE NEXT BUF PTR         50000019
CHAINSWA CR    RJ,R9                    ARE ALL BUFFERS CHAINED         50200019
         BE    LASTSWA                  BRANCH IF YES                   50400019
         ST    RD,NULL(RB)              CHAIN BUFFER POINTER            50600019
         XC    PAROFF(SIX,RB),PAROFF(RB)                                50800019
*                                       CLEAR BUFFER CONTROL FIELD      50810019
         LA    RJ,ONE(RJ)               INCREMENT COUNT REGISTER        51000019
         LR    RB,RD                    UPDATE BUFFER POINTER           51200019
         AR    RD,RC                    POINT TO NEXT BUFFER            51400019
         B     CHAINSWA                 BRANCH                          51600019
LASTSWA  XC    NULL(C10,RB),NULL(RB)    ZERO LAST BUFFER POINTER        51800019
RESTREGS EQU   *                                                        52000019
         LM    WKREG0,R9,DXCCW4         RESTORE OPEN'S REGISTERS        52200019
         MVI   NULL(RWTGC),NULL         INDICATE THIS DCB FINISHED      52400019
*                                                                       52600019
*                                                                       52800019
*                                                                       53000019
*  ROUTINE TO SCAN DCB LIST FOR OTHER DCBS REQUIRING THIS EXECUTOR.     53200019
*  IF NONE ARE FOUND, CONTROL IS TRANSFERED TO THE NEXT EXECUTOR OF THE 53400019
*  FIRST DCB WHICH IS NOT COMPLETED.                                    53600019
*                                                                       53800019
*                                                                       54000019
*                                                                       54200019
SCAN4EQ  EQU   *                                                        54400019
         LA    RWTGC,WGOFF(NULL,RWTGC)  INCREMENT WHERE TO GO INDEX     54600019
         LA    RPARC,PAROFF(NULL,RPARC) AND DCB PARAMETER LIST INDEX    54800019
         CLC   NULL(TWO,RWTGC),AMIDCNST DOES TABLE NAME THIS EXECUTOR   55000019
         BCR   WGOFF,FDNBASE            YES,BRANCH TO ENTRY POINT       55200019
         CLC   NULL(TWO,RWTGC),OPIDCNST NO, IS THIS END OF TABLE        55400019
         BNE   SCAN4EQ                  NO, LOOP TO INCREMENT STEPS     55600019
*                                                                       55800019
         LR    RPARC,RPAR               RESTORE BOTH INDEX REGISTERS TO 56000019
         LA    RWTGC,C32(NULL,RWTG)     THEIR INITIAL VALUES            56200019
SCAN4ANY CLI   NULL(RWTGC),NULL         IS THIS DCB COMPLETED           56400019
         BNE   XCTLRTN                  IF NOT, GO TO NAMED EXECUTOR    56600019
         LA    RWTGC,WGOFF(NULL,RWTGC)  INCREMENT BOTH INDEX REGISTERS  56800019
         LA    RPARC,PAROFF(NULL,RPARC) TO THE NEXT ENTRIES             57000019
         B     SCAN4ANY                 LOOP TO CHECK COMPLETION        57200019
*                                                                       57400019
XCTLRTN  EQU   *                                                        57600019
         MVC   SIX(TWO,RWTG),NULL(RWTGC)                                57800019
*                                       MOVE EXECUTOR ID TO PARAM LIST  57810019
         MVC   C14(THREE,RWTG),TWO(RWTGC)                               58000019
*                                       MOVE TTR                        58010019
         LA    WKREG3,DXCCW12                                           58200019
         XCTL  DE=(RWTG),SF=(E,(15))                                    58400019
GETCORE  EQU   *                                                        58600019
         LA    RE,SUB250                LOAD IN SUBPOOL BYTE            58800019
         SLL   RE,SHIFT                                                 59000019
         OR    RE,WKREG2                LOAD SIZE TO BE GOTTEN          59200019
         AIF   ('&LIB' NE 'LIB1').LIB1CA                                59300001
*                                                                       59400019
*****  HIARCHY TEST PRIOR TO GETMAIN.  DETERMINE WHETHER CORE WILL BE   59600019
*****  GOTTEN FROM HI SPEED STORAGE OR LCS.                             59800019
*                                                                       60000019
         SR    RF,RF                                                    60200019
         TM    DCBBFTEK,HIARCHY         TEST FOR HI SPEED STORAGE OR    60400019
*                                       LCS                             60600019
         BO    GETH1                    GET CORE FOR LCS REQUEST        60800019
.LIB1CA  ANOP                                                           60900001
         GETMAIN R,LV=(0),HIARCHY=0                                     61000019
         BR    RJ                       RETURN                          61200019
         AIF   ('&LIB' NE 'LIB1').LIB1CB                                61300001
GETH1    EQU   *                                                        61400019
         GETMAIN R,LV=(0),HIARCHY=1                                     61600019
         BR    RJ                       RETURN                          61800019
.LIB1CB  ANOP                                                           61900001
*                                                                       62000019
***** CONSTANTS                                                         62200019
*                                                                       62400019
         DS    0F                                                       62600019
AMIDCNST DC    C'3F'                    THIS EXECUTOR'S ID              62800019
OPIDCNST DC    C'0S'                    LAST WTG TABLE ENTRY            63000019
LASTFOUR DC    X'0000000F'              CLEAR DEVICE CODE REGISTER      63200019
FOUR     DC    F'4'                     CONSTANT TO ROUND TO F WORD     63400019
EIGHT    DC    F'8'                     CONSTANT TO ROUND TO D WORD     63600019
RNDDBL   DC    X'FFFFFFF8'              ROUND BUFFER LENGTH TO D        63800019
RNDFULL  DC    X'FFFFFFFC'              ROUND BUFFER LENGTH TO F        64000019
NULL     EQU   0                        CONSTANT FOR ZERO               64010019
ONE      EQU   1                        CONSTANT FOR ONE                64020019
TWO      EQU   2                        CONSTANT FOR TWO                64030019
THREE    EQU   3                        CONSTANT FOR 3                  64040019
SIX      EQU   6                        CONSTANT FOR SIX                64050019
C10      EQU   10                       CONSTANT FOR 10                 64060019
C12      EQU   12                       CONSTANT FOR 12                 64070019
C14      EQU   14                       CONSTANT FOR 14                 64071019
C16      EQU   16                       CONSTANT FOR 16                 64080019
C32      EQU   32                       CONSTANT FOR 32                 64090019
WGOFF    EQU   8                        OFFSET IN WHERE-TO-GO TABLE     64200019
PAROFF   EQU   4                        OFFSET IN DCB PARAMETER LIST    64400019
FWDALN   EQU   X'01'                    ALIGN BUFFERS TO FULL WORD      64600019
HIARCHY  EQU   X'80'                    TEST DCBBFTEK FOR WHICH STORAGE 64800019
THREERND EQU   X'03'              USED TO ROUND # OF BUFFS NEEDED       64850001
RNDFCTOR EQU   X'07'              USED FOR ROUNDING                     64900001
*                                       BOX, HI SPEED OR LCS.           65000019
*                                       WHICH IS NOT A DOUBLE WORD      65200019
*                                       BOUNDARY                        65400019
DEBOFF   EQU   44                       OFFSET TO DEB                   65410019
SHIFT    EQU   24                       SHIFT REGISTER                  65420019
SUB250   EQU   250                      SUBPOOL NUMBER                  65430019
DYNB     EQU   X'04'                    DYNAMIC BUFFERING               65600019
TYPCD    EQU   19                       OFFSET TO DEV CLASS IN DEV TAB  65800019
         AIF   ('&LIB' EQ 'LIB1').LIB1DA                                65820001
*                                                                       65840001
ADDR     EQU   B'0111'       LOW-ORDER 24 BITS OF A REGISTER            65860001
FIRSTUSL EQU   64            SIZE OF FIRST COPY OF THE                  65880001
*                            UNSCHEDULED LIST.                          65900001
.LIB1DA  ANOP                                                           65920001
         ORG   IGG0193F+1016            ORG                             66000019
         DC    F'0'                     END OF TABLE MARKER             66200019
         DC    C'019'                   SVC CODE 019                    66400019
         DC    AL1(127)                 OFFSET(DOUBLE WORDS) TO ID TAB  66600019
FORECORE DSECT                                                          66800019
         IECDSECT                                                       67000019
CVT      DSECT                                                          67200021
         CVT                                                            67400019
         IKJTCB                                                         67500021
*                                                                       67600019
DEB      DSECT                                                          67800019
         DS    0F                                                       68000019
DEBNMSUB DS    0CL1                     NO. OF SUBR. LOADED BY OPEN     68200019
DEBTCBAD DS    CL4                      ADDRESS OF THE TCB FOR THIS DEB 68400019
DEBAMLNG DS    0CL1                     NO. OF BYTES IN THE ACCESS      68600019
*                                       MTHD. DPDT. SECTION             68800019
DEBDABAD DS    CL4                      ADDRESS OF THE PREVIOUS DEB     69000019
DEBOFLGS DS    0CL1                     DATA SET STATUS FLAGS           69200019
DEBIRBAD DS    CL4                      IRB ADDRESS                     69400019
DEBOPATB DS    0CL1                     TYPE OF FILES                   69600019
DEBSYSPG DS    CL4                      ADDRESS OF 1ST IOB IN SYSTEM    69800019
*                                       PURGE CHAIN                     70000019
DEBNMEXT DS    0CL1                     NUMBER OF EXTENTS SPECIFIED IN  70200019
*                                       THE DSCB                        70400019
DEBUSRPG DS    CL4                      ADDRESS OF 1ST IOB IN USERS     70600019
*                                       PURGE CHAIN                     70800019
DEBPRIOR DS    0CL1                     ALWAYS ZERO                     71000019
DEBECBAD DS    CL4                      ECB ADDRESS FOR SVC PURGE REQST 71200019
DEBPROTG DS    0CL1                     RESERVE (FIRST 4 BITS)          71400019
DEBDEBID DS    0CL1                     HEX 'F' IDENTIFY THIS AS A DEB  71600019
DEBDCBAD DS    CL4                      ADDR OF DCB ASSOC. WITH DEB     71800019
DEBEXSCL DS    0CL1                     EXTENT SCALE                    72000019
DEBAPPAD DS    CL4                      ADDR OF I/O APPENDAGE VECTOR T  72200019
DEBDNMOD DS    0CL1                     DEVICE MODIFIER FILE MASK       72400019
DEBUCBAD DS    CL4                      ADDR OF UCB FOR DATA EXTENT     72600019
DEBBINUM DS    CL2                      RESERVED FOR FUTURE USE         72800019
DEBSTRCC DS    CL2                      STARTING CYLINDER NO FOR EXTENT 73000019
DEBSTRHH DS    CL2                      STARTING HEAD NO. FOR EXTENT    73200019
DEBENDCC DS    CL2                      ENDING CYLINDER NO. FOR EXTENT  73400019
DEBENDHH DS    CL2                      ENDING HEAD NO. FOR EXTENT      73600019
DEBNMTRK DS    CL2                      NO OF TRKS ALLOCATED TO EXTENT  73800019
DEBSUBID EQU   0                        SUBROUTINE ID'S                 74000019
*                                                                       74200019
*                                                                       74400019
         DCBD  DSORG=DA                                                 74600019
         EJECT                                                          74604021
*********************************************************************** 74608021
*                BUFFER FORMAT FOR VRE DYNAMIC BUFFERING                74612021
*********************************************************************** 74616021
BUFFERA  DSECT                          SEGMENT WORKAREA         A44855 74620021
BUFNXT   DS    A                        ADDR OF NEXT BUFFER ON   A44855 74624021
*                                       AVAILABLE CHAIN                 74628021
BUFRAPTR DS    A                        ADDR OF RECORD AREA IN   A44855 74632021
*                                       BUFFER                   A44855 74636021
BUFBI    DS    FL2                      OFFSET IN RECORD AREA    A44855 74640021
*                                       FOR                      A44855 74644021
*                                       CURRENT SEGMENT                 74648021
BUFSEGAR EQU   *                        SEGMENT AREA; LENGTH IS  A44855 74652021
*                                       THE                      A44855 74656021
*                                       SMALLER OF BLOCKSIZE+KEY LENGTH 74660021
*                                       OR TRACK CAPACITY               74664021
*********************************************************************** 74668021
BUFFERB  DSECT                          REST OF BUFFER; BUFRECAR A44855 74672021
*                                       IS                       A44855 74676021
*                                       ALIGNED AS SPECIFIED IN         74680021
*                                       DCBBFALN                        74684021
BUFBFPTR DS    A                        ADDR OF SEGMENT WORKAREA A44855 74688021
BUFRECAR EQU   *                        RECORD AREA; LENGTH =    A44855 74692021
*                                       BLKSIZE+                 A44855 74696021
*                                       KEY LENGTH                      74700021
*********************************************************************** 74704021
*                    BUFFER CONTROL BLOCK FORMAT                        74708021
*********************************************************************** 74712021
BCBDEF   DSECT                                                          74716021
BCBFRQT  DS    A                        FIRST IOB WAITING FOR A  A44855 74720021
*                                       BUFFER                   A44855 74724021
BCBFRQB  DS    A                        LAST IOB WAITING FOR A   A44855 74728021
*                                       BUFFER                   A44855 74732021
BCBNABFR DS    A                        ADDRESS OF NEXT          A44855 74736021
*                                       AVAILABLE BUF            A44855 74740021
BCBTBRS  DS    F                        TOTAL CORE SIZE OF       A44855 74744021
*                                       BUFFERS,CTL              A44855 74748021
*                                       BLOCKS                          74752021
         AIF   ('&LIB' EQ 'LIB1').LIB1AF                                74754001
BCBLENTH EQU   *-BCBDEF                 SIZE OF BASIC SECTION OF A44855 74756021
*                       FORMAT FOR TASKS IN REAL ADDRSPCE.              74756101
.LIB1AF  ANOP                                                           74758001
*                                       BCB                      A44855 74760021
*********************************************************************** 74764021
         AIF   ('&LIB' EQ 'LIB1').LIB1AG                                74792201
*                       FORMAT FOR TASKS IN VIRTUAL ADDRSPCE            74792401
         ORG   BCBDEF                                                   74792601
BCBBUF1  DS    A        ADDRESS OF FIRST BUFFER IN POOL                 74792801
BCBBUFL  DS    F        LENGTH OF EACH BUFFER                           74793001
BCBBFAVL DS    FL1      BUFFER # OF NEXT AVAILABLE BUFFER               74793201
BCBRAOFS DS    FL3      OFFSET OF RECORD AREA IN BUFFER (VRE)           74793401
         DS    F        BCBTBRS, INCLUDES USL LENGTH                    74793601
BCBSUFFX EQU   *        BUFFER SUFFIX, 1 BYTE PER BUFFER, USED          74793801
*                       AS AVAILABLE CHAIN.                             74794001
         SPACE 3                                                        74794201
USL      DSECT          UNSCHEDULED LIST FORMAT                         74794401
USLSIZE  DS    H        SIZE OF CURRENT LIST IN BYTES                   74794601
         DS    H        UNUSED                                          74794801
USLFLAGS DS    0BL1                                                     74795001
USLCURNT EQU   BIT0     IF ON, THIS IS THE CURRENT LIST                 74795201
USLBFRQT DS    A        PTR TO ADDR OF IOB ON TOP OF BUFFER Q           74795401
USLBFRQB DS    A        PTR TO ADDR OF IOB LAST ON BUFFER Q             74795601
USLCHAIN DS    A        ADDR OF PRIOR COPY OF LIST (0 FOR 1ST)          74795801
USLSLOT1 DS    A        TOP SLOT ON QUEUE                               74796001
         SPACE 3                                                        74796201
USLSLOT  DSECT          FORMAT OF EACH SLOT ON USL                      74796401
USLSLTFL DS    0BL1     FLAGS                                           74796601
USLENDL  EQU   BIT0     IF ON, SLOT IS LAST IN USL                      74796801
USLINUSE EQU   BIT1     IF ON, SLOT IS BEING USED                       74797001
USLIOBA  DS    A        IF SLOT IS BEING USED, ADDR OF IOB ON Q         74797201
USLNXT   DS    A        NEXT SLOT                                       74797401
*                                                                       74797601
.LIB1AG  ANOP                                                           74797801
         END                                                            74800019
