         TITLE 'IGG0193G - BDAM OPEN EXECUTOR NO. 3'                    00200019
IGG0193G CSECT                                                        * 00400019
*                                                                     * 00600019
*          RELEASE 20 DELETIONS                                       * 00800019
*          RELEASE 21 DELETIONS                                       * 01000019
* 274000-288800,392000                                           A35339 01060021
* 314000-330000,652000,654000,672000                             A30797 01120021
*          RELEASE 22 DELETIONS                                       * 01200019
*          RELEASE 23 DELETIONS                                       * 01400019
*          RELEASE 24 DELETIONS                                       * 01600019
*          RELEASE 25 DELETIONS                                       * 01610019
*          RELEASE 26 DELETIONS                                       * 01620019
*          RELEASE 27 DELETIONS                                       * 01630019
*          RELEASE 28 DELETIONS                                       * 01640019
*                                                                     * 01650019
*STATUS CHANGE LEVEL 000                                              * 01800019
*                                                                     * 01810019
*FUNCTION/OPERATION - SPLIT OF IGG0193C FOR RELEASE 19.                 01910019
*   THIS ROUTINE IS BROUGHT INTO CORE AND GIVEN                         02010019
*   CONTROL WHEN SOME OPEN EXECUTOR ISSUES 'XCTL' TO IGG0193G.        * 02200019
*   THIS ROUTINE LOADS THE REQUIRED BDAM MODULES AS SPECIFIED IN THE  * 02400019
*   DCB FIELDS, MACRF,RECFM,OPTCD,BUFTEK AND STORES THE MODULE ID     * 02600019
*   AND A COUNT OF MODULES LOADED, INTO THE DEB. AN IRB IS CONSTRUCTED* 02800019
*   AND IT'S ADDRESS PLACED IN THE DEB AND CERTAIN FIELDS OF THE DCB  * 03000019
*   ARE INITIALIZED.                                                  * 03200019
*                                                                     * 03400019
*ENTRY POINT- ENTRY WILL BE TO THE FIRST BYTE OF THE MODULE BY AN     * 03600019
*   'XCTL' TO IGG0193G.                                               * 03800019
*                                                                     * 04000019
*INPUT- THE REGISTERS 5,6,7,8 ARE THE INPUT AS FOLLOWS,               * 04200019
*   5 - BEGINNING OF THE DCB PARAMETER LIST                           * 04400019
*   6 - BEGINNING OF THE WHERE-TO-GO TABLE                            * 04600019
*   7 - ADDRESS OF THE CURRENT ENTRY IN THE PARAMETER LIST            * 04800019
*   8 - ADDRESS OF THE CURRENT ENTRY IN THE WHERE-TO-GO TABLE         * 05000019
*                                                                     * 05200019
*OUTPUT- THE REGISTERS 7,8 WILL BE POSITIONED TO THE NEXT UNFINISHED  * 05400019
*   ENTRY, AN IRB WILL BE CONSTRUCTED IN PROTECTED CORE, AND THE      * 05600019
*   REQUIRED BDAM MODULES LOADED INTO CORE.                           * 05800019
*                                                                     * 06000019
*EXTERNAL ROUTINES- 'IEA1EF00' IS ENTERED VIA THE CIRB MACRO TO CAUSE * 06200019
*   AN IRB TO BE CONSTRUCTED AND INITIALIZED.                         * 06400019
*                                                                     * 06600019
*EXIT-NORMAL- THIS ROUTINE TERMINATES BY LOCATING THE NEXT NON-ZERO   * 06800019
*   ENTRY IN THE WHERE-TO-GO TABLE AND EXECUTING AN XCTL TO THAT      * 07000019
*   ROUTINE. THE SCAN OF THE TABLE BEGINS AT 'SCAN4EQ'.               * 07200019
*                                                                     * 07400019
*TABLES/WORK AREAS- 1.DCB PARAMETER LIST CONTAINS THE ADDRESS OF EACH * 07600019
*   DCB SPECIFIED IN THE OPEN MACRO INSTRUCTION.  2.WHERE-TO-GO TABLE * 07800019
*   CONTAINS THE ID AND TTR OF THE ROUTINE NEEDED TO PROCESS THE      * 08000019
*   DCB WHICH CORRESPONDS TO THIS ENTRY AND THE ADDRESS OF A WORK AREA* 08200019
*   FOR THE DCB.  3.WORK AREA IS A 464 BYTE AREA ASSIGNED TO THIS DCB * 08400019
*   TEMPORARILY AND USED BY IGG0193G AS A REGISTER SAVE AREA.  4.THE  * 08600019
*   COMMUNICATION VECTOR TABLE IS A RESIDENT VECTOR LIST USED TO      * 08800019
*   LOCATE THE IOS APPENDAGE LIST, ROUTINE TO BUILD AN IRB, AND THE   * 09000019
*   SVC LIBRARY DCB.                                                  * 09200019
*                                                                     * 09400019
*ATTRIBUTES- THIS ROUTINE IS EXECUTED IN THE TRANSIENT AREA AS        * 09600019
*   DISABLED, PRIVILEGED, AND REUSABLE.                               * 09800019
*                                                                     * 10000019
*NOTES- THIS ROUTINE IS THE THIRD OPEN EXECUTOR FOR A BDAM DCB AND    * 10200019
*   COMPLETES THE PROCESSING FOR THE DCB IF VRE, RELATIVE BLOCK       * 10400019
*   ADDRESSING OR DYNAMIC BUFFERING ARE NOT SPECIFIED.  IN THIS CASE  * 10600019
*   THE WHERE-TO-GO TABLE ENTRY WILL BE SET TO ZERO.  IF RELATIVE     * 10800019
*   BLOCK ADDRESSING OR DYNAMIC BUFFERING ARE SPECIFIED,HOWEVER, THE  * 11000019
*   ID AND TTR OF IGG0193E ARE PLACED IN THE WHERE-TO-GO TABLE AS THE * 11200019
*   NEXT EXECUTOR TO BE CALLED FOR THIS DCB.  IF VRE IS SPECIFIED THE * 11400019
*   ID AND TTR OF IGG0193F ARE PLACED IN THE WHERE-TO-GO TABLE.       * 11600019
*                                                                       11800019
*                                                                       12000019
*                                                                       12200019
         USING STEPONE,RBASE                                            12400019
         USING DEB,RDEB                                                 12600019
         USING IHADCB,RDCB                                              12800019
         USING FORCORE,RCORE                                            13000019
*                                                                       13200019
*  REGISTER USAGE                                                       13400019
*                                                                       13600019
*                                                                       13800019
RE       EQU   0                        WORK REGISTER                   14000019
RF       EQU   1                        WORK REGISTER                   14200019
RDCB     EQU   2                        USER'S DCB ADDRESS              14400019
RBASE    EQU   3                        BASE REGISTER                   14600019
RCORE    EQU   4                        WORK AREA ADDRESS               14800019
RPAR     EQU   5                        PARAMETER LIST ADDRESS          15000019
RWTG     EQU   6                        FRONT OF WHERE-TO-GO TABLE      15200019
RPARC    EQU   7                        CURRENT ENTRY IN PARAMETER LIST 15400019
R7       EQU   7                        DEB SUBROUTINE ID INDEX         15600019
RWTGC    EQU   8                        CURRENT ENTRY IN WTG            15800019
RTIOT    EQU   9                       TIOT ADDRESS                     16000019
R9       EQU   9                       RETURN FOR MODULE LOAD ROUTINE   16200019
RUCB     EQU   10                      CURRENT UCB ADDRESS              16400019
MODLOADR EQU   10                      ADDRESS OF MODULE LOAD ROUTINE   16600019
RDEB     EQU   11                      DEB BASE REGISTER                16800019
RB       EQU   12                      WORK REGISTER                    17000019
RC       EQU   13                      WORK REGISTER                    17200019
RD       EQU   14                      WORK REGISTER                    17400019
RJ       EQU   15                      WORK/PARAMETER REGISTER          17600019
*                                                                       17800019
*                                                                       18000019
         EJECT                                                          18200019
*                                                                       18400019
         BALR  RBASE,0                  ESTABLISH BASE FOR THIS ROUTINE 18600019
STEPONE  L     RDCB,ZERO(ZERO,RPARC)    LOAD THE DCB BASE REGISTER      18800019
         L     RCORE,FOUR(ZERO,RWTGC)   SET POINTER TO DCB WORK AREA    19000019
         STM   RPAR,RUCB,DXCCW4         SAVE OPEN'S REGISTERS           19200019
         L     RDEB,DCBDEBAD            LOAD THE DEB BASE               19400019
         LA    R7,DEBDVMOD              * ESTABLISH A POINTER TO        19600019
         SR    RF,RF                    * THE SUBROUTINE ID AREA OF     19800019
         IC    RF,DEBNMEXT              * THE DEB BY OFFSETTING FOR     20000019
         SLL   RF,FOUR                  * NO. OF EXTENTS X 16           20200019
         AR    R7,RF                    * AND ACCESS METHOD LENGTH      20400019
         SR    RF,RF                    * (WORD COUNT FOR RELATIVE      20600019
         IC    RF,DEBAMLNG              * EXTENT) X 4 AND NO.           20800019
         SLL   RF,TWO                   * OF SUBROUTINES                21000019
         AR    R7,RF                    * LOADED X 2.                   21200019
         SR    RF,RF                    *                               21400019
         IC    RF,DEBNMSUB              *                               21600019
         SLL   RF,ONE                   *                               21800019
         AR    R7,RF                    *                               22000019
         LA    MODLOADR,MODLOAD         SET POINTER TO LOAD ROUTINE     22200019
         LA    RC,ZERO(RC)              CLEAR HIGH ORDER BYTE           22400019
         L     RC,DCBREAD               LOAD FOUNDATION MODULE ADDR     22600019
*                                                                       22800019
*                                                                       23000019
*        THIS ROUTINE TESTS FOR ADDITIONAL OPTIONS AND LOADS THE        23200019
*        REQUIRED OPTION MODULES.                                       23400019
*                                                                       23600019
         LA    RB,IDTBLOPS              INCREMENT TO OPTION ENTRIES     23800019
TVER     TM    DCBOPTCD,VERIFY          IS WRITE CHECK SPECIFIED        24000019
         BZ    TSTCHK                   NO,GO TEST FOR CHECK MACRO      24200019
         BALR  R9,MODLOADR              LOAD THE WRITE VERIFY MODULE    24400019
         ST    RE,VERAD(ZERO,RC)        STORE THE ADDR IN FOUNDATION    24600019
TSTCHK   LA    RB,IDTBLCHK              INCREMENT INDEX TO CHECK ID     24800019
         TM    DCBMACRF,CHECK           IS CHECK MACRO BEING USED       25000019
         BZ    TRDX                     NO,GO TEST READ EXCLUSIVE       25200019
         BALR  R9,MODLOADR              LOAD THE CHECK ROUTINE          25400019
         IC    RC,DCBOPTCD              SAVE THE OPTCD BITS             25600019
         ST    RE,DCBCHECK              STORE THE CHECK ROUTINE ADDRESS 25800019
         STC   RC,DCBOPTCD              RESTORE THE OPTCD BITS          26000019
TRDX     LA    RB,IDTBLRDX              INCREMENT TO READ EXCLUSIVE ENT 26200019
         TM    DCBOPTCD,READX           AND SEE IF THE MODULE IS NEEDED 26400019
         BZ    TDYN                     NO, GO TEST DYNAMIC BUFFER      26600019
         BALR  R9,MODLOADR              LOAD READ EXCLUSIVE MODULE      26800019
         ST    RE,DCBDRDX               STORE THE ADDRESS IN THE DCB    27000019
*                                                                       27200019
*                                                                     * 27400021
*        LOAD REQUIRED APPENDAGES INTO PROTECTED CORE                 * 27700021
*                                                                     * 28000021
TDYN     EQU   *                                                 A35339 28300021
         L     RC,DEBAPPAD              SET A POINTER TO APPENDAGE LIST 28890019
         TM    DCBOPTCD,DYNB            IF THE OPTION IS SPECIFIED      28900019
         BZ    TEOE                     BRANCH IF NO DYNAMIC BUFFERING  28910019
         TM    DCBBFTEK,RBFTKMSK        TEST FOR BUFTEK=R               31200019
         BZ    TSIO                     BR IF NOT R              A30797 31400021
         LA    RB,VREDB                LOAD SIO APPEND 19KL-VS   A30797 31700021
         B     LDSIO                   BR TO LOAD APPENDAGE      A30797 32000021
*                                                                       32300021
TSIO     LA    RB,IDTBLSIO             LOAD SIO APPEND 19LE      A30797 32600021
LDSIO    EQU   *                                                        33200019
         BALR  R9,MODLOADR              LOAD THE SIO APPENDAGE          33400019
         ST    RE,FOUR(ZERO,RC)         STORE ADDR IN APPENDAGE LIST    33600019
TEOE     LA    RB,IDTBLEOE              THE END OF EXTENT APPENDAGE IS  33800019
         TM    DCBIOBAD,EOEBIT          REQUIRED IF EXTENDED SEARCH     34000019
         BZ    LDCEXCE                  HAS BEEN SPECIFIED              34200019
         BALR  R9,MODLOADR              LOAD THE APPENDAGE              34400019
         ST    RE,ZERO(ZERO,RC)         STORE ADDR IN APPENDAGE LIST    34600019
LDCEXCE  LA    RB,IDTBLCE               LOAD CHANNEL END AND            34800019
         BALR  R9,MODLOADR              EXCEPTIONAL CHAN. END           35000019
         ST    RE,C12(ZERO,RC)          STORE ADDR IN APPENDAGE LIST    35200019
         LR    RF,RE                    OFFSET TO EXCEPTIONAL CHANNEL   35400019
         L     RE,FOUR(ZERO,RF)         END ADDRESS                     35600019
         AR    RE,RF                                                    35800019
         ST    RE,C16(ZERO,RC)          STORE ADDRESS IN APPENDAGE LIST 36000019
*                                                                       36200019
*                                                                       36400019
*         INITIALIZE THE DCB FIELDS WHICH ARE USED BY BDAM.             36600019
*                                                                       36800019
CLRFIELD EQU   *                                                        37000019
         XC    DCBIOBAD,DCBIOBAD        CLEAR IOB POOL POINTER AND      37200019
         XC    DCBIOBSQ(C16),DCBIOBSQ   IOB QUEUE POINTERS              37400019
*                                                                       37600019
*                                                                       37800019
*        INITIALIZE THE IRB                                             38000019
*                                                                       38200019
SETUPIRB EQU   *                                                        38400019
         L     RD,DCBREAD               LOCATE ASI ADDRESS              38600019
         L     RE,ASIAD(ZERO,RD)        LOAD ASI ADDR. INTO PARAMETER   38800019
*                                       REGISTER                        39000019
         CIRB  EP=(0),KEY=PP,MODE=PP,STAB=(RE)                   A35339 39200021
         O     RF,DEBIRBAD              SAVE HI ORDER BYTE BY OR'ING IT 39400019
         ST    RF,DEBIRBAD              INTO REG RF,THEN STORE IRB ADDR 39600019
*                                       EXCLUSIVE VALIDITY CHECK        39800019
RSTOR    LM    RPAR,RUCB,DXCCW4         RESTORE OPEN'S REGISTERS        40000019
         MVC   C22(SEVEN,RWTG),CONATB   RESTORE XCTL ATTRIBUTES,LGTH    40200019
         TM    DCBBFTEK,RBFTKMSK        TEST FOR BUFTEK=R               40400019
         BZ    NOVRE                    IF NOT R BRANCH                 40600019
         TM    DCBMACRF+ONE,SEGWKARS    DID USER SUPPLY SWA             40800019
         BO    NOLOAD3E                 SEGMENT WORK AREA SUPPLIED      41000019
NXTBEXEC MVC   ZERO(FIVE,RWTGC),DAM3F   GO NEXT TO BDAM EXECUTOR 3      41200019
         B     SCAN4EQ                  BRANCH                          41400019
NOVRE    EQU   *                                                        41600019
         TM    DCBOPTCD,DYNB+RELRD      IF EITHER RELATIVE BLOCK ADR OR 41800019
         BZ    NOLOAD3E                 DYNAMIC BUFFERING IS REQUESTED  42000019
         MVC   ZERO(FIVE,RWTGC),DAM3ID  GO NEXT TO BDAM EXECUTOR 3      42010019
         B     *+EIGHT                  GO SCAN DCB                     42020019
NOLOAD3E MVI   ZERO(RWTGC),ZERO         OTHERWISE MARK THIS DCB FINISH  42030019
*                                                                       42050019
*                                                                       42060019
*        ROUTINE TO SCAN DCB LIST FOR OTHER DCBS REQUIRING THIS         42070019
*        EXECUTOR.  IF NONE ARE FOUND, CONTROL IS TRANSFERED TO         42080019
*        THE NEXT EXECUTOR OF THE FIRST DCB WHICH IS NOT COMPLETED.     42090019
*                                                                       42100019
SCAN4EQ  LA    RWTGC,WGOFF(ZERO,RWTGC)  INCREMENT WHERE TO GO INDEX     42110019
         LA    RPARC,PAROFF(ZERO,RPARC) AND DCB PARAMETER LIST INDEX    42120019
         CLC   ZERO(TWO,RWTGC),AMIDCNST DOES TABLE NAME THIS EXECUTOR   42130019
         BCR   EIGHT,RBASE              YES, BRANCH TO ENTRY POINT      44600019
         CLC   ZERO(TWO,RWTGC),OPIDCNST NO, IS THIS END OF TABLE        44800019
         BNE   SCAN4EQ                  NO, LOOP TO INCREMENT STEPS.    45000019
         LR    RPARC,RPAR               RESTORE BOTH INDEX REGISTERS TO 45200019
         LA    RWTGC,C32(ZERO,RWTG)     THEIR INITIAL VALUES            45400019
SCAN4ANY CLI   ZERO(RWTGC),ZERO         IS THIS DCB COMPLETED           45600019
         BNE   XCTLRTN                  IF NOT, GO TO NAMED EXECUTOR.   45800019
         LA    RWTGC,WGOFF(ZERO,RWTGC)  INCREMENT BOTH INDEX REGISTERS  46000019
         LA    RPARC,PAROFF(ZERO,RPARC) TO THE NEXT ENTRIES.            46200019
         B     SCAN4ANY                 LOOP TO CHECK COMPLETION        46400019
XCTLRTN  EQU   *                                                        46600019
         MVC   SIX(TWO,RWTG),ZERO(RWTGC)                                46800019
*                                       MOVE EXECUTOR ID TO PARAM LIST  46810019
         MVC   C14(THREE,RWTG),TWO(RWTGC)                               47000019
*                                       MOVE TTR                        47010019
         LA    RJ,DXCCW12               POINT TO WORK AREA              47200019
         XCTL  DE=(RWTG),SF=(E,(15))                                    47400019
*                                                                       47600019
*                                                                       47800019
*        THIS ROUTINE LOADS ALL BDAM MODULES AS REQUIRED.               48000019
*                                                                       48200019
MODLOAD  EQU   *                                                        48400019
         MVC   SIX(TWO,RWTG),ZERO(RB)   MOVE ID AS LAST 2 BYTES OF NAME 48600019
         MVC   C14(THREE,RWTG),TWO(RB)  MOVE TTR FROM TABLE             48800019
         SR    RE,RE                                                    49000019
         IC    RE,FIVE(ZERO,RB)         CONVERT DOUBLE-WORD COUNT TO    49200019
         SLL   RE,THREE                 BYTES,                          49400019
         ST    RE,C24(ZERO,RWTG)        STORE INTO PARAMETER LIST.      49600019
         MVC   C25(TWO,RWTG),C26(RWTG)  MOVE LENGTH TO BOTH SLOTS       49800019
         MVC   C27(TWO,RWTG),C25(RWTG)  IN THE PARAMETER LIST.          50000019
         MVI   C22(RWTG),ATBL           SET ATTRIBUTES                  50200019
         CH    RE,MAXSZ                 TEXT GREATER THAN 1024          50400019
         BNH   SKIPMVC                  NO                              50600019
         MVC   C27(TWO,RWTG),MAXSZ      YES, REDUCE TO MAXIMUM          50800019
         NI    C22(RWTG),ATIN           SET ATTRIBUTES TO INDICATE      51000019
*                                       MULTIPLE TEXT RECORDS           51200019
SKIPMVC  EQU   *                                                        51400019
         LR    RE,RWTG                  SET POINTER TO MODULE NAME      51600019
         L     RF,CVTPTR(ZERO,ZERO)     SET POINTER TO THE              51800019
         L     RF,CVTSVDCB-CVTDEF(ZERO,RF)                              52000019
*                                       SVC DCB                         52010019
         LOAD  DE=(0),DCB=(1)                                           52200019
         MVC   DEBSUBID(TWO,SEVEN),ZERO(RB)                             52400019
*                                       MOVE ROUTINES ID TO THE DEB     52410019
         LA    SEVEN,TWO(ZERO,SEVEN)    INCREMENT DEB ID INDEX          52600019
         LA    RB,SIX(ZERO,RB)          MODULE NAME INDEX               52800019
         IC    RF,DEBNMSUB              DEB COUNT OF                    53000019
         LA    RF,ONE(ZERO,RF)          ROUTINES                        53200019
         STC   RF,DEBNMSUB                                              53400019
         BR    R9                       RETURN TO DECISIONS             53600019
*                                                                       53800019
*                                                                       54000019
*                                                                       54200019
AMIDCNST DC    C'3G'                    THIS EXECUTOR'S ID              54400019
OPIDCNST DC    C'0S'                    LAST WTG TABLE ENTRY            54600019
MAXSZ    DC    H'1024'                  MAXIMUM LENGTH OF A TEXT RECORD 54800019
CONATB   DC    X'C3780004000400'        XCTL ATTRIBUTES AND LENGTHS     55000019
*                                                                       55200019
*                                                                       55400019
*                                                                       55600019
ATIN     EQU   X'CA'                    MULTIPLE TEXT RECORD ATTRIBUTE  55610019
ATBL     EQU   X'CB'                    LOAD ATTRIBUTES                 55800019
WGOFF    EQU   8                        OFFSET IN WHERE TO GO TABLE     56000019
PAROFF   EQU   4                        OFFSET IN DCB PARAMETER LIST    56200019
*                                                                       56400019
RELRD    EQU   X'01'                    RELATIVE BLOCK ADDRESSING       56600019
DYNB     EQU   X'04'                    DYNAMIC BUFFERING               56800019
VERIFY   EQU   X'80'                    WRITE VERIFY                    57000019
READX    EQU   X'02'                    READ EXCLUSIVE                  57200019
*                                                                       57400019
EOEBIT   EQU   8                        END OF EXTENT IS TO BE LOADED   57600019
RDXCNT   EQU   9                        NO OF ENTRIES IN READX LIST     57800019
*                                                                       58000019
*                                                                       58200019
VERAD    EQU   12                       OFFSET TO VERIFY MODULE ADDRESS 58400019
ASIAD    EQU   16                       OFFSET TO ASYNCHRONOUS          58600019
*                                       INTERRUPT ROUTINE ADDR          58620019
CHECK    EQU   X'01'                    CHECK MACRO BEING USED BIT      58800019
*                                                                       59000019
ZERO     EQU   0                        CONSTANT                        59200019
ONE      EQU   1                        CONSTANT                        59400019
TWO      EQU   2                        CONSTANT                        59410019
THREE    EQU   3                        CONSTANT                        59600019
FOUR     EQU   4                        CONSTANT                        59610019
FIVE     EQU   5                        CONSTANT                        59800019
SIX      EQU   6                        CONSTANT                        59810019
SEVEN    EQU   7                        CONSTANT                        59820019
EIGHT    EQU   8                        CONSTANT                        59830019
HUNDRED  EQU   101                      CONSTANT                        60000019
C12      EQU   12                       CONSTANT                        60010019
C14      EQU   14                       CONSTANT                        60020019
C16      EQU   16                       CONSTANT                        60021019
C20      EQU   20                       CONSTANT                        60030019
C22      EQU   22                       CONSTANT                        60040019
C24      EQU   24                       CONSTANT                        60050019
C25      EQU   25                       CONSTANT                        60060019
C26      EQU   26                       CONSTANT                        60061019
C27      EQU   27                       CONSTANT                        60070019
C32      EQU   32                       CONSTANT                        60080019
C80      EQU   80                       CONSTANT                        60090019
*                                                                       60200019
RBFTKMSK EQU   X'20'                    TEST IF BUFTK = R               60400019
SEGWKARS EQU   X'01'                    TEST IF SWA IS PRESENT          60600019
*                                                                       60800019
*                                                                       61000019
*                                                                       61200019
         ORG   IGG0193G+848             ORG                             61400019
MODIDTBL DS    0D                       TABLE OF MODULE IDS, TTR, LNGTH 61600019
*                                                                       61800019
         DC    C'KA    '                FOUNDATION                      62000019
         DC    C'KC    '                RELATIVE TRACK                  62200019
         DC    C'KE    '                RELATIVE BLOCK                  62400019
         DC    C'KG    '                FEEDBACK-RELATIVE BLOCK         62600019
         DC    C'KF    '                RELATIVE BLOCK WITH TRK OFLOW   62800019
         DC    C'KH    '                FDBACK-RELATIVE BLK WITH OFLOW  63000019
IDTBLKEY DC    C'KI    '                KEY                             63200019
         DC    C'KW    '                KEY-EXTENDED SEARCH             63400019
IDTBLID  DC    C'KK    '                ID                              63600019
IDTBLSF  DC    C'KM    '                SELF FORMAT                     63800019
IDKY     DC    C'KY    '                SELF FORMAT-EXTENDED SRCH       64000019
         DC    C'KO    '                PRE FORMAT                      64200019
         DC    C'LA    '                PRE FORMAT-EXTENDED SEARCH      64400019
IDTBLOPS DC    C'KQ    '                VERIFY                          64600019
IDTBLCHK DC    C'LI    '                CHECK                           64800019
IDTBLRDX DC    C'LG    '                READ EXCLUSIVE                  65000019
IDTBLSIO DC    C'LE    '               SIO APPENDAGE - NON VS    A30797 65400021
IDTBLEOE DC    C'LC    '                END-OF-EXTENT APPENDAGE         65600019
IDTBLCE  DC    C'KU    '                CHANNEL END APPENDAGES          65800019
DAM3ID   DC    C'3E    '                BDAM 3RD EXECUTOR               66000019
VREKJ    DC    C'KJ    '                VRE FOUNDATION                  66200019
         DC    C'KC    '                RELATIVE TRACK                  66400019
VREKR    DC    C'KR    '                VRE REPLACES KI OR KK           66600019
         DC    C'KW    '                KEY EXTENDED SEARCH             66800019
VREKN    DC    C'KN    '                SELF-FORMAT                     67000019
VREDB    DC    C'KL    '               SIO APPEND FOR VS         A30797 67200021
DAM3F    DC    C'3F    '                NEXT OPEN EXECUTOR FOR VRE      67400019
*                                                                       67600019
         DC    H'0'                     END OF TABLE MARKER             67800019
*                                                                       68000019
*                                                                       68200019
         ORG   IGG0193G+1020            ORG                             68400019
*                                                                       68600019
*                                                                       68800019
         DC    C'019'                   SVC OF OPEN                     69000019
         DC    AL1(106)                 DOUBLE WD OFFSET TO ID TAB      69200019
         EJECT                                                          69400019
FORCORE  DSECT                                                          69600019
         IECDSECT                                                       69800019
CVTDEF   DSECT                                                          70000019
         CVT                                                            70200019
*                                                                       70400019
DEB      DSECT                                                          70600019
         DS    0F                                                       70800019
DEBNMSUB DS    0CL1      NO. OF SUBR. LOADED BY OPEN                    71000019
DEBTCBAD DS    CL4       ADDRESS OF THE TCB FOR THIS DEB                71200019
DEBAMLNG DS    0CL1      NO. OF BYTES IN THE ACCESS MTHD. DPDT. SECTION 71400019
DEBDEBAB DS    CL4       ADDRESS OF THE PREVIOUS DEB IN THE SAME TASK   71600019
DEBOFLGS DS    0CL1      DATA SET STATUS FLAGS                          71800019
DEBIRBAD DS    CL4       IRB ADDRESS                                    72000019
DEBOPATB DS    0CL1      TYPE OF FILES                                  72200019
DEBSYSPG DS    CL4       ADDRESS OF FIRST IOB IN THE SYSTEM PURGE CHAIN 72400019
DEBNMEXT DS    0CL1      NUMBER OF EXTENTS SPECIFIED IN THE DSCB        72600019
DEBUSRPG DS    CL4       ADDRESS OF FIRST IOB IN THE USER PURGE CHAIN   72800019
DEBPRIOR DS    0CL1      ALWAYS ZERO                                    73000019
DEBECBAD DS    CL4       ECB ADDRESS FOR SVC PURGE REQUEST              73200019
DEBPROTG DS    0CL1      RESERVED FOR FUTURE USE (FIRST 4 BITS)         73400019
DEBDEBID DS    0CL1      HEX 'F' TO IDENTIFY THIS BLOCK AS A DEB        73600019
DEBDCBAD DS    CL4       ADDRESS OF THE DCB ASSOCIATED WITH THIS DEB    73800019
DEBEXSCL DS    0CL1      EXTENT SCALE                                   74000019
DEBAPPAD DS    CL4       ADDRESS OF I/O APPENDAGE VECTOR TABLE          74200019
DEBDVMOD DS    0CL1      DEVICE MODIFIER FILE MASK                      74400019
DEBUCBAD DS    CL4       ADDR OF UCB ASSOCIATED WITH THIS DATA EXTENT   74600019
DEBBINUM DS    CL2       RESERVED FOR FUTURE USE-ALWAYS ZERO            74800019
DEBSTRCC DS    CL2       STARTING CYLINDER NUMBER FOR EXTENT            75000019
DEBSTRHH DS    CL2       STARTING HEAD NUMBER FOR EXTENT                75200019
DEBENDCC DS    CL2       ENDING CYLINDER NUMBER FOR EXTENT              75400019
DEBENDHH DS    CL2       ENDING HEAD NUMBER FOR EXTENT                  75600019
DEBNMTRK DS    CL2       NUMBER OF TRACKS ALLOCATED TO A GIVEN EXTENT   75800019
DEBSUBID EQU   0         SUBROUTINE ID'S                                76000019
*                                                                       76200019
*                                                                       76400019
         DCBD  DSORG=DA                                                 76600019
         END                                                            76800019
