 TITLE 'IGG019BT--C.E.A. FOR BSAM CREATION OF VS-BDAM DATA SET'         00200019
*                                                                       00600019
IGG019BT CSECT                                                          00800019
*                                                                       01000019
*          RELEASE 20 DELETIONS                                         01010019
*3631334000                                                      20201  01015020
*          RELEASE 21 DELETIONS                                         01020019
*          RELEASE 22 DELETIONS                                         01030019
*          RELEASE 23 DELETIONS                                         01040019
*          RELEASE 24 DELETIONS                                         01050019
*          RELEASE 25 DELETIONS                                         01060019
*          RELEASE 26 DELETIONS                                         01070019
*          RELEASE 27 DELETIONS                                         01080019
*          RELEASE 28 DELETIONS                                         01090019
*                                                                       01100019
*STATUS CHANGE LEVEL 002                                                01110020
*                                                                       01120019
*FUNCTIONS - THIS ROUTINE IS LOADED TOGETHER WITH IGGO19BR,IGGO19BS     01200019
*            WHEN DCB SPECIFIES MACRF=(WL),RECFM=VS,BETTEK=R,DSORG=PS   01400019
*            AND DD STATEMENT SPECIFIES DSORG=DA                        01600019
*                                                                       01800019
*            THE ROUTINE OPERATES AS FOLLOWS                            02000019
*              WHEN THE WRITE-SZ WAS ISSUED,IT RETURNS CONTROL BACK TO  02200019
*              IOS                                                      02400019
*                                                                       02600019
*              WHEN THE WRITE-SF WAS ISSED,IT DETERMINES WHETHER THE    02800019
*              BLOCK IS SPANNED RECORD.IF NOT SPANNED,IT RETURNS CONTRL 03000019
*              BACK TO IOS                                              03200019
*                                                                       03400019
*              WHEN A SPANNED RECORD IS BEING PROCESSED,IT DETERMINES   03600019
*              IF THE ENTIRE RECORD HAS BEEN WRITTEN.IF THE RECORD HAS  03800019
*              BEEN WRITTEN,THE ROUTINE RETURNS CONTROL TO IOS.WHEN THE 04000019
*              ENTIRE RECORD HAS NOT BEEN WRITTEN,THE ROUTINE SCHEDULES 04200019
*              THE ASYNCHRONOUS EXIT ROUTINE SO THAT THE ASYNCHRONOUS   04400019
*              EXIT ROUTINE WILL SCHEDULE EXCP TO WRITE A MIDDLE OR THE 04600019
*              LAST SEGMENT OF THE RECORD.                              04800019
*                                                                       05000019
*                                                                       05200019
*ENTRY - THIS ROUTINE IS ENTERED WHEN A CHANNEL END,CHANNEL END WITH    05400019
*        UNIT EXCEPTION,OR CHANNEL END WITH WRONG LENGTH RECORD OCCUR   05600019
*        WITHOUT ANY OTHER ABNORMAL END CONDITIONS                      05800019
*                                                                       06000019
*INPUT - ENTRY PARAMETERS                                               06200019
*        R1 - ADDRESS OF RQE (MUST NEVER BE TOUCHED)                    06400019
*        R2 - ADDRESS OF IOB                                            06600019
*        R3 - ADDRESS OF DEB                                            06800019
*        R4 - ADDRESS OF DCB                                            07000019
*        R7 - ADDRESS OF UCB                                            07200019
*        R14- RETURN ADDRESS                                            07400019
*                                                                       07600019
*                                                                       07800019
*OUTPUT -                                                               08000019
*                                                                       08200019
*EXIT - TO IOS                                                          08400019
*                                                                       08600019
*        +0(R14) - I/O COMPLETE AND RB IS MADE AVAILABLE                08800019
*      'ASYOUT' TO EXIT EFFECTOR TO SCHEDULE ASYNCHRONOUS ROUTINE       09000019
*                                                                       09200019
*EXTERNAL ROUTINES -                                                    09400019
*                                                                       09600019
*TABLES -                                                               09800019
*                                                                       10000019
*ATTRIBUTES - THIS ROUTINE IS RE-ENTRANT AND DISABLED.                  10200019
*                                                                       10400019
*NOTES -                                                                10600019
*                                                                       10800019
*                                                                       11000019
*********************************************************************** 11200019
*                                                                       11400019
*   REGISTER CONVENTIONS                                                11600019
*                                                                       11800019
*********************************************************************** 12000019
*                                                                       12200019
R0       EQU   0                   PARAMETER REGISTER                   12400019
RQER     EQU   1                   ADDR OF RQE (NEVER USE)              12600019
RIOB     EQU   2                   ADDR OF IOB                          12800019
RDEB     EQU   3                   ADDR OF DEB                          13000019
RDCB     EQU   4                   ADDR OF DCB                          13200019
R5       EQU   5                                                        13400019
R6       EQU   6                                                        13600019
RUCB     EQU   7                   ADDR OF UCB                          13800019
R8       EQU   8                                                        14000019
SGWKR    EQU   9                   SEGENT WORK REG.(MUST BE SET TO '0') 14200019
WKR10    EQU   10                  WORK REGISTER                        14400019
WKR11    EQU   11                  WORK REGISTER                        14600019
RBASE    EQU   12                  BASE REGISTER                        14800019
RDECB    EQU   13                  ADDR OF DECB                         15000019
RTNR     EQU   14                  RETURN REGISTER                      15200019
WKR15    EQU   15                  WORK REGISTER                        15400019
*                                                                       15600019
*                                                                       15800019
*********************************************************************** 16000019
*                                                                       16200019
*   EQUATES AND MASKS                                                   16400019
*                                                                       16600019
*********************************************************************** 16800019
*                                                                       17000019
SETSECT  EQU   X'23'                    SET SECTOR CC MASK       20201  17100020
WRITESZ  EQU   X'04'               TYPE OF WRITE = 'SZ'                 17200019
SPANNED  EQU   X'04'               RECORD IS A SPANNED RECORD           17400019
NOT      EQU   X'FF'               CONSTANT 'FF'                        17600019
TWELVE   EQU   12                  CONSTANT '12'                        17800019
*                                                                       18000019
NULL     EQU   0                   CONSTANT '0'                         18200019
ONE      EQU   1                   CONSTANT '1'                         18400019
FOUR     EQU   4                   CONSTANT '4                          18600019
RA       EQU   10                                                       18800019
RB       EQU   11                                                       19000019
UNITCHK  EQU   X'02'                                                    19200019
*                                                                       19400019
*                                                                       19600019
*********************************************************************** 19800019
*                                                                       20000019
*   ESTABLISH REGISTERS                                                 20200019
*                                                                       20400019
*********************************************************************** 20600019
*                                                                       20800019
         BALR  RBASE,NULL          ESTABLISH                            21000019
         USING START,RBASE         BASE FOR C.E.A.                      21200019
START    EQU   *                                                        21400019
*                                                                       21600019
         SH    RIOB,KIOBPREF       (IOB ADDR) - PREFIX = IOB ADDR       21800019
         USING IOBDEF,RIOB         ESTABLISH IOB BASE                   22000019
         USING IHADCB,RDCB              ESTABLISH DCB BASE       20201  22100020
*                                                                       22200019
*********************************************************************** 22400019
         CLI   IOBCCW1,SETSECT          RPS DEVICE               20201  22420020
         BNE   NOTRPS                   NO, BRANCH               20201  22440020
         L     SGWKR,IOBCCW1            GET SECTOR AREA          20201  22460020
         MVC   NULL(ONE,SGWKR),ONE(SGWKR)  MOVE SECT BYTE FOR    20201  22480020
*                                       NEXT                     20201  22500020
*                                       WRITE                           22520020
NOTRPS   EQU   *                                                 20201  22540020
*                                                                       22600019
         TM    IOBCSW+FOUR,UNITCHK TEST UNIT CHECK                      23000019
         BO    NORMAL              BRANCH IF ON                         23200019
*                                                                       23400019
*********************************************************************** 23600019
*                                                                       23800019
         L     RDECB,IOBECBPT      LOAD ADDR OF DECB                    24000019
         USING DECBDEF,RDECB       ESTABLISH DECB BASE                  24200019
*                                                                       24400019
*********************************************************************** 24600019
*                                                                       24800019
*   DETERMINE THE TYPE OF I/O REQUEST AND IT HANDLING                   25000019
*     1. WRITE/SZ - RETURN TO +0(IOS)                                   25200019
*     2. NON-SPANNED RECORD - RETURN TO +0(IOS)                         25400019
*     3. SPANNED RECORD - FARTHER ANALYSIS                              25600019
*                                                                       25800019
*********************************************************************** 26000019
*                                                                       26200019
         TM    DECTYPE+ONE,WRITESZ TEST IF WRITE/SZ REQUEST             26400019
         BO    NORMAL              YES,GOTO IOS IMEDIATELY              26600019
*                                                                       26800019
         TM    IOBLINK,SPANNED     TEST IF SPANNED RECORD               27000019
         BO    CHKSPAN             YES, GO TO CHECK SPANNED RECORD      27200019
*                                                                       27400019
*********************************************************************** 27600019
*                                                                       27800019
NORMAL   EQU   *                                                        28000019
*                                                                       28200019
*********************************************************************** 28400019
*                                                                       28600019
*   NORMAL RETURN TO IOS  - +0(IOS)                                     28800019
*                                                                       29000019
*********************************************************************** 29200019
*                                                                       29400019
         SR    SGWKR,SGWKR         RESET REGISTER '9'                   29600019
         AH    RIOB,KIOBPREF       SET IOB TO IOS'S IOB                 29800019
*                                                                       30000019
         BR    RTNR                GO BACK TO IOS                       30200019
*                                                                       30400019
*********************************************************************** 30600019
*                                                                       30800019
*********************************************************************** 31000019
*                                                                       31200019
CHKSPAN  EQU   *                                                        31400019
*                                                                       31600019
*********************************************************************** 31800019
*                                                                       32000019
*   DETERMINE WHETHER ANY MORE I/O IS REQUIRED                          32200019
*        YES - SCHEDULE ASYNCHRONOUS EXIT ROUTINE                       32400019
*        NO  - RESET SPAN BIT AND GO BACK TO IOS                        32600019
*                                                                       32800019
*********************************************************************** 33000019
*                                                                       33200019
         SR    SGWKR,SGWKR              ZERO OUT REG 9           20201  33300020
         IC    SGWKR,DCBOFFSW           GET OFFSET TO WRT CCW    20201  33400020
         L     SGWKR,NULL(SGWKR,RIOB)   GET SEG WRK AREA ADDR    20201  33500020
         SH    SGWKR,KSGWKCB       MINUS S.W.A. CONTROL FIELD(10 BYTES) 33600019
         USING SGWKAREA,SGWKR      ESTABLISH BASE FOR SEG.WORK AREA     33800019
*                                                                       34000019
         TM    SGWKFLAG,LASTSEG    TEST IF PREVIOUS I/O WAS LAST SEG.   34200019
         BNO   ASYOUT              NO,GOTO EXIT TO ASYNCHRONOUS EXIT    34400019
*                                                                       34600019
         NI    IOBLINK,NOT-SPANNED RESET SPANNED BIT IN IOB             34800019
*                                                                       35000019
         B     NORMAL              GO BACK TO +0(IOS)                   35200019
*                                                                       35400019
*********************************************************************** 35600019
*                                                                       35800019
ASYOUT   EQU   *                                                        36000019
*                                                                       36200019
*********************************************************************** 36400019
*                                                                       36600019
*   EXIT TO EXIT EFFECTOR TO SCHEDULE ASYNCHRONOUS EXIT ROUTINE.        36800019
*        THE ROUTINE WILL ISSUE EXCP TO WRITE NEXT SEGMENT OF THE       37000019
*        RECORD                                                         37200019
*                                                                       37400019
*********************************************************************** 37600019
*                                                                       37800019
         LA    RTNR,TWELVE(RTNR)   LOAD +12(IOS) TO SCHEDULE A.S.I      38000019
         L     WKR15,CVTPTR        BY SETTING RETURN TO IGNORE AND      38200019
         USING CVT,WKR15           LOCATE EXIT EFFECTOR ADDR            38400019
         L     WKR15,CVT0EF00      FROM CVT                             38600019
*                                                                       38800019
         SR    SGWKR,SGWKR         RESET REG.9 TO '0'                   39000019
         AH    RIOB,KIOBPREF       SET IOB TO IOS'S IOB                 39200019
*                                                                       39400019
         BR    WKR15               GOTO EXIT EFFECTOR TO SCHEDULE A.S.1 39600019
*                                                                       39800019
*                                                                       46200019
*********************************************************************** 46400019
*                                                                       46600019
*                                                                       46800019
*********************************************************************** 47000019
*                                                                       47200019
*   CONSTANTS                                                           47400019
*                                                                       47600019
*********************************************************************** 47800019
*                                                                       48000019
KIOBPREF DC    H'8'                LENGTH OF IOBPREFIX                  48200019
KSGWKCB  DC    H'10'               LENGTH OF CONTROL FIELD FOR S.W.A.   48400019
*                                                                       48600019
         LTORG                                                          48800019
         EJECT                                                          49000019
**********************************************************************  49200019
*                                                                       49400019
*    CONTROL BLOCK DEFINITIONS FOLLOW                                   49600019
*                                                                       49800019
**********************************************************************  50000019
*                                                                       50200019
*   DSECT FOR CVT                                                       50400019
*                                                                       50600019
*********************************************************************** 50800019
*                                                                       51000019
CVT      DSECT                                                          51200019
*                                                                       51400019
         CVT                                                            51600019
*                                                                       51800019
         SPACE 2                                                        52000019
*                                                                       52200019
**********************************************************************  52400019
*                                                                       52600019
         DCBD  DSORG=(PS),DEVD=(DA)                                     52800019
*                                                                       53000019
*********************************************************************** 53200019
*                                                                       53400019
         SPACE 2                                                        53600019
*                                                                       53800019
DEB      DSECT                          THIS DSECT DESCRIBES A DEB      54000019
DEBNMSUB DS    0CL1                    NO. OF SUB RTNS                  54200019
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDR          54400019
DEBAMLNG DS    0CL1                    LENGTH OF ACCESS METHOD SEC      54600019
DEBDEBAD DS    CL4                     ADDR OF NEXT DEB IN DEB CHAIN    54800019
DEBOFLGS DS    0CL1                    DEB OPEN FLAGS                   55000019
DEBIRBAD DS    CL4                     ADDR OF THE IRB CONTROL BLOCK    55200019
DEBOPATB DS    0CL1                    OPEN ATRIBUTES                   55400019
DEBSYSPG DS    CL4                     SYSTEM PURGE FIELD               55600019
DEBNMEXT DS    0CL1                    NUMBER OF EXTENTS IN DEB         55800019
DEBUSRPG DS    CL4                     USER PURGE FIELD                 56000019
DEBPRIOR DS    0CL1                    INFO BYTE                        56200019
DEBECBAD DS    CL4                     EVENT CONTROL BLOCK ADDR         56400019
DEBPROTG DS    0CL1                    INFO BYTE                        56600019
DEBDEBID DS    0CL1                    INFO BYTE                        56800019
DEBDCBAD DS    CL4                     ADDR OF DCB                      57000019
DEBEXSCL DS    0CL1                    SCALING FACTOR OF DEB EXTENT     57200019
DEBAPPAD DS    CL4                     APPENDAGE TABLE ADDR             57400019
DEBDVMOD DS    0CL1                    DEVICE MODIFIER BYTE             57600019
DEBUCBAD DS    CL4                     UNIT CTL BLOCK ADDR              57800019
DEBTVLSQ DS    0CL2                    VOL SEQ FOR TAPE                 58000019
DEBBINUM DS    CL2                     BIN NUMBER                       58200019
DEBTVLNM DS    0CL2                    NO OF VOL FOR TAPE               58400019
DEBSTRCC DS    CL2                     START CYLINDER NUMBER            58600019
DEBSTRHH DS    CL2                     START HEAD NUMBER                58800019
DEBENDCC DS    CL2                     END CYLINDER NUMBER              59000019
DEBENDHH DS    CL2                     END HEAD NUMBER                  59200019
DEBNMTRK DS    CL2                     NUMBER OF TRACKS                 59400019
*  FOR ADDITIONAL EXTENT ON DIRECT ACCESS THE FOLLOWING FIELDS          59600019
*  WILL HAVE TO BE OFFSET ANOTHER 16 BYTES                              59800019
DEBVOLSQ DS    H                       VOL SEQUENCE NUMBER              60000019
DEBVOLNM DS    H                       VOLUME NUMBER                    60200019
*  FOR EACH SUBROUTINE LOADED BUMP THIS OFFSET BY 2                     60400019
DEBSUBID DS    H                       SUBROUTINE ID ( 2 BYTES )        60600019
*                                                                       60800019
*********************************************************************** 61000019
*                                                                       61200019
         SPACE 2                                                        61400019
*********************************************************************** 61600019
*                                                                       61800019
IOBDEF   DSECT           I/O BLOCK DEFINITION                           62000019
IOBLINK  DS    F         IOB LINK ADDRESS                               62200019
IOBIOBA  DS    F         IOB ADDRESS FOR EOV                            62400019
IOBFLAG1 DS    CL1       ERROR FLAG 1                                   62600019
IOBFLAG2 DS    CL1       ERROR FLAG 2                                   62800019
IOBSENSE DS    CL2       I/O SENSE BITS                                 63000019
IOBECBPT DS    F         ECB ADDRESS                                    63200019
IOBCSW   DS    D         CSW STORED BY IOS                              63400019
IOBSIOCC DS    0BL1      SIO CONDITION CODE                             63600019
IOBSTART DS    F         CHANNEL PROGRAM STARTING CCW                   63800019
IOBDCBPT DS    F         DCB ADDRESS                                    64000019
IOBRESTR DS    F         CHANNEL PROGRAM RESTART ADDRESS                64200019
IOBINCAM DS    CL2       BLOCK INCREMENT AMOUNT                         64400019
IOBERRCT DS    CL2       ERROR COUNTS                                   64600019
IOBSEEK  DS    D         SEEK ADDRESS                                   64800019
IOBDNRCF DS    D         NEW RECORD COUNT FIELD                         65000019
IOBR0CNT DS    D         COUNT FIELD OF R0                              65200019
IOBR0DAT DS    D         DATA FIELD OF R0                               65400019
IOBCCW1  DS    D         FIRST CCW OF CHANNEL PROGRAM                   65600019
IOBCCW2  DS    D         2ND CCW OF CHANNEL PROGRAM                     65800019
IOBCCW3  DS    D         3RD CCW OF CHANNEL PROGRAM                     66000019
IOBCCW4  DS    D         4TH CCW OF CHANNEL PROGRAM                     66200019
IOBCCW5  DS    D         5TH CCW OF CHANNEL PROGRAM                     66400019
IOBCCW6  DS    D         6TH CCW OF CHANNEL PROGRAM                     66600019
IOBCCW7  DS    D         7TH CCW OF CHANNEL PROGRAM                     66800019
IOBCCW8  DS    D         8TH CCW OF CHANNEL PROGRAM                     67000019
IOBCCW9  DS    D         9TH CCW OF CHANNEL PROGRAM                     67200019
IOBCCW10 DS    D         10TH CCW OF CHANNEL PROGRAM                    67400019
IOBCCW11 DS    D         11TH CCW OF CHANNEL PROGRAM                    67600019
IOBCCW12 DS    D         12TH CCW OF CHANNEL PROGRAM                    67800019
IOBCCW13 DS    D         13TH CCW OF CHANNEL PROGRAM                    68000019
IOBCCW14 DS    D         LAST CCW OF LONGEST CHANNEL PROGRAM            68200019
*                                                                       68400019
OFFTOMAX EQU   IOBCSW-IOBDEF                                            68600019
OFFTONEW EQU   IOBCSW+FOUR-IOBDEF                                       68800019
*                                                                       69000019
         SPACE 2                                                        69200019
**********************************************************************  69400019
*                                                                       69600019
*  DSECT FOR DECB                                                       69800019
*                                                                       70000019
*********************************************************************** 70200019
DECBDEF  DSECT           DATA EVENT CONTROL BLOCK                       70400019
DECSDECB DS    F         STANDARD ECB                                   70600019
DECTYPE  DS    CL2       TYPE AND OPTIONS                               70800019
DECLNGTH DS    CL2       DATA LENGTH                                    71000019
DECDCBAD DS    F         DCB ADDRESS                                    71200019
DECAREA  DS    F         AREA ADDRESS                                   71400019
DECIOBPT DS    F         IOB ADDRESS                                    71600019
DECNEXT  DS    F         NEXT ADDRESS                                   71800019
         SPACE 2                                                        72000019
*********************************************************************** 72200019
*                                                                       72400019
         SPACE 3                                                        72600019
*                                                                       72800019
*********************************************************************** 73000019
*                                                                       73200019
*   DSECT FOR SEGMENT WORK AREA CONTROL BLOCK - 8 BYTES                 73400019
*                                                                       73600019
*********************************************************************** 73800019
*                                                                       74000019
SWACB    DSECT                                                          74200019
*                                                                       74400019
SWACBPTR DS    AL4                 POINTER TO THE 1ST SEG. WORK AREA    74600019
SWACBNO  DS    H                   NUMBER OF SEGMENT WORK AREAS         74800019
SWACBLNG DS    H                   LENGTH OF A SEGMENT WORK AREA        75000019
SWACBTT  DS    H                   TT OF THIS VOLUME RELATIVE TO THE    75200019
*                                  BEGINNING OF DATA SET                75400019
         DS    H                   NOT USED                             75600019
*                                                                       75800019
         SPACE 3                                                        76000019
*                                                                       76200019
*********************************************************************** 76400019
*                                                                       76600019
*   DSECT FOR SEGMENT WORK AREA                                         76800019
*                                                                       77000019
*********************************************************************** 77200019
*                                                                       77400019
SGWKAREA DSECT                                                          77600019
*                                                                       77800019
SGWKPTR  DS    AL4                 POINTER TO NEXT SEG WORK AREA        78000019
SGWKRCRD DS    AL4                 POINTER TO RECORD AREA               78200019
*                                                                       78400019
SGWKFLAG EQU   SGWKRCRD            FLAG BYTES                           78600019
*                                                                       78800019
SPANVLM  EQU   X'80'               SPAN VOLUME                          79000019
LASTSEG  EQU   X'40'               LAST SEGMENT WAS WRITTEN             79200019
*                                                                       79400019
SGWKOFF  DS    H                   OFFSET OF THE CURRENT SEGMENT        79600019
SGWKDATA DS    0H                  SEGMENT AREA                         79800019
*                                                                       80000019
         SPACE 3                                                        80200019
*                                                                       80400019
*********************************************************************** 80600019
*                                                                       80800019
*   DSECT FOR DASD DEVICE CHARACTERISTIC TABLE                          81000019
*                                                                       81200019
*********************************************************************** 81400019
*                                                                       81600019
DASDTBL  DSECT                                                          81800019
*                                                                       82000019
DASDCYL  DS    H                   NO. OF CYLINDERS                     82200019
DASDTRK  DS    H                   NO. OF TRACKS/CYLINDER               82400019
DASDLNGH DS    H                   TRACK LENGTH                         82600019
DASDINTR DS    AL1                 OVERHEAD FOR INTERMEDIATE RECORD     82800019
DASDLAST DS    AL1                 OVERHEAD FOR LAST RECORD             83000019
DASDKEY  DS    AL1                 OVERHEAD FOR KEY                     83200019
DASDFLAG DS    AL1                 FLAGS                                83400019
*                                                                       83600019
BYTEMODE EQU   X'02'               MBBCCHHR IS BY BYTE (2321)           83800019
TOLERANC EQU   X'01'               TOLERANCE FACTOR MUST BE ADDED       84000019
*                                                                       84200019
DASDTOL  DS    AL2                 TOLERANCE FACTOR                     84400019
*                                                                       84600019
         SPACE 2                                                        84800019
         END                                                            85000019
