IGG019DB CSECT                                                          00006000
*          RELEASE 16 DELETIONS                                         00012000
*2080                                                             12748 00013016
*2080                                                             12987 00015016
*          RELEASE 17 DELETIONS                                         00018000
*          RELEASE 18 DELETIONS                                         00024000
*          RELEASE 19 DELETIONS                                         00030000
*          RELEASE 20 DELETIONS                                         00036000
*          RELEASE 21 DELETIONS                                         00042000
*0833                                                            A46868 00045021
*          RELEASE 22 DELETIONS                                         00048000
*          RELEASE 23 DELETIONS                                         00054000
*          RELEASE 24 DELETIONS                                         00060000
*STATUS CHANGE LEVEL 003                                                00070016
 TITLE   'IGG019DB - WRITE FORMAT V,U, LOAD MODE'                       00080000
*FUNCTIONS- THIS ROUTINE OBTAINS AN IOB, INITIALIZES THE CHANNEL        00100000
*    PROGRAM, AND ISSUES THE 'EXCP' FOR A WRITE TYPE SF OR SZ TO A      00120000
*    FORMAT 'V' OR 'U' DATA SET.                                        00140000
*    IF THIS WRITE IS FOR A RECORD WHICH WILL NOT FIT ON THIS TRACK,    00160000
*    A RETURN CODE OF 4 WILL BE RETURNED AND THE USER SHOULD NEXT ISSUE 00180000
*    A WRITE TYPE 'SZ'. THIS WILL CAUSE THE CAPACITY RECORD TO BE       00200000
*    WRITTEN ON THE CURRENT TRACK.                                      00220000
*    IF A TYPE 'SZ' IS ISSUED AND THERE HAVE BEEN NO RECORDS WRITTEN    00240000
*    ON THIS TRACK, THE CAPACITY RECORD WILL BE WRITTEN AND AN ERASE    00260000
*    CCW INCLUDED TO CLEAR THE REMAINDER OF THE TRACK.                  00280000
*                                                                       00300000
*ENTRY POINTS- 'WRTENTRY' IS THE NORMAL ENTRY POINT FROM THE WRITE      00320000
*    MACRO EXPANSION. CALLING SEQUENCE IS     L     15,DCBWRITE         00340000
*                                             BALR  14,15               00360000
*                                                                       00380000
*    'EOVENTRY' IS THE ENTRY FROM THE BSAM END-OF-VOLUME EXECUTOR TO    00400000
*    RESTART A WRITE WHICH WAS ISSUED AFTER THE CURRENT SPACE           00420000
*    ALLOCATION WAS FILLED. THE RECORD WILL NOW BE WRITTEN INTO THE     00440000
*    SPACE OBTAINED AS SECONDARY ALLOCATION. CALLING SEQUENCE IS        00460000
*                                              L    15,DCBWRITE         00480000
*                                              BAL  14,4(15)            00500000
*INPUT- TO 'WRTENTRY'- DECB ADDRESS IN REGISTER 1                       00520000
*       TO 'EOVENTRY'- IOB ADDRESS IN REGISTER 3                        00540000
*                      DCB ADDRESS IN REGISTER 2                        00560000
*                      DEB ADDRESS IN REGISTER 5                        00580000
*                                                                       00600000
*OUTPUT- AN IOB FROM THE POOL OF IOBS WILL BE ASSIGNED TO THIS DECB     00620000
*    AND ITS ADDRESS PLACED IN THE DECB, EXCP WILL BE ISSUED TO         00640000
*    SCHEDULE THIS WRITE.                                               00660000
*                                                                       00680000
*EXTERNAL ROUTINES-                                                     00700000
*                                                                       00720000
*EXITS- 'RETURN' IS AN EXIT BACK TO THE USER, REGISTER 15 WILL CONTAIN  00740000
*    A RETURN CODE AS FOLLOWS,                                          00760000
*        0 = RECORD WAS WRITTEN, THERE IS MORE SPACE ON THE TRACK       00780000
*        4 = RECORD NOT WRITTEN, THE TRACK IS FILLED, TYPE SZ SHOULD BE 00800000
*            ISSUED AND THEN THE TYPE SF MAY BE REISSUED.               00820000
*        8 = RECORD WAS WRITTEN, DATA SET IS FILLED                     00840000
*        12= RECORD NOT WRITTEN, NO IOB IS AVAILABLE UNTIL 'CHECK' HAS  00860000
*            BEEN ISSUED.                                               00880000
*    'EOVEXIT' IS A RETURN TO THE END-OF-VOLUME EXECUTOR.               00900000
*                                                                       00920000
*    'ABEXIT' IS AN ABENDT WHEN THE RECORD WILL NOT FIT ON AN EMPTY     00940000
*      TRACK. THE ERROR CODE RETURNED IS X'00002000'                    00960000
*                                                                       00980000
*TABLES  1. DIRECT ACCESS DEVICE TABLE IS USED TO CALCULATE THE BYTES   01000000
*           OF OVERHEAD FOR THIS RECORD AND TO DETERMINE THE NEXT       01020000
*           VALID TRACK ADDRESS AND TRACK LENGTH.                       01040000
*                                                                       01060000
*ATTRIBUTES- THIS ROUTINE IS REENTRANT AND EXECUTED ENABLED.            01080000
*                                                                       01100000
*NOTES- THE REGISTER USAGE IN THIS MODULE AND THE BSAM END-OF-VOLUME    01120000
*    EXECUTOR MUST REMAIN CONSISTENT.                                   01140000
*                                                                       01160000
*                                                                       01180000
*  REGISTER USAGE                                                       01200000
*                                                                       01220000
         USING IGG019DB,EPREG                                           01240000
         USING IHADCB,DCBREG                                            01260000
         USING IOBDEF,IOBREG                                            01280000
         USING DEB,DEBREG                                               01300000
         USING DECBDEF,DECBREG                                          01320000
*                                                                       01340000
WKREG    EQU   0         WORK REGISTER                                  01360000
PARAM1   EQU   1         PARAMETER REGISTER                             01380000
DECBREG  EQU   1         DECB ADDRESS                                   01400000
DCBREG   EQU   2         DCB ADDRESS                                    01420000
IOBREG   EQU   3         IOB ADDRESS                                    01440000
EOVRETRN EQU   4         EOV RETURN ADDRESS                             01460000
DEBREG   EQU   5         DEB ADDRESS                                    01480000
WKREG1   EQU   6         WORK REGISTERS                                 01500000
WKREG2   EQU   7                                                        01520000
WKREG3   EQU   8                                                        01540000
WKREG4   EQU   9                                                        01560000
CCHH     EQU   9                                                        01580000
WKREG5   EQU   10                                                       01600000
WKREG6   EQU   11                                                       01620000
BASE     EQU   12        BASE OF THIS MODULE                            01640000
SAVE     EQU   13        USER'S SAVE AREA                               01660000
RETREG   EQU   14        RETURN ADDRESS WHEN ENTERED                    01680000
EPREG    EQU   15        ENTRY POINT                                    01700000
*                                                                       01720000
*                                                                       01740000
*                                                                       01760000
*                                                                       01780000
*  ENTRY POINTS TO THIS ROUTINE                                         01800000
*                                                                       01820000
WRTENTRY B     BEGIN                   GO TO BEGINNING OF WRITE CODE    01840000
*                                                                       01860000
         DROP  EPREG                                                    01880000
         USING IGG019DB,BASE                                            01900000
*                                                                       01920000
EOVENTRY L     DECBREG,IOBECBPT        LOAD DECB BASE ADDRESS           01940000
         L     BASE,DCBWRITE           SET BASE REGISTER                01960000
         LR    EOVRETRN,RETREG         MOVE RETURN TO EOV ADDRESS       01980000
         B     TSTSZ                   GO DETERMINE TYPE OF WRITE       02000000
*                                                                       02020000
*                                                                       02040000
BEGIN    SAVE  (14,12)                 SAVE THE USER'S REGISTER         02060000
         L     DCBREG,DECDCBAD         LOAD DCB BASE ADDRESS FROM DECB  02080000
         L     DEBREG,DCBDEBAD         LOAD DEB BASE ADDRESS FROM DCB   02100000
         LR    BASE,EPREG              MOVE ENTRY POINT TO BASE REG.    02120000
         L     IOBREG,DCBIOBA          LOAD CURRENT IOB ADDRESS         02140000
         TS    IOBLINK+4               IS CURRENT IOB AVAILABLE         02160000
         BC    8,OKIOB                 BR YES (PREV RCD DIDN'T FIT TRK) 02180000
*                                                                       02200000
         L     IOBREG,IOBLINK          LOAD ADDRESS OF NEXT IOB         02220000
         TS    IOBLINK+4               IF NEXT IOB IS AVAILABLE         02240000
         BC    8,OKIOB                  GO INITIALIZE IT                02260000
*                                      ELSE RETURN WITH ERROR CODE 12   02280000
         LA    15,12                                                    02300000
         B     RETURN                                                   02320000
*                                                                       02340000
*                                                                       02360000
USEBLKS  LH    WKREG4,DCBBLKSI         USE MAXIMUM LENGTH AS DATA LNG   02380000
         B     ADDKEY                   GO ADD KEY LENGTH               02400000
*                                                                       02420000
USELL    LA    WKREG4,0(WKREG1,WKREG3) FIND THE FIRST TWO BYTES OF THE  02440000
         MVC   IOBCSW(2),0(WKREG4)      USER'S RECORD, ALIGN THEM,      02460000
         LH    WKREG4,IOBCSW            USE AS DATA LENGTH.             02480000
         B     ADDKEY                  GO ADD KEY LENGTH                02500000
*                                                                       02520000
*                                                                       02540000
OKIOB    ST    IOBREG,DCBIOBA          STORE CURRENT IOB ADDRESS IN DCB 02560000
         LA    WKREG,8(0,IOBREG)       STORE ADDRESS OF IOS IOB IN      02580000
         ST    WKREG,DECIOBPT            THE DECB                       02600000
         ST    DECBREG,IOBECBPT        STORE DECB ADDRESS IN IOB        02620000
         TM    DCBCIND1,VOLFUL          IS THE VOLUME FULL YET   A46868 02625021
         BO    POSTEOV                  YES, SET EOV BIT AND     A46868 02630021
*                                       RETURN                   A46868 02635021
TSTSZ    TM    DECTYPE+1,WZERO         IS THIS A WRITE R0 REQUEST       02640000
         BC    1,WZERORTN               YES, GO TO WZERO ROUTINE        02660000
         LA    WKREG,IOBCCW1           BE SURE IOBSTART IS              02680000
         ST    WKREG,IOBSTART           RESET TO CCW1                   02700000
*                                                                       02720000
         SR    WKREG1,WKREG1           INSERT KEY LENGTH FROM THE DCB   02740000
         IC    WKREG1,DCBKEYLE          (MAY BE ZERO)                   02760000
         L     WKREG3,DECAREA          LOAD ADDRESS OF OUTPUT AREA      02780000
TSTV     TM    DCBRECFM,UNKWN          IF FORMAT IS VARIABLE            02800000
         BC    8,USELL                  GO USE LL FROM RECORD           02820000
         TM    DECTYPE,SOPT     IF THE OPTION TO USE DCBBLOCK SIZE 6991 02840000
         BC    1,USEBLKS                WAS SPECIFIED, GO USE IT        02860000
         LH    WKREG4,DECLNGTH         USE DECB LENGTH AS DATA LENGTH   02880000
*                                                                       02900000
ADDKEY   LA    WKREG2,0(WKREG1,WKREG4) ADD KEY LENGTH + DATA LENGTH     02920000
         STH   WKREG4,IOBDNRCF+6       STORE DATA LNG IN NEW COUNT FLD  02940000
         LTR   WKREG2,WKREG2           TEST IF ANY BYTES ARE WRITTEN    02960000
         BC    7,REALRITE              YES GO ON                        02980000
         NI    IOBCCW3+4,X'BF'          TURN OFF COMMAND CHAIN BIT      03000000
         B     *+8                                                      03020000
REALRITE EQU   *                                                        03040000
         OI    IOBCCW3+4,CCHN          TURN ON COMMAND CHAIN BIT        03060000
         MVC   IOBCCW4+1(3),DECAREA+1  MOVE AREA TO WRITE CCW ADDRESS   03080000
         STH   WKREG2,IOBCCW4+6        STORE KL+DL IN WRITE CCW COUNT   03100000
*                                                                       03120000
*                                                                       03140000
*  CALCULATE RECORD LENGTH PLUS OVERHEAD                                03160000
*                                                                       03180000
CALCLGN  L     WKREG3,DCBDVTBL         LOAD ADDR. OF DADT ENTRY         03200000
         SR    WKREG,WKREG             IF NO KEYS ARE BEING WRITTEN,    03220000
         CLI   DCBKEYLE,0               WKREG WILL CONTAIN THE OVERHEAD 03240000
         BC    7,*+8                     TO BE SUBTRACTED               03260000
         IC    WKREG,OVERK(0,WKREG3)     FOR UNKEYED RECORDS            03280000
         SR    WKREG5,WKREG5                                            03300000
         IC    WKREG5,OVERL(0,WKREG3)  DEVELOP BYTES NEEDED FOR A       03320000
         AR    WKREG5,WKREG2               LAST RECORD BY               03340000
         SR    WKREG5,WKREG                KL+DL+OVERHEAD.              03360000
*                                                                       03380000
         SR    WKREG6,WKREG6              DEVELOP BYTES NEEDED FOR AN   03400000
         IC    WKREG6,OVERI(0,WKREG3)      INTERMEDIATE RECORD BY       03420000
         MH    WKREG2,TOLER(0,WKREG3)       (KL+DL)TOLER+OVERHEAD       03440000
         SRL   WKREG2,9                                                 03460000
         AR    WKREG6,WKREG2                                            03480000
         SR    WKREG6,WKREG                                             03500000
*                              WKREG5 = SIZE OF A LAST RECORD ON TRACK  03520000
*                              WKREG6 = SIZE OF AN INTERMEDIATE RECORD  03540000
*                                                                       03560000
*                                                                       03580000
         TM    DCBCIND2,WZEROBIT       WAS PREVIOUS WRITE A WRITE R0    03600000
         BC    1,WZEROFF                YES, GO INCREMENT TO NEXT TRACK 03620000
*                                                                       03640000
         CH    WKREG5,DCBTRBAL         DOES RECORD FIT AS LAST ON TRACK 03660000
         BC    2,FULLTRK                NO, USE RETURN CODE OF 4        03680000
*                                                                       03700000
*   UPDATE DCB FIELDS                                                   03720000
*                                                                       03740000
FITS     LH    WKREG3,DCBTRBAL         DECREMENT TRACK BALANCE BY       03760000
         SR    WKREG3,WKREG6            THE SIZE OF AN                  03780000
         STH   WKREG3,DCBTRBAL          INTERMEDIATE RECORD             03800000
         MVC   IOBSEEK(8),DCBFDAD      MOVE PRIOR RECORD AS SEARCH ARG  03820000
         IC    WKREG3,DCBFDAD+7        INCREMENT THE R BYTE             03840000
         LA    WKREG3,1(0,WKREG3)       OF MBBCCHHR                     03860000
         STC   WKREG3,DCBFDAD+7         BY ONE                          03880000
         MVC   IOBDNRCF(5),DCBFDAD+3   MOVE CURRENT CCHHR TO NEW COUNT  03900000
*                                                                       03920000
         BAL   WKREG1,EXCP             GO SCHEDULE THIS WRITE AND       03940000
*                                       TEST FOR ENTRY FROM EOV         03960000
*                                                                       03980000
NORMAL   SR    15,15                                                    04000000
*                                                                       04020000
RETURN   RETURN (14,12),T,RC=(15)      RETURN TO THE USER               04040000
*                                                                       04060000
*                                                                       04080000
*                                                                       04100000
SETEOV   OI    DCBCIND1,VOLFUL         MARK DCB SO FUTURE REQ.S BYPASS  04120000
         BCTR  WKREG3,0                 RESTORE DCBFDAD           12987 04126016
         STC   WKREG3,DCBFDAD                                     12987 04132016
POSTEOV  OI    IOBLINK,EOVBIT          MARK IOB AS NOT SCHEDULED BY IOS 04140000
         B     NORMAL                  RETURN TO THE USER               04160000
*                                                                       04180000
*  WRITE ZERO ROUTINE                                                   04200000
*                                                                       04220000
WZERORTN LA    WKREG1,IOBCCW5          RESET START ADDR. TO SEARCH R0   04240000
         TM    DCBOPTCD,WRTCHK          CCW. IF WRITE CHECK IS NOT      04260000
         BC    8,SETCCHN                SPECIFIED ADDRESS IS CCW5       04280000
         LA    WKREG1,IOBCCW8           ELSE START ADDRESS IS CCW8      04300000
SETCCHN  OI    20(WKREG1),CCHN          TURN ON VERIFY COMMAND CHAIN    04320000
         OI    44(WKREG1),CCHN           AND ERASE COMMAND CHAIN        04340000
         ST    WKREG1,IOBSTART          STORE STARTING ADDRESS IN IOB   04360000
         TM    DCBCIND2,WZEROBIT       SHOULD THIS WRITE ERASE TRACK    04380000
         BC    1,UPTRACK                YES, GO INCREMENT TRACK NUMBER  04400000
         CLI   DCBFDAD+7,0             FIRST WRITE MAY BE TO WRITE R0   04420000
         BC    8,TURNONR0               IF SO, ERASE TRACK ONE          04440000
         NI    44(WKREG1),X'30'         TURN OFF ERASE COMMAND CHAIN    04460000
         TM    DCBOPTCD,WRTCHK          IS WRITE CHECK SPECIFIED        04480000
         BC    1,TURNONR0                YES, GO SET UP TO WRITE.  NO,  04500000
         NI    20(WKREG1),X'30'         TURN OFF VERIFY COMMAND CHAIN   04520000
*                                                                       04540000
TURNONR0 MVC   IOBR0CNT(4),DCBFDAD+3   MOVE CCHH0 TO R0 COUNT           04560000
         MVC   IOBR0DAT(5),DCBFDAD+3   MOVE CCHHR AS HIGHEST ID ON TRK  04580000
         MVC   IOBR0DAT+5(2),DCBTRBAL  MOVE TRBAL AS BYTES REMAINING    04600000
         MVC   IOBSEEK,DCBFDAD         MOVE CURRENT ADDR AS SEEK ADDR   04620000
         OI    DCBCIND2,WZEROBIT       SET- LAST I/O WAS A WRITE R0 BIT 04640000
*                                                                       04660000
         BAL   WKREG1,EXCP             GO SCHEDULE THIS WRITE AND       04680000
*                                       TEST FOR ENTRY FROM EOV         04700000
*                                                                       04720000
         SR    WKREG2,WKREG2           FIND LAST EXTENT IN THE DEB      04740000
         IC    WKREG2,DEBNMEXT          BY NUMBER OF EXTENTS            04760000
         BCTR  WKREG2,0                  MINUS ONE                      04780000
         SLL   WKREG2,4                 TIMES 16                        04800000
         AR    WKREG2,DEBREG            PLUS DEB BASE ADDRESS           04820000
         CLC   DCBFDAD+3(4),DEBENDCC-DEB(WKREG2)  IS THIS LAST TRACK    04840000
         BC    7,NORMAL                 NO, USE RETURN CODE OF 0        04860000
*                                                                       04880000
EOV      LA    15,8          SET RETURN CODE-LAST TRACK WRITTEN         04900000
         B     RETURN         GO BACK TO THE USER                       04920000
*                                                                       04940000
*                                                                       04960000
FULLTRK  MVI   IOBLINK+4,0             MARK THIS IOB AVAILABLE AGAIN    04980000
         LA    15,4                    SET RETURN CODE-TRACK IS FULL    05000000
         B     RETURN                  GO BACK TO THE USER              05020000
*                                                                       05040000
*                                                                       05060000
*   INCREMENT TRACK ADDRESS BY 1 AND CHECK VALIDITY                     05080000
*                                                                       05100000
WZEROFF  XI    DCBCIND2,WZEROBIT       TURN OFF WRITE R0 FLAG           05120000
UPTRACK  L     WKREG1,DCBDVTBL         LOAD ADDRESS OF DADT ENTRY       05140000
         MVC   IOBCSW(4),MAXCC(WKREG1) MOVE NO. OF CYL.S, TRACKS TO IOB 05160000
         MVC   IOBCSW+4(4),DCBFDAD+3   MOVE CURRENT CCHH FOR ALIGNMENT  05180000
         MVC   DCBTRBAL,TRKL(WKREG1)   RESET TRACK BALANCE TO FULL AMT  05200000
         SR    WKREG2,WKREG2                                            05220000
         IC    WKREG2,DCBFDAD          DEVELOP POINTER TO CURRENT       05240000
         SLL   WKREG2,4                 EXTENT IN THE DEB               05260000
         AR    WKREG2,DEBREG                                            05280000
         LA    IOBREG,0(0,IOBREG)      BE SURE HI-ORDER BYTE IS ZERO    05300000
         LA    WKREG3,3(0,IOBREG)       SET CCHH VALUE TO HH      12748 05320016
         L     CCHH,IOBCSW+4           LOAD CURRENT CCHH TO AN ACCUM.   05340000
         TM    BYTEDEV(WKREG1),BYTE     ARE BYTES NON-CONTIGUOUS  12748 05346016
         BZ    DOWNONE                  BRANCH IF CONTIGUOUS      12748 05352016
ADDONE   AH    CCHH,ONE                ADD ONE TO THE LO-ORDER BYTE     05360000
         TM    BYTEDEV(WKREG1),BYTE    ARE BYTES NON-CONTIGUOUS         05380000
         BC    1,USEBYTE                YES, TREAT EACH SEPARATELY      05400000
         STH   CCHH,IOBCSW+4-IOBDEF(0,WKREG3)     STORE NEW CC OR HH    05420000
         CLC   IOBCSW+4-IOBDEF(2,WKREG3),IOBCSW-IOBDEF(WKREG3)          05440000
*                                                 CHECK FOR VALID VALUE 05460000
         BC    4,TSTEXT                ADDRESS VALID, CHECK EXTENT      05480000
         SRL   CCHH,16                 SHIFT TO CC VALUE                05500000
         XC    IOBCSW-IOBDEF+4(2,WKREG3),IOBCSW-IOBDEF+4(WKREG3)  12748 05520016
*        ZERO THE BYTES PROCESSED                                 12748 05540016
*                                                OF CCHH                05560000
         BCTR  WKREG3,0                DECREMENT THE CCHH INDEX         05580000
DOWNONE  BCTR  WKREG3,0                                                 05600000
         CR    WKREG3,IOBREG           HAVE ALL BYTES BEEN PROCESSED    05620000
         BC    10,ADDONE                NO, LOOP TO ADD ONE TO NEXT BYT 05640000
*                                                                       05660000
NEXTEXT  IC    WKREG3,DCBFDAD          INCREMENT M AND SEE IF THIS WAS  05680000
         LA    WKREG3,1(0,WKREG3)       THE LAST EXTENT.                05700000
         STC   WKREG3,DCBFDAD                                           05720000
         CLC   DCBFDAD(1),DEBNMEXT                                      05740000
         BC    8,SETEOV                 YES, GO SET EOV BIT             05760000
*                                                                       05780000
         LA    WKREG2,16(0,WKREG2)     INCREMENT TO NEXT EXTENT         05800000
         MVC   DCBFDAD+1(6),DEBBINUM-DEB(WKREG2) MOVE BBCCHH TO DCB     05820000
RESETBAL MVI   DCBFDAD+7,0             MOVE A ZERO TO R BYTE            05840000
         TM    DECTYPE+1,WZERO         THIS A WRITE ZERO REQUEST        05860000
         BC    1,TURNONR0               YES GO TO SET UP FOR WRITE R0   05880000
         CH    WKREG5,DCBTRBAL         WILL THE NEW TRACK HOLD ONE RCD. 05900000
         BC    12,FITS                  YES, GO UPDATE DCB              05920000
         L     1,ABCODE                                                 05940000
ABEXIT   ABEND (1),DUMP                                            6486 05960000
*                                                                       05980000
USEBYTE  STC   CCHH,IOBCSW+4-IOBDEF(0,WKREG3) STORE AND           12748 06000016
         SRL   CCHH,8                   SHIFT TO THE NEXT ONE           06020000
         CLC   IOBCSW+4-IOBDEF(1,WKREG3),IOBCSW-IOBDEF(WKREG3)    12748 06040016
*                                               THIS BYTE VALID         06060000
         BC    4,TSTEXT                YES, GO CHECK EXTENT LIMIT       06080000
         MVI   IOBCSW+4-IOBDEF(WKREG3),0  ZERO INVALID BYTE       12748 06100016
         BC    15,DOWNONE               GO LOOK AT THE NEXT ONE         06120000
*                                                                       06140000
TSTEXT   CLC   IOBCSW+4(4),DEBENDCC-DEB(WKREG2) ADDRESS WITHIN EXTENT   06160000
         BC    2,NEXTEXT               NO, SEE IF THERE'S ANOTHER EXT   06180000
         MVC   DCBFDAD+3(4),IOBCSW+4   YES, MOVE NEW CCHH TO DCB        06200000
         BC    15,RESETBAL              AND GO RESET TRACK BALANCE      06220000
*                                                                       06240000
*                                                                       06260000
EXCP     EQU   *                                                        06280000
         LA    PARAM1,8(0,IOBREG)      SET IOS IOB PARAMETER            06300000
         EXCP  (1)                                                      06320000
*                                                                       06340000
*                                                                       06360000
EOVTST   TM    IOBLINK,EOVBIT          IF ENTERED BY A WRITE MACRO      06380000
         BCR   8,WKREG1                 RETURN TO THE BAL+4             06400000
*                                                                       06420000
         NI    IOBLINK,NOTEOV                                           06440000
EOVEXIT  EQU   *                                                        06460000
         BR    EOVRETRN                 ELSE RETURN TO EOV              06480000
         EJECT                                                          06500000
*                                                                       06520000
ONE      DC    H'1'      CONSTANT ONE                                   06540000
         DS    0F                                                       06560000
ABCODE   DC    AL1(128)                DUMP OPTION                      06580000
         DC    XL3'002000'             BLOCK WILL NOT FIT ON ONE TRACK  06600000
CCHN     EQU   X'40'     COMMAND CHAIN FLAG                             06620000
SILI     EQU   X'20'     SUPPRESS INCORRECT LENGTH FLAG                 06640000
WRTCHK   EQU   X'80'     WRITE CHECK OPTION                             06660000
UNKWN    EQU   X'80'     UNKNOWN FORMAT                                 06680000
NOTEOV   EQU   X'7F'     ALL BITS EXCEPT EOV FLAG                       06700000
SOPT     EQU   X'80'          LENGTH CODED AS 'S'                  6991 06720000
WZERO    EQU   X'04'     TYPE WRITE R0                                  06740000
WZEROBIT EQU   X'40'     LAST I/O WAS WRITE R0                          06760000
EOVBIT   EQU   X'80'     THIS WRITE NOT SCHEDULED BECAUSE OF EOV        06780000
VOLFUL   EQU   X'20'     VOLUME FULL BIT                                06800000
*                                                                       06820000
*      DIRECT ACCESS DEVICE TABLE DEFINITION                            06840000
BYTE     EQU   2         BYTES OF  CCHH ARE NON-CONTIGUOUS              06860000
OVERK    EQU   8         OFFSET TO KEY OVERHEAD                         06880000
OVERI    EQU   6                   INTERMEDIATE RECORD OVERHEAD         06900000
OVERL    EQU   7                   LAST RECORD OVERHEAD                 06920000
TOLER    EQU   10                  TOLERANCE FACTOR                     06940000
TRKL     EQU   4                   BYTES ON TRACK                       06960000
MAXCC    EQU   0                   NO. OF CYLINDERS, TRACKS             06980000
BYTEDEV  EQU   9                   FLAG, BYTES ARE NON-CONTIGUOUS       07000000
*                                                                       07020000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   07040000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   07060000
*                                                                       07080000
*                                                                       07100000
**********************************************************************  07120000
*                                                                       07140000
*    CONTROL BLOCK DEFINITIONS FOLLOW                                   07160000
         DCBD  DSORG=(PS),DEVD=(DA)                                     07180000
*                                                                       07200000
**********************************************************************  07220000
*                                                                       07240000
DECBDEF  DSECT     DATA EVENT CONTROL BLOCK                             07260000
DECSDECB DS    F         STANDARD ECB                                   07280000
DECTYPE  DS    CL2       TYPE AND OPTIONS                               07300000
DECLNGTH DS    CL2       DATA LENGTH                                    07320000
DECDCBAD DS    F         DCB ADDRESS                                    07340000
DECAREA  DS    F         AREA ADDRESS                                   07360000
DECIOBPT DS    F         IOB ADDRESS                                    07380000
DECKYADR DS    F                                                        07400000
DECOFSET DS    CL2                                                      07420000
DECRESPN DS    CL1                                                      07440000
         SPACE 2                                                        07460000
*                                                                       07480000
**********************************************************************  07500000
*                                                                       07520000
         SPACE 2                                                        07540000
IOBDEF   DSECT      I/O BLOCK DEFINITION                                07560000
IOBLINK  DS    F         IOB LINK ADDRESS                               07580000
IOBIOBA  DS    F         IOB ADDRESS FOR EOV                            07600000
IOBFLAG1 DS    CL1       ERROR FLAG 1                                   07620000
IOBFLAG2 DS    CL1       ERROR FLAG 2                                   07640000
IOBSENSE DS    CL2       I/O SENSE BITS                                 07660000
IOBECBPT DS    F         ECB ADDRESS                                    07680000
IOBCSW   DS    D         CSW STORED BY IOS                              07700000
IOBSIOCC DS    0BL1      SIO CONDITION CODE                             07720000
IOBSTART DS    F         CHANNEL PROGRAM STARTING CCW                   07740000
IOBDCBPT DS    F         DCB ADDRESS                                    07760000
IOBRESTR DS    F         CHANNEL PROGRAM RESTART ADDRESS                07780000
IOBINCAM DS    CL2       BLOCK INCREMENT AMOUNT                         07800000
IOBERRCT DS    CL2       ERROR COUNTS                                   07820000
IOBSEEK  DS    D         SEEK ADDRESS                                   07840000
IOBDNRCF DS    D         NEW RECORD COUNT FIELD                         07860000
IOBR0CNT DS    D         COUNT FIELD OF R0                              07880000
IOBR0DAT DS    D         DATA FIELD OF R0                               07900000
IOBCCW1  DS    D         FIRST CCW OF CHANNEL PROGRAM                   07920000
IOBCCW2  DS    D                                                        07940000
IOBCCW3  DS    D                                                        07960000
IOBCCW4  DS    D                                                        07980000
IOBCCW5  DS    D                                                        08000000
IOBCCW6  DS    D                                                        08020000
IOBCCW7  DS    D                                                        08040000
IOBCCW8  DS    D                                                        08060000
IOBCCW9  DS    D                                                        08080000
IOBCCW10 DS    D                                                        08100000
IOBCCW11 DS    D                                                        08120000
IOBCCW12 DS    D                                                        08140000
IOBCCW13 DS    D                                                        08160000
IOBCCW14 DS    D         LAST CCW OF LONGEST CHANNEL PROGRAM            08180000
*                                                                       08200000
**********************************************************************  08220000
*                                                                       08240000
*                                                                       08260000
DEB      DSECT                                                          08280000
         DS    0F                                                       08300000
DEBNMSUB DS    0CL1                                                     08320000
DEBTCBAD DS    CL4                                                      08340000
DEBAMLNG DS    0CL1                                                     08360000
DEBDEBAD DS    CL4                                                      08380000
DEBOGLGS DS    0CL1                                                     08400000
DEBIRBAD DS    CL4                                                      08420000
DEBOPATB DS    0CL1                                                     08440000
DEBSYSPG DS    CL4                                                      08460000
DEBNMEXT DS    0CL1                                                     08480000
DEBUSRPG DS    CL4                                                      08500000
DEBPRIOR DS    0CL1                                                     08520000
DEBECBAD DS    CL4                                                      08540000
DEBPROTG DS    0CL1                                                     08560000
DEBDEBID DS    0CL1                                                     08580000
DEBDCBAD DS    CL4                                                      08600000
DEBEXSCL DS    0CL1                                                     08620000
DEBAPPAD DS    CL4                                                      08640000
DEBDVMOD DS    0CL1                                                     08660000
DEBUCBAD DS    CL4                                                      08680000
DEBBINUM DS    CL2                                                      08700000
DEBSTRCC DS    CL2                                                      08720000
DEBSTRHH DS    CL2                                                      08740000
DEBENDCC DS    CL2                                                      08760000
DEBENDHH DS    CL2                                                      08780000
DEBNMTRK DS    CL2                                                      08800000
DEBSUBID EQU   0         SUBROUTINE ID'S                                08820000
         END                                                            08840000
