         TITLE 'IGG019DD-WRITE FORMAT F,TRACK OVERFLOW,LOAD MODE'       00004016
IGG019DD CSECT                                                          00008000
*          RELEASE 16 DELETIONS                                         00016000
*7030                                                             12987 00020016
*          RELEASE 17 DELETIONS                                         00024000
*          RELEASE 18 DELETIONS                                         00032000
*0833059400                                                       21476 00036018
*          RELEASE 19 DELETIONS                                         00040000
*1351066200                                                      A27071 00044019
*1351049200,067800-068000,075400-075800,086400                   A30241 00046019
*          RELEASE 20 DELETIONS                                         00048000
*0832020200,020400,026100-026200,056100-056200,063400,066260,    M5894  00049020
*0832066330,082200,085200,089800                                 M5894  00050020
*0832026200,056200,082200,089800                                 A33537 00052020
*          RELEASE 21 DELETIONS                                         00056000
*1110                                                            A37232 00060021
*          RELEASE 218 DELETIONS/CHANGES                                00062000
*A020700,091320,0914000,66280-066320,066900,066960              SA69176 00062421
*C066190,066260                                                 SA69176 00064421
*A020720,020740                                                 SA69175 00072400
*THE FIX FOR XA05387 IS FLAGGED SA69176                         XA05387 00073500
*THE FIX FOR XA05386 IS FLAGGED SA69175                         XA05386 00083300
*          RELEASE 22 DELETIONS                                         00086800
*          RELEASE 23 DELETIONS                                         00090100
*          RELEASE 24 DELETIONS                                         00093400
* STATUS CHANGE LEVEL 007      5/10/74                                  00096700
*FUNCTIONS- THIS ROUTINE OBTAINS AN IOB, INITIALIZES THE CHANNEL        00100000
*    PROGRAM, AND ISSUES THE 'EXCP' FOR A WRITE TYPE SF OR SD TO A      00120000
*    FORMAT 'F' DATA SET WITH THE TRACK OVERFLOW OPTION SPECIFIED.      00140000
*    IF THE BLOCK WILL NOT FIT ON THE CURRENT TRACK, IT WILL BE         00160000
*    SEGMENTED AS MANY TIMES AS ARE REQUIRED TO COMPLETELY WRITE THE    00180000
*    BLOCK.                                                             00200000
*    CAPACITY RECORDS WILL BE WRITTEN AS EACH TRACK IS FILLED.          00220000
*                                                                       00240000
*    PRIOR TO WRITING THE FIRST BLOCK IN AN ALLOCATED EXTENT, A TEST IS 00260000
*    MADE FOR TRACKS AT THE END OF THE PREVIOUS EXTENT WHICH COULD NOT  00280000
*    BE USED AND MUST BE ERASED. IF THERE ARE UNUSED TRACKS THEY ARE    00300000
*    ERASED BY A COMMON SEQUENCE OF CCWS EXECUTED AS A SEPARATE REQUEST 00320000
*    AND WHEN THAT REQUEST COMPLETES, THE NEW BLOCK WILL BE WRITTEN.    00340000
*                                                                       00360000
*ENTRY POINTS- 'WRTENTRY' IS THE NORMAL ENTRY POINT FROM THE WRITE      00380000
*    MACRO EXPANSION. CALLING SEQUENCE IS     L     15,DCBWRITE         00400000
*                                             BALR  14,15               00420000
*    'EOVENTRY' IS THE ENTRY FROM THE BSAM END-OF-VOLUME EXECUTOR TO    00440000
*    RESTART A WRITE WHICH WAS ISSUED AFTER THE CURRENT SPACE           00460000
*    ALLOCATION WAS FILLED. THE RECORD WILL NOW BE WRITTEN INTO THE     00480000
*    SPACE OBTAINED AS SECONDARY ALLOCATION. CALLING SEQUENCE IS        00500000
*                                              L    15,DCBWRITE         00520000
*                                              BAL  14,4(15)            00540000
*INPUT- TO 'WRTENTRY'- DECB ADDRESS IN REGISTER 1                       00560000
*       TO 'EOVENTRY'- IOB ADDRESS IN REGISTER 3                        00580000
*                      DCB ADDRESS IN REGISTER 2                        00600000
*                      DEB ADDRESS IN REGISTER 5                        00620000
*                                                                       00640000
*OUTPUT- AN IOB FROM THE POOL OF IOBS WILL BE ASSIGNED TO THIS DECB     00660000
*    AND ITS ADDRESS PLACED IN THE DECB, EXCP WILL BE ISSUED TO         00680000
*    SCHEDULE THIS WRITE.                                               00700000
*                                                                       00720000
*EXTERNAL ROUTINES-                                                     00740000
*                                                                       00760000
*EXITS- 'RETURN' IS AN EXIT BACK TO THE USER, REGISTER 15 WILL CONTAIN  00780000
*    A RETURN CODE AS FOLLOWS,                                          00800000
*        0 = RECORD WAS WRITTEN, THERE IS MORE SPACE ON THE TRACK       00820000
*        8 = RECORD WAS WRITTEN, DATA SET IS FILLED                     00840000
*        12= RECORD NOT WRITTEN, NO IOB IS AVAILABLE UNTIL 'CHECK' HAS  00860000
*            BEEN ISSUED.                                               00880000
*    'EOVEXIT' IS A RETURN TO THE END-OF-VOLUME EXECUTOR.               00900000
*                                                                       00905019
*ERROR EXITS-                                                           00910019
*   002 ABEND-     BLOCK WILL NOT FIT ON ONE EXTENT                     00915019
*                                                                       00920000
*TABLES- 1. DIRECT ACCESS DEVICE TABLE IS USED TO CALCULATE THE BYTES   00940000
*           OF OVERHEAD FOR THIS RECORD AND TO DETERMINE THE NEXT       00960000
*           VALID TRACK ADDRESS AND THE TRACK LENGTH.                   00980000
*                                                                       01000000
*ATTRIBUTES- THIS ROUTINE IS REENTRANT AND EXECUTED ENABLED.            01020000
*                                                                       01040000
*NOTES- THE REGISTER USAGE IN THIS MODULE AND THE BSAM END-OF-VOLUME    01060000
*    EXECUTOR MUST REMAIN CONSISTENT.                                   01080000
*                                                                       01100000
*                                                                       01120000
*  REGISTER USAGE                                                       01140000
*                                                                       01160000
         USING IGG019DD,EPREG                                           01180000
         USING IHADCB,DCBREG                                            01200000
         USING IOBDEF,IOBREG                                            01220000
         USING DEB,DEBREG                                               01240000
         USING DECBDEF,DECBREG                                          01260000
*                                                                       01280000
WKREG    EQU   0         WORK REGISTER                                  01300000
CCHH     EQU   0                                                        01320000
PARAM1   EQU   1         PARAMETER REGISTER                             01340000
DECBREG  EQU   1         DECB ADDRESS                                   01360000
DCBREG   EQU   2         DCB ADDRESS                                    01380000
IOBREG   EQU   3         IOB ADDRESS                                    01400000
EOVRETRN EQU   4         EOV RETURN ADDRESS                             01420000
DEBREG   EQU   5         DEB ADDRESS                                    01440000
WKREG1   EQU   6         WORK REGISTERS                                 01460000
WKREG2   EQU   7                                                        01480000
WKREG3   EQU   8                                                        01500000
WKREG4   EQU   9                                                        01520000
WKREG5   EQU   10                                                       01540000
WKREG6   EQU   11                                                       01560000
BASE     EQU   12        BASE OF THIS MODULE                            01580000
SAVE     EQU   13        USER'S SAVE AREA                               01600000
RETREG   EQU   14        RETURN ADDRESS WHEN ENTERED                    01620000
EPREG    EQU   15        ENTRY POINT                                    01640000
*                                                                       01660000
*                                                                       01680000
*                                                                       01700000
*                                                                       01720000
*  ENTRY POINTS TO THIS ROUTINE                                         01740000
*                                                                       01760000
WRTENTRY B     BEGIN                   GO TO BEGINNING OF WRITE CODE    01780000
*                                                                       01800000
         DROP  EPREG                                                    01820000
         USING IGG019DD,BASE                                            01840000
*                                                                       01860000
EOVENTRY L     DECBREG,IOBECBPT        LOAD DECB BASE ADDRESS           01880000
         TM    DCBCIND1,VOLFUL          IS THE VOLUME FULL       M5894  01886020
         BCR   1,RETREG                 YES,RETURN TO EOV        M5894  01892020
         L     BASE,DCBWRITE           SET BASE REGISTER                01900000
         LR    EOVRETRN,RETREG         MOVE RETURN TO EOV ADDRESS       01920000
         SR    WKREG2,WKREG2           SET INDEX TO THE CURRENT EXTENT  01940000
         IC    WKREG2,DCBFDAD           IN THE DEB                      01960000
         SLL   WKREG2,4                                                 01980000
         AR    WKREG2,DEBREG                                            02000000
         L     EPREG,DCBDVTBL           LOAD POINTER TO DEVICE   M5894  02005020
*                                       CHAR                     M5894  02010020
         LH    WKREG,DEBNMTRK-DEB(0,WKREG2) GET NO. TRKS IN EXT  M5894  02015020
         MH    WKREG,TRKL(0,EPREG)   MULTIPLY NO. BY TRK LENGTH  M5894  02020020
         CH    WKREG,DCBOFFSR           WILL BLK FIT ON EXTENT?  M5894  02025020
         BL    ABEND                    NO, ABEND WITH 002       M5894  02030020
*                                                                       02060000
         OI    IOBLINK,EOVRET           SET BIT FOR EOV ENTRY   SA69176 02070000
         TM    DCBCIND1,VOLFUL          IS THIS EXTENT FULL YET SA69175 02072000
         BO    EOVON                    YES,SET BIT AND RET     SA69175 02074000
         B     BOTHENT                  BRANCH TO COMMON ROUTINE M5894  02076000
*                                                                       02080000
BEGIN    SAVE  (14,12)                 SAVE THE USER'S REGISTER         02100000
         L     DCBREG,DECDCBAD         LOAD DCB BASE ADDRESS FROM DECB  02120000
         L     DEBREG,DCBDEBAD         LOAD DEB BASE ADDRESS FROM DCB   02140000
         LR    BASE,EPREG              MOVE ENTRY POINT TO BASE REG.    02160000
*                                                                       02180000
         L     IOBREG,DCBIOBA          USE CURRENT IOB TO LOCATE THE    02200000
         TM    DCBCIND2,CLOSEDCB       DID WE ENTER FROM CLOSE   A37232 02206021
         BO    LDBLKSI                 YES, GO WRT OUT R 0       A37232 02212021
         L     IOBREG,IOBLINK           NEXT IOB ADDRESS                02220000
         TS    IOBLINK+4               IF NEXT IOB IS AVAILABLE         02240000
         BC    8,OKIOB                  GO INITIALIZE IT                02260000
*                                      ELSE RETURN WITH ERROR CODE 12   02280000
         LA    15,12                                                    02300000
         B     RETURN                                                   02320000
*                                                                       02340000
*                                                                       02360000
OKIOB    ST    IOBREG,DCBIOBA          STORE CURRENT IOB ADDRESS IN DCB 02380000
         LA    WKREG1,8(0,IOBREG)      STORE IOS IOB ADDRESS IN         02400000
         ST    WKREG1,DECIOBPT          THE DECB                        02420000
         ST    DECBREG,IOBECBPT        STORE DECB ADDRESS IN IOB        02440000
         TM    DCBCIND1,VOLFUL         IS VOLUME FULL            M5894  02446020
         BO    EOVON                IF YES GO TO TURN ON BIT     M5894  02452020
BOTHENT  EQU   *                                                        02460000
         L     EPREG,DCBDVTBL          LOAD POINTER TO DEVICE CHAR.     02480000
*                                                                       02500000
         TM    DCBCIND2,WZEROBIT       DID LAST WRITE FILL A TRACK      02520000
         BZ    MVCSRCH                  NO, CONTINUE ON THIS TRACK      02540000
         XI    DCBCIND2,WZEROBIT         YES,TURN OFF R0 FLAG    A30241 02550019
         BAL   RETREG,WZEROFF           YES, GO INCREMENT TRACK NUMBER  02560000
*                                                                       02580000
MVCSRCH  MVC   IOBSEEK,DCBFDAD         MOVE DCB TRACK ADDRESS TO IOB    02600000
         TM    DCBCIND1,ERASEBIT       ARE THERE UNUSED TRACKS   M5894E 02610020
*                                       TO ERAS                  M5894  02620020
         BC    1,ERSRTN                 YES, GO BUILD ERASE REQUEST     02640000
*                                                                       02660000
*                                                                       02680000
         L     WKREG4,DECAREA          LOAD AREA START ADDRESS          02700000
         IC    WKREG2,DCBFDAD+7        INCREMENT BLOCK ID (R) OF        02720000
         LA    WKREG2,1(0,WKREG2)       DCB ADDRESS                     02740000
         STC   WKREG2,DCBFDAD+7                                         02760000
*                                                                       02780000
         SR    WKREG3,WKREG3           ZERO REGISTER                    02800000
         IC    WKREG3,DCBKEYLE          INSERT KEY LENGTH               02820000
         LTR   WKREG3,WKREG3            AND TEST FOR ZERO               02840000
         BZ    LDBLKSI                 IF NO KEYS, SKIP WRITE DUMMY TST 02860000
*                                                                       02880000
*                                                                       02900000
         TM    DECTYPE+1,DUMMY         THIS A WRITE DUMMY               02920000
         BZ    LDBLKSI                  NO                              02940000
         MVI   0(WKREG4),X'FF'          YES, SET FIRST BYTE OF KEY TO 1 02960000
         STC   WKREG2,0(WKREG4,WKREG3)   FIRST BYTE OF DATA TO BLOCK ID 02980000
*                                                                       03000000
LDBLKSI  LH    WKREG5,DCBBLKSI         INITIALIZE DATA FIELD LENGTH     03020000
         LA    WKREG1,IOBDNRCF         SET COUNT FIELD INDEX            03040000
         L     WKREG6,IOBSTART          AND CCW INDEX                   03060000
*                        WKREG1 = COUNT FIELD INDEX                     03080000
*                        WKREG4 = AREA ADDRESS                          03100000
*                        WKREG5 = TOTAL BYTES OF DATA TO BE WRITTEN     03120000
*                        WKREG6 = CCW INDEX                             03140000
         TM    DCBCIND2,CLOSEDCB       DID WE ENTER FROM CLOSE   A37232 03146021
         BO    WRTR0                   YES, JUST WRT OUT R0      A37232 03152021
MVCAREA  EQU   *                                                        03160000
         ST    WKREG4,CCW4(0,WKREG6)   STORE ADDR INTO WRITE CCW        03180000
         MVI   CCW4(WKREG6),WRTCKD      RESET THE OP-CODE               03200000
*                                                                       03220000
         SR    WKREG,WKREG             CLEAR WORK REGISTERS             03240000
         SR    WKREG2,WKREG2                                            03260000
         SR    WKREG3,WKREG3                                            03280000
         IC    WKREG3,DNRCF+5(0,WKREG1) INSERT KEY LENGTH FOR THIS SEG. 03300000
         IC    WKREG,OVERK(0,EPREG)     AND O'HEAD FOR KEYS             03320000
         LTR   WKREG3,WKREG3           IS A KEY BEING WRITTEN           03340000
         BZ    NOKEYS                   NO, LET O'HEAD SUB. FROM TOTAL  03360000
         SR    WKREG,WKREG              YES, ZERO AMOUNT TO BE SUB.     03380000
NOKEYS   EQU   *                    DEVELOP BYTES REQUIRED FOR LAST RCD 03400000
         IC    WKREG2,OVERL(0,EPREG)                                    03420000
         SR    WKREG2,WKREG            IF NO KEY, SUB. O'HEAD FOR KEYS  03440000
         AR    WKREG2,WKREG3            (O'HEAD + KEY LENGTH            03460000
         LH    WKREG3,DCBTRBAL           + DATA LENGTH) THIS SUM WILL   03480000
         SR    WKREG3,WKREG2           BE SUBTRACTED FROM TRACK BALANCE 03500000
         SR    WKREG3,WKREG5           IF RESULT IS NEGATIVE, RECORD    03520000
         BM    SEGMENT                 WILL NOT FIT                     03540000
*                   WKREG2 = KEY LENGTH + O'HEAD FOR A LAST RECORD      03560000
*                                                                       03580000
*                                                                       03600000
         SR    WKREG4,WKREG4           CALCULATE BYTES REQUIRED FOR AN  03620000
         IC    WKREG4,DNRCF+5(0,WKREG1) INTERMEDIATE RECORD.            03640000
         AR    WKREG4,WKREG5          ((KEY LENGTH + DATA LENGTH) TOLER 03660000
         MH    WKREG4,TOLER(0,EPREG)    + O'HEAD)                       03680000
         SRL   WKREG4,9                                                 03700000
         SR    WKREG4,WKREG                                             03720000
         IC    WKREG,OVERI(0,EPREG)                                     03740000
         AR    WKREG4,WKREG                                             03760000
*                                                                       03780000
         LH    WKREG,DCBTRBAL          DECREMENT TRACK BALANCE BY THE   03800000
         SR    WKREG,WKREG4             CALCULATED VALUE                03820000
         STH   WKREG,DCBTRBAL                                           03840000
         NI    CCW4+4(WKREG6),0        PRE-SET CHAN. PRGM. TO END HERE  03860000
         MVI   CCW3(WKREG6),WRTCKD     TURN OFF WRITE-SPECIAL BIT       03880000
*                                                                       03900000
         CH    WKREG,DCBEOBR+2         WILL A MINIMUM SEGMENT FIT ON    03920000
         LR    WKREG,WKREG5             THIS TRACK. (MOVE DATA LENGTH)  03940000
         BNL   SETCNTS                  YES, GO PREPARE TO WRITE BLOCK  03960000
         SPACE                                                          03966021
WRTR0    EQU   *                                                 A37232 03972021
         OI    DCBCIND2,WZEROBIT       SET TRACK-FULL INDICATION        03980000
         XC    DCBTRBAL(2),DCBTRBAL     ZERO TRACK BALANCE       M5894  03990020
         B     SETR0CNT                GO PREPARE TO WRITE R0 AND BLOCK 04000000
*                                                                       04020000
*                                                                       04040000
SEGMENT  EQU   *                                                        04060000
         LH    WKREG,DCBTRBAL          CALC. BYTES OF DATA FIELD WHICH  04080000
         SR    WKREG,WKREG2             WILL FIT ON THIS TRACK          04100000
         MVI   CCW3(WKREG6),WRTSP      MOVE IN WRITE SPECIAL CKD OPCODE 04120000
SETR0CNT EQU   *                                                        04140000
         MVC   R0CNT(4,WKREG1),DCBFDAD+3  MOVE CCHH TO R0 COUNT AND     04160000
         MVC   R0DATA(5,WKREG1),DCBFDAD+3  CCHHR OF LAST BLOCK TO R0    04180000
*                                          DATA FIELD                   04200000
         TM    DCBCIND2,CLOSEDCB       DID WE ENTER FROM CLOSE   A37232 04202021
         BNO   NOTCLOSE                NO, BYPASS NEXT           A37232 04204021
         LA    WKREG2,CCW5(WKREG6)     LOAD ADDR OF WRT R0 C.P.  A37232 04206021
         ST    WKREG2,IOBSTART         ST C.P. BEGIN IN IOB      A37232 04208021
         NI    20(WKREG2),X'FF'-CCHN   TURN OFF COMMAND CHAIN    A37232 04210021
         B     DOEXCP                  GO WRT OUT RECORD ZERO    A37232 04212021
         SPACE                                                          04214021
NOTCLOSE EQU   *                                                 A37232 04216021
         OI    CCW4+4(WKREG6),CCHN     SET COMMAND CHAIN TO WRITE R0    04220000
         TM    DCBOPTCD,WRTCHK         IS THERE A TIC AT CCW5 LOCATION  04240000
         BZ    CHECK                   NO                               04260000
         LA    WKREG2,CCW6(0,WKREG6)                                    04280000
         ST    WKREG2,CCW5(0,WKREG6)                                    04300000
         MVI   CCW5(WKREG6),TICOP                                       04320000
CHECK    EQU   *                                                        04340000
         LTR   WKREG5,WKREG5           HAVE WE FINISHED WRITING THE     04360000
         LH    WKREG2,DCBWCPO          CCWS                             04380000
         BZ    SKIPNOP                 YES GO BACK TO OUTPUT THEM       04400000
         BCTR  WKREG2,0                NO, DECREMENT TRACK COUNT BY ONE 04420000
         STH   WKREG2,DCBWCPO                                           04440000
SETCNTS  EQU   *                                                        04460000
         STH   WKREG,DNRCF+6(0,WKREG1)  STORE DATA LENGTH IN COUNT      04480000
         MVC   DNRCF(5,WKREG1),DCBFDAD+3 MOVE CCHHR TO COUNT            04500000
*                                                                       04520000
         SR    WKREG5,WKREG            DECREMENT DATA BYTES             04540000
         SR    WKREG2,WKREG2                                            04560000
         IC    WKREG2,DNRCF+5(0,WKREG1) CALC. TOTAL BYTES TO BE         04580000
         AR    WKREG,WKREG2              WRITTEN AS A SEGMENT AND       04600000
         STH   WKREG,CCW4+6(0,WKREG6)   USE AS WRITE CCW COUNT          04620000
*                                                                       04640000
         LA    WKREG2,CCW7(0,WKREG6)   TURN OFF COMMAND CHAIN TO END    04660000
         TM    DCBOPTCD,WRTCHK          CHANNEL PROGRAM                 04680000
         BZ    *+8                      (EITHER CCW7 OR CCW9)           04700000
         LA    WKREG2,16(0,WKREG2)                                      04720000
         NI    4(WKREG2),X'BF'                                          04740000
         LTR   WKREG5,WKREG5           IS BYTES REQUIRED = ZERO         04760000
         BZ    CHK1MORE                 YES, SEE IF ANOTHER BLOCK FITS  04780000
*                                                                       04800000
         OI    4(WKREG2),CCHN          SET COMMAND CHAIN TO CONTINUE    04820000
         AR    WKREG4,WKREG            INCREMENT AREA ADDRESS           04840000
         LA    WKREG1,24(0,WKREG1)      AND COUNT FIELD INDEX           04860000
         LA    WKREG6,8(0,WKREG2)       AND CCW INDEX                   04880000
*                                                                       04900000
         BAL   RETREG,WZEROFF           GO INCR. TRK ADDR.       A30241 04920019
         MVC   R0CNT(4,WKREG1),DCBFDAD+3 FILL COUNT FIELD FOR SCH ID EQ 04940000
       MVI   DCBFDAD+7,1             INCREMENT TO FIRST RECORD          04960000
         B     MVCAREA                 GO FILL NEXT GROUP OF CCWS       04980000
*                                                                       05000000
*   SEE IF THERE ARE BYTES REMAINING IN THIS EXTENT FOR ANOTHER BLOCK   05020000
*                                                                       05040000
CHK1MORE EQU   *                                                        05060000
         LH    WKREG2,DCBWCPO          LOAD NO. OF TRACKS REMAINING     05080000
         TM    DCBCIND2,WZEROBIT       IF END OF PERIOD DON'T DECREMENT 05100000
         BO    NODECR                  TRACK COUNT                      05120000
         LTR   WKREG2,WKREG2           TEST ANY REMAINING               05140000
         BZ    NODECR                  IF NONE SEE IF A RECORD WILL FIT 05160000
         BCTR  WKREG2,0                DECREMENT NO. TRACKS BY ONE      05180000
NODECR   EQU   *                                                        05200000
         MH    WKREG2,TRKL(0,EPREG)    MULTIPLY BY TRACK LENGTH         05220000
         AH    WKREG2,DCBTRBAL          ADD BALANCE OF CURRENT TRACK    05240000
         LH    WKREG3,DCBEOBR+2                                         05260000
         BCTR  WKREG3,0                                                 05280000
         AH    WKREG3,DCBBLKSI         KEY LENGTH+DATA LENGTH+O'HEAD    05300000
         SR    EPREG,EPREG             PRE-SET RETURN CODE TO 0         05320000
         CR    WKREG2,WKREG3           BYTES  ENOUGH FOR ANOTHER BLOCK  05340000
         BNL   CHKWRTCK                 YES, DON'T WRITE R0             05360000
*                                                                       05380000
OUTPUTR0 EQU   *                                                        05400000
         B     SETR0CNT                OUTPUT R0 CCWS                   05420000
SKIPNOP  EQU   *                                                        05440000
         TM    DCBCIND2,WZEROBIT       IF R0 WRITTEN DON'T DECREMENT    05460000
         BO    R0SET                   TRACK COUNT.SET TRACK FILLED BIT 05480000
         OI    DCBCIND2,WZEROBIT       SET TRACK-FILLED INDICATION      05500000
         BCTR  WKREG2,0                DECREMENT TRACKS REMAINING BY 1  05520000
         STH   WKREG2,DCBWCPO                                           05540000
R0SET    EQU   *                                                        05560000
         LTR   WKREG2,WKREG2           ANY TRACKS LEFT TO BE ERASED     05580000
         BZ    *+8                      NO, LAST BLOCK FILLED LAST TRK. 05600000
         OI    DCBCIND1,ERASEBIT       TURN ON SW TO INDICATE    M5894  05610020
*                                       ERASE                    M5894  05620020
*                                                                       05640000
         IC    WKREG2,DEBNMEXT         SEE IF THIS IS LAST EXTENT       05660000
         BCTR  WKREG2,0                 CURRENTLY ALLOCATED BY          05680000
         EX    WKREG2,CLIEXTNT          COMPARING M TO NO. OF EXTENTS-1 05700000
         BL    CHKWRTCK                NOT LAST EXTENT                  05720000
         LA    EPREG,8                 SET RETURN CODE TO 8             05740000
*                                                                       05760000
CHKWRTCK EQU   *                                                        05780000
         NI    CCW7+4(WKREG6),0        PRE-SET CHAN. PRGM. TO END       05800000
         TM    DCBOPTCD,WRTCHK         IS WRITE CHECK SPECIFIED         05820000
         BZ    DOEXCP                   NO, GO EXECUTE                  05840000
*                                                                       05860000
         TM    CCW4+4(WKREG6),CCHN     IS R0 BEING WRITTEN TOO          05880000
         MVI   CCW4+4(WKREG6),CCHN      (NEED COMMAND CHAIN EITHER WAY) 05900000
         BZ    SETTICAD                 NO, GO SET A TIC TO VERIFY BLK. 05920000
         TM    CCW2+5(WKREG6),1         IS THIS THE LAST CCW      21476 05930018
*                                       SEQUE                     21476 05940018
         BZ    SHFTR0                   NO, GO MOVE R0 FIELDS           05960000
         OI    CCW9+4(WKREG6),CCHN     SET COMMAND CHAIN TO VERIFY BLK. 05980000
         B     DOEXCP                   GO EXECUTE                      06000000
*                                                                       06020000
SHFTR0   EQU   *                       USE LAST SEQUENCE OF CCWS TO     06040000
         MVC   R0CNT+24(16,WKREG1),R0CNT(WKREG1) OUTPUT R0 BY MOVING    06060000
         LA    WKREG,112(0,WKREG6)      FIELDS AND ALTERING TIC AT CCW5 06080000
         ST    WKREG,CCW5(0,WKREG6)                                     06100000
         OI    CCW9+76(WKREG6),CCHN    SET COMMAND CHAIN TO VERIFY BLK. 06120000
         B     SETTICOP                                                 06140000
SETTICAD EQU   *                                                        06160000
         MVC   CCW5(4,WKREG6),CCW5+4(WKREG6) RESTORE TIC ADDR. OF CCW5  06180000
SETTICOP MVI   CCW5(WKREG6),TICOP      RESTORE TIC OP-CODE TO CCW5      06200000
*                                                                       06220000
*                                                                       06240000
DOEXCP   EQU   *                                                        06260000
         LR    WKREG2,EPREG            SAVE RETURN CODE                 06280000
         LA    PARAM1,8(0,IOBREG)      SET IOS IOB PARAMETER            06300000
         EXCP  (1)                                                      06320000
EXCPOUT  LR    EPREG,WKREG2             RESTORE RETURN CODE      M5894  06340020
*                                                                       06360000
*                                                                       06380000
         TM    IOBLINK,EOVBIT          WAS ENTRY FROM EOV               06400000
         BZ    RETURN                   NO, ENTERED BY WRITE MACRO      06420000
*                                                                       06440000
         NI    IOBLINK,NOTEOV          CLEAR EOV UNSCHEDULED INDICATION 06460000
         BR    EOVRETRN                GO BACK TO EOV                   06480000
*                                                                       06500000
*                                                                       06520000
*                                                                       06540000
*  BYPASS EXCP FOR REQUESTS AFTER EOV                                   06560000
*                                                                       06580000
SETEOV   OI    DCBCIND1,VOLFUL         MARK DCB SO FUTURE REQ.S BYPASS  06600000
         BCTR  WKREG3,0                 RESTORE DCBFDAD           12987 06606016
         STC   WKREG3,DCBFDAD                                     12987 06612016
POSTEOV  TM    IOBLINK,EOVRET           WAS ENTRY FROM EOV      SA69176 06619021
         BNO   EOVON                   YES,RETURN TO EOV        SA69176 06626021
RETEOV   EQU   *                        RETURN TO EOV           SA69176 06628021
         NI    IOBLINK,X'FF'-EOVRET     YES,TURN OFF BIT 1ST    SA69176 06630021
         BR    EOVRETRN                 AND RETURN TO EOV       SA69176 06632021
EOVON    OI    IOBLINK,EOVBIT       MARK IOB AS NOT EXCP'D       M5894  06633020
*                                                                       06640000
NORMAL   SR    15,15                   SET RETURN CODE TO ZERO          06660000
*                                                                       06680000
RETURN   EQU   *                        RET TO USER OR EOV      SA69176 06690021
         TM    IOBLINK,EOVRET           WAS ENTRY FROM EOV      SA69176 06692021
         BNO   USERRET                  NO,TO RESTORE USER REGS SA69176 06694021
         B     RETEOV                   BR TO RETURN TO EOV     SA69176 06696021
USERRET  RETURN (14,12),T,RC=(15)      RETURN TO THE USER               06700021
*                                                                       06720000
*   INCREMENT TRACK ADDRESS BY 1 AND CHECK VALIDITY                     06740000
*                                                                       06760000
WZEROFF  MVC   IOBCSW(4),MAXCC(EPREG)   MOVE NO. OF CYL          A30241 06780019
*                                        AND TRKS TO IOB                06800019
         MVC   IOBCSW+4(4),DCBFDAD+3   MOVE CURRENT CCHH FOR ALIGNMENT  06820000
         MVC   DCBTRBAL,TRKL(EPREG)    RESET TRACK BALANCE              06840000
         MVI   DCBFDAD+7,0              AND ZERO RECORD NO.             06860000
         SR    WKREG2,WKREG2                                            06880000
         IC    WKREG2,DCBFDAD          DEVELOP POINTER TO CURRENT       06900000
         SLL   WKREG2,4                 EXTENT IN THE DEB               06920000
         AR    WKREG2,DEBREG                                            06940000
         LA    IOBREG,0(0,IOBREG)      BE SURE HI-ORDER BYTE IS ZERO    06960000
         LA    WKREG3,3(0,IOBREG)       SET CCHH INDEX TO LAST H        06980000
         L     CCHH,IOBCSW+4           LOAD CURRENT CCHH TO AN ACCUM.   07000000
         TM    BYTEDEV(EPREG),BYTE      ARE ADDRESS BYTES CONTIGUOUS    07020000
         BZ    DOWNONE                  BRANCH IF CONTIG ADDRESS BYTES  07040000
ADDONE   AH    CCHH,ONE                ADD ONE TO THE LO-ORDER BYTE     07060000
         TM    BYTEDEV(EPREG),BYTE     ARE BYTES NON-CONTIGUOUS         07080000
         BC    1,USEBYTE                YES, TREAT EACH SEPARATELY      07100000
         STH   CCHH,IOBCSW+4-IOBDEF(0,WKREG3)  STORE NEW CC OR HH       07120000
         CLC   IOBCSW+4-IOBDEF(2,WKREG3),IOBCSW-IOBDEF(WKREG3)          07140000
*                                            CHECK FOR VALID VALUE      07160000
         BC    4,TSTEXT                ADDRESS VALID, CHECK EXTENT      07180000
         SRL   CCHH,16                 SHIFT TO CC VALUE                07200000
         MVC   IOBCSW-IOBDEF+4(2,WKREG3),ZEROS  ZERO BYTES PROCESSED    07220000
         BCTR  WKREG3,0                  AND DECREMENT THE INDEX        07240000
DOWNONE  BCTR  WKREG3,0                 DECREMENT POINTER               07260000
         CR    WKREG3,IOBREG           HAVE ALL BYTES BEEN PROCESSED    07280000
         BC    10,ADDONE                NO, LOOP TO ADD ONE TO NEXT BYT 07300000
*                                                                       07320000
NEXTEXT  IC    WKREG3,DCBFDAD          INCREMENT M AND SEE IF THIS WAS  07340000
         LA    WKREG3,1(0,WKREG3)       THE LAST EXTENT.                07360000
         STC   WKREG3,DCBFDAD                                           07380000
         CLC   DCBFDAD(1),DEBNMEXT                                      07400000
         BC    8,SETEOV                 YES, GO SET EOV BIT             07420000
         LA    WKREG2,16(0,WKREG2)     INCREMENT TO NEXT EXTENT         07440000
         MVC   DCBFDAD+1(6),DEBBINUM-DEB(WKREG2)  MOVE BBCCHH TO DCB    07460000
         LH    WKREG,DEBNMTRK-DEB(0,WKREG2) GET THE NUMBER OF TRACKS    07480000
*                                      IN THIS EXTENT AND MULTIPLY IT   07500000
         MH    WKREG,TRKL(0,EPREG)     BY TRACK LENGTH                  07520000
         CH    WKREG,DCBOFFSR           COMPARE TO LENGTH OF ONE A30241 07540019
         BNL   RESETTRK                 RECORD. IF IT FITS,GO ON A30241 07560019
ABEND    EQU   *                                                 A27071 07590019
         L     1,ABCODE                SET ABEND CODE PLUS DUMP OPTION  07600000
         ABEND (1),DUMP                 AND ABEND                       07620000
*                                                                       07640000
RESETTRK EQU   *                                                        07660000
         MVC   DCBWCPO(2),DEBNMTRK-DEB(WKREG2) MOVE TRACKS IN EXTENT TO 07680000
         BR    RETREG                           DCB, RETURN             07700000
*                                                                       07720000
*                                                                       07740000
*                                                                       07760000
*                                                                       07780000
USEBYTE  EQU   *                                                        07800000
         STC   CCHH,IOBCSW-IOBDEF+4(0,WKREG3)  STORE NEW BYTE OF CCHH   07820000
         SRL   CCHH,8                   SHIFT TO THE NEXT ONE           07840000
         CLC   IOBCSW-IOBDEF+4(1,WKREG3),IOBCSW-IOBDEF(WKREG3)          07860000
*                                                 THIS BYTE VALID       07880000
         BC    4,TSTEXT                 BRANCH IF YES                   07900000
         MVI   IOBCSW-IOBDEF+4(WKREG3),0  ZERO THIS BYTE OF CCHH        07920000
         B     DOWNONE                  GO SEE IF ALL BYTES PROCESSED   07940000
*                                                                       07960000
TSTEXT   CLC   IOBCSW+4(4),DEBENDCC-DEB(WKREG2)  ADDRESS WITHIN EXTENT  07980000
         BC    2,NEXTEXT               NO, SEE IF THERE'S ANOTHER EXT   08000000
         MVC   DCBFDAD+3(4),IOBCSW+4   YES, MOVE NEW CCHH TO DCB        08020000
         BR    RETREG                  RETURN TO MAINLINE               08040000
*                                                                       08060000
*                                                                       08080000
*   SET UP THE CCWS TO ERASE A VARIABLE NUMBER OF TRACKS AT THE END OF  08100000
*   THE EXTENT WHICH COULD NOT BE USED.                                 08120000
*                                                                       08140000
*                                                                       08160000
ERSRTN   EQU   *                                                        08180000
*                                                                       08200000
         XI    DCBCIND1,ERASEBIT       CLEAR ERASE FLAG          M5894  08220020
         L     WKREG6,DCBEOBW          LOAD ADDRESS OF ERASE CCW'S      08240000
         MVC   IOBDNRCF(4),IOBSTART    SAVE WRITE CHAN. PROGRAM ADDRESS 08260000
         ST    WKREG6,IOBSTART         STORE NEW START ADDRESS          08280000
         MVC   ERSDATA(4,WKREG6),DCBFDAD+3 MOVE STARTING CCHH ADDRESS   08300000
*                                                                       08320000
EXCPERS  EQU   *                                                        08340000
         LA    PARAM1,8(0,IOBREG)      SET IOS IOB PARAMETER            08360000
         EXCP  (1)                                                      08380000
*                                                                       08400000
         L     DECBREG,IOBECBPT        RELOAD DECB ADDRESS              08420000
         WAIT  ECB=(1)                 WAIT FOR ERASE TO COMPLETE       08440000
*                                                                       08460000
         L     DECBREG,IOBECBPT        RELOAD DECB ADDRESS              08480000
         SR    WKREG2,WKREG2            SET RETURN CODE IN REG   M5894  08490020
         CLI   DECSDECB,X'42'          ANY ERROR OTHER THAN END-OF-EXT. 08500000
         BNE   EXCPOUT                 YES, CK WHERE ENTERED     M5894  08520020
         NI    DECSDECB,0              CLEAR OUT THE ECB                08540000
*                                                                       08560000
         MVC   DCBFDAD+3(4),ERSDATA(WKREG6) MOVE LAST CCHH TO THE DCB   08580000
         MVC   IOBSTART(4),IOBDNRCF    RESTORE CHAN. PROGRAM ADDRESS    08600000
         LA    RETREG,MVCSRCH          SET RETURN ADDRESS               08620000
         B     WZEROFF                  AND GO INCR. TRK ADDR    A30241 08640019
*                                                                       08660000
*                                                                       08680000
*                                                                       08700000
CLIEXTNT CLI   DCBFDAD,0   ---EXECUTED-- CHECK FOR M = LAST EXTENT      08720000
*                                                                       08740000
*                                                                       08760000
**********************************************************************  08780000
*                                                                       08800000
ZEROS    DC    H'0'                     CONSTANT OF ZERO                08820000
ONE      DC    H'1'      CONSTANT ONE                                   08840000
NOP      EQU   X'03'     NOP CHANNEL COMMAND OP-CODE                    08860000
TICOP    EQU   X'08'     TIC COMMAND OP-CODE                            08880000
SCHIDEQ  EQU   X'31'     SEARCH ID EQUAL OP-CODE                        08900000
WRTD     EQU   X'05'     WRITE DATA OP-CODE                             08920000
WRTSP    EQU   X'01'     WRITE COUNT-KEY-DATA SPECIAL                   08940000
WRTCKD   EQU   X'1D'     WRITE COUNT-KEY-DATA                           08960000
CLOSEDCB EQU   X'20'                   SW IN DCB TO INDICATE IN  A37232 08966021
*                                       CLOSE                    A37232 08972021
ERASEBIT EQU   X'04'       THERE ARE TRCKS TO BE ERASED          M5894  08980020
CCHN     EQU   X'40'     COMMAND CHAIN FLAG                             09000000
WRTCHK   EQU   X'80'     WRITE CHECK OPTION                             09020000
DUMMY    EQU   X'10'     WRITE DUMMY TYPE                               09040000
WZEROBIT EQU   X'40'     LAST I/O WAS WRITE R0                          09060000
EOVBIT   EQU   X'80'     THIS WRITE NOT SCHEDULED BECAUSE OF EOV        09080000
NOTEOV   EQU   X'7F'     ALL BITS EXCEPT USCHEDULED BECAUSE OF EOV      09100000
VOLFUL   EQU   X'20'     VOLUME FULL BIT                                09120000
EOVRET   EQU   X'10'                    BIT INDICATING CALLER   SA69176 09130000
*                                       OF THIS MODULE WAS EOV  SA69176 09132000
         DS    0F                                                       09140000
ABCODE   DC    AL1(128)                DUMP OPTION                      09160000
         DC    XL3'002000'             BLOCK WILL NOT FIT ON ONE EXTENT 09180000
*                                                                       09200000
*      DIRECT ACCESS DEVICE TABLE DEFINITION                            09220000
BYTE     EQU   2         BYTES OF  CCHH ARE NON-CONTIGUOUS              09240000
OVERK    EQU   8         OFFSET TO KEY OVERHEAD                         09260000
OVERI    EQU   6                   INTERMEDIATE RECORD OVERHEAD         09280000
OVERL    EQU   7                   LAST RECORD OVERHEAD                 09300000
TOLER    EQU   10                  TOLERANCE FACTOR                     09320000
TRKL     EQU   4                   BYTES ON TRACK                       09340000
MAXCC    EQU   0                   NO. OF CYLINDERS, TRACKS             09360000
BYTEDEV  EQU   9                   FLAG, BYTES ARE NON-CONTIGUOUS       09380000
*                                                                       09400000
CCW1     EQU   0         OFFSET TO THE CCWS OF A WRITE SEQUENCE         09420000
CCW2     EQU   8                                                        09440000
CCW3     EQU   16                                                       09460000
CCW4     EQU   24                                                       09480000
CCW5     EQU   32                                                       09500000
CCW6     EQU   40                                                       09520000
CCW7     EQU   48                                                       09540000
CCW8     EQU   56                                                       09560000
CCW9     EQU   64                                                       09580000
ERSDATA  EQU   72        8 BYTE DATA FIELD FOLLOWING ERASE CCWS         09600000
*                                                                       09620000
DNRCF    EQU   0         OFFSET TO NEW RECORD COUNT FIELD               09640000
R0CNT    EQU   8         OFFSET TO R0 COUNT FIELD                       09660000
R0DATA   EQU   16        OFFSET TO R0 DATA FIELD                        09680000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   09700000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   09720000
*                                                                       09740000
*                                                                       09760000
*************************  DCB DEFINITION  **************************** 09780000
         DCBD  DSORG=(PS),DEVD=(DA)                                     09800000
         EJECT                                                          09820000
*************************  IOB DEFINITION  **************************** 09840000
IOBDEF   DSECT      I/O BLOCK DEFINITION                                09860000
IOBLINK  DS    F         IOB LINK ADDRESS                               09880000
IOBIOBA  DS    F         IOB ADDRESS FOR EOV                            09900000
IOBFLAG1 DS    CL1       ERROR FLAG 1                                   09920000
IOBFLAG2 DS    CL1       ERROR FLAG 2                                   09940000
IOBSENSE DS    CL2       I/O SENSE BITS                                 09960000
IOBECBPT DS    F         ECB ADDRESS                                    09980000
IOBCSW   DS    D         CSW STORED BY IOS                              10000000
IOBSIOCC DS    0BL1      SIO CONDITION CODE                             10020000
IOBSTART DS    F         CHANNEL PROGRAM STARTING CCW                   10040000
IOBDCBPT DS    F         DCB ADDRESS                                    10060000
IOBRESTR DS    F         CHANNEL PROGRAM RESTART ADDRESS                10080000
IOBINCAM DS    CL2       BLOCK INCREMENT AMOUNT                         10100000
IOBERRCT DS    CL2       ERROR COUNTS                                   10120000
IOBSEEK  DS    D         SEEK ADDRESS                                   10140000
IOBDNRCF DS    D         NEW RECORD COUNT FIELD                         10160000
IOBR0CNT DS    D         COUNT FIELD OF R0                              10180000
IOBR0DAT DS    D         DATA FIELD OF R0                               10200000
IOBCCW1  DS    D         FIRST CCW OF CHANNEL PROGRAM                   10220000
IOBCCW2  DS    D                                                        10240000
IOBCCW3  DS    D                                                        10260000
IOBCCW4  DS    D                                                        10280000
IOBCCW5  DS    D                                                        10300000
IOBCCW6  DS    D                                                        10320000
IOBCCW7  DS    D                                                        10340000
IOBCCW8  DS    D                                                        10360000
IOBCCW9  DS    D                                                        10380000
IOBCCW10 DS    D                                                        10400000
IOBCCW11 DS    D                                                        10420000
IOBCCW12 DS    D                                                        10440000
IOBCCW13 DS    D                                                        10460000
IOBCCW14 DS    D         LAST CCW OF LONGEST CHANNEL PROGRAM            10480000
*                                                                       10500000
*************************  DECB DEFINITION  *************************** 10520000
*                                                                       10540000
DECBDEF  DSECT     DATA EVENT CONTROL BLOCK                             10560000
DECSDECB DS    F         STANDARD ECB                                   10580000
DECTYPE  DS    CL2       TYPE AND OPTIONS                               10600000
DECLNGTH DS    CL2       DATA LENGTH                                    10620000
DECDCBAD DS    F         DCB ADDRESS                                    10640000
DECAREA  DS    F         AREA ADDRESS                                   10660000
DECIOBPT DS    F         IOB ADDRESS                                    10680000
DECKYADR DS    F                                                        10700000
DECOFSET DS    CL2                                                      10720000
DECRESPN DS    CL1                                                      10740000
         EJECT                                                          10760000
*************************  DEB DEFINITION  **************************** 10780000
*                                                                       10800000
DEB      DSECT                                                          10820000
         DS    0F                                                       10840000
DEBNMSUB DS    0CL1                                                     10860000
DEBTCBAD DS    CL4                                                      10880000
DEBAMLNG DS    0CL1                                                     10900000
DEBDEBAD DS    CL4                                                      10920000
DEBOGLGS DS    0CL1                                                     10940000
DEBIRBAD DS    CL4                                                      10960000
DEBOPATB DS    0CL1                                                     10980000
DEBSYSPG DS    CL4                                                      11000000
DEBNMEXT DS    0CL1                                                     11020000
DEBUSRPG DS    CL4                                                      11040000
DEBPRIOR DS    0CL1                                                     11060000
DEBECBAD DS    CL4                                                      11080000
DEBPROTG DS    0CL1                                                     11100000
DEBDEBID DS    0CL1                                                     11120000
DEBDCBAD DS    CL4                                                      11140000
DEBEXSCL DS    0CL1                                                     11160000
DEBAPPAD DS    CL4                                                      11180000
DEBDVMOD DS    0CL1                                                     11200000
DEBUCBAD DS    CL4                                                      11220000
DEBBINUM DS    CL2                                                      11240000
DEBSTRCC DS    CL2                                                      11260000
DEBSTRHH DS    CL2                                                      11280000
DEBENDCC DS    CL2                                                      11300000
DEBENDHH DS    CL2                                                      11320000
DEBNMTRK DS    CL2                                                      11340000
DEBSUBID EQU   0         SUBROUTINE ID'S                                11360000
         END                                                            11380000
