         TITLE 'IGG019KA - DAM FOUNDATION MODULE'                       00010003
         COPY  LCGASMSW                                                 00012001
IGG019KA CSECT                                                          00020000
*                                                                       00024020
*                                                                       00028020
*        VS1  RELEASE 030  DELETIONS                                    00030003
*A113800,C115900,C116540,C116580                                 XM5240 00030403
*D115200,115400,115600                                          XA02860 00032003
*                                                               XA03071 00034003
*        RELEASE VS 2-1 DELETIONS/CHANGES                               00038003
*                                                               XA02033 00038403
*        RELEASE 21 DELETIONS/CHANGES                                   00040020
*           THE FIX FOR XM3774 IS FLAGGED SM5427                 XM3774 00040102
*        RELEASE 21.8 CHANGES/DELETIONS                                 00040221
*                                                               YA04292 00040421
*           THE FIX FOR XA05380 IS FLAGGED YA04292              XA05380 00040821
*           THE FIX FOR SA69171 IS FLAGGED YA04292              SA69171 00041021
*A05150-051580,139900,081720                                    YA04292 00042221
*                                                                       00044221
*                                                                XM0911 00045421
*057800,059200-060200                                           SA54515 00047321
*1132111200,117400,120400,120800-121800,122600,132200-132400     A35339 00049221
*1132112600-112800                                               A30797 00051121
*                                                               SA53267 00053021
*                                                                YM5538 00054921
*D094300,095956                                                  YM5568 00056821
*                                                                YM5544 00058721
*D124520-124799,124812                                           SM5472 00060621
*D094420,094500,095964                                          YA02106 00062521
* THE FIX FOR SA65558 IS FLAGGED XA02033                        SA65558 00064421
* THE FIX FOR XA02394 IS FLAGGED YA02106                        XA02394 00066321
* THE FIX FOR SA67343 IS FLAGGED XM5240                         SA67343 00068221
*          RELEASE 18 DELETIONS                                         00070121
*2438093900,098920,100200,100600,101220-101360                    24512 00072021
*          RELEASE 19 DELETIONS                                         00073921
*1777084200,084600                                               S19015 00075821
*1777                                                            A29259 00077721
*          RELEASE 20 DELETIONS                                         00079621
*0286074860-074920                                               M5471  00081521
*0286                                                            A33688 00083421
*0286000270-000440,000690-000830,048200,053400,063920,064080,    20201  00085321
*0286083400-083800,084400,084600                                 20201  00087221
*0286134860-134920                                               M5461  00089121
*STATUS CHANGE LEVEL 015   8/28/73                                      00091003
*FUNCTION/OPERATION- THIS MODULE CONTAINS THREE ROUTINES WHOSE        * 00100000
*   FUNCTIONS ARE,                                                    * 00120000
*   ROUTINE 1. INITIAL ENTRY FOR ANY BDAM READ OR WRITE, CHECK THE    * 00140000
*    VALIDITY OF SPECIFIED TYPE AND OPTIONS, OBTAIN AN IOB, PROVIDE   * 00160000
*    LINKAGE FOR ADDRESS CONVERSION AND CHANNEL PROGRAM CONSTRUCTION, * 00180000
*    ISSUE THE 'EXCP' AND RETURN TO THE USER.                         * 00200000
*                                                                     * 00220000
*   ROUTINE 2. ASYNCHRONOUS INTERRUPT ROUTINE (ASI), PROVIDE LINKAGE  * 00240000
*    TO THE FEEDBACK AND SELF-FORMAT MODULES, MAKE THE IOB AVAILABLE  * 00260000
*    AND LINK NEW IOBS TO THE DCB, ISSUE THE 'POST' AND RETURN TO     * 00280000
*    SUPERVISOR.                                                      * 00300000
*                                                                     * 00320000
*   ROUTINE 3. ERROR ROUTINES, RELEASE THE IOB, SET THE PROPER        * 00340000
*    EXCEPTION CODES, ISSUE THE 'POST'.                               * 00360000
*                                                                     * 00380000
*ENTRY POINTS- 'IGG019KA' (ENTRYPT) IS THE ENTRY FOR A BDAM READ OR   * 00400000
*   WRITE MACRO INSTRUCTION. THE GENERATED CALLING SEQUENCE IS,       * 00420000
*   L    15,DCBREAD   (DCB+48)                                        * 00440000
*   BALR 14,15                                                        * 00460000
*                                                                     * 00480000
*   'IECDFDNA' IS THE ENTRY POINT TO THE ASI ROUTINE FROM SUPERVISOR  * 00500000
*   WHEN THE REQUEST HAS TERMINATED. THE CALLING SEQUENCE USED IS,    * 00520000
*   L    15,IRBRBEP   (IRB+12)                                        * 00540000
*   BALR 14,15                                                        * 00560000
*                                                                     * 00580000
*   'LATERR' IS AN ENTRY TO THE INVALID REQUEST ERROR ROUTINE FROM    * 00600000
*   THE ADDRESS CONVERSION OR PRE-FORMAT MODULES. CALLING SEQUENCE IS,* 00620000
*   L    REG,20(IGG019KA BASE)                                        * 00640000
*   BR   REG                                                          * 00660000
*                                                                     * 00680000
*INPUT- ROUTINE 1.- DECB ADDRESS IN REGISTER 1, SAVE AREA ADDRESS IN  * 00700000
*   REGISTER 13, RETURN ADDRESS IN REGISTER 14, ENTRY POINT IN        * 00720000
*   REGISTER 15.                                                      * 00740000
*                                                                     * 00760000
*   ROUTINE 2.(ASI)- IOS QUEUEING ELEMENT ADDRESS IN REGISTER 1,      * 00780000
*   RETURN ADDRESS IN REGISTER 14, ENTRY POINT IN REGISTER 15.        * 00800000
*                                                                     * 00820000
*   ROUTINE 3.(INVALID REQUEST)- REGISTERS 5,7,11,13 WILL CONTAIN THE * 00840000
*   DECB ADDRESS, IOB ADDRESS, IGG019KA ADDRESS, SAVE AREA ADDRESS,   * 00860000
*   RESPECTIVELY. REGISTER 12 WILL CONTAIN THE REASON CODE WHICH WILL * 00880000
*   APPEAR IN BYTE TWO OF THE DECB AFTER 'POST' IS EXECUTED.          * 00900000
*                                                                     * 00920000
*OUTPUT- ROUTINE 1.- AN IOB WILL BE OBTAINED, CHANNEL PROGRAM         * 00940000
*   CONSTRUCTED AND 'EXCP' EXCECUTED FOR A VALID READ OR WRITE.       * 00960000
*                                                                     * 00980000
*   ROUTINE 2.(ASI)- FEEDBACK WILL BE RETURNED IF REQUESTED, AND A    * 01000000
*   COMPLETION CODE PLACED IN THE DECB BY THE 'POST' ROUTINE.         * 01020000
*                                                                     * 01040000
*   ROUTINE 3.(INVALID REQUEST)- A COMPLETION CODE AND REASON CODE    * 01060000
*   ARE PLACED IN THE DECB BY THE 'POST' ROUTINE.                     * 01080000
*                                                                     * 01100000
*EXTERNAL ROUTINES- 'IGG019KC'-CONVERT RELATIVE TRACK ADDRESS (TT OR  * 01120000
*   TTR) TO AN ACTUAL ADDRESS OR CONVERT ACTUAL TO TTR FOR FEEDBACK.  * 01140000
*                                                                     * 01160000
*   'IGG019KE'-CONVERT RELATIVE BLOCK ADDRESS TO AN ACTUAL ADDRESS.   * 01180000
*                                                                     * 01200000
*   'IGG019KF'-CONVERT RELATIVE BLOCK ADDRESS TO AN ACTUAL ADDRESS    * 01220000
*   FOR OVERFLOW RECORDS                                              * 01240000
*                                                                     * 01260000
*   'IGG019KK'-CONSTRUCT A CHANNEL PROGRAM TO SEARCH BY BLOCK ID.     * 01280000
*                                                                     * 01300000
*   'IGG019KI'-CONSTRUCT A CHANNEL PROGRAM TO SEARCH BY BLOCK KEY.    * 01320000
*                                                                     * 01340000
*   'IGG019KO'-CONSTRUCT A CHANNEL PROGRAM TO ADD A NEW BLOCK TO A    * 01360000
*   DATA SET OF FIXED FORMAT RECORDS, (PRE-FORMAT MODULE).            * 01380000
*                                                                     * 01400000
*   'IGG019KM'-CONSTRUCT A CHANNEL PROGRAM TO ADD A NEW BLOCK TO A    * 01420000
*   DATA SET OF VALIABLE OR UNDEFINED LENGTH RECORDS, (SELF-FORMAT    * 01440000
*   MODULE).                                                          * 01460000
*   ALSO ENTERED TO DETERMINE IF THE NEW BLOCK WILL FIT ON THE TRACK  * 01480000
*   AFTER THE CAPACITY RECORD IS READ INTO THE IOB.                   * 01500000
*   ALSO ENTERED AFTER THE WRITE-ADD REQUEST HAS COMPLETED, TO SCAN   * 01520000
*   THE UNSCHEDULED QUEUE FOR OTHER WRITE-ADD REQUESTS AND EXECUTE    * 01540000
*   THE FIRST REQUEST FOUND, IF ANY.                                  * 01560000
*                                                                     * 01580000
*   'IGG019LG'-PLACE A RECORD ON THE READ EXCLUSIVE LIST FOR A READ   * 01600000
*   OR REMOVE A RECORD FROM THE READ EXCLUSIVE LIST FOR A WRITE       * 01620000
*   WHEN EXCLUSIVE CONTROL IS SPECIFIED.                              * 01640000
*                                                                     * 01660000
*   'IGG019KG'-CONVERT AN ACTUAL ADDRESS TO A RELATIVE BLOCK NUMBER   * 01680000
*   IF FEEDBACK IS REQUESTED.                                         * 01700000
*                                                                     * 01720000
*   'IGG019KH'-CONVERT AN ACTUAL ADDRESS TO A RELATIVE BLOCK NUMBER   * 01740000
*   FOR OVERFLOW RECORDS, IF FEEDBACK IS REQUESTED.                   * 01760000
*                                                                     * 01780000
*EXITS-NORMAL- 'RSTOR' IS THE RETURN TO THE PROGRAM WHICH ISSUED THE  * 01800000
*   READ OR WRITE MACRO-INSTRUCTION. THE REQUEST HAS EITHER BEEN      * 01820000
*   EXECUTED VIA 'EXCP' OR HAS BEEN POSTED COMPLETE AS AN INVALID     * 01840000
*   REQUEST.                                                          * 01860000
*   'SUPEXIT' IS THE EXIT FROM THE ASI ROUTINE TO SUPERVISOR. THE DECB* 01880000
*   HAS BEEN POSTED AS COMPLETE WITH A CODE INDICATING SUCCESSFUL OR  * 01900000
*   ERROR COMPLETION.                                                 * 01920000
*                                                                     * 01940000
*TABLES/WORK AREAS- N/A                                               * 01960000
*                                                                     * 01980000
*ATTRIBUTES- THE INITIAL ENTRY ROUTINE AND INVALID REQUEST ERROR      * 02000000
*   ROUTINE ARE REENTRANT AND EXECUTED ENABLED.                       * 02020000
*   THE ASI ROUTINE IS REUSEABLE AND EXECUTED DISABLED, PRIVILEGED,   * 02040000
*   AND WITH THE PROBLEM PROGRAM PROTECT KEY.                         * 02060000
*                                                                     * 02080000
*NOTE- THE BDAM MODUES BRANCH AND LINK TO EACH OTHER WITHOUT USE OF   * 02100000
*   A REGISTER SAVE AREA SO THE REGISTER USAGE MUST REMAIN CONSISTENT * 02120000
*   IN THE BDAM MODULES, IGG019KA, IGG019KC, IGG019KE, IGG019KF,      * 02140000
*   IGG019KG, IGG019KH, IGG019KI, IGG019KK, IGG019KM, IGG019KO,       * 02160000
*   IGG019KQ9.                                                        * 02180000
*                                                                     * 02200000
*                                                                       02220000
*                                                                       02240000
*                                                                       02260000
*                                                                       02280000
         USING IGG019KA,EPREG                                           02300000
         USING IHADCB,DCBREG                                            02320000
         USING DECB,DECBREG                                             02340001
         USING IOBSTDRD,IOBREG                                          02360001
         USING DEBDEF,DEBREG                                            02380000
*                                                                       02400000
*  REGISTER USAGE                                                       02420000
*                                                                       02440000
PARAM2   EQU   0                                                        02460000
PARAM    EQU   1         PARAMETERS                                     02480000
WKREG1   EQU   2         WORK REGISTER                                  02500000
DEBREG   EQU   3         DEB ADDRESS                                    02520000
WKREG3   EQU   3         WORK REGISTER                                  02530001
DCBREG   EQU   4         DCB ADDRESS                                    02540000
DECBREG  EQU   5         DECB ADDRESS                                   02560000
WKREG2   EQU   6         WORK REGISTER                                  02580000
IOBREG   EQU   7         IOB ADDRESS                                    02600000
SECTOR   EQU   8         POINTER TO SECTOR AREA OR LAST DW       20201  02610020
FDNBASE  EQU   11        BASE FOR THE FOUNDATION MODULE                 02620000
INTRET   EQU   12        RETURN FOR INTERNAL LINKAGES                   02640000
SAVE     EQU   13        POINTER TO USER SAVE AREA                      02660000
RETREG   EQU   14        RETURN REGISTER                                02680000
EPREG    EQU   15        ENTRY POINT                                    02700000
*                                                                       02720000
         IEZBITS                                                        02730001
         EJECT                                                          02740000
*                                                                       02760000
*                                                                       02780000
ENTRYPT  BC    15,BEGIN       BRANCH AROUND ADDRESS LOCATIONS           02800000
*                                                                       02820000
RRAD     DC    F'0'                    RELATIVE BLOCK MODULE ADDRESS    02840000
RTAD     DC    F'0'                    RELATIVE TRACK MODULE ADDRESS    02860000
VERAD    DC    F'0'                    VERIFY MODULE ADDRESS            02880000
ASIAD    DC    A(IECDFDNA-ENTRYPT)     ASYNCHRONOUS INTERRUPT ROUTINE   02900000
ERRENTRY DC    A(LATERR-ENTRYPT)       INVALID REQUEST ERROR ROUTINE    02920000
KEYMODAD DC    F'0'                    ADDRESS OF THE KEY MODULE        02940000
IDMODAD  DC    F'0'                    ADDRESS OF THE ID MODULE         02960000
RROVAD   DC    F'0'                     REL BLOCK/TRK OFLO MOD AD 13883 02970016
*                                                                       02980000
*                                                                       03000000
*                                                                       03020000
         DROP  EPREG                                                    03040000
         USING IGG019KA,FDNBASE                                         03060000
BEGIN    SAVE  (14,12)                 SAVE USER REGISTERS IN HIS AREA  03080000
         LR    FDNBASE,EPREG           ESTABLISH A BASE FOR THIS MODULE 03100000
         LR    DECBREG,PARAM       SET BASE REGISTERS FOR DECB          03120000
         L     DCBREG,DECDCBAD                            DCB           03140000
         L     DEBREG,DCBDEBAD                            DEB           03160000
*                                                                       03180000
         IC    INTRET,DECTYPE          SAVE REQUESTED OPTIONS IN A REG  03200000
         OI    DECTYPE,VERIFY+EXSCH+ACTAD+RELRD+OFLOW                   03220000
         NC    DECTYPE(1),DCBOPTCD     COMBINE DCB OPTIONS WITH THE     03240000
         EX    INTRET,ORBACK            REQUEST OPTIONS.                03260000
         N     INTRET,OPSMSK           VALIDITY CHECK READX,DYN. BFR.   03280000
         BC    8,OKOPTS                 OPTIONS (BR IF NONE PRESENT),BY 03300000
         EX    INTRET,VALCHK            EXECUTING A TM INSTRUCTION.     03320000
         BC    1,OKOPTS                OK IF ALSO SPECIFIED IN DCB,     03340000
         IC    INTRET,INVOPT            ELSE FLAG THIS REQUEST AS       03360000
         BC    15,ABORT                 INVALID AND GO POST COMPLETION. 03380000
*                                                                       03400000
ORBACK   OI    DECTYPE,0     EXECUTED-RETURN FEEDBACK OPTION BIT.       03420000
VALCHK   TM    DCBOPTCD,0    EXECUTED-CHECK READX,DYN. BFR. REQUEST.    03440000
*                                                                       03460000
OKOPTS   TM    DECTYPE+1,READ          IS THIS A READ REQUEST           03480000
         BC    1,LGNCHK                 YES, GO TEST LENGTH OPTION      03500000
         TM    DEBOPATB,WRTMSK         DID OPEN SPECIFY OUTPUT/UPDATE   03520000
         BC    5,FORMCHK                YES, WRITE REQUEST IS VALID     03540000
         IC    INTRET,INVWRT           FLAG THIS WRITE TO INPUT DATA    03560000
         BC    15,ABORT                 SET, GO POST COMPLETION         03580000
*                                                                       03600000
*                                                                       03620000
FORMCHK  TM    DCBRECFM,VFORM          IS RECORD FORMAT VARIABLE        03640000
         BC    1,LGNCHK                 NO, GO TEST LENGTH OPTION       03660000
         L     WKREG2,DECAREA          USE FIRST TWO BYTES OF DATA AS   03680000
         MVC   DECLNGTH(2),0(WKREG2)    BLOCK LENGTH FOR THE WRITE      03700000
         B     SZRTN                   GO DETERMINE IOB SIZE            03720000
*                                                                       03740000
LGNCHK   TM    DECTYPE+1,LGNOP         DID USER CODE LENGTH AS 'S'      03760000
         BC    8,SZRTN                  NO, USE DECB LENGTH             03780000
         MVC   DECLNGTH(2),DCBBLKSI    USE MAXIMUM BLOCK SIZE AS LENGTH 03800000
*                                                                       03820000
*   THE FOLLOWING ROUTINE DETERMINES THE SIZE IOB AND CHANNEL PROGRAM   03840000
*        CORE AREA REQUIRED FOR THIS REQUEST                            03860000
*                                                                       03880000
SZRTN    LA    WKREG1,BASESZ           SIZE=BASE + OPTIONS              03900000
         LA    PARAM,XSCHSZ            SET TO EXTENDED SEARCH CORE AMT. 03920000
         SR    INTRET,INTRET            CLEAR FEEDBACK INCREMENT REG    03940000
         TM    DCBOPTCD,OFLOW          ARE OVERFLOW RECORDS PRESENT     03960000
         BC    8,*+8                   NO , CONTINUE                    03980000
         LA    WKREG1,OFLINCR(0,WKREG1) ADD ON FOR NOP CCW AT END OF CP 04000000
         TM    DECTYPE+1,READ          TEST TYPE FOR READ               04020000
         BO    TSTRDX                   YES, GO TEST FOR READ EXCLUSIVE 04040000
*                                                                       04060000
         TM    DECTYPE,VERIFY           TEST FOR VERIFY OPTION          04080000
         BC    8,TSTWA                  BR IF NO VERIFY SPECIFIED       04100000
         LA    WKREG1,VERSZ(0,WKREG1)  INCREMENT FOR VERIFY CCW'S       04120000
TSTWA    TM    DECTYPE+1,ADD            TEST FOR WRITE ADD TYPE         04140000
         BC    8,TSTRDX                 NO, GO TEST FOR WRITE RELEASE   04160000
         LA    WKREG1,ADDSZ+ENQPL(0,WKREG1)  INCREMENT FOR WRITE ADD    04180000
*                                            AND ENQUE PARAMETER LIST   04200000
         LA    PARAM,PFEXTSZ           PRE-SET EXTENDED SEARCH REGISTER 04220000
         TM    DCBRECFM,FIXDMSK        ARE RECORDS FIXED FORMAT         04240000
         BC    8,TSTX                   BRANCH IF YES                   04260000
         LA    WKREG1,SFSZ(0,WKREG1)   INCREMENT FOR SELF FORMAT WRITE  04280000
         SR    PARAM,PARAM             NO CORE REQ'D FOR EXTENDED SRCH  04300000
         B     TSTX                    GO TEST FOR EXTENDED SEARCH      04320000
*                                                                       04340000
TSTRDX   TM    DECTYPE,READX            IS IT A READ EXCLUSIVE OR A     04360000
*                                       WRITE TO RELEASE                04380000
         BZ    TST4KEY                  BRANCH IF NO                    04400000
         LA    WKREG1,ENQPL(WKREG1)     ADD FOR ENQ PARAMETER LIST      04420000
*                                                                       04440000
TST4KEY  TM    DECTYPE+1,KEY           IS TYPE = KEY                    04460000
         BC    8,CHKPOOL                NO, SIZE IS IN WKREG1           04480000
         TM    DECTYPE,FEEDB+READX+OFLOW  ARE FEEDBACK CCWS NEEDED      04500000
         BC    8,TSTX                   NO, LEAVE REGISTER ZERO         04520000
         LA    INTRET,FDBSZ            SET POSSIBLE FEEDBACK INCREMENT  04540000
*                                                                       04560000
TSTX     TM    DECTYPE,EXSCH            TEST FOR EXTENDED SEARCH OPTION 04580000
         BC    8,CHKPOOL                BR IF NOT SPECIFIED             04600000
         CLC   ZEROS(3),DCBLIMCT       IS LENGTH OF SEARCH SPECIFIED    04620000
         BC    7,UPSZ88                 YES, REQUEST IS VALID           04640000
         IC    INTRET,INVLIMCT         FLAG INVALID REQUEST (LIMCT=0)   04660000
         BC    15,ABORT                 GO POST COMPLETION              04680000
UPSZ88   AR    WKREG1,PARAM            INCREMENT FOR EXTENDED SEARCH    04700000
         AR    WKREG1,INTRET            INCREMENT FOR FEEDBACK          04720000
*                                                                       04740000
*        THIS CODE IS ADDED TO GET ONE MORE DOUBLE WORD FOR THE         04742020
*        SECTOR BYTES ASSOCIATED WITH RECORD READY.                     04744020
*                                                                       04746020
CHKPOOL  EQU   *                                                 20201  04748020
         LA    WKREG1,RRINCR(WKREG1)   INCR IOB SZ FOR REC REDY  20201  04750020
*                                                                       04752020
*    THE FOLLOWING ROUTINE OBTAINS AN IOB AREA FROM THE POOL OF AREAS   04760000
*     IF ONE OF ENOUGH SIZE IS AVAILABLE                                04780000
*                                                                       04800000
         L     IOBREG,DCBIOBAD          LOAD FIRST LINK ADDRESS  20201  04820020
SHFT     LA    IOBREG,0(0,IOBREG)      BE SURE HI-ORDER BYTE IS ZERO    04840000
         LTR   IOBREG,IOBREG            TEST FOR ZERO LINK ADDRESS.     04860000
         BC    8,GETCR                 IF ADDR=0, GO GET CORE FOR IOB   04880000
         CH    WKREG1,IOBDIOBS          IS THIS IOB AREA LARGE ENOUGH   04900000
         BC    2,TRYNEXT              IF NOT GO SEE IF THERE ARE MORE   04920000
         TS    IOBDAVLI                 IS THIS IOB AVAILABLE           04940000
         BC    8,CLRIOB                 YES, GO INITIALIZE AREA         04960000
*                                                                       04980000
TRYNEXT  L     IOBREG,IOBDPLAD         LOAD NEXT POOL LINK              05000000
         B     SHFT                    GO TEST FOR END OF CHAIN         05020000
*                                                                       05040000
*                                                                       05060000
CLRXC    XC    IOBDTYPE(1),IOBDTYPE  EXECUTED-- CLEAR LAST PART OF IOB  05080000
CLRXXC   XC    IOBDTYPE+Q255(Q1),IOBDTYPE+Q255  CLR IF IOB+CCWS  20201  05085020
*                                       GO                       20201  05090020
*                                                 BEYOND IOBDTYPE+255   05095020
*                                                                       05100000
*                                                                       05120000
*  GETMAIN ROUTINE                                                      05140000
GETCR    EQU   *                                                YA04292 05150021
         TM    DEBPROTG,KEYMASK         IS KEY EQUAL TO 0       YA04292 05152021
         BNZ   PPKEY                    BRANCH IF NOT           YA04292 05154021
         O     WKREG1,MASK              OR IN SP 250            YA04292 05156021
PPKEY    EQU   *                                                YA04292 05158021
         LR    PARAM2,WKREG1           MOVE BYTE COUNT TO PARAMETER REG 05160021
         GETMAIN R,LV=(0)                                               05180000
*                                                                       05200000
         LR    IOBREG,PARAM            LOAD CORE ADDRESS TO IOB BASE    05220000
         STH   WKREG1,IOBDIOBS         STORE THE AREA SIZE IN IOB       05240000
         SR    WKREG2,WKREG2            CLEAR THE POOL                  05260000
         ST    WKREG2,IOBDAVLI            ADDRESS AREA                  05280000
CLRIOB   XC    IOBFLAG1(42),IOBFLAG1   CLEAR TO IOB SIZE FIELD          05300000
         LR    SECTOR,IOBREG            LOAD ADDR OF IOB         20201  05301020
         AR    SECTOR,WKREG1            ADD NUMBER OF BYTES      20201  05302020
         S     SECTOR,EIGHT             POINT TO LAST DOUBLE     20201  05303020
*                                       WORD                     20201  05304020
         TM    DECTYPE+Q1,ADD           IS THIS WRITE ADD        20201  05305020
         BO    SUBRDX                   SUBTRACT OFF ENQ AREA    20201  05306020
         TM    DECTYPE,READX            IS THIS READ EXCLUSIVE   20201  05307020
         BZ    NOTREADX                 NO, ALL O.K.             20201  05308020
SUBRDX   EQU   *                                                 20201  05309020
         SH    SECTOR,RDXCORE           SUBTRACT OFF ENQ AREA    20201  05310020
NOTREADX EQU   *                                                 20201  05311020
         SH    WKREG1,K49              REDUCE SIZE TO REMAINING SIZE    05320000
         CH    WKREG1,IOBSZ255          IOB GO BEYOND            20201  05324020
*                                       IOBDTYPE+255?            20201  05328020
         BH    CLROVFF                  YES, GO TO CLEAR BEYOND  20201  05332020
         EX    WKREG1,CLRXC             ELSE CLEAR WHAT IS       20201  05336020
*                                       SPECIFIED                20201  05340020
         B     CORCLRD                  CORE ZEROED SO BRANCH    20201  05344020
CLROVFF  XC    IOBDTYPE(Q255),IOBDTYPE  CLR OUT 1ST 255 BYTES    20201  05348020
         EX    WKREG1,CLRXXC            CLEAR OUT THE REMAINDER  20201  05352020
CORCLRD  EQU   *                                                 20201  05356020
*                                                                       05360000
*                                                                       05380000
         ST    DCBREG,IOBDCBPT         STORE DCB ADDRESS IN IOB         05400000
         ST    DECBREG,IOBECBPT        STORE ECB ADDRESS IN IOB         05420000
         ST    IOBREG,DECIOBPT                   STORE IOB ADDR IN DECB 05440000
         LA    WKREG1,IOBCHNPR         DEVELOP CHANNEL PROGRAM STARTING 05460001
         ST    WKREG1,IOBSTART          ADDRESS AND STORE IT IN IOB     05480000
         MVC   IOBDTYPE(L'DECTYPE),DECTYPE  MOVE OPTION & TYPE CODE     05500001
         MVI   IOBFLAG1,CPFLAG         MARK AS UNRELATED, COMMAND CHAIN 05520000
*                                                                       05540000
*    THE FOLLOWING ROUTINE DETERMINES THE ADDRESSING METHOD BEING       05560000
*     USED AND CHECKS THE VALIDITY OF THE ADDRESS.                      05580000
*                                                                       05600000
ADDRDEC  L     PARAM,DECRECPT          LOAD POINTER TO USER'S ADDRESS   05620000
         LA    RETREG,CLRCP            LOAD COMMON RETURN POINT ADDRESS 05640000
         TM    IOBDTYPE+1,RDADD        BYPASS NEXT RTN IF READ OR ADD   05660000
         BC    5,D1NOFDBK               AND GO DETERMINE ADDRESS TYPE   05680000
         TM    IOBDTYPE+1,KEY           IF TYPE IS KEY, BYPASS CHECKING 05700000
         BC    1,TRYX                   FOR A WRITE TO R ZERO           05720003
         TM    IOBDTYPE,ACTAD           IS ADDRESS ACTUAL               05740003
         BC    8,TRYRT                  NO, GO TEST FURTHER             05760003
GOBACK   EQU   *                        TEST IF WRT TO R0       XA02033 05770003
         CLI   7(PARAM),0               IS THIS A WRITE TO R0           05800003
         BC    7,ACTUAL                 NO, ACTUAL ADDRESS IS OK        05820000
SETIRBIT IC    INTRET,INVID             FLAG INVAL REQUEST(WRITE TO R0) 05840003
         BC    15,LATERR                GO POST COMPLETION, FREE IOB    05860000
*                                                                       05880000
TRYRT    EQU   *                                                        05900000
         TM    DCBOPTCD,FEEDB           FEEDBACK IN DCB OPTCD?  XA02033 05950003
         BO    TRYRT2                   YES, NO ACTUAL ADDRESS  XA02033 06000003
         TM    IOBDTYPE,RDXFDB          X OR F TYPE?            XA03071 06010003
         BNZ   GOBACK                   YES, ASSUME ACTUAL ADDR XA02033 06020003
*                                       BECAUSE FEEDBACK ALWAYS XA02033 06022003
*                                       PROVIDED FOR READX REQ  XA02033 06024003
*                                       AND WRT REL MUST ASSUME XA02033 06026003
*                                       PREVIOUS READX REQ      XA02033 06028003
TRYRT2   EQU   *                        NOT ACTUAL ADDRESSING   XA02033 06032003
         TM    IOBDTYPE,RELRD          IS ADDRESS RELATIVE BLOCK NUMBER 06040000
         BC    1,RELRCDX                YES, GO TO RELATIVE BLOCK EXIT  06060000
         CLI   2(PARAM),0              IS R OF TTR A 0                  06080000
         BC    8,SETIRBIT               YES,WRITE REQUEST IS INVALID    06100000
*                                                                       06120000
RELTRKX  L     EPREG,RTAD               EXIT TO CONVERT TTR TO AN       06140000
         BC    15,RTRKOFFS(0,EPREG)        ACTUAL ADDRESS               06160001
*                                                                       06180000
TRYX     TM    IOBDTYPE,READX          IS THIS A WRITE WITH FEEDBACK    06200000
         BC    8,D1NOFDBK               NO, GO TEST ADDRESS TYPE        06220000
         TM    DCBOPTCD,FEEDB          WAS FEEDBACK RELATIVE FOR READ   06240000
         BC    8,ACTUAL                 NO, GO MOVE ACTUAL ADDR TO IOB  06260000
D1NOFDBK TM    IOBDTYPE,ACTAD           IF ADDRESS IS ALREADY ACTUAL,   06280000
         BC    1,ACTUAL                   GO MOVE IT TO THE IOB,        06300000
         TM    IOBDTYPE,RELRD          IS ADDRESS RELATIVE BLOCK        06320000
         BC    8,RELTRKX                NO, GO TO RELATIVE TRACK EXIT   06340000
*                                                                       06360000
RELRCDX  TM    DCBRECFM,X'20'           IT TRK OVERFLOW PRESENT   13883 06368016
         BO    TRKOV                    YES--GO TO REL BLK/TRK OV 13883 06376016
         L     EPREG,RRAD               NO--CONVERSION MOD EXIT   13883 06384016
         ST    SECTOR,IOBDCPND          ST SECT ADDR WHEN        20201  06385020
*                                       BRANCHING TO             20201  06386020
*                                          THIS MODULE ONLY             06387020
         BALR  RETREG,EPREG             BRANCH TO BLOCK CONVERT  20201  06388020
*                                       RTN                      20201  06389020
         L     SECTOR,IOBDCPND          RESTORE SECTOR ADDR      20201  06390020
         B     CLRCP                    GO CLEAR OUT CHANNEL PGM 20201  06391020
*                                       AREA                     20201  06392020
TRKOV    L     EPREG,RROVAD             TRK OVERFLOW EXIT         13883 06400016
         ST    SECTOR,IOBDCPND                                   20201  06404020
         BALR  RETREG,EPREG             GO TO REL BLK TRK OVFLO  20201  06408020
*                                          MODULE                       06412020
         L     SECTOR,IOBDCPND                                   20201  06416020
*                                                                       06420000
CLRCP    XC    IOBDNRCF(40),IOBDNRCF   CLEAR AREA USED TO STORE REG'S   06440000
         BC    15,TYPEDEC              GO GENERATE CHANNEL PROGRAM      06460000
*                                                                       06480000
*  THE FOLLOWING ROUTINE DETERMINES THE TYPE OF READ OR WRITE           06500000
*    AND PROVIDES LINKAGE TO THE PROPER MODULE                          06520000
*                                                                       06540000
ACTUAL   MVC   IOBSEEK,0(PARAM)        MOVE USER ADDRESS TO             06560000
         MVC   IOBUPLIM(7),IOBSEEK           SEEK AND LIMIT FIELDS      06580000
TYPEDEC  LA    RETREG,READY             LOAD COMMON RETURN ADDRESS      06600000
*                                                                       06601020
*    RECORD READY IS TESTED FOR HERE. IF RECORD READY IS TO BE          06602020
*    USED A X'FF' AND THE ADDRESS OF THE LAST DOUBLE WORD ARE           06603020
*    PASSED IN IOBDCPND.  IF REC READY IS NOT TO BE USED X'00' AND      06604020
*    THE ADDRESS OF THE LAST DOUBLE WORD ARE PASSED IN IOBDCPND         06605020
*                                                                       06606020
         ST    SECTOR,IOBDCPND          STORE LAST DOUBLE WORD   20201  06607020
         XR    EPREG,EPREG              ZERO OUT WORK REG        20201  06608020
         IC    EPREG,IOBSEEK            INSERT NO. OF EXTENTS    20201  06609020
         SLL   EPREG,FOUR               MULT BY 16               20201  06610020
         L     EPREG,UCBADDR(EPREG,DEBREG)  LOAD THE UCB ADDRESS 20201  06611020
         TM    UCBTBYT2(EPREG),RECREDY  DOES THIS UCB HAVE REC   20201  06612020
*                                       REDY                     20201  06613020
         BNO   AROUND                   NO, BRANCH AROUND        20201  06614020
         MVI   IOBDCPND,FF              MOVE IN THE REC REDY ID  20201  06615020
AROUND   EQU   *                                                 20201  06616020
         TM    UCBTBYT4(EPREG),TYP2305 IS IT A 2305?             YM5538 06618001
         BNO   INITCCWX                BR IF NOT                 YM5538 06618401
         MVI   IOBFLAG1,RELREQ         MARK AS RELATED REQUEST   YM5538 06618801
INITCCWX EQU   *                                                 YM5538 06619201
         LA    WKREG2,IOBCHNPR         INITIALIZE CCW INDEX             06620001
*                                                                       06640000
OVERMVC  TM    IOBDTYPE+1,ADDKY        IS TYPE KEY OR WRITE ADD         06660000
         BC    8,IDEXIT                 NO, GO GENERATE ID CHAN PROGRAM 06680000
         MVI   IOBSEEK+7,0             MAKE R BYTE ZERO TO SEARCH ON R0 06700000
*                                                                       06720000
         TM    IOBDTYPE+1,ADD          IS TYPE WRITE ADD                06740000
         BC    1,SOMEWA                 YES, GO TEST RECORD FORMAT      06760000
TEST4KEY CLI   DCBKEYLE,0              HAVE KEYS BEEN SPECIFIED         06780000
         BC    8,SETNOKEY               NO, GO SET ERROR CODE           06800000
         L     WKREG1,DECKYADR         LOAD AND TEST FOR MISSING KEY    06820000
         LTR   WKREG1,WKREG1            ADDRESS FIELD IN DECB           06840000
         BC    7,PROCEED               IF NOT MISSING GO TEST EXIT      06860000
SETNOKEY IC    INTRET,INVKEY           SET INVALID REQUEST CODE         06880000
         BC    15,LATERR                GO POST COMPLETION, FREE IOB    06900000
*                                                                       06920000
PROCEED  TM    IOBDTYPE+1,KEY          IS TYPE KEY                      06940000
         BC    8,SELFOR                 NO, GO TO WRITE ADD EXIT        06960000
         L     EPREG,KEYMODAD          EXIT TO GENERATE KEY CHANNEL     06980000
         BCR   15,EPREG                  PROGRAM                        07000000
IDEXIT   L     EPREG,IDMODAD           LOAD ID MODULE ADDRESS AND       07020000
         BCR   15,EPREG                 GO TO GENERATE ID CHANNEL PROG. 07040000
*                                                                       07060000
SOMEWA   TM    DCBRECFM,FIXDMSK         DATA SET FIXED LENGTH RECORDS   07080000
         BC    8,TEST4KEY               IF YES, GO TEST KEYS PRESENT    07100000
SELFOR   L     EPREG,DCBDFOR           LOAD ENTRY POINT OF THE          07120000
         BCR   15,EPREG                  WRITE ADD MODULE AND BR. TO IT 07140000
*                                                                       07160000
*                                                                       07180000
READY    EQU   *                                                        07200000
         TM    DCBOPTCD,OFLOW          TEST FOR TRACK OVERFLOW          07220000
         BZ    EXPCTEND                NOT PRESENT, NO NOP CCW          07240000
         OI    4(WKREG2),CCHN          TURN ON COMMAND CHAIN BIT        07260000
         LA    WKREG2,8(0,WKREG2)      UPDATE TO NEXT CCW               07280000
         MVI   0(WKREG2),NOPCODE       PUT IN NOP OP CODE               07300000
         MVI   4(WKREG2),SILI          TURN ON SILI BIT IN NOP CCW      07320000
         MVI   7(WKREG2),ONE           SET A NON-ZERO COUNT IN NOP CCW  07340000
EXPCTEND EQU   *                                                        07360000
         LA    WKREG2,8(0,WKREG2)      UPDATE POINTER TO PROGRAM END    07380000
         ST    WKREG2,IOBDCPND           EXPECTED ENDING ADDRESS        07400000
         MVC   IOBDNRCF+1(1),IOBSEEK+2  MOVE 'B' TO INLINE SEEK AREA    07420000
*                                                                       07440000
EXCP     LR    PARAM,IOBREG            LOAD IOB ADDR. AS THE PARAMETER  07460000
         EXCP  (1)                                                      07480000
*                                                                       07500000
RSTOR    RETURN (14,12),T,RC=0                                          07520000
*                                                                       07540000
*                                                                       07560000
*    THE FOLLOWING ROUTINE COMPLETES THE PROCESSING OF AN INVALID       07580000
*     REQUEST AND RETURNS TO THE USER.                                  07600000
*                                                                       07620000
LATERR   TM    IOBDAVLI,AVLMSK        IF THE AVAILABILITY BIT IS SET    07640000
         BC    1,FRMPOOL                 THIS IOB IS LINKED TO THE POOL 07660000
         LH    PARAM2,IOBDIOBS         SET SIZE PARAMETER FOR FREEMAIN  07680000
         TM    DEBPROTG,KEYMASK         IS KEY EQUAL TO 0       YA04292 07690021
         BNZ   PPKEY2                   BRANCH IF NOT           YA04292 07692021
         O     PARAM2,MASK              OR IN SP 250            YA04292 07694021
PPKEY2   EQU   *                                                YA04292 07696021
         LR    PARAM,IOBREG            SET ADDRESS PARAMETER            07700000
         FREEMAIN R,LV=(0),A=(1)                                        07720000
         B     ABORT                                                    07740000
*                                                                       07760000
FRMPOOL  EQU   *                                                        07780000
         MVI   IOBDAVLI,0              AVAILABLE                        07800000
ABORT    AH    INTRET,INVREQ           SET INVALID REQUEST EXCEPT. CODE 07820000
         SR    WKREG2,WKREG2           ZERO OUT THE IOB POINTER FIELD   07840000
         ST    WKREG2,DECIOBPT           OF THE DECB                    07860000
         LR    PARAM2,INTRET           POSITION THE POST CODE           07880000
         SLL   PARAM2,8                  (EXCEPTION CODES)              07900000
         LR    PARAM,DECBREG           LOAD ECB ADDRESS PARAMETER       07920000
         MVI   0(PARAM),0               AND CLEAR THE OLD POST CODE AND 07940000
         LA    PARAM,0(0,PARAM)         CLEAR HIGH ORDER BITS    A29259 07950019
         POST  (1),(0)                 POST.                            07960000
         BC    15,RSTOR                 GO RESTORE REGISTERS AND RETURN 07980000
*                                                                       08000000
OPSMSK   DC    F'6'                    OPTIONS-READX,DYNAMIC BFR.       08020000
ZEROS    EQU   OPSMSK                   PLUS ZEROS FOR COMPARING.       08040000
*                                                                       08060000
INVID    DC    X'08'                   INVALID ZERO ID                  08080000
INVOPT   DC    X'02'                   INVALID OPTIONS                  08100000
INVWRT   DC    X'40'                   WRITE TO INPUT DATA SET          08120000
INVLIMCT DC    X'20'                   EXTENDED SEARCH, LIMIT IS ZERO   08140000
INVREQ   DC    H'4096'                 INVALID REQUEST BIT              08160000
         DS    0F                                                       08170021
MASK     DC    X'FA000000'              SP 250                  YA04292 08172021
*                                                                       08180000
K49      DC    H'49'                   CONSTANT 49                      08200000
INVKEY   DC    X'04'                   KEYS ARE MISSING                 08220000
AVLMSK   EQU   X'80'          IOB AVAILABILITY FLAG                     08240000
FIXDMSK  EQU   X'40'          FORMAT 'F' DATA SET                       08260000
VFORM    EQU   X'80'          FORMAT 'V' DATA SET                       08280000
WRTMSK   EQU   15             DCB WAS OPENED FOR OUTPUT OR UPDATE       08300000
*                                                                       08320000
IOBSZ255 DC    H'255'                   COMPARATOR FOR IOB SIZE  20201  08330020
BASESZ   EQU   X'78'                    IOBBASE SIZE =120 BYTES  20201  08340020
ADDSZ    EQU   X'30'                    WRITE ADD = 48 BYTES     20201  08350020
VERSZ    EQU   X'30'                    VERIFT SIZE INCREMENT =  20201  08360020
*                                       48                       20201  08370020
SFSZ     EQU   X'010'         SELF-FORMAT INCREMENT = 16 BYTES          08400000
XSCHSZ   EQU   X'028'         EXTENDED SEARCH (KEY) INCREMENT=   S19015 08410019
*                                       40 BYTE                  S19015 08420019
PFEXTSZ  EQU   X'60'                    PRE-FORMAT INCREMENT=96  20201  08440020
FDBSZ    EQU   X'038'                   FEEDBACK(K) INCR=56      20201  08443020
Q1       EQU   1                        ONE BYTE QUANTITY        20201  08446020
Q255     EQU   255                      255 BYTE QUANTITY        20201  08449020
RRINCR   EQU   8                                                 20201  08452020
FOUR     EQU   4                                                 20201  08455020
UCBADDR  EQU   32                                                20201  08458020
UCBTBYT2 EQU   17                                                20201  08461020
RECREDY  EQU   X'10'                                             20201  08464020
FF       EQU   X'FF'                                             20201  08467020
RDXCORE  DC    H'28'                    RD EXCLUSIVE ADDITIVE    20201  08470020
UCBTBYT4 EQU   19                      DEVICE TYPE IN UCB        YM5538 08472001
TYP2305  EQU   X'06'                   2305 DEVICE IN UCB        YM5538 08474001
RELREQ   EQU   X'40'                   IOS RELATED REQUEST       YM5538 08476001
TEMPECB  EQU   3                       OFFST TO RIGHT HALF CSW   YM5538 08478001
NEGNUMBR EQU   X'80'                   NEGATIVE ADDR             YM5544 08478801
PURGED   EQU   X'48'                   PURGED ECB CODE           YM5544 08479201
OFLINCR  EQU   8                       BYTES NECESSARY FOR OVERFLOW     08480000
*                                      RECORDS IN IOB(FOR EXTRA CCW)    08500000
*                                                                       08520000
RDADD    EQU   X'0A'          TEST FOR READ OR WRITE ADD                08540000
ADDKY    EQU   X'06'          TEST FOR KEY OR ADD                       08560000
RDXFDB   EQU   X'12'          TEST FOR READ EXCLUSIVE OR FEEDBACK       08580000
CPFLAG   EQU   X'42'          SET UNRELATED, COMMAND CHAIN BITS         08600000
SILI     EQU   X'20'         SUPPRESS INCORRECT LENGTH INDICATION       08620000
NOPCODE  EQU   X'03'     NO OP                                          08640000
ONE      EQU   X'01'     COUNT OF ONE                                   08660000
CCHN     EQU   X'40'         COMMAND CHAIN BIT IN CCW                   08680000
ENQPL    EQU   28                       ENQUE LIST LENGTH               08700000
CNVENTRY EQU   12                       ENTRY IN ADDR CONV RTN   A35339 08710021
*                                                                       08720000
         DROP  DECBREG                                                  08730001
         EJECT                                                          08740000
*                                                                       08760000
*                                                                       08780000
*  ASYNCHRONOUS INTERRUPT ROUTINE                                       08800000
*   THIS ROUTINE IS ENTERED         BY SUPERVISOR SO THAT BDAM MAY      08820000
*   COMPLETE THE PROCESSING OF A REQUEST.                               08840000
*   BDAM EXPECTS THE FOLLOWING REGISTER USAGE'                          08860000
*     1 12* ADDRESS                                                     08880000
*    14 RETURN POINT                                                    08900000
*    15 ENTRY POINT OF THIS ROUTINE                                     08920000
*                                                                       08940000
         USING IECDFDNA,EPREG                                           08960000
         USING IOBSTDRD,PARAM                                           08980001
         USING IHADCB,SAVE                                              09000000
         DROP  FDNBASE                                                  09020000
         DROP  IOBREG                                                   09040000
         DROP  DCBREG                                                   09060000
RIOB     EQU   2                  IOB ADDRESS                           09070001
GPR7     EQU   7                  REG 7 WILL SAVE 12* ADDRESS           09080001
RETURN   EQU   9                  RETURN REGISTER FOR READX & ADD       09100001
READADD  EQU   10                 ENTRY POINT REG FOR READX & ADD       09120001
RRETCODE EQU   15                 RETURN CODE REGISTER                  09126001
FREEDBUF EQU   57                 FREE DYNAMIC BUFFER SVC               09132001
B1       EQU   1                  ONE BYTE OFFSET TO ADDR       YA02106 09134003
*                                                                       09140000
IECDFDNA BC    15,DASIA       ENTRY FROM SUPERVISOR                     09160000
         BC    15,DASIB       ENTRY FROM SELF-FORMAT                    09180000
         BC    15,DASIC       ENTRY FROM READ EXCLUSIVE (WRITE)         09200000
         BC    15,DASID       ENTRY FROM SELF-FORMAT, READ-EXCLUSIVE    09220000
*                                                                       09240000
DASIA    EQU   *                                                        09260000
         LR    GPR7,PARAM              SAVE IOS 12* ADDRESS             09280000
         L     PARAM,4(0,PARAM)         GET IOB ADDRESS FROM 12*        09300000
         LR    INTRET,RETREG           MOVE SUPVERVISOR RETURN ADDRESS. 09320000
         L     DECBREG,IOBECBPT   GET DECB ADDRESS                      09326001
         USING DECB,DECBREG                                             09332001
         TM    IOBDSTAT,EXCPMSK        DID END OF EXTENT CAUSE ASI      09340000
         BC    8,TSTERR                 NO, CONTINUE LOOKING FOR CAUSE. 09360000
         XI    IOBDSTAT,EXCPMSK+ABNMSK YES,CLEAR EXCP AND ABNORM. BITS  09380000
         MVC   IOBDQPTR+B1(3),IOBECBPT+B1     SAVE ECB ADDR     YA02106 09430003
         LA    WKREG3,IOBCSW+3          ADDR OF RIGHT HALF CSW   SM5472 09432021
         ST    WKREG3,IOBECBPT          USE AS TEMPORARY ECB     SM5472 09434021
         EXCP  (1)                      RESTART THE CHANNEL PROGRAM     09440000
         BCR   15,INTRET                GO BACK TO SUPERVISOR.          09480000
*                                                                       09500000
TSTERR   L     SAVE,IOBDCBPT           ESTABLISH DCB BASE.              09520000
         LR    FDNBASE,EPREG           MOVE BASE TO TRANSPARENT REG.    09540000
         DROP  EPREG                                                    09560000
         USING IECDFDNA,FDNBASE        PICK UP NEW BASE                 09580000
         AIF   ('&LIB' EQ 'LIB1').LIB1AA                                09580401
         USING RQE,GPR7                                                 09580801
         L     WKREG2,TSTTCB      GET TCB ADDRESS                       09581201
         USING TCB,WKREG2                                               09581601
         TM    TCBFLGS6,TCBRV     IS TASK IN REAL ADDRSPCE?             09582001
         BO    DBFNODBF           BRANCH IF YES                         09582401
         DROP  GPR7                                                     09582801
         DROP  WKREG2                                                   09583201
*                                                                       09583601
         TM    IOBDTYPE,IOBDYNBF  IS REQUEST WITH DYNAMIC BUFFER        09584001
         BZ    DBFNODBF           BRANCH IF NO                          09584401
         LR    RIOB,PARAM                                               09584801
         DROP  PARAM                                                    09585201
         USING IOBSTDRD,RIOB                                            09585601
*                                                                       09586001
*                       IF CHANNEL PROGRAM WAS MODIFIED, RESTORE        09586401
*                       IT.                                             09586801
*                                                                       09587201
         TM    IOBDQSW,IOBDQCP    WAS CHANNEL PROGRAM MODIFIED?         09587601
         BZ    DBFASI             BRANCH IF NO                          09588001
         MVC   IOBCHNPR(L'DECARB1),DECARB1   RESTORE CCW1 OP-CODE       09588401
         MVC   IOBCHNPR+SCNDHALF(L'DECARB2),DECARB2   RESTORE           09588801
*                                                  CCW FLAGS            09589201
         CLC   DCBDYNB+SKPHIBYT(CMP3BYTS),IOBDQPTR+SKPHIBYT             09589601
*                                 LIST EXTENDED                         09589701
*                                 SINCE THE TIME OF THIS SIO?           09590001
         BNE   DBFCKXCP           YES, DON'T EXTEND NOW                 09590401
*                                                                       09590801
*                       GO TO DYNAMIC BUFFER MODULE                     09591201
*                                                                       09591601
         LR    PARAM,SAVE         R1 = DCB ADDRESS                      09592001
         LCR   PARAM2,DECBREG     R0 = DECB ADDRESS COMPLEMENTED        09592401
         SVC   FREEDBUF           ISSUE SVC 57                          09592801
         LTR   RRETCODE,RRETCODE  DID EXTEND GO RIGHT?                  09593201
         BZ    DBFCKXCP           YES, REISSUE EXCP NOW                 09593601
         OI    IOBSTAT2,OTHERERR  SET ERROR INDICATIONS                 09594001
         B     MAKEAVL            GO TO MAKE IOB AVAIL.                 09594401
*                                                                       09594801
DBFCKXCP NI    IOBDQSW,X'FF'-IOBDQCP   RESET SWITCH                     09595201
         MVC   IOBDQPTR+B1(3),IOBECBPT+B1     SAVE ECB ADDR     YA02106 09595603
         LA    WKREG3,IOBCSW+3    RIGHT HALF OF CSW              SM5472 09596203
         ST    WKREG3,IOBECBPT    USE AS TEMPORARY ECB           SM5472 09596303
         EXCP  (RIOB)             RE-ISSUE EXCP                         09596403
         BR    INTRET             RETURN TO SUPERVISOR                  09596801
*                                                                       09597201
DBFASI   EQU   *                  RESTORE REGS FOR REST OF MOD          09597601
         LR    PARAM,RIOB         RESTORE IOB ADDR TO R1                09598001
         DROP  RIOB                                                     09598401
         USING IOBSTDRD,PARAM                                           09598801
DBFNODBF EQU   *                  HERE IF NO DYNAMIC BUFFERING          09599201
.LIB1AA  ANOP                                                           09599601
         ST    INTRET,IOBDQPTR         SAVE SUPVERVISOR RETURN IN IOB.  09600000
         LR    INTRET,PARAM            PUT IOB ADDR INTO READX REG      09620000
         TM    IOBDSTAT,ABNMSK          WAS THIS ABNORMAL COMPLETION    09640000
         BO    ASIERR                   BRANCH IF YES                   09660000
         TM    IOBDTYPE,READX          IS READX EXCLUSIVE SPECIFIED     09680000
         BO    ENQRCD                   YES CHECK IF RECORD ENQ'D       09700000
         TM    IOBDTYPE+1,ADD          IS WRITE ADD SPECIFIED           09720000
         BZ    ASI2NDEN                 NO TEST FOR CHANNEL PROGRAM END 09740000
         TM    DCBRECFM,FIXDMSK         IS THIS FIXED LENGTH RECORDS    09760000
         BZ    ASI2NDEN                 YES, TEST FOR CHANNEL PROG. END 09780000
ENQRCD   EQU   *                                                        09800000
         TM    IOBDTYPE+1,READ+ADD     YES-IS THIS A READ OR WRITE ADD  09820000
         BZ    ASI2NDEN                 NO TEST FOR CHANNEL PROGRAM END 09840000
         TM    IOBDSTAT,ENQD           HAS RECORD BEEN OBTAINED YET     09860000
         BO    ASI2NDEN                YES-GO TEST FOR PROGRAM END      09880000
         TM    IOBDTYPE+1,ADD           IS THIS A WRITE ADD       13513 09883015
         BO    ENQUEUE                  YES--ENQUEUE IT           13513 09886015
         CLC   IOBDCPND+SKPHIBYT(CMP3BYTS),IOBCSW     CHANNEL           09889001
*                                                PROGRAM FINISHED?      09891001
         BNE   ASIERR2                  NO RECORD FOUND           24512 09892018
ENQUEUE  EQU   *                                                  13513 09895015
         L     READADD,DCBDRDX         NO-LOAD ADDR OF EXCLUSIVE MOD.   09900000
         BALR  RETURN,READADD          AND LINK TO IT                   09920000
         SVC   EXIT                     RETURN TO SUPERVISOR            09940000
ASI2NDEN CLC   IOBDCPND+SKPHIBYT(CMP3BYTS),IOBCSW     WAS CHANNEL       09960001
*                                                 PROGRAM FINISHED?     09962001
         BE    DASIE                    BRANCH IF COMPLETE              09980000
         TM    IOBDTYPE+1,ADD          IS THIS A WRITE ADD              10000000
         BZ    ASIERR2                  BRANCH IF AN ERROR        24512 10020018
         TM    DCBRECFM,FIXDMSK         FIXED LENGTH RECORDS            10040000
         BZ    ASIERR2                  IF SO, AN ERROR OCCURRED  24512 10060018
         L     READADD,DCBDFOR         GET BASE OF SELF FORMAT MODULE   10080000
         B     8(0,READADD)            AND BRANCH TO IT                 10100000
*                                                                       10120000
DASIB    TM    IOBDTYPE,RDXFDB         IF NOT READ EXCLUSIVE OR         10140000
         BC    8,DASIC                  FEEDBACK OPTION, SKIP NEXT RTN. 10160000
*                                                                       10180000
*  THE FOLLOWING ROUTINE LOCATES OR DEVELOPS ACTUAL ADDRESS FOR USE AS  10200000
*     FEEDBACK AND/OR READ EXCLUSIVE ARGUMENT                           10220000
*                                                                       10240000
         TM    IOBDSTAT,RCDFIT         IS THIS A SELF FORMAT ADD        10260000
         BO    TSTEXIT                  YES-SKIP MOVING FEEDBACK        10280000
         MVC   IOBSEEK+2(6),IOBDNRCF+1 ELSE MOVE ACTUAL TO COMMON FIELD 10300000
*                                                                       10320000
*  IF THIS WAS A WRITE TO RELEASE AN EXCLUSIVE RECORD, GO TO THE READ   10340000
*   EXCLUSIVE MODULE WITHOUT TESTING FOR FEEDBACK TO BE RETURNED.       10360000
*                                                                       10380000
TSTEXIT  TM    IOBDTYPE+1,READ         IS THIS A READ OR WRITE          10400000
         BC    1,TSTFDB                 READ, GO TEST FOR FEEDBACK      10420000
         TM    IOBDTYPE,READX          IF WRITE AND EXCLUSIVE BITS SET, 10440000
         BC    1,RDXEXIT                  GO TO THE READX MODULE        10460000
TSTFDB   TM    DCBOPTCD,FEEDB            DCB DOES NOT SPECIFY           10480000
         BC    8,ACTFDBK                  FEEDBACK                      10500000
         TM    IOBDTYPE,ACTAD              OR ADDRESSING IS ACTUAL      10520000
         BC    8,TSTRR                      RETURN                      10540000
ACTFDBK  L     WORKR1,IOBECBPT               ACTUAL ADDRESS             10560000
         L     WORKR1,DECRECPT-DECB(0,WORKR1)  AS                       10580001
         MVC   0(8,WORKR1),IOBSEEK             FEEDBACK.                10600000
         B     DASIC                    GO TEST FOR DYNAMIC BUFFERING   10620000
DASIE    TM    IOBDTYPE,READX           IS THIS A READX                 10640000
         BO    DASIB                    BRANCH IF YES                   10660000
         TM    IOBDTYPE+1,READ          IS THIS A READ                  10680000
         BO    DASIB                    BRANCH IF YES                   10700000
         TM    DCBRECFM,FIXDMSK         IS THIS FIXED LENGTH RECORDS    10720000
         BZ    DASIB                    BRANCH IF FIXED LENGTH          10740000
         TM    IOBDTYPE+1,RELEX+ADD     IS THIS A RELEX REQUEST/WRT ADD 10760000
         BZ    DASIB                    BRANCH IF NO                    10780000
         L     READADD,DCBDRDX          GET ADDRESS OF EXCLUSIVE MODULE 10800000
         BALR  RETURN,READADD           AND LINK TO IT                  10820000
         B     DASIB                                                    10840000
RDXEXIT  L     READADD,DCBDRDX         GET ADDR OF EXCLUSIVE MODULE     10860000
         BALR  RETURN,READADD          AND LINK TO IT                   10880000
         B     DASIC                   CHECK FOR DYNAMIC BUFFERING      10900000
*                                                                       10920000
TSTRR    LA    INTRET,DASIC             SET UP TO TEST FOR DYN. BUFF.   10940000
*                                       ON RETURN FROM ADDR CONVERSION  10960000
         TM    IOBDTYPE,RELRD           IS RELATIVE RECORD BEING        10980000
         BC    8,RTEXIT                 USED,NO-GO TO RELATIVE TRACK    11000000
         L     EPREG,DCBDFBK             LOAD ENTRY POINT OF FEEDBACK   11020000
         BCR   15,EPREG                  MODULE AND GO THERE            11040000
*                                                                       11060000
RTEXIT   L     EPREG,DCBREAD           LOCATE THE                       11080000
         L     EPREG,8(0,EPREG)          ADDR OF RELATIVE TRACK MODULE  11100000
         B     FDBKOFFS(EPREG)                  AND GO THERE            11130001
*                                                                       11140000
*                                                                       11160000
DASIC    TM    IOBDTYPE+1,READ         IS THIS A READ REQUEST           11180000
         BO    DASID                    YES-POOL THE IOB                11200000
         TM    IOBDTYPE,DYNBF           NO-TEST FOR DYN. BUFFERING      11220000
         BZ    DASID                    NO-POOL THE IOB                 11240000
*                                                                       11260021
*                       FREE DYNAMIC BUFFER                             11264021
*                                                                       11268021
         LR    SAVE,PARAM               SAVE IOB POINTER         XM5413 11270001
         USING IOBSTDRD,SAVE                                            11272001
         L     PARAM2,IOBECBPT         ADDR OF DECB              A30797 11276021
         L     PARAM,IOBDCBPT     ADDR OF DCB                    A30797 11280021
         FREEDBUF (0),D,(1)       ISSUE FREEDBUF SVC CALL        A30797 11284021
         LR    PARAM,SAVE         RESTORE IOB POINTER            A30797 11288021
         USING IOBSTDRD,PARAM                                           11290001
         L     SAVE,IOBDCBPT      RESTORE DCB POINTER            A30797 11292021
         USING IHADCB,SAVE                                       A30797 11296021
*                                                                       11300000
*  THE FOLLOWING ROUTINE LINKS IOB'S TO THE DCB POOL IF THEY WERE       11320000
*    OBTAINED BY GETMAIN, OR IF ALREADY IN THE POOL, IT ZEROES THE      11340000
*    AVAILABILITY BYTE AND POST'S COMPLETION                            11360000
*                                                                       11380000
*    NOTE: THIS ROUTINE IS ENTERED FROM BOTH THE WRITE ADD (19KM)       11390003
*          AND EXCLUSIVE CONTROL MODULES (19LG). THEY BOTH ASSUME       11392003
*          THE INTEGRITY OF CERTAIN REGISTERS ON RETURN. CHECK          11394003
*          WHICH ONES BEFORE ADDITIONAL REGISTERS ARE USED IN           11396003
*          THIS ROUTINE.                                                11398003
*                                                                       11398403
DASID    L     WORKR1,IOBDPLAD         WAS IOB FROM POOL OR OBTAINED    11400000
         LTR   WORKR1,WORKR1            BY GETMAIN                      11420000
         BC    8,POOL                     GO PUT NEW IOB ON POOL        11440000
MAKEAVL  SR    PARAM2,PARAM2           CLEAR FOR EXCEPTION CODES.       11460000
         IC    PARAM2,IOBSTAT2    INSERT EXCEP. CODES FROM THE IOB      11480001
         SLL   PARAM2,16               POSITION THEM FOR POST.          11500000
* ATTENTION MAINTENANCE PROGRAMMERS: THE NEXT INSTRUCTION WILL  XA02860 11550003
* CHANGE THE BASE REGISTER. DO NOT INSERT CODE WHICH REQUIRES   XA02860 11560003
* A BASE BETWEEN HERE AND 'SUPEXIT'.                            XA02860 11570003
         L     FDNBASE,IOBDQPTR         LOAD STORED SUPERVISOR RETURN   11580000
         LR    RIOB,PARAM               SAVE IOB ADDR            XM5240 11590003
         L     PARAM,IOBECBPT          SET DECB PARAMETER               11600000
         LA    PARAM,0(0,PARAM)         CLEAR HIGH ORDER BITS    A29259 11610019
*                                                                       11620000
         POST  (1),(0)                  AND POST.                       11640000
         TM    DCBMACRF,CHECK           CHECK SPECIFIED?        XA02860 11650003
         BCR   1,FDNBASE                BR IF YES               XA02860 11652003
         USING IOBSTDRD,RIOB            TEMP BASE FOR IOB        XM5240 11654003
         MVI   IOBDAVLI,0               SET IOB AVAILABLE       XA02860 11656003
         DROP  RIOB                     DROP TEMP BASE           XM5240 11658003
SUPEXIT  BR    FDNBASE               RETURN TO SUPERVISOR               11660001
*                                                                       11680000
*                                                                       11700000
POOL     EQU   *                                                        11720000
         LA    PARAM,0(PARAM)     CLEAR HI-ORDER BYTE            A44088 11740021
         L     WORKR1,DCBIOBAD         PUT DCB POOL ADDRESS IN          11760000
         LA    WORKR2,0(WORKR1)        BOTH WORK REGS.            10141 11770015
LOOP     LA    WORKR1,0(WORKR1)         CLEAR HI BYTE.            10141 11780015
         LTR   WORKR1,WORKR1            ANY IOB'S BEYOND THIS.    10141 11790015
         BC    8,TSTEQ                  NO, GO TEST FOR FIRST IOB       11820000
*                                                                       11840000
*   PUT IOB ON POOL IN ORDER OF INCREASING SIZE.                        11860000
*                                                                       11880000
         CLC   IOBDIOBS,IOBDIOBS-IOBSTDRD(WORKR1)                       11900001
         BC    2,SEENEXT1                  NEW IOB IS LARGER            11920000
         ST    WORKR1,IOBDPLAD    STORE NEXT ADDR IN CURRENT IOB A35339 11926021
         MVI   IOBDAVLI,UNAVALSW    SET IOB UNAVAILABLE                 11932001
TSTEQ    CR    WORKR1,WORKR2              IF EQUAL, THIS IOB IS THE     11940000
         BC    8,FIRSTIOB                   FIRST ONE TO BE POOLED      11960000
*                                                                       11980000
*   RELINK THE POOL CHAIN WITHOUT DESTROYING THE AVAILABILITY FLAG.     12000000
*                                                                       12020000
         IC    PARAM2,IOBDAVLI-IOBSTDRD(0,WORKR2)  PICK UP FLAG         12040001
         SLL   PARAM2,24                         AS HI-ORDER BYT A35339 12046021
         OR    PARAM,PARAM2                      COMPLETE WORD   A35339 12052021
         ST    PARAM,IOBDPLAD-IOBSTDRD(0,WORKR2)                        12060001
         MVI   IOBDAVLI,UNAVALSW        MARK  IOB UNAVAILABLE    XM0911 12110002
         B     MAKEAVL                  GO COMPLETE IOB PROCESSING      12200000
*                                                                       12220000
FIRSTIOB ST    PARAM,DCBIOBAD          INSERT THIS IOB AS TOP OF CHAIN  12240000
         MVI   IOBDAVLI,X'FF'          SET IOB UNAVAILABLE      SA53267 12250000
         B     MAKEAVL            GO COMPLETE IOB PROCESSING     A35339 12260021
SEENEXT1 LR    WORKR2,WORKR1            SAVE THE ADDRESS OF PRIOR LINK, 12280000
         L     WORKR1,IOBDPLAD-IOBSTDRD(0,WORKR1)  LOAD THE ADDRESS OF  12300001
*                                                 THE NEXT IOB IN POOL  12320000
         B     LOOP                      GO TEST LINK ADDRESS = ZERO    12340000
*                                                                       12360000
*    THE FOLLOWING ROUTINE DETERMINES THE CAUSE OF ABNORMAL COMPLETION  12380000
*     BY ANAYSING THE SENSE BYTES AND CSW STORED IN THE IOB BY IOS.     12400000
*                                                                       12420000
*                                                                       12440000
ASIERR   EQU   *                                                 SM5472 12450021
         TM    IOBDSTAT+1,ALLMSK       HAS ERROR ALREADY BEEN FLAGGED   12486601
         BC    4,ERREXIT                  IF YES , EXIT                 12493301
         TM    IOBCSW+3,UCMSK          TEST FOR UNIT CHECK              12500001
         BC    8,TSTEXC                  BR. IF NOT                     12520000
         TM    IOBSENS0,DCMSK          TEST FOR DATA CHECK              12540001
         BC    1,SETUDC                  BRANCH IF YES                  12560000
         TM    IOBSENS1,NRMSK          TEST NO RECORD FOUND             12580001
         BC    8,SETUE                   IF NOT SET, MUST BE UNRELATED  12600000
ASIERR2  OI    IOBDSTAT+1,NOREC        SET NO RECORD FOUND EX. CODE     12620000
         TM    IOBDTYPE+1,ADD          IS TYPE WRITE ADD                12640000
         BC    8,DASIC                  NO, RETURN TO POOLING ROUTINE   12660000
         XI    IOBDSTAT+1,FLIPMSK      CHG NO-RCD-FOUND TO NO-SPACE-FND 12680000
         B     DASIC                 GO BACK TO ASI TESTING             12700001
*                                                                       12720000
SETUDC   OI    IOBDSTAT+1,UNCOR        SET UNCORRECTABLE DATA CHECK     12740000
         B     ERREXIT               GO TEST FOR EXIT                   12760001
*                                                                       12780000
TSTEXC   EQU   *                                                        12800000
         TM    IOBCSW+4,INCLMSK        WAS THE RECORD WRONG LENGTH      12820001
         BC    1,SETINCL                 IF YES GO SET FLAG             12840000
SETUE    OI    IOBDSTAT+1,UNREL        SET UNRELATED ERROR FLAG         12860000
*                                                                       12880000
ERREXIT  TM    IOBDSTAT,FMATMSK        IF THIS WAS A FORMAT WRITE,      12900000
         BC    1,12(0,EPREG)           GO SCAN UNSCHEDULED QUEUE        12920000
         TM    IOBDSTAT+1,INCLMSK+ENDOD IF INCORRECT LENGTH OR END OF   12940000
         BC    7,DASIB                  DATA SET, GO CHECK FEEDBACK     12960000
         B     DASIC                   ELSE BYPASS FEEDBACK TEST        12980000
*                                                                       13000000
SETINCL  OI    IOBDSTAT+1,LGNCK        SET INCORRECT LENGTH EXCEPTION   13020000
         B     ERREXIT                  CODE, GO DETERMINE EXIT         13040000
*                                                                       13060000
*                                                                       13080000
EIGHT    DC    F'8'                                                MC0J 13086000
READCCW  EQU   X'06'                                               MC0J 13092000
EXIT     EQU   3                        SVC NUMBER TO RETURN TO SUPERV. 13100000
ENQD     EQU   X'08'                    INDICATION FROM EXCLUSIVE MOD.  13120000
*                                       THAT RECORD HAS BEEN OBTAINED   13140000
RCDFIT   EQU   X'02'                   INDICATION FROM SELF FORMAT MOD. 13160000
*                                       THAT THE RECORD FIT             13180000
RTRKOFFS EQU   X'0C'                   OFFSET TO REL TRK ENTRY IN       13190001
*                                      CONVERT ROUTINE                  13190401
FDBKOFFS EQU   X'08'              OFFSET TO FEEDBACK ENTRY              13190501
*                                 IN CONVERT ROUTINE                    13190601
SKPHIBYT EQU   X'01'             OFFSET TO START AT SCND BYTE OF WORD   13190801
*                                 FOR THREE BYTE COMPARES               13191201
CMP3BYTS EQU   X'03'              USED FOR THREE-BYTE COMPARES          13191601
UNAVALSW EQU   X'FF'              IOB UNAVAILABLE SWITCH                13192001
SCNDHALF EQU   X'04'                   SECOND HALF OF CCW               13192401
RELEX    EQU   X'01'                    RELEX INDICATOR                 13200000
CHECK    EQU   X'01'                   CHECK MACRO BEING USED BIT       13260000
WORKR1   EQU   EPREG     WORK REGISTER IN ASI ROUTINE                   13280000
WORKR2   EQU   RETREG    WORK REGISTER IN ASI ROUTINE                   13300000
FLIPMSK  EQU   X'A0'     CHANGE NO RECORD FOUND TO NO SPACE FOUND       13320000
ABNMSK   EQU   X'80'     ABNORMAL COMPLETION                            13340000
EXCPMSK  EQU   X'40'     EOE CAUSED ASYNCHRONOUS INTERRUPT              13360000
FMATMSK  EQU   X'02'     WRITE ADD, SELF FORMAT FLAG                    13380000
ALLMSK   EQU   X'FF'     TEST FOR EXCEPTION CODES                       13400000
INCLMSK  EQU   X'40'     INCORRECT LENGTH                               13420000
NRMSK    EQU   X'08'     NO RECORD FOUND                                13440000
UCMSK    EQU   X'02'     UNIT CHECK                                     13460000
DCMSK    EQU   X'08'     DATA CHECK                                     13480000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   13500000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   13520000
         EJECT                                                          13540000
*              EXCEPTION CODES                                          13560000
NOREC    EQU   X'80'                                                    13580000
LGNCK    EQU   X'40'                                                    13600000
NOSPA    EQU   X'20'                                                    13620000
INVAL    EQU   X'10'                                                    13640000
UNCOR    EQU   X'08'                                                    13660000
ENDOD    EQU   X'04'                                                    13680000
UNREL    EQU   X'02'                                                    13700000
*              OPTIONS AND TYPE                                         13720000
VERIFY   EQU   X'80'                                                    13740000
OFLOW    EQU   X'40'                                                    13760000
EXSCH    EQU   X'20'                                                    13780000
FEEDB    EQU   X'10'                                                    13800000
ACTAD    EQU   X'08'                                                    13820000
DYNBF    EQU   X'04'                                                    13840000
READX    EQU   X'02'                                                    13860000
RELRD    EQU   X'01'                                                    13880000
KEYOP    EQU   X'80'                                                    13900000
LGNOP    EQU   X'40'                                                    13920000
READ     EQU   X'08'                                                    13940000
KEY      EQU   X'04'                                                    13960000
ADD      EQU   X'02'                                                    13980000
KEYMASK  EQU   X'F0'                                            YA04292 13990021
*      DATA CONTROL BLOCK (DCB) DEFINITION                              14000000
*                                                                       14020000
*                                                                       14040000
         DCBD  DSORG=DA                                                 14060000
         EJECT                                                          14080000
         IHADECB                                                        14100001
         AIF   ('&LIB' EQ 'LIB1').LIB1CA                                14110001
         ORG   DECAREA                                                  14120001
DECARB1  DS    X                  SAVED OP-CODE FOR CCW1                14130001
DECARB2  DS    X                  SAVED FLAGS FOR CCW1                  14140001
*                                                                       14150001
RQE      DSECT                                                          14160001
TSTLNK   DS    AL2           LINK FIELD                                 14170001
TSTUCB   DS    AL2           UCB ADDRESS                                14180001
TSTIOB   DS    A             IOB ADDRESS                                14190001
TSTDEB   DS    A             DEB ADDRESS                                14200001
TSTTCB   DS    A             TCB ADDRESS                                14210001
.LIB1CA  ANOP                                                           14220001
         EJECT                                                          14320000
         IEZIOB                                                         14340001
CCW1     DS    D                  CHANNEL COMMAND # 1                   14390001
CCW2     DS    D                  CHANNEL COMMAND # 2                   14392001
CCW3     DS    D                  CHANNEL COMMAND # 3                   14394001
         ORG   IOBDAYLI           ********************                  14400001
IOBDAVLI DS    B                  ******************                    14460001
         ORG   IOBDQPTR+4         *******************                   14520001
IOBUPLIM DS    XL8                ******************                    14580001
IOBDNRCF DS    CL8                ******************                    14640001
         AIF   ('&LIB' EQ 'LIB1').LIB1BA                                14700001
         ORG   IOBSTAT2                                                 14760001
OTHERERR EQU   BIT6               ERROR INDICATED IN NXT 2 BYTES        14820001
         ORG   IOBDQPTR                                                 14880001
IOBDQSW  DS    B                  FLAGS                                 14940001
IOBDQCP  EQU   BIT0               CHANNEL PGM ALTERED IN SIO APD        15000001
.LIB1BA  ANOP                                                           15060001
         IKJTCB                                                         15120001
         EJECT                                                          15260000
*                                                                       15280000
*      DATA EXTENT BLOCK (DEB) DEFINITION                               15300000
*                                                                       15320000
DEBDEF   DSECT                                                          15340000
         DS    0F                                                       15360000
DEBNMSUB DS    0CL1      NO. OF SUBR. LOADED BY OPEN                    15380000
DEBTCBAD DS    CL4       ADDRESS OF THE TCB FOR THIS DEB                15400000
DEBAMLNG DS    0CL1      NO. OF BYTES IN THE ACCESS MTHD. DPDT. SECTION 15420000
DEBDEBAB DS    CL4       ADDRESS OF THE PREVIOUS DEB IN THE SAME TASK   15440000
DEBOFLGS DS    0CL1      DATA SET STATUS FLAGS                          15460000
DEBIRBAD DS    CL4       IRB ADDRESS                                    15480000
DEBOPATB DS    0CL1      TYPE OF FILES                                  15500000
DEBSYSPG DS    CL4       ADDRESS OF FIRST IOB IN THE SYSTEM PURGE CHAIN 15520000
DEBNMEXT DS    0CL1      NUMBER OF EXTENTS SPECIFIED IN THE DSCB        15540000
DEBUSRPG DS    CL4       ADDRESS OF FIRST IOB IN THE USER PURGE CHAIN   15560000
DEBPRIOR DS    0CL1      ALWAYS ZERO                                    15580000
DEBECBAD DS    CL4       ECB ADDRESS FOR SVC PURGE REQUEST              15600000
DEBPROTG DS    0CL1      RESERVED FOR FUTURE USE (FIRST 4 BITS)         15620000
DEBDEBID DS    0CL1      HEX 'F' TO IDENTIFY THIS BLOCK AS A DEB        15640000
DEBDCBAD DS    CL4       ADDRESS OF THE DCB ASSOCIATED WITH THIS DEB    15660000
DEBEXSCL DS    0CL1      EXTENT SCALE                                   15680000
DEBAPPAD DS    CL4       ADDRESS OF I/O APPENDAGE VECTOR TABLE          15700000
DEBDVMOD DS    0CL1      DEVICE MODIFIER FILE MASK                      15720000
DEBUCBAD DS    CL4       ADDR OF UCB ASSOCIATED WITH THIS DATA EXTENT   15740000
DEBBINUM DS    CL2       RESERVED FOR FUTURE USE-ALWAYS ZERO            15760000
DEBSTRCC DS    CL2       STARTING CYLINDER NUMBER FOR EXTENT            15780000
DEBSTRHH DS    CL2       STARTING HEAD NUMBER FOR EXTENT                15800000
DEBENDCC DS    CL2       ENDING CYLINDER NUMBER FOR EXTENT              15820000
DEBENDHH DS    CL2       ENDING HEAD NUMBER FOR EXTENT                  15840000
DEBNMTRK DS    CL2       NUMBER OF TRACKS ALLOCATED TO A GIVEN EXTENT   15860000
DEBSUBID EQU   0         SUBROUTINE ID'S                                15880000
         END                                                            15900000
