IGG019KC CSECT                                                          00020000
*                                                                       00040000
 TITLE   'IGG019KC - RELATIVE TRACK CONVERSION MODULE'                  00060000
*STATUS- CHANGE LEVEL 1 12/01/72                                      * 00080002
*4093002800,016600                                               A35339 00090021
*                                                               SA55595 00092002
*                                                                XM1263 00098002
*FUNCTION/OPERATION- THIS MODULE IS LOADED IF THE DCB INDICATES THAT  * 00100000
*   ADDRESSING IS BY RELATIVE TRACK (TT OR TTR), AND IS COMPOSED OF   * 00120000
*   TWO ROUTINES. 1.CONVERT TTR TO AN ACTUAL (MBBCCHHR) ADDRESS PRIOR * 00140000
*   TO EXECUTING THE I/O REQUEST.                                     * 00160000
*   2.CONVERT AN ACTUAL ADDRESS TO A TTR VALUE FOR FEEDBACK AFTER THE * 00180000
*   REQUEST HAS COMPLETED SUCCESSFULLY.                               * 00200000
*                                                                     * 00220000
*ENTRY POINTS- THE ENTRY TO THE FIRST ROUTINE (TTR TO ACTUAL) IS      * 00240000
*   'IECDRTB' WITH THE CALLING SEQUENCE,  L     15,8(IGG019KA BASE)   * 00260000
*                                        BAL  14,12(15)                 00280021
*   THE  ENTRY TO THE SECOND ROUTINE (ACTUAL TO TTR) IS 'IGG019KC'    * 00300000
*   (IECDRT) WITH THE CALLING SEQUENCE    L     15,8(IGG019KA BASE)   * 00320000
*                                         BALR  14,15                 * 00340000
*                                                                       00346021
*   THE ENTRY FROM RELEX IS VIA A SYNCH TO BEGINNING                  * 00352021
*                                                                     * 00360000
*INPUT- FOR THE FIRST ROUTINE THE REGISTERS ARE SET AS FOLLOWS,       * 00380000
*   3 - DEB ADDRESS                                                   * 00400000
*   4 - DCB ADDRESS                                                   * 00420000
*   5 - DECB ADDRESS                                                  * 00440000
*   7 - IOB ADDRESS                                                   * 00460000
*   11- BASE ADDRESS FOR MODULE IGG019KA (FOUNDATION MODULE)          * 00480000
*                                                                     * 00500000
*   FOR THE SECOND ROUTINE THE FOLLOWING REGISTERS ARE INPUT,         * 00520000
*   1 - IOB ADDRESS                                                   * 00540000
*   13- DCB ADDRESS                                                   * 00560000
*                                                                     * 00580000
*OUTPUT- THE FIRST ROUTINE WILL PLACE MBBCCHHR INTO IOB SEEK ADDRESS. * 00600000
*   THE SECOND ROUTINE WILL PLACE TTR INTO THE USER'S BLKREF FIELD.   * 00620000
*                                                                     * 00640000
*EXTERNAL ROUTINES- 'IECPCNVT' IS USED TO CONVERT TTR TO ACTUAL.      * 00660000
*   'IECPRLTV' IS USED TO CONVERT ACTUAL TO A TTR VAUE.               * 00680000
*                                                                     * 00700000
*EXITS-NORMAL- 'D3EXIT1' IS THE NORMAL RETURN TO MODULE IGG019KA      * 00720000
*   AFTER AN ACTUAL ADDRESS HAS BEEN DEVELOPED AND STORED AT IOBSEEK. * 00740000
*   'D3EXIT2' IS THE RETURN TO THE ASYNCHRONOUS INTERRUPT ROUTINE IN  * 00760000
*   THE MODULE IGG019KA AFTER TTR FEEDBACK HAS BEEN DEVELOPED AND     * 00780000
*   STORED INTO THE USERS BLKREF FIELD.                               * 00800000
*                                                                     * 00820000
*EXIT-ERROR- 'D3EXIT3' IS AN EXIT TO THE INVALID REQUEST ERROR ROUTINE* 00840000
*   IN MODULE IGG019KA. A TT VALUE GREATER THAN THE NUMBER OF TRACKS  * 00860000
*   IN THE DATA SET HAS BEEN SPECIFIED TO THE TTR TO ACTUAL CONVERSION* 00880000
*   ROUTINE. REGISTER 12 IS USED TO PASS THE EXCEPTION CODE TO THE    * 00900000
*   ERROR ROUTINE.                                                    * 00920000
*                                                                     * 00940000
*TABLES/WORK AREAS- THE COMMUNICATION VECTOR TABLE IS USED TO LOCATE  * 00960000
*   THE ROUTINES, IECPCNVT AND IECPRLTV.                              * 00980000
*                                                                     * 01000000
*ATTRIBUTES- THE FIRST ROUTINE IS REENTRANT AND EXECUTED ENABLED.     * 01020000
*   THE SECOND ROUTINE IS EXECUTED DISABLED, WITH THE PROBLEM PROGRAM * 01040000
*   PROTECTION KEY AND IS REUSABLE.                                   * 01060000
*                                                                     * 01080000
*NOTES- REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT WITH THE * 01100000
*   MODULES, IGG019KA, IECPCNVT, IECPRLTV.                            * 01120000
*                                                                       01140000
*                                                                       01160000
         USING IGG019KC,EPREG                                           01180000
         USING IOBDEF,IOBREG                                            01200000
         USING DECBDEF,DECBREG                                          01220000
         USING IHADCB,DCBREG                                            01240000
*                                                                       01260000
*                                                                       01280000
*  REGISTER USAGE                                                       01300000
*                                                                       01320000
D3CONVR  EQU   0         RELATIVE TRACK PARAMETER                       01340000
PARAM    EQU   1         DEB ADDRESS PARAMETER, (ASI-PARAM=IOB ADDRESS) 01360000
ACTUAL   EQU   2         ACTUAL ADDRESS LOCATION PARAMETER              01380000
DEBREG   EQU   3         DEB ADDRESS                                    01400000
DCBREG   EQU   4         DCB ADDRESS                                    01420000
DECBREG  EQU   5         DECB ADDRESS                                   01440000
D3WKREG  EQU   6         WORK REGISTER                                  01460000
IOBREG   EQU   7         IOB ADDRESS                                    01480000
GPR9     EQU   9         CONVERSION ROUTINE WORK REGISTERS ARE 9-13     01500000
FDNBASE  EQU   11        BASE FOR THE FOUNDATION MODULE                 01520000
D3ASIRET EQU   12        RETURN TO ASI                                  01540000
SAVE     EQU   13        USER'S SAVE AREA , (ASI- SAVE=DCB ADDRESS)     01560000
RETREG   EQU   14        RETURN TO FOUNDATION                           01580000
EPREG    EQU   15        BASE FOR THIS MODULE                           01600000
         EJECT                                                          01620000
*                                                                       01640000
RELEX    TM    IOBDTYPE+1,DRELEX       IS ENTRY FROM RELEX       A35339 01660021
         BO    IECDRTB                 YES, BR AROUND NEXT INST  A35339 01664021
         SPACE                                                          01668021
IECDRTA  BC    15,D3FDBK               GO TO THE FEEDBACK        A35339 01672021
*                                       ROUTINE                  A35339 01676021
*                                                                       01680000
IECDRTB  STM   GPR9,EPREG,IOBDNRCF     SAVE VOLATILE REGISTERS IN IOB   01700000
         LR    PARAM,DEBREG            SET DEB ADDR FOR CONVERSION RTN  01720000
         L     D3WKREG,DECRECPT        LOCATE USER'S ADDRESS AREA       01740000
         MVC   IOBDCPND(3),0(D3WKREG)  MOVE TTR TO ALIGN IT.            01760000
         TM    IOBDTYPE+1,KEYADD       IS TYPE ID                       01780000
         BC    8,*+8                    YES, LEAVE R AS STATED          01800000
         MVI   IOBDCPND+2,0             NO, MOVE A 0 TO R BYTE OF TTR   01820000
         L     D3CONVR,IOBDCPND        LOAD TTR0 TO CONVERSION REGISTER 01840000
         LA    ACTUAL,IOBSEEK          SET ACTUAL ADDRESS PARAMETER     01860000
D3LINK   EQU   *                                                        01880000
         L     EPREG,CVTPTR(0,0)       LOAD ADDRESS OF CONVERSION       01900000
         L     EPREG,CVTPCNVT-CVTDEF(0,EPREG) MODULE FROM COMM.         01920000
*                                             VECTOR TABLE              01940000
         BALR  RETREG,EPREG              AND GO THERE.                  01960000
*                                                                       01980000
         LM    GPR9,RETREG,IOBDNRCF    RESTORE ALL BUT R15       XM1263 02000002
         TM    IOBDTYPE+1,DRELEX       ENTRY FROM RELEX?         XM1263 02020002
         BCR   1,RETREG                RETURN IF YES             XM1263 02040002
         LTR   EPREG,EPREG             RETURN CODE FROM CONVERT  XM1263 02050002
         L     EPREG,SAV15(IOBREG)     RESTORE BASE REG          XM1263 02052002
         BZ    TSTPS2                  BR IF GOOD CONVERT        XM1263 02054002
         IC    D3ASIRET,INVREF         INSERT CAUSE FLAG FOR INVALID    02060000
         L     RETREG,ERROFF(0,FDNBASE) REQUEST, LOCATE ERROR ROUTINE,  02080000
D3EXIT3  BCR   15,RETREG                AND BRANCH THERE                02100000
*                                                                       02120000
TSTPS2   TM    IOBDCPND+3,D3PASS1      TEST 2ND PASS, EXTENDED SEARCH   02140000
         BC    1,D3CLR                  BRANCH YES                      02160000
D3TSTXS  TM    IOBDTYPE,EXSCH          IF EXTENDED SEARCH OPTION,       02180000
         BC    1,D3LOOP                 GO CALCULATE LIMIT ADDRESS.     02200000
         MVC   IOBUPLIM(7),IOBSEEK     DUPLICATE SEEK AS SEARCH LIMIT   02220000
D3EXIT1  BCR   15,RETREG               RETURN TO THE FOUNDATION MODULE. 02240000
*                                                                       02260000
*   THE FOLLOWING ROUTINE  DEVELOPS THE LIMIT TTR FOR EXTENDED SEARCH   02280000
*     AND RETURNS TO THE CONVERSION ROUTINE TO DEVELOP IOBUPLIM (ACTL)  02300000
*                                                                       02320000
D3LOOP   CLC   DCBREL+1(2),DCBLIMCT+1  IS SEARCH FOR ENTIRE DATA SET    02340000
         BC    13,D3WRAP                YES, GO SET END EQUAL TO START  02360000
*                                                                       02380000
         L     D3CONVR,IOBDCPND        LOAD SEARCH STARTING CC          02400000
         SRL   D3CONVR,16               GET RID OF EXTRA BYTES          02420000
         MVC   IOBCSW+2(2),DCBLIMCT+1  ALIGN NUMBER OF TRACKS TO SEARCH 02440000
         A     D3CONVR,IOBCSW          ADD TO BEGINNING TRACK NUMBER    02460000
         MVC   IOBCSW+2(2),DCBREL+1    ALIGN DATA SET SIZE(IN TRACKS)   02480000
         C     D3CONVR,IOBCSW          ARE WE OUT OF THE DATA SET RANGE 02500000
         BC    4,D3SHFT                NO , CONTINUE                    02520000
         S     D3CONVR,IOBCSW          YES,SUBTRACT DATA SET SIZE FROM  02540000
*                                         UPPER LIMIT TO GET SEARCH END 02560000
D3SHFT   EQU   *                                                        02580000
         SLL   D3CONVR,16              SHIFT TT, R WILL BE 0            02600000
         OI    IOBDCPND+3,D3PASS1      SET EXT. SEARCH PASS 1 FLAG ON.  02620000
         LA    ACTUAL,IOBUPLIM         SET ACTUAL ADDRESS PARAMETER     02640000
         BC    15,D3LINK                GO LINK TO CONVERSION ROUTINE   02660000
*                                                                       02680000
D3WRAP   EQU   *                                                        02700000
         MVC   IOBUPLIM(7),IOBSEEK     SET LIMIT TO SEARCH ALL TRACKS   02720000
D3CLR    CLC   IOBSEEK(1),IOBUPLIM     ARE SEEK, LIMIT IN SAME EXTENT   02740000
         BC    7,D3DUMMY                 IF NOT, GO DUMMY R BYTE        02760000
         CLC   IOBSEEK+3(4),IOBUPLIM+3   DID SEARCH WRAP AROUND         02780000
         BC    4,D3EXIT1                             NO, GO EXIT        02800000
D3DUMMY  MVI   IOBUPLIM+7,X'FF'         SET R BYTE TO DUMMY VALUE       02820000
         B     D3EXIT1                  RETURN TO THE FOUNDATION MODULE 02840000
*                                                                       02860000
*  FEEDBACK ROUTINE                                                     02880000
*                                                                       02900000
*                                                                       02920000
D3FDBK   STM   GPR9,ACTUAL,IOBDNRCF-IOBDEF(PARAM) SAVE REGISTERS USED   02940000
         LA    ACTUAL,IOBSEEK-IOBDEF(0,PARAM) SET ACTUAL ADDR.PARAMETER 02960000
         L     PARAM,DCBDEBAD-IHADCB(0,SAVE) SET DEB ADDRESS PARAMETER  02980000
         L     EPREG,CVTPTR(0,0)       LOAD ADDRESS OF CONVERSION       03000000
         L     EPREG,CVTPRLTV-CVTDEF(0,EPREG) MODULE FROM COMM.         03020000
*                                             VECTOR TABLE              03040000
         BALR  RETREG,EPREG              AND GO THERE.                  03060000
*                                                                       03080000
         USING CNVRET,RETREG                                            03100000
CNVRET   EQU   *                                                        03120000
         SH    ACTUAL,IOBOFF           ESTABLISH IOB BASE ADDRESS       03140000
         ST    D3CONVR,IOBDCPND-IOBDEF(0,ACTUAL) SAVE THE RETURNED TTR  03160000
         LM    GPR9,ACTUAL,IOBDNRCF-IOBDEF(ACTUAL)  RESTORE THE         03180000
*                                                  REGISTERS USED       03200000
         L     EPREG,IOBECBPT-IOBDEF(0,PARAM) LOCATE USER'S ADDR. AREA  03220000
         L     EPREG,DECRECPT-DECBDEF(0,EPREG)    AND                   03240000
         MVC   0(3,EPREG),IOBDCPND-IOBDEF(PARAM) MOVE TTR TO HIS  AREA  03260000
D3EXIT2  BCR   15,D3ASIRET             GO BACK TO THE ASI ROUTINE.      03280000
*                                                                       03300000
*                                                                       03320000
*                                                                       03340000
IOBOFF   DC    AL2(IOBSEEK-IOBFLAG1)   OFFSET OF IOBSEEK                03360000
INVREF   DC    X'10'     TTR IS OUTSIDE OF DATA SET                     03380000
ERROFF   EQU   20        OFFSET TO ERROR ROUTINE ADCON.                 03400000
ENTRY1   EQU   X'20'     TEST FOR ENTRY FROM ASI                        03420000
D3PASS1  EQU   X'10'     MASK FOR FIRST PASS BIT                        03440000
KEYADD   EQU   X'06'     TEST FOR TYPE = KEY OR ADD                     03460000
*              OPTIONS AND TYPE                                         03480000
VERIFY   EQU   X'80'                                                    03500000
OFLOW    EQU   X'40'                                                    03520000
EXSCH    EQU   X'20'                                                    03540000
FEEDB    EQU   X'10'                                                    03560000
ACTAD    EQU   X'08'                                                    03580000
DYNBF    EQU   X'04'                                                    03600000
READX    EQU   X'02'                                                    03620000
RELRD    EQU   X'01'                                                    03640000
KEYOP    EQU   X'80'                                                    03660000
LGNOP    EQU   X'40'                                                    03680000
READ     EQU   X'08'                                                    03700000
KEY      EQU   X'04'                                                    03720000
ADD      EQU   X'02'                                                    03740000
SAV15    EQU   X'60'                   REG 15 SAVE AREA IN IOB   XM1263 03742002
DRELEX   EQU   X'01'                   IOB BIT FOR RELEX         A35339 03750021
         DC    X'00'   FILLER - FILLER - FILLER                         03760000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   03780000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   03800000
         EJECT                                                          03820000
CVTDEF   DSECT                                                          03840000
         CVT                                                            03860000
         EJECT                                                          03880000
         DCBD  DSORG=DA                                                 03900000
         EJECT                                                          03920000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       03940000
         DS    0F                                                       03960000
DECBDEF  DSECT                                                          03980000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        04000000
DECTYPE  DS    CL2            TYPE FIELD                                04020000
DECLNGTH DS    CL2            DATA LENGTH                               04040000
DECDCBAD DS    CL4            ADDRESS OF DCB                            04060000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      04080000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        04100000
DECKYADR DS    CL4            ADDRESS OF KEY                            04120000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               04140000
         EJECT                                                          04160000
*                                                                       04180000
*      I/O BLOCK (IOB) DEFINITION                                       04200000
*                                                                       04220000
*              STANDARD IOB                                             04240000
         DS    0F                                                       04260000
IOBDEF   DSECT                                                          04280000
IOBFLAG1 DS    CL1            STATUS FLAG                               04300000
IOBFLAG2 DS    CL1            ERROR FLAG                                04320000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       04340000
IOBECBPT DS    CL4            ECB POINTER                               04360000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       04380000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           04400000
         DS    CL1                                                      04420000
         DS    CL3                                                      04440000
IOBCSWST DS    CL2            STATUS BYTES                              04460000
IOBCSWCT DS    CL2            REMAINING COUNT                           04480000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   04500000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        04520000
         DS    CL3                                                      04540000
IOBDCBPT DS    0CL4           DCB POINTER                               04560000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            04580000
         DS    CL3                                                      04600000
IOBRESTR DS    0CL4           RESTART POINTER                           04620000
         DS    CL1                                                      04640000
         DS    CL3                                                      04660000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              04680000
IOBERRCT DS    CL2            ERROR COUNTER                             04700000
IOBSEEK  DS    CL8            SEEK ADDRESS                              04720000
*        BDAM EXTENDED IOB                                              04740000
*                                                                       04760000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  04780000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          04800000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     04820000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                04840000
         DS    CL3                                                      04860000
IOBDTYPE DS    CL2            TYPE FIELD                                04880000
IOBDSTAT DS    CL2            IOB STATUS                                04900000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        04920000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                04940000
         DS    CL2                                                      04960000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               04980000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        05000000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                05020000
IOBCP    DS    CL8            FIRST CCW IN CHANNEL PROGRAM              05040000
         END                                                            05060000
