IGG019KG CSECT                                                          00020000
 TITLE   'IGG019KG - FEEDBACK RELATIVE BLOCK NUMBER'                    00040000
*                                                                     * 00060000
*                                                                     * 00080000
*STATUS- CHANGE LEVEL 0                                               * 00100000
*FUNCTION/OPERATION- THIS MODULE IS ENTERED FROM THE ASYNCHRONOUS     * 00120000
*   INTERRUPT ROUTINE TO CONVERT THE ACTUAL ADDRESS OF THE BLOCK      * 00140000
*   JUST PROCESSED TO A RELATIVE BLOCK NUMBER. THIS IS DONE IF THE    * 00160000
*   USER HAS SPECIFIED FEEDBACK OPTION IN THE READ OR WRITE MACRO AND * 00180000
*   RELATIVE BLOCK AND FEEDBACK OPTIONS IN THE OPTCD PARAMETER OF THE * 00200000
*   DCB MACRO.                                                        * 00220000
*   THIS ROUTINE FIRST USES THE RESIDENT ROUTINE WHICH CONVERTS ACTUAL* 00240000
*   TO RELATIVE TRACK NUMBER TO OBTAIN A TTR VALUE. THIS VALUE IS     * 00260000
*   THEN CONVERTED TO A RELATIVE BLOCK NUMBER BY USE OF THE RELATIVE  * 00280000
*   EXTENTS ADDED TO THE DEB BY THE BDAM EXECUTOR 'IGG0193A'.         * 00300000
*                                                                     * 00320000
*ENTRY POINT- 'IGG019KG' (FDBSTAR) IS THE ENTRY POINT FROM THE        * 00340000
*   ASYNCHRONOUS INTERRUPT ROUTINE BY THE CALLING SEQUENCE,           * 00360000
*   L     15,96(DCB)                                                  * 00380000
*   BALR  12,15                                                       * 00400000
*                                                                     * 00420000
*INPUT- THE FOLLOWING REGISTERS ARE LOADED BY ASYNCHRONOUS INTERRUPT, * 00440000
*   1 - IOB ADDRESS                                                   * 00460000
*   13- DCB ADDRESS                                                   * 00480000
*   THE ACTUAL ADDRESS TO BE CONVERTED WILL BE FOUND IN THE IOB AT    * 00500000
*   IOBSEEK.                                                          * 00520000
*                                                                     * 00540000
*OUTPUT- THE CALCULATED RELATIVE BLOCK NUMBER WILL BE MOVED TO THE    * 00560000
*   USER'S BLKREF FIELD. BLKREF WILL BE LOCATED BY USING THE ECB      * 00580000
*   ADDRESS IN THE IOB TO LOCATE THE DECB AND THE ADDRESS OF BLKREF   * 00600000
*   WILL BE LOADED FROM THE DECB FIELD 'DECRECPT'.                    * 00620000
*                                                                     * 00640000
*EXTERNAL ROUTINES- 'IECPRLTV' IS USED TO CONVERT MBBCCHHR TO A TTR   * 00660000
*   VALUE.                                                            * 00680000
*                                                                     * 00700000
*EXIT NORMAL- 'EXTASI' IS THE EXIT TO RETURN TO THE ASYNCHRONOUS      * 00720000
*   INTERRUPT ROUTINE BY A     BR   12.                               * 00740000
*                                                                     * 00760000
*TABLES/WORK AREAS- THE COMMUNICATIONS VECTOR TABLE IS REFERENCED TO  * 00780000
*   OBTAIN THE ADDRESS OF THE RESIDENT CONVERT ROUTINE (IECPRLTV).    * 00800000
*                                                                     * 00820000
*ATTRIBUTES- THIS MODULE IS REENTRANT AND EXECUTED ENABLED.           * 00840000
*                                                                     * 00860000
*NOTES- REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT WITH     * 00880000
*   THE MODULES IGG019KA, IECPRLTV.                                   * 00900000
*                                                                     * 00920000
         USING IGG019KG,BASE                                            00940000
         USING IOBDEF,IOBREG                                            00960000
         USING DEBDEF,SREG2                                             00980000
         USING IHADCB,DCBREG                                            01000000
         USING DECBDEF,DECBREG                                          01020000
*                                                                       01040000
*              REGISTER USAGE                                           01060000
*                                                                       01080000
WKREG0   EQU   0                       WORKING REGISTER                 01100000
SREG1    EQU   1                        PARAMETER REGISTER FOR BPAM     01120000
IOBREG   EQU   1                        IOB ADDRESS                     01140000
SREG2    EQU   2                        PARAMETER REGISTER FOR BPAM     01160000
SREG9    EQU   9                        START OF SAVED REGISTERS        01180000
WKREG3   EQU   10                      WORKING REGISTER                 01200000
DECBREG  EQU   11                      DECB ADDRESS                     01220000
WKREG1   EQU   11                      WORKING REGISTER                 01240000
FDNBASE  EQU   11                       BASE FOR FOUNDATION MODULE      01260000
SREG12   EQU   12                      ERROR CONDITION REGISTER         01280000
INTREG   EQU   12                      INTERNAL RETURN FOR THIS MODULE  01300000
WKREG2   EQU   12                      WORKING REGISTER                 01320000
DCBREG   EQU   13                      DCB ADDRESS                      01340000
RETREG   EQU   14                      RETURN TO FOUNDATION MODULE      01360000
SREG14   EQU   14                       PARAMETER REGISTER FOR BPAM     01380000
WKREG4   EQU   14                      WORKING REGISTER                 01400000
SREG15   EQU   15                       PARAMETER REGISTER FOR BPAM     01420000
BASE     EQU   15                      BASE REGISTER FOR THIS MODULE    01440000
*                                                                       01460000
FDBSTAR  STM   SREG9,SREG2,IOBDNRCF     SAVE REGISTERS  9-2             01480000
         LR    WKREG2,IOBREG           SAVE IOB ADDRESS                 01500000
         L     SREG1,DCBDEBAD           SET DEB POINTER FOR CONVERT     01520000
         LA    SREG2,IOBSEEK-IOBDEF(0,WKREG2) SET POINTER TO ACTUAL     01540000
*                                              ADDRESS                  01560000
         L     SREG15,CVTPTR(0,0)      LOAD ADDR.OF COMM. VECTOR TABLE  01580000
         L     SREG15,CVTPRLTV-CVTDEF(0,SREG15) LOAD ADDRESS OF         01600000
*                                                 CONVERSION ROUTINE    01620000
         BALR  SREG14,SREG15            GO TO ROUTINE                   01640000
*                                                                       01660000
*                                                                       01680000
*                   RETURN FROM CONVERT ROUTINE                         01700000
RETURN   EQU   *                                                        01720000
         LM    SREG9,SREG15,SAVEOFF(SREG2)  RESTORE REGISTERS  9-15     01740000
         L     IOBREG,IOBSAVE(0,SREG2)  RESTORE IOB POINTER             01760000
RETPT    SR    WKREG1,WKREG1            CLEAR REGISTER                  01780000
         SRL   WKREG0,8                 SET REGISTER TO 0TTR            01800000
         BCTR  WKREG0,0                 SET R VALUE RELATIVE TO ZERO    01820000
         ST    WKREG1,IOBSTART          CLEAR IOB START POINTER         01840000
         STC   WKREG0,IOBSTART+3        PLACE R VALUE RETURNED BY       01860000
         IC    WKREG1,IOBSTART+3        CONVERT ROUTINE IN RESULT REG.  01880000
         L     SREG2,DCBDEBAD           LOAD DEB POINTER                01900000
         SRL   WKREG0,8                 SET REGISTER TO 00TT            01920000
         LA    WKREG2,EXT1(0,SREG2)     SET POINTER TO FIRST EXTENT     01940000
         SR    WKREG4,WKREG4            CLEAR REGISTER                  01960000
         IC    WKREG4,DEBNMEXT          LOAD NUMBER OF EXTENTS          01980000
         LR    WKREG3,WKREG2            SET POINTER TO FIRST EXTENT     02000000
INCPT    LA    WKREG3,EXTSZ(0,WKREG3)   INCREMENT POINTER BY EXT. SIZE  02020000
         BCT   WKREG4,INCPT             IS THIS THE LAST EXTENT         02040000
*                                       NO-GO TO INCPT                  02060000
*                                       YES WKREG3 NOW POINTS TO FIRST  02080000
*                                        RELATIVE RECORD EXTENT         02100000
SUBTRK   SH    WKREG0,NMTRK(0,WKREG2)   SUBTRACT NO.OF TRACKS IN THIS   02120000
*                                        EXTENT FROM CONVERTED VALUE    02140000
         BC    4,ADDBACK                BRANCH IF RESULT IS MINUS       02160000
         MVC   IOBSTART+1(3),1(WKREG3)  ALIGN RECORDS PER EXTENT VALUE  02180000
         A     WKREG1,IOBSTART          ADD VALUE TO RESULT             02200000
         LA    WKREG2,EXTSZ(0,WKREG2)   INCREMENT NORMAL EXTENT POINTER 02220000
         LA    WKREG3,REXTSZ(0,WKREG3)  INCREMENT RELATIVE EXTENT PTR   02240000
         BC    15,SUBTRK                REPEAT CALCULATION              02260000
*                                                                       02280000
ADDBACK  AH    WKREG0,NMTRK(0,WKREG2)   ADD NO. OF TRACK IN THIS EXTENT 02300000
*                                        BACK TO TT REG.                02320000
         BC    8,NOMORE                 IF RESULT IS ZERO GO TO NOMORE  02340000
         MVC   IOBSTART+1(1),0(WKREG3)  ALIGN RECORDS PER TRACK VALUE   02360000
ADDRR    AH    WKREG1,IOBSTART          ADD VALUE TO RESULT REGISTER    02380000
         BCT   WKREG0,ADDRR             BRANCH IF MORE TRACKS IN EXTENT 02400000
NOMORE   ST    WKREG1,IOBSTART          STORE RESULT                    02420000
         L     DECBREG,IOBECBPT         SET DECB POINTER                02440000
         L     WKREG2,DECRECPT          LOAD ADDRESS OF USER'S BLKREF   02460000
*                                        FIELD                          02480000
         MVC   0(3,WKREG2),IOBSTART+1   MOVE RELATIVE RECORD VALUE TO   02500000
*                                        USER'S AREA                    02520000
         L     FDNBASE,DCBREAD          SET FOUNDATION MODULE BASE ADDR 02540000
         L     FDNBASE,16(0,FDNBASE)    SET ASI BASE ADDRESS            02560000
         LM    WKREG0,SREG2,IOBDNRCF+28 RESTORE REGISTERS  0-2          02580000
         L     INTREG,IOBDNRCF+12       RESTORE RETURN ADDRESS          02600000
EXITASI  EQU   *                                                        02620000
         BCR   15,INTREG                RETURN TO ASYNCHRONOUS          02640000
*                                        INTERRUPT ROUTINE              02660000
EXT1     EQU   32                       FIRST EXTENT OFFSET FROM START  02680000
*                                        OF DEB                         02700000
EXTSZ    EQU   16                       DEB EXTENT SIZE                 02720000
REXTSZ   EQU   4                        RELATIVE RECORD EXTENT SIZE     02740000
NMTRK    EQU   14                       NUMBER OF TRACKS OFFSET IN EXT. 02760000
SAVEOFF  EQU   40                       OFFSET FROM IOBSEEK TO IOBDNRCF 02780000
IOBSAVE  EQU   72                       OFFSET OF SAVED IOB REGISTER    02800000
*                                                                       02820000
*              EXCEPTION CODES                                          02840000
NOREC    EQU   X'80'                                                    02860000
LGNCK    EQU   X'40'                                                    02880000
NOSPA    EQU   X'20'                                                    02900000
INVAL    EQU   X'10'                                                    02920000
UNCOR    EQU   X'08'                                                    02940000
ENDOD    EQU   X'04'                                                    02960000
UNREL    EQU   X'02'                                                    02980000
*              OPTIONS AND TYPE                                         03000000
VERIFY   EQU   X'80'                                                    03020000
OFLOW    EQU   X'40'                                                    03040000
EXSCH    EQU   X'20'                                                    03060000
FEEDB    EQU   X'10'                                                    03080000
ACTAD    EQU   X'08'                                                    03100000
DYNBF    EQU   X'04'                                                    03120000
READX    EQU   X'02'                                                    03140000
RELRD    EQU   X'01'                                                    03160000
KEYOP    EQU   X'80'                                                    03180000
LGNOP    EQU   X'40'                                                    03200000
READ     EQU   X'08'                                                    03220000
KEY      EQU   X'04'                                                    03240000
ADD      EQU   X'02'                                                    03260000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   03280000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   03300000
CVTDEF   DSECT                                                          03320000
         CVT                                                            03340000
         EJECT                                                          03360000
*      DATA CONTROL BLOCK (DCB) DEFINITION                              03380000
*                                                                       03400000
         DCBD  DSORG=DA                                                 03420000
         EJECT                                                          03440000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       03460000
         DS    0F                                                       03480000
DECBDEF  DS    0CL25                                                    03500000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        03520000
DECTYPE  DS    CL2            TYPE FIELD                                03540000
DECLNGTH DS    CL2            DATA LENGTH                               03560000
DECDCBAD DS    CL4            ADDRESS OF DCB                            03580000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      03600000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        03620000
DECKYADR DS    CL4            ADDRESS OF KEY                            03640000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               03660000
         EJECT                                                          03680000
*                                                                       03700000
*      I/O BLOCK (IOB) DEFINITION                                       03720000
*                                                                       03740000
*              STANDARD IOB                                             03760000
         DS    0F                                                       03780000
IOBDEF   DSECT                                                          03800000
         DS    0CL344                                                   03820000
IOBFLAG1 DS    CL1            STATUS FLAG                               03840000
IOBFLAG2 DS    CL1            ERROR FLAG                                03860000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       03880000
IOBECBPT DS    CL4            ECB POINTER                               03900000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       03920000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           03940000
         DS    CL1                                                      03960000
         DS    CL3                                                      03980000
IOBCSWST DS    CL2            STATUS BYTES                              04000000
IOBCSWCT DS    CL2            REMAINING COUNT                           04020000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   04040000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        04060000
         DS    CL3                                                      04080000
IOBDCBPT DS    0CL4           DCB POINTER                               04100000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            04120000
         DS    CL3                                                      04140000
IOBRESTR DS    0CL4           RESTART POINTER                           04160000
         DS    CL1                                                      04180000
         DS    CL3                                                      04200000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              04220000
IOBERRCT DS    CL2            ERROR COUNTER                             04240000
IOBSEEK  DS    CL8            SEEK ADDRESS                              04260000
*        BDAM EXTENDED IOB                                              04280000
*                                                                       04300000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  04320000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          04340000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     04360000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                04380000
         DS    CL3                                                      04400000
IOBDTYPE DS    CL2            TYPE FIELD                                04420000
IOBDSTAT DS    CL2            IOB STATUS                                04440000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        04460000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                04480000
         DS    CL2                                                      04500000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               04520000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        04540000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                04560000
IOBCP    DS    CL256                   FIRST CCW IN CHANNEL PROGRAM     04580000
         EJECT                                                          04600000
*                                                                       04620000
*      DATA EXTENT BLOCK (DEB) DEFINITION                               04640000
*                                                                       04660000
         DS    0F                                                       04680000
DEBDEF   DSECT                                                          04700000
*                                                                       04720000
         DS    0F                                                       04740000
DEBNMSUB DS    0CL1                    COUNT OF ROUTINES LOADED         04760000
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDRESS       04780000
DEBAMLNG DS    0CL1                    WORD CNT OF BDAM ADDED CORE      04800000
DEBDEBAD DS    CL4                     DEB CHAIN ADDRESS                04820000
DEBOFLGS DS    0CL1                    OPEN FLAGS                       04840000
DEBIRBAD DS    CL4                     IRB ADDRESS                      04860000
DEBOPATB DS    0CL1                    DATA SET ATTRIBUTES              04880000
DEBSYSPG DS    CL4                                                      04900000
DEBNMEXT DS    0CL1                    COUNT OF EXTENTS                 04920000
DEBUSRPG DS    CL4                                                      04940000
DEBPRIOR DS    0CL1                                                     04960000
DEBECBAD DS    CL4                                                      04980000
DEBPROTG DS    0CL1                                                     05000000
DEBDEBID DS    0CL1                                                     05020000
DEBDCBAD DS    CL4                     DCB ADDRESS                      05040000
DEBEXSCL DS    0CL1                    EXTENT SIZE SCALE                05060000
DEBAPPAD DS    CL4                     IOS APPENDAGE LIST ADDRESS       05080000
DEBDVMOD DS    0CL1                    FILE MASK CODE                   05100000
DEBUCBAD DS    CL4                     UCB ADDRESS                      05120000
DEBBINUM DS    CL2                     BIN NUMBER (BB)                  05140000
DEBSTRCC DS    CL2                     STARTING CYLINDER NUMBER         05160000
DEBSTRHH DS    CL2                     STARTING TRACK NUMBER            05180000
DEBENDCC DS    CL2                     ENDING CYLINDER NUMBER           05200000
DEBENDHH DS    CL2                     ENDING TRACK NUMBER              05220000
DEBNMTRK DS    CL2                     NO. OF TRACKS IN THIS EXTENT     05240000
DEBSUBID EQU   0         SUBROUTINE ID'S                                05260000
*                                                                       05280000
*                IO DEVICE TABLE                                        05300000
*                                                                       05320000
         DS    0F                                                       05340000
DTAB     DC    X'000814202C380000'                                      05360000
DEVSZ    DS    CL4                     DEVICE SIZE   CCHH               05380000
TRKLNGTH DS    CL2                     TRACK LENGTH                     05400000
OVERI    DS    CL1                     OVERHEAD  NOT LAST               05420000
OVERL    DS    CL1                     OVERHEAD  NLAST                  05440000
OVERK    DS    CL1                     OVERHEAD  NNON KEYED             05460000
FLAG     DS    CL1                     FLAG                             05480000
TOLER    DS    CL2                     TOLERANCE                        05500000
         END                                                            05520000
