         TITLE 'IGG019KH - FEEDBACK RELATIVE BLOCK WITH TRACK OVERFLOW' 00010016
IGG019KH CSECT                                                          00020000
*          RELEASE 16 DELETIONS                                         00027016
*3004                                                             13883 00030016
*          RELEASE 17 DELETIONS                                         00034016
*          RELEASE 18 DELETIONS                                         00041016
*          RELEASE 19 DELETIONS                                         00048016
*          RELEASE 20 DELETIONS                                         00055016
*          RELEASE 21 DELETIONS                                         00062016
*          RELEASE 22 DELETIONS                                         00069016
*          RELEASE 23 DELETIONS                                         00076016
*          RELEASE 24 DELETIONS                                         00083016
*STATUS CHANGE LEVEL 001                                                00093016
*                                                                     * 00120000
*FUNCTION/OPERATION- THIS MODULE IS ENTERED FROM THE ASYNCHRONOUS     * 00140000
*   INTERRUPT ROUTINE TO CONVERT THE ACTUAL ADDRESS OF THE BLOCK      * 00160000
*   JUST PROCESSED TO A RELATIVE BLOCK NUMBER. THIS IS DONE IF THE    * 00180000
*   USER HAS SPECIFIED THE FEEDBACK OPTION IN THE READ OR WRITE MACRO * 00200000
*   AND THE RELATIVE BLOCK AND FEEDBACK OPTIONS IN THE OPTCD PARAMETER* 00220000
*   OF THE DCB MACRO.                                                 * 00240000
*   THIS ROUTINE FIRST USES THE RESIDENT ROUTINE WHICH CONVERTS ACTUAL* 00260000
*   ADDRESSES TO RELATIVE TRACK ADDRESSES(TTR). THIS VALUE IS THEN    * 00280000
*   CONVERTED TO A RELATIVE BLOCK NUMBER BY USE OF THE RELATIVE       * 00300000
*   EXTENTS AND OF THE TRACKS/PERIOD AND RECORDS/PERIOD VALUES ADDED  * 00320000
*   TO THE DEB BY THE BDAM OPEN EXECUTOR 'IGG0193A'.                  * 00340000
*                                                                     * 00360000
*ENTRY POINTS- 'IGG019KH' IS THE ENTRY POINT FROM THE ASYNCHRONOUS    * 00380000
*   INTERRUPT ROUTINE BY THE CALLING SEQUENCE,                        * 00400000
*   L    15,96(DCB)                                                   * 00420000
*   BALR 12,15                                                        * 00440000
*   'NOMORE' IS THE RETURN POINT FROM THE RELATIVE BLOCK CONVERT      * 00460000
*   ROUTINE BY THE CALLING SEQUENCE,                                  * 00480000
*   L    15,96(DCB)                                                   * 00500000
*   B    4(0,15)                                                      * 00520000
*                                                                     * 00540000
*INPUT- THE FOLLOWING REGISTERS ARE LOADED BY ASYNCHRONOUS INTERRUPT, * 00560000
*   1 - IOB ADDRESS                                                   * 00580000
*   13- DCB ADDRESS                                                   * 00600000
*   THE ACTUAL ADDRESS TO BE CONVERTED WILL BE FOUND IN THE IOB AT    * 00620000
*   IOBSEEK.                                                          * 00640000
*                                                                     * 00660000
*OUTPUT- THE CALCULATED RELATIVE BLOCK NUMBER WILL BE MOVED TO THE    * 00680000
*   USER'S BLKREF FIELD. BLKREF WILL BE LOCATED BY USING THE ECB      * 00700000
*   ADDRESS IN THE IOB TO LOCATE THE DECB AND THE ADDRESS OF BLKREF   * 00720000
*   WILL BE LOADED FROM THE DECB FIELD 'DECRECPT'.                    * 00740000
*                                                                     * 00760000
*EXTERNAL ROUTINES- 'IECPRLTV' IS USED TO CONVERT MBBCCHHR TO A TTR   * 00780000
*   VALUE.                                                            * 00800000
*   'IGG019KF' IS USED TO DETERMINE THE NUMBER OF BLOCKS THE GIVEN    * 00820000
*   TTR IS WITHIN A PERIOD.                                           * 00840000
*                                                                     * 00860000
*EXIT- NORMAL- 'EXTASI' IS THE EXIT TO RETURN TO THE ASYNCHRONOUS     * 00880000
*   INTERRUPT ROUTINE BY A         BR   12.                           * 00900000
*                                                                     * 00920000
*TABLES/WORK AREAS- THE COMMUNICATIONS VECTOR TABLE IS REFERENCED TO  * 00940000
*   OBTAIN THE ADDRESS OF THE RESIDENT CONVERT ROUTINE (IECPRLTV)     * 00960000
*                                                                     * 00980000
*ATTRIBUTES- THIS ROUTINE IS REENTRANT AND EXECUTED ENABLED.          * 01000000
*                                                                     * 01020000
*NOTES- REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT WITH THE * 01040000
*   MODULES IGG019KA,IGG019KF, AND IECPRLTV.                          * 01060000
*                                                                     * 01080000
         EJECT                                                          01100000
*                                                                     * 01120000
         USING IGG019KH,BASE                                            01140000
         USING IOBDEF,IOBREG                                            01160000
         USING DEBDEF,SREG2                                             01180000
         USING IHADCB,DCBREG                                            01200000
         USING DECBDEF,DECBREG                                          01220000
*                                                                       01240000
*              REGISTER USAGE                                           01260000
*                                                                       01280000
WKREG0   EQU   0                       WORKING REGISTER                 01300000
SREG1    EQU   1                        PARAMETER REGISTER FOR BPAM     01320000
IOBREG   EQU   1                        IOB ADDRESS                     01340000
SREG2    EQU   2                        PARAMETER REGISTER FOR BPAM     01360000
WKREG2   EQU   3                       WORKING REGISTER                 01380000
DEBREG   EQU   3                       BASE REGISTER FOR DEB            01400000
DCB2REG   EQU  4                       BASE REGISTER FOR DCB FOR RR     01420000
IOB2REG  EQU   7                       IOB REG. FOR REL. BL. ROUTINE    01440000
SREG9    EQU   9                        START OF SAVED REGISTERS        01460000
WKREG3   EQU   10                      WORKING REGISTER                 01480000
DECBREG  EQU   11                      DECB ADDRESS                     01500000
WKREG1   EQU   11                      WORKING REGISTER                 01520000
FDNBASE  EQU   11                       BASE FOR FOUNDATION MODULE      01540000
SREG12   EQU   12                      ERROR CONDITION REGISTER         01560000
INTREG   EQU   12                      INTERNAL RETURN FOR THIS MODULE  01580000
DCBREG   EQU   13                      DCB ADDRESS                      01600000
RETREG   EQU   14                      RETURN TO FOUNDATION MODULE      01620000
SREG14   EQU   14                       PARAMETER REGISTER FOR BPAM     01640000
WKREG4   EQU   14                      WORKING REGISTER                 01660000
SREG15   EQU   15                       PARAMETER REGISTER FOR BPAM     01680000
BASE     EQU   15                      BASE REGISTER FOR THIS MODULE    01700000
*                                                                       01720000
         EJECT                                                          01740000
         B     FDBSTAR                 BRANCH TO FIRST INSTRUCTION      01760000
         B     NOMORE                  BRANCH TO RETURN POINT FROM RR   01780000
FDBSTAR  STM   SREG9,DCB2REG,IOBUPLIM  SAVE REGISTERS 9-4               01800000
         LR    WKREG2,IOBREG           SAVE IOB ADDRESS                 01820000
         L     SREG1,DCBDEBAD           SET DEB POINTER FOR CONVERT     01840000
         LA    SREG2,IOBSEEK-IOBDEF(0,WKREG2) SET POINTER TO ACTUAL     01860000
*                                              ADDRESS                  01880000
         L     SREG15,CVTPTR(0,0)      LOAD ADDR.OF COMM. VECTOR TABLE  01900000
         L     SREG15,CVTPRLTV-CVTDEF(0,SREG15) LOAD ADDRESS OF         01920000
*                                                 CONVERSION ROUTINE    01940000
         BALR  SREG14,SREG15            GO TO ROUTINE                   01960000
*                                                                       01980000
*                                                                       02000000
*                   RETURN FROM CONVERT ROUTINE                         02020000
RETURN   EQU   *                                                        02040000
         LM    SREG9,SREG15,SAVEOFF(SREG2)  RESTORE REGISTERS  9-15     02060000
         L     IOBREG,IOBSAVE(0,SREG2)  RESTORE IOB POINTER             02080000
RETPT    SR    WKREG1,WKREG1            CLEAR REGISTER                  02100000
         SRL   WKREG0,8                 SET REGISTER TO 0TTR            02120000
         BCTR  WKREG0,0                 SET R VALUE RELATIVE TO ZERO    02140000
         ST    WKREG1,IOBSTART          CLEAR IOB START POINTER         02160000
         STC   WKREG0,IOBSTART+3        PLACE R VALUE RETURNED BY       02180000
         IC    WKREG1,IOBSTART+3        CONVERT ROUTINE IN RESULT REG.  02200000
         L     SREG2,DCBDEBAD           LOAD DEB POINTER                02220000
         SRL   WKREG0,8                 SET REGISTER TO 00TT            02240000
         LA    WKREG2,EXT1(0,SREG2)     SET POINTER TO FIRST EXTENT     02260000
         SR    WKREG4,WKREG4            CLEAR REGISTER                  02280000
         IC    WKREG4,DEBNMEXT          LOAD NUMBER OF EXTENTS          02300000
         LR    WKREG3,WKREG2            SET POINTER TO FIRST EXTENT     02320000
INCPT    LA    WKREG3,EXTSZ(0,WKREG3)   INCREMENT POINTER BY EXT. SIZE  02340000
         BCT   WKREG4,INCPT             IS THIS THE LAST EXTENT         02360000
*                                       NO-GO TO INCPT                  02380000
*                                       YES WKREG3 NOW POINTS TO FIRST  02400000
*                                        RELATIVE RECORD EXTENT         02420000
         LR    WKREG4,WKREG3           YES SAVE POINTER TO PERIOD FIELD 02440000
         LA    WKREG3,8(0,WKREG3)      SET POINTER TO FIRST REL EXTENT  02460000
SUBTRK   SH    WKREG0,NMTRK(0,WKREG2)   SUBTRACT NO.OF TRACKS IN THIS   02480000
*                                        EXTENT FROM CONVERTED VALUE    02500000
         BC    4,ADDBACK                BRANCH IF RESULT IS MINUS       02520000
         MVC   IOBSTART+1(3),1(WKREG3)  ALIGN RECORDS PER EXTENT VALUE  02540000
         A     WKREG1,IOBSTART          ADD VALUE TO RESULT             02560000
         LA    WKREG2,EXTSZ(0,WKREG2)   INCREMENT NORMAL EXTENT POINTER 02580000
         LA    WKREG3,REXTSZ(0,WKREG3)  INCREMENT RELATIVE EXTENT PTR   02600000
         BC    15,SUBTRK                REPEAT CALCULATION              02620000
*                                                                       02640000
ADDBACK  AH    WKREG0,NMTRK(0,WKREG2)   ADD NO. OF TRACK IN THIS EXTENT 02660000
*                                        BACK TO TT REG.                02680000
         BC    8,NOMORE                 IF RESULT IS ZERO GO TO NOMORE  02700000
SUBPRD   S     WKREG0,0(0,WKREG4)      YES SUBTRACT  TRACKS/PERIOD      02720000
         BM    OVER                    MINUS RESULT?GO ADD BACK TRACKS  02740000
         A     WKREG1,4(0,WKREG4)      NO ADD ON RECORDS/PERIOD         02760000
         B     SUBPRD                  LOOP BACK                        02780000
OVER     A     WKREG0,0(0,WKREG4)      ADD BACK TRACKS SUBTRACTED       02800000
         BZ    NOMORE                  IF NOT GO AROUND OVERFLOW        02820000
         OI    IOBDTYPE+1,RBFDBK       INDICATE ENTRY FROM FEEDBACK     02840000
         L     DEBREG,DCBDEBAD         GET DEB ADDR INTO CORRECT REG    02860000
         LR    DCB2REG,DCBREG          GET DCB ADDR INTO CORRECT REG    02880000
         LR    IOB2REG,IOBREG          LOAD IOB ADDR FOR REL. BL MODULE 02900000
         L     BASE,DCBREAD            GET ADDRESS OF THE FOUNDATION    02920000
         L     BASE,32(0,BASE)          MODULE.  GET ADDR OF      13883 02940016
         B     4(0,BASE)               OF THE RELATIVE RECORD MOD. BR   02960000
NOMORE   ST    WKREG1,IOBSTART          STORE RESULT                    02980000
         L     DECBREG,IOBECBPT         SET DECB POINTER                03000000
         L     WKREG2,DECRECPT          LOAD ADDRESS OF USER'S BLKREF   03020000
*                                        FIELD                          03040000
         MVC   0(3,WKREG2),IOBSTART+1   MOVE RELATIVE RECORD VALUE TO   03060000
*                                        USER'S AREA                    03080000
         L     FDNBASE,DCBREAD          SET FOUNDATION MODULE BASE ADDR 03100000
         L     FDNBASE,16(0,FDNBASE)    SET ASI BASE ADDRESS            03120000
         LM    WKREG0,DCB2REG,IOBDNRCF+20 RESTORE REGISTERS 0-4         03140000
EXITASI  EQU   *                                                        03160000
         BCR   15,INTREG                RETURN TO ASYNCHRONOUS          03180000
*                                        INTERRUPT ROUTINE              03200000
EXT1     EQU   32                       FIRST EXTENT OFFSET FROM START  03220000
*                                        OF DEB                         03240000
EXTSZ    EQU   16                       DEB EXTENT SIZE                 03260000
REXTSZ   EQU   4                        RELATIVE RECORD EXTENT SIZE     03280000
NMTRK    EQU   14                       NUMBER OF TRACKS OFFSET IN EXT. 03300000
SAVEOFF  EQU   32                      OFFSET FROM IOBSEEK TO IOBUPLIM  03320000
IOBSAVE  EQU   64                      OFFSET OF SAVED IOB REGISTER     03340000
*                                                                       03360000
*              EXCEPTION CODES                                          03380000
NOREC    EQU   X'80'                                                    03400000
LGNCK    EQU   X'40'                                                    03420000
NOSPA    EQU   X'20'                                                    03440000
INVAL    EQU   X'10'                                                    03460000
UNCOR    EQU   X'08'                                                    03480000
ENDOD    EQU   X'04'                                                    03500000
UNREL    EQU   X'02'                                                    03520000
*              OPTIONS AND TYPE                                         03540000
VERIFY   EQU   X'80'                                                    03560000
OFLOW    EQU   X'40'                                                    03580000
EXSCH    EQU   X'20'                                                    03600000
FEEDB    EQU   X'10'                                                    03620000
ACTAD    EQU   X'08'                                                    03640000
DYNBF    EQU   X'04'                                                    03660000
READX    EQU   X'02'                                                    03680000
RELRD    EQU   X'01'                                                    03700000
KEYOP    EQU   X'80'                                                    03720000
LGNOP    EQU   X'40'                                                    03740000
READ     EQU   X'08'                                                    03760000
KEY      EQU   X'04'                                                    03780000
ADD      EQU   X'02'                                                    03800000
OVERFL   EQU   2                                                        03820000
RBFDBK   EQU   X'20'                                                    03840000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   03860000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   03880000
CVTDEF   DSECT                                                          03900000
         CVT                                                            03920000
         EJECT                                                          03940000
*      DATA CONTROL BLOCK (DCB) DEFINITION                              03960000
*                                                                       03980000
         DCBD  DSORG=DA                                                 04000000
         EJECT                                                          04020000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       04040000
         DS    0F                                                       04060000
DECBDEF  DS    0CL25                                                    04080000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        04100000
DECTYPE  DS    CL2            TYPE FIELD                                04120000
DECLNGTH DS    CL2            DATA LENGTH                               04140000
DECDCBAD DS    CL4            ADDRESS OF DCB                            04160000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      04180000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        04200000
DECKYADR DS    CL4            ADDRESS OF KEY                            04220000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               04240000
         EJECT                                                          04260000
*                                                                       04280000
*      I/O BLOCK (IOB) DEFINITION                                       04300000
*                                                                       04320000
*              STANDARD IOB                                             04340000
         DS    0F                                                       04360000
IOBDEF   DSECT                                                          04380000
         DS    0CL344                                                   04400000
IOBFLAG1 DS    CL1            STATUS FLAG                               04420000
IOBFLAG2 DS    CL1            ERROR FLAG                                04440000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       04460000
IOBECBPT DS    CL4            ECB POINTER                               04480000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       04500000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           04520000
         DS    CL1                                                      04540000
         DS    CL3                                                      04560000
IOBCSWST DS    CL2            STATUS BYTES                              04580000
IOBCSWCT DS    CL2            REMAINING COUNT                           04600000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   04620000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        04640000
         DS    CL3                                                      04660000
IOBDCBPT DS    0CL4           DCB POINTER                               04680000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            04700000
         DS    CL3                                                      04720000
IOBRESTR DS    0CL4           RESTART POINTER                           04740000
         DS    CL1                                                      04760000
         DS    CL3                                                      04780000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              04800000
IOBERRCT DS    CL2            ERROR COUNTER                             04820000
IOBSEEK  DS    CL8            SEEK ADDRESS                              04840000
*        BDAM EXTENDED IOB                                              04860000
*                                                                       04880000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  04900000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          04920000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     04940000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                04960000
         DS    CL3                                                      04980000
IOBDTYPE DS    CL2            TYPE FIELD                                05000000
IOBDSTAT DS    CL2            IOB STATUS                                05020000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        05040000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                05060000
         DS    CL2                                                      05080000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               05100000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        05120000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                05140000
IOBCP    DS    CL256                   FIRST CCW IN CHANNEL PROGRAM     05160000
         EJECT                                                          05180000
*                                                                       05200000
*      DATA EXTENT BLOCK (DEB) DEFINITION                               05220000
*                                                                       05240000
         DS    0F                                                       05260000
DEBDEF   DSECT                                                          05280000
*                                                                       05300000
         DS    0F                                                       05320000
DEBNMSUB DS    0CL1                    COUNT OF ROUTINES LOADED         05340000
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDRESS       05360000
DEBAMLNG DS    0CL1                    WORD CNT OF BDAM ADDED CORE      05380000
DEBDEBAD DS    CL4                     DEB CHAIN ADDRESS                05400000
DEBOFLGS DS    0CL1                    OPEN FLAGS                       05420000
DEBIRBAD DS    CL4                     IRB ADDRESS                      05440000
DEBOPATB DS    0CL1                    DATA SET ATTRIBUTES              05460000
DEBSYSPG DS    CL4                                                      05480000
DEBNMEXT DS    0CL1                    COUNT OF EXTENTS                 05500000
DEBUSRPG DS    CL4                                                      05520000
DEBPRIOR DS    0CL1                                                     05540000
DEBECBAD DS    CL4                                                      05560000
DEBPROTG DS    0CL1                                                     05580000
DEBDEBID DS    0CL1                                                     05600000
DEBDCBAD DS    CL4                     DCB ADDRESS                      05620000
DEBEXSCL DS    0CL1                    EXTENT SIZE SCALE                05640000
DEBAPPAD DS    CL4                     IOS APPENDAGE LIST ADDRESS       05660000
DEBDVMOD DS    0CL1                    FILE MASK CODE                   05680000
DEBUCBAD DS    CL4                     UCB ADDRESS                      05700000
DEBBINUM DS    CL2                     BIN NUMBER (BB)                  05720000
DEBSTRCC DS    CL2                     STARTING CYLINDER NUMBER         05740000
DEBSTRHH DS    CL2                     STARTING TRACK NUMBER            05760000
DEBENDCC DS    CL2                     ENDING CYLINDER NUMBER           05780000
DEBENDHH DS    CL2                     ENDING TRACK NUMBER              05800000
DEBNMTRK DS    CL2                     NO. OF TRACKS IN THIS EXTENT     05820000
DEBSUBID EQU   0         SUBROUTINE ID'S                                05840000
*                                                                       05860000
*                IO DEVICE TABLE                                        05880000
*                                                                       05900000
         DS    0F                                                       05920000
DTAB     DC    X'000814202C380000'                                      05940000
DEVSZ    DS    CL4                     DEVICE SIZE   CCHH               05960000
TRKLNGTH DS    CL2                     TRACK LENGTH                     05980000
OVERI    DS    CL1                     OVERHEAD  NOT LAST               06000000
OVERL    DS    CL1                     OVERHEAD  NLAST                  06020000
OVERK    DS    CL1                     OVERHEAD  NNON KEYED             06040000
FLAG     DS    CL1                     FLAG                             06060000
TOLER    DS    CL2                     TOLERANCE                        06080000
         END                                                            06100000
