IGG019KI CSECT                                                          00020000
*                                                                       00040000
 TITLE   'IGG019KI - KEY MODULE'                                        00060000
*STATUS- CHANGE LEVEL 0                                               * 00080000
*FUNCTION/OPERATION- THIS ROUTINE IS ENTERED FROM IGG019KA TO         * 00100000
*   CONSTRUCT A CHANNEL PROGRAM TO PERFORM A READ OR WRITE BY KEY,    * 00120000
*   (SEARCH ARGUMENT IS BLOCK KEY).                                   * 00140000
*   THE CCWS ARE CONSTRUCTED OF CONSTANTS DEFINED IN THIS MODULE AND  * 00160000
*   ADDRESSES RESOLVED AT THE TIME THIS ROUTINE IS EXECUTED.          * 00180000
*                                                                     * 00200000
*ENTRY POINT- 'IGG019KI' (BEGIN) IS ENTERED BY THE CALLING SEQUENCE,  * 00220000
*   L    15,DCBDKEY                                                   * 00240000
*   BALR 14,15                                                        * 00260000
*                                                                     * 00280000
*INPUT- THE REGISTERS ARE INPUT AS FOLLOWS,                           * 00300000
*   4 - DCB ADDRESS                                                   * 00320000
*   5 - DECB ADDRESS                                                  * 00340000
*   6 - ADDRESS OF CCW 1 (CHANNEL PROGRAM START)                      * 00360000
*   7 - IOB ADDRESS                                                   * 00380000
*   11- BASE ADDRESS OF FOUNDATION MODULE (IGG019KA)                  * 00400000
*                                                                     * 00420000
*OUTPUT- THE REQUIRED CCWS WILL BE CONSTRUCTED FOLLOWING THE IOB.     * 00440000
*   REGISTER 6 WILL CONTAIN THE ADDRESS OF THE LAST CCW.              * 00460000
*                                                                     * 00480000
*EXTERNAL ROUTINES- 'IGG019KQ' WILL BE ENTERED TO CONSTRUCT THE VERIFY* 00500000
*   CCWS IF THE REQUEST IS A READ AND THE WRITE VALIDITY CHECK OPTION * 00520000
*   HAS BEEN SPECIFIED.                                               * 00540000
*                                                                     * 00560000
*EXITS-NORMAL- 'D4TOVER' IS THE EXIT TO IGG019KQ IF REQUIRED.         * 00580000
*   'D4EXIT' IS THE NORMAL RETURN TO THE MODULE IGG019KA.             * 00600000
*                                                                     * 00620000
*TABLES/WORK AREAS- N/A                                               * 00640000
*                                                                     * 00660000
*ATTRIBUTES- THIS ROUTINE IS REENTRANT AND EXECUTED ENABLED.          * 00680000
*                                                                     * 00700000
*NOTE- REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT WITH THE  * 00720000
*   MODULES, IGG019KA, IGG019KQ.                                      * 00740000
*                                                                     * 00750020
* FIX FOR SA69168 IS FLAGGED YA04138                            SA69168 00752020
* FIX FOR XA04521 IS FLAGGED YA04138                            XA04521 00754020
         EJECT                                                          00760000
         USING IGG019KI,D4EPREG                                         00780000
         USING IHADCB,DCBREG                                            00800000
         USING DECBDEF,DECBREG                                          00820000
         USING IOBDEF,IOBREG                                            00840000
*                                                                       00860000
*                                                                       00880000
*  REGISTER USAGE                                                       00900000
*                                                                       00920000
D4WKREG  EQU   0         WORK REGISTER                                  00940000
D4VERR   EQU   1         POINTER TO A SEARCH CCW FOR VERIFY             00960000
DEBREG   EQU   3         DEB ADDRESS                                    00980000
DCBREG   EQU   4         DCB ADDRESS                                    01000000
DECBREG  EQU   5         DECB ADDRESS                                   01020000
D4CCWIND EQU   6         CHANNEL COMMAND INDEX                          01040000
IOBREG   EQU   7         IOB ADDRESS                                    01060000
VERBASE  EQU   10        BASE FOR THE VERIFY MODULE                     01080000
FDNBASE  EQU   11        BASE FOR THE FOUNDATION MODULE                 01100000
D4       EQU   12        RETURN FOR INTERNAL BAL                        01120000
RETREG   EQU   14        RETURN TO FOUNDATION MODULE                    01140000
D4EPREG  EQU   15        BASE FOR THIS MODULE                           01160000
*                                                                       01180000
*                                                                       01200000
*                                                                       01220000
BEGIN    B     D4ENTRY            BRANCH TO THE BEGINNING OF THE CODE   01240000
D4EKAD   DS    F       ADDRESS OF KEY-EXTENDED SEARCH MODULE            01260000
*                                                                       01280000
*                                                                       01300000
D4ENTRY  LA    D4WKREG,IOBDNRCF+2      DEVELOP AND STORE ADDRESS OF     01320000
         ST    D4WKREG,0(D4CCWIND)       NEW RECORD COUNT FIELD IN CCW1 01340000
         MVI   0(D4CCWIND),D4RDCNT      MOVE READ COUNT OP CODE TO CCW1 01360000
         MVC   4(5,D4CCWIND),D4CON1     MOVE FLAGS,COUNT AND SEARCH OP. 01380000
         MVC   9(3,D4CCWIND),DECKYADR+1 MOVE KEY ADDRESS FROM DECB      01400000
         MVI   12(D4CCWIND),D4CCHN+SILI SET COMMAND CHAIN+SILI FLAGS    01420000
         MVC   15(1,D4CCWIND),DCBKEYLE MOVE KEY LENGTH AS COUNT         01440000
         LR    D4WKREG,D4CCWIND        MOVE TO A COMMON LOCATION        01460000
         TM    IOBDTYPE,EXSCH           AND USE AS TIC ADDRESS          01480000
         BC    8,*+8                     UNLESS THIS IS EXTENDED        01500000
         LA    D4WKREG,IOBCP+64           SEARCH                        01520000
         ST    D4WKREG,16(D4CCWIND)    STORE TIC ADDRESS                01540000
         MVI   16(D4CCWIND),D4TIC       MOVE TIC OP CODE                01560000
         MVI   24(D4CCWIND),RDDOP      MOVE READ DATA OP-CODE           01580000
         MVC   25(3,D4CCWIND),DECAREA+1 MOVE AREA ADDRESS FROM DECB     01600000
         MVC   30(2,D4CCWIND),DECLNGTH  MOVE DECB LENGTH AS COUNT       01620000
         TM    IOBDTYPE,EXSCH          IF THIS IS EXTENDED SEARCH       01640000
         BC    1,D4EXSCH                GO TO THAT MODULE               01660000
         LA    D4CCWIND,24(D4CCWIND)   INCREMENT TO LAST CCW            01680000
         TM    IOBDTYPE+1,READ         TEST FOR READ OR WRITE           01700000
         BCR   1,RETREG                EXIT IF THIS WAS A READ REQUEST  01720000
         TM    DCBRECFM,UNDEF           IF UNDEFINED RECFM      YA04138 01730020
         BM    NOTU                     INCORRECT LENGTH        YA04138 01732020
         OI    HALFCCW(D4CCWIND),SILI  WILL BE SUPPRESSED       YA04138 01734020
NOTU     MVI   0(D4CCWIND),D4WRITE     CHANGE READ OP  TO WRITE DATA OP 01740020
         TM    IOBDTYPE,VERIFY          TEST FOR VERIFY OPTION          01760000
         BCR   8,RETREG                  IF NOT GO EXIT                 01780000
         LA    D4VERR,IOBCP+8           SET A POINTER TO THE SEARCH CCW 01800000
         L     VERBASE,12(0,FDNBASE)   LOAD VERIFY'S ENTRY POINT/BASE   01820000
         BR    VERBASE                 GO CONSTRUCT VERIFY CCWS         01840000
*                                      VERIFY MODULE WILL RETURN TO     01860000
*                                      FOUNDATION ON REGISTER 14        01880000
*                                                                       01900000
D4EXSCH  L     D4EPREG,D4EKAD           LOAD ADDRESS OF EXTENDED SEARCH 01920000
         BCR   15,D4EPREG            GO TO KEY-EXTENDED SEARCH MODULE   01940000
*                                                                       01960000
*                                                                       01980000
D4CON1   DC    X'6000000529'  FLAGS, COUNT, SEARCH-KEY-EQUAL OP-CODE    02000000
D4RDCNT  EQU   X'12'   OP CODE FOR READ COUNT                           02020000
D4CCHN   EQU   X'40'   COMMAND CHAIN FLAG                               02040000
SILI     EQU   X'20'                   SUPPRESS INCORRECT LENGTH        02060000
D4TIC    EQU   X'08'   TIC OP CODE                                      02080000
D4WRITE  EQU   X'05'   WRITE DATA OP CODE                               02100000
RDDOP    EQU   X'06'    READ DATA OP-CODE                               02120000
UNDEF    EQU   X'C0'                    UNDEFINED RECFM         YA04138 02130020
HALFCCW  EQU   4                        HALF CCW OFFSET         YA04138 02132020
*                                                                       02140000
         DC    X'00'   FILLER - FILLER - FILLER                         02160000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   02180000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   02200000
         EJECT                                                          02220000
*              EXCEPTION CODES                                          02240000
NOREC    EQU   X'80'                                                    02260000
LGNCK    EQU   X'40'                                                    02280000
NOSPA    EQU   X'20'                                                    02300000
INVAL    EQU   X'10'                                                    02320000
UNCOR    EQU   X'08'                                                    02340000
ENDOD    EQU   X'04'                                                    02360000
UNREL    EQU   X'02'                                                    02380000
*              OPTIONS AND TYPE                                         02400000
VERIFY   EQU   X'80'                                                    02420000
OFLOW    EQU   X'40'                                                    02440000
EXSCH    EQU   X'20'                                                    02460000
FEEDB    EQU   X'10'                                                    02480000
ACTAD    EQU   X'08'                                                    02500000
DYNBF    EQU   X'04'                                                    02520000
READX    EQU   X'02'                                                    02540000
RELRD    EQU   X'01'                                                    02560000
KEYOP    EQU   X'80'                                                    02580000
LGNOP    EQU   X'40'                                                    02600000
READ     EQU   X'08'                                                    02620000
KEY      EQU   X'04'                                                    02640000
ADD      EQU   X'02'                                                    02660000
*      DATA CONTROL BLOCK (DCB) DEFINITION                              02680000
*                                                                       02700000
         DCBD  DSORG=DA                                                 02720000
*                                                                       02740000
*                                                                       02760000
*                                                                       02780000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       02800000
         DS    0F                                                       02820000
DECBDEF  DSECT                                                          02840000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        02860000
DECTYPE  DS    CL2            TYPE FIELD                                02880000
DECLNGTH DS    CL2            DATA LENGTH                               02900000
DECDCBAD DS    CL4            ADDRESS OF DCB                            02920000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      02940000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        02960000
DECKYADR DS    CL4            ADDRESS OF KEY                            02980000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               03000000
         EJECT                                                          03020000
*                                                                       03040000
*      I/O BLOCK (IOB) DEFINITION                                       03060000
*                                                                       03080000
*              STANDARD IOB                                             03100000
         DS    0F                                                       03120000
IOBDEF   DSECT                                                          03140000
IOBFLAG1 DS    CL1            STATUS FLAG                               03160000
IOBFLAG2 DS    CL1            ERROR FLAG                                03180000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       03200000
IOBECBPT DS    CL4            ECB POINTER                               03220000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       03240000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           03260000
         DS    CL1                                                      03280000
         DS    CL3                                                      03300000
IOBCSWST DS    CL2            STATUS BYTES                              03320000
IOBCSWCT DS    CL2            REMAINING COUNT                           03340000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   03360000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        03380000
         DS    CL3                                                      03400000
IOBDCBPT DS    0CL4           DCB POINTER                               03420000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            03440000
         DS    CL3                                                      03460000
IOBRESTR DS    0CL4           RESTART POINTER                           03480000
         DS    CL1                                                      03500000
         DS    CL3                                                      03520000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              03540000
IOBERRCT DS    CL2            ERROR COUNTER                             03560000
IOBSEEK  DS    CL8            SEEK ADDRESS                              03580000
*        BDAM EXTENDED IOB                                              03600000
*                                                                       03620000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  03640000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          03660000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     03680000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                03700000
         DS    CL3                                                      03720000
IOBDTYPE DS    CL2            TYPE FIELD                                03740000
IOBDSTAT DS    CL2            IOB STATUS                                03760000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        03780000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                03800000
         DS    CL2                                                      03820000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               03840000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        03860000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                03880000
IOBCP    DS    CL200                   CHANNEL PROGRAM AREA             03900000
         END                                                            03920000
