IGG019KK CSECT                                                          00020000
*                                                                       00040000
 TITLE   'IGG019KK - ID MODULE'                                         00060000
*                                                                     * 00080000
*STATUS- CHANGE LEVEL 0                                               * 00100000
*FUNCTION/OPERATION- THIS ROUTINE CONSTRUCTS A CHANNEL PROGRAM TO     * 00120000
*   PERFORM A READ OR WRITE BY ID (USES BLOCK ID AS THE SEARCH        * 00140000
*   ARGUMENT).                                                        * 00160000
*   THE CCWS ARE CONSTRUCTED OF CONSTANTS DEFINED IN THIS MODULE AND  * 00180000
*   ADDRESSES RESOLVED AT THE TIME THIS CODE IS EXECUTED.             * 00200000
*                                                                     * 00220000
*ENTRY POINT- ENTRY IS TO 'IGG019KK' (BEGIN) FROM MODULE IGG019KA BY  * 00240000
*   THE CALLING SEQUENCE,   L    15,DCBDID                            * 00260000
*                           BALR 14,15                                * 00280000
*                                                                     * 00300000
*INPUT- THE REGISTERS ARE INPUT AS FOLLOWS,                           * 00320000
*   4 - DCB ADDRESS                                                   * 00340000
*   5 - DECB ADDRESS                                                  * 00360000
*   6 - THE ADDRESS OF CCW 1 (CHANNEL PROGRAM START)                  * 00380000
*   7 - IOB ADDRESS                                                   * 00400000
*   11- BASE ADDRESS OF MODULE IGG019KA (FOUNDATION MODULE)           * 00420000
*                                                                     * 00440000
*OUTPUT- THE REQUIRED CCWS WILL BE CONSTRUCTED FOLLOWING THE IOB.     * 00460000
*   REGISTER 6 WILL CONTAIN THE ADDRESS OF THE LAST CCW.              * 00480000
*                                                                     * 00500000
*EXTERNAL ROUTINE- 'IGG019KQ' IS ENTERED TO CONSTRUCT THE VERIFY CCWS * 00520000
*   IF THE REQUEST IS A WRITE AND THE WRITE VALIDITY CHECK OPTION HAS * 00540000
*   BEEN SPECIFIED.                                                   * 00560000
*                                                                     * 00580000
*EXITS-NORMAL- 'D6TOVER' IS THE EXIT TO IGG019KQ IF NECESSARY. THE    * 00600000
*   REGISTERS WILL BE LOADED AS REQUIRED BY IGG019KQ.                 * 00620000
*   'D6EXIT' IS THE RETURN TO THE FOUNDATION MODULE, IGG019KA.        * 00640000
*                                                                     * 00660000
*TABLES/WORK AREAS- N/A                                               * 00680000
*                                                                     * 00700000
*ATTRIBUTES- THIS ROUTINE IS REENTRANT AND EXECUTED ENABLED.          * 00720000
*                                                                     * 00740000
*NOTE- REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT WITH THE  * 00760000
*   MODULES, IGG019KA, IGG019KQ.                                      * 00780000
*                                                                     * 00790020
* FIX FOR SA69168 IS FLAGGED YA04138                            SA69168 00792020
* FIX FOR XA04521 IS FLAGGED YA04138                            XA04521 00794020
         EJECT                                                          00800000
         USING IGG019KK,D6EPREG                                         00820000
         USING IHADCB,DCBREG                                            00840000
         USING DECBDEF,DECBREG                                          00860000
         USING IOBDEF,IOBREG                                            00880000
*                                                                       00900000
*                                                                       00920000
*                                                                       00940000
*  REGISTER USAGE                                                       00960000
*                                                                       00980000
D6WKREG  EQU   0         WORK REGISTER                                  01000000
D6VERR   EQU   1         POINTER TO A SEARCH CCW FOR VERIFY             01020000
DEBREG   EQU   3         DEB ADDRESS                                    01040000
DCBREG   EQU   4         DCB ADDRESS                                    01060000
DECBREG  EQU   5         DECB ADDRESS                                   01080000
CCWIND   EQU   6         CHANNEL COMMAND INDEX                          01100000
IOBREG   EQU   7         IOB ADDRESS                                    01120000
VERBASE  EQU   10        BASE FOR VERIFY MODULE                         01140000
FDNBASE  EQU   11        BASE FOR THE FOUNDATION MODULE                 01160000
D6       EQU   12        RETURN FROM INTERNAL BAL                       01180000
RETREG   EQU   14        RETURN TO FOUNDATION MODULE                    01200000
D6EPREG  EQU   15        BASE OF THIS MODULE                            01220000
*                                                                       01240000
*                                                                       01260000
BEGIN    LR    D6VERR,CCWIND           SAVE THE ADDRESS OF SEARCH CCW.  01280000
         MVC   IOBDNRCF+2(5),IOBSEEK+3 POSITION FEEDBACK TO COMMON LOC. 01300000
         LA    D6WKREG,IOBSEEK+3        DEVELOP SEARCH ARGUMENT ADDRESS 01320000
         ST    D6WKREG,0(CCWIND)           AND STORE IN CCW1 .          01340000
         ST    CCWIND,8(CCWIND)          STORE TIC ADDRESS              01360000
         MVI   0(CCWIND),D6SCHID         MOVE OP CODE TO CCW1           01380000
         MVC   4(5,CCWIND),D6CON1        MOVE FLAGS,COUNT,TIC OP CODE   01400000
         LA    CCWIND,16(CCWIND)         INCREMENT INDEX TO THIRD CCW   01420000
         MVC   0(2,CCWIND),D6CON2        MOVE 2 READ OP CODES TO CCW3   01440000
         TM    IOBDTYPE+1,READ         IF THIS IS A WRITE ,             01460000
         BC    1,D6TSTK                    REPLACE THE READ             01480000
         MVC   0(2,CCWIND),D6CON3           OP CODES WITH WRITE OP CODE 01500000
D6TSTK   CLI   DCBKEYLE,0              TEST FOR KEYED RECORDS           01520000
         BC    8,D6NOKEY                  IF NOT, OVERLAY THE READ OR   01540000
         L     D6WKREG,DECKYADR            WRITE KEY-DATA OP CODE       01560000
         LTR   D6WKREG,D6WKREG              WITH                        01580000
         BC    7,D6KEY                       THE                        01600000
         TM    IOBDTYPE+1,KEYOP               READ OR WRITE DATA        01620000
         BC    1,D6KEY                         OP CODE                  01640000
D6NOKEY  MVC   0(1,CCWIND),1(CCWIND)            STORED AT CCW3+1        01660000
         BC    15,D6DATA                         AND OMIT KEY-DATA CCW  01680000
D6KEY    MVC   7(1,CCWIND),DCBKEYLE    MOVE KEY LENGTH AS COUNT         01700000
         MVC   8(1,CCWIND),1(CCWIND)    MOVE STORED OP-CODE TO CCW4     01720000
         MVI   4(CCWIND),D6DCCHN         SET DATA, COMMAND CHAIN FLAGS  01740000
         MVC   1(3,CCWIND),DECKYADR+1    MOVE KEY ADDR. FROM DECB       01760000
         LA    CCWIND,8(CCWIND)          INCREMENT INDEX TO CCW4        01780000
D6DATA   MVC   1(3,CCWIND),DECAREA+1     MOVE AREA ADDR. FROM DECB      01800000
         MVC   6(2,CCWIND),DECLNGTH    MOVE DATA LENGTH AS COUNT.       01820000
         TM    IOBDTYPE+1,READ         IF THIS IS A READ, THE CHANNEL   01840000
         BCR   1,RETREG                   PROGRAM IS COMPLETE           01860000
         TM    DCBRECFM,UNDEF           IF UNDEFINED RECFM      YA04138 01870020
         BM    NOTU                     THEN INCORRECT LENGTH   YA04138 01872020
         OI    HALFCCW(CCWIND),SILI     WILL BE SUPPRESSED      YA04138 01874020
NOTU     TM    IOBDTYPE,VERIFY         IS THE VERIFY OPTION SPECIFIED   01880020
         BCR   8,RETREG                IF NOT CHANNEL PROG. IS COMPLETE 01900000
         L     VERBASE,12(0,FDNBASE)    SET UP TO GO TO THE             01920000
         BR    VERBASE                 VERIFY MODULE TO CONSTRUCT CCWS  01940000
*                                      VERIFY MODULE WILL RETURN TO     01960000
*                                      FOUNDATION ON REGISTER 14        01980000
*                                                                       02000000
HALFCCW  EQU   4                        4 BYTE OFFSET           YA04138 02010020
D6SCHID  EQU   X'31'     SEARCH-ID-EQUAL OP-CODE                        02020000
D6DCCHN  EQU   X'C0'     DATA AND COMMAND CHAIN FLAGS                   02040000
D6CON1   DC    X'4000000508'  FLAGS COUNT TIC OP-CODE                   02060000
D6CON2   DC    X'0E'     READ KEY-DATA                                  02080000
         DC    X'06'     READ DATA                                      02100000
D6CON3   DC    X'0D'     WRITE KEY-DATA                                 02120000
         DC    X'05'     WRITE DATA                                     02140000
*                                                                       02160000
*     BDAM OPTIONS AND TYPES                                            02180000
UNDEF    EQU   X'C0'                    UNDEFINED RECFM         YA04138 02190020
SILI     EQU   X'20'                 SUPPRESS INCORRECT LENGTH  YA04138 02192020
VERIFY   EQU   X'80'                                                    02200000
OFLOW    EQU   X'40'                                                    02220000
EXSCH    EQU   X'20'                                                    02240000
FEEDB    EQU   X'10'                                                    02260000
ACTAD    EQU   X'08'                                                    02280000
DYNBF    EQU   X'04'                                                    02300000
READX    EQU   X'02'                                                    02320000
RELRD    EQU   X'01'                                                    02340000
KEYOP    EQU   X'80'                                                    02360000
LGNOP    EQU   X'40'                                                    02380000
READ     EQU   X'08'                                                    02400000
KEY      EQU   X'04'                                                    02420000
ADD      EQU   X'02'                                                    02440000
         DC    X'00'   FILLER - FILLER - FILLER                         02460000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   02480000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   02500000
         EJECT                                                          02520000
*      DATA CONTROL BLOCK (DCB) DEFINITION                              02540000
*                                                                       02560000
         DCBD  DSORG=DA                                                 02580000
*                                                                       02600000
*                                                                       02620000
*                                                                       02640000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       02660000
         DS    0F                                                       02680000
DECBDEF  DSECT                                                          02700000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        02720000
DECTYPE  DS    CL2            TYPE FIELD                                02740000
DECLNGTH DS    CL2            DATA LENGTH                               02760000
DECDCBAD DS    CL4            ADDRESS OF DCB                            02780000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      02800000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        02820000
DECKYADR DS    CL4            ADDRESS OF KEY                            02840000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               02860000
         EJECT                                                          02880000
*                                                                       02900000
*      I/O BLOCK (IOB) DEFINITION                                       02920000
*                                                                       02940000
*              STANDARD IOB                                             02960000
         DS    0F                                                       02980000
IOBDEF   DSECT                                                          03000000
IOBFLAG1 DS    CL1            STATUS FLAG                               03020000
IOBFLAG2 DS    CL1            ERROR FLAG                                03040000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       03060000
IOBECBPT DS    CL4            ECB POINTER                               03080000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       03100000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           03120000
         DS    CL1                                                      03140000
         DS    CL3                                                      03160000
IOBCSWST DS    CL2            STATUS BYTES                              03180000
IOBCSWCT DS    CL2            REMAINING COUNT                           03200000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   03220000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        03240000
         DS    CL3                                                      03260000
IOBDCBPT DS    0CL4           DCB POINTER                               03280000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            03300000
         DS    CL3                                                      03320000
IOBRESTR DS    0CL4           RESTART POINTER                           03340000
         DS    CL1                                                      03360000
         DS    CL3                                                      03380000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              03400000
IOBERRCT DS    CL2            ERROR COUNTER                             03420000
IOBSEEK  DS    CL8            SEEK ADDRESS                              03440000
*        BDAM EXTENDED IOB                                              03460000
*                                                                       03480000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  03500000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          03520000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     03540000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                03560000
         DS    CL3                                                      03580000
IOBDTYPE DS    CL2            TYPE FIELD                                03600000
IOBDSTAT DS    CL2            IOB STATUS                                03620000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        03640000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                03660000
         DS    CL2                                                      03680000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               03700000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        03720000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                03740000
IOBCP    DS    CL200                   CHANNEL PROGRAM AREA             03760000
         END                                                            03780000
