 TITLE 'IGG019KL -- DYNAMIC BUFFERING MODULE && START-I/O APPENDAGE'    00200021
         COPY  LCGASMSW                                                 00250001
IGG019KL CSECT                                                          00600021
         AIF   ('&LIB' NE 'LIB1').LIB1BA                                00610001
*                                                                       00650001
*                            RELEASE 23 DELETIONS                       00700001
*                                                                       00750001
*                            RELEASE 22 DELETIONS                       00800001
*                                                                       00850001
*                            RELEASE 21 DELETIONS                       00900001
*D648333                                                        YA02106 00910003
*             THE FIX FOR OX02394 IS FLAGGED YA02106            XA02394 00920003
*                                                                A44114 00950001
*D468000                                                        XA00093 00960021
*                                                                YM3709 00970002
*                                                                       01000001
*3574                                                            M1780  01050001
*  RELEASE 21.8 CHANGES AND DELETIONS                                   01060021
*D444500,445000                                                  SM0210 01070021
*A450500,451000                                                  SM0210 01080021
*STATUS CHANGE LEVEL 006   3/6/74                                       01100021
*                                                                       01150001
*THIS MODULE WAS TOTALLY REPLACED IN R-21 AS A RESULT OF A30797.  IT    01200001
*INCORPORATES IGG019KS WHICH NO LONGER EXISTS AS OF R-21.  TWO SEPARATE 01250001
*FUNCTIONS EXIST IN THE MODULE: SIO APPENDAGE FUNCTION AND FREEDBUF     01300001
*FUNCTION.  TWO SEPARATE FUNCTIONAL DESCRIPTIONS EXIST, ONE UNDER       01350001
*SIORTNE AND THE OTHER UNDER FBUFRTNE.  ALL EQUATES ARE IN 1ST ROUTINE. 01400001
*                                                                       01450001
.LIB1BA  ANOP                                                           01500001
         USING *,RAPDBASE                                               04000021
SIOEP    B     SIORTNE            START I/O APPENDAGE E.P.              04200021
         ORG   IGG019KL+8                                               04400021
FRBUFEP  B     FBUFRTNE           FREE DYNAMIC BUFFER SVC E.P.          04600021
*                                                                       04800021
* FUNCTION:                                                           * 05000021
*    THE START-I/O APPENDAGE ATTEMPTS TO ASSIGN A BUFFER TO A         * 05200021
*    READ REQUEST IF THE REQUEST SPECIFIES DYNAMIC BUFFERING AND      * 05400021
*    NO BUFFER WAS ASSIGNED BEFORE EXCP.  IF A BUFFER IS              * 05600021
*    AVAILABLE FOR ASSIGNMENT, IT IS REMOVED FROM THE BUFFER          * 05800021
*    POOL AND THE BUFFER CHAIN IS UPDATED.  THE BUFFER ADDRESS        * 06000021
*    IS PLACED IN THE REQUEST'S DECB AND IN THE READ CCWS OF THE      * 06200021
*    REQUEST'S CHANNEL PROGRAM.  THE ADDRESS OF THE SEGMENT WORK      * 06400021
*    AREA (PART OF THE BUFFER) IS PLACED IN THE IOB.  THE ROUTINE     * 06600021
*    THEN RETURNS TO IOS TO INITIATE THE I/O.                         * 06800021
*    IF NO BUFFER IS AVAILABLE THE REQUEST IS PLACED ON A QUEUE       * 07000021
*    OF REQUESTS WAITING FOR BUFFERS.  THE ROUTINE TAKES THE IOS      * 07200021
*    RETURN WHICH INDICATES THAT THE I/O REQUEST SHOULD NOT BE        * 07400021
*    INITIATED.                                                       * 07600021
*                                                                     * 07800021
* ENTRY POINT:                                                        * 08000021
*         SIOEP -- ENTERED ASYNCHRONOUSLY FROM IOS AT START-I/O       * 08200021
*         TIME.  THE ADDRESS OF IGG019KL IS PLACED IN THE             * 08400021
*         APPENDAGE VECTOR TABLE (AVT) DURING OPEN PROCESSING.        * 08600021
*         CALLING SEQUENCE -- L     15,4(AVTPTR)                      * 08800021
*                             BALR  14,15                             * 09000021
*                                                                     * 09200021
* INPUT                                                               * 09400021
*    **** REGISTER CONTENTS ****                                      * 09600021
*    REGISTER  2 -- INPUT/OUTPUT BLOCK (IOB) ADDRESS                  * 09800021
*    REGISTER  3 -- DATA EXTENT BLOCK (DEB) ADDRESS                   * 10000021
*    REGISTER  4 -- DATA CONTROL BLOCK (DCB) ADDRESS                  * 10200021
*    REGISTER  7 -- UNIT CONTROL BLOCK (UCB) ADDRESS                  * 10400021
*    REGISTER 14 -- RETURN ADDRESS                                    * 10600021
*    REGISTER 15 -- ADDRESS OF IGG019KL                               * 10800021
*                                                                     * 11000021
* OUTPUT                                                              * 11200021
*    **** REGISTER CONTENTS ****                                      * 11400021
*    ALL REGISTER CONTENTS ARE UNCHANGED EXCEPT AS FOLLOWS:           * 11600021
*    REGISTER  9 -- SET TO ZERO                                       * 11800021
*    REGISTER 10 -- USED AS A WORK REGISTER, NOT RESTORED             * 12000021
*    REGISTER 11 -- USED AS A WORK REGISTER, NOT RESTORED             * 12200021
*    REGISTER 13 -- USED AS A WORK REGISTER, NOT RESTORED             * 12400021
*                                                                     * 12600021
*    **** DATA AREAS SET BY THIS ROUTINE ****                         * 12800021
*    IOBSWAP            IF A BUFFER IS ASSIGNED, SEGMENT WORK         * 13000021
*                       AREA ADDRESS                                  * 13200021
*    IOBDSTAT BIT IOBBUFF    SET IF A BUFFER IS ASSIGNED              * 13400021
*    IOBDQPTR FIELD OF IOB POINTED TO BY BCBFRQB,  OR                 * 13600021
*    BCBFRQT            UPDATED TO POINT TO THIS IOB IF REQUEST       * 13800021
*                       MUST WAIT FOR A BUFFER                        * 14000021
*    BCBFRQB            UPDATED TO POINT TO THIS IOB IF REQUEST       * 14200021
*                       MUST WAIT FOR A BUFFER                        * 14400021
*    BCBNABFR           UPDATED IF A BUFFER IS ASSIGNED.              * 14600021
*    DECAREA            DATA ADDR IN THE ASSIGNED BUFFER              * 14800021
*    DECKYADR           KEY ADDR IN THE ASSIGNED BUFFER FOR A READ    * 15000021
*                       BY BLOCK ID, & KEY ADDR SPECIFIED 'S'.        * 15200021
*    NEXT-TO-LAST CCW ADDR   KEY ADDR WHEN KEY IS IN DYNAMIC BUFFER   * 15400021
*                            (SEE DECKYADR).                          * 15600021
*    LAST CCW ADDR      DATA ADDR                                     * 15800021
*                                                                     * 16000021
* EXITS                                                               * 16200021
*         0(R14)        RETURN TO IOS & START I/O                     * 16400021
*         4(R14)        RETURN TO IOS & DISREGARD I/O REQUEST         * 16600021
*                                                                     * 16800021
* ATTRIBUTES -- REUSABLE,PRIVILEGED,KEY=0,DISABLED                    * 17000021
*                                                                     * 17200021
* NOTES -- THIS ROUTINE SAVES AND RESTORES REGISTERS 6 AND 7.         * 17400021
*        THE SAVEAREA IS 2-FULL WORDS LOCATED AT THE LABEL            * 17600021
*        'SAVEAREA' IN THIS MODULE.                                   * 17800021
*                                                                     * 18000021
         IEZBITS                                                        18200021
*                  REGISTER EQUATES                                     18400021
R0       EQU   0        INPUT REGISTER 0    SVC                         18600021
R1       EQU   1        INPUT REGISTER 1                                18800021
RIOB     EQU   2        ADDRESS OF IOB                                  19000021
RBASE3   EQU   3        BASE REGISTER       SVC                         19200021
RDCB     EQU   4        ADDRESS OF DCB                                  19400021
SVRBREG  EQU   5                        IOS BASE(SIO) OR SVRBPTR(SVC 57 19450001
RBUFFR   EQU   6        BUFFER ADDRESS                                  19800021
RSWA     EQU   6        PTR TO SEGMENT WORK AREA (ASSGNBUF)             20000021
RWORK6   EQU   6        WORK REGISTER                                   20200021
RDECB    EQU   7        DECB ADDRESS                                    20400021
RCCW     EQU   7        PTR TO CCW TO MODIFY (ASSGNBUF)                 20600021
RWORK7   EQU   7        WORK REGISTER                                   20800021
RWORK9   EQU   9        WORK REGISTER                                   21000021
RWKAREA  EQU   10       ADDR OF SVRB EXTENDED SAVEAREA                  21200021
RWORK10  EQU   10       WORK REGISTER                                   21400021
RWORK11  EQU   11       WORK REGISTER                                   21600021
RWORK12  EQU   12       WORK REGISTER                                   21800021
RLINK    EQU   13       INTERNAL LINKAGE REGISTER                       22000021
RWORK13  EQU   13       WORK REGISTER                                   22200021
RRETURN  EQU   14       RETURN ADDRESS                                  22400021
RRETCODE EQU   15       RETURN CODE REGISTER                            22600021
RAPDBASE EQU   15       BASE REGISTER FOR APPENDAGE ROUTINES            22800021
         SPACE 5                                                        23000021
ALL      EQU   X'FF'                    ALL BITS ON                     23050001
PGMSTATE EQU   X'01'                    BIT INDICATING PGM STATE        23100001
KEY      EQU   X'F0'                    KEY FIELD                       23150001
KEYDATOP EQU   X'0E'         CCW OP-CODE  READ KEY & DATE               23800021
RDDATAOP EQU   X'06'         CCW OP-CODE  READ DATA                     24000021
LENZERO   EQU   0                       KEY LENGTH OF 0          YM3709 24050002
SIORTNE  EQU   *                                                        24200021
*                                                                     * 24400021
         USING IOBSTDRD,RIOB                                            24600021
         USING IHADCB,RDCB                                              24800021
         TM    IOBDTYP2,IOBRQUST  IS THIS A READ REQUEST?               25000021
         BCR   8,RRETURN          IF NOT, RETURN TO IOS                 25200021
         TM    IOBDTYPE,IOBDYNBF  DOES REQUEST SPECIFY DYNAMIC          25400021
*                                 BUFFERING?                            25600021
         BCR   8,RRETURN          IF NO, RETURN TO IOS                  25800021
         TM    IOBSTAT1,IOBBUFF   HAS A BUFFER BEEN ASSIGNED TO         26000021
*                                 THIS REQUEST?                         26200021
         BCR   1,RRETURN          IF SO, RETURN TO IOS                  26400021
*                                                                       26600021
*                       IF A BUFFER IS AVAILABLE, ASSIGN IT TO          26800021
*                       THIS REQUEST AND UPDATE THE BUFFER POOL.        27000021
*                                                                       27200021
         L     RWORK10,DCBBUFCB   GET BUFFER CONTROL BLOCK ADDR         27400021
         USING BCBDEF,RWORK10                                           27600021
         L     RWORK11,BCBNABFR   GET ADDRESS OF NEXT AVAILABLE         27800021
*                                 BUFFER                                28000021
         LTR   RWORK11,RWORK11    IS ONE AVAILABLE?                     28200021
         BZ    PTONBUFQ           IF NOT BRANCH TO QUEUE REQUEST        28400021
         USING BUFFR,RWORK11                                            28600021
         L     RWORK13,BUFNXT     GET ADDR OF 2ND BUFFER (OR 0).        28800021
         DROP  RWORK11                                                  29000021
         ST    RWORK13,BCBNABFR   MAKE IT NEXT AVAILABLE                29200021
         STM   RWORK6,RWORK7,SAVEAREA  SAVE WORK REGISTERS              29400021
         BAL   RLINK,ASSGNBUF     ASSIGN BUFFER TO REQUEST              29600021
         LM    RWORK6,RWORK7,SAVEAREA  RELOAD SAVED REGISTERS           29800021
*                                                                       30000021
SIORET   SR    RWORK9,RWORK9      SET REG 9 TO ZERO                     30200021
         BR    RRETURN            RETURN TO IOS TO INITIATE             30400021
*                                 I/O REQUEST                           30600021
         SPACE 5                                                        30800021
PTONBUFQ EQU   *                                                        31000021
*                                                                       31200021
*                       NO BUFFER WAS AVAILABLE. PUT THIS IOB ON        31400021
*                       THE QUEUE WAITING FOR BUFFERS.                  31600021
*                                                                       31800021
         L     RWORK13,BCBFRQT    ADDR OF 1ST IOB ON QUEUE.             32000021
         LTR   RWORK13,RWORK13    IS THE QUEUE EMPTY?                   32200021
         BNZ   ONEONQ             BRANCH IF NOT                         32400021
         ST    RIOB,BCBFRQT       IF SO, STORE IOB ADDR AS FIRST        32600021
         B     BOTTOMST                                                 32800021
ONEONQ   L     RWORK13,BCBFRQB    GET ADDR OF LAST IOB ON QUEUE         33000021
         ST    RIOB,IOBDQPTR-IOBSTDRD(RWORK13)   POINT CHAIN TO         33200021
*                                                THIS IOB               33400021
BOTTOMST ST    RIOB,BCBFRQB       THIS IOB IS LAST ON QUEUE             33600021
         SR    RWORK9,RWORK9      ZERO REGISTER 9                       33800021
         B     4(RRETURN)         IOS RETURN - DON'T DO I/O             34000021
         DROP  RIOB                                                     34200021
         DROP  RDCB                                                     34400021
*                                                                       34600021
SAVEAREA DC    2F'0'                                                    34800021
         EJECT                                                          35000021
*                                                                       35200021
*                  THIS SUBROUTINE IS USED BY THE START-I/O             35400021
*                  APPENDAGE AND THE FREE DYNAMIC BUFFER SVC            35600021
*                  ROUTINE.                                             35800021
*                  IT ASSIGNS A BUFFER TO AN I/O REQUEST BY             36000021
*                  PLACING THE BUFFER ADDRESS INTO THE DECB             36200021
*                  AND THE CHANNEL PROGRAM.  IT ALSO PLACES THE         36400021
*                  SEGMENT WORK AREA ADDRESS IN THE IOB.                36600021
*                                                                       36800021
*              REGISTER INPUT:  RIOB    - ADDR OF IOB TO WHICH          37000021
*                                    BUFFER WILL BE ASSIGNED            37200021
*                               RDCB    - DCB ADDRESS                   37400021
*                               RWORK11 - BUFFER ADDRESS                37600021
*                               RLINK   - RETURN ADDRESS                37800021
*              REGISTER OUTPUT: RSWA    - WORK REGISTER                 38000021
*              REGISTER OUTPUT: RWORK9  - WORK REGISTER                 38200021
*                               RCCW    - WORK REGISTER                 38400021
*                             RWORK9  - WORK REGISTER                   38600021
*                               RWORK10 - WORK REGISTER                 38800021
*                               RWORK11 - WORK REGISTER                 39000021
         USING BUFFR,RWORK11                                            39200021
         USING IHADCB,RDCB                                              39400021
         USING IOBSTDRD,RIOB                                            39600021
ASSGNBUF L     RWORK9,IOBECBPT    GET DECB ADDRESS                      39800021
         USING DECB,RWORK9                                              40000021
*                                 PLACE SWA ADDR IN IOB                 40200021
         LR    RWORK10,RIOB       PLACE IOB ADDRESS IN WORK REG         40400021
         LA    RSWA,IOBSTDRD-IOBSWAP   DISP TO IOBSWAP FIELD            40600021
         SR    RWORK10,RSWA       POINT TO IOB PREFIX                   40800021
         USING IOBSWAP,RWORK10                                          41000021
         ST    RWORK11,IOBSWAP    PLACE SWA ADDR IN IOB                 41200021
*                                 DATA & KEY (IF REQUESTED) WILL        41400021
*                                 BE READ INTO THE SEGMENT AREA         41600021
*                                 OF THE DYNAMIC BUFFER.  THE           41800021
*                                 USER WILL BE PASSED THE ADDRESS       42000021
*                                 OF LOCATIONS IN THE RECORD            42200021
*                                 AREA.                                 42400021
*                                                                       42600021
         LA    RSWA,BUFSEGAR      GET ADDRESS OF SEGMENT AREA           42800021
         L     RWORK11,BUFRAPTR   GET ADDRESS OF RECORD AREA            43000021
         L     RCCW,IOBDCPND      POINT BEYOND LAST CCW                 43200021
         SH    RCCW,H16           POINT TO NEXT-TO-LAST CCW             43400021
*                                 FOR A READ BY BLOCK ID, KEY           43600021
*                                 CODED 'S', THE KEY IS READ            43800021
*                                 INTO THE DYNAMIC BUFFER.              44000021
         TM    IOBDTYP2,IOBTYPE   IS THIS READ BY BLOCK ID?             44200021
         BO    FILLSCCW           BRANCH IF NO                          44400021
         TM    IOBDTYP2,IOBSKEY   WAS KEY ADDRESS CODED 'S'?            44600021
         BZ    FILLSCCW           BRANCH IF NO                          44800021
         ST    RWORK11,DECKYADR   PLACE KEY ADDRESS IN DECB             45000021
         CLI   DCBKEYLE,LENZERO   ZERO KEY LENGTH?               SM0210 45050021
         BE    FILLSCCW           BR IF YES                      SM0210 45100021
         ST    RWORK11,0(RCCW)    PLACE ADDR OF KEY IN RECORD   XA00093 45200021
*                                 AREA INTO NEXT-TO-LAST CCW.           45400021
         MVI   0(RCCW),KEYDATOP   RESTORE OP-CODE                       45600021
*                                 INCREMENT RECORD AREA & SEGMENT       45800021
*                                 AREA POINTERS BEYOND KEY.             46000021
         SR    RWORK10,RWORK10                                          46200021
         IC    RWORK10,DCBKEYLE   GET LENGTH OF KEY                     46400021
         AR    RWORK11,RWORK10    BUMP RECORD AREA POINTER              46600021
*                                                                       47000021
FILLSCCW ST    RWORK11,DECAREA    PLACE DATA ADDRESS IN DECB            47200021
         ST    RSWA,8(RCCW)       PLACE DATA ADDRESS IN LAST CCW        47400021
         MVI   8(RCCW),RDDATAOP   RESTORE OP-CODE.                      47600021
         OI    IOBDSTAT,IOBBUFF   SET BUFFER-ASSIGNED SWITCH            47800021
         BR    RLINK              RETURN TO CALLER                      48000021
         DROP  RWORK11                                                  48200021
         DROP  RWORK9                                                   48400021
         DROP  RIOB                                                     48600021
         DROP  RDCB                                                     48800021
         EJECT                                                          49000021
FBUFRTNE EQU   *                                                        49200021
*                                                                     * 49400021
* FUNCTION:                                                           * 49600021
*    THE FREE DYNAMIC BUFFER ROUTINE RELEASES A DYNAMIC BUFFER.       * 49800021
*    IF ANY IOBS ARE ON THE UNSCHEDULED QUEUE (WAITING FOR A          * 50000021
*    BUFFER) THE ROUTINE ASSIGNS THE BUFFER TO THE FIRST IOB ON       * 50200021
*    THE QUEUE, AND ISSUES AN EXCP FOR THAT IOB.  IF NO IOBS ARE      * 50400021
*    ON THE UNSCHEDULED QUEUE THE ROUTINE PLACES THE BUFFER ON        * 50600021
*    THE CHAIN OF AVAILABLE BUFFERS.                                  * 50800021
*                                                                     * 51000021
* ENTRY POINT:                                                        * 51200021
*         FRBUFEP -- ENTERED FROM MODULE IGC0005G WHEN SVC 57 IS      * 51400021
*         ISSUED FOR A DCB WHICH SPECIFIED DIRECT ORGANIZATION.       * 51600021
*         CALLING SEQUENCE -- L    15,DCBDEBAD                        * 51800021
*                             L    15,DEBAPPAD                        * 52000021
*                             L    15,4(15)                           * 52200021
*                             BAL  14,8(15)                           * 52400021
*                                                                     * 52600021
* INPUT                                                               * 52800021
*    **** REGISTER CONTENTS ****                                      * 53000021
*    REGISTER  0 -- DECB ADDRESS                                      * 53200021
*    REGISTER  1 -- DCB ADDRESS                                       * 53400021
*    REGISTER 10 -- ADDRESS OF SVRB EXTENDED SAVEAREA                 * 53600021
*    REGISTER 14 -- RETURN ADDRESS                                    * 53800021
*    REGISTER 15 -- ADDRESS OF IGG019LE                               * 54000021
*                                                                     * 54200021
* OUTPUT                                                              * 54400021
*    **** REGISTER CONTENTS ****                                      * 54600021
*    ALL REGISTERS EXCEPT REGISTER 14 CAN BE USED WITHOUT SAVING      * 54800021
*    OR RESTORING CONTENTS.                                           * 55000021
*    REGISTER 15 CONTAINS RETURN CODE.                                * 55200021
*                                                                     * 55400021
*    **** DATA FIELDS SET BY THIS ROUTINE ****                        * 55600021
*    BCBFRQT       IF AN IOB IS WAITING FOR A BUFFER, PTR TO 1ST      * 55800021
*                  IOB ON QUEUE IS UPDATED.                           * 56000021
*    IOBDQPTR      FIELD IN DEQUEUED IOB IS CLEARED                   * 56200021
*    IF THE FREED BUFFER IS ASSIGNED TO A WAITING REQUEST, THE        * 56400021
*    BUFFER ADDRESS IS PLACED IN THE CHANNEL PROGRAM AND DECB         * 56600021
*    FIELDS, AND IN THE IOB AS THE SEGMENT WORK AREA ADDRESS (SEE     * 56800021
*    SIORTNE DESCRIPTION FOR DETAILS).                                * 57000021
*    BCBNABFR      IF THE BUFFER IS NOT ASSIGNED TO A REQUEST,        * 57200021
*                  ITS ADDRESS IS PLACED IN BCBNABFR                  * 57400021
*    BUFNXT        FIELD OF THE RELEASED BUFFER IS SET TO THE         * 57600021
*                  ADDR OF THE 2ND AVAILABLE BUFFER.                  * 57800021
*    BUFBI         SET TO ZERO                                        * 58000021
*                                                                     * 58200021
* EXTERNAL REFERENCES                                                 * 58400021
*        EXCP CALL TO IOS                                             * 58600021
*                                                                       58800021
* EXITS, NORMAL                                                       * 59000021
*    BRANCH RETURN TO IGC0005G ON REGISTER 14.  RETURN CODE (R15)     * 59200021
*    = 0.                                                             * 59400021
*                                                                     * 59600021
* TABLES / WORK AREAS                                                 * 59800021
*        IOB, DCB, DECB, BUFFER CONTROL BLOCK                         * 60000021
*                                                                     * 60200021
* ATTRIBUTES -- REENTRANT, READONLY, PREVILEGED, KEY=0                * 60400021
*                                                                     * 60600021
* NOTES -- THE ROUTINE MUST DISABLE TO UPDATE THE SERIALLY            * 60800021
*        REUSABLE IOB AND BUFFER QUEUES.                              * 61000021
*                                                                     * 61200021
         EJECT                                                          61400021
         LR    RBASE3,RAPDBASE    ESTABLISH BASE REGISTER               61600021
         USING IGG019KL,RBASE3                                          61800021
         DROP  RAPDBASE                                                 61802001
         LR    RDCB,R1            TRANSFER DCB ADDRESS                  61804001
         USING IHADCB,RDCB                                              61806001
         LR    RDECB,R0           TRANSFER DECB ADDRESS                 61808001
         USING DECB,RDECB                                               61808401
*                                                                       61808801
*                       LOCATE THE BEGINNING ADDRESS OF THE             61809201
*                       BUFFER BEING FREED.                             61809601
*                                                                       61809701
         L     RBUFFR,DECAREA     ASSUME RECORD AREA ADDR = DATA        61809801
*                                 ADDR                                  61809901
         TM    DECTYPE2,DECKEYS   WAS KEY IN BUFFER (CODED 'S')?        61813201
         BZ    FBU0500            BRANCH NO                             61815201
         L     RBUFFR,DECKYADR    RECORD AREA ADDR = KEY ADDR           61823201
FBU0500  EQU   *                                                        61833201
         LA    RWORK12,BUFRECAR-BUFBFPTR                                61835201
         SR    RBUFFR,RWORK12     POINT TO ADDR OF BEGINNING OF         61837201
*                                 BUFFER                                61839201
         L     RBUFFR,0(RBUFFR)   GET BUFFER ADDRESS                    61839601
         USING BUFFR,RBUFFR                                             61839701
         XC    BUFBI,BUFBI        CLEAR RECORD AREA OFFSET PTR          61839801
         L     RWORK12,DCBBUFCB   BUFFER CONTROL BLOCK ADDR             61839901
         USING BCBDEF,RWORK12                                           61853201
         AIF   ('&LIB' EQ 'LIB1').LIB1AA                                61866701
         MODESET MF=(E,DISABLE)   DISABLE IN ORDER TO UPDATE QS         61880001
         AGO   .LIB1AB                                                  61920001
.LIB1AA  ANOP                                                           61960001
         SSM   NOINTRP            DISABLE IN ORDER TO UPDATE QS         62010001
.LIB1AB  ANOP                                                           62100001
         L     RIOB,BCBFRQT       ADDR OF FIRST IOB QUEUED              62150001
         LTR   RIOB,RIOB          ARE THERE ANY IOBS?                   62200001
         BZ    MAKEAVAL           IF NOT, GO MAKE THIS BUFFER           62250001
*                                 AVAILABLE                             62300001
*                                                                       62350001
*                       UPDATE QUEUE BY REMOVING FIRST IOB              62400001
*                                                                       62450001
         USING IOBSTDRD,RIOB                                            62500001
CHAIN    L     RWORK9,IOBDQPTR    GET ADDRESS OF NEXT IOB AND           62550001
         ST    RWORK9,BCBFRQT     MAKE IT THE NEXT IOB ON QUEUE         62600001
         XC    IOBDQPTR,IOBDQPTR  CLEAR QUEUING FIELD                   62650001
         AIF   ('&LIB' EQ 'LIB1').LIB1AC                                64240001
         MODESET MF=(E,ENABLE)    ENABLE INTERRUPTS                     64280001
         AGO   .LIB1AD                                                  64320001
.LIB1AC  ANOP                                                           64360001
         SSM   INTRPTOK           ENABLE INTERRUPTS                     64362001
.LIB1AD  ANOP                                                           64500001
         LR    RWORK11,RBUFFR     PUT BUFFER ADDR IN R11                64502001
         LR    RAPDBASE,RBASE3    RESTORE BASE REG FOR SUBRTN    XM6073 64502421
         BAL   RLINK,ASSGNBUF     ASSIGN THE BUFFER TO THE              64504001
*                                 DEQUEUED IOB.                         64506001
         MVC   IOBDQPTR+1(3),IOBECBPT+1   SAVE ECB ADDR         YA02106 64510003
         LA    RWORK11,IOBCSW+3         ADDR OF TEMP ECB        YA02106 64512003
         ST    RWORK11,IOBECBPT         INTO IOB                YA02106 64514003
         AIF   ('&LIB' NE 'LIB1').LIB1BB                                64520001
         USING PSW,RWKAREA              SET UP PSW BASE PTR      A44114 64530001
         USING RBSECT,SVRBREG           SET UP BASE FOR SVRB     A44114 64540001
         LA    RWKAREA,RBEXSAVE         RESTORE EX SAVE PTR      M1780  64542001
         MVC   FULLPSW,RBOPSW           MV USER'S PSW FROM SVRB  A44114 64544001
*                                       FOR FREEDBUF TO EXTENDED SAVE   64546001
         LA    RRETCODE,LPSWBR1         LOAD RET ADDR FROM LPSW  A44114 64548001
         ST    RRETCODE,INSTADDR        ST RET ADDR IN 1ST COPY  A44114 64548401
*                                       OF PSW TO BE USED               64548801
         NI    KEYAMWP,ALL-PGMSTATE     PUT 1ST COPY OF PSW IN   A44114 64549201
*                                       SUPERVISOR STATE,USER KEY       64549601
         USING PSW-PSWLG,RWKAREA        APPLY PSW DSECT TO NEXT  A44114 64549701
*                                       8 BYTES WITHOUT CHANGING BASE   64549801
*                                       PTR, ONLY ITS APPLICABILITY 8   64549901
*                                       BYTES BEYOND ITS ADDRESS        64566601
         MVC   FULLPSW,RBOPSW           MV 2ND COPY OF           A44114 64576601
*                                       USER'S PSW TO EXTENDED SAVE     64586601
         LA    RRETCODE,LPSWBR2         LOAD RET ADDRESS FROM    A44114 64596601
*                                       EXECUTION OF 2ND LPSW           64598601
         ST    RRETCODE,INSTADDR        ST ADDR IN 2ND PSW       A44114 64599001
         NI    KEYAMWP,ALL-KEY-PGMSTATE SET UP FOR SUPER STATE,  A44114 64599401
*                                       KEY 0                           64599801
         LPSW  RBEXSAVE                 CHANGE TO USER KEY, SUPE A44114 64599901
*                                       STATE SO THAT IOS WILL PERFORM  64649901
*                                       VALIDITY CHECK ON DEB & BUFFERS 64659901
LPSWBR1  EQU   *                                                 A44114 64669901
.LIB1BB  ANOP                                                           64679901
         EXCP  (RIOB)                   SCHEDULE I/O FOR NEXT IOB ON Q  64699901
         AIF   ('&LIB' NE 'LIB1').LIB1BC                                64749901
         LPSW  PSW                      RETURN TO SUPER STATE,   A44114 64799901
*                                       KEY 0                           64816601
         DROP  RWKAREA                                                  64826601
LPSWBR2  EQU   *                                                 A44114 64828601
.LIB1BC  ANOP                                                           64830601
         SR    RRETCODE,RRETCODE  NORMAL COMPLETION                     64850001
         BR    RRETURN            RETURN TO IGC0005G                    64900001
*                                                                       64950001
         SPACE 5                                                        65000001
*                                                                       65050001
*                       NO IOBS ARE WAITING FOR BUFFERS. RETURN         65100001
*                       BUFFER TO THE AVAILABLE CHAIN.                  65150001
*                                                                       65200001
MAKEAVAL EQU   *                                                        65250001
         L     RWORK9,BCBNABFR    GET ADDR OF AVAILABLE BUFFER          65300001
         USING BUFFR,RBUFFR                                             65350001
         ST    RWORK9,BUFNXT      POINT THIS BUFFER TO IT               65400001
         ST    RBUFFR,BCBNABFR    MAKE THIS ONE NEXT AVAILABE           65450001
         DROP  RBUFFR              (LIFO QUEUE)                         65500001
         AIF   ('&LIB' EQ 'LIB1').LIB1AE                                68440001
         MODESET MF=(E,ENABLE)    ENABLE FOR INTERRUPTS                 68480001
         AGO   .LIB1AF                                                  68520001
.LIB1AE  ANOP                                                           68560001
         SSM   INTRPTOK           ENABLE FOR INTERRUPTS                 68610001
.LIB1AF  ANOP                                                           68700001
         SR    RRETCODE,RRETCODE  RETURN CODE = 0.                      68750001
         BR    RRETURN            RETURN TO IGC0005G.                   68800001
*                                                                       68850001
H16      DC    H'16'                                                    68900001
         AIF   ('&LIB' NE 'LIB1').LIB1JA                                69700001
NOINTRP  DC    X'00'              CONSTANT FOR DISABLING SYSTEM         69750001
INTRPTOK DC    X'FF'              CONSTANT FOR ENABLING SYSTEM          69800001
         AGO   .LIB1JB                                                  70020001
.LIB1JA  ANOP                                                           70040001
         DS    0F                 ALIGN LISTS                           70060001
*                                                                       70080001
ENABLE   MODESET ENABLE=YES,MF=L                                        70100001
*                                                                       70120001
DISABLE  MODESET ENABLE=NO,MF=L                                         70140001
*                                                                       70160001
.LIB1JB  ANOP                                                           70180001
         CNOP  0,8           INSURE MODULE SIZE IS MULTIPLE OF 8        81200021
         EJECT                                                          81400021
         IEZIOB                                                         81600021
*                                                                       81800021
         DCBD  DSORG=DA                                                 82000001
*                                                                       82200021
         IHADECB                                                        82400021
*                                                                       82600021
BCBDEF   DSECT                                                          82800021
BCBFRQT  DS    A        ADDR OF FIRST IOB WAITING FOR A BUFFER          83000021
BCBFRQB  DS    A        ADDR OF LAST IOB WAITING FOR A BUFFER           83200021
BCBNABFR DS    A        ADDR OF THE NEXT BUFFER AVAILABLE               83400021
BCBTBRS  DS    F        SIZE OF BCB & BUFFER POOL IN BYTES              83600021
*                                                                       83800021
BUFFR    DSECT                                                          84000021
BUFNXT   DS    A        ADDR OF NEXT BUFFER ON AVAILABLE CHAIN          84200021
BUFRAPTR DS    A        ADDRESS OF RECORD AREA                          84400021
BUFBI    DS    FL2      OFFSET OF NEXT SEGMENT IN RECORD AREA           84600021
BUFSEGAR EQU   *        SEGMENT AREA, LENGTH IS THE SMALLER OF          84800021
*                       BLOCKSIZE + KEY-LENGTH OR TRACK CAPACITY.       85000021
BUFFERB  DSECT          FORMAT OF BUFFER BEYOND SEGMENT AREA            85200021
BUFBFPTR DS    A        ADDRESS OF BEGINNING OF BUFFER                  85400021
BUFRECAR EQU   *        RECORD AREA; BUFBFPTR IS ALIGNED SO THAT        85600021
*                       BUFRECAR FALLS AS SPECIFIED BY DCBBFALN.        85800021
*                                                                       86000021
         AIF   ('&LIB' NE 'LIB1').LIB1BD                                86050001
PSW      DSECT                          PROGRAM STATUS WORD FORMAT      86100001
         DS    0F                                                       86150001
FULLPSW  DS    0CL8                                                     86200001
SYSMASK  DS    BL1                      SYSTEM MASK                     86250001
KEYAMWP  DS    XL1                      KEY AND STATE OF USER           86300001
INTERUPT DS    H                        INTERRUPT CODE                  86350001
INSTADDR DS    A                        ADDR OF NEXT INSTRUCTION        86400001
PSWLG    EQU   *-PSW                    LENGTH OF PSW                   86450001
*                                                                       86500001
         EJECT                                                          86550001
         IKJRB                                                          86600001
.LIB1BD  ANOP                                                           86650001
         END                                                            88400021
