IGG019KM CSECT                                                          00020000
 TITLE   'IGG019KM - SELF FORMAT MODULE'                                00040000
*          RELEASE 20 DELETIONS                                         00065000
*          RELEASE 21 DELETIONS                                         00070000
*058600,059200                                                  SA53787 00075000
*C058500                                                        YA02106 00085021
*    THE FIX FOR SA69165 IS FLAGGED YA02106                     SA69165 00087021
*STATUS CHANGE LEVEL 006                                                00092018
*FUNCTION/OPERATION- THIS MODULE CONTAINS THREE ROUTINES WHOSE        * 00100000
*   FUNCTIONS ARE,                                                    * 00120000
*   1.CREATE THE CHANNEL PROGRAM REQUIRED TO ADD A NEW BLOCK TO A     * 00140000
*    DATA SET OF V OR U FORMAT RECORDS. THE REQUEST WHICH PERFORMS    * 00160000
*    THIS IS A WRITE MACRO WITH A TYPE DA.                            * 00180000
*    THE CHANNEL PROGRAM WILL CONSIST OF TWO PARTS, THE FIRST THREE   * 00200000
*    CCWS WILL READ THE CAPACITY RECORD FROM A TRACK, THE SECOND      * 00220000
*    SEQUENCE OF CCWS WILL WRITE THE NEW RECORD AND UPDATE THE        * 00240000
*    CAPACITY RECORD.                                                 * 00260000
*                                                                     * 00280000
*   2.CALCULATE THE NUMBER OF BYTES THE NEW BLOCK WILL REQUIRE ON THE * 00300000
*    TRACK AND COMPARE THAT VALUE TO THE NUMBER OF UNUSED BYTES       * 00320000
*    REMAINING ON THE TRACK ACCORDING TO THE CAPACITY RECORD. IF THE  * 00340000
*    BLOCK WILL FIT, THE COUNT FIELD FOR THE NEW BLOCK AND AN UPDATED * 00360000
*    CAPACITY RECORD ARE FORMED AND THE SECOND PART OF THE CHANNEL    * 00380000
*    PROGRAM IS SCHEDULED VIA THE EXCP MACRO. IF THE BLOCK WILL NOT   * 00400000
*    FIT, INDICATORS ARE SET IN THE IOB WHICH WILL CAUSE THE DECB TO  * 00420000
*    BE POSTED WITH A NO-SPACE-FOUND EXCEPTION CODE.                  * 00440000
*                                                                     * 00460000
*   3.SEARCH THE UNSCHEDULED QUEUE OF IOBS WHEN THE CURRENT WRITE ADD * 00480000
*    HAS COMPLETED, FOR ANOTHER WRITE ADD REQUEST. THE FIRST SUCH     * 00500000
*    UNSCHEDULED REQUEST FOUND (IF ANY) WILL BE UNQUEUED AND          * 00520000
*    SCHEDULED VIA EXCP.                                              * 00540000
*                                                                     * 00560000
*ENTRY POINTS- THERE ARE THREE ENTRY POINTS AS FOLLOWS,               * 00580000
*   1.   'IECDSF1' IS ENTERED FROM THE FOUNDATION MODULE (IGG019KA)   * 00600000
*     TO PERFORM FUNCTION 1.  CALLING SEQUENCE IS, L    15,DCBDFOR    * 00620000
*                                                  BALR 14,15         * 00640000
*   2.   'IECDSF2' IS ENTERED FROM ASYNCHRONOUS INTERRUPT (IGG019KA)  * 00660000
*     TO PERFORM FUNCTION 2. AND ALSO FUNCTION 3. IF THE BLOCK WILL   * 00680000
*     NOT FIT ON THE TRACK. CALLING SEQUENCE IS, L   15,DCBDFOR       * 00700000
*                                                BC  15,8(15)         * 00720000
*   3.   'IECDSF3' IS ENTERED FROM ASYNCHRONOUS INTERRUPT TO PERFORM  * 00740000
*     FUNCTION 3. CALLING SEQUENCE IS,    L     15,DCBDFOR            * 00760000
*                                         BC    15,12(15)             * 00780000
*                                                                     * 00800000
*INPUT-                                                               * 00820000
*   TO FUNCTION 1.                                                    * 00840000
*    REGISTER 4  DCB ADDRESS                                          * 00860000
*    REGISTER 5  DECB ADDRESS                                         * 00880000
*    REGISTER 6  ADDRESS OF THE LOCATION FOR CCW 1.                   * 00900000
*    REGISTER 7  IOB ADDRESS                                          * 00920000
*    REGISTER 11 BASE ADDRESS OF MODULE IGG019KA                      * 00940000
*    REGISTER 14 RETURN ADDRESS                                       * 00960000
*    REGISTER 15 BASE OF THIS MODULE                                  * 00980000
*                                                                     * 01000000
*   TO FUNCTION 2.                                                    * 01020000
*    REGISTER 1  IOB ADDRESS                                          * 01040000
*    REGISTER 10 12* (IOS QUEUEING ELEMENT) ADDRESS                   * 01060000
*    REGISTER 13 DCB ADDRESS                                          * 01080000
*    REGISTER 15 BASE ADDRESS FOR THIS MODULE                         * 01100000
*                                                                     * 01120000
*   TO FUNCTION 3.                                                    * 01140000
*    REGISTER 1  IOB ADDRESS                                          * 01160000
*    REGISTER 13 DCB ADDRESS                                          * 01180000
*    REGISTER 15 BASE ADDRESS FOR THIS MODULE                         * 01200000
*                                                                     * 01220000
*OUTPUT- FUNCTION 1 WILL CONSTRUCT THE REQUIRED CCWS AND LEAVE        * 01240000
*   REGISTER 6 POSITIONED AT THE LAST CCW.                            * 01260000
*   FUNCTION 2 WILL FORM THE NEW BLOCK'S COUNT FIELD AND UPDATED      * 01280000
*   CAPACITY RECORD IF THE RECORD FITS OR WILL SET BITS IN THE IOB    * 01300000
*   (IOBDSTAT) IF THERE IS NO SPACE FOR THE BLOCK.                    * 01320000
*   FUNCTION 3 WILL SCHEDULE ANOTHER WRITE ADD IF ONE HAS BEEN        * 01340000
*   QUEUED AWAITING THE CURRENT WRITE'S COMPLETION.                   * 01360000
*                                                                     * 01380000
*EXTERNAL ROUTINES-                                                   * 01400000
*        'IGG019KQ' IS USED TO CONSTRUCT ADDITIONAL CCWS TO VERIFY    * 01420000
*   THE NEW BLOCK IF THE WRITE VALIDITY CHECK OPTION WAS SPECIFIED IN * 01440000
*   THE OPTCD PARAMETER OF THE DCB MACRO.                             * 01460000
*                                                                     * 01480000
*EXITS-NORMAL- 'EXITFDN' IS THE RETURN TO MODULE IGG019KA AFTER THE   * 01500000
*   CHANNEL PROGRAM HAS BEEN CONSTRUCTED.                             * 01520000
*        'EXITSUPV' IS AN SVC EXIT TO RETURN TO SUPERVISOR WHEN THE   * 01540000
*   BLOCK FITS ON THE TRACK AND THE IOB HAS BEEN RESCHEDULED WITH IOS.* 01560000
*        'EXITASI' IS THE RETURN TO ASYNCHRONOUS INTERRUPT AFTER THE  * 01580000
*   UNSCHEDULED QUEUE HAS BEEN SCANNED FOR ANOTHER WRITE ADD.         * 01600000
*EXITS-ERROR-  'EXITERR' IS A RETURN TO ASYNCHRONOUS INTERRUPT ALSO   * 01620000
*   BUT WILL BYPASS FEEDBACK TESTS BECAUSE THIS WRITE ADD COMPLETED   * 01640000
*   ABNORMALLY.                                                       * 01660000
*                                                                     * 01680000
*TABLES/WORK AREA- THE COMMUNICATION VECTOR TABLE IS REFERENCED TO    * 01700000
*   REACH THE DIRECT ACCESS DEVICE TABLE WHICH SUPPLIES THE DEVICE    * 01720000
*   CHARACTERISTICS NECESSARY TO CALCULATE THE BYTES REQUIRED FOR     * 01740000
*   THIS BLOCK ON THIS DEVICE.                                        * 01760000
*                                                                     * 01780000
*ATTRIBUTES- THIS ROUTINE IS REENTRANT, FUNCTION 1. IS EXECUTED       * 01800000
*   ENABLED WHILE FUNCTIONS 2., AND 3. ARE EXECUTED DISABLED AS       * 01820000
*   EXTERED FROM ASYNCHRONOUS INTERRUPT.                              * 01840000
*                                                                     * 01860000
*NOTES- THE REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT      * 01880000
*   WITH MODULES  IGG019KA, IGG019KQ.                                 * 01900000
*                                                                       01920000
*                                                                       01940000
*                                                                       01960000
         USING IGG019KM,SF1BASE                                         01980000
         USING IOBDEF,IOBREG                                            02000000
         USING IHADCB,DCBREG                                            02020000
         USING DECBDEF,DECBREG                                          02040000
*                                                                       02060000
*              REGISTER USAGE                                           02080000
*                                                                       02100000
WKREG2   EQU   1                       WORKING REGISTER                 02120000
REG2     EQU   2                        SRCH/ID PTR HOLD REGISTER       02130013
*                                       VERIFY MODULE                   02140000
DEBREG   EQU   3                       DEB ADDRESS                      02160000
DCBREG   EQU   4                       DCB ADDRESS                      02180000
DECBREG  EQU   5                       DECB ADDRESS                     02200000
CCWIND   EQU   6                       CHANNEL COMMAND INDEX            02220000
IOBREG   EQU   7                       IOB ADDRESS                      02240000
WKREG0   EQU   6                       WORKING REGISTER                 02260000
UCBREG   EQU   7                       ADDRESS OF DEVICE TABLE ENTRY    02280000
UTIL     EQU   8                        UTILITY REGISTER                02300000
WKREG3   EQU   9                       WORK REGISTER                    02320000
SFBASE   EQU   10                      BASE REGISTER FOR PART TWO       02340000
FDNBASE  EQU   11                      BASE FOR FOUNDATION MODULE       02360000
WKREG1   EQU   11                       WORKING REGISTER                02380000
INTREG   EQU   12                      INTERNAL RETURN FOR THIS MODULE  02400000
PARAM    EQU   12                      IOB REGISTER                     02420000
DCBREG2  EQU   13                      DCB REGISTER FOR PART TWO        02440000
WKREG4   EQU   14                       WORKING REGISTER                02460000
RETREG   EQU   14                      RETURN TO FOUNDATION MODULE      02480000
SF1BASE  EQU   15                      BASE REGISTER FOR PART ONE       02500000
B1       EQU   1                       OFFSET 1 BYTE            YA02106 02510021
*                                                                       02520000
*                                                                       02540000
         BC    15,IECDSF1              ENTRY FROM FOUNDATION MODULE     02560000
         DS    CL4                     EXTENDED SEARCH ADDR. SLOT       02580000
         BC    15,IECDSF2-IGG019KM(0,SFBASE)                            02600000
IECDSF1  EQU   *                                                        02620000
         ST    CCWIND,8(0,CCWIND)       SET TIC ADDR. IN CCW2           02640000
         ST    CCWIND,48(0,CCWIND)      SET PRIOR RECORD SEARCH         02660000
*                                        ARGUMENT ADDR. IN CCW7         02680000
         LA    WKREG2,IOBDNRCF          LOAD ADDRESS OF THE NEW RECORD  02700000
*                                        COUNT FIELD IN THE IOB         02720000
         ST    WKREG2,16(0,CCWIND)      SET CAPACITY RECORD INPUT ADRR. 02740000
*                                        IN CCW3                        02760000
         ST    WKREG2,64(0,CCWIND)      SET NEW RECORD COUNT FIELD      02780000
*                                        ADDRESS IN CCW9                02800000
         LA    WKREG2,IOBSEEK+3                                         02820000
*                                        IN CCW3                        02840000
         ST    WKREG2,40(0,CCWIND)      SET CAPACITY REC. OUTPUT ADDR.  02860000
*                                        IN CCW6                        02880000
         ST    WKREG2,0(0,CCWIND)       SET CAPACITY RECORD SEARCH      02900000
*                                        ARGUMENT ADDR. IN CCW1         02920000
         MVI   0(CCWIND),SCHID          SET SEARCH ID OP-CODE IN CCW1   02940000
         LR    REG2,CCWIND              LOAD PARAM REG TO C.P.START     02950013
         LR    WKREG2,CCWIND           LOAD PARAM REG TO START OF C.P.  02960000
         MVC   4(5,CCWIND),SCHCON       SET SEARCH ID FLAG AND COUNT IN 02980000
*                                        CCW1 AND TIC OP-CODE IN CCW2   03000000
         MVI   16(CCWIND),READD         SET READ DATA OP-CODE IN CCW3   03020000
         MVI   20(CCWIND),SILI          SET SILI FLAG IN CCW3           03040000
         MVI   23(CCWIND),SEVEN         SET COUNT OF SEVEN IN CCW3      03060000
         LA    CCWIND,24(0,CCWIND)      SET POINTER TO CCW4             03080000
         ST    CCWIND,8(0,CCWIND)       SET TIC ADDR. IN CCW5           03100000
         MVC   4(5,CCWIND),SCHCON       SET SEARCH ID FLAG AND COUNT IN 03120000
*                                        CCW4 AND TIC OP-CODE IN CCW5   03140000
         LA    WKREG2,IOBUPLIM                                          03160000
         ST    WKREG2,0(0,CCWIND)       SET CAPACITY RECORD SEARCH      03180000
*                                        ARGUMENT ADDR. IN CCW4         03200000
         MVI   0(CCWIND),SCHID          SET SEARCH ID OP-CODE IN CCW4   03220000
         MVI   16(CCWIND),WRTD          SET WRITE DATA OP-CODE IN CCW6  03240000
         MVI   24(CCWIND),SCHID         SET SEARCH ID OP-CODE IN CCW7   03260000
*                                                                       03280000
         MVI   20(CCWIND),CCSI          SET CC AND SILI FLAGS IN CCW6   03300000
         MVI   23(CCWIND),SEVEN         SET COUNT OF SEVEN IN CCW6      03320000
*                                                                       03340000
         LA    CCWIND,24(0,CCWIND)      SET POINTER TO CCW7             03360000
         ST    CCWIND,8(0,CCWIND)       SET TIC ADDR. IN CCW8           03380000
         MVC   4(5,CCWIND),SCHCON       SET SEARCH ID FLAG AND COUNT IN 03400000
*                                        CCW7 AND TIC OP-CODE IN CCW8   03420000
         MVI   16(CCWIND),WRTCKD       SET WRITE OP-CODE IN CCW9        03440000
         MVI   23(CCWIND),EIGHT         SET COUNT OF EIGHT IN CCW9      03460000
         LA    CCWIND,16(0,CCWIND)      SET POINTER TO CCW9             03480000
         CLI   DCBKEYLE,ZERO            IS KEY LENGTH IN DCB ZERO       03500000
         BC    8,NOKEY                   YES  BYPASS WRITE KEY          03520000
         MVC   9(3,CCWIND),DECKYADR+1    NO-MOVE KEY ADDR. FROM DECB    03540000
*                                            TO CCW10                   03560000
         MVI   4(CCWIND),DCCC           SET DC,CC FLAGS IN CCW9         03580000
         MVC   15(1,CCWIND),DCBKEYLE    SET COUNT IN CCW10 TO KEY LNGTH 03600000
         LA    CCWIND,8(0,CCWIND)                                       03620000
NOKEY    EQU   *                                                        03640000
         CLC   DECLNGTH(2),14(CCWIND)   IS DATA LENGTH ZERO             03660000
         BCR   8,RETREG                 YES-END OF FILE MARK IS BEING   03680000
*                                        WRITTEN    CHANNEL PROGRAM     03700000
*                                        COMPLETED,RETURN TO FOUNDATION 03720000
*                                        MODULE                         03740000
         MVI   4(CCWIND),DCCC           SET DC,CC FLAGS IN PRIOR CCW    03760000
         MVC   9(3,CCWIND),DECAREA+1    MOVE AREA ADDR FROM DECB TO CCW 03780000
         MVC   14(2,CCWIND),DECLNGTH    MOVE DATA LENGTH FROM DECB TO   03800000
*                                        CCW                            03820000
         LA    CCWIND,8(0,CCWIND)       SET POINTER TO END OF CHANNEL   03840000
*                                        PROGRAM                        03860000
         TM    IOBDTYPE,VERIFY          IS VERIFY OPTION SPECIFIED      03880000
         BCR   8,RETREG                  NO-RETURN TO FOUNDATION MODULE 03900000
*                                        FOR VERIFY                     03920000
         LR    WKREG2,REG2              LOAD PARAM REG TO C.P. START    03930013
         L     SFBASE,12(0,FDNBASE)    LOAD ADDRESS OF VERIFY MODULE    03940000
         BR    SFBASE                   GO CONSTRUCT VERIFY CCWS        03960000
*                                      VERIFY MODULE WILL RETURN TO     03980000
*                                      FOUNDATION ON REGISTER 14        04000000
*                                                                       04020000
*        THIS PORTION OF THE SELF-FORMAT MODULE CALCULATES THE NUMBER   04040000
*        OF BYTES REQUIRED FOR THE NEW RECORD                           04060000
*                                                                       04080000
         DROP  IOBREG,DCBREG,DECBREG    CHANGE IOB AND DCB REGISTERS TO 04100000
         DROP  SF1BASE                                                  04120000
         USING IGG019KM,SFBASE                                          04140000
         USING IOBDEF,PARAM              THOSE USED BY THE ASYNCHRONOUS 04160000
         USING IHADCB,DCBREG2                                           04180000
         USING DECBDEF,UTIL                                             04200000
IECDSF2  EQU   *                                                        04220000
         LR    PARAM,WKREG2             LOAD IOB POINTER                04240000
         SR    WKREG2,WKREG2            CLEAR WORK REGISTER             04260000
         CLC   IOBSEEK+3(4),IOBDNRCF    IS CAPACITY RECORD VALID  16681 04266000
         BNE   NOFIT                    NO--SKIP THIS TRACK       16681 04272000
         MVC   IOBSEEK+3(7),IOBDNRCF    MOVE CAPACITY RECORD PRIOR TO   04280000
*                                        SETTING UP NEW CHANNEL PROGRAM 04300000
*                                        FIELDS                         04320000
*                                                                       04340000
*        OBTAIN DEVICE CODE FROM UCB                                    04360000
*                                                                       04380000
         LH    UCBREG,2(0,UCBREG)       LOAD UCB ADDRESS FROM 12*       04400000
*                                                                       04420000
         L     WKREG1,CVTPTR(0,0)      LOAD THE ADDRESS OF THE          04440000
*                                        COMMUNICATION VECTOR TABLE CVT 04460000
         L     WKREG1,CVTZDTAB-CVTDEF(0,WKREG1)   LOAD ADDRESS OF       04480000
*                                       DEVICE TABLE FROM CVT           04500000
         IC    WKREG2,TYPCD(UCBREG)     LOAD DEVICE CODE FROM UCB       04520000
         N     WKREG2,LASTFOUR          CLEAR ALL BUT LOW ORDER 4 BITS  04540000
         IC    WKREG2,0(WKREG2,WKREG1)  FIND ENTRY OFFSET               04560000
         LA    UCBREG,0(WKREG2,WKREG1) SET POINTER TO DESIRED ENTRY     04580000
MAKECALC EQU   *                                                        04600000
         L     UTIL,IOBECBPT            SET DECB POINTER                04620000
*                                                                       04640000
         IC    WKREG2,DCBKEYLE         PICK UP KEY LENGTH FROM THE DCB  04660000
         STC   WKREG2,IOBDNRCF+5       PUT KEY LENGTH AND DATA LENGTH   04680000
         MVC   IOBDNRCF+6(2),DECLNGTH   IN NEW RECORD COUNT FIELD       04700000
         TM    IOBDSTAT,FIRST          IS THIS THE FIRST TIME THRU THIS 04720000
*                                       ROUTINE FOR THIS REQUEST        04740000
         BC    1,NOCALC                NO, BYPASS CALCULATION           04760000
*                                                                       04780000
*        CALCULATE BYTES REQUIRED FOR NEW RECORD                        04800000
*                                                                       04820000
CALC     SR    WKREG4,WKREG4                                            04840000
         LTR   WKREG2,WKREG2            IS KEY LENGTH ZERO              04860000
         BC    2,KEYED                  NO                              04880000
         IC    WKREG4,OVERK(0,UCBREG)  LOAD VALUE TO BE SUBTRACTED      04900000
*                                        FROM OVERHEAD FOR NON-KEYED    04920000
*                                        RECORDS                        04940000
KEYED    EQU   *                                                        04960000
         AH    WKREG2,DECLNGTH          ADD DATA LENGTH TO KEY LENGTH   04980000
         SR    WKREG3,WKREG3                                            05000000
         IC    WKREG3,OVERL(0,UCBREG)  LOAD OVERHEAD FOR LAST RECORD    05020000
         SR    WKREG3,WKREG4            SUBTRACT NO KEY OVERHEAD        05040000
         AR    WKREG2,WKREG3            ADD OVERHEAD FOR LAST RECORD TO 05060000
*                                       RECORD LENGTH                   05080000
         STH   WKREG2,IOBDBYTN+2        STORE BYTES REQUIRED FOR LAST   05100000
*                                        RECORD INTO IOB                05120000
         SR    WKREG2,WKREG3            RESTORE REG2 TO KEY+DATA LENGTH 05140000
         IC    WKREG3,OVERI(0,UCBREG)  LOAD OVERHEAD FOR NOT LAST REC.  05160000
         MH    WKREG2,TOLER(0,UCBREG)  MULTIPLY KEY+DATA LENGTH BY      05180000
*                                        TOLERANCE FACTOR               05200000
         SRA   WKREG2,9                 DIVIDE RESULT BY 512            05220000
NOTOL    SR    WKREG3,WKREG4            SUBTRACT NO KEY OVERHEAD FROM   05240000
*                                        KEYED OVERHEAD                 05260000
         AR    WKREG2,WKREG3            ADD OVERHEAD BYTES TO RECORD    05280000
*                                        LENGTH                         05300000
         STH   WKREG2,IOBDBYTN          STORE RESULT IN IOB             05320000
         OI    IOBDSTAT,FIRST           SET FIRST TIME THRU INDICATOR   05340000
*                                        IN IOB                         05360000
*                                                                       05380000
*        DETERMINE IF RECORD WILL FIT ON THIS TRACK                     05400000
*                                                                       05420000
NOCALC   EQU   *                                                        05440000
         LH    WKREG4,IOBDBYTR          LOAD REMAINING BYTE COUNT READ  05460000
*                                        IN FROM CAPACITY RECORD        05480000
         CH    WKREG4,IOBDBYTN+2        WILL RECORD FIT AS LAST RECORD  05500000
*                                        ON THE TRACK                   05520000
         BC    4,NOFIT                  NO                              05540000
RECFIT   MVC   IOBCP(5),IOBSEEK+3       MOVE HI ID FROM CAPACITY RECORD 05560000
*                                       TO CCW1                         05580000
         IC    WKREG3,IOBSEEK+7         LOAD R OF HI ID                 05600000
         LA    WKREG3,1(0,WKREG3)       ADD ONE TO R VALUE              05620000
         STC   WKREG3,IOBDNRCF+4        STORE NEW RECORD ID             05640000
         MVC   IOBUPLIM(4),IOBSEEK+3   SET CAPACITY RECORD SEARCH CCHH  05660000
         NI    IOBUPLIM+4,ZERO          SET CAPACITY RECORD SEARCH R    05680000
         STC   WKREG3,IOBSEEK+7         SET HI ID IN CAPACITY RECORD    05700000
         SH    WKREG4,IOBDBYTN          SUBTRACT NOT LAST RECORD SIZE   05720000
*                                        FROM BYTES REMAINING ON TRACK  05740000
         LTR   WKREG4,WKREG4            DID BYTE COUNT GO         25010 05742018
*                                       NEGATIVE                  25010 05744018
         BP    STORE                    NO, BR TO STORE BYTE      25010 05746018
*                                       COUNT                     25010 05748018
         SR    WKREG4,WKREG4            YES, ZERO BYTE COUNT SO   25010 05750018
*                                       A NEGATIVE COUNT WILL NOT BE    05752018
*                                       WRITTEN IN THE R0 ON DISK.      05754018
STORE    EQU   *                                                  25010 05756018
         STH   WKREG4,IOBDBYTR          STORE RESULT INTO NEW CAPACITY  05760000
*                                        RECORD                         05780000
         OI    IOBDSTAT,RCDFIT         INDICATE THAT RECORD FIT         05800000
         LA    WKREG2,IOBCP+24          LOAD ADDR. OF WRITE CHAN PROG.  05820000
         ST    WKREG2,IOBSTART          SET IN CHAN. PROG. START ADDR.  05840000
         MVC   IOBDQPTR+B1(3),IOBECBPT+B1 SAVE USER ECB ADDR    YA02106 05850021
         LA    WKREG2,IOBCSW+4         GET ADDR OF AREA TO USE  SA53787 05866000
         ST    WKREG2,IOBECBPT         AS ECB FOR THIS EXCP     SA53787 05872000
         EXCP  (12)                                                     05880000
*                                                                       05900000
         SVC   EXIT                                                     05940000
NOFIT    EQU   *                                                        05960000
         L     SFBASE,DCBDRDX          GET READ EXCL. MOD. BASE         05980000
         BALR  WKREG3,SFBASE            AND LINK TO IT                  06000000
         L     SFBASE,DCBDFOR           RESTORE OUR BASE REGISTER       06020000
         TM    IOBDSTAT,RCDFIT          DID RECORD FIT                  06040000
         BZ    XSCHLNK                  NO TEST FOR EXTENDED SEARCH     06060000
NEXTIOB  LTR   WKREG0,WKREG0            WAS ANY IOB FOUND WAITING FOR   06080000
*                                       THE TRACK JUST FREED            06100000
         BZ    GOBACK                   NO, RETURN TO FOUNDATION MODULE 06120000
         SR    WKREG2,WKREG2            CLEAR REGISTER            14231 06140016
         LR    PARAM,WKREG0             GET IOB INTO RIGHT REG    14231 06160016
         MVC   IOBSEEK+3(7),IOBDNRCF    SAVED SEEK AND BYTE COUNT 14231 06180016
         B     MAKECALC                YES, SEE IF THIS RECORD FITS     06200000
*                                                                       06220000
XSCHLNK TM     IOBDTYPE,EXSCH          IS EXTENDED SEARCH OPTION USED   06240000
         BC    8,SETABNOR               NO                              06260000
         L     SF1BASE,4(0,SFBASE)     YES-LOAD BASE ADDRESS FOR        06280000
*                                        EXTENDED SEARCH MODULE         06300000
         BALR  RETREG,SF1BASE           GO TO EXTENDED SEARCH MODULE    06320000
        B     KMENQ                    IF EXCP IS TO BE ISSUED GO FOR   06340000
*                                      EXCLUSIVE CONTROL OF THIS RECORD 06360000
*                                      RETURN FROM EXTENDED SEARCH AT   06380000
*                                      THIS INSTRUCTION INDICATES       06400000
*                                       ANOTHER TRACK WAS FOUND ELSE    06420000
*                                       RETURN IS TO NEXT INSTRUCTION   06440000
*                                                                       06460000
SETABNOR OI    IOBDSTAT,ABNORM          SET ABNORMAL COMPLETION BIT     06480000
         MVI   IOBDSTAT+1,NOSPA         SET NO SPACE FOUND EXCEPTION    06500000
*                                        CODE                           06520000
        LA    WKREG3,NEXTIOB           GET RETURN ADDRESS FROM ASI      06540000
        ST    WKREG3,IOBDQPTR          STORE IN ASI RETURN FIELD        06560000
        L     FDNBASE,DCBREAD          GET ADDRESS OF FOUNDATION        06580000
        L     FDNBASE,ASIOFF(0,FDNBASE)  GET ADDR OF ASI ROUTINE        06600000
         LR    WKREG2,PARAM            PUT IOB ADDR INTO REG ASI WANTS  06620000
         LR    SF1BASE,FDNBASE         GET ASI ADDRESS INTO TWO REGS    06640000
         B     POOLOFF(0,FDNBASE)       BRANCH TO POST THE REQUEST      06660000
KMENQ    NI    IOBDSTAT,NOTENQD        TURN OFF INDICATION THAT THE     06680000
         L     SFBASE,DCBDRDX           RECORD WAS ENQ'D. GET ADDR OF   06700000
         BALR  WKREG3,SFBASE           EXCLUSIVE MODULE AND LINK TO IT  06720000
         L     SFBASE,DCBDFOR           RESTORE BASE OF THIS MODULE     06740000
         B     NEXTIOB                  GO TO HANDLE NEXT IOB           06760000
GOBACK   EQU   *                                                        06780000
        SVC   EXIT                     RETURN TO SUPERVISOR             06800000
*                                                                       06820000
*********************************************************************** 06840000
NOINTRPT DC    X'00'                   DISALLOW ALL INTERRUPTS          06860000
INTRPTOK DC    X'FF'                   ALLOW ALL INTERRUPTS             06880000
NOREAD   EQU   X'F7'                                                    06900000
RCDFIT   EQU   X'02'                                                    06920000
ENQD     EQU   X'08'                                                    06940000
NOTENQD  EQU   X'F7'                                                    06960000
EXCP     EQU   0                        EXCP SVC NO.                    06980000
EXIT     EQU   3                        EXIT SVC NO.                    07000000
DEVSZ    EQU   0                       DEVICE SIZE CCHH                 07020000
TRKLNGTH EQU   4                       TRACK LENGTH                     07040000
OVERI    EQU   6                       OVERHEAD NOT LAST RECORD         07060000
OVERL    EQU   7                       OVERHEAD LAST RECORD             07080000
OVERK    EQU   8                       OVERHEAD KEYED RECORD            07100000
FLAG     EQU   9                       FLAG                             07120000
TOLER    EQU   10                      TOLERANCE                        07140000
*        CCW FLAGS AND COUNT                                            07160000
         DS    0F                                                       07180000
LASTFOUR DC    X'0000000F'                                              07200000
SCHCON   DC    X'4000000508'            COMMAND CHAIN WITH COUNT OF 5   07220000
*                                        PLUS TIC OP-CODE               07240000
ASIOFF   EQU   16                      ASI ADDR SLOT IN FOUNDATION      07260000
FDBOFF   EQU   4                       FEEDBACK BRANCH IN ASI           07280000
POOLOFF  EQU   12                      IOB POOL BRANCH IN ASI           07300000
FIRST    EQU   X'10'                                                    07320000
CFORFLG  EQU   X'08'                    CAUSED FORMAT FLAG              07340000
CLRFFLAG EQU   X'FE'                                                    07360000
*        CHANNEL PROGRAM OP-CODES                                       07380000
SCHID    EQU   X'31'                    SEARCH ID EQUAL                 07400000
TIC      EQU   X'08'                    TRANSFER IN CHANNEL             07420000
READD    EQU   X'06'                    READ DATA                       07440000
WRTD     EQU   X'05'                    WRITE DATA                      07460000
WRTCKD   EQU   X'1D'                    WRITE COUNT KEY DATA            07480000
*        CCW FLAGS                                                      07500000
DCSKFLG  EQU   X'F0'                    CD CC SILI SKIP FLAG BITS       07520000
DCCC     EQU   X'C0'                   DATA + COMMAND CHAIN             07540000
SKIP     EQU   X'10'                    SKIP DATA TRANSFER              07560000
CC       EQU   X'40'                    COMMAND CHAIN                   07580000
SILI     EQU   X'20'                    SUPPRESS INCORRECT LENGTH       07600000
CCSI     EQU   X'60'                    COMMAND CHAIN  SUPPRESS LENGTH  07620000
ONE      EQU   X'1'                                                     07640000
FIVE     EQU   X'5'                                                     07660000
SEVEN    EQU   X'7'                                                     07680000
EIGHT    EQU   X'8'                                                     07700000
ZERO     EQU   X'0'                                                     07720000
TYPCD    EQU   19                       DA TYPE CODE OFFSET IN UCB      07740000
ABNORM   EQU   X'80'                    ABNORMAL COMPLETION INDICATOR   07760000
FOR1     EQU   X'02'                    TEST FOR FORMAT 1               07780000
*              EXCEPTION CODES                                          07800000
NOREC    EQU   X'80'                                                    07820000
LGNCK    EQU   X'40'                                                    07840000
NOSPA    EQU   X'20'                                                    07860000
INVAL    EQU   X'10'                                                    07880000
UNCOR    EQU   X'08'                                                    07900000
ENDOD    EQU   X'04'                                                    07920000
UNREL    EQU   X'02'                                                    07940000
*              OPTIONS AND TYPE                                         07960000
VERIFY   EQU   X'80'                                                    07980000
OFLOW    EQU   X'40'                                                    08000000
EXSCH    EQU   X'20'                                                    08020000
FEEDB    EQU   X'10'                                                    08040000
ACTAD    EQU   X'08'                                                    08060000
DYNBF    EQU   X'04'                                                    08080000
READX    EQU   X'02'                                                    08100000
RELRD    EQU   X'01'                                                    08120000
KEYOP    EQU   X'80'                                                    08140000
LGNOP    EQU   X'40'                                                    08160000
READ     EQU   X'08'                                                    08180000
KEY      EQU   X'04'                                                    08200000
ADD      EQU   X'02'                                                    08220000
         DC    X'00'   FILLER - FILLER - FILLER                         08240000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   08260000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   08280000
*      DATA CONTROL BLOCK (DCB) DEFINITION                              08300000
*                                                                       08320000
         DCBD  DSORG=DA                                                 08340000
         EJECT                                                          08360000
CVTDEF   DSECT                                                          08380000
         CVT                                                            08400000
         EJECT                                                          08420000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       08440000
         DS    0F                                                       08460000
DECBDEF  DSECT                                                          08480000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        08500000
DECTYPE  DS    CL2            TYPE FIELD                                08520000
DECLNGTH DS    CL2            DATA LENGTH                               08540000
DECDCBAD DS    CL4            ADDRESS OF DCB                            08560000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      08580000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        08600000
DECKYADR DS    CL4            ADDRESS OF KEY                            08620000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               08640000
         EJECT                                                          08660000
*                                                                       08680000
*      I/O BLOCK (IOB) DEFINITION                                       08700000
*                                                                       08720000
*              STANDARD IOB                                             08740000
         DS    0F                                                       08760000
IOBDEF   DSECT                                                          08780000
IOBFLAG1 DS    CL1            STATUS FLAG                               08800000
IOBFLAG2 DS    CL1            ERROR FLAG                                08820000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       08840000
IOBECBPT DS    CL4            ECB POINTER                               08860000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       08880000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           08900000
         DS    CL1                                                      08920000
         DS    CL3                                                      08940000
IOBCSWST DS    CL2            STATUS BYTES                              08960000
IOBCSWCT DS    CL2            REMAINING COUNT                           08980000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   09000000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        09020000
         DS    CL3                                                      09040000
IOBDCBPT DS    0CL4           DCB POINTER                               09060000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            09080000
         DS    CL3                                                      09100000
IOBRESTR DS    0CL4           RESTART POINTER                           09120000
         DS    CL1                                                      09140000
         DS    CL3                                                      09160000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              09180000
IOBERRCT DS    CL2            ERROR COUNTER                             09200000
IOBSEEK  DS    CL8            SEEK ADDRESS                              09220000
*        BDAM EXTENDED IOB                                              09240000
*                                                                       09260000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  09280000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          09300000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     09320000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                09340000
         DS    CL3                                                      09360000
IOBDTYPE DS    CL2            TYPE FIELD                                09380000
IOBDSTAT DS    CL2            IOB STATUS                                09400000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        09420000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                09440000
         DS    CL2                                                      09460000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               09480000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        09500000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                09520000
IOBCP    DS    CL256                   FIRST CCW IN CHANNEL PROGRAM     09540000
         END                                                            09560000
