 TITLE   'IGG019KN - VRE SELF FORMAT MODULE   '                         00100019
IGG019KN CSECT                                                          00200019
*                                                                     * 00210019
*          RELEASE 20 DELETIONS                                         00400019
*          RELEASE 21 DELETIONS/CHANGES                                 00500021
*C469500                                                         XM3808 00550021
*C469600,469700                                                  YM3709 00560021
*    THE FIX FOR SA69165 IS FLAGGED XM3808                      SA69165 00570021
*          RELEASE 22 DELETIONS                                         00600019
*          RELEASE 23 DELETIONS                                         00700019
*          RELEASE 24 DELETIONS                                         00800019
*          RELEASE 25 DELETIONS                                         00810019
*          RELEASE 26 DELETIONS                                         00820019
*          RELEASE 27 DELETIONS                                         00830019
*          RELEASE 28 DELETIONS                                         00840019
*                                                                       00850019
*STATUS CHANGE LEVEL 000                                                00900019
*                                                                       00910019
*FUNCTION/OPERATION- THIS MODULE CONTAINS THREE ROUTINES WHOSE        * 01000019
*   FUNCTIONS ARE,                                                    * 01100019
*   1.CREATE THE CHANNEL PROGRAM REQUIRED TO ADD A NEW BLOCK TO A     * 01200019
*    VRE DATA SET.                                                    * 01300019
*    THE CHANNEL PROGRAM WILL CONSIST OF TWO PARTS, THE FIRST THREE   * 01400019
*    CCWS WILL READ THE CAPACITY RECORD FROM A TRACK, THE SECOND      * 01500019
*    SEQUENCE OF CCWS WILL WRITE THE NEW RECORD AND UPDATE THE        * 01600019
*    CAPACITY RECORD.                                                 * 01700019
*                                                                     * 01800019
*   2.CALCULATE THE NUMBER OF BYTES THE NEW BLOCK WILL REQUIRE ON THE * 01900019
*    TRACK AND COMPARE THAT VALUE TO THE NUMBER OF UNUSED BYTES       * 02000019
*    REMAINING ON THE TRACK ACCORDING TO THE CAPACITY RECORD. IF THE  * 02100019
*    BLOCK WILL FIT, THE COUNT FIELD FOR THE NEW BLOCK AND AN UPDATED * 02200019
*    CAPACITY RECORD ARE FORMED AND THE SECOND PART OF THE CHANNEL    * 02300019
*    PROGRAM IS SCHEDULED VIA THE EXCP MACRO. IF THE BLOCK WILL NOT   * 02400019
*    FIT,THE CAPACITY RECORD OF THE NEXT TRACK IS ENQ'ED AND READ     * 02500019
*    (VIA MODULE IGG019LG) AND THE COMBINED SPACE EXAMINED.  THIS     * 02600019
*    PROCESS CONTINUES UNTIL EITHER ENOUGH SPACE IS OBTAINED, IN WHICH* 02700019
*    CASE THE FIRST SEGMENT IS WRITTEN, OR A NON-EMPTY TRACK OR A     * 02800019
*    VOLUME SWITCH IS ENCOUNTERED.  FOR THESE CASES, THE SEARCH LIMIT * 02900019
*    IS CHECKED AND IF REACHED, THE REQUEST IS TERMINATED WITH A NO-  * 03000019
*    SPACE-FOUND INDICATION.  IF THE SEARCH LIMIT WAS NOT REACHED, THE* 03100019
*    TRACKS PREVIOUSLY ENQ'ED ARE DEQ'ED AND THE SEARCH STARTS OVER.  * 03200019
*                                                                     * 03300019
*   3.SEARCH THE UNSCHEDULED QUEUE OF IOBS WHEN THE CURRENT WRITE ADD * 03400019
*    HAS COMPLETED, FOR ANOTHER WRITE ADD REQUEST. THE FIRST SUCH     * 03500019
*    UNSCHEDULED REQUEST FOUND (IF ANY) WILL BE UNQUEUED AND          * 03600019
*    SCHEDULED VIA EXCP.                                              * 03700019
*                                                                     * 03800019
*ENTRY POINTS- THERE ARE THREE ENTRY POINTS AS FOLLOWS,               * 03900019
*   1.   'IECDSF1' IS ENTERED FROM THE FOUNDATION MODULE (IGG019KA)   * 04000019
*     TO PERFORM FUNCTION 1.  CALLING SEQUENCE IS, L    15,DCBDFOR    * 04100019
*                                                  BALR 14,15         * 04200019
*   2.   'IECDSF2' IS ENTERED FROM ASYNCHRONOUS INTERRUPT (IGG019KA)  * 04300019
*     TO PERFORM FUNCTION 2. AND ALSO FUNCTION 3. IF THE BLOCK WILL   * 04400019
*     NOT FIT ON THE TRACK. CALLING SEQUENCE IS, L   15,DCBDFOR       * 04500019
*                                                BC  15,8(15)         * 04600019
*   3.   'IECDSF3' IS ENTERED FROM ASYNCHRONOUS INTERRUPT TO PERFORM  * 04700019
*     FUNCTION 3. CALLING SEQUENCE IS,    L     15,DCBDFOR            * 04800019
*                                         BC    15,12(15)             * 04900019
*                                                                     * 05000019
*INPUT-                                                               * 05100019
*   TO FUNCTION 1.                                                    * 05200019
*    REGISTER 4  DCB ADDRESS                                          * 05300019
*    REGISTER 5  DECB ADDRESS                                         * 05400019
*    REGISTER 6  ADDRESS OF THE LOCATION FOR CCW 1.                   * 05500019
*    REGISTER 7  IOB ADDRESS                                          * 05600019
*    REGISTER 11 BASE ADDRESS OF MODULE IGG019KA                      * 05700019
*    REGISTER 14 RETURN ADDRESS                                       * 05800019
*    REGISTER 15 BASE OF THIS MODULE                                  * 05900019
*                                                                     * 06000019
*   TO FUNCTION 2.                                                    * 06100019
*    REGISTER 1  IOB ADDRESS                                          * 06200019
*    REGISTER 10 12* (IOS QUEUEING ELEMENT) ADDRESS                   * 06300019
*    REGISTER 13 DCB ADDRESS                                          * 06400019
*    REGISTER 15 BASE ADDRESS FOR THIS MODULE                         * 06500019
*                                                                     * 06600019
*   TO FUNCTION 3.                                                    * 06700019
*    REGISTER 1  IOB ADDRESS                                          * 06800019
*    REGISTER 13 DCB ADDRESS                                          * 06900019
*    REGISTER 15 BASE ADDRESS FOR THIS MODULE                         * 07000019
*                                                                     * 07100019
*OUTPUT- FUNCTION 1 WILL CONSTRUCT THE REQUIRED CCWS AND LEAVE        * 07200019
*   REGISTER 6 POSITIONED AT THE LAST CCW.                            * 07300019
*   FUNCTION 2 WILL FORM THE NEW BLOCK'S COUNT FIELD AND UPDATED      * 07400019
*   CAPACITY RECORD IF THE RECORD FITS OR WILL SET BITS IN THE IOB    * 07500019
*   (IOBDSTAT) IF THERE IS NO SPACE FOR THE BLOCK.                    * 07600019
*   FUNCTION 3 WILL SCHEDULE ANOTHER WRITE ADD IF ONE HAS BEEN        * 07700019
*   QUEUED AWAITING THE CURRENT WRITE'S COMPLETION.                   * 07800019
*                                                                     * 07900019
*EXTERNAL ROUTINES-                                                   * 08000019
*        'IGG019KQ' IS USED TO CONSTRUCT ADDITIONAL CCWS TO VERIFY    * 08100019
*   THE NEW BLOCK IF THE WRITE VALIDITY CHECK OPTION WAS SPECIFIED IN * 08200019
*   THE OPTCD PARAMETER OF THE DCB MACRO.                             * 08300019
*                                                                     * 08400019
*EXITS-NORMAL- 'EXITFDN' IS THE RETURN TO MODULE IGG019KA AFTER THE   * 08500019
*   CHANNEL PROGRAM HAS BEEN CONSTRUCTED.                             * 08600019
*        'EXITSUPV' IS AN SVC EXIT TO RETURN TO SUPERVISOR WHEN THE   * 08700019
*   BLOCK FITS ON THE TRACK AND THE IOB HAS BEEN RESCHEDULED WITH IOS.* 08800019
*EXITS-ERROR - 'EXITERR' IS A RETURN TO THE SUPERVISOR AFTER THE      * 08900019
*   TRACKS HAVE BEEN RELEASED AND THE ERROR CONDITION POSTED.         * 09000019
*                                                                     * 09100019
*TABLES/WORK AREA- THE COMMUNICATION VECTOR TABLE IS REFERENCED TO    * 09200019
*   REACH THE DIRECT ACCESS DEVICE TABLE WHICH SUPPLIES THE DEVICE    * 09300019
*   CHARACTERISTICS NECESSARY TO CALCULATE THE BYTES REQUIRED FOR     * 09400019
*   THIS BLOCK ON THIS DEVICE.                                        * 09500019
*                                                                     * 09600019
*ATTRIBUTES- THIS ROUTINE IS REENTRANT, FUNCTION 1. IS EXECUTED       * 09700019
*   ENABLED WHILE FUNCTIONS 2., AND 3. ARE EXECUTED DISABLED AS       * 09800019
*   EXTERED FROM ASYNCHRONOUS INTERRUPT.                              * 09900019
*                                                                     * 10000019
*NOTES- THE REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT      * 10100019
*   WITH MODULES  IGG019KA, IGG019KQ.                                 * 10200019
*                                                                       10300019
*                                                                       10400019
*                                                                       10500019
*                                                                       10600019
*              REGISTER USAGE                                           10700019
*                                                                       10800019
SCHREG   EQU   1                        PARAMETER REG                   10900019
DEQRTN   EQU   1                        LINK TO DEQ RTN REGISTER        11000019
SWAREG   EQU   2                        SWA ADDRESS                     11100019
SWAPTR   EQU   2                        POINTER TO SWA                  11200019
DEBREG   EQU   3                        DEB ADDRESS                     11300019
W1       EQU   3                        WORK REGISTER                   11400019
DCBREG   EQU   4                        DCB ADDRESS                     11500019
W2       EQU   4                        WORK REGISTER                   11600019
DECBREG  EQU   5                        DECB ADDRESS                    11700019
W3       EQU   5                        WORK REGISTER                   11800019
CCWIND   EQU   6                        ADDRESS OF FIRST CCW            11900019
W4       EQU   6                        WORK REGISTER                   12000019
IOBREG   EQU   7                        IOB ADDRESS                     12100019
UCBREG   EQU   7                        ADDRESS OF DEVICE TABLE ENTRY   12200019
UTIL     EQU   8                        UTILITY REGISTER                12300019
WKREG1   EQU   9                        GENERAL PURPOSE WORK REGISTER   12400019
LGRTN    EQU   9                        LINK TO IGG019LG REGISTER       12500019
SFBASE   EQU   10                       BASE REG FOR IGG019KQ           12600019
FDNBASE  EQU   11                       BASE REG FOR FOUNDATION MOD     12700019
PARAM    EQU   12                       IOB REGISTER                    12800019
DCBREG2  EQU   13                       DCB REGISTER FOR PART TWO       12900019
RETREG   EQU   14                       RETURN ADDRESS TO IGG019KJ      13000019
INTRET   EQU   12                                                       13100019
EPREG    EQU   15                                                       13200019
SF1BASE  EQU   15                       BASE REG FOR PART ONE OF THIS   13300019
*                                       MODULE                          13400019
B1       EQU   1                        OFFSET TO BYTE 1 OF WORD XM3803 13450021
*                                                                       13500019
*                                                                       13600019
*********************************************************************** 13700019
         USING IGG019KN,SF1BASE                                         13800019
         USING IOBDEF,IOBREG                                            13900019
         USING IHADCB,DCBREG                                            14000019
         USING DECBDEF,DECBREG                                          14100019
*********************************************************************** 14200019
         B     IECDSF1                  ENTRY FROM FOUNDATION MODULE    14300019
         DS    CL4                      EXTENDED SEARCH ADDRESS SLOT    14400019
         B     IECDSF2-IGG019KN(SFBASE) ENTRY TO ADD LOGIC              14500019
         B     ENTRYP12-IGG019KN(SFBASE)  ENTRY TO END OF ADD ROUTINE   14600019
*                                                                       14700019
IECDSF1  EQU   *                                                        14800019
*                                                                       14900019
*                                                                     * 15700019
         LR    SWAREG,IOBREG            FETCH IOB ADDRESS               15800019
         SH    SWAREG,H4                PREPARE TO GO TO IOB-4          15900019
         L     SWAREG,NULL(SWAREG)      FETCH SWA ADDRESS THERE         16000019
         LA    SWAREG,SEGAREOF(SWAREG)  GET ADDRESS OF SEGMENT AREA     16100019
*********************************************************************** 16200019
         MVC   NULL(BYTE8,CCWIND),NOPCCW    CONSTRUCT A NOP CCW         16300019
         ST    CCWIND,EIGHTCCW(CCWIND)  SET LAST RECORD SEARCH ARGUMENT 16400019
*                                       ADDRESS IN CCW 9                16500019
         LA    WKREG1,IOBSEEK+BYTE3     FETCH CAPACITY RECORD ADDRESS   16600019
         ST    WKREG1,ONECCW(CCWIND)    PUT CAPACITY RECORD SEARCH      16700019
*                                       ARGUMENT ADDRESS IN CCW 2       16800019
         ST    WKREG1,SEVENCCW(CCWIND)  PUT CAPACITY RECORD OUTPUT      16900019
*                                       ADDRESS IN CCW 8                17000019
         LA    WKREG1,IOBDNRCF          FETCH ADDRESS OF NEW RECORD     17100019
*                                       COUNT FIELD IN IOB              17200019
         ST    WKREG1,THREECCW(CCWIND)  PUT CAPACITY RECORD INPUT ADDR. 17300019
*                                       IN CCW 4                        17400019
         ST    WKREG1,TENCCW(CCWIND)    PUT NEW RECORD COUNT FIELD      17500019
*                                       ADDRESS IN CCW 11               17600019
         LA    WKREG1,ONECCW(CCWIND)    TIC ADDRESS FOR SEARCH ID EQ    17700019
         ST    WKREG1,TWOCCW(CCWIND)    PUT TIC ADDRESS IN CCW 3        17800019
         MVI   ONECCW(CCWIND),SRCHIDEQ  SET SEARCH ID EQ OP CODE IN     17900019
*                                       CCW 2                           18000019
         MVC   BYTE12(BYTE5,CCWIND),SCHCON  MOVE FLAGS AND COUNT IN     18100019
*                                           CCW 2 AND TIC OP CODE IN    18200019
*                                           CCW 3                       18300019
         LA    SCHREG,ONECCW(CCWIND)    SAVE ADDRESS OF CCW 2 FOR       18400019
*                                       BUILDING VERIFY CCW'S           18500019
         LA    CCWIND,THREECCW(CCWIND)  SET POINTER TO CCW 4            18600019
         MVI   NULL(CCWIND),READDATA    MOVE READ DATA OP CODE IN CCW 4 18700019
         MVC   BYTE4(BYTE4,CCWIND),SILCNT7  MOVE SUPPRESS INCORRECT     18800019
*                                           LENGTH FLAGS AND COUNT=7    18900019
*                                           IN CCW 4                    19000019
*                                                                     * 19100019
*                                                                     * 19900019
         MVC   ONECCW(BYTE8,CCWIND),NOPCCW  CONSTRUCT A NOP CCW IN CCW5 20000019
         LA    CCWIND,TWOCCW(CCWIND)    SET POINTER TO CCW 6            20100019
         LA    WKREG1,THREE(WKREG1)     POINTER TO CCHHR                20200019
         ST    WKREG1,NULL(CCWIND)      PUT TIC TO SEARCH ID EQ CCW     20300019
*                                       ADDRESS IN CCW 6                20400019
         ST    CCWIND,ONECCW(CCWIND)    PUT TIC TO CCW 6 ADDR. IN CCW 7 20500019
         MVI   NULL(CCWIND),SRCHIDEQ    SET SEARCH ID EQ OP CODE IN     20600019
*                                       CCW 6                           20700019
         MVC   BYTE4(BYTE5,CCWIND),SCHCON   MOVE FLAGS AND COUNT IN     20800019
*                                           CCW 6 AND TIC OP CODE IN    20900019
*                                           CCW 7                       21000019
         MVI   TWOCCW(CCWIND),WRITDATA  MOVE WRITE DATA OP CODE IN CCW8 21100019
         MVC   BYTE20(BYTE4,CCWIND),CCSIL7  COMMAND CHAIN AND SUPPRESS  21200019
*                                           INCORRECT LENGTH FLAGS AND  21300019
*                                           COUNT OF 7 IN CCW 8         21400019
         LA    CCWIND,THREECCW(CCWIND)  SET POINTER TO CCW 9            21500019
         MVI   NULL(CCWIND),SRCHIDEQ    SET SEARCH ID EQ OP CODE IN     21600019
*                                       CCW 9                           21700019
         ST    CCWIND,ONECCW(CCWIND)    PUT TIC TO CCW 9 ADDR IN CCW 10 21800019
         MVC   BYTE4(BYTE5,CCWIND),SCHCON   MOVE FLAGS AND COUNT IN     21900019
*                                           CCW 9 AND TIC OP CODE IN    22000019
*                                           CCW 10                      22100019
         MVI   TWOCCW(CCWIND),WRITCKD   MOVE IN WRITE COUNT KEY DATA    22200019
*                                       OP CODE IN CCW 11               22300019
         MVI   BYTE23(CCWIND),EIGHT     SET COUNT OF 8 IN CCW 11        22400019
         LA    CCWIND,TWOCCW(CCWIND)    SET POINTER TO CCW 11           22500019
         CLI   DCBKEYLE,ZERO            CHECK IF KEY LENGTH IS ZERO     22600019
         BE    NOKEY                    BRANCH IF YES                   22700019
         MVC   BYTE9(BYTE3,CCWIND),DECKYADR+BYTE1   ELSE, MOVE KEY ADDR 22800019
*                                                   IN CCW 12           22900019
         MVI   BYTE4(CCWIND),DACHGAP    SET DATA CHAIN BETWEEN GAPS OF  23000019
*                                       RECORD FLAGS IN CCW 11          23100019
         MVC   BYTE15(BYTE1,CCWIND),DCBKEYLE   PUT KEY LENGTH AS COUNT  23200019
*                                              IN CCW 12                23300019
         LA    CCWIND,ONECCW(CCWIND)    SET POINTER TO CCW 12           23400019
*                                                                       23500019
NOKEY    EQU   *                                                        23600019
*                                                                       23700019
         CLC   DECLNGTH(BYTE2),ZEROS    IS DATA LENGTH ZERO             23800019
         BCR   CC8,RETREG               IF YES, CHANNEL PROGRAM ENDS    23900019
*                                       AND RETURN CONTROL TO IGG019KJ  24000019
         MVI   BYTE4(CCWIND),DACHGAP    SET DATA CHAIN BETWEEN GAPS OF  24100019
*                                       A RECORD FLAGS IN CURRENT CCW   24200019
         ST    SWAREG,ONECCW(CCWIND)    PUT SEGMENT ADDRESS IN NEXT CCW 24300019
         MVC   BYTE14(BYTE2,CCWIND),DECLNGTH   MOVE IN DATA LENGTH AS   24400019
*                                              COUNT                    24500019
         LA    CCWIND,ONECCW(CCWIND)    SET POINTER TO LAST CCW         24600019
         TM    IOBDTYPE,VERIFY          CHECK IF WRITE CHECK OPTION     24700019
*                                       HAS BEEN SPECIFIED              24800019
         BCR   CC8,RETREG               IF NOT, RETURN CONTROL TO THE   24900019
*                                       FOUNDATION MODULE IGG019KJ      25000019
         L     SFBASE,VERMODOF(NULL,FDNBASE)  ELSE, GET ADDRESS OF THE  25100019
*                                             VERIFY MODULE IGG019KQ    25200019
         BR    SFBASE                   GO TO IGG019KQ TO CONSTRUCT     25300019
*                                       VERIFY CCW'S                    25400019
*                                                                     * 25500019
*                                                                     * 25600019
*              BDAM OPTIONS AND TYPE                                  * 25700019
*                                                                     * 25800019
*                                                                     * 25900019
NOPCCW   DC    X'0300000060000001'      NOP CCW                         26000019
SCHCON   DC    X'4000000508'            COMMAND CHAIN FLAGS WITH COUNT  26100019
*                                       OF 5  AND TIC OP CODE           26200019
SILCNT7  DC    X'20000007'              SUPPRESS INCORRECT LENGTH FLAGS 26300019
*                                       AND COUNT OF 7                  26400019
CCSIL7   DC    X'60000007'              COMMAND CHAIN AND SUPPRESS IN-  26500019
*                                       CORRECT LENGTH FLAGS AND COUNT  26600019
*                                       OF 7                            26700019
*                                                                       26800019
SRCHIDEQ EQU   X'31'                    SEARCH ID EQ OP CODE            26900019
READDATA EQU   X'06'                    READ DATA OP CODE               27000019
WRITDATA EQU   X'05'                    WRITE DATA OP CODE              27100019
WRITCKD  EQU   X'1D'                    WRITE COUNT KEY DATA OP CODE    27200019
DACHGAP  EQU   X'C0'                    DATA CHAIN BETWEEN GAPS OF A    27300019
*                                       RECORD FLAGS                    27400019
VERIFY   EQU   X'80'                    WRITE VALIDITY CHECK OPTION     27500019
*                                                                       27600019
*                                                                       27700019
*              CONSTANTS                                                27800019
*                                                                       27900019
*                                                                       28000019
ZEROS    DC    X'0000'                  GENERAL PURPOSE CONSTANT        28050019
ZERO     EQU   X'0'                     GENERAL PURPOSE CONSTANT        28100019
EIGHT    EQU   X'8'                     GENERAL PURPOSE CONSTANT        28200019
NULL     EQU   0                        NO DISPLACEMENT                 28300019
ONECCW   EQU   8                        LENGTH OF ONE CCW               28400019
TWOCCW   EQU   16                       LENGTH OF TWO CCW'S             28500019
THREECCW EQU   24                       LENGTH OF THREE CCW'S           28600019
FOURCCW  EQU   32                       LENGTH OF FOUR CCW'S            28700019
SEVENCCW EQU   56                       LENGTH OF SEVEN CCW'S           28800019
EIGHTCCW EQU   64                       LENGTH OF EIGHT CCW'S           28900019
TENCCW   EQU   80                       LENGTH OF TEN CCW'S             29000019
*                                                                       29100019
*                                                                       29200019
BYTE1    EQU   1                        ONE BYTE                        29300019
BYTE2    EQU   2                        TWO BYTES                       29400019
BYTE3    EQU   3                        THREE BYTES                     29500019
BYTE4    EQU   4                        FOUR BYTES                      29600019
BYTE5    EQU   5                        FIVE BYTES                      29700019
BYTE6    EQU   6                        SIX BYTES                       29800019
BYTE7    EQU   7                        SEVEN BYTES                     29900019
BYTE8    EQU   8                        EIGHT BYTES                     30000019
BYTE9    EQU   9                        NINE BYTES                      30100019
BYTE10   EQU   10                       TEN BYTES                       30200019
BYTE12   EQU   12                       TWELVE BYTES                    30300019
BYTE14   EQU   14                       FOURTEEN BYTES                  30400019
BYTE15   EQU   15                       FIFTEEN BYTES                   30500019
BYTE20   EQU   20                       TWENTY BYTES                    30600019
BYTE23   EQU   23                       TWENTY-THREE BYTES              30700019
CC8      EQU   8                        CONDITION CODE SETTING OF 8     30710019
VERMODOF EQU   12                       OFFSET TO ADDRESS OF IGG019KQ   30800019
*                                       IN THE FOUNDATION MODULE        30900019
SEGAREOF EQU   10                       OFFSET TO ADDRESS OF SEGMENT    31000019
*                                       AREA IN SWA                     31100019
*                                                                       31200019
*                                                                       31300019
         EJECT                                                          31400019
*********************************************************************** 31500019
*                                                                       31600019
*                                                                       31700019
*********************************************************************** 31800019
*                                                                       31900019
*                                                                       32000019
*   THIS PORTION OF THE SELF-FORMAT MODULE PERFORMS THE SEARCH FOR      32100019
*   SUFFICIENT SPACE TO ADD THE RECORD TO THE DATA SET.                 32200019
*                                                                       32300019
         DROP  IOBREG,DCBREG,DECBREG    CHANGE REGISTER USAGE TO THOSE  32400019
         DROP  SF1BASE                  USED BY THE ASYNCHRONOUS        32500019
         USING IGG019KN,SFBASE          INTERRUPT ROUTINE               32600019
         USING IOBDEF,PARAM                                             32700019
         USING IHADCB,DCBREG2                                           32800019
         USING DECBDEF,UTIL                                             32900019
         USING SWA,SWAPTR                                               33000019
*                                                                       33100019
IECDSF2  L     UTIL,IOBECBPT            SET DECB POINTER                33200019
         TM    IOBDSTAT,ABNORM          WAS THIS AN ABNORMAL COMPLETION 33300019
         BZ    COMPLOK                  BR IF NOT                       33400019
         L     W1,IOBSTART                                              33800019
         USING WRITEADD,W1                                              33900019
         CLI   WARD,READDATA            DID ABNORMAL END OCCUR DURING   34000019
*                                       THE READ OF A CAPACITY RECORD   34100019
         BNE   MVINFRST                 BR IF NO                        34200019
         IC    W1,TRKCNT                *                               34240019
         LA    W1,ONE(W1)                *  ADD 1 TO TRACK COUNT        34280019
         STC   W1,TRKCNT                *                               34320019
         CLI   TRKCNT,ONE               IF THE TRACK COUNT IS ONE, WE   34360019
         BNE   ACB4                     MUST PLACE THE FIRST TRACK      34400019
         MVC   SAVEMBB(EIGHT),IOBSEEK   ADDRESS IN THE SWA FOR DEQ RTN  34500019
         B     ACB4                     GO DEQ TRACKS USED, POST THE    34600019
*                                       REQUEST, AND EXIT.              34700019
*                                                                       34800019
COMPLOK  EQU   *                                                        34900019
         CLC   IOBDBYTR,LASTFOUR        IS SPACE TOTAL SO FAR = 0       35000019
         BNE   NOTFIRST                 BR IF NO                        35100019
*                                                                       35106019
*   OBTAIN POINTER TO THE DEVICE TABLE ENTRY                            35112019
*                                                                       35118019
         LH    UCBREG,TWO(UCBREG)       LOAD UCB ADDRESS FROM 12*       35124019
         LA    W3,DONEDVT                                               35130019
GETDVENT EQU   *                                                        35136019
         L     W1,CVTPTR                LOAD ADDRESS OF THE CVT         35142019
         L     W1,CVTZDTAB-CVTDEF(W1)   GET ADDRESS OF THE DEVICE TABLE 35148019
         IC    W2,TYPCD(UCBREG)         LOAD DEVICE CODE FROM UCB       35154019
         N     W2,LASTFOUR              CLEAR ALL BUT LOW ORDER 4 BITS  35160019
         IC    W2,NULL(W2,W1)           FIND ENTRY OFFSET               35166019
         LA    UCBREG,NULL(W2,W1)       SET POINTER TO DESIRED ENTRY    35172019
         BR    W3                       RETURN TO CALLING ROUTINE       35178019
DONEDVT  EQU   *                                                        35184019
*                                                                       35190019
OTHRFRST EQU   *                                                        35200019
         MVC   SAVEMBB,IOBSEEK          SAVE MBB FROM IOBSEEK           35300019
         MVC   IOBSEEK3(SEVEN),IOBDNRCF MOVE IN THE CAPACITY RECORD     35400019
*                                       (THIS ALSO INITIALIZES          35500019
*                                        IOBDBYTR WITH THE TRACK BAL.)  35600019
         MVC   SVCCHHR,IOBDNRCF         ALSO SAVE IT IN THE SWA         35700019
         MVI   TRKCNT,ONE               SET TRACK COUNT TO ONE          35800019
         SR    W2,W2                                                    35900019
         SR    W4,W4                                                    36000019
*                                                                       37100019
         TM    IOBDSTAT,FIRST           IS THIS THE FIRST TIME THROUGH  37200019
*                                       THIS ROUTINE FOR THIS REQUEST   37300019
         BO    NOCALC                   NO,BYPASS CALCULATION           37400019
*                                                                       37500019
*   THE DISK SPACE REQUIRED FOR THE RECORD WILL NOW BE CALCULATED.      37600019
*                                                                       37700019
         IC    W2,DCBKEYLE              GET KEY LENGTH FROM DCB         37800019
         LTR   W2,W2                    IS KEY LENGTH ZERO              37900019
         BP    KEYED                    BR IF NOT ZERO                  38000019
         IC    W4,OVERK(UCBREG)         GET VALUE TO BE SUBTRACTED FROM 38100019
*                                       OVERHEAD FOR NON-KEYED RECORDS  38200019
KEYED    EQU   *                                                        38300019
         AH    W2,DECLNGTH              ADD DATA LENGTH TO KEY LENGTH   38400019
         SR    W3,W3                                                    38500019
         IC    W3,OVERL(UCBREG)         GET OVERHEAD FOR LAST RECORD    38600019
         SR    W3,W4                    SUBTRACT NON-KEYED OVERHEAD     38700019
         AR    W2,W3                    ADD LAST RECORD OVERHEAD TO     38800019
*                                       RECORD LENGTH                   38900019
         STH   W2,IOBDBYTN+TWO          STORE BYTES REQUIRED FOR LAST   39000019
*                                       RECORD                          39100019
         SR    W2,W3                    RESTORE W2 TO KEY+DATA LENGTH   39200019
         IC    W3,OVERI(UCBREG)         GET OVERHEAD FOR NOT LAST RCD.  39300019
         MH    W2,TOLER(UCBREG)         MULTIPLY KEY+DATA LENGTH BY     39400019
*                                       THE TOLERANCE FACTOR            39500019
         SRA   W2,NINE                  DIVIDE RESULT BY 512            39600019
         SR    W3,W4                    SUBTRACT NO-KEY OVERHEAD        39700019
         AR    W2,W3                    ADD OVERHEAD TO RECORD LENGTH   39800019
         STH   W2,IOBDBYTN              STORE RESULT IN IOB             39900019
         OI    IOBDSTAT,FIRST           SET FIRST TIME THROUGH IND.     40000019
*                                                                       40100019
NOCALC   EQU   *                                                        40200019
         LH    W4,IOBDBYTR              GET THE TRACK BALANCE           40300019
         LTR   W4,W4                    SEE IF NEGATIVE TRK BALANCE     40310019
         BM    TRKFULL                  BR IF NEGATIVE                  40320019
         CH    W4,IOBDBYTN+TWO          WILL RECORD FIT AS LAST RECORD  40400019
*                                       ON THE TRACK                    40500019
         BL    NOFIT                    BR IF NO                        40600019
         MVI   SEGFLGS,NULL             SET SEGMENT FLAGS TO 0 TO       40700019
*                                       INDICATE A ONE SEGMENT RECORD   40800019
         MVC   SAVELL,DECLNGTH          SET SEGMENT SIZE TO RECORD SIZE 40900019
         SH    W4,IOBDBYTN              SUBTRACT NOT-LAST-RECORD SIZE   41000019
*                                       FROM TRACK BALANCE AND          41100019
         STH   W4,IOBDBYTR              STORE NEW TRACK BALANCE IN THE  41200019
*                                       CAPACITY RECORD TO BE WRITTEN   41300019
FINSETUP EQU   *                                                        41400019
         MVC   IOBDNRCF+SIX(TWO),SAVELL MOVE SEGMENT SIZE TO NEW        41500019
*                                       CAPACITY RECORD                 41600019
         L     W1,IOBSTART              GET CHANNEL PROGRAM START ADDR. 41700019
         USING WRITEADD,W1              SET UP CHANNEL PROGRAM DSECT    41800019
         CLI   DCBKEYLE,NULL            ARE KEYS BEING WRITTEN          41900019
         BE    NOKEYCP                  BR IF NO                        42000019
         MVC   WAKWD+CNTOFF(TWO),SAVELL MOVE DATA LENGTH TO WRITE CCW   42200019
AFTERLL  EQU   *                                                        42300019
         MVC   WANOP1(FIVE),SVCCHHR     PUT CCHHR OF CURRENT LAST BLOCK 42400019
*                                       IN CCW1                         42500019
         MVC   IOBDNRCF(FOUR),SVCCHHR   PUT CCHH OF NEW RECORD IN THE   42600019
*                                       NEW COUNT FIELD                 42700019
         MVC   IOBDNRCF+FIVE(ONE),DCBKEYLE PUT KEY LENGTH IN THE COUNT  42800019
*                                       FIELD                           42900019
         MVC   IOBSEEK(THREE),SAVEMBB   MOVE MBB TO IOBSEEK             43000019
         MVC   WASIE1,SAVEMBB           PUT THE MBBCCHH OF THE CAPACITY 43100019
*                                       RECORD IN CCW2                  43200019
         MVI   WASIE1+SEVEN,NULL        SET R OF THE CAPACITY RECORD    43300019
*                                       ADDRESS TO ZERO                 43400019
         IC    W3,SVCCHHR+FOUR          *                               43500019
         LA    W3,ONE(W3)                * PUT ID OF NEW RECORD IN THE  43600019
         STC   W3,IOBDNRCF+FOUR         *  NEW COUNT FIELD              43700019
         MVC   IOBSEEK3(FIVE),IOBDNRCF  PUT CCHHR OF NEW LAST BLOCK IN  43800019
*                                       THE NEW CAPACITY RECORD         43900019
         MVC   SWABDW(TWO),SAVELL       PUT DATA LENGTH IN THE BLOCK    44000019
*                                       RESCRIPTOR WORD                 44100019
         MVI   SEGUNUSD,NULL            ZERO BYTE AFTER FLAGS           44200019
         LA    W1,WANOP2                SET NEW CHANNEL PROGRAM START   44300019
         ST    W1,IOBSTART              POINTER                         44400019
         OI    IOBDSTAT,RCDFIT          INDICATE THAT THE RECORD FIT    44500019
         XC    SWABDW+TWO(TWO),SWABDW+TWO ZERO THE LAST TWO BYTES OF    44600019
*                                       THE BLOCK DESCRIPTOR WORD       44700019
         MVC   SWARAPT+ONE(THREE),DECAREA+ONE  MOVE THE RECORD AREA     44800019
*                                       POINTER TO THE SWA              44900019
         LH    W1,SWABDW                *                               45000019
         SH    W1,H4                     * SET SEGMENT DESCRIPTOR TO    45100019
         STH   W1,SEGLL                 *  FOUR LESS THAN THE BDW       45200019
         SH    W1,H4                    SUBTRACT 4 AND THIS IS THE      45300019
*                                       NUMBER OF BYTES TO MOVE TO THE  45400019
*                                       SEGMENT AREA.                   45500019
         LA    W2,SEGDATA               *                               45600019
         L     W3,SWARAPT                * SET UP TO AND FROM ADDRESSES 45700019
         LA    W3,EIGHT(W3)             *  FOR THE MOVE                 45800019
MOVE     SH    W1,H256                  IF SIZE IS GREATER OR EQUAL TO  45900019
         BH    MOVE256                  256, GO MOVE 256 BYTES          46000019
         AH    W1,H255                  ELSE,                           46100019
         EX    W1,AMOVE                  MOVE REMAINING NBR OF BYTES    46200019
*                                                                       46300019
*   MOVE COMPLETED                                                      46400019
*                                                                       46500019
         MVC   SWABFINC,SWABDW          PUT DATA LENGTH IN THE BUFFER   46600019
*                                       INCREMENT FIELD                 46700019
EXCP     EQU   *                                                        46800019
         LR    DEQRTN,PARAM             SET UP IOB POINTER              46810019
         MVC   IOBDQPTR+B1(3),IOBECBPT+B1 SAVE ECB ADDRESS       XM3808 46950021
         LA    W1,IOBCSWST               RIGHT HALF OF CSW IS    YM3709 46960021
         ST    W1,IOBECBPT               ECB FOR THIS OPERATION  YM3709 46970021
         EXCP  (1)                                                      47000019
TSTIFDON LR    W1,PARAM                 GET IOB ADDRESS                 47200019
         SH    W1,H8                    POINT TO IOB PREFIX             47300019
         TM    NULL(W1),DEQIP           DID THIS IOB GET CONTROL FROM   47400019
*                                       ONE WHICH WAS BEING DEQ'ED      47500019
         BZ    EXIT                     EXIT IF NOT                     47600019
         L     PARAM,NULL(W1)           ELSE, ESTABLISH THE IOB WHICH   47700019
*                                       WAS BEING DEQ'ED AS THE CURRENT 47800019
*                                       IOB                             47900019
         NI    NULL(W1),DEQIPOFF        TURN OFF DEQ IN PROCESS BIT     48000019
         B     CONTDEQ                  RESUME PROCESSING IN THE DEQ    48600019
*                                       ROUTINE                         48700019
NOFIT    EQU   *                                                        48800019
         SR    W3,W3                                                    48900019
         LH    W3,IOBDBYTN+TWO          GET SIZE REQUIRED AS LAST RCD.  49000019
         SR    W3,W4                    SUBTRACT TRACK BALANCE          49100019
         LA    W3,EIGHT(W3)             ALLOW FOR DESCRIPTORS           49200019
*   W3 NOW CONTAINS THE NUMBER OF BYTES WHICH CANNOT FIT ON THE TRACK   49300019
*                                                                       49400019
         LH    W4,DECLNGTH              GET ACTUAL DATA LENGTH          49500019
         SR    W4,W3                    THE RESULT IN W4 IS THE NUMBER  49600019
*                                       OF DATA BYTES WHICH COULD BE    49700019
*                                       WRITTEN                         49800019
         BP    WRTSOME                  BRANCH IF RESULT IS GREATER     49900019
*                                       THAN ZERO                       50000019
*                                                                       50100019
*   IF THIS POINT IS REACHED, THE TRACK DOES NOT CONTAIN ENOUGH ROOM    50200019
*   TO WRITE A RECORD WHOSE DATA PORTION IS NONE BYTES, SO THE TRACK    50300019
*   WILL BE RELEASED AND THE SEARCH STARTED AGAIN ON THE NEXT TRACK.    50400019
*                                                                       50500019
TRKFULL  EQU   *                                                        50510019
         BAL   DEQRTN,ACA1              GO DEQ THIS TRACK               50600019
         XC    IOBDBYTR,IOBDBYTR        ZERO THE BYTE TOTAL             50700019
         MVI   TRKCNT,NULL              SET TRACK COUNT TO ZERO         50800019
         TM    IOBDTYPE,EXSCH           IS EXTENDED SEARCH SPECIFIED    50900019
         BO    AAE5                     BR IF YES                       51000019
SETNOSPA MVI   IOBDSTAT+ONE,NOSPA       SET NO SPACE EXCEPTION CODE     51100019
         B     AAF2                     TERMINATE THE REQUEST           51200019
WRTSOME  EQU   *                                                        51300019
         LA    W4,EIGHT(W4)             ADD 8 FOR DESCRIPTORS           51400019
         STH   W4,IOBDBYTR              STORE THE DATA LENGTH IN THE    51500019
         STH   W4,SAVELL+ONE            BYTE TOTAL AND FIRST SEG SIZE   51600019
         MVC   SAVELL,SAVELL+ONE                                        51700019
AAE5     EQU   *                                                        51800019
         L     SF1BASE,FOUR(SFBASE)     GO TO EXTENDED SEARCH MODULE TO 51900019
         BALR  RETREG,SF1BASE           GET NEXT TRACK ADDRESS          52000019
         B     OKRTN                    IF THE RETURN IS TO THIS INSTR, 52100019
*                                       IF WAS A NORMAL RETURN.         52200019
         OI    IOBDSTAT+ONE,NOSPA       ELSE, A RETURN TO THIS INSTR.   52300019
*                                       INDICATOR SEARCH LIMIT REACHED. 52400019
*                                       SO SET NO SPACE INDICATOR FOR   52500019
*                                       LATER TESTING                   52600019
OKRTN    EQU   *                                                        52700019
         LR    W1,PARAM                 *                               52720019
         SH    W1,H4                     * RESTORE SWA POINTER          52740019
         L     SWAPTR,NULL(W1)          *                               52760019
         CLI   TRKCNT,NULL              IF TRACK COUNT IS ZERO, DON'T   52800019
         BE    TRKOK                    WORRY WHERE THE NEW TRACK IS    52900019
         L     W1,DCBDEBAD              GET DEB ADDRESS                 53000019
         LA    W1,DEBBASE(W1)           POINT TO DEVICE SECTION         53100019
         CLI   IOBSEEK,NULL             IS THI TRACK IN THE FIRST       53200019
*                                       EXTENT                          53300019
         BNE   VOLTST                   BR IF NOT                       53400019
         CLC   IOBSEEK3(FOUR),SIX(W1)   IF THE NEW TRACK IS THE FIRST   53500019
         BE    REINIT                   TRACK IN THE FIRST EXTENT, WE   53600019
*                                       HAVE JUST WRAPPED AROUND AND    53700019
*                                       MUST START THE SEARCH AGAIN     53800019
VOLTST   EQU   *                                                        53900019
         SR    W2,W2                                                    54000019
         SR    W3,W3                                                    54100019
         IC    W2,IOBSEEK               GET EXTENT NBR OF NEW TRACK     54200019
         SLL   W2,FOUR                  MULTIPLY BY 16 (EXTENT SIZE)    54300019
         AR    W2,W1                    ADD ON POINTER TO FIRST EXTENT  54400019
         IC    W3,SAVEMBB               GET EXTENT NBR OF FIRST TRACK   54500019
         SLL   W3,FOUR                  MULTIPLY BY 16                  54600019
         AR    W3,W1                    ADD ON DEB BASE SIZE            54700019
         CLC   ONE(THREE,W2),ONE(W3)    COMPARE THE UCB ADDRESSES       54800019
         BNE   REINIT                   IF NOT THE SAME, THE NEW TRACK  54900019
*                                       IS ON A DIFFERENT VOLUME AND    55000019
*                                       THE SEARCH MUST START OVER ON   55100019
*                                       THE NEW VOLUME                  55200019
TRKOK    EQU   *                                                        55300019
         NI    IOBDSTAT,NOTENQD         TURN OFF INDICATION THAT THE    55400019
         L     SFBASE,DCBDRDX           TRACK WAS ENQ'ED. GET ADDR OF   55500019
         BALR  LGRTN,SFBASE             EXCLUSIVE MODULE AND BR TO IT.  55600019
         L     SFBASE,DCBDFOR           RESTORE BASE OF THIS MODULE     55700019
         B     TSTIFDON                 GO TEST IF DONE                 55800019
REINIT   EQU   *                                                        55900019
         TM    IOBDSTAT+ONE,NOSPA       IS NOT SPACE INDICATED          56000019
         BO    AAF2                     BR IF YES                       56100019
         MVC   IOBDNRCF,IOBSEEK         SAVE IOBSEEK                    56200019
         BAL   DEQRTN,ACA1              GO DEQ ALL TRACKS BUT LAST      56300019
         MVC   IOBSEEK,IOBDNRCF         RESTORE                         56400019
         XC    IOBDBYTR,IOBDBYTR        ZERO OUT BYTE TOTAL             56500019
         B     TRKOK                    GO ENQ CURRENT TRACK            56600019
NOTFIRST EQU   *                                                        56700019
         CLI   IOBDNRCF+FOUR,NULL       SEE IF THI TRACK IS EMPTY (IF   56800019
*                                       IT IS, THE LAST BLOCK POINTER   56900019
*                                       IN THE CAPACITY RECORD IS ZERO) 57000019
         BNE   NOTEMPTY                 BR IF NOT EMPTY                 57100019
         IC    W1,TRKCNT                *                               57200019
         LA    W1,ONE(W1)                * ADD ONE TO TRACK COUNT       57300019
         STC   W1,TRKCNT                *                               57400019
         MVC   IOBDNRCF(TWO),IOBDNRCF+FIVE MOVE TRK BAL TO HALF WORD    57500019
*                                       BOUNDARY                        57600019
         LH    W1,IOBDNRCF              GET TRACK BALANCE               57700019
         SH    W1,H8                    SUBTRACT 8 FOR DESCRIPTORS      57800019
         AH    W1,IOBDBYTR              ADD TO BYTE TOTAL               57900019
         STH   W1,IOBDBYTR                                              58000019
         LH    UCBREG,TWO(UCBREG)       GET UCB ADDR FROM 12*           58030019
         BAL   W3,GETDVENT              GET DEVICE TABLE ENTRY          58060019
         CLC   IOBDBYTR,DECLNGTH        DO WE HAVE ENOUGH SPACE YET     58130019
         BL    AAE5                     BR IF NO                        58200019
         MVI   SEGFLGS,ONE              SET SEGMENT FLAGS TO 01 TO      58300019
*                                       INDICATE FIRST SEGMENT OF A     58400019
*                                       MULTI-SEGMENT RECORD            58500019
         XC    IOBDBYTR,IOBDBYTR        SET TRACK BALANCE FOR FIRST     58600019
*                                       SEGMENT TO ZERO                 58700019
         B     FINSETUP                 GO FINISH SEGMENT SET UP        58800019
*                                                                       58900019
NOTEMPTY EQU   *                                                        59000019
         TM    IOBDSTAT+ONE,NOSPA       IS THERE A NO SPACE INDICATION  59100019
         BZ    RETRY                    BR IF NO                        59200019
         IC    W1,TRKCNT                *                               59300019
         LA    W1,ONE(W1)                * ADD ONE TO TRACK COUNT       59400019
         STC   W1,TRKCNT                *                               59500019
AAF2     EQU   *                                                        59600019
         OI    IOBDSTAT,ABNORM          SET ABNORMAL COMPLETION BIT     59700019
         B     ACB4                     GO DEQ TRACKS USED              59800019
*                                                                       59900019
RETRY    EQU   *                                                        60000019
         MVC   SAVELL(THREE),IOBSEEK    SAVE MBB FROM IOBSEEK           60100019
         BAL   DEQRTN,ACA1              GO FREE ALL TRACKS BUT LAST     60200019
         MVC   IOBSEEK(THREE),SAVELL    RESTORE MBB IN IOBSEEK          60300019
         B     OTHRFRST                 GO START SEARCH ALL OVER        60400019
ACA1     EQU   *                                                        60500019
*                                                                       60600019
*   THE FOLLOWING ROUTINE WILL DEQ THE NUMBER OF TRACKS INDICATED IN    60700019
*   TRKCNT STARTING WITH THE TRACK WHOSE ADDRESS IS IN SAVEMBB          60800019
*                                                                       60900019
         CLI   TRKCNT,NULL              IF TRACK COUNT IS ZERO, RETURN  61000019
         BCR   EIGHT,DEQRTN             BECAUSE NO TRACKS TO DEQ        61100019
         ST    DEQRTN,SVDEQRTN          SAVE RETURN ADDRESS             61150019
         MVC   IOBSEEK,SAVEMBB          MOVE IN FIRST TRACK ADDRESS     61200019
         NI    IOBDSTAT,RCDNOFIT        TURN OF RECORD FIT BIT          61300019
         OI    IOBDSTAT,ENQD            TURN ON RECORD ALREADY ENQD BIT 61400019
GOTOLG   L     SFBASE,DCBDRDX           GET ADDRESS OF EXCLUSIVE CNTRL  61500019
         BALR  LGRTN,SFBASE             MODULE AND BRANCH TO IT TO DEQ  61600019
         L     SFBASE,DCBDFOR           RESTORE BASE OF THIS MODULE     61650019
         LTR   W4,W4                    DOES ANOTHER IOB WANT THE TRACK 61700019
         BZ    CONTDEQ                  BR IF NO                        61800019
         LR    W1,W4                    GET NEW IOB ADDRESS             62000019
         SH    W1,H8                    GET TO THE IOBPREFIX            62100019
         ST    PARAM,NULL(W1)           STORE OLD IOB ADDR IN NEW IOB   62200019
         OI    NULL(W1),DEQIP           INDICATE A DEQ WAS INTERRUPTED  62300019
         LR    PARAM,W4                 ESTABLISH NEW IOB AS CURRENT    62400019
         B     EXCP                     GO READ THE CAPACITY RECORD     62500019
CONTDEQ  EQU   *                                                        62600019
*                                                                       62606019
*   RESTORE REGISTERS BEFORE EXIT FROM DEQ ROUTINE                      62612019
*                                                                       62618019
         LR    SWAPTR,PARAM             *                               62624019
         SH    SWAPTR,H4                 * RESTORE SWA POINTER          62630019
         L     SWAPTR,NULL(SWAPTR)      *                               62636019
         L     UTIL,IOBECBPT            RESTORE DECB POINTER            62642019
         L     UCBREG,DCBDEBAD          *                               62648019
         SR    W2,W2                     *                              62654019
         IC    W2,IOBSEEK                 * GET UCB ADDRESS             62660019
         SLL   W2,FOUR                   *                              62666019
         L     UCBREG,DEBBASE(W2,UCBREG) *                              62672019
         BAL   W3,GETDVENT              GET POINTER TO DEVICE TABLE     62678019
         L     DEQRTN,SVDEQRTN          RESTORE RETURN ADDR FROM DEQ    62684019
*                                                                       62690019
         IC    W1,TRKCNT                *                               62700019
         BCTR  W1,NULL                   * SUBTRACT ONE FROM TRACK CNT  62800019
         STC   W1,TRKCNT                *                               62900019
         CLI   TRKCNT,NULL              IF TRACK COUNT IS ZERO.         63000019
         BCR   EIGHT,DEQRTN             RETURN TO CALLING SEQUENCE      63100019
         L     SF1BASE,FOUR(SFBASE)     GO TO EXTENDED SEARCH MODULE TO 63200019
         BALR  RETREG,SF1BASE           GET NEXT TRACK ADDRESS          63300019
         B     GOTOLG                   FOR EITHER RETURN, GO TO THE    63400019
         B     GOTOLG                   EXCLUSIVE CONTROL MODULE TO DEQ 63500019
*                                       THE NEXT TRACK                  63600019
ENTRYP12 EQU   *                                                        63700019
MVINFRST EQU   *                                                        63780019
         MVC   SAVEMBB(EIGHT),IOBCP+EIGHT  MOVE IN MBB AND R (0) OF     63860019
*                                          FIRST TRACK                  63940019
         MVC   SVCCHHR(FOUR),IOBCP      MOVE IN CCHH OF FIRST TRACK     64020019
ACB4     EQU   *                                                        64100019
         BAL   DEQRTN,ACA1              GO DEQ ALL TRACKS USED          64200019
         MVC   IOBSEEK,SAVEMBB          RESTORE IOBSEEK TO FIRST TRACK  64300019
*                                       ADDRESS IN CASE FEEDBACK IS     64400019
*                                       REQUESTED                       64500019
         IC    W1,IOBCP+FOUR                                            64510019
         LA    W1,ONE(W1)                                               64520019
         STC   W1,IOBSEEK+SEVEN                                         64530019
         LR    W1,PARAM                                                 64600019
         SH    W1,H8                    POINT W1 TO IOB PREFIX          64700019
         OI    IOBDSTAT,RCDFIT                                          64710019
         TM    NULL(W1),DEQIP           DID THIS IOB GET CONTROL FROM   64800019
*                                       ONE WHICH WAS BEING DEQ'ED.     64900019
         BZ    POSTNDQ                  POST IF NOT                     65000019
         L     W4,NULL(W1)              SAVE THE IOB'S ADDRESS          65200019
         NI    NULL(W1),DEQIPOFF        TURN OFF DEQ LOOP BIT           65300019
         LA    W1,AFTPOSTQ                                              65400019
         ST    W1,IOBDQPTR              SET RETURN ADDRESS FROM POST    65500019
GOTOPOST L     FDNBASE,DCBREAD                                          65600019
         L     FDNBASE,ASIOFF(FDNBASE)  SET UP DESIRED ENTRY TO ASI     65700019
         LR    EPREG,FDNBASE            PUT ADDR IN 2 REGS              65730019
         LR    DEQRTN,PARAM             PUT IOB ADDR IN ASI REGISTER    65760019
         B     FOUR(FDNBASE)            AND BRANCH TO IT                65800019
*                                                                       65900019
AFTPOSTQ EQU   *                                                        66000019
         LR    PARAM,W4                 ESTABLISH IOB WHICH WAS BEING   66100019
*                                       DEQ'ED                          66200019
         B     CONTDEQ                  GET INTO DEQ LOOP AGAIN         66400019
POSTNDQ  EQU   *                                                        66600019
         LA    W1,EXIT                                                  66700019
         ST    W1,IOBDQPTR              SET RETURN ADDRESS FROM POST    66800019
         B     GOTOPOST                 GO POST                         66900019
NOKEYCP  EQU   *                                                        67000019
         MVC   WANKWD+CNTOFF(TWO),SAVELL MOVE DATA LENGTH TO WRITE CCW  67100019
         B     AFTERLL                  GO FINISH THE SET UP            67200019
*                                                                       67300019
MOVE256  MVC   NULL(FFF,W2),NULL(W3)    MOVE 256 BYTES                  67400019
         LA    W2,FFF(W2)               *                               67500019
         LA    W3,FFF(W3)                * UPDATE MOVE AREA POINTERS    67600019
         B     MOVE                     *  AND GO SEE IF MORE TO MOVE   67700019
*                                                                       67800019
AMOVE    MVC   NULL(NULL,W2),NULL(W3)   - EXECUTED - MOVE LESS THAN 256 67900019
*                                                                       68000019
EXIT     EQU   *                                                        68100019
         SVC   EXITSVC                  EXIT                            68200019
*                                                                       68300019
*                                                                       68400019
*********************************************************************** 68500019
H8       DC    H'8'                     IOB PREFIX SIZE                 68600019
H4       DC    H'4'                     DESCRIPTOR LENGTHS              68700019
H256     DC    H'256'                   *                               68800019
H255     DC    H'255'                    * CONSTANTS USED BY MOVE RTN   68900019
FFF      EQU   256                      *                               69000019
DEBBASE  EQU   32                       SIZE OF DEB BASE PORTION        69100019
RCDNOFIT EQU   X'FD'                    MASK TO TURN OFF RCDFIT BIT     69200019
DEQIP    EQU   X'80'                    DEQ IN PROCESS INDICATOR        69300019
DEQIPOFF EQU   X'7F'                    MASK TO TURN DEQIP OFF          69400019
NOINTRPT DC    X'00'                    DISALLOW ALL INTERRUPTS         69500019
INTRPTOK DC    X'FF'                    ALLOW ALL INTERRUPTS            69600019
NOREAD   EQU   X'F7'                                                    69700019
RCDFIT   EQU   X'02'                                                    69800019
ENQD     EQU   X'08'                                                    69900019
NOTENQD  EQU   X'F7'                                                    70000019
EXITSVC  EQU   3                        EXIT SVC NO.                    70100019
DEVSZ    EQU   0                        DEVICE SIZE CCHH                70200019
TRKLNGTH EQU   4                        TRACK LENGTH                    70300019
OVERI    EQU   6                        OVERHEAD NOT LAST RECORD        70400019
OVERL    EQU   7                        OVERHEAD LAST RECORD            70500019
OVERK    EQU   8                        OVERHEAD KEYED RECORD           70600019
FLAG     EQU   9                        FLAG                            70700019
TOLER    EQU   10                       TOLERANCE                       70800019
*        CCW FLAGS AND COUNT                                            70900019
         DS    0F                                                       71000019
LASTFOUR DC    X'0000000F'              CLEARS ALL BUT LOW ORDER 4 BITS 71100019
ASIOFF   EQU   16                       ASI ADDR SLOT IN FOUNDATION     71200019
FDBOFF   EQU   4                        FEEDBACK BRANCH IN ASI          71300019
POOLOFF  EQU   12                       IOB POOL BRANCH IN ASI          71400019
FIRST    EQU   X'10'                                                    71500019
CFORFLG  EQU   X'08'                    CAUSED FORMAT FLAG              71600019
CLRFFLAG EQU   X'FE'                                                    71700019
*        CHANNEL PROGRAM OP-CODES                                       71800019
SCHID    EQU   X'31'                    SEARCH ID EQUAL                 71900019
TIC      EQU   X'08'                    TRANSFER IN CHANNEL             72000019
READD    EQU   X'06'                    READ DATA                       72100019
WRTD     EQU   X'05'                    WRITE DATA                      72200019
WRTCKD   EQU   X'1D'                    WRITE COUNT KEY DATA            72300019
*        CCW FLAGS                                                      72400019
DCSKFLG  EQU   X'F0'                    CD CC SILI SKIP FLAG BITS       72500019
DCCC     EQU   X'C0'                    DATA + COMMAND CHAIN            72600019
SKIP     EQU   X'10'                    SKIP DATA TRANSFER              72700019
CC       EQU   X'40'                    COMMAND CHAIN                   72800019
SILI     EQU   X'20'                    SUPPRESS INCORRECT LENGTH       72900019
CCSI     EQU   X'60'                    COMMAND CHAIN  SUPPRESS LENGTH  73000019
CNTOFF   EQU   6                        OFFSET TO THE COUNT FIELD IN A  73100019
*                                       CCW                             73200019
ONE      EQU   X'1'                                                     73300019
TWO      EQU   2                                                        73400019
THREE    EQU   3                                                        73500019
FOUR     EQU   4                                                        73600019
FIVE     EQU   X'5'                                                     73700019
SIX      EQU   6                                                        73800019
SEVEN    EQU   X'7'                                                     73900019
NINE     EQU   9                                                        74000019
TYPCD    EQU   19                       DA TYPE CODE OFFSET IN UCB      74100019
ABNORM   EQU   X'80'                    ABNORMAL COMPLETION INDICATOR   74200019
FOR1     EQU   X'02'                    TEST FOR FORMAT 1               74300019
*              EXCEPTION CODES                                          74400019
NOREC    EQU   X'80'                                                    74500019
LGNCK    EQU   X'40'                                                    74600019
NOSPA    EQU   X'20'                                                    74700019
INVAL    EQU   X'10'                                                    74800019
UNCOR    EQU   X'08'                                                    74900019
ENDOD    EQU   X'04'                                                    75000019
UNREL    EQU   X'02'                                                    75100019
*              OPTIONS AND TYPE                                         75200019
OFLOW    EQU   X'40'                                                    75300019
EXSCH    EQU   X'20'                                                    75400019
FEEDB    EQU   X'10'                                                    75500019
ACTAD    EQU   X'08'                                                    75600019
DYNBF    EQU   X'04'                                                    75700019
READX    EQU   X'02'                                                    75800019
RELRD    EQU   X'01'                                                    75900019
KEYOP    EQU   X'80'                                                    76000019
LGNOP    EQU   X'40'                                                    76100019
READ     EQU   X'08'                                                    76200019
KEY      EQU   X'04'                                                    76300019
ADD      EQU   X'02'                                                    76400019
         DC    X'00'                    FILLER                          76500019
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   76600019
         CNOP  0,8                      PAD MODULE TO DOUBLE WORD       76700019
*********************************************************************** 76800019
*                                                                       76900019
*                                                                       77000019
*              DATA CONTROL BLOCK (DCB) DEFINITION                      77100019
*                                                                       77200019
*                                                                       77300019
*                                                                       77400019
         DCBD  DSORG=DA                                                 77500019
         EJECT                                                          77600019
CVTDEF   DSECT                                                          77700019
         CVT                                                            77800019
         EJECT                                                          77900019
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       78000019
         DS    0F                                                       78100019
DECBDEF  DSECT                                                          78200019
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        78300019
DECTYPE  DS    CL2            TYPE FIELD                                78400019
DECLNGTH DS    CL2            DATA LENGTH                               78500019
DECDCBAD DS    CL4            ADDRESS OF DCB                            78600019
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      78700019
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        78800019
DECKYADR DS    CL4            ADDRESS OF KEY                            78900019
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               79000019
DECNA    DS    CL4            ADDRESS OF NEXT ADDRESS FEEDBACK AREA     79100019
         EJECT                                                          79200019
*                                                                       79300019
*      I/O BLOCK (IOB) DEFINITION                                       79400019
*                                                                       79500019
*              STANDARD IOB                                             79600019
         DS    0F                                                       79700019
IOBDEF   DSECT                                                          79800019
IOBFLAG1 DS    CL1            STATUS FLAG                               79900019
IOBFLAG2 DS    CL1            ERROR FLAG                                80000019
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       80100019
IOBECBPT DS    CL4            ECB POINTER                               80200019
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       80300019
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           80400019
         DS    CL1            IOS ERROR FLAG BYTE                       80500019
         DS    CL3            COMMAND ADDRESS                           80600019
IOBCSWST DS    CL2            STATUS BYTES                              80700019
IOBCSWCT DS    CL2            REMAINING COUNT                           80800019
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   80900019
IOBSIOCC DS    CL1            SIO CONDITION CODE                        81000019
         DS    CL3            ADDRESS OF CHANNEL PROGRAM START          81100019
IOBDCBPT DS    0CL4           DCB POINTER                               81200019
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            81300019
         DS    CL3            DCB ADDRESS                               81400019
IOBRESTR DS    0CL4           RESTART POINTER                           81500019
         DS    CL1            IOS AND                                   81600019
         DS    CL3                 ERROR RESTART FIELDS                 81700019
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              81800019
IOBERRCT DS    CL2            ERROR COUNTER                             81900019
IOBSEEK  DS    CL8            SEEK ADDRESS                              82000019
IOBSEEK3 EQU   IOBSEEK+3                                                82100019
*        BDAM EXTENDED IOB                                              82200019
*                                                                       82300019
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  82400019
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          82500019
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     82600019
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                82700019
         DS    CL3            NEXT IOB POINTER                          82800019
IOBDTYPE DS    CL2            TYPE FIELD                                82900019
IOBDSTAT DS    CL2            IOB STATUS                                83000019
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        83100019
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD  (NOT LAST)    83200019
         DS    CL2            BYTES NEEDED FOR LAST RECORD ON TRACK     83300019
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               83400019
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        83500019
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                83600019
IOBCP    DS    CL256                   FIRST CCW IN CHANNEL PROGRAM     83700019
         EJECT                                                          83800019
*   THE FOLLOWING DSECT SHOWS THE FORMAT OF THE SEGMENT WORK AREA       83900019
*                                                                       84000019
SWA      DSECT                          SEGMENT WORK AREA DSECT         84100019
SWANXTPT DS    F                        POINTER TO NEXT SWA             84200019
SWARAPT  DS    F                        POINTER TO THE RECORD AREA      84300019
SWABFINC DS    CL2                      BUFFER INCREMENT FIELD          84400019
SWABDW   DS    CL4                      BLOCK DESCRIPTOR WORD           84500019
SAVEID   EQU   SWABDW+5                 SAVE AREA FOR ID OF LAST SEGMNT 84600019
SWASDW   DS    0CL4                     SEGMENT DESCRIPTOR WORD         84700019
SEGLL    DS    H                        SEGMENT LENGTH (LL)             84800019
SEGFLGS  DS    C                        SEGMENTATION FLAGS              84900019
SVDEQRTN EQU   SWA+16                   SAVE DEQ RTN RETURN ADDR        84950019
SEGUNUSD DS    C                        CURRENTLY UNUSED                85000019
SEGDATA  DS    C                        DATA PORTION OF RECORD          85100019
*                                                                       85200019
*                                                                       85300019
*   WHEN THE SEGMENT WORK AREA IS USED FOR A TEMPORARY WORK SPACE, IT   85400019
*   HAS THE FOLLOWING USAGE -                                           85500019
         ORG   SWA                      START AT SWA                    85600019
SWAWNXTB DS    F                        POINTER TO NEXT SWA (UNCHANGED) 85700019
TRKCNT   DS    C                        TRACK COUNT (NBR OF TRACKS      85800019
*                                            USED FOR THE RECORD)       85900019
SAVEMBB  DS    CL3                      SAVE MBB FROM IOBSEEK           86000019
SVCCHHR  DS    CL5                      CCHHR OF LAST RECORD ON THE     86100019
*                                            FIRST TRACK EXAMINED       86200019
SAVELL   DS    CL2                      LENGTH OF THE FIRST SEGMENT TO  86300019
*                                            BE FORMED, OR A 3 BYTE     86400019
         DS    C                             SAVE AREA FOR MBB WHEN A   86500019
*                                            SEARCH IS TO BE RESTARTED  86600019
         EJECT                                                          86700019
*********************************************************************** 86800019
*                                                                     * 86900019
*                                                                     * 87000019
*                       CHANNEL PROGRAM DSECTS                        * 87100019
*                                                                     * 87200019
*                                                                     * 87300019
*********************************************************************** 87400019
         SPACE 10                                                       87500019
*                                                                       87600019
*   ORIGINAL CHANNEL PROGRAM TO WRITE (ADD) A NEW VRE RECORD            87700019
*                                                                       87800019
WRITEADD DSECT                                                          87900019
WANOP1   DS    D                  CCW1  NOP                             88000019
WASIE1   DS    D                  CCW2  SEARCH ID EQUAL (R0)            88100019
WATIC1   DS    D                  CCW3  TIC TO CCW2                     88200019
WARD     DS    D                  CCW4  READ DATA (R0)                  88300019
WANOP2   DS    D                  CCW5  NOP                             88400019
WASIE2   DS    D                  CCW6  SEARCH ID EQUAL (R0)            88500019
WATIC2   DS    D                  CCW7  TIC TO CCW6                     88600019
WAWDR0   DS    D                  CCW8  UPDATE CAPACITY RECORD          88700019
WASIE3   DS    D                  CCW9  SEARCH ID EQUAL                 88800019
WATIC3   DS    D                  CCW10 TIC TO CCW9                     88900019
WAWCKD1  DS    D                  CCW11 WRITE COUNT                     89000019
* THE NEXT CCW'S MAY BE PRESENT ONLY IF KEYS ARE TO BE WRITTEN.         89100019
WAKWK    DS    D                  CCW12 WRITE KEY                       89200019
WAKWD    DS    D                  CCW13 WRITE DATA                      89300019
WAKNOP1  DS    D               ** CCW14 NOP                             89400019
WAKNOP2  DS    D               ** CCW15 NOP                             89500019
WAKSIE   DS    D               ** CCW16 SEARCH ID EQUAL                 89600019
WAKTIC   DS    D               ** CCW17 TIC TO CCW16                    89700019
WAKRKD   DS    D               ** CCW18 READ-KEY-DATA TO DO WRITE CHECK 89800019
WAKRR0   DS    D               ** CCW19 WRITE CHECK R0                  89900019
* IF KEYS ARE NOT TO BE WRITTEN, THE FOLLOWING CCW'S ARE USED           90000019
WANK     EQU   WAKWK-WRITEADD                                           90100019
         ORG   WRITEADD+WANK      ORG BACK TO CCW12                     90200019
WANKWD   DS    D                  CCW12 WRITE DATA                      90300019
WANKNOP1 DS    D               ** CCW13 NOP                             90400019
WANKNOP2 DS    D               ** CCW14 NOP                             90500019
WANKSIE  DS    D               ** CCW15 SEARCH ID EQUAL                 90600019
WANKTIC  DS    D               ** CCW16 TIC TO CCW15                    90700019
WANKRKD  DS    D               ** CCW17 READ-KEY-DATA TO DO WRITE CHECK 90800019
WANKRR0  DS    D               ** CCW18 WRITE CHECK R0                  90900019
*                                                                       91000019
*                              ** THESE CCW'S ARE INCLUDED ONLY IF      91100019
*                                 WRITE CHECK IS REQUESTED.             91200019
         SPACE 3                                                        91300019
*                                                                       91400019
*   CHANNEL PROGRAM FOR WRITE ADD AFTER WRITING THE FIRST SEGMENT       91500019
*                                                                       91600019
WRITADD1 DSECT                                                          91700019
WA1NOP1  DS    D                  CCW1  NOP                             91800019
WA1SIE   DS    D                  CCW2  SEARCH ID EQUAL (R0)            91900019
WA1TIC   DS    D                  CCW3  TIC TO CCW2                     92000019
WA1WC    DS    D                  CCW4  WRITE COUNT                     92070019
WA1WD    DS    D                  CCW5  WRITE DATA                      92140019
WA1SIE2  DS    D                  CCW6  SEARCH ID EQUAL (R0)            92210019
WA1TIC2  DS    D                  CCW7  TIC TO CCW6                     92280019
WA1WCR   DS    D                  CCW8  UPDATE CAPACITY RECORD          92350019
WA1NOP2  DS    D               ** CCW9  NOP                             92420019
WA1RR0   DS    D               ** CCW10 READ R0 FOR WRITE CHECK         92490019
WA1RD    DS    D               ** CCW11 READ DATA FOR WRITE CHECK       92560019
*                                                                       92700019
*                              ** THESE CCW'S ARE INCLUDED WHEN WRITE   92800019
*                                 CHECK IS REQUESTED.                   92900019
         END                                                            93000019
