IGG019KO CSECT                                                          00020000
*          RELEASE 17 DELETIONS                                         00023000
*3000018400,018800-020600                                         MC0J  00026000
*          RELEASE 18 DELETIONS                                         00029000
*2740018400,019300,028500                                         24512 00030018
*          RELEASE 19 DELETIONS                                         00032000
*          RELEASE 20 DELETIONS                                         00035000
*          RELEASE 21 DELETIONS                                         00038000
*          RELEASE 22 DELETIONS                                         00041000
*          RELEASE 23 DELETIONS                                         00044000
*          RELEASE 24 DELETIONS                                         00047000
*          RELEASE 25 DELETIONS                                         00050000
 TITLE   'IGG019KO - PRE-FORMAT MODULE'                                 00060000
*                                                                       00080000
*STATUS CHANGE LEVEL 004                                                00100018
*FUNCTION/OPERATION- THIS ROUTINE IS ENTERED TO CONSTRUCT THE CHANNEL * 00120000
*   PROGRAM TO ADD A NEW BLOCK TO A DATA SET OF FIXED FORMAT RECORDS. * 00140000
*   THE CCWS ARE CONSTRUCTED OF CONSTANTS DEFINED IN THIS MODULE AND  * 00160000
*   ADDRESSES RESOLVED AT THE TIME THIS CODE IS EXECUTED.             * 00180000
*                                                                     * 00200000
*ENTRY POINT- 'IGG019KO' (BEGIN) IS ENTERED FROM MODULE IGG019KA BY   * 00220000
*   THE CALLING SEQUENCE,   L    15,DCBDFOR                           * 00240000
*                           BALR 14,15                                * 00260000
*                                                                     * 00280000
*INPUT- THE REGISTERS ARE USED AS INPUT AS FOLLOWS,                   * 00300000
*   4 - DCB ADDRESS                                                   * 00320000
*   5 - DECB ADDRESS                                                  * 00340000
*   6 - ADDRESS OF CCW 1 (IOB+80)                                     * 00360000
*   7 - IOB ADDRESS                                                   * 00380000
*   11- BASE ADDRESS OF MODULE IGG019KA (FOUNDATION MODULE)           * 00400000
*                                                                     * 00420000
*OUTPUT- THE REQUIRED CCWS QILL BE CONSTRUCTED FOLLOWING THE IOB.     * 00440000
*   REGISTER 6 WILL CONTAIN THE ADDRESS OF THE LAST CCW.              * 00460000
*                                                                     * 00480000
*EXTERNAL ROUTINES- 'IGG019KQ' IS ENTERED TO ADD THE VERIFY CCWS IF   * 00500000
*   THAT OPTION IS SPECIFIED.                                         * 00520000
*                                                                     * 00540000
*EXIT-NORMAL- 'D9EXIT' IS THE NORMAL RETURN TO THE FOUNDATION MODULE  * 00560000
*   WHEN ALL CCWS ARE COMPLETE.                                       * 00580000
*   'D9TOVER' IS THE EXIT TO MODULE IGG019KQ                          * 00600000
*EXIT-ERROR- 'D9ERR' IS AN EXIT TO THE INVALID REQUEST ERROR ROUTINE  * 00620000
*   IN MODULE IGG019KA WHEN IT HAS BEEN DETERMINED THAT THE USER IS   * 00640000
*   ATTEMPTING TO ADD A RECORD WHOSE KEY IS THE SAME AS A DUMMY KEY.  * 00660000
* REGISTER 12 WILL CONTAIN AN INVALID REQUEST ERROR CODE.             * 00680000
*                                                                     * 00700000
*TABLES/WORK AREAS- NOA                                               * 00720000
*                                                                     * 00740000
*ATTRIBUTES- THIS ROUTINE IS REENTRANT AND EXECUTED ENABLED.          * 00760000
*                                                                     * 00780000
*NOTE- THE REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT WITH  * 00800000
*   THE MODULES, IGG019KA, IGG019KQ.                                  * 00820000
*                                                                       00840000
         USING IGG019KO,D9EPREG                                         00860000
         USING IHADCB,DCBREG                                            00880000
         USING DECBDEF,DECBREG                                          00900000
         USING IOBDEF,IOBREG                                            00920000
*                                                                       00940000
*                                                                       00960000
*   REGISTER USAGE                                                      00980000
*                                                                       01000000
D9WKREG  EQU   0                       WORK REGISTER                    01020000
D9VERR   EQU   1                       ADDR. OF SEARCH CCW FOR VERIFY   01040000
DEBREG   EQU   3                       DEB ADDRESS                      01060000
DCBREG   EQU   4                       DCB ADDRESS                      01080000
DECBREG  EQU   5                       DECB ADDRESS                     01100000
D9CCWIND EQU   6                       CHANNEL PROGRAM INDEX            01120000
IOBREG   EQU   7                       IOB ADDRESS                      01140000
VERBASE  EQU   10                      ENTRY POINT-BASE, VERIFY MODULE  01160000
FDNBASE  EQU   11                      BASE, FOUNDATION MODULE          01180000
D9WKRET  EQU   12                      RETURN FOR INTERNAL LINKAGE      01200000
SAVE     EQU   13                      USER'S SAVE AREA ADDRESS         01220000
D9RETREG EQU   14                      RETURN TO FOUNDATION MODULE      01240000
D9EPREG  EQU   15                      BASE OF THIS MODULE              01260000
*                                                                       01280000
*                                                                       01300000
BEGIN    B     D9ENTRY                 GO TO THE BEGINNING OF THE CODE  01320000
EPAD     DS    F                       ADDRESS OF EXT. SEARCH MODULE    01340000
*                                                                       01360000
D9ENTRY  L     D9VERR,DECKYADR         TEST TO BE SURE THE USER'S       01380000
         TM    0(D9VERR),X'FF'          KEY DOES NOT HAVE BITS LIKE THE 01400000
         BC    12,D9OKKEY               DUMMY KEY, BRANCH IF OK.        01420000
         IC    D9WKRET,D9INVKY          ELSE INSERT EXCEPTION CODE,     01440000
         L     D9RETREG,D9ERRET(0,FDNBASE) LOCATE ERROR ROUTINE         01460000
D9ERR    BCR   15,D9RETREG              AND GO POST AS INVALID REQUEST  01480000
*                                                                       01500000
D9OKKEY  TM    IOBDTYPE,EXSCH          TEST FOR EXTENDED SEARCH OPTION  01520000
         BC    1,D9XSCH                  AND GO TO THAT LINKAGE         01540000
         LA    D9WKREG,IOBDNRCF+2      DEVELOP AND STORE ADDRESS        01560000
         ST    D9WKREG,0(D9CCWIND)       FOR READING FEEDBACK           01580000
         MVI   0(D9CCWIND),D9RDCNT      MOVE READ COUNT OP CODE         01600000
         MVI   4(D9CCWIND),D9CSFLG     SET COMMAND CHAIN, SILI FLAGS    01620000
         MVI   7(D9CCWIND),D9FIVE      MOVE COUNT OF FIVE               01640000
         ST    D9CCWIND,16(D9CCWIND)    INSERT TIC ADDRESS              01660000
         LA    D9CCWIND,8(D9CCWIND)     INCREMENT INDEX                 01680000
D9BOTH   LA    D9WKREG,DUMMKEY         DEVELOP ADDR OF DUMMY KEY BYTE   01700000
         ST    D9WKREG,0(D9CCWIND)       FOR SEARCH ARGUMENT            01720000
         MVI   0(D9CCWIND),D9SCHKEY     MOVE SEARCH KEY EQUAL OP CODE   01740000
         MVC   4(5,D9CCWIND),D9CON3     MOVE FLAGS, COUNT, TIC OP CODE  01760000
         LA    D9WKREG,IOBDNRCF+6      DEVELOP AND STORE THE ADDRESS    01780000
         ST    D9WKREG,16(D9CCWIND)      FOR READING DUMMY RECORD ID    01800000
         MVI   16(D9CCWIND),D9RDDATA    MOVE READ DATA OP CODE          01820000
         MVI   20(D9CCWIND),D9CSFLG     COMMAND CHAIN, SILI FLAGS 24512 01840018
         MVI   23(D9CCWIND),D9ONE       SET COUNT TO ONE                01860000
         LA    D9CCWIND,24(D9CCWIND)    INCREMENT TO OPTIONAL     24512 01870018
*                                       SEEK                      24512 01880018
         TM    IOBDTYPE,OFLOW           TEST FOR TRK OVERFLOW     24512 01890018
         BZ    D9NOTOF                  BRANCH TO OMIT SEEK       24512 01900018
         LA    D9WKREG,IOBDNRCF         IF NOT USING OPTION.      24512 01910018
         ST    D9WKREG,0(0,D9CCWIND)    OTHERWISE, SEEK NEEDED.   24512 01920018
         MVI   0(D9CCWIND),D9SEEKOP                               24512 01930018
         MVI   4(D9CCWIND),D9CFLG                                 24512 01940018
         MVI   7(D9CCWIND),D9SIX                                  24512 01950018
         LA    D9CCWIND,8(D9CCWIND)                               24512 01960018
D9NOTOF  EQU   *                                                  24512 01970018
         LA    D9WKREG,IOBDNRCF+2       CONSTRUCT SCH ID EQUAL CCW MC0J 02000000
         ST    D9WKREG,0(D9CCWIND)       USING IOBSEEK AND ID READ FROM 02080000
         MVI   0(D9CCWIND),D9SCHID       THE DUMMY RECORD               02100000
         ST    D9CCWIND,8(D9CCWIND)     SET TIC ADDRESS TO SEARCH CCW   02120000
         MVC   4(5,D9CCWIND),D9CON9      MOVE FLAGS, COUNT, TIC OP CODE 02140000
         MVI   16(D9CCWIND),D9WRTKD     MOVE WRITE KEY-DATA OP CODE     02160000
         MVC   17(3,D9CCWIND),DECKYADR+1 MOVE KEY ADDRESS               02180000
         MVI   20(D9CCWIND),D9DCFLG      DATA, COMMAND CHAIN FLAGS      02200000
         MVC   23(1,D9CCWIND),DCBKEYLE  KEY LENGTH                      02220000
         MVI   24(D9CCWIND),D9WRTD      MOVE WRITE DATA OP CODE         02240000
         MVC   25(3,D9CCWIND),DECAREA+1  AREA ADDRESS                   02260000
         MVC   30(2,D9CCWIND),DECLNGTH   MOVE DECB LENGTH AS COUNT      02280000
         LR    D9VERR,D9CCWIND          SAVE SEARCH ADDR. FOR VERIFY    02300000
         LA    D9CCWIND,24(D9CCWIND)    INCREMENT TO LAST CCW           02320000
         TM    IOBDTYPE,VERIFY         TEST FOR WRITE VERIFY OPTION     02340000
         BCR   8,D9RETREG               NO , CHANNEL PROGRAM IS DONE    02360000
         L     VERBASE,12(0,FDNBASE)   LOAD VERIFY ENTRY POINT/BASE     02380000
         BR    VERBASE                 GO CONSTRUCT VERIFY CCWS         02400000
*                                      VERIFY MODULE WILL RETURN TO     02420000
*                                      FOUNDATION ON REGISTER 14        02440000
*                                                                       02460000
D9XSCH   LA    D9WKRET,D9BOTH          SET RETURN ADDRESS               02480000
         L     D9EPREG,EPAD            LOAD ADDR. OF EXTENDED MODULE    02500000
         BCR   15,D9EPREG                GO CONSTRUCT EXT. SEARCH CCW'S 02520000
*                                                                       02540000
         EJECT                                                          02560000
*                                                                       02580000
D9RDCNT  EQU   X'12'  READ-COUNT OP CODE                                02600000
D9CSFLG  EQU   X'60'  COMMAND CHAIN, SUPPRESS INCORRECT LENGTH FLAGS    02620000
D9FIVE   EQU   X'05'  COUNT OF 5 FOR READ-COUNT                         02640000
D9CFLG   EQU   X'40'  COMMAND CHAIN                                     02660000
D9RDDATA EQU   X'06'  READ-DATA OP CODE                                 02680000
D9ONE    EQU   X'01'  COUNT OF ONE                                      02700000
D9SEEKOP EQU   X'0B'  SEEK CCHH OP-CODE                                 02720000
D9SIX    EQU   X'06'  COUNT FOR SEEK                                    02740000
D9SCHID  EQU   X'31'  SEARCH-ID-EQUAL OP CODE                           02760000
D9WRTKD  EQU   X'0D'  WRITE-KEY-DATA OP CODE                            02780000
D9DCFLG  EQU   X'C0'  DATA, COMMAND CHAIN FLAGS                         02800000
D9WRTD   EQU   X'05'  WRITE-DATA OP CODE                                02820000
D9SCHKEY EQU   X'29'  SEARCH-KEY-EQUAL                                  02840000
D9CON3   DC    X'6000000108'  FLAGS, COUNT, TIC OP-CODE                 02860000
D9CON9   DC    X'4000000508'  FLAG,COUNT,TIC OP-CODE                    02880000
DUMMKEY  DC    X'FF'         DUMMY KEY OF AVAILABLE RECORDS             02900000
D9INVKY  DC    X'01'         KEY MATCHES DUMMY KEY-ERROR                02920000
D9ERRET  EQU   20            OFFSET TO ERROR ROUTINE ADCON              02940000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   02960000
         CNOP  0,8                 PAD MODULE TO DOUBLE WORD MULTIPLE   02980000
         EJECT                                                          03000000
*              EXCEPTION CODES                                          03020000
NOREC    EQU   X'80'                                                    03040000
LGNCK    EQU   X'40'                                                    03060000
NOSPA    EQU   X'20'                                                    03080000
INVAL    EQU   X'10'                                                    03100000
UNCOR    EQU   X'08'                                                    03120000
ENDOD    EQU   X'04'                                                    03140000
UNREL    EQU   X'02'                                                    03160000
*              OPTIONS AND TYPE                                         03180000
VERIFY   EQU   X'80'                                                    03200000
OFLOW    EQU   X'40'                                                    03220000
EXSCH    EQU   X'20'                                                    03240000
FEEDB    EQU   X'10'                                                    03260000
ACTAD    EQU   X'08'                                                    03280000
DYNBF    EQU   X'04'                                                    03300000
READX    EQU   X'02'                                                    03320000
RELRD    EQU   X'01'                                                    03340000
KEYOP    EQU   X'80'                                                    03360000
LGNOP    EQU   X'40'                                                    03380000
READ     EQU   X'08'                                                    03400000
KEY      EQU   X'04'                                                    03420000
ADD      EQU   X'02'                                                    03440000
*      DATA CONTROL BLOCK (DCB) DEFINITION                              03460000
*                                                                       03480000
         DCBD  DSORG=DA                                                 03500000
*                                                                       03520000
*                                                                       03540000
*                                                                       03560000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       03580000
         DS    0F                                                       03600000
DECBDEF  DSECT                                                          03620000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        03640000
DECTYPE  DS    CL2            TYPE FIELD                                03660000
DECLNGTH DS    CL2            DATA LENGTH                               03680000
DECDCBAD DS    CL4            ADDRESS OF DCB                            03700000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      03720000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        03740000
DECKYADR DS    CL4            ADDRESS OF KEY                            03760000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               03780000
         EJECT                                                          03800000
*                                                                       03820000
*      I/O BLOCK (IOB) DEFINITION                                       03840000
*                                                                       03860000
*              STANDARD IOB                                             03880000
         DS    0F                                                       03900000
IOBDEF   DSECT                                                          03920000
IOBFLAG1 DS    CL1            STATUS FLAG                               03940000
IOBFLAG2 DS    CL1            ERROR FLAG                                03960000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       03980000
IOBECBPT DS    CL4            ECB POINTER                               04000000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       04020000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           04040000
         DS    CL1                                                      04060000
         DS    CL3                                                      04080000
IOBCSWST DS    CL2            STATUS BYTES                              04100000
IOBCSWCT DS    CL2            REMAINING COUNT                           04120000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   04140000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        04160000
         DS    CL3                                                      04180000
IOBDCBPT DS    0CL4           DCB POINTER                               04200000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            04220000
         DS    CL3                                                      04240000
IOBRESTR DS    0CL4           RESTART POINTER                           04260000
         DS    CL1                                                      04280000
         DS    CL3                                                      04300000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              04320000
IOBERRCT DS    CL2            ERROR COUNTER                             04340000
IOBSEEK  DS    CL8            SEEK ADDRESS                              04360000
*        BDAM EXTENDED IOB                                              04380000
*                                                                       04400000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  04420000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          04440000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     04460000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                04480000
         DS    CL3                                                      04500000
IOBDTYPE DS    CL2            TYPE FIELD                                04520000
IOBDSTAT DS    CL2            IOB STATUS                                04540000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        04560000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                04580000
         DS    CL2                                                      04600000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               04620000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        04640000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                04660000
IOBCP    DS    CL8            FIRST CCW IN CHANNEL PROGRAM              04680000
         END                                                            04700000
