  TITLE  'IGG019KR-VRE READ/WRITE CHANNEL PROGRAM GENERATOR'            00200019
         COPY  LCGASMSW                                                 00250001
*                                                                       00300020
*                                                                       00400020
*        RELEASE 21 DELETIONS/CHANGES                                   00700020
*                                                               SA53251 00900021
*          RELEASE 20 DELETIONS                                         01200019
*D374200                                                         XM6363 01250001
*3574004000-006000,014000-025200,268000-270000                   20201  01300020
*                                                                       02600019
*                                                                       02650021
*        RELEASE 218 DELETIONS/CHANGES                                  02660021
*   THE FIX FOR SM0238 IS FLAGGED XM6363                         SM0238 02700021
*STATUS CHANGE LEVEL 004   DATE 7/2/74                                  02800021
*                                                                       03000019
*FUNCTION/OPERATION- THIS MODULE CONSTRUCTS A CHANNEL PROGRAM TO PER-   03200019
*   FORM A READ OR WRITE BY BLOCK ID OR BY BLOCK KEY FOR VRE.           03400019
*   THE CCW'S CONSTRUCTED OF CONSTANTS DEFINED IN THIS MODULE AND       03600019
*   ADDRESSES RESOLVED AT THE TIME THIS CODE IS EXECUTED.               03800019
*                                                                       04000019
*ENTRY POINT- ENTRY IS TO IGG019KR (BEGIN) FROM FOUNDATION MODULE       04200019
*   IGG019KJ BY THE CALLING SEQUENCE           L     EPREG,KEYMODAD     04300019
*                                              BR    EPREG              04400019
*                                 OR           L     EPREG,IDMODAD      04500019
*                                              BR    EPREG              04600019
*                                                                       04800019
*INPUT- THE REGISTERS ARE INPUT AS FOLLOWS,                             05000019
*   4- DCB ADDRESS                                                      05200019
*   5- DECB ADDRESS                                                     05400019
*   6- THE ADDRESS OF CCW 1 (CHANNEL PROGRAM START)                     05600019
*   7- IOB ADDRESS                                                      05800019
*  11- BASE ADDRESS OF MODULE IGG019KJ (FOUNDATION MODULE)              06000019
*                                                                       06200019
*OUTPUT- THE REQUIRED CCW'S WILL BE CONSTRUCTED FOLLOWING THE IOB.      06400019
*   REGISTER 6 WILL CONTAIN THE ADDRESS OF THE LAST CCW.                06600019
*                                                                       06800019
*EXTERNAL ROUTINE- CONTROL IS PASSED TO 'IGG019KW' IF EXTENDED SEARCH   07000019
*   IS SPECIFIED. IF THE REQUEST IS A WRITE AND THE WRITE VALIDITY      07200019
*   CHECK OPTION HAS BEEN SPECIFIED, 'IGG019KQ' IS ENTERED TO CONSTRUCT 07400019
*   THE VERIFY CCW'S.                                                   07600019
*                                                                       07800019
*EXITS- TO IGG019KJ BY       BR   RETREG  OR BY   BCR   8,RETREG        08000019
*       TO IGG019KQ BY       L    VERBASE,VERMODOF(NULL,FDNREG)         08200019
*                            BR   VERBASE                               08400019
*       TO IGG019KW BY       L    EPREG,DKEXSRAD                        08600019
*                            BR   EPREG                                 08800019
*                                                                       09000019
*TABLES/WORK AREAS- REFER TO THE DSECTS, BDAM OPTIONS AND TYPES AND     09200019
*   CONSTANTS AREA AT THE END OF THIS MODULE.                           09400019
*                                                                       09600019
*ATTRIBUTES- THIS MODULE IS REENTERANT AND EXECUTED ENABLED.            09800019
*                                                                       10000019
*NOTE- REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT WITH THE    10200019
*   MODULES IGG019KJ, IGG019KQ AND IGG019KW.                            10400019
*                                                                       10600019
*                                                                       10800019
IGG019KR CSECT                                                          11200019
*                                                                       11400019
*                                                                       11600019
*   REGISTER USAGE                                                      11800019
*                                                                       12000019
*                                                                       12200019
SCHREG   EQU   1                        REG FOR PARAMETER               12300019
SWAREG   EQU   2                        SEGMENT WORK AREA POINTER       12400019
DCBREG   EQU   4                        DCB ADDRESS                     12800019
DECBREG  EQU   5                        DECB ADDRESS                    13000019
CCWIND   EQU   6                        ADDRESS OF FIRST CCW            13200019
IOBREG   EQU   7                        IOB ADDRESS                     13400019
WKREG1   EQU   8                        GENERAL PURPOSE WORK REGISTER   13600019
WKREG2   EQU   9                        GENERAL PURPOSE WORK REGISTER   13800019
VERBASE  EQU   10                       BASE REG FOR IGG019KQ           14000019
LINKREG  EQU   10                 INTERNAL SUBROUTINE LINKAGE           14100001
FDNREG   EQU   11                       BASE FOR THE FOUNDATION MODULE  14200019
CCWPTR   EQU   12                       POINTER TO NEXT CCW INSTRUCTION 14400019
RETREG   EQU   14                       RETURN TO FOUNDATION MODULE     14600019
EPREG    EQU   15                       BASE REGISTER FOR THIS MODULE   14800019
*                                                                       15000019
*                                                                       15200019
         USING IHADCB,DCBREG            REG 4 IS THE BASE FOR THE DCB   15400019
         USING DECBDEF,DECBREG          REG 5 IS THE BASE FOR THE DECB  15600019
         USING IOBDEF,IOBREG            REG 7 IS THE BASE FOR THE IOB   15800019
         USING IGG019KR,EPREG           REG 15 IS THE BASE FOR THIS MOD 16000019
*                                                                       16200019
*                                                                       16400019
BEGIN    EQU   *                                                        16600019
         B     ENTRY                    BRANCH TO BEGINNING OF CODE     16800019
DKEXSRAD DS    F                        ADDRESS OF KEY-EXTENDED-SEARCH  17000019
*                                       MODULE--IGG019KW                17200019
*                                                                       17400019
ENTRY    EQU   *                                                        17600019
*                                                                       17800019
*                                                                       18000019
         LR    SWAREG,IOBREG            FETCH IOB ADDRESS               18200019
         SH    SWAREG,FOUR              PREPARE TO GO TO IOB-4          18400019
         L     SWAREG,NULL(SWAREG)      FETCH SWA ADDRESS               18600019
         LA    SWAREG,SEGAREOF(SWAREG)  ADDRESS OF SEGMENT AREA         18800019
         LR    CCWPTR,CCWIND            POINTER TO CCW1                 19000019
*                                                                       19200019
*                                                                       19400019
*                                                                       19600019
         MVC   IOBDNRCF+BYTE2(BYTE5),IOBSEEK+BYTE3    SAVE FEEDBACK ADR 19700019
         MVC   IOBDNRCF+BYTE7(BYTE1),IOBSEEK  SAVE EXTENT NUMBER        19710019
         TM    DECTYPE+BYTE1,NEXADIND   CHECK IF NEXT ADDRESS HAS BEEN  19800019
*                                       REQUESTED                       20000019
         BNO   CHEKTYPE                 BRANCH IF NO NEXT ADDR          20200019
         TM    DECTYPE+BYTE1,DITYPE     OTHERWISE CHECK IF TYPE=DI      20400019
         BO    CHEXSRCH                 BRANCH IF TYPE=DK               20600019
         LA    WKREG2,IOBUPLIM+BYTE3    FETCH SEARCH ADDRESS POINTER    20800019
         MVC   IOBUPLIM,IOBSEEK         INSERT TRK ADDR OF 1ST SEGMENT  20810019
         MVI   IOBUPLIM+BYTE7,NULL      POINT TO CAPACITY RECORD        20820019
         ST    WKREG2,ONECCW(CCWIND)    PUT IT IN CCW 2                 21000019
         LA    WKREG2,IOBDNRCF+BYTE2    OTHERWISE FETCH CAPACITY RCD AD 21200019
         LA    CCWIND,FORTHCCW(CCWIND)  GO TO CCW 4                     21400019
         ST    WKREG2,NULL(CCWIND)      PUT CAPACITY RECORD ADDR THERE  21600019
         LA    CCWIND,ONECCW(CCWIND)    SET CHANNEL COMMAND INDEX TO    21800019
*                                       CCW 5                           22000019
         B     CNSTRUCT                 BRANCH TO BUILD CCW 1 TO CCW 4  22200019
*                                                                       22400019
*                                                                       22600019
CHEXSRCH EQU   *                                                        22800019
*                                                                       23000019
*                                                                       23200019
         TM    IOBDTYPE,EXSRCH          CHECK IF EXTENDED SEARCH OPTION 23400019
*                                       HAS BEEN REQUESTED              23600019
         BO    CHEKTYPE                 BRANCH IF YES                   23800019
         LA    CCWPTR,NINTHCCW(CCWPTR)  OTHERWISE POINT TO CCW 9        24000019
         MVI   NULL(CCWPTR),NOP         MOVE IN NOP OP CODE             24200019
         MVC   BYTE4(BYTE4,CCWPTR),FCNT1     MOVE IN FLAGS AND COUNT    24400019
         LA    WKREG1,ONECCW            ONE CCW INSTRUCTION             24600019
         SR    CCWPTR,WKREG1            GO TO CCW 8                     24800019
         ST    SWAREG,NULL(CCWPTR)      MOVE IN SEGMENT ADDRESS         25000019
         LA    WKREG1,TWOCCW            LENGTH OF TWO CCW'S             25200019
         SR    CCWPTR,WKREG1            GO TO CCW 6                     25400019
         LA    WKREG1,IOBSEEK+BYTE3     FETCH SEARCH ADDRESS POINTER    25600019
         ST    WKREG1,NULL(CCWPTR)      PUT IT IN CCW 6                 25800019
         LA    CCWPTR,FIFTHCCW(CCWIND)  GO TO CCW 5                     26000019
*                                                                       26200019
*                                                                       26400019
CNSTRUCT EQU   *                                                        26600019
         CLI   IOBDCPND,SETSC           RCD READY USED           20201  26700020
         BNE   NOTRRA                   BRANCH IF NO             20201  26800020
         L     WKREG1,IOBDCPND          GET SECTOR ADDR          20201  26900020
         ST    WKREG1,NULL(CCWPTR)      PUT IN CCW               20201  27000020
         MVI   NULL(CCWPTR),SETSC       PUT IN SET SECTOR CMND   20201  27100020
         MVI   BYTE4(CCWPTR),CC         CMND CHAIN CCW           20201  27200020
         MVI   BYTE7(CCWPTR),BYTE1      SET BYTE COUNT TO ONE    20201  27300020
         B     FEATA                    GO AROUND NEXT           20201  27400020
NOTRRA   EQU   *                                                 20201  27500020
*                                                                       28500019
*                                                                       28600019
         MVI   NULL(CCWPTR),NOP         BUILD NO OP CCW                 28800019
         MVC   BYTE4(BYTE4,CCWPTR),NOPFCNT1   MOVE IN FLAGS AND COUNT   29000019
*                                             FOR NOP CCW               29200019
FEATA    EQU   *                                                 20201  29300020
         LA    CCWPTR,ONECCW(CCWPTR)    GO TO NEXT CCW                  29400019
         MVI   NULL(CCWPTR),SRCHIDEQ    MOVE IN SEARCH ID EQ OP-CODE    29600019
         MVI   BYTE4(CCWPTR),COMCHAIN   SET COMMAND CHAIN FLAG          29800019
         LA    WKREG1,NULL(CCWPTR)      FETCH SEARCH ID EQ CCW ADDRESS  30000019
         ST    WKREG1,ONECCW(CCWPTR)    STORE IT IN TIC CCW             30200019
         MVC   BYTE6(BYTE3,CCWPTR),COUNTTIC  MOVE IN COUNT=5 AND TIC    30400019
*                                            OP CODE FOR NEXT CCW       30600019
         LA    CCWPTR,TWOCCW(CCWPTR)    GO TO THE NEXT CCW              30800019
         MVI   NULL(CCWPTR),READDATA    MOVE IN READ-DATA OP-CODE       31000019
         MVC   BYTE4(BYTE4,CCWPTR),FCNT5   MOVE IN FLAGS AND COUNT=5    31200019
*                                                                       31400019
*                                                                       31600019
CHEKTYPE EQU   *                                                        31800019
*                                                                       32000019
*                                                                       32200019
         TM    DECTYPE+BYTE1,DITYPE     CHECK IF TYPE=DI                32400019
         BO    TYPEDK                   BRANCH IF TYPE=DK               32600019
         TM    DECTYPE+BYTE1,READ       CHECK IF READ HAS BEEN REQUEST- 32800019
*                                       ED                              33000019
         BO    READDI                   BRANCH IF YES                   33200019
         MVI   NULL(CCWIND),NOP         OTHERWISE BUILD NO OP CCW FOR   33400019
*                                       WRITE TYPE D1                   33600019
         MVC   BYTE4(BYTE4,CCWIND),NOPFCNT1   MOVE IN FLAGS AND COUNT   33800019
*                                             FOR NOP CCW               34000019
         LA    CCWIND,ONECCW(CCWIND)    INCREMENT TO NEXT CCW           34200019
         LR    SCHREG,CCWIND            SAVE SEARCH ID EQ CCW POINTER   34300019
*                                                                       34400019
*                                                                       34600019
READDI   EQU   *                                                        34800019
*                                                                       35000019
*                                                                       35200019
         LA    WKREG1,IOBSEEK+BYTE3     FETCH CCHHR ADDRESS             35400019
         ST    WKREG1,NULL(CCWIND)      PUT IT IN SEARCH ID EQ CCW      35600019
         MVI   NULL(CCWIND),SRCHIDEQ    MOVE IN SEARCH ID EQ OP-CODE    35800019
         LA    WKREG1,NULL(CCWIND)      FETCH SEARCH ID EQ CCW ADDRESS  36000019
         ST    WKREG1,ONECCW(CCWIND)    PUT SEARCH ID EQ CCW ADR IN TIC 36200019
         MVC   BYTE4(BYTE5,CCWIND),FLCNTIC  MOVE FLAGS,COUNT,TIC OPCODE 36400019
         LA    CCWIND,TWOCCW(CCWIND)    INCREMENT TO NEXT CCW           36600019
         TM    DECTYPE+BYTE1,READ       CHECK IF IT IS READ TYPE DI     36800019
         BNO   BUIWRDI                  BRANCH IF IT IS WRITE TYPE DI   37000019
         TM    DECTYPE,FEEDB            CHECK IF FEEDBACK IS REQUESTED  37003019
         BZ    AFTFEEDB                 BRANCH IF NOT REQUESTED         37006019
         TM    DCBOPTCD,FEEDB           CHECK IF RELATIVE FEEDBACK IS   37010019
*                                       REQUESTED                       37020019
         BO    AFTFEEDB                 BRANCH IF YES                   37030019
         L     WKREG1,DECRECPT          ELSE GET FEEDBACK ADDRESS       37040019
         MVC   NULL(BYTE8,WKREG1),IOBSEEK   SUPPLY ABSOLUTE FEEDBACK    37050019
*                                                                       37060019
*                                                                       37070019
AFTFEEDB EQU   *                                                        37080019
*                                                                       37090019
*                                                                       37100019
         CLI   DCBKEYLE,NULL            OTHERWISE CHECK FOR KEYED RCD   37200019
         BE    BUIRDATA                 BRANCH IF NOT KEYED RECORD      37400019
         TM    DECTYPE+BYTE1,SKEY      IS KEY TO BE READ INTO    XM6363 37420001
*                                      DYNAMIC BUFFER?                  37440021
         BNO   CHKEYAD                 NO, CHK IF ADDR IN DECB  SA53251 37460021
         B     READKEY                 YES, BUILD CHAN PGM FOR  SA53251 37480021
*                                      READING KEY AND DATA             37500021
CHKEYAD  EQU   *                                                SA53251 37520021
         L     WKREG1,DECKYADR          ELSE FETCH KEY ADDRESS          37600019
         LTR   WKREG1,WKREG1            CHECK IF DECKYADR=0             37800019
         BE    BUIRDATA                 BRANCH IF NO KEY ADDRESS        38000019
READKEY  EQU   *                                                SA53251 38100021
         MVI   NULL(CCWIND),READKYDA    MOVE IN READ KEY DATA OP-CODE   38200019
         MVC   BYTE1(BYTE3,CCWIND),DECKYADR+BYTE1  MOVE IN KEY ADDRESS  38400019
         MVI   BYTE4(CCWIND),DACHGAP    MOVE IN FLAGS FOR COMMAND CHAIN 38600019
*                                       BETWEEN GAPS OF A RECORD        38800019
         MVC   BYTE7(BYTE1,CCWIND),DCBKEYLE  MOVE KEY LENGTH AS COUNT   39000019
         LA    CCWIND,ONECCW(CCWIND)    INCREMENT TO NEXT CCW           39200019
*                                                                       39400019
*                                                                       39600019
BUIRDATA EQU   *                                                        39800019
*                                                                       40000019
*                                                                       40200019
         ST    SWAREG,NULL(CCWIND)      MOVE IN SEGMENT ADDRESS         40400019
         MVI   NULL(CCWIND),READDATA    MOVE IN READ-DATA OP CODE       40600019
         XC    BYTE4(BYTE2,CCWIND),BYTE4(CCWIND)      ZERO FLAG BYTES   40700019
         CLI   IOBSEEK+BYTE7,NULL       IS THIS A READ OF R0            40710019
         BNE   SETRDILN                 BR IF NO                        40720019
         TM    DECTYPE+BYTE1,NAS        IS IT NEXT ADDR AND 'S' FOR     40730019
*                                       BLOCK LENGTH                    40740019
         BNO   SETRDILN                 BR IF NO                        40750019
         MVC   DECLNGTH,CSCNT8+BYTE2    SET LENGTH TO 8                 40760019
SETRDILN EQU   *                                                        40770019
         AIF   ('&LIB' EQ 'LIB1').LIB1AA                                40773001
         BAL   LINKREG,CALCLNTH   DETERMINE WHETHER CCW COUNT IS        40776001
*                                 DECLNGTH OR SWA LENGTH.               40779001
         USING CCW,CCWIND                                               40782001
         STH   WKREG2,CCWCOUNT    SET LENGTH IN CCW                     40785001
         DROP  CCWIND                                                   40788001
         AGO   .LIB1AB                                                  40791001
.LIB1AA  ANOP                                                           40794001
         MVC   BYTE6(BYTE2,CCWIND),DECLNGTH  MOVE DATA LENGTH AS COUNT  40800019
.LIB1AB  ANOP                                                           40900001
         BR    RETREG                   RETURN CONTROL TO IGG019KJ      41000019
*                                                                       41200019
*                                                                       41400019
BUIWRDI  EQU   *                                                        41600019
*                                                                       41800019
*                                                                       42000019
         ST    SWAREG,NULL(CCWIND)      MOVE IN SEGMENT ADDRESS         42200019
         MVI   NULL(CCWIND),READDATA    MOVE IN READ-DATA OP CODE       42400019
         MVC   BYTE4(BYTE4,CCWIND),FCNT8     MOVE IN FLAGS AND COUNT    42600019
         CLI   DCBKEYLE,NULL            CHECK IF DCBKEYLE=0             42800019
         BE    VERIWRI                  BRANCH IF YES                   43000019
         L     WKREG1,DECKYADR          FETCH KEY ADDRESS               43200019
         LTR   WKREG1,WKREG1            CHECK IF DECKYADR=0             43400019
         BE    VERIWRI                  BRANCH IF YES                   43600019
         LA    CCWIND,ONECCW(CCWIND)    INCREMENT TO NEXT CCW           43800019
         ST    SWAREG,NULL(CCWIND)      MOVE IN SEGMENT ADDRESS         44000019
         MVI   NULL(CCWIND),WRITDATA    MOVE IN WRITE-DATA OP CODE      44200019
         MVC   BYTE6(BYTE2,CCWIND),DECLNGTH  MOVE DATA LENGTH AS COUNT  44400019
         B     VERIWRI                  GO TO CHECK WRITE-VALIDITY-     44600019
*                                       CHECK OPTION                    44800019
*                                                                       45000019
*                                                                       45200019
TYPEDK   EQU   *                                                        45400019
*                                                                       45600019
*                                                                       45800019
         ST    CCWIND,TWOCCW(CCWIND)    PUT CCW 1 ADDRESS IN TIC CCW    46000019
         LA    WKREG2,IOBDNRCF+BYTE2    ADDRESS OF CCHHR FOR FEEDBACK   46200019
         ST    WKREG2,NULL(CCWIND)      PUT IT IN READ-COUNT CCW        46400019
         MVI   NULL(CCWIND),READCNT     MOVE IN READ-COUNT OP CODE      46600019
         MVC   BYTE4(BYTE4,CCWIND),FCNT5     MOVE IN FLAGS AND COUNT    46800019
         MVC   ONECCW(BYTE4,CCWIND),DECKYADR PUT KEY ADDR IN NEXT CCW   47000019
         MVI   ONECCW(CCWIND),SRCHKYEQ  MOVE IN SEARCH KEY EQ OP CODE   47200019
         MVI   BYTE12(CCWIND),COMSUPLN  MOVE IN FLAGS                   47400019
         MVC   BYTE15(BYTE1,CCWIND),DCBKEYLE MOVE IN KEY LENGTH         47600019
         MVI   TWOCCW(CCWIND),TIC       MOVE IN TIC OP CODE             47800019
         ST    SWAREG,FORTHCCW(CCWIND)  MOVE IN SEGMENT ADDRESS         48000019
         MVI   FORTHCCW(CCWIND),READDATA    MOVE IN READ-DATA OP CODE   48200019
         TM    DECTYPE+BYTE1,READ       CHECK IF READ HAS BEEN REQUEST- 48400019
*                                       ED                              48600019
         BO    READDK                   BRANCH IF YES                   48800019
         MVC   BYTE28(BYTE4,CCWIND),CSCNT8  ELSE MOVE IN FLAGS, COUNT   49000019
*                                                                       49100020
         CLI   IOBDCPND,SETSC           RCD READY USED           20201  49200020
         BNE   NOTRRC                   BRANCH IF NO             20201  49300020
         L     WKREG1,IOBDCPND          GET BASIC SECTOR ADDR    20201  49400020
         LA    WKREG1,BYTE1(WKREG1)     INCR BY ONE              20201  49500020
         ST    WKREG1,BYTE32(CCWIND)    PUT IN CCW               20201  49600020
         MVI   BYTE32(CCWIND),RDSC      RD SECTOR CCW CMND       20201  49700020
         MVI   BYTE39(CCWIND),BYTE1     SET BYTE CNT TO ONE      20201  49800020
         B     FEATC                    GO AROUND NEXT           20201  49900020
NOTRRC   EQU   *                                                 20201  50000020
*                                                                       50100020
         MVI   BYTE32(CCWIND),NOP       CONSTRUCT NOP CCW               51200019
         MVC   BYTE36(BYTE4,CCWIND),FCNT1         MOVE IN FLAGS AND     51400019
*                                                 COUNT FOR NOP CCW     51600019
FEATC    EQU   *                                                 20201  51700020
         TM    IOBDTYPE,EXSRCH          CHECK IF EXTENDED SEARCH OPTION 51800019
*                                       HAS BEEN REQUESTED              52000019
         BO    DKEXSRCH                 BRANCH IF YES                   52200019
         LA    CCWIND,FIFTHCCW(CCWIND)  UPDATE CHANNEL COMMAND INDEX    52400019
*                                       TO THE LAST CCW                 52600019
*                                                                       52800019
*                                                                       53000019
VERIWRI  EQU   *                                                        53200019
*                                                                       53400019
*                                                                       53600019
         TM    IOBDTYPE,VERIFY          CHECK IF WRITE-VALIDITY-        53800019
*                                       CHECK HAS BEEN REQUESTED        54000019
         BCR   EIGHT,RETREG             IF NOT, CHANNEL PROGRAM ENDS    54200019
*                                       AND RETURN CONTROL TO IGG019KJ  54400019
         TM    DECTYPE+BYTE1,DITYPE     CHECK IF TYPE=DI                54406019
         BNO   TOVERMOD                 BRANCH IF TYPE=DI               54412019
         LA    WKREG1,IOBSEEK+BYTE3     FETCH SEARCH ADDRESS POINTER    54420019
         ST    WKREG1,ONECCW(CCWIND)    PUT IT IN NEXT CCW              54440019
         MVI   ONECCW(CCWIND),SRCHIDEQ  MOVE IN SEARCH ID EQ OP CODE    54460019
         MVC   BYTE12(BYTE4,CCWIND),CCCNT5  MOVE IN COMMAND CHAIN FLAGS 54480019
*                                           AND COUNT OF 5              54500019
         LA    SCHREG,ONECCW(CCWIND)    SAVE POINTER TO THIS CCW        54520019
*                                                                       54540019
TOVERMOD EQU   *                                                        54560019
*                                                                       54580019
*                                                                       54600019
         L     VERBASE,VERMODOF(NULL,FDNREG)  GET ADDRESS OF IGG019KQ   56600019
         BR    VERBASE                  GO TO IGG019KQ                  56800019
*                                                                       57000019
*                                                                       57200019
DKEXSRCH EQU   *                                                        57400019
*                                                                       57600019
*                                                                       57800019
         L     EPREG,DKEXSRAD           LOAD ADDRESS OF IGG019KW        58000019
         BR    EPREG                    GO TO KEY-EXTENDED-SEARCH MOD   58200019
*                                                                       58400019
*                                                                       58600019
READDK   EQU   *                                                        58800019
*                                                                       59000019
*                                                                       59200019
         AIF   ('&LIB' EQ 'LIB1').LIB1BA                                59220001
         BAL   LINKREG,CALCLNTH   DETERMINE WHETHER CCW COUNT IS        59240001
*                                 DECLNGTH OR SWA LENGTH.               59260001
         USING CCW,CCWIND                                               59280001
         STH   WKREG2,CCWCOUNT+FORTHCCW     SET LENGTH IN CCW.          59300001
         DROP  CCWIND                                                   59320001
         AGO   .LIB1BB                                                  59340001
.LIB1BA  ANOP                                                           59360001
         MVC   BYTE30(BYTE2,CCWIND),DECLNGTH MOVE DATA LENGTH AS COUNT  59400019
*                                            IN CCW4                    59600019
.LIB1BB  ANOP                                                           59700001
         TM    IOBDTYPE,EXSRCH          CHECK IF EXTENDED SEARCH HAS    59800019
*                                       BEEN REQUESTED                  60000019
         BO    DKEXSRCH                 BRANCH IF YES                   60200019
         TM    DECTYPE+BYTE1,NEXADIND   ELSE CHECK IF NEXT ADDRESS HAS  60400019
*                                       BEEN REQUESTED                  60600019
         BNO   UPDACCW                  BRANCH IF NO NEXT ADDRESS       60800019
         LA    CCWIND,NINTHCCW(CCWIND)  ELSE SET CHANNEL COMMAND INDEX  61000019
*                                       TO THE LAST CCW                 61200019
*                                                                       61400019
*                                                                       61600019
FINIS    EQU   *                                                        61800019
*                                                                       62000019
*                                                                       62200019
         BR    RETREG                   RETURN TO IGG019KJ              62400019
*                                                                       62600019
*                                                                       62800019
UPDACCW  EQU   *                                                        63000019
*                                                                       63200019
*                                                                       63400019
         LA    CCWIND,FORTHCCW(CCWIND)  SET CHANNEL COMMAND INDEX       63600019
*                                       TO THE LAST CCW                 63800019
         B     FINIS                    GO TO IGG019KJ                  64000019
*                                                                       64200019
         AIF   ('&LIB' EQ 'LIB1').LIB1CA                                64205001
*                                                                       64210001
*                  SUBROUTINE CALCLNTH DETERMINES THE COUNT-FIELD       64215001
*                  OF A READ-DATA CCW.  THIS IS THE SMALLER OF          64220001
*                  DECLNGTH AND TRACK LENGTH.                           64225001
*                                                                       64230001
*                  INPUT REG:  LINKREG -- RETURN ADDRESS                64235001
*                  OUTPUT REG:  WKREG2 -- COUNT                         64240001
*                               WKREG1 -- USED AS WORK REGISTER         64245001
*                                                                       64250001
CALCLNTH L     WKREG2,DCBDEBAD    GET DEB ADDR FROM DCB                 64255001
         USING DEBBASIC,WKREG2                                          64260001
         LA    WKREG2,DEBBASND    BUMP TO DIRECT ACCESS SECTION         64265001
         USING DEBDASD,WKREG2     DASD SECTION LOACTED HERE             64270001
         L     WKREG2,DEBUCBAD    GET UCB ADDRESS FROM DEB              64275001
         USING UCB,WKREG2                                               64280001
*                                                                       64285001
         LA    WKREG1,X'0F'       4 LOW-ORDER BITS OF WORD              64290001
         N     WKREG1,UCBTYP      PUT DEVICE CODE IN REG                64295001
*                                                                       64300001
         L     WKREG2,CVTPTR      GET CVT ADDRESS                       64305001
         USING CVT,WKREG2                                               64310001
         L     WKREG2,CVTZDTAB    GET DEVICE CHAR TABLE ADDR            64315001
         DROP  WKREG2                                                   64320001
         IC    WKREG1,0(WKREG1,WKREG2) DEVICE CODE SERVES AS            64325001
*                                 INDEX TO TABLE ENTRY DISP             64330001
         LH    WKREG2,TRKLNGTH(WKREG1,WKREG2)    TRACK LENGTH           64335001
*                                                                       64340001
         CH    WKREG2,DECLNGTH    IS TRACK SIZE GT RECORD LENGTH?       64345001
         BCR   12,LINKREG         RETURN IF NO; COUNT IS TRK SIZE       64350001
         LH    WKREG2,DECLNGTH    ELSE COUNT IS RECORD LENGTH           64355001
         BR    LINKREG            RETURN TO CALLER                      64360001
*                                                                       64365001
.LIB1CA  ANOP                                                           64370001
*                                                                       64400019
**********                                                   ********** 64600019
*                                                                       64800019
*              BDAM OPTIONS AND TYPES                                   65000019
*                                                                       65200019
**********                                                   ********** 65400019
*                                                                       65600019
*                                                                       65800019
VERIFY   EQU   X'80'                    MASK FOR WRITE-VALIDITY-CHECK   66000019
*                                       OPTION                          66200019
EXSRCH   EQU   X'20'                    MASK FOR EXTENDED SEARCH OPTION 66400019
DITYPE   EQU   X'04'                    MASK FOR BLOCK ID TYPE          66600019
READ     EQU   X'08'                    MASK FOR READ REQUEST           66800019
NEXADIND EQU   X'10'                    MASK FOR NEXT ADDRESS OPTION    67000019
NAS      EQU   X'50'                    MASK FOR NEXT ADDR AND          67010019
*                                       'S' CODED FOR BLOCK LENGTH      67020019
COMSUPLN EQU   X'60'                    COMMAND CHAIN AND SUPPRESS IN-  67200019
*                                       CORRECT LENGTH                  67400019
SETSC    EQU   X'23'                    SET SECTOR CCW CMND      20201  67460020
RDSC     EQU   X'22'                    RD SECTOR CCW CMND       20201  67520020
DACHGAP  EQU   X'C0'                    DATA CHAIN BETWEEN GAPS OF RCD  67600019
SRCHKYEQ EQU   X'29'                    SEARCH KEY EQ OP CODE           67800019
COMCHAIN EQU   X'40'                    DATA AND COMMAND CHAIN FLAGS    68000019
SRCHIDEQ EQU   X'31'                    SEARCH ID EQ OP CODE            68200019
READKYDA EQU   X'0E'                    READ KEY DATA OP CODE           68400019
READDATA EQU   X'06'                    READ DATA OP CODE               68600019
READCNT  EQU   X'12'                    READ COUNT OP CODE              68800019
WRITDATA EQU   X'05'                    WRITE DATA OP CODE              69000019
NOP      EQU   X'03'                    NOP OP CODE                     69200019
TIC      EQU   X'08'                    TRANSFER IN CHANNEL OP CODE     69400019
FEEDB    EQU   X'10'                    MASK FOR RELATIVE FEEDBACK      69500019
LO4BITS  EQU   X'0F'              USED TO LOAD REG WITH LO 4 BITS ON    69510001
TRKLNGTH EQU   4             DISP OF TRACK LENGTH FIELD IN DEVICE       69530001
*                            CHARACTERISTICS TABLE ENTRY                69560001
FLCNTIC  DC    X'4000000508'            COMMAND CHAIN FLAG, COUNT AND   69600019
*                                       OP CODE                         69800019
COUNTTIC DC    X'000508'                COUNT AND TIC OP CODE           70000019
FCNT5    DC    X'60000005'              COMMAND CHAIN AND SUPPRESS IN-  70200019
*                                       CORRECT LENGTH FLAGS AND COUNT  70400019
FCNT1    DC    X'20000001'              SUPPRESS INCORRECT LENGTH FLAGS 70600019
*                                       AND COUNT                       70800019
FCNT8    DC    X'20000008'              SUPPRESS INCORRECT LENGTH FLAGS 71000019
*                                       AND COUNT                       71200019
NOPFCNT1 DC    X'60000001'              COMMAND CHAIN AND SUPPRESS      71400019
*                                       INCORRECT LENGTH FLAGS AND      71600019
*                                       COUNT                           71800019
CSCNT8   DC    X'60000008'              COMMAND CHAIN AND SUPPRESS IN-  72000019
*                                       CORRECT LENGTH FLAGS AND        72200019
*                                       COUNT=8                         72400019
CCCNT5   DC    X'40000005'              COMMAND CHAIN FLAGS AND COUNT=5 72500019
*                                                                       72600019
*                                                                       72800019
*                                                                       73000019
**********                                                   ********** 73200019
*                                                                       73400019
*              CONSTANTS USED FOR DISPLACEMENT                          73600019
*                                                                       73800019
**********                                                   ********** 74000019
*                                                                       74200019
FOUR     DC    H'4'                     CONSTANT USED TO GO TO IOB-4    74400019
NULL     EQU   0                        NO DISPLACEMENT                 74600019
BYTE1    EQU   1                        ONE BYTE                        74800019
BYTE2    EQU   2                        TWO BYTES                       75000019
BYTE3    EQU   3                        THREE BYTES                     75200019
BYTE4    EQU   4                        FOUR BYTES                      75400019
BYTE5    EQU   5                        FIVE BYTES                      75600019
BYTE6    EQU   6                        SIX BYTES                       75800019
BYTE7    EQU   7                        SEVEN BYTES                     76000019
BYTE8    EQU   8                        EIGHT BYTES                     76100019
EIGHT    EQU   8                        ZERO CONDITION FOR TM           76130019
BYTE12   EQU   12                       TWELVE BYTES                    76200019
BYTE15   EQU   15                       FIFTEEN BYTES                   76600019
BYTE28   EQU   28                       TWENTY-EIGHT BYTES              76800019
BYTE30   EQU   30                       THIRTY BYTES                    77000019
BYTE32   EQU   32                       THIRTY-TWO BYTES                77200019
BYTE36   EQU   36                       THIRTY-SIX BYTES                77400019
BYTE39   EQU   39                       THIRTY-NINE BYTES        20201  77500020
ONECCW   EQU   8                        8 BYTES FOR LENGTH OF ONE CCW   77600019
TWOCCW   EQU   16                       LENGTH OF TWO CCW'S             77800019
FORTHCCW EQU   24                       LENGTH OF THREE CCW'S           78000019
FIFTHCCW EQU   32                       LENGTH OF FOUR CCW'S            78200019
NINTHCCW EQU   64                       LENGTH OF EIGHT CCW'S           78400019
CHPOFF   EQU   80                       OFFSET IN IOB TO CHP     20201  78450020
CC       EQU   X'40'                    CMND CHAIN FLAG          20201  78500020
SKEY     EQU   X'80'                   'S' CODED FOR KEY LENGTH SA53251 78550021
SEGAREOF EQU   10                       OFFSET TO ADDRESS OF SEGMENT    78600019
*                                       AREA IN SWA                     78800019
VERMODOF EQU   12                       OFFSET TO ADDRESS OF IGG019KQ   79000019
*                                       IN IGG019KJ                     79200019
         CNOP  0,8                      PAD MODULE TO DOUBLE WORD       79210019
*                                                                       79400019
*                                                                       79600019
*                                                                       79800019
*                                                                       80000019
*                                                                       80200019
*                                                                       80400019
*                                                                       80600019
*              DATA CONTROL BLOCK (DCB) DEFINITION                      80800019
*                                                                       81000019
*                                                                       81200019
*                                                                       81400019
         DCBD  DSORG=DA                                                 81600019
*                                                                       81800019
*                                                                       82000019
*                                                                       82200019
*                                                                       82400019
*                                                                       82600019
*                                                                       82800019
*              DATA EVENT CONTROL BLOCK (DECB) DEFINITION               83000019
*                                                                       83200019
*                                                                       83400019
*                                                                       83600019
         DS    0F                                                       83800019
DECBDEF  DSECT                                                          84000019
DECSDECB DS    CL4                      STANDARD ECB                    84200019
DECTYPE  DS    CL2                      TYPE OF I/O REQUEST AND OPTIONS 84400019
DECLNGTH DS    CL2                      DATA LENGTH                     84600019
DECDCBAD DS    CL4                      ADDRESS OF DCB                  84800019
DECAREA  DS    CL4                      ADDRESS OF DATA AREA            85000019
DECIOPT  DS    CL4                      ADDRESS OF THE IOB              85200019
DECKYADR DS    CL4                      ADDRESS OF KEY                  85400019
DECRECPT DS    CL4                      ADDRESS OF RECORD REFERENCE     85600019
*                                                                       85800019
*                                                                       86000019
*                                                                       86200019
*        I/O BLOCK (IOB) DEFINITION                                     86400019
*                                                                       86600019
*                                                                       86800019
*                                                                       87000019
*              STANDARD IOB                                             87200019
*                                                                       87400019
*                                                                       87600019
*                                                                       87800019
         DS    0F                                                       88000019
IOBDEF   DSECT                                                          88200019
IOBFLAG1 DS    CL1                      STATUS FLAG                     88400019
IOBFLAG2 DS    CL1                      ERROR FLAG                      88600019
IOBSENSE DS    CL2                      SENSE BYTES 0 AND 1             88800019
IOBECBPT DS    CL4                      ECB POINTER                     89000019
IOBCSW   DS    0CL8                     CHANNEL STATUS WORD             89200019
IOBCSWCA DS    0CL4                     COMMAND ADDRESS                 89400019
         DS    CL1                      IOS ERROR ROUTINE FLAG BYTE     89600019
         DS    CL3                      COMMAND ADDRESS                 89800019
IOBCSWST DS    CL2                      STATUS BYTES                    90000019
IOBCSWCT DS    CL2                      REMAINING COUNT                 90200019
IOBSTART DS    0CL4                     CHANNEL PROGRAM POINTER         90400019
IOBSIOCC DS    CL1                      SIO CONDITION CODE              90600019
         DS    CL3                      ADDRESS OF CHANNEL PROGRAM      90800019
IOBDCBPT DS    0CL4                     DCB POINTER                     91000019
IOBWGHT  DS    CL1                      CHANNEL WEIGHT                  91200019
         DS    CL3                      ADDRESS OF DCB                  91400019
IOBRESTR DS    0CL4                     RESTART POINTER                 91600019
         DS    CL1                      BYTE FOR I/O ERROR CORRECTION   91800019
         DS    CL3                      RESTART POINTER                 92000019
IOBINCAM DS    CL2                      BLOCK COUNT INCREMENT AMOUNT    92200019
IOBERRCT DS    CL2                      ERROR COUNTER                   92400019
IOBSEEK  DS    CL8                      SEEK ADDRESS                    92600019
*                                                                       92800019
*              BDAM EXTENDED IOB                                        93000019
*                                                                       93200019
IOBDBYTR DS    CL2                      BYTES REMAINING ON TRACK        93400019
IOBDIOBS DS    CL2                      SIZE OF THIS IOB                93600019
IOBDPLAD DS    0CL4                     IOB POOL LINK ADDRESS           93800019
IOBDAVLI DS    CL1                      IOB AVAILABILITY INDICATOR      94000019
         DS    CL3                      VARIOUS INDICATORS              94200019
IOBDTYPE DS    CL2                      TYPE FIELD                      94400019
IOBDSTAT DS    CL2                      IOB STATUS                      94600019
IOBDCPND DS    CL4                      CHANNEL PROGRAM NORMAL END ADDR 94800019
IOBDBYTN DS    CL2                      BYTES NEEDED BY NEW RECORD      95000019
         DS    CL2                      RESERVED                        95200019
IOBDQPTR DS    CL4                      LINK FIELD FOR QUEUED IOB'S     95400019
IOBUPLIM DS    CL8                      LIMIT MBBCCHHR FOR EXT SEARCH   95600019
IOBDNRCF DS    CL8                      COUNT FIELD FOR NEW RECORD      95800019
IOBCP    DS    CL200                    CHANNEL PROGRAM AREA            96000019
*                                                                       96200019
         SPACE 3                                                        96210001
CCW      DSECT               CHANNEL COMMAND WORD FORMAT                96220001
CCWOPCOD DS    C             OP-CODE                                    96230001
CCWADDR  DS    AL3           ADDRESS FOR DATA TRANSFER                  96240001
CCWFLAGS DS    BL1           FLAGS                                      96250001
         DS    X             UNUSED                                     96260001
CCWCOUNT DS    H             BYTES TO BE TRANSFERRED                    96270001
CVT      DSECT                                                          96280021
         CVT                                                            96285021
UCB      DSECT                                                          96290001
         IEFUCBOB                                                       96300001
         IEZDEB                                                         96310001
         END                                                            96400019
