         TITLE 'IGG019LC - BDAM END OF EXTENT APPENDAGE'                00020000
IGG019LC CSECT                                                          00040000
*7030024000-024200                                               M0174  00050021
*                                                                     * 00060000
*    CHANGE LEVEL 02  13OCT72                                         * 00070002
*                                                                     * 00080000
*FUNCTION/OPERATION- THIS MODULE CONTAINS THE BDAM END OF EXTENT IOS  * 00100000
*   APPENDAGE.THIS MODULE IS REQUIRED IF THE DCB SPECIFIES THAT THE   * 00120000
*   EXTENDED SEARCH OPTION IS DESIRED. THIS MODULE IS ENTERED BY IOS  * 00140000
*   WHEN IOS DETERMINES THAT A CHANNEL PROGRAM,IN THE COURSE OF A     * 00160000
*   SEARCH,IS ABOUT TO LEAVE THE CURRENT EXTENT.THIS MODULE IS ALSO   * 00180000
*   USED BY IGG019KY WHEN THE ADDRESS OF THE NEXT TRACK TO BE EXAMINED* 00200000
*   BY THE SELF-FORMAT ROUTINE IS NOT WITHIN THE CURRENT EXTENT.      * 00220000
*   THIS ROUTINE OBTAINS THE STARTING ADDRESS IN THE NEXT EXTENT ,AND * 00240000
*   CHECKS THIS ADDRESS TO DETERMINE IF IT IS WITHIN THE SEARCH       * 00260000
*   LIMITS.                                                           * 00280000
*                                                                     * 00300000
*ENTRY POINT- 'EEAENTRY' IS THE NORMAL ENTRY POINT FROM IOS WITH A    * 00320000
*   CALLING SEQUENCE,   L     15,0(APPENDAGE LIST)                    * 00340000
*                       BALR  14,15                                   * 00360000
*                                                                     * 00380000
*   'SFMENTRY' IS THE ENTRY POINT FROM THE SELF FORMAT MODULE WITH A  * 00400000
*   CALLING SEQUENCE,   L     15,0(APPENDAGE LIST)                    * 00420000
*                       L     12,RETURN ADDR                          * 00440000
*                       BC    15,4(15)                                * 00460000
*                                                                     * 00480000
*INPUT- TO 'EEAENTRY' THE FOLLOWING REGISTERS ARE USED AS POSITIONED  * 00500000
*   BY IOS,                                                           * 00520000
*   1- ADDRESS OF IOS QUEUING ELEMENT FOR THIS I/O REQUEST            * 00540000
*   2- ADDRESS OF THE IOB ASSOCIATED WITH THIS I/O REQUEST            * 00560000
*   3- ADDRESS OF THE DEB ASSOCIATED WITH THIS DATA SET               * 00580000
*   7- ADDRESS OF THE UCB ASSOCIATED WITH THE CURRENT EXTENT          * 00600000
*   14-RETURN (NORMAL) TO IOS                                         * 00620000
*   15-ENTRY POINT IN THIS MODULE                                     * 00640000
*                                                                     * 00660000
*   TO 'SFMENTRY' THE FOLLOWING REGISTERS ARE USED AS POSITIONED BY   * 00680000
*   'IGG019KY'                                                        * 00700000
*   1- ADDRESS OF THE IOB ASSOCIATED WITH THIS I/O REQUEST            * 00720000
*   12-RETURN TO SELF-FORMAT MODULE                                   * 00740000
*   14-ADDRESS  OF THE DEB ASSOCIATED WITH THIS DATA SET              * 00760000
*   15-ADDRESS OF THIS MODULE                                         * 00780000
*                                                                     * 00800000
*OUTPUT- IF THE LIMIT OF THE SEARCH HAS NOT BEEN REACHED THIS MODULE  * 00820000
*   CAUSES THE SEARCH TO BE RESTARTED AT THE START OF THE NEXT EXTENT.* 00840000
*   IF THE LIMIT HAS BEEN REACHED THE PROPER ERROR FLAG IS SET.       * 00860000
*                                                                     * 00880000
*EXTERNAL ROUTINES- N/A                                               * 00900000
*                                                                     * 00920000
*EXIT-NORMAL-'EXITA' IS THE POINT AT WHICH AN 'EXCP' IS GIVEN AND A   * 00940000
*   RETURN TO SUPERVISOR EFFECTED BY USE OF THE 'EXIT' SVC .          * 00960000
*   'CLRENTR1' IS A RETURN TO THE IOS IGNORE OFFSET WHICH CAUSES THE  * 00980000
*   ABNORMAL END APPENDAGE TO BE ENTRED.                              * 01000000
*   'EXITB' IS A RETURN TO THE IOS EXCP RETURN OFFSET                 * 01020000
*                                                                     * 01040000
*EXIT-ERROR- 'EXITC' IS A RETURN TO THE IOS IGNORE OFFSET WHICH CAUSES* 01060000
*   THE ABNORMAL END APPENDAGE TO BE ENTERED-THIS EXIT IS TAKEN IF THE* 01080000
*   SEARCH LIMIT IS REACHED AND THE REQUEST WAS NOT FOR A WRITE-ADD   * 01100000
*   'EXITD' IS A RETURN TO THE IOS IGNORE OFFSET-THIS EXIT IS TAKEN IF* 01120000
*   THE SEARCH LIMIT IS REACHED ON A WRITE ADD PRE-FORMAT REQUEST     * 01140000
*   'EXITE' IS A RETURN TO THE SELF FORMAT MODULE-THIS EXIT IS TAKEN  * 01160000
*   IF THE SEARCH LIMIT IS REACHED AND ENTRY WAS AT 'SFMENTRY'        * 01180000
*                                                                     * 01200000
*TABLES/WORK AREAS- N/A                                               * 01220000
*                                                                     * 01240000
*ATTRIBUTES- THIS ROUTINE IS EXECUTED DISABLED AND PRIVILEGED AND IS  * 01260000
*   REUSABLE.                                                         * 01280000
*                                                                     * 01300000
*NOTE- THIS ROUTINE RELIES ON THE REGISTER USAGE OF IOS.              * 01320000
*                                                                     * 01340000
*                                                                     * 01360000
*                                                                     * 01380000
*   REGISTER USAGE                                                    * 01400000
*                                                                     * 01420000
         USING IGG019LC,BASER                                           01440000
         USING IOBDEF,IOBR                                              01460000
         USING DEBDEF,DEBR                                              01480000
*                                                                     * 01500000
*                                                                     * 01520000
*   REGISTER EQUATES                                                  * 01540000
*                                                                     * 01560000
R12STAR  EQU   1                       TWELVE STAR ADDRESS              01580000
IOBR     EQU   2                       IOB ADDRESS                      01600000
DEBR     EQU   3                       DEB ADDRESS                      01620000
UCBR     EQU   7                       UCB ADDRESS                      01640000
INTDEBR  EQU   8                       SELF FORMAT DEB REGISTER         01660000
WRKR4    EQU   9                       WORKING REGISTER                 01680000
WRKR1    EQU   10                      WORKING REGISTER                 01700000
WRKR2    EQU   11                      WORKING REGISTER                 01720000
WRKR3    EQU   12                      WORKING REGISTER                 01740000
INTIOBR  EQU   12                      SELF FORMAT IOB ADDRESS          01760000
INTDCBR  EQU   13                      SELF FORMAT DCB REGISTER         01780000
RETNR    EQU   14                      RETURN TO IOS                    01800000
BASER    EQU   15                      BASE REGISTER  FOR THIS MODULE   01820000
DISPR    EQU   7                       OFFSET WHERE EXTENT     XA00088  01830002
*                                      IS SAVED FOR FEEDBACK   XA00088  01832002
*                                                                     * 01840000
*                                                                     * 01860000
*                                                                     * 01880000
EEAENTRY EQU   *                       END OF EXTENT APPENDAGE ENTRY    01900000
         B     TSTEXTNO                BRANCH TO MAIN FLOW              01920000
SFMENTRY EQU   *                       SELF-FORMAT MODULE ENTRY POINT   01940000
         LR    DEBR,INTDEBR            SET UP DEB REGISTER              01960000
         LR    IOBR,INTIOBR            SET UP IOB REGISTER              01980000
TSTEXTNO EQU   *                                                        02000000
         SR    WRKR3,WRKR3             CLEAR REGISTER AND               02020000
         IC    WRKR3,IOBSEEK           LOAD CURRENT EXTENT NUMBER       02040000
         LA    WRKR1,1(0,WRKR3)        ADJUST EXTENT NUMBER             02060000
         SR    WRKR2,WRKR2             CLEAR REGISTER                   02080000
         IC    WRKR2,DEBNMEXT          AND PICK UP NO. OF EXTENTS       02100000
         CR    WRKR1,WRKR2             IS THIS THE LAST EXTENT          02120000
         BNE   NEXTEXTT                NO-WORK WITH NEXT EXTENT         02140000
         SR    WRKR1,WRKR1             YES-USE FIRST EXTENT             02160000
NEXTEXTT EQU   *                                                        02180000
         STC   WRKR1,IOBSEEK           STORE NEW EXTENT NO IN IOBSEEK   02200000
         STC   WRKR1,IOBDNRCF+DISPR      AND IN FEEDBACK FIELD  XA00088 02210002
         SLL   WRKR1,4                 MULT EXTENT NO. BY 16            02220000
         LA    WRKR2,DEBDVMOD(WRKR1)   LOAD ADDRESS OF EXTENT           02240000
         USING DEBDVMOD,WRKR2                                    M0174  02250021
         MVC   IOBSEEK+1(6),4(WRKR2)   MOVE REST OF IOBSEEK FIELD       02260000
TSTUPLIM EQU   *                                                        02280000
         CLC   IOBUPLIM(1),IOBSEEK     IS LIMIT IN THIS EXTENT          02300000
         BE    MOVEZERO                YES-TAKE BRANCH                  02320000
TSTENTRY EQU   *                       NO-WAS ENTRY MADE FROM IOS       02340000
         CR    DEBR,INTDEBR            END OF EXTENT APPENDAGE          02360000
         BE    EXITA                   NO- TAKE BRANCH                  02380000
         L     WRKR3,DEBUCBAD     GET UCB ADDR FOR THIS EXTENT   M0174  02390021
         LA    WRKR3,0(WRKR3)     CLEAR HI-ORDER BYTE            M0174  02400021
         CR    UCBR,WRKR3         IS DEVICE SAME AS BEFORE?      M0174  02410021
         DROP  WRKR2                                             M0174  02420021
         BNE   NEWEXCP                 NO-TAKE BRANCH                   02440000
         MVC   UCBSEEK(8,UCBR),IOBSEEK YES-MOVE NEW SEEK ADDRESS TO UCB 02460000
EXITB    EQU   *                                                        02480000
         B     EXCPRETN(RETNR)         RETURN TO EXCP OFFSET            02500000
NEWEXCP  EQU   *                                                        02520000
         OI    IOBDSTAT,EXCPBIT        SET EXCP BIT IN DSTAT            02540000
CLRENTR1 EQU   *                                                        02560000
         BR    RETNR                   RETURN-THEN ENTER ABNL. END APP. 02580000
MOVEZERO EQU   *                                                        02600000
         MVI   IOBUPLIM+7,ZERO         ZERO R BYTE OF IOBUPLIM          02620000
         CLC   IOBUPLIM(8),IOBSEEK     DOES IOBSEEK EQUAL IOBUPLIM      02640000
         BNE   TSTENTRY                NO-TAKE BRANCH                   02660000
*                                      YES-CONTINUE                     02680000
         TM    IOBDTYPE+1,ADDBIT       IS THIS A WRITE ADD              02700000
         BO    NOSPACE                 YES-TAKE BRANCH                  02720000
         OI    IOBDSTAT+1,NOREC        NO-SET NO RECORD FOUND BIT       02740000
EXITC    EQU   *                                                        02760000
         BR    RETNR                   IN EXCEPTION CODE AND RETURN     02780000
NOSPACE  OI    IOBDSTAT+1,NOSPA        SET NO SPACE FOUND BIT IN        02800000
*                                      EXCEPTION CODE                   02820000
         CR    DEBR,INTDEBR            WAS ENTRY MADE FROM IOS END OF   02840000
*                                      EXTENT APPENDAGE                 02860000
EXITD    EQU   *                                                        02880000
         BCR   7,RETNR                 YES-RETURN                       02900000
         L     WRKR1,DCBDFOR(0,INTDCBR) NO-RESET THE BASE OF THE        02920000
*                                       SELF FORMAT MODULE              02940000
         LR    INTIOBR,IOBR            RESTORE THE IOB TO CORRECT REG   02960000
EXITE    EQU   *                                                        02980000
         B     4(0,RETNR)              AND RETURN TO IT                 03000000
EXITA    EQU   *                       SAVE THE CONTENTS OF             03020000
         L     WRKR1,DCBDFOR(0,INTDCBR) RESTORE SELF FORMAT BASE        03040000
         LR    INTIOBR,IOBR            RESTORE IOB ADDR TO CORRECT REG  03060000
         BR    RETNR                   ROUTINE AND RETURN TO IT         03080000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   03100000
         CNOP  0,8                     PAD TO DOUBLE WORD SIZE FOR TTR  03120000
*                                                                       03140000
*CONSTANT EQUATES                                                       03160000
*                                                                       03180000
ENTRY1   EQU   X'20'                   ENTRY 1 BIT MASK FOR DSTAT       03200000
EXTSN    EQU   16                      SIZE OF NORMAL EXTENT FOR D. A.  03220000
UCBSEEK  EQU   48                      SEEK ADDRESS OFFSET IN UCB       03240000
TYPCD    EQU   19                      DEVICE TYPE OFFSET IN UCB        03260000
EXCPRETN EQU   8                       OFFSET FOR EXCP RETURN           03280000
EXCPBIT  EQU   X'40'                   EXCP BIT MASK FOR DSTAT          03300000
ZERO     EQU   0                                                        03320000
ADDBIT   EQU   X'02'                                                    03340000
NOREC    EQU   X'80'                   NO RECORD FOUND EXCEPTION CODE   03360000
NOSPA    EQU   X'20'                   NO SPACE  FOUND EXCEPTION CODE   03380000
DCBDFOR  EQU   92                      OFFSET OF SELF-FORMAT MODULE     03400000
DCBDEBAD EQU   44                      OFFSET OF DEB ADDRESS IN DCB     03420000
DEVMASK  EQU   X'0F'                   MASK FOR ISOLATING DEVICE TYPE   03440000
FIRST    EQU   X'10'                   FIRST PASS BIT MASK FOR DSTAT    03460000
EXIT     EQU   3                       EXIT SVC                         03480000
         EJECT                                                          03500000
*      I/O BLOCK (IOB) DEFINITION                                       03520000
*                                                                       03540000
*              STANDARD IOB                                             03560000
IOBDEF   DSECT                                                          03580000
IOBFLAG1 DS    CL1            STATUS FLAG                               03600000
IOBFLAG2 DS    CL1            ERROR FLAG                                03620000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       03640000
IOBECBPT DS    CL4            ECB POINTER                               03660000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       03680000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           03700000
         DS    CL1                                                      03720000
         DS    CL3                                                      03740000
IOBCSWST DS    CL2            STATUS BYTES                              03760000
IOBCSWCT DS    CL2            REMAINING COUNT                           03780000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   03800000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        03820000
         DS    CL3                                                      03840000
IOBDCBPT DS    0CL4           DCB POINTER                               03860000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            03880000
         DS    CL3                                                      03900000
IOBRESTR DS    0CL4           RESTART POINTER                           03920000
         DS    CL1                                                      03940000
         DS    CL3                                                      03960000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              03980000
IOBERRCT DS    CL2            ERROR COUNTER                             04000000
IOBSEEK  DS    CL8            SEEK ADDRESS                              04020000
*        BDAM EXTENDED IOB                                              04040000
*                                                                       04060000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  04080000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          04100000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     04120000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                04140000
         DS    CL3                                                      04160000
IOBDTYPE DS    CL2            TYPE FIELD                                04180000
IOBDSTAT DS    CL2            IOB STATUS                                04200000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        04220000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                04240000
         DS    CL2                                                      04260000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               04280000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        04300000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                04320000
IOBCP    DS    CL256                   FIRST CCW IN CHANNEL PROGRAM     04340000
         EJECT                                                          04360000
*                                                                       04380000
*      DATA EXTENT BLOCK (DEB) DEFINITION                               04400000
*                                                                       04420000
DEBDEF   DSECT                                                          04440000
DEBNMSUB DS    0CL1      NO. OF SUBR. LOADED BY OPEN                    04460000
DEBTCBAD DS    CL4       ADDRESS OF THE TCB FOR THIS DEB                04480000
DEBAMLNG DS    0CL1      NO. OF BYTES IN THE ACCESS MTHD. DPDT. SECTION 04500000
DEBDEBAB DS    CL4       ADDRESS OF THE PREVIOUS DEB IN THE SAME TASK   04520000
DEBOFLGS DS    0CL1      DATA SET STATUS FLAGS                          04540000
DEBIRBAD DS    CL4       IRB ADDRESS                                    04560000
DEBOPATB DS    0CL1      TYPE OF FILES                                  04580000
DEBSYSPG DS    CL4       ADDRESS OF FIRST IOB IN THE SYSTEM PURGE CHAIN 04600000
DEBNMEXT DS    0CL1      NUMBER OF EXTENTS SPECIFIED IN THE DSCB        04620000
DEBUSRPG DS    CL4       ADDRESS OF FIRST IOB IN THE USER PURGE CHAIN   04640000
DEBPRIOR DS    0CL1      ALWAYS ZERO                                    04660000
DEBECBAD DS    CL4       ECB ADDRESS FOR SVC PURGE REQUEST              04680000
DEBPROTG DS    0CL1      RESERVED FOR FUTURE USE (FIRST 4 BITS)         04700000
DEBDEBID DS    0CL1      HEX 'F' TO IDENTIFY THIS BLOCK AS A DEB        04720000
DEBDCBAD DS    CL4       ADDRESS OF THE DCB ASSOCIATED WITH THIS DEB    04740000
DEBEXSCL DS    0CL1      EXTENT SCALE                                   04760000
DEBAPPAD DS    CL4       ADDRESS OF I/O APPENDAGE VECTOR TABLE          04780000
DEBDVMOD DS    0CL1      DEVICE MODIFIER FILE MASK                      04800000
DEBUCBAD DS    CL4       ADDR OF UCB ASSOCIATED WITH THIS DATA EXTENT   04820000
DEBBINUM DS    CL2       RESERVED FOR FUTURE USE-ALWAYS ZERO            04840000
DEBSTRCC DS    CL2       STARTING CYLINDER NUMBER FOR EXTENT            04860000
DEBSTRHH DS    CL2       STARTING HEAD NUMBER FOR EXTENT                04880000
DEBENDCC DS    CL2       ENDING CYLINDER NUMBER FOR EXTENT              04900000
DEBENDHH DS    CL2       ENDING HEAD NUMBER FOR EXTENT                  04920000
DEBNMTRK DS    CL2       NUMBER OF TRACKS ALLOCATED TO A GIVEN EXTENT   04940000
DEBSUBID EQU   0         SUBROUTINE ID'S                                04960000
         END                                                            04980000
