 TITLE 'IGG019LE -- DYNAMIC BUFFERING MODULE && START-I/O APPENDAGE'    00200021
         COPY  LCGASMSW                                                 00349901
*                                                                       00400021
IGG019LE CSECT                                                          00600021
         AIF   ('&LIB' NE 'LIB1').LIB1BA                                00610001
*                                                                       00650001
*                            RELEASE 23 DELETIONS                       00700001
*                                                                       00750001
*                            RELEASE 22 DELETIONS                       00800001
*                                                                       00850001
*                            RELEASE 21 DELETIONS                       00900001
*                                                                A44114 00950001
*D643500,697000                                                  XM3744 01000021
*         THE FIX FOR SM5482 IS FLAGGED XM3744                   SM5482 01010021
*0153                                                            M1780  01050001
*D694100                                                        YA02106 01060003
*  THE FIX FOR XA02394 IS FLAGGED YA02106                       XA02394 01070003
*STATUS CHANGE LEVEL 007    6/27/73                                     01100003
*                                                                       01150001
*THIS MODULE WAS TOTALLY REPLACED IN R-21 AS A RESULT OF A30797.  IT    01200001
*INCORPORATES IGG019KS WHICH NO LONGER EXISTS AS OF R-21.  TWO SEPARATE 01250001
*FUNCTIONS EXIST IN THE MODULE: SIO APPENDAGE FUNCTION AND FREEDBUF     01300001
*FUNCTION.  TWO SEPARATE FUNCTIONAL DESCRIPTIONS EXIST, ONE UNDER       01350001
*SIORTNE AND THE OTHER UNDER FBUFRTNE.  ALL EQUATES ARE IN 1ST ROUTINE. 01400001
*                                                                       01450001
*                                                                       01500001
.LIB1BA  ANOP                                                           01550001
         USING *,RAPDBASE                                               04200021
SIOEP    B     SIORTNE            START I/O APPENDAGE E.P.              04400021
         ORG   IGG019LE+8         SET F.D.BUFF. ENTRY POINT             04650001
FRBUFEP  B     FBUFRTNE           FREE DYNAMIC BUFFER SVC E.P.          04800021
*                                                                     * 05000021
* FUNCTION:                                                           * 05400021
*    THE START-I/O APPENDAGE ATTEMPTS TO ASSIGN A BUFFER TO A         * 05600021
*    READ REQUEST IF THE REQUEST SPECIFIES DYNAMIC BUFFERING AND      * 05800021
*    NO BUFFER WAS ASSIGNED BEFORE EXCP.  IF A BUFFER IS              * 06000021
*    AVAILABLE FOR ASSIGNMENT, IT IS REMOVED FROM THE BUFFER          * 06200021
*    POOL AND THE BUFFER CHAIN IS UPDATED.  THE BUFFER ADDRESS        * 06400021
*    IS PLACED IN THE REQUEST'S DECB AND IN THE READ CCWS OF THE      * 06600021
*    REQUEST'S CHANNEL PROGRAM.  THE ROUTINE THEN RETURNS TO IOS      * 06800021
*    TO INITIATE THE I/O.                                             * 07000021
*    IF NO BUFFER IS AVAILABLE THE REQUEST IS PLACED ON A QUEUE       * 07200021
*    OF REQUESTS WAITING FOR BUFFERS.  THE ROUTINE TAKES THE IOS      * 07400021
*    RETURN WHICH INDICATES THAT THE I/O REQUEST SHOULD NOT BE        * 07600021
*    INITIATED.                                                       * 07800021
*                                                                     * 08000021
* ENTRY POINT:                                                        * 08200021
*         SIOEP -- ENTERED ASYNCHRONOUSLY FROM IOS AT START-I/O       * 08400021
*         TIME.  THE ADDRESS OF IGG019LE IS PLACED IN THE             * 08600021
*         APPENDAGE VECTOR TABLE (AVT) DURING OPEN PROCESSING.        * 08800021
*         CALLING SEQUENCE -- L     15,4(AVTPTR)                      * 09000021
*                             BALR  14,15                             * 09200021
*                                                                     * 09400021
* INPUT                                                               * 09600021
*    **** REGISTER CONTENTS ****                                      * 09800021
*    REGISTER  2 -- INPUT/OUTPUT BLOCK (IOB) ADDRESS                  * 10000021
*    REGISTER  3 -- DATA EXTENT BLOCK (DEB) ADDRESS                   * 10200021
*    REGISTER  4 -- DATA CONTROL BLOCK (DCB) ADDRESS                  * 10400021
*    REGISTER  7 -- UNIT CONTROL BLOCK (UCB) ADDRESS                  * 10600021
*    REGISTER 14 -- RETURN ADDRESS                                    * 10800021
*    REGISTER 15 -- ADDRESS OF IGG019LE                               * 11000021
*                                                                     * 11200021
* OUTPUT                                                              * 11400021
*    **** REGISTER CONTENTS ****                                      * 11600021
*    ALL REGISTER CONTENTS ARE UNCHANGED EXCEPT AS FOLLOWS:           * 11800021
*    REGISTER  9 -- SET TO ZERO                                       * 12000021
*    REGISTER 10 -- USED AS A WORK REGISTER, NOT RESTORED             * 12200021
*    REGISTER 11 -- USED AS A WORK REGISTER, NOT RESTORED             * 12400021
*    REGISTER 13 -- USED AS A WORK REGISTER, NOT RESTORED             * 12600021
*                                                                     * 12800021
*    **** DATA AREAS SET BY THIS ROUTINE ****                         * 13000021
*    IOBDSTAT BIT IOBBUFF    SET IF A BUFFER IS ASSIGNED              * 13200021
*    IOBDQPTR FIELD OF IOB POINTED TO BY BCBFRQB,  OR                 * 13400021
*    BCBFRQT            UPDATED TO POINT TO THIS IOB IF REQUEST       * 13600021
*                       MUST WAIT FOR A BUFFER                        * 13800021
*    BCBFRQB            UPDATED TO POINT TO THIS IOB IF REQUEST       * 14000021
*                       MUST WAIT FOR A BUFFER                        * 14200021
*    BCBNABFR           UPDATED IF A BUFFER IS ASSIGNED.              * 14400021
*    DECAREA            DATA ADDR IN THE ASSIGNED BUFFER              * 14600021
*    DECKYADR           KEY ADDR IN THE ASSIGNED BUFFER FOR A READ    * 14800021
*                       BY BLOCK ID, & KEY ADDR SPECIFIED 'S'.        * 15000021
*    CCW3 ADDR          KEY ADDR,FOR NON-RPS CHANNEL PROGRAMS WHEN    * 15200021
*                       KEY IS IN DYNAMIC BUFFER (SEE DECKYADR).      * 15400021
*    CCW4 ADDR          KEY ADDR FOR RPS CHANNEL PROGRAMS, AS ABOVE   * 15600021
*    NEXT-TO-LAST CCW ADDR -- DATA ADDR FOR TRACK-OVERFLOW PROGRAMS   * 15800021
*    LAST CCW ADDR      DATA ADDR FOR NON-TRACK-OVERFLOW PROGRAMS     * 16000021
*                                                                     * 16200021
* EXITS                                                               * 16400021
*         0(R14)        RETURN TO IOS & START I/O                     * 16600021
*         4(R14)        RETURN TO IOS & DISREGARD I/O REQUEST         * 16800021
*                                                                     * 17000021
* ATTRIBUTES -- REUSABLE,PRIVILEGED,KEY=0,DISABLED                    * 17200021
*                                                                     * 17400021
         IEZBITS                                                        17600021
*                  REGISTER EQUATES                                     17800021
R0       EQU   0        INPUT REGISTER 0    SVC                         18000021
R1       EQU   1        INPUT REGISTER 1                                18200021
RIOB     EQU   2        ADDRESS OF IOB                                  18400021
RBASE3   EQU   3        BASE REGISTER       SVC                         18600021
RDCB     EQU   4        ADDRESS OF DCB                                  18800021
SVRBREG  EQU   5                        IOS BASE(SIO) OR SVRBPTR(SVC 57 18850001
RBUFFR   EQU   6        BUFFER ADDRESS                                  19200021
RDECB    EQU   7        DECB ADDRESS                                    19400021
RWORK9   EQU   9        WORK REGISTER                                   19600021
RWKAREA  EQU   10       ADDR OF SVRB EXTENDED SAVEAREA                  19800021
RWORK10  EQU   10       WORK REGISTER                                   20000021
RWORK11  EQU   11       WORK REGISTER                                   20200021
RWORK12  EQU   12       WORK REGISTER                                   20400021
RLINK    EQU   13       INTERNAL LINKAGE REGISTER                       20600021
RWORK13  EQU   13       WORK REGISTER                                   20800021
RRETURN  EQU   14       RETURN ADDRESS                                  21000021
RRETCODE EQU   15       RETURN CODE REGISTER                            21200021
RAPDBASE EQU   15       BASE REGISTER FOR APPENDAGE ROUTINES            21400021
         SPACE 5                                                        21600021
SETSECT  EQU   X'23'         CCW OP-CODE                                21800021
ALL      EQU   X'FF'                    ALL BITS ON                     21850001
PGMSTATE EQU   X'01'                    BIT INDICATING PGM STATE        21900001
KEY      EQU   X'F0'                    KEY FIELD                       21950001
KEYDATOP EQU   X'0E'         CCW OP-CODE  READ KEY & DATE               22600021
RDDATAOP EQU   X'06'         CCW OP-CODE  READ DATA                     22800021
SIORTNE  EQU   *                                                        22950001
*                                                                       23200021
         USING IOBSTDRD,RIOB                                            23400021
         USING IHADCB,RDCB                                              23600021
         TM    IOBDTYP2,IOBRQUST  IS THIS A READ REQUEST?               23800021
         BCR   8,RRETURN          IF NOT, RETURN TO IOS                 24000021
         TM    IOBDTYPE,IOBDYNBF  DOES REQUEST SPECIFY DYNAMIC          24200021
*                                 BUFFERING?                            24400021
         BCR   8,RRETURN          IF NO, RETURN TO IOS                  24600021
         TM    IOBSTAT1,IOBBUFF   HAS A BUFFER BEEN ASSIGNED TO         24800021
*                                 THIS REQUEST?                         25000021
         BCR   1,RRETURN          IF SO, RETURN TO IOS                  25200021
*                                                                       25400021
*                       IF A BUFFER IS AVAILABLE, ASSIGN IT TO          25600021
*                       THIS REQUEST AND UPDATE THE BUFFER POOL.        25800021
*                                                                       26000021
         L     RWORK10,DCBBUFCB   GET BUFFER CONTROL BLOCK ADDR         26200021
         USING BCBDEF,RWORK10                                           26400021
         L     RWORK11,BCBNABFR   GET ADDRESS OF NEXT AVAILABLE         26600021
*                                 BUFFER                                26800021
         LTR   RWORK11,RWORK11    IS ONE AVAILABLE?                     27000021
         BZ    PTONBUFQ           IF NOT BRANCH TO QUEUE REQUEST        27200021
         USING BUFFR,RWORK11                                            27400021
         L     RWORK13,BUFNXT     GET ADDR OF 2ND BUFFER (OR 0).        27600021
         DROP  RWORK11                                                  27800021
         ST    RWORK13,BCBNABFR   MAKE IT NEXT AVAILABLE                28000021
         BAL   RLINK,ASSGNBUF     ASSIGN BUFFER TO REQUEST              28200021
*                                                                       28400021
SIORET   SR    RWORK9,RWORK9      SET REG 9 TO ZERO                     28600021
         BR    RRETURN            RETURN TO IOS TO INITIATE             28800021
*                                 I/O REQUEST                           29000021
         SPACE 5                                                        29200021
PTONBUFQ EQU   *                                                        29400021
*                                                                       29600021
*                       NO BUFFER WAS AVAILABLE. PUT THIS IOB ON        29800021
*                       THE QUEUE WAITING FOR BUFFERS.                  30000021
*                                                                       30200021
         L     RWORK13,BCBFRQT    ADDR OF 1ST IOB ON QUEUE.             30400021
         LTR   RWORK13,RWORK13    IS THE QUEUE EMPTY?                   30600021
         BNZ   ONEONQ             BRANCH IF NOT                         30800021
         ST    RIOB,BCBFRQT       IF SO, STORE IOB ADDR AS FIRST        31000021
         B     BOTTOMST                                                 31200021
ONEONQ   L     RWORK13,BCBFRQB    GET ADDR OF LAST IOB ON QUEUE         31400021
         ST    RIOB,IOBDQPTR-IOBSTDRD(RWORK13)   POINT CHAIN TO         31600021
*                                                THIS IOB               31800021
BOTTOMST ST    RIOB,BCBFRQB       THIS IOB IS LAST ON QUEUE             32000021
         SR    RWORK9,RWORK9      ZERO REGISTER 9                       32200021
         B     4(RRETURN)         IOS RETURN - DON'T DO I/O             32400021
         DROP  RIOB                                                     32600021
         DROP  RDCB                                                     32800021
         EJECT                                                          33000021
*                                                                       33200021
*                  THIS SUBROUTINE IS USED BY THE START-I/O             33400021
*                  APPENDAGE AND THE FREE DYNAMIC BUFFER SVC            33600021
*                  ROUTINE.                                             33800021
*                  IT ASSIGNS A BUFFER TO AN I/O REQUEST BY             34000021
*                  PLACING THE BUFFER ADDRESS INTO THE DECB             34200021
*                  AND THE CHANNEL PROGRAM.                             34400021
*                                                                       34600021
*              REGISTER INPUT:  RIOB    - ADDR OF IOB TO WHICH          34800021
*                                    BUFFER WILL BE ASSIGNED            35000021
*                               RDCB    - DCB ADDRESS                   35200021
*                               RWORK11 - BUFFER ADDRESS                35400021
*                               RLINK   - RETURN ADDRESS                35600021
*              REGISTER OUTPUT: RWORK9  - WORK REGISTER                 35800021
*                               RWORK10 - WORK REGISTER                 36000021
*                               RWORK11 - WORK REGISTER                 36200021
         USING IHADCB,RDCB                                              36400021
         USING IOBSTDRD,RIOB                                            36600021
ASSGNBUF L     RWORK9,IOBECBPT    GET DECB ADDRESS                      36800021
         USING DECB,RWORK9                                              37000021
*                                 FOR A READ BY BLOCK ID, KEY           37200021
*                                 CODED 'S', THE KEY IS READ            37400021
*                                 INTO THE DYNAMIC BUFFER.              37600021
         TM    IOBDTYP2,IOBTYPE   IS THIS READ BY BLOCK ID?             37800021
         BO    FILLSCCW           BRANCH IF NO                          38000021
         TM    IOBDTYP2,IOBSKEY   WAS KEY ADDRESS CODED 'S'?            38200021
         BZ    FILLSCCW           BRANCH IF NO                          38400021
*                                 IN AN RPS PROGRAM CCW 3 READS         38600021
*                                 THE KEY; IN A NON-RPS PROGRAM,        38800021
*                                 CCW 4.                                39000021
         LA    RWORK10,IOBCHNPR+16     ADDR OF CCW 3                    39200021
         CLI   IOBCHNPR,SETSECT   TEST FOR RPS PROGRAM                  39400021
         BNE   NORPS              BRANCH IF NOT                         39600021
         LA    RWORK10,8(RWORK10) FOR RPS -- CCW 4                      39800021
*                                 PUT BUFFER ADDR OF KEY IN             40000021
*                                 CORRECT CCW & IN DECB                 40200021
NORPS    ST    RWORK11,0(RWORK10) PLACE ADDRESS IN READ KEY CCW         40400021
         MVI   0(RWORK10),KEYDATOP   RESTORE OP-CODE                    40600021
         ST    RWORK11,DECKYADR   PLACE KEY ADDRESS IN DECB             40800021
*                                 INCREMENT BUFFER POINTER              41000021
*                                 BEYOND KEY                            41200021
         SR    RWORK10,RWORK10                                          41400021
         IC    RWORK10,DCBKEYLE   GET KEY LENGTH                        41600021
         AR    RWORK11,RWORK10    BUMP BUFFER PTR BEYOND KEY            41800021
*                                 IN A NON-TRACK-OVERFLOW PGM           42000021
*                                 THE LAST CCW READS DATA; FOR          42200021
*                                 TRACK OVERFLOW, THE NEXT-TO-          42400021
*                                 LAST CCW                              42600021
FILLSCCW L     RWORK10,IOBDCPND   POINTS BEYOND LAST CCW                42800021
         SH    RWORK10,H8         ADDR OF LAST CCW                      43000021
         TM    DCBOPTCD,X'40'     TEST FOR TRACK OVERFLOW               43200001
         BZ    STADDR             BRANCH IF NO                          43400021
         SH    RWORK10,H8         ADDR OF NEXT-TO-LAST CCW              43600021
*                                                                       43800021
STADDR   ST    RWORK11,0(RWORK10) PUT DATA ADDR IN CCW                  44000021
         MVI   0(RWORK10),RDDATAOP     RESTORE READ DATA OP-CODE        44200021
         ST    RWORK11,DECAREA    PLACE DATA ADDRESS IN DECB            44400021
         OI    IOBDSTAT,IOBBUFF   SET BUFFER-ASSIGNED SWITCH            44600021
         BR    RLINK              RETURN TO CALLER                      44800021
         DROP  RWORK9                                                   45000021
         DROP  RIOB                                                     45200021
         DROP  RDCB                                                     45400021
         EJECT                                                          45600021
FBUFRTNE EQU   *                                                        45800021
*                                                                     * 46000021
* FUNCTION:                                                           * 46200021
*    THE FREE DYNAMIC BUFFER ROUTINE RELEASES A DYNAMIC BUFFER.       * 46400021
*    IF ANY IOBS ARE ON THE UNSCHEDULED QUEUE (WAITING FOR A          * 46600021
*    BUFFER) THE ROUTINE ASSIGNS THE BUFFER TO THE FIRST IOB ON       * 46800021
*    THE QUEUE, AND ISSUES AN EXCP FOR THAT IOB.  IF NO IOBS ARE      * 47000021
*    ON THE UNSCHEDULED QUEUE THE ROUTINE PLACES THE BUFFER ON        * 47200021
*    THE CHAIN OF AVAILABLE BUFFERS.                                  * 47400021
*                                                                     * 47600021
* ENTRY POINT:                                                        * 47800021
*         FRBUFEP -- ENTERED FROM MODULE IGC0005G WHEN SVC 57 IS      * 48000021
*         ISSUED FOR A DCB WHICH SPECIFIED DIRECT ORGANIZATION.       * 48200021
*         CALLING SEQUENCE -- L    15,DCBDEBAD                        * 48400021
*                             L    15,DEBAPPAD                        * 48600021
*                             L    15,4(15)                           * 48800021
*                             BAL  14,8(15)                           * 49000021
*                                                                     * 49200021
* INPUT                                                               * 49400021
*    **** REGISTER CONTENTS ****                                      * 49600021
*    REGISTER  0 -- DECB ADDRESS                                      * 49800021
*    REGISTER  1 -- DCB ADDRESS                                       * 50000021
*    REGISTER 10 -- ADDRESS OF SVRB EXTENDED SAVEAREA                 * 50200021
*    REGISTER 14 -- RETURN ADDRESS                                    * 50400021
*    REGISTER 15 -- ADDRESS OF IGG019LE                               * 50600021
*                                                                     * 50800021
* OUTPUT                                                              * 51000021
*    **** REGISTER CONTENTS ****                                      * 51200021
*    ALL REGISTERS EXCEPT REGISTER 14 CAN BE USED WITHOUT SAVING      * 51400021
*    OR RESTORING CONTENTS.                                           * 51600021
*    REGISTER 15 CONTAINS RETURN CODE.                                * 51800021
*                                                                     * 52000021
*    **** DATA FIELDS SET BY THIS ROUTINE ****                        * 52200021
*    BCBFRQT       IF AN IOB IS WAITING FOR A BUFFER, PTR TO 1ST      * 52400021
*                  IOB ON QUEUE IS UPDATED.                           * 52600021
*    IOBDQPTR      FIELD IN DEQUEUED IOB IS CLEARED                   * 52800021
*    THE BUFFER ADDRESS IS PLACED IN THE CHANNEL PROGRAM AND DECB     * 53000021
*    FIELDS (SEE SIORTNE DESCRIPTION FOR DETAILS).                    * 53200021
*    BCBNABFR      IF THE BUFFER IS NOT ASSIGNED TO A REQUEST,        * 53400021
*                  ITS ADDRESS IS PLACED IN BCBNABFR                  * 53600021
*    BUFNXT        FIELD OF THE RELEASED BUFFER IS SET TO THE         * 53800021
*                  ADDR OF THE 2ND AVAILABLE BUFFER.                  * 54000021
*                                                                     * 54200021
* EXTERNAL REFERENCES                                                 * 54400021
*        EXCP CALL TO IOS                                             * 54600021
*                                                                       54800021
* EXITS, NORMAL                                                       * 55000021
*    BRANCH RETURN TO IGC0005G ON REGISTER 14.  RETURN CODE (R15)     * 55200021
*    = 0.                                                             * 55400021
*                                                                     * 55600021
* TABLES / WORK AREAS                                                 * 55800021
*        IOB, DCB, DECB, BUFFER CONTROL BLOCK                         * 56000021
*                                                                     * 56200021
* ATTRIBUTES -- REENTRANT, READONLY, PREVILEGED, KEY=0                * 56400021
*                                                                     * 56600021
* NOTES -- THE ROUTINE MUST DISABLE TO UPDATE THE SERIALLY            * 56800021
*        REUSABLE IOB AND BUFFER QUEUES.                              * 57000021
*                                                                     * 57200021
         EJECT                                                          57400021
         LR    RBASE3,RAPDBASE    ESTABLISH BASE REGISTER               57600021
         USING IGG019LE,RBASE3                                          57800021
         DROP  RAPDBASE                                                 58000021
         LR    RDCB,R1            TRANSFER DCB ADDRESS                  58200021
         USING IHADCB,RDCB                                              58400021
         LR    RDECB,R0           TRANSFER DECB ADDRESS                 58600021
         USING DECB,RDECB                                               58800021
*                                                                       59000021
*                       LOCATE THE BEGINNING ADDRESS OF THE             59200021
*                       BUFFER BEING FREED.                             59400021
*                                                                       59600021
         L     RBUFFR,DECAREA     ASSUME BUFFER ADDR = DATA ADDR        59800021
         TM    DECTYPE2,DECKEYS   WAS KEY IN BUFFER (CODED 'S')?        60000021
         BZ    FBU0500            BRANCH NO                             60200021
         L     RBUFFR,DECKYADR    BUFFER ADDR = KEY ADDR                60400021
FBU0500  EQU   *                                                        60600021
         L     RWORK12,DCBBUFCB   BUFFER CONTROL BLOCK ADDR             60800021
         USING BCBDEF,RWORK12                                           61000021
         AIF   ('&LIB' EQ 'LIB1').LIB1AA                                61050001
         MODESET MF=(E,DISABLE)   DISABLE IN ORDER TO UPDATE QS         61100001
         AGO   .LIB1AB                                                  61150001
.LIB1AA  ANOP                                                           61160001
         SSM   NOINTRP            DISABLE IN ORDER TO UPDATE QS         61200021
.LIB1AB  ANOP                                                           61250001
         L     RIOB,BCBFRQT       ADDR OF FIRST IOB QUEUED              61400021
         LTR   RIOB,RIOB          ARE THERE ANY IOBS?                   61600021
         BZ    MAKEAVAL           IF NOT, GO MAKE THIS BUFFER           61800021
*                                 AVAILABLE                             62000021
*                                                                       62200021
*                       UPDATE QUEUE BY REMOVING FIRST IOB              62400021
*                                                                       62600021
         USING IOBSTDRD,RIOB                                            62800021
CHAIN    L     RWORK9,IOBDQPTR    GET ADDRESS OF NEXT IOB AND           63000021
         ST    RWORK9,BCBFRQT     MAKE IT THE NEXT IOB ON QUEUE         63200021
         XC    IOBDQPTR,IOBDQPTR  CLEAR QUEUING FIELD                   63400021
         AIF   ('&LIB' EQ 'LIB1').LIB1AC                                63450001
         MODESET MF=(E,ENABLE)    ENABLE INTERRUPTS                     63500001
         AGO   .LIB1AD                                                  63550001
.LIB1AC  ANOP                                                           63560001
         SSM   INTRPTOK           ENABLE INTERRUPTS                     63600021
.LIB1AD  ANOP                                                           63650001
         LR    RWORK11,RBUFFR     PUT BUFFER ADDR IN R11                63800021
         LR    RAPDBASE,RBASE3    RESTORE BASE FOR SUBRTN        XM6073 63850021
         BAL   RLINK,ASSGNBUF     ASSIGN THE BUFFER TO THE              64000021
*                                 DEQUEUED IOB.                         64200021
         AIF    ('&LIB' NE 'LIB1').LIB1BB                               64250001
         USING PSW,RWKAREA              SET UP PSW BASE PTR      A44114 64400001
         USING RBSECT,SVRBREG           SET UP BASE FOR SVRB     A44114 64450001
         LA    RWKAREA,RBEXSAVE         RESTORE EX SAVE PTR      M1780  64500001
         MVC   FULLPSW,RBOPSW           MV USER'S PSW FROM SVRB  A44114 64550001
*                                       FOR FREEDBUF TO EXTENDED SAVE   64600001
         LA    RRETCODE,LPSWBR1         LOAD RET ADDR FROM LPSW  A44114 64650001
         ST    RRETCODE,INSTADDR        ST RET ADDR IN 1ST COPY  A44114 64700001
*                                       OF PSW TO BE USED               64750001
         NI    KEYAMWP,ALL-PGMSTATE     PUT 1ST COPY OF PSW IN   A44114 64800001
*                                       SUPERVISOR STATE,USER KEY       64850001
         USING PSW-PSWLG,RWKAREA        APPLY PSW DSECT TO NEXT  A44114 64900001
*                                       8 BYTES WITHOUT CHANGING BASE   64950001
*                                       PTR, ONLY ITS APPLICABILITY 8   65000001
*                                       BYTES BEYOND ITS ADDRESS        65050001
         MVC   FULLPSW,RBOPSW           MV 2ND COPY OF           A44114 65100001
*                                       USER'S PSW TO EXTENDED SAVE     65150001
         LA    RRETCODE,LPSWBR2         LOAD RET ADDRESS FROM    A44114 65200001
*                                       EXECUTION OF 2ND LPSW           65250001
         ST    RRETCODE,INSTADDR        ST ADDR IN 2ND PSW       A44114 65300001
         NI    KEYAMWP,ALL-KEY-PGMSTATE SET UP FOR SUPER STATE,  A44114 65350001
*                                       KEY 0                           65400001
         LPSW  RBEXSAVE                 CHANGE TO USER KEY, SUPE A44114 65450001
*                                       STATE SO THAT IOS WILL PERFORM  65500001
*                                       VALIDITY CHECK ON DEB & BUFFERS 65550001
LPSWBR1  EQU   *                                                 A44114 65600001
.LIB1BB  ANOP                                                           65650001
         MVC   IOBDQPTR+1(3),IOBECBPT+1  SAVE ECB POINTER       YA02106 65660003
         LA    R1,IOBCSW+3              ADDR OF RIGHT HALF CSW   XM3774 65700021
         ST    R1,IOBECBPT              USE AS TEMPORARY ECB     XM3744 65750021
         EXCP  (RIOB)                   SCHEDULE I/O FOR NEXT IOB ON Q  69400021
         AIF   ('&LIB' NE 'LIB1').LIB1BC                                69450001
         LPSW  PSW                      RETURN TO SUPER STATE,   A44114 69500001
*                                       KEY 0                           69550001
         DROP  RWKAREA                                                  69600001
LPSWBR2  EQU   *                                                 A44114 69650001
.LIB1BC  ANOP                                                           69660001
         SR    RRETCODE,RRETCODE  NORMAL COMPLETION                     70600021
         BR    RRETURN            RETURN TO IGC0005G                    70800021
*                                                                       71000021
         SPACE 5                                                        71200021
*                                                                       71400021
*                       NO IOBS ARE WAITING FOR BUFFERS. RETURN         71600021
*                       BUFFER TO THE AVAILABLE CHAIN.                  71800021
*                                                                       72000021
MAKEAVAL EQU   *                                                        72200021
         L     RWORK9,BCBNABFR    GET ADDR OF AVAILABLE BUFFER          72400021
         USING BUFFR,RBUFFR                                             72600021
         ST    RWORK9,BUFNXT      POINT THIS BUFFER TO IT               72800021
         ST    RBUFFR,BCBNABFR    MAKE THIS ONE NEXT AVAILABE           73000021
         DROP  RBUFFR              (LIFO QUEUE)                         73200021
         AIF   ('&LIB' EQ 'LIB1').LIB1AE                                73250001
         MODESET MF=(E,ENABLE)    ENABLE FOR INTERRUPTS                 73300001
         AGO   .LIB1AF                                                  73350001
.LIB1AE  ANOP                                                           73360001
         SSM   INTRPTOK           ENABLE FOR INTERRUPTS                 73400021
.LIB1AF  ANOP                                                           73450001
*                                                                       73600021
         SR    RRETCODE,RRETCODE  RETURN CODE = 0.                      73800021
         BR    RRETURN            RETURN TO IGC0005G.                   74000021
*                                                                       74200021
H8       DC    H'8'               HALFWORD  VALUE = 8                   74450001
         AIF   ('&LIB' EQ 'LIB2').LIB1JA                                74500001
NOINTRP  DC    X'00'              CONSTANT FOR DISABLING SYSTEM         74510001
INTRPTOK DC    X'FF'              CONSTANT FOR ENABLING SYSTEM          74520001
         AGO   .LIB1JB                                                  74550001
.LIB1JA  ANOP                                                           74560001
         DS    0F                 ALIGN LISTS                           74570001
*                                                                       74580001
ENABLE   MODESET ENABLE=YES,MF=L                                        74590001
*                                                                       74592001
DISABLE  MODESET ENABLE=NO,MF=L                                         74594001
*                                                                       74596001
.LIB1JB  ANOP                                                           74598001
         CNOP  0,8           INSURE MODULE SIZE IS MULTIPLE OF 8        75200021
         EJECT                                                          75400021
         IEZIOB                                                         75600021
CCW1     DS    D                        CCW # 1                         75650001
CCW2     DS    D                        CCW # 2                         75700001
CCW3     DS    D                        CCW # 3                         75750001
*                                                                       75800021
         DCBD  DSORG=DA                                                 76000001
*                                                                       76200021
         IHADECB                                                        76400021
*                                                                       76600021
BCBDEF   DSECT                                                          76800021
BCBFRQT  DS    A        ADDR OF FIRST IOB WAITING FOR A BUFFER          77000021
BCBFRQB  DS    A        ADDR OF LAST IOB WAITING FOR A BUFFER           77200021
BCBNABFR DS    A        ADDR OF THE NEXT BUFFER AVAILABLE               77400021
BCBTBRS  DS    F        SIZE OF BCB & BUFFER POOL IN BYTES              77600021
*                                                                       77800021
BUFFR    DSECT                                                          78000021
BUFNXT   DS    A        ADDR OF NEXT BUFFER ON AVAILABLE CHAIN          78200021
*                                                                       78400021
         AIF   ('&LIB' NE 'LIB1').LIB1BD                                78450001
PSW      DSECT                          PROGRAM STATUS WORD FORMAT      78500001
         DS    0F                                                       78550001
FULLPSW  DS    0CL8                                                     78600001
SYSMASK  DS    BL1                      SYSTEM MASK                     78650001
KEYAMWP  DS    XL1                      KEY AND STATE OF USER           78700001
INTERUPT DS    H                        INTERRUPT CODE                  78750001
INSTADDR DS    A                        ADDR OF NEXT INSTRUCTION        78800001
PSWLG    EQU   *-PSW                    LENGTH OF PSW                   78850001
         EJECT                                                          78900001
         IKJRB                                                          78950001
.LIB1BD  ANOP                                                           79000001
         END                                                            80600021
