         TITLE 'IGG019LG - BDAM READ EXCLUSIVE MODULE'                  00030000
IGG019LG CSECT                                                          00060000
*          RELEASE 14 DELETIONS                                       * 00063000
*          RELEASE 15 DELETIONS                                       * 00066000
*7030                                                             12728 00067015
*          RELEASE 16 DELETIONS                                       * 00069000
*3170                                                             14231 00070016
*          RELEASE 17 DELETIONS                                       * 00072000
*1082065000                                                       18527 00073000
*1082001070                                                       MC0H  00074000
*          RELEASE 18 DELETIONS                                       * 00075000
*          RELEASE 19 DELETIONS                                       * 00078000
*          RELEASE 20 DELETIONS                                       * 00081000
*          RELEASE 21 DELETIONS                                       * 00084000
*2751009000,020000-023200,039600,040600,078000-078600,079000-    A35339 00084321
*2751079200,080000-080400,081400,082000-083600,085600-085800     A35339 00084621
*2751041000,041400                                               A39071 00085021
*D041300,041400                                                 YA02106 00085403
*  THE FIX FOR XA02394 IS FLAGGED YA02106                       XA02394 00085803
*D023420-023540,076200-077000                                   SA69157 00086221
*        THE FIX FOR XA04418 IS FLAGGED SA68925                 XA04418 00086321
*        THE FIX FOR OY03417 IS FLAGGED SA68925                 OY03417 00086421
*C034000                                                        SA68925 00086621
*                                                               SA69490 00086721
*        THE FIX FOR OY03664 IS FLAGGED SA69490                 OY03664 00086821
*        THE FIX FOR OX04510 IS FLAGGED SA69490                 OX04510 00086921
*A039900                                                        SA69490 00093621
*          RELEASE 22 DELETIONS                                       * 00100321
*STATUS CHANGE LEVEL 007    10/26/73                                    00107021
*FUNCTIONS/OPERATION- THIS MODULE CONTAINS THREE ROUTINES WHOSE       * 00140000
*   FUNCTIONS ARE,                                                    * 00160000
*   1.ON THE COMPLETION OF A READ EXCLUSIVE REQUEST CHECK THE         * 00180000
*    EXCLUSIVE LIST TO DETERMINE IF THIS BLOCK IS IN EXCLUSIVE STATUS.* 00200000
*    IF THE BLOCK IS NOT IN EXCLUSIVE STATUS,THE ACTUAL ADDRESS OF THE* 00220000
*    BLOCK IS ENTERED IN THE LIST AND CONTROL IS RETURNED TO THE ASI  * 00240000
*    ROUTINE FOR POSTING.                                             * 00260000
*    IF THE BLOCK IS IN EXCLUSIVE STATUS,THE IOB IS PUT ON THE        * 00280000
*    UNPOSTED QUEUE OF THE DCB AND CONTROL IS RETURNED TO THE SYSTEM. * 00300000
*                                                                     * 00320000
*   2.ON COMPLETION OF A WRITE REQUEST WHICH IS RELEASING A BLOCK FROM* 00340000
*    EXCLUSIVE STATUS,THE ENTRY IN THE LIST IS REMOVED AND A SEARCH OF* 00360000
*    THE UNPOSTED QUEUE IS MADE FOR A REQUEST OF THE SAME BLOCK BEING * 00380000
*    RELEASED. IF A REQUEST IS FOUND,IT IS REMOVED FROM THE UNPOSTED  * 00400000
*    QUEUE,ENTERED IN THE EXCLUSIVE LIST AND IS POSTED AS COMPLETE.   * 00420000
*    PROCESSING THEN CONTINUES AS IF A REQUEST WAS NOT FOUND ON THE   * 00440000
*    UNPOSTED QUEUE.                                                  * 00460000
*    IF A REQUEST IS NOT FOUND ON THE UNPOSTED QUEUE,THE UNSCHEDULED  * 00480000
*    QUEUE IS CHECKED FOR A REQUEST THAT WAS QUEUED BY THE START I/O  * 00500000
*    MODULE BECAUSE THERE WAS NOT AN AVAILABLE ENTRY IN THE READ      * 00520000
*    EXCLUSIVE LIST. IF A REQUEST IS FOUND IT IS TAKEN OFF THE        * 00540000
*    UNSCHEDULED QUEUE AND IS SCHEDULED VIA EXCP.                     * 00560000
*    IF A REQUEST IS NOT FOUND THE COUNT,OF AVAILABLE READ EXCLUSIVE  * 00580000
*    ENTRIES,IN THE DCB IS INCREMENTED BY ONE.                        * 00600000
*    CONTROL IS THEN RETURNED TO THE ASI ROUTINE TO COMPLETE THE      * 00620000
*    PROCESSING OF THE WRITE REQUEST.                                 * 00640000
*                                                                     * 00660000
*   3.THIS MODULE IS ALSO ENTERED BY THE RELEX SVC ROUTINE. THE       * 00680000
*    FUNCTION PERFORMED IS THE SAME AS FOR A WRITE REQUEST EXCEPT THAT* 00700000
*    CONTROL IS RETURNED TO THE SVC ROUTINE.                          * 00720000
*    THE LINKAGE FROM THE SVC ROUTINE IS VIA A SYNCH MACRO, AND RETURN* 00726021
*    MUST BE MADE ON REGISTER 14.                                     * 00732021
*                                                                     * 00740000
*                                                                     * 00760000
*ENTRY POINT- ENTRY IS TO 'IGG019LG' (RDXSTART) FROM MODULE IGG019KA  * 00780000
*   FOR A READ OR WRITE REQUEST OR FROM MODULE IGC0005C FOR A RELEX   * 00800000
*   REQUEST.   THE CALLING SEQUENCE IS:  L  15,DCBDRDX                * 00820000
*                                        BR 15                        * 00840000
*                                                                     * 00860000
*                                                                     * 00880000
*INPUT-REGISTER 12  IOB ADDRESS                                       * 00900021
*      REGISTER 13  DCB ADDRESS                                       * 00920000
*      REGISTER 15  BASE ADDRESS OF THIS MODULE                       * 00940000
*                                                                     * 00960000
*                                                                     * 00980000
*OUTPUT- N/A                                                          * 01000000
*OUTPUT-REGISTER 5  RETURN CODE FOR RELEX                          MC0H 01010000
*                                                                     * 01020000
*EXTERNAL ROUTINES- MODULE IGG019KA IS ENTERED TO POST A READ REQUEST * 01040000
*   THAT WAS TAKEN OFF THE UNPOSTED QUEUE AND ALSO TO PLACE THE IOB   * 01060000
*   ON THE AVAILABLE POOL.                                            * 01080000
*                                                                     * 01100000
*                                                                     * 01120000
*EXITS- CONTROL IS RETURNED TO MODULE IGG019KA FOR READ AND WRITE     * 01140000
*   REQUESTS AND TO MODULE IGC0005C FOR A RELEX REQUEST               * 01160000
*                                                                     * 01180000
*                                                                     * 01200000
*TABLES/WORK AREA- THE EXTENDED SAVE AREA IN THE SVRB IS SET UP TO    * 01220000
*                                                                     * 01240000
*   LOOK LIKE AN IOB BY THE RELEX SVC ROUTINE.                        * 01260000
*                                                                     * 01280000
*                                                                     * 01300000
*ATTRIBUTES- THIS MODULE IS EXECUTED DISABLED AND PRIVILEGED AND IS   * 01320000
*   REUSABLE.                                                         * 01340000
*                                                                     * 01360000
*                                                                     * 01380000
*NOTE- REGISTER USAGE IN THIS MODULE MUST REMAIN CONSISTENT WITH        01400000
*   MODULES IGG019KA AND IGC0005C.                                    * 01420000
*                                                                     * 01440000
         USING IGG019LG,BASE                                            01460000
         USING IOBDEF,IOBREG                                            01480000
         USING IHADCB,DCBREG                                            01500000
         USING DECBDEF,WKREG4                                           01520000
*                                                                       01540000
*                                                                       01560000
*              REGISTER USAGE                                           01580000
*                                                                       01600000
WKREG0   EQU   0         WORK REGISTER                                  01620000
REG1     EQU  1          REGISTER ONE                                   01640000
WKREG1   EQU   2         WORK REGISTER                                  01660000
WKREG2   EQU   3         WORK REGISTER                                  01680000
WKREG3   EQU   4         WORKING REGISTER                               01700000
WKREG4   EQU   5         WORK REGISTER                                  01720000
WKREG5   EQU   6         WORK REGISTER                                  01740000
WKREG6   EQU   7         WORK REGISTER                                  01760000
WKREG7   EQU   8         WORK REGISTER                                  01780000
RETURN   EQU   9                       RETURN REGISTER                  01800000
SVCRET   EQU   9                       RETURN REGISTER TO RELEX SVC     01820000
BASE     EQU   10                      BASE REGISTER FOR THIS ROUTINE   01840000
RETREG   EQU   11                                                       01860000
IOBREG   EQU   12                      IOB POINTER                      01880000
DCBREG   EQU   13        DCB POINTER                                    01900000
WKREG8   EQU   14                      WORK REGISTER                    01920000
WKREG9   EQU   15                      WORK REGISTER                    01940000
B1       EQU   1                       OFFSET TO ADDR           YA02106 01950003
*                                                                       01960000
RDXSTART EQU   *                                                        01980000
BEGIN    EQU   *                                                        02340000
         BAL   RETREG,LISTLOAD          GO GET ENQUE LIST ADDRESS       02360000
         MVI   27(WKREG3),X'00'         ZERO OUT R FIELD OF RECORD      02380000
         TM    IOBDTYPE+1,ADD           IS THIS A WRITE ADD             02400000
         BZ    NOTADD                   BRANCH IF NO                    02420000
         MVC   22(5,WKREG3),IOBSEEK+2   MOVE SEEK ADDRESS TO ENQ AREA   02440000
         B     LOADEXTN                                                 02460000
NOTADD   MVC   22(6,WKREG3),IOBDNRCF+1  MOVE DNRCF ADDR TO ENQ AREA     02480000
LOADEXTN SR    WKREG4,WKREG4                                            02500000
         IC    WKREG4,IOBSEEK           GET EXTENT NUMBER               02520000
         SLL   WKREG4,4                 TIMES 16                        02540000
         A     WKREG4,DCBDEBAD          PLUS DEB ADDRESS                02560000
         MVC   22(1,WKREG3),37(WKREG4)  GET LOW ORDER 'B' TO LIST       02580000
         L     WKREG4,32(WKREG4)        GET UCB ADDRESS                 02600000
         STH   WKREG4,20(WKREG3)        STORE INTO SEARCH FIELD         02620000
         LA    WKREG4,20(WKREG3)       INDICATE SEARCH FOR EQUAL TO UCB 02640000
SCANXARG EQU   *                                                        02660000
         L     WKREG1,DCBXARG           LOAD ADDRESS OF READ EXCLUSIVE  02680000
*                                        LIST FROM THE DCB              02700000
         LA    WKREG1,0(0,WKREG1)       CLEAR HIGH ORDER BYTE           02720000
         L     WKREG2,0(0,WKREG1)       LOAD FIRST WORD OF EXCLUSIVE    02740000
*                                        LIST                           02760000
         LA    WKREG2,0(0,WKREG2)      CLEAR OUT HI BYTE TO      A35339 02766021
*                                       COMPARE                  A35339 02772021
         CR    WKREG1,WKREG2            DOES LIST POINT TO ITSELF       02780000
         BNE   TERMTASK                 NO-POINTER FROM DCB MUST HAVE   02800000
*                                        BEEN DESTROYED,GO TO TERMINATE 02820000
*                                        TASK VIA ABEND                 02840000
GETCNT   LA    WKREG3,RDXCNT           PICK UP NO. OF SLOTS PER SEG.    02860000
         LA    WKREG1,8(0,WKREG1)       YES-SET POINTER TO FIRST ENTRY  02880000
SCANLIST EQU   *                                                        02900000
         CLC   0(8,WKREG1),0(WKREG4)   COMPARE THIS ENTRY FOR EQUAL     02920000
*                                        ON EXCLUSIVE LIST              02940000
         BE    TYPETST                  YES-DETERMINE TYPE OF REQUEST   02960000
         LA    WKREG1,8(0,WKREG1)       NO-SET UP TO CHECK NEXT ENTRY   02980000
         BCT   WKREG3,SCANLIST         MORE ENTRIES CONTINUE IF YES     03000000
GETPTR   L     WKREG1,4(0,WKREG2)      GET ADDR OF NEXR SECTION OF LIST 03020000
         LA    WKREG1,0(0,WKREG1)      ZERO HI ORDER BTYE               03040000
         LTR   WKREG1,WKREG1           TEST FOR ZERO(NO POINTER)        03060000
         BZ    TYPETST                 ZERO- TEST FOR WRITE             03080000
         LR    WKREG2,WKREG1           NON-ZERO - SET UP POINTERS       03100000
         B     GETCNT                  GO TO PICK UP COUNT IN THIS PART 03120000
TYPETST  EQU   *                                                        03140000
         TM    IOBDTYPE+1,READ+ADD     IS THIS A READ OR WRITE ADD      03160000
         BZ    WRTTYPE                  NO                              03180000
         TM    IOBDSTAT,ENQD           WAS THE WRITE ADD ENQ'D ALREADY  03200000
         BO    WRTTYPE                  YES GO ON TO DEQ                03220000
         TM    IOBDTYPE+1,PASS2        IS THIS THE SECOND PASS          03240000
         BO    POSTQ                   YES-GO TO ENTER ON LIST          03260000
         LTR WKREG3,WKREG3             NO- TEST FOR NO EQUAL FOUND      03280000
         BZ    SCANZERO                 NO                              03300000
         MVC   IOBCSW(8),0(WKREG4)      MOVE DATA TO IOB GOING ON QUE   03320000
         L     WKREG2,DCBUQND           YES-SET UP TO PLACE THIS IOB    03340000
*                                        ON THE UNPOSTED QUEUE          03360000
         LTR   WKREG2,WKREG2            WAS THIS THE FIRST IOB ON THE Q 03380000
         BNZ   NOTFRST                  NO                      SA68925 03400021
         ST    IOBREG,DCBIOBUQ          YES-PUT IOB ADDRESS AS START    03420000
*                                        OF QUEUE                       03440000
         B     *+8                     GO TO MAKE THIS IOB LAST         03460000
NOTFRST  ST    IOBREG,IOBDQPTR-IOBDEF(0,WKREG2) LINK IOB TO PRESENT END 03480000
         SR    WKREG2,WKREG2                                            03500000
         ST    WKREG2,IOBDQPTR         ZERO THE LINK FIELD OF THE IOB   03520000
         ST    IOBREG,DCBUQND          MAKE THIS IOB LAST ON THE QUEUE  03540000
         B     ASIEXIT                  RETURN                    12728 03560015
SCANZERO EQU   *                                                        03580000
         LA    WKREG4,AVAIL            INDICATE SEARCH FOR EMPTY SLOT   03600000
         OI    IOBDTYPE+1,PASS2        INDICATE SECOND PASS             03620000
         B     SCANXARG                GO TO SEARCH FOR AN EMPTY SLOT   03640000
POSTQ    EQU   *                                                        03660000
         NI    IOBDTYPE+1,NOPASS2      TURN OFF PASS2 INDICATION        03680000
         LTR   WKREG3,WKREG3           WAS AN EMPTY SLOT FOUND          03700000
         BC    7,PLACEONL              YES- PLACE IT ON LIST            03720000
         BAL   RETREG,ZEROKEY           NO-GO GET ANOTHER READX LIST    03740000
PLACEONL EQU   *                                                        03760000
         LA    RETREG,MOVELIST          LOAD RETURN REGISTER            03780000
LISTLOAD LA    WKREG3,ENQPL             LOAD LENGTH OF ENQUE LIST       03800000
         LNR   WKREG3,WKREG3            NEGATE                          03820000
         AH    WKREG3,IOBDIOBS          IOB LENGTH MINUS QUE LIST       03840000
         AR    WKREG3,IOBREG            PLUS IOB START ADDRESS          03860000
         BR    RETREG                                                   03880000
MOVELIST MVC   12(8,WKREG3),RCDQ        MOVE QNAME TO ENQ LIST          03900000
         MVI   0(WKREG3),X'FF'          SET LAST ENTRY CODE             03920000
         BAL   RETREG,ZEROKEY           GO MOVE ENTRY TO READX LIST     03940000
*                                                                       03980000
         MVI   2(WKREG3),0              SET DEFAULT OPTIONS OFF SA69490 03990021
         ENQ   (12(WKREG3),20(WKREG3),E,8,SYSTEM),RET=HAVE,            X04000000
               MF=(E,(WKREG3))                                          04020000
         OI    IOBDSTAT,ENQD           INDICATE THE RECORD ENQUEUED     04040000
         MVC   IOBDQPTR+B1(3),IOBECBPT+B1  SAVE ECB ADDR IN IOB YA02106 04080003
         LA    RETREG,IOBCSW+4         LOAD CSW ADDR TO USE AS   A39071 04090021
*                                      DUMMY ECB FOR IOS                04100021
         ST    RETREG,IOBECBPT         ST CSW ADDR IN ECB        A39071 04110021
         EXCP  (IOBREG)                 ISSUE EXCP                      04120000
         B     ASIEXIT                  RETURN                    12728 04160015
WRTTYPE  EQU   *                                                        04180000
         LTR   WKREG3,WKREG3           TEST TO SEE IF A MATCH WAS FOUND 04200000
         BZ    ERRTST                   NO-GO SET EXCEPTION CODE        04220000
*                                                                       04240000
*        THE NEXT ROUTINE SCANS THE UNPOSTED QUEUE TO DETERMINE IF      04260000
*        THERE WAS ANOTHER READ EXCLUSIVE REQUEST FOR THE RECORD BEING  04280000
*        RELEASED BY THE WRITE REQUEST                                  04300000
*                                                                       04320000
         L     WKREG9,DCBIOBUQ         LOAD POINTER TO FIRST IOB ON     04340000
*                                        THE QUEUE                      04360000
         LTR   WKREG9,WKREG9           ARE ANY IOBS ON THE QUEUE        04380000
         BZ    ZEROENT                  NO- GO CHECK UNSCHEDULED QUEUE  04400000
         LR    WKREG3,WKREG9           SET PRIOR IOB POINTER            04420000
LOOP     EQU   *                                                        04440000
         LTR   WKREG3,WKREG3            IS THERE AN IOB ON THE QUEUE    04460000
         BZ    ZEROENT                  NO- GO CHECK UNSCHEDULED QUEUE  04480000
         CLC   0(8,WKREG1),IOBCSW-IOBDEF(WKREG3)  YES-IS THERE ANOTHER  04500000
*                                        REQUEST FOR THIS RECORD        04520000
         BE    DEQUEUEU                 YES-TAKE IOB OFF UNPOSTED QUEUE 04540000
         LR    WKREG9,WKREG3           NO-ADVANCE PRIOR IOB POINTER     04560000
         L     WKREG3,IOBDQPTR-IOBDEF(0,WKREG3) LOAD ADDRESS OF NEXT    04580000
*                                                IOB ON THE QUEUE       04600000
         B     LOOP                     CHECK NEXT IOB                  04620000
*                                                                       04640000
DEQUEUE  EQU   *                                                        04660000
         L     WKREG0,IOBDQPTR-IOBDEF(0,WKREG3) LOAD ADDRESS OF NEXT    04680000
*                                                IOB ON THE QUEUE       04700000
         CR    WKREG9,WKREG3           WAS IOB FIRST ON QUEUE           04720000
         BNE   NOTFIRST                 NO                              04740000
         ST    WKREG0,0(0,WKREG4)       YES-SET NEXT IOB ADDRESS IN DCB 04760000
ONLYTST  EQU   *                                                        04780000
         LTR   WKREG0,WKREG0            WAS THE IOB UNQUEUED THE ONLY   04800000
*                                        IOB ON THE QUEUE               04820000
         BCR   7,WKREG5                NO                               04840000
         ST    WKREG0,4(0,WKREG4)       YES-ZERO END OF QUEUE POINTER   04860000
         BR    WKREG5                    IN DCB                         04880000
*                                                                       04900000
NOTFIRST EQU   *                                                        04920000
         ST    WKREG0,IOBDQPTR-IOBDEF(0,WKREG9) SET NEXT IOB ADDRESS IN 04940000
*                                                PRIOR IOB              04960000
LASTTST  EQU   *                                                        04980000
         LTR   WKREG0,WKREG0            WAS THE IOB UNQUEUED THE LAST   05000000
*                                        IOB ON THE CHAIN               05020000
         BCR   7,WKREG5                NO                               05040000
         ST    WKREG9,4(0,WKREG4)      YES-SET PRIOR IOB ADDRESS IN     05060000
*                                        END OF QUEUE POINTER           05080000
         BR    WKREG5                   RETURN                          05100000
DEQUEUEU EQU   *                                                        05120000
         LA    WKREG4,DCBIOBUQ          SET POINTER TO UNPOSTED QUEUE   05140000
         BAL   WKREG5,DEQUEUE           GO TO COMMON DEQUEUE ROUTINE    05160000
MOVETST  EQU   *                                                        05180000
         OI    IOBDSTAT-IOBDEF(WKREG3),ENQD INDICATE RECORD WAS ENQ'D   05200000
         LR    WKREG0,WKREG3            SAVE POINTER TO UNPOSTED IOB    05220000
         LR    WKREG5,WKREG0           GET IOB(NEXT) INTO REG 6         05240000
         TM    IOBDTYPE+1,RELEX+ADD    ENTRY FROM RELEX OF WRITE ADD    05260000
         BM    READPOST                YES- BRANCH AROUND MOVING DATA   05280000
*                                                                       05300000
*        THE FOLLOWING ROUTINE LOOKS THROUGH THE UNPOSTED QUEUE FOR     05320000
*        REQUESTS FOR THE SAME BLOCK THAT IS BEING WRITTEN OUT. FOR ALL 05340000
*        REQUESTS FOUND, THE BLOCK BEING WRITTEN IS ALSO MOVED INTO     05360000
*        THE DATA AREA OF THE READS, THUS THE QUEUED REQUESTS WILL HAVE 05380000
*        THE UPDATED BLOCK.                                             05400000
*                                                                       05420000
DATAMOVE EQU   *                                                        05440000
*                                                                       05460000
         L     WKREG4,IOBECBPT          LOCATE DECB FOR BLOCK BEING     05480000
         L     WKREG5,IOBECBPT-IOBDEF(0,WKREG3) WRITTEN AND FOR BLOCK   05500000
*                                               ON UNPOSTED QUEUE       05520000
         CLC   DECLNGTH-DECBDEF(2,WKREG5),DECLNGTH   COMPARE THE LENGTH 05540000
*                                                     OF EACH BLOCK     05560000
         BH    WRITELOW                 BRANCH IF WRITTEN AREA IS LESS  05580000
         LH    WKREG6,DECLNGTH-DECBDEF(0,WKREG5)   LOAD CONTROLLING     05600000
*                                                  LENGTH FOR MOVE      05620000
AREAPTRS EQU   *                                                        05640000
         L     WKREG7,DECAREA           LOAD ADDRESS OF THE TWO AREAS   05660000
         L     WKREG8,DECAREA-DECBDEF(0,WKREG5)  PRIOR TO THE MOVE      05680000
         B     TEST256                                                  05700000
MOVE256  EQU   *                                                        05720000
         MVC   0(256,WKREG8),0(WKREG7)  MOVE 256 BYTES TO BLOCK ON      05740000
*                                        UNPOSTED QUEUE                 05760000
         LA    WKREG7,256(0,WKREG7)     UPDATE THE TWO                  05780000
         LA    WKREG8,256(0,WKREG8)      AREA POINTERS                  05800000
TEST256  EQU   *                                                        05820000
         SH    WKREG6,CON256            CAN 256 BYTES BE MOVED          05840000
         BP    MOVE256                  YES                             05860000
         LA    WKREG6,255(0,WKREG6)    NO-RESTORE REMAINING LENGTH      05880000
         EX    WKREG6,MOVEREST          MOVE REST OF THE DATA           05900000
         AR    WKREG8,WKREG6            UPDATE READ AREA POINTER        05920000
         LA    WKREG8,1(0,WKREG8)      ADD ON ONE BYTE FOR AREA ADDRESS 05940000
         CLC   DECLNGTH-DECBDEF(2,WKREG5),DECLNGTH     WAS READ AREA    05960000
*                                                    LARGER THAN WRITE  05980000
*                                                    AREA               06000000
         BNH   TST4MORE                 NO-GO TEST FOR MORE READS ON    06020000
*                                        UNPOSTED QUEUE                 06040000
PADTST   EQU   *                        YES-PAD REMAINDER OF BLOCK      06060000
         SH    WKREG9,CON256            IS PADDING GREATER THAN 256     06080000
         BP    PAD256                   YES                             06100000
         LA    WKREG9,255(0,WKREG9)     NO-RESTORE LENGTH               06120000
         EX    WKREG9,PADBLOCK          PAD REST OF BLOCK               06140000
         B     TST4MORE                 GO TEST FOR MORE READS          06160000
PAD256   EQU   *                                                        06180000
         XC    0(256,WKREG8),0(WKREG8) CLEAR 256 BYTES                  06200000
         LA    WKREG8,256(0,WKREG8)     UPDATE AREA POINTER             06220000
         B     PADTST                   GO TO PAD BLOCK                 06240000
WRITELOW EQU   *                                                        06260000
         LH    WKREG6,DECLNGTH          USE WRITTEN AREA AS DATA LENGTH 06280000
         LH    WKREG9,DECLNGTH-DECBDEF(0,WKREG5)  CALCULATE THE AMOUNT  06300000
         SR    WKREG9,WKREG6                      OF PADDING REQUIRED   06320000
         B     AREAPTRS                 GO TO SET UP FOR DATA MOVE      06340000
TST4MORE EQU   *                                                        06360000
         L     WKREG3,IOBDQPTR-IOBDEF(0,WKREG3) LOAD ADDRESS OF NEXT    06380000
*                                                IOB ON THE UNPOSTED    06400000
*                                                QUEUE                  06420000
         LTR   WKREG3,WKREG3            IS THERE ANOTHER IOB ON THE     06440000
*                                        QUEUE                          06460000
         BZ    READPOST                 NO-GO POST FIRST IOB FOUND      06480000
         CLC   0(8,WKREG1),IOBCSW-IOBDEF(WKREG3)  YES--IS REQUEST 18527 06500000
*                                                  FOR THE SAME BLOCK   06520000
*                                                  BEING RELEASED       06540000
         BE    DATAMOVE                 YES-GO TO MOVE DATA             06560000
         B     TST4MORE                 NO-TEST FOR MORE READS ON QUEUE 06580000
*                                                                       06600000
*                                                                       06620000
READPOST EQU   *                                                        06640000
*        THE FOLLOWING ROUTINE SETS UP TO GO TO THE ASYNCHRONOUS        06660000
*        INTERRUPT ROUTINE WHICH WILL POST THE UNQUEUED READ REQUEST    06680000
*        AND PLACE THE IOB ON THE AVAILABLE POOL. CONTROL WILL BE       06700000
*        RETURNED TO THIS MODULE FOR FURTHER PROCESSING OF THE WRITE    06720000
*        OR RELEX REQUEST.                                              06740000
*                                                                       06760000
         TM    IOBDTYPE+1,ADD          WRITE ADD REQUEST                06780000
         BC    1,WRTPOST                                          12728 06800015
         LR    WKREG2,IOBREG            SAVE POINTER TO THE WRITE       06820000
*                                        REQUEST IOB                    06840000
         LR    REG1,WKREG0             SET IOB POINTER TO THE UNQUEUED  06860000
*                                        READ REQUEST                   06880000
POSTEXIT EQU   *                                                  12728 06890015
         LA    WKREG4,POSTRTRN          LOAD RETURN ADDRESS             06900000
         ST    WKREG4,IOBDQPTR-IOBDEF(0,REG1) STORE ADDR IN IOB FOR USE 06920000
*                                        ASI                            06940000
         L     RETREG,DCBREAD          LOAD FOUNDATION BASE ADDRESS     06960000
         L     RETREG,ASIOFF(0,RETREG) LOAD ASI BASE ADDRESS            06980000
         LR    WKREG9,RETREG           GET ADDR INTO WKREG9(FOR VECTOR) 07000000
         B     FEEDB(0,RETREG)         RETURN TO ASI                    07020000
WRTPOST  EQU   *                                                  12728 07021015
*   THE FOLLOWING ROUTINE PREPARES TO GO TO THE ASYNCHRONOUS      12728 07022015
* INTERRUPT ROUTINE WHICH WILL POST THE FIRST WRITE ADD REQUEST,  12728 07023015
* PLACE THE IOB ON THE AVAILABLE POOL, AND WILL RETURN CONTROL.   12728 07024015
*   UPON RETURNING, CONTROL WILL BE GIVEN TO THE SELF FORMAT      12728 07025015
* MODULE FOR AN EXCP UPON THE IOB TAKEN FROM THE UNPOSTED QUEUE.  12728 07026015
*                                                                 12728 07027015
         LR    REG1,IOBREG    PUT IOB ADDRESS IN CORRECT REGISTER 12728 07028015
         LR    WKREG2,WKREG3            SAVE POINTER TO NEW IOB   12728 07029015
         MVC   IOBDNRCF-IOBDEF(7,WKREG2),IOBSEEK+3                14231 07029116
*  MOVE NEW CAPACITY RECORD TO NEW IOB.                           14231 07029216
         TM    IOBDSTAT,X'02'           DID CURRENT RECORD FIT    14231 07029316
         BCR   8,RETURN                 NO--RETURN TO SELF FORMAT 14231 07029416
*                                       TO TEST FOR EXT SCH AND   14231 07029516
*                                       TO POST THIS IOB          14231 07029616
         B     POSTEXIT      GO TO ASYNCH RTN TO POST REQUEST     12728 07030015
*                                                                       07040000
POSTRTRN EQU   *                                                        07060000
         L     BASE,DCBDRDX             RESTORE BASE ADDRESS            07080000
         LR    IOBREG,WKREG2            RESTORE POINTER TO THE WRITE    07100000
*                                        REQUEST IOB                    07120000
         B     EXITTST                 GO RETURN TO PROPER ROUTINE      07140000
*                                                                       07160000
ZEROENT  EQU   *                                                        07180000
         LA    WKREG3,AVAIL-20          LOAD POINTER TO ZERO            07200000
         BAL   RETREG,ZEROKEY           GO TO CLEAR ENTRY               07220000
         BAL   RETREG,LISTLOAD          GO SET UP DEQUE LIST            07240000
         CLC   12(8,WKREG3),RCDQ        IS THERE A DEQ LIST THIS IOB    07260000
         BE    ISDEQL                   BRANCH IF YES                   07280000
         MVC   12(8,WKREG3),RCDQ        MOVE QNAME TO DEQ LIST          07300000
         MVI   0(WKREG3),X'FF'          SET LAST ENTRY CODE             07320000
         DEQ   (12(WKREG3),20(WKREG3),8,SYSTEM),MF=(E,(WKREG3))         07340000
         B     DEQRTN                                                   07360000
*                                                                       07380000
ISDEQL   DEQ   ,MF=(E,(WKREG3))                                         07400000
DEQRTN   XC    12(8,WKREG3),12(WKREG3)  CLEAR OUT QNAME AREA            07420000
         SR    WKREG4,WKREG4            SET ZERO RETURN CODE       MC0H 07430000
         SR    WKREG5,WKREG5           INDICATE NO IOB WAS FOUND        07440000
         B     ERREXIT                                            12728 07450015
EXITTST  EQU   *                                                        07460000
         TM    IOBDTYPE+1,ADD           IS IT A WRITE ADD         12728 07466015
         BC    1,WRTEXIT                YES--GO TO SELF FORMAT    12728 07472015
         SR    WKREG4,WKREG4           SET ZERO RETURN CODE             07480000
ERREXIT  LR    REG1,IOBREG             GET IOB ADDRESS INTO CORRECT REG 07500000
ASIEXIT  EQU   *                                                  12728 07510015
         L     RETREG,DCBREAD          LOAD FOUNDATION BASE ADDRESS     07520000
         L     RETREG,ASIOFF(0,RETREG) LOAD ASI BASE ADDRESS            07540000
         LR    WKREG8,RETURN            RESTORE R14 FOR RELEX    A35339 07546021
*                                       LINKAGE                  A35339 07552021
         BR   RETURN                   RETURN                           07560000
WRTEXIT  EQU   *                                                  12728 07564015
         LR    REG1,IOBREG   GET IOB ADDRESS INTO CORRECT REG     12728 07568015
         L     BASE,DCBDFOR    GET BASE OF SELF FORMAT MODULE     12728 07572015
         B     8(0,BASE)                BRANCH TO IT              12728 07576015
*                                                                       07580000
ERRTST   EQU   *                                                        07600000
WRITERR  EQU   *                                                        07720000
         OI    IOBDSTAT+1,XERR          SET ERROR CODE FOR ASI          07740000
         B     ERREXIT                  RETURN                          07760000
*                                                                       07780000
ZEROKEY  EQU   *                                                        07880000
         LTR   WKREG3,WKREG3            IS THIS A GETMAIN ENTRY         07940000
         BNE   SUPER                    BRANCH IF NO                    07960000
         LA    WKREG0,80               YES-SET UP TO ISSUE A GETMAIN    07980000
         GETMAIN R,LV=(0)              ISSUE THE GETMAIN                08060000
         XC    0(80,REG1),0(REG1)      CLEAR OUT THE LIST               08080000
         ST   REG1,4(0,WKREG2)         STORE ADDR IN PRIOR CHAIN FIELD  08100000
         LA    WKREG1,8(REG1)           SET 1ST SLOT POINTER            08120000
         BR    RETREG                   RETURN                   A35339 08140021
SUPER    EQU   *                                                        08160000
         MVC   0(8,WKREG1),20(WKREG3)   MOVE ENTRY INTO LIST            08180000
         BR    RETREG                   RETURN                          08380000
*                                                                       08400000
*        THE NEXT ROUTINE IS USED TO TERMINATE THE TASK,VIA ABEND,WHEN  08420000
*        THE POINTER TO THE EXCLUSIVE IN THE DCB IS FOUND TO BE INVALID 08440000
*                                                                       08460000
TERMTASK EQU   *                                                        08480000
         L     1,ABCODE                GET ABEND CODE AND               08500000
         ABEND (1)                      ISSUE ABEND                     08520000
*                                                                       08540000
         DS    0F                                                       08600000
ABCODE   DC    AL1(128)                DUMP OPTION FOR ABEND            08620000
         DC    XL3'026000'             ABEND CODE FOR INVALID ADDRESS   08640000
DYNOFF   EQU   8                                                        08660000
POSTOFF  EQU   12                                                       08680000
RELEX    EQU   X'01'                    RELEX INDICATOR IN IOBDSTAT     08700000
ADD      EQU   X'02'                    ADD   INDICATOR IN IOBDSTAT     08720000
READ     EQU   X'08'                    READ                            08740000
ASIOFF   EQU   16                                                       08760000
PASS2    EQU   X'01'                   PASS TWO INDICATION              08780000
DRELEX   EQU   X'01'                    RELEX ENTRY INDICATOR           08800000
NOPASS2  EQU   X'FE'                   TURN OFF PASS TWO MASK           08820000
ENQD     EQU   X'08'                   INDICATION RECORD WAS ENQ'D      08840000
ENQPL    EQU   28                       ENQUE LIST LENGTH               08860000
FEEDB    EQU   4                       OFFSET TO GET FEEDBACK IN ASI    08880000
*                                       EXCLUSIVE LIST                  08900000
READX    EQU   X'02'                    READ EXCLUSIVE INDICATOR IN IOB 08920000
XERR     EQU   X'01'                    READ EXCLUSIVE ERROR INDICATOR  08940000
EXIT     EQU   3                                                        08960000
RDXCNT   EQU   9                       NUMBER OF SLOTS PER SEGMENT      08980000
POOLOFF  EQU   12                       IOB POOL OFFSET IN ASI          09000000
         DS    0F                                                       09020000
RCDQ     DC    C'SYSI'                  MAJOR QUEUE NAME                09040000
         DC    C'GGLG'                                                  09060000
AVAIL    DC    1D'0'                                                    09080000
MOVEREST EQU   *                                                        09100000
         MVC   0(1,WKREG8),0(WKREG7)    EXECUTED DATA MOVE              09120000
PADBLOCK EQU   *                                                        09140000
         XC    0(1,WKREG8),0(WKREG8)    EXECUTED CLEARING OF BLOCK      09160000
CON256   DC    H'256'                                                   09180000
*        THE FOLLOWING CNOP MUST REMAIN ON A HALF WORD BOUNDARY         09200000
         CNOP  0,8                     PAD TO DOUBLE WORD SIZE FOR TTR  09220000
*********************************************************************** 09240000
*                                                                       09260000
*              STANDARD IOB                                             09280000
         DS    0F                                                       09300000
IOBDEF   DSECT                                                          09320000
IOBFLAG1 DS    CL1            STATUS FLAG                               09340000
IOBFLAG2 DS    CL1            ERROR FLAG                                09360000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       09380000
IOBECBPT DS    CL4            ECB POINTER                               09400000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       09420000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           09440000
         DS    CL1                                                      09460000
         DS    CL3                                                      09480000
IOBCSWST DS    CL2            STATUS BYTES                              09500000
IOBCSWCT DS    CL2            REMAINING COUNT                           09520000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   09540000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        09560000
         DS    CL3                                                      09580000
IOBDCBPT DS    0CL4           DCB POINTER                               09600000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            09620000
         DS    CL3                                                      09640000
IOBRESTR DS    0CL4           RESTART POINTER                           09660000
         DS    CL1                                                      09680000
         DS    CL3                                                      09700000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              09720000
IOBERRCT DS    CL2            ERROR COUNTER                             09740000
IOBSEEK  DS    CL8            SEEK ADDRESS                              09760000
*        BDAM EXTENDED IOB                                              09780000
*                                                                       09800000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  09820000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          09840000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     09860000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                09880000
         DS    CL3                                                      09900000
IOBDTYPE DS    CL2            TYPE FIELD                                09920000
IOBDSTAT DS    CL2            IOB STATUS                                09940000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        09960000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                09980000
         DS    CL2                                                      10000000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               10020000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        10040000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                10060000
IOBCP    DS    CL8            FIRST CCW IN CHANNEL PROGRAM              10080000
         EJECT                                                          10100000
*                                                                       10120000
*      DATA EXTENT BLOCK (DEB) DEFINITION                               10140000
*                                                                       10160000
         DS    0F                                                       10180000
DEB      DSECT                                                          10200000
DEBNMSUB DS    0CL1                    COUNT OF ROUTINES LOADED         10220000
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDRESS       10240000
DEBAMLNG DS    0CL1                    WORD CNT OF BDAM ADDED CORE      10260000
DEBDEBAD DS    CL4                     DEB CHAIN ADDRESS                10280000
DEBOFLGS DS    0CL1                    OPEN FLAGS                       10300000
DEBIRBAD DS    CL4                     IRB ADDRESS                      10320000
DEBOPATB DS    0CL1                    DATA SET ATTRIBUTES              10340000
DEBSYSPG DS    CL4                                                      10360000
DEBNMEXT DS    0CL1                    COUNT OF EXTENTS                 10380000
DEBUSRPG DS    CL4                                                      10400000
DEBPRIOR DS    0CL1                                                     10420000
DEBECBAD DS    CL4                                                      10440000
DEBPROTG DS    0CL1                                                     10460000
DEBDEBID DS    0CL1                                                     10480000
DEBDCBAD DS    CL4                     DCB ADDRESS                      10500000
DEBEXSCL DS    0CL1                    EXTENT SIZE SCALE                10520000
DEBAPPAD DS    CL4                     IOS APPENDAGE LIST ADDRESS       10540000
DEBDVMOD DS    0CL1                    FILE MASK CODE                   10560000
DEBUCBAD DS    CL4                     UCB ADDRESS                      10580000
DEBBINUM DS    CL2                     BIN NUMBER (BB)                  10600000
DEBSTRCC DS    CL2                     STARTING CYLINDER NUMBER         10620000
DEBSTRHH DS    CL2                     STARTING TRACK NUMBER            10640000
DEBENDCC DS    CL2                     ENDING CYLINDER NUMBER           10660000
DEBENDHH DS    CL2                     ENDING TRACK NUMBER              10680000
DEBNMTRK DS    CL2                     NO. OF TRACKS IN THIS EXTENT     10700000
DEBSUBID EQU   0         SUBROUTINE ID'S                                10720000
*                                                                       10740000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       10760000
         DS    0F                                                       10780000
DECBDEF  DSECT                                                          10800000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        10820000
DECTYPE  DS    CL2            TYPE FIELD                                10840000
DECLNGTH DS    CL2            DATA LENGTH                               10860000
DECDCBAD DS    CL4            ADDRESS OF DCB                            10880000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      10900000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        10920000
DECKYADR DS    CL4            ADDRESS OF KEY                            10940000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               10960000
         DCBD  DSORG=DA                                                 10980000
         END                                                            11000000
