 TITLE   'IGG019LI-BDAM CHECK MODULE'                                   00021221
IGG019LI CSECT                                                          00021621
*                                                                       00022019
*          RELEASE 18 DELETIONS                                       * 00027019
*          RELEASE 19 DELETIONS                                       * 00032019
*9038020800-021000                                               I19116 00034019
*          RELEASE 20 DELETIONS                                       * 00037019
*          RELEASE 21 DELETIONS/CHANGE                                * 00042021
*C016400,017200                                                  SM0208 00042421
*3043014050-014150                                               21905  00043021
*3043014200                                                      M0055  00044021
*          RELEASE 22 DELETIONS                                       * 00047019
*          RELEASE 23 DELETIONS                                       * 00052019
*          RELEASE 24 DELETIONS                                       * 00057019
*          RELEASE 25 DELETIONS                                       * 00062019
*          RELEASE 26 DELETIONS                                       * 00067019
*        VS1/3.0 DELETIONS/CHANGES                                    * 00077003
*D014050-014150                                                 XA02037 00087003
* STATUS CHANGE LEVEL 003     5/30/73                                   00090003
*                                                                       00092003
*                                                                     * 00100019
*FUNCTIONS/OPERATION - THIS MODULE IS ENTERED BY THE CHECK MACRO      * 00120000
*    ISSUED BY THE PROBLEM PROGRAM.THIS ROUTINE WAITS(IF NECESSARY)   * 00140000
*    FOR THE COMPLETION OF THE INPUT/OUTPUT OPERATION ASSOCIATED WITH * 00160000
*    THE DATA EVENT CONTROL BLOCK(DECB) PASSED TO THIS ROUTINE BY     * 00180000
*    THE PROBLEM PROGRAM. IF THE I/O OPERATION HAS COMPLETED WITHOUT  * 00200000
*    ANY OF THE EXCEPTION BITS IN THE DECB BEING SET, THIS ROUTINE    * 00220000
*    THEN FREES THE IOB ASSOCIATED WITH THE I/O EVENT TO THE POOL OF  * 00240000
*    IOBS. IF ONE OF THE EXCEPTION BITS HAS BEEN SET THIS ROUTINE WILL* 00260000
*    (1) ABEND IF NO SYNAD ROUTINE HAS BEEN SUPPLIED BY THE USER      * 00280000
*    (2) GO TO THE USER'S SYNAD ROUTINE IF ONE IS SUPPLIED AND WHEN   * 00300000
*    CONTROL IS RETURNED TO THIS ROUTINE BY THE USER THE PROCESSING   * 00320000
*    CONTINUES AS IF NONE OF THE EXCEPTION BITS HAD BEEN SET          * 00340000
*                                                                     * 00360000
*ENTRY POINT -'IGG019LI'IS THE ENTRY POINT FROM THE CHECK MACRO       * 00380000
*    EXPANSION VIA THE CALLING SEQUENCE-          L    15,DCBCHECK    * 00400000
*                                                 BALR 14,15          * 00420000
*                                                                     * 00440000
*INPUT- INPUT TO THE CHECK ROUTINE IS THE ADDRESS OF THE DECB ASSIGNED* 00460000
*    TO THE READ OR WRITE BEING CHECKED. THIS ADDRESS WILL BE LOADED  * 00480000
*    INTO REGISTER 1 PRIOR TO ENTERING THIS ROUTINE.                  * 00500000
*                                                                     * 00520000
*OUTPUT- THE IOB(IF ONE HAS BEEN ASSIGNED) FOR THIS REQUEST IS FREED  * 00540000
*    TO THE POOL OF IOBS.                                             * 00560000
*    IF THE USER'S SYNAD EXIT IS TAKEN,REGISTER 0 WILL CONTAIN THE    * 00580000
*    DECB ADDRESS AND REGISTER 1 WILL CONTAIN THE DCB ADDRESS PLUS    * 00600000
*    SOME INFORMATIONAL BITS.                                         * 00620000
*                                                                     * 00640000
*EXTERNAL ROUTINES- NONE                                              * 00660000
*                                                                     * 00680000
*EXITS - 'RETURN' IS THE EXIT TO RETURN TO THE PROBLEM PROGRAM ON     * 00700000
*    NORMAL COMPLETION.                                               * 00720000
*    'SETSYNAD' IS THE EXIT TO THE USER'S SYNCHRONOUS ERROR ROUTINE.  * 00740000
*                                                                     * 00760000
*TABLES/WORK AREAS- NONE                                              * 00780000
*                                                                     * 00800000
*ATTRIBUTES - THIS ROUTINE IS REENTRANT AND EXECUTED ENABLED.         * 00820000
*                                                                     * 00840000
         EJECT                                                          00860000
*                                                                       00880000
*        REGISTER USAGE                                                 00900000
*                                                                       00920000
*                                                                       00940000
PARAM1   EQU   0                       PARAMETER REGISTER FOR SYNAD     00960000
DCBR     EQU   1                       ADDRESS OF DCB FOR SYNAD+CODES   00980000
DECBR    EQU   2                       DECB ADDRESS                     01000000
CODER    EQU   3                       CODE REGISTER                    01020000
CODER1   EQU   4                       CODE REGISTER                    01040000
IOBR     EQU   4                       IOB ADDRESS                      01060000
BASE     EQU   5                       BASE OF THIS MODULE              01080000
RETREG   EQU   14                      RETURN REGISTER                  01100000
EPREG    EQU   15                      ENTRY POINT REGISTER             01120000
*                                                                       01140000
*                                                                       01160000
*                                                                       01180000
         USING IOBDEF,IOBR                                              01200000
         USING IGG019LI,BASE                                            01220000
         USING DECBDEF,DECBR                                            01240000
         USING IHADCB,DCBR                                              01260000
*                                                                       01280000
*                                                                       01300000
         SAVE  (14,5)                  SAVE REGISTERS 14-5              01320000
         LR    BASE,EPREG                                               01340000
         LR    DECBR,DCBR                                               01360000
         TM    DECSDECB,COMPLETE       HAS THIS ECB BEEN POSTED COMPLET 01380000
         BZ    WAIT                    NO WAIT ON THIS ECB              01400000
CHECKERR TM    DECSDECB+1,ALLONES      ANY ERRORS IN ECB         M0055  01425003
         BZ    MKIOBAVL                NO.MAKE IOB AVAILABLE            01440000
         LA    CODER,WRITE             PUT WRITE BIT ON                 01460000
         TM    DECTYPE+1,READ          IS THIS A READ                   01480000
         BZ    WRITEADD                NO GO ON                         01500000
         LA    CODER,READ1             YES CHANGE WRITE TO READ         01520000
         L     IOBR,DECIOBPT           GET IOB ADDRESS                  01540000
         LTR   IOBR,IOBR               WAS AN IOB ASSIGNRD              01560000
         BZ    INVREQ                  NO, SKIP TESTING IF BLOCK IS IN  01580000
         CLC   IOBDCPND+1(3),IOBCSW+1  IS CHANNEL PROGRAM COMPLETE      01600000
         BNE   INVREQ                  NO GO ON                         01620000
         LA    CODER1,DCBBIT4          YES INDICATE THAT         SM0208 01640021
         OR    CODER,CODER1            THE BLOCK IS IN CORE             01660021
WRITEADD TM    DECTYPE+1,ADD           IS THIS A WRITE ADD              01680000
         BO    INVREQ                  YES GO ON                        01700000
         LA    CODER1,DCBBIT4          NO INDICATE THAT THIS IS  SM0208 01720021
         OR    CODER,CODER1            AN UPDATE AND NOT A NEW RECORD   01740021
INVREQ   TM    DECSDECB+1,INVALID      IS THIS AN INVALID REQUEST       01760000
         BZ    UNRELATD                NO GO ON                         01780000
         LA    CODER1,BADREQ           YES INDICATE THAT THIS IS AN     01800000
         OR    CODER,CODER1            INVALID REQUEST                  01820000
UNRELATD TM    DECSDECB+1,NOTRELTD     IS THIS AN UNREACHABLE BLOCK     01840000
         BZ    NOSPACE                 NO GO ON                         01860000
         LA    CODER1,UNREACH          YES INDICATE THIS BLOCK COULD    01880000
         OR    CODER,CODER1            NOT BE REACHED                   01900000
NOSPACE  TM    DECSDECB+1,NOSPACEB     WAS NO SPACE AVAILABLE           01920000
         BZ    SYNAD                   NO GO ON                         01940000
         LA    CODER1,NOSPACEF         YES INDICATE NO SPACE FOUND      01960000
         OR    CODER,CODER1                                             01980000
SYNAD    EQU   *                                                        02000000
         L     DCBR,DECDCBAD           PUT DCB ADDR INTO REG 1          02020000
         TM    DCBSYNAD+3,X'01'        IS THERE A SYNAD ROUTINE         02040000
         BZ    SETSYNAD                YES GO SET UP TO LINK TO IT      02060000
         LH    PARAM1,ABNOSYND                                   I19116 02080019
         SVC   55                                                I19116 02100019
SETSYNAD LR    PARAM1,DECBR            PUT DECB ADDR INTO REG 0         02120000
         SLL   CODER,24                PUT ERROR SUMMARY BITS INTO      02140000
         OR    DCBR,CODER              HI-ORDER BYTE OF REG 1           02160000
         L     EPREG,DCBSYNAD          GET SYNAD ADDRESS                02180000
         STM   2,5,44(13)              SAVE OUR REGISTERS               02200000
         LM    2,5,28(13)              RESTORE USER'S REGISTERS         02220000
         BALR  RETREG,EPREG            LINK TO IT                       02240000
         STM   2,5,28(13)              SAVE USER'S REGISTERS            02260000
         LM    2,5,44(13)              RESTORE OUR REGISTERS            02280000
MKIOBAVL L     IOBR,DECIOBPT           GET  THE IOB ADDR.               02300000
         LTR   IOBR,IOBR               WAS AN IOB ASSIGNED              02320000
         BZ    RETURN                  NO, RETURN TO USER               02340000
FROMPOOL MVI   IOBDAVLI,0              ZERO AVAILABILITY BYTE           02360000
RETURN   EQU   *                                                        02380000
         RETURN (14,5),T                                                02400000
WAIT     WAIT  ECB=(1)                 WAIT FOR EVENT TO COMPLETE       02420000
         B     CHECKERR                GO BACK TO CHECK ERRORS          02440000
*                                                                       02460000
AVLMSK   EQU   X'80'                   IOB AVAILABILITY BYTE            02480000
ALLONES  EQU   X'FF'                   MASK TO TEST FOR ANY ERRORS      02500000
WRITE    EQU   X'40'                   WRITE BIT IN CODE                02520000
READ     EQU   X'08'                   READ BIT IN DECTYPE FIELD        02540000
ADD      EQU   X'02'                   WRITE ADD BIT IN DECTYPE FIELD   02580000
INVALID  EQU   X'10'                   INVALID REQUEST IN DECB          02600000
BADREQ   EQU   X'08'                   INVALID REQUEST IN CODE          02620000
NOTRELTD EQU   X'02'                   UNRELATED ERROR IN DECB          02640000
UNREACH  EQU   X'02'                   UNRELATED ERROR IN CODE          02660000
NOSPACEB EQU   X'20'                   NO SPACE FOUND BIT IN DECB       02680000
NOSPACEF EQU   X'01'                   NO SPACE FOUND BIT IN CODE       02700000
ABNOSYND DC    XL2'1000'               ABEND CODE IF NO SYNAD IS GIVEN  02720000
COMPLETE EQU   X'40'                   COMPLETE BIT IN ECB              02740000
READ1    EQU   X'80'                   READ BIT IN CODE                 02760000
*                                                                       02780000
*              THE FOLLOWING CNOP MUST REMAIN ON A HALF-WORD BOUNDARY   02800000
         CNOP  0,8                     PAD MODULE TO A DOUBLE WORD      02820000
*      DATA CONTROL BLOCK (DCB) DEFINITION                              02840000
*                                                                       02860000
*                                                                       02880000
         DCBD  DSORG=DA                                                 02900000
         EJECT                                                          02920000
*      DATA EVENT CONTROL BLOCK (DECB) DEFINITION                       02940000
         DS    0F                                                       02960000
DECBDEF  DSECT                                                          02980000
DECSDECB DS    CL4            STANDARD EVENT CONTROL BLOCK (ECB)        03000000
DECTYPE  DS    CL2            TYPE FIELD                                03020000
DECLNGTH DS    CL2            DATA LENGTH                               03040000
DECDCBAD DS    CL4            ADDRESS OF DCB                            03060000
DECAREA  DS    CL4            ADDRESS OF DATA AREA                      03080000
DECIOBPT DS    CL4            ADDRESS OF THE IOB                        03100000
DECKYADR DS    CL4            ADDRESS OF KEY                            03120000
DECRECPT DS    CL4            ADDRESS OF RECORD REFERENCE               03140000
         EJECT                                                          03160000
*                                                                       03180000
*      I/O BLOCK (IOB) DEFINITION                                       03200000
*                                                                       03220000
*              STANDARD IOB                                             03240000
         DS    0F                                                       03260000
IOBDEF   DSECT                                                          03280000
IOBFLAG1 DS    CL1            STATUS FLAG                               03300000
IOBFLAG2 DS    CL1            ERROR FLAG                                03320000
IOBSENSE DS    CL2            SENSE BYTES 0 AND 1                       03340000
IOBECBPT DS    CL4            ECB POINTER                               03360000
IOBCSW   DS    0CL8           CHANNEL STATUS WORD                       03380000
IOBCSWCA DS    0CL4           COMMAND ADDRESS                           03400000
         DS    CL1                                                      03420000
         DS    CL3                                                      03440000
IOBCSWST DS    CL2            STATUS BYTES                              03460000
IOBCSWCT DS    CL2            REMAINING COUNT                           03480000
IOBSTART DS    0CL4           CHANNEL PROGRAM POINTER                   03500000
IOBSIOCC DS    CL1            SIO CONDITION CODE                        03520000
         DS    CL3                                                      03540000
IOBDCBPT DS    0CL4           DCB POINTER                               03560000
IOBWGHT  DS    CL1            CHANNEL WEIGHT                            03580000
         DS    CL3                                                      03600000
IOBRESTR DS    0CL4           RESTART POINTER                           03620000
         DS    CL1                                                      03640000
         DS    CL3                                                      03660000
IOBINCAM DS    CL2            BLOCK COUNT INCREMENT AMOUNT              03680000
IOBERRCT DS    CL2            ERROR COUNTER                             03700000
IOBSEEK  DS    CL8            SEEK ADDRESS                              03720000
*        BDAM EXTENDED IOB                                              03740000
*                                                                       03760000
IOBDBYTR DS    CL2            BYTES REMAINING ON TRACK                  03780000
IOBDIOBS DS    CL2            SIZE OF THIS IOB                          03800000
IOBDPLAD DS    0CL4           IOB POOL LINK ADDRESS                     03820000
IOBDAVLI DS    CL1            IOB AVAILABILITY INDICATOR                03840000
         DS    CL3                                                      03860000
IOBDTYPE DS    CL2            TYPE FIELD                                03880000
IOBDSTAT DS    CL2            IOB STATUS                                03900000
IOBDCPND DS    CL4            CHANNEL PROGRAM NORMAL END ADDRESS        03920000
IOBDBYTN DS    CL2            BYTES NEEDED BY NEW RECORD                03940000
         DS    CL2                                                      03960000
IOBDQPTR DS    CL4            LINK FIELD FOR QUEUED IOB'S               03980000
IOBUPLIM DS    CL8            LIMIT MBBCCHHR FOR EXTENDED SEARCH        04000000
IOBDNRCF DS    CL8            COUNT FIELD FOR NEW RECORD                04020000
IOBCP    DS    CL8            FIRST CCW IN CHANNEL PROGRAM              04040000
IOBDIOBX EQU   42                      OFFSET FOR IOBDIOS               04060000
IOBDPLAX EQU   44                      OFFSET FOR IOBDPLAD              04080000
         END                                                            04100000
