 TITLE   'IFBSTAT,IGC0007F,SYS1.LOGREC RECORDER'                        00050021
* /* START OF SPECIFICATIONS******************************************* 00100021
*                                                                       00150021
*01* MODULE-NAME = IGC0007F                                             00200021
*                                                                       00250021
*01* DESCRIPTIVE-NAME = 1.IFBSTAT 2.SYS1.LOGREC RECORDER                00300021
*                                                                       00350021
*01* COPYRIGHT =N/A                                                     00400021
*                                                                       00450021
*01* STATUS = VERSION 000 MODULE SUPPORT CODE S21021                    00500021
*                                                                       00550021
*01* CHANGE-ACTIVITY = MODULE REPLACED COMPLETELY                       00600021
*                                                                       00650021
*02*     A = ALL NEW LINES ADDED                                        00700021
*                                                                       00750021
*02*     D = ALL PREVIOUS LINES DELETED                                 00800021
*                                                                       00850021
*02*     C = NO LINES CHANGED                                           00900021
*                                                                       00950021
*                                                                       01000021
*01* FUNCTION = THE SYS1.LOGREC RECORDER IS THE FIRST LOAD OF THE       01050021
*    TRANSIENT SVC ROUTINE IFBSTAT, INVOKED BY ISSUING SVC76. ITS       01100021
*    FUNCTION PROVIDES A METHOD OF RECORDING TO THE SYS1.LOGREC DATA    01150021
*    SET.                                                               01200021
*                                                                       01250021
*01* NOTES =                                                            01300021
*                                                                       01350021
*02*     CHARACTER-CODE DEPENDENCIES = MUST BE REASSEMBLED IF MODE      01400021
*        CHANGED FROM EBCDIC.                                           01450021
*                                                                       01500021
*02*     DEPENDENCIES = N/A                                             01550021
*                                                                       01600021
*02*     RESTRICTIONS = NONE                                            01650021
*                                                                       01700021
*02*     REGISTER-CONVENTIONS = ALL REGISTERS EQUATED TO SYMBOLS        01750021
*        SEE REG EQUATES AT FRONT OF LISTING                            01800021
*        REG.0-1 INPUT PARAMETERS REG.                                  01850021
*        REG.2   CVT POINTER REG.                                       01900021
*        REG.3   BASE REG.                                              01950021
*        REG.4-13 WORK REGS.                                            02000021
*        REG.14  RETURN REG.                                            02050021
*        REG.15  RETURN CODE REG.                                       02100021
*                                                                       02150021
*02*     PATCH-LABEL = PTCHAREA, 10 WORDS RESERVED FOR PTCHAREA         02200021
*                                                                       02250021
*01* MODULE-TYPE = PROCEDURE,  TRANSIENT SVC                            02300021
*                                                                       02350021
*02*     PROCESSOR = ASSEMBLER F                                        02400021
*                                                                       02450021
*02*     MODULE-SIZE = 1024 BYTES                                       02500021
*                                                                       02550021
*02*     ATTRIBUTES = PROTECT KEY ZERO, REENTRANT                       02600021
*                                                                       02650021
*01* ENTRY-POINT = IGC0007F                                             02700021
*                                                                       02750021
*02*     PURPOSE = TO RECORD TO SYS1.LOGREC DATA SET                    02800021
*                                                                       02850021
*02*     LINKAGE = INVOKED BY ISSUING SVC 76.                           02900021
*                                                                       02950021
*02*     INPUT = INPUT PARMS ARE-                                       03000021
*        REG.0 - TWOS COMPLEMENT OF NUMBER OF BYTES TO BE RECORDED      03050021
*        REG.1 - ADDRESS OF DATA TO BE RECORDED                         03100021
*                                                                       03150021
*02*     OUTPUT = INPUT TO SYS1.LOGREC DATA SET                         03200021
*                                                                       03250021
*02*     EXIT-NORMAL = (1) INSTRUCTION FOLLOWING THE SVC CALL           03300021
*                      (2) XCTL TO IGC0307F(IFBSTAT0)                   03350021
*        REG.15 = ZERO                                                  03400021
*                                                                       03450021
*02*     EXIT-ERROR = (1) INSTRUCTION FOLLOWING THE SVC CALL            03500021
*                     (2) XCTL TO IGC0207F(IFBSTAT2)                    03550021
*        REG.15 = TWELVE - NO SPACE AVAILABLE (NORECORDING ATTEMPTED)   03600021
*        REG.15 = SIXTEEN - PERM.I/O ERROR WHILE ATTEMPTING TO RECORD   03650021
*                                                                       03700021
*01* EXTERNAL-REFERENCES =                                              03750021
*                                                                       03800021
*02*     ROUTINES = SVC 00,SVC 07                                       03850021
*                                                                       03900021
*02*     DATA-SETS = SYS1.LOGREC                                        03950021
*                                                                       04000021
*02*     DATA-AREAS = INPUT DATA AREA,CVT,LOGDCB,WORK AREA              04050021
*                                                                       04100021
*01* TABLES = WORK AREA OBTAINED FROM SP-253 (256 BYTES)                04150021
*                                                                       04200021
*01* MACROS = GETMAIN,ENQ,DEQ,FREEMAIN,WAIT                             04250021
*                                                                       04300021
**** END OF SPECIFICATIONS *********************************/           04350021
       EJECT                                                            04400021
*                        HEADER  RECORD  AREA                         * 04450021
*       *************************************************************** 04500021
*       *              *                                *     HIGH    * 04550021
*  +0   *  F F F F     *          LOW EXTENT            *   EXTENT    * 04600021
*       *              *            (CCHH)              *      (CC)   * 04650021
*       *************************************************************** 04700021
*       * HIGH EXTENT  *       *         RECORD ENTRY AREA ADDRESS    * 04750021
*  +8   *   (CONT.)    * SPARE *                (BBCCHHR)             * 04800021
*       *    (HH)      *       *                                      * 04850021
*       *************************************************************** 04900021
*       *  REC. ENTRY  *  REMAINING     *  TOTAL BYTES  *  ADDRESS OF * 04950021
*  +16  * AREA ADDR.   *   BYTES ON     *      ON       *  LAST RECORD* 05000021
*       *    (CONT.)   *     TRACK      *    TRACK      *    WRITTEN  * 05050021
*       *************************************************************** 05100021
*       *           ADDRESS OF LAST RECORD       * TRACKS      * EARLY* 05150021
*  +24  *                WRITTEN (CONT.)         *    PER      * WARN.* 05200021
*       *                                        * CYLINDER    *  CNT.* 05250021
*       *************************************************************** 05300021
*       * EARLY * DEV- *     EARLY WARNING              * EARLY*  CK. * 05350021
*  +32  * WARN. *  ICE *               MESSAGE TRACK    * WARN.* BYTE * 05400021
*       * CNT.  * CODE *                                * SWT. * (FF) * 05450021
*       *************************************************************** 05500021
         EJECT                                                          05550021
ZEROREG  EQU   0                                                        05600021
LINKREG  EQU   1                                                        05650021
PARMREG1 EQU   1                                                        05700021
VECTREG  EQU   2                                                        05750021
BASEREG  EQU   3                                                        05800021
WORK4    EQU   4                                                        05850021
WORK1    EQU   5                                                        05900021
WORK2    EQU   6                                                        05950021
WORK3    EQU   7                                                        06000021
WORKREG  EQU   8                                                        06050021
WORK5    EQU   9                                                        06100021
SIZEREG  EQU   10                                                       06150021
RECADREG EQU   11                                                       06200021
REG12    EQU   12                                                       06250021
REG13    EQU   13                                                       06300021
RETRNREG EQU   14                                                       06350021
CODEREG  EQU   15                                                       06400021
*                                                                       06450021
EXTENTNG EQU   X'42'              NOT WITHIN EXTENT COMP CODE IN ECB    06500021
NORMAL   EQU   X'7F'               NORMAL COMPLETION CODE IN ECB        06550021
INTCEPT  EQU   X'44'               INTERCEPT CODE IN ECB                06600021
*                                                                       06650021
C8       EQU   8                                                 19E09  06700021
C16      EQU   16                                                       06750021
ZERO     EQU   0                                                        06800021
ONE      EQU   1                                                        06850021
TWO      EQU   2                                                        06900021
THREE    EQU   3                                                        06950021
FOUR     EQU   4                                                        07000021
FIVE     EQU   5                                                        07050021
SIX      EQU   6                                                        07100021
XCTLNO7  EQU   7                                                        07150021
SEVEN    EQU   7                                                        07200021
OCTO     EQU   8                        DECIMAL 8                       07250021
EQUAL    EQU   8                                                        07300021
EIGHT    EQU   8                                                        07350021
TWELVE   EQU   12                                                       07400021
ENQUEUE  EQU   56                                                       07450021
DEQUEUE  EQU   48                                                       07500021
TWOFORTY EQU   X'F0'                         DECIMAL 240                07550021
GETMAIN  EQU   4                                                        07600021
SIXTEEN  EQU   16                                                       07650021
TWENTY9  EQU   29                                                       07700021
FORTY8   EQU   48                                                       07750021
FORTY9   EQU   49                                                       07800021
FIFTY6   EQU   56                                                       07850021
SIXTY    EQU   60                                                       07900021
L96      EQU   96                                                       07950021
TWO38    EQU   238                                                      08000021
TWO53    EQU   253                                                      08050021
TWO56    EQU   256                                                      08100021
XZERO    EQU   X'00'                                                    08150021
XONE     EQU   X'01'                                                    08200021
XTWO     EQU   X'02'                                                    08250021
XT20     EQU   X'20'                                                    08300021
X42      EQU   X'42'                                                    08350021
X80      EQU   X'80'                    80 IN XEX                       08400021
XEIGHTY  EQU   X'80'                                                    08450021
XFF      EQU   X'FF'                                                    08500021
XF7      EQU   X'F7'                                                    08550021
         EJECT                                                          08600021
EXCP     EQU   0                                                        08650021
RETURN   EQU   3                                                        08700021
IOBF0    EQU   4                  ECB POINTER FIELD IN IOB              08750021
IOBF2    EQU   16                 START ADDRESS IN IOB                  08800021
IOBF3    EQU   20                  DCB ADDRESS IN 10B                   08850021
DEBF2    EQU   32                 UCB POINTER FIELD IN DEB              08900021
WTO      EQU   35                                                       08950021
DEBF4    EQU   36                 BBCCHH OF EZTENT LOCATED IN DEB       09000021
DCBF0    EQU   44                 DEB POINTER FIELD IN DCB              09050021
UCBF3B   EQU   19                 DEV TYPE BYTE IN UCB DEV TYPE FIELD   09100021
         EJECT                                                          09150021
*                                                                       09200021
IGC0007F CSECT                                                          09250021
         USING LOGDSECT,WORK5                                           09300021
LOGDSECT DSECT                                                          09350021
WCFIELD  DS    CL2                 UNUSED                               09400021
CTFIELD  DS    CL10               RECORD ENTRY TP ERROR                 09450021
CTFLDID  EQU   CTFIELD            COUNT FIELD ID-CCHHR                  09500021
CTFLD4D  EQU   CTFIELD+4                                                09550021
CTFLDKEY EQU   CTFIELD+5          COUNT FIELD KEY LENGTH                09600021
CTFLDDL  EQU   CTFIELD+6          COUNT FIELD DATA LENGTH               09650021
         DS    0H                                                       09700021
BUFFAREA DS    CL10               27 PLANT CNTRL MPXOR                  09750021
RECSIZE  EQU   BUFFAREA           SIZE OF RECORD                        09800021
         DS    0D                                                       09850021
CCWAREA  DS    CL56                CHANNEL PROGRAM                      09900021
MSGAREA  EQU   CCWAREA                                                  09950021
XCTL     EQU   CCWAREA                                                  10000021
CCW8     EQU   CCWAREA+8                                                10050021
CCW16    EQU   CCWAREA+16                                               10100021
CCW24    EQU   CCWAREA+24                                               10150021
CCW32    EQU   CCWAREA+32                                               10200021
CCW40    EQU   CCWAREA+40                                               10250021
CCW44    EQU   CCWAREA+44                                               10300021
CCW48    EQU   CCWAREA+48                                               10350021
CCW54    EQU   CCWAREA+54                                               10400021
         DS    CL8                 SPARE                                10450021
         DS    0D                                                       10500021
TPRIOB   DS    CL32                IOB FLAG                             10550021
EXCPSEEK DS    CL8                SEEK ADDRESS FOR EXCP OF HD REC       10600021
EXCPSEK1 EQU   EXCPSEEK+1                                               10650021
EXCPSEK3 EQU   EXCPSEEK+3                                               10700021
EXCPSEK7 EQU   EXCPSEEK+7                                               10750021
STARADR  DS    CL4                ADDRESS OF 12*                        10800021
SEEKADR  DS    CL7                BBCCHHR USED FOR RD/WR                10850021
SEEKADR2 EQU   SEEKADR+2                                                10900021
SEEKADR6 EQU   SEEKADR+6                                                10950021
FLAGS    DS    CL1                INTERNAL 27 PLANT CTRL MPXOR          11000021
HDRREC   DS    CL40                     HEADER RECORD                   11050021
HDRID    EQU   HDRREC+0                                                 11100021
LOWLIMIT EQU   HDRREC+2                                                 11150021
UPLIMIT  EQU   HDRREC+6                                                 11200021
SPARE    EQU   HDRREC+10                                                11250021
RESTART  EQU   HDRREC+11                                                11300021
BYTSREM  EQU   HDRREC+18                                                11350021
TRKCAP   EQU   HDRREC+20                                                11400021
LASTTTR  EQU   HDRREC+22                                                11450021
LASTTR2  EQU   HDRREC+24                                                11500021
LASTTR4  EQU   HDRREC+26                                                11550021
LASTTR6  EQU   HDRREC+28                                                11600021
TRKSPER  EQU   HDRREC+29                                                11650021
TRKSPER1 EQU   HDRREC+30                                                11700021
EWMCNT   EQU   HDRREC+31                                                11750021
EWMTRK   EQU   HDRREC+34                                                11800021
EWMSW    EQU   HDRREC+38                                                11850021
SFTYBYTS EQU   HDRREC+39                                                11900021
         DS    0F                                                       11950021
TPRECB   DS    CL4                 ECB FLAG                             12000021
         DS    0D                                                       12050021
SAVEREGS DS    CL55                     SAVE AREA FOR GEN PURPSE REG    12100021
OBRINPGR DS    CL1'0'              IN PROGRESS STAT                     12150021
         USING CVTDSECT,VECTREG   ADDRESS OF DSECT FOR CVT              12200021
CVTDSECT DSECT                                                          12250021
         EJECT                                                          12300021
EQUATE   CVT   SYS=MIN                                                  12350021
IGC0007F CSECT                                                          12400021
         EJECT                                                          12450021
*******************************************************************     12500021
*********************************************************************** 12550021
*                                                                     * 12600021
*                                                                 *     12650021
****           SYS1.LOGREC RECORDER MODULE                         **** 12700021
*                                                                     * 12750021
*                                                                 *     12800021
*                                                                 *     12850021
*********************************************************************** 12900021
*******************************************************************     12950021
         BALR  BASEREG,ZEROREG          SET UP BASE REGISTER            13000021
         USING *,BASEREG                                                13050021
         L     VECTREG,CVTPTR           LOAD CVT POINTER                13100021
         L     WORK5,CVTDCB             LOAD ADDR OF LOG DCB            13150021
         TM    FORTY8(WORK5),XONE       TEST FOR EXTENDED DCB           13200021
         BC    EQUAL,XWRK               BR NOT EXTENDED DCB             13250021
         LA    WORK5,SIXTY(WORK5)       USE DCB EXTENSION               13300021
         B     XWRKA                    BYPASS USE OF LOG AREA          13350021
XWRK     L     WORK5,WRKADR             USE LOG AREA                    13400021
XWRKA    LR    RECADREG,PARMREG1        FREE REG 1                      13450021
         LTR   ZEROREG,ZEROREG          TEST ZERO REG FOR MINUS         13500021
         BNM   EXITOTH                  NO - XFER TO NEXT LOAD          13550021
         LPR   ZEROREG,ZEROREG          REG ZEOR TO PLUS VALUE          13600021
         BCR   EQUAL,RETRNREG           REC SIZE ZERO-RETURN    SA60671 13620021
         LR    SIZEREG,ZEROREG          FREE REG 0                      13650021
         LA    WORK4,OBRINPGR           GET ADR OF OBRINPGR             13700021
         TM    ZERO(WORK4),OCTO         TEST OBRINPGR FLAG              13750021
         BO    RTRN1                    ON - EXIT                       13800021
         OI    ZERO(WORK4),OCTO         SET IT ON                       13850021
         SSM   ENABLE                   ENABLE ALL INTERUPTS            13900021
         LA    WORK1,L96(WORK1)         ADDR OF SVRB EXT                13950021
         MVC   ZERO(SIXTEEN,WORK1),MAINTAB   MOVE GETMAIN TABLE TO SVRB 14000021
         LR    PARMREG1,WORK1                POINT REG 1 TO TABLE       14050021
         LA    WORK1,TWELVE(WORK1)           FETCH ADDR OF GOTTEN CORE  14100021
         ST    WORK1,FOUR(PARMREG1)          STORE IN TABLE             14150021
         LR    WORK1,PARMREG1                RESTORE WORK1              14200021
         SVC   GETMAIN                       ISSUE SVC TOGET CORE       14250021
         LTR   CODEREG,CODEREG          CK SUCCESSFUL GETMAIN           14300021
         BZ    STGAVAIL                 YES,CONTINUE RECORDING          14350021
         LA    CODEREG,TWELVE           NO,SET COND CODE                14400021
         BR    RETRNREG                 RETURN TO CALLER                14450021
STGAVAIL L     WORK5,TWELVE(WORK1)           SET BASE OF WORK STG       14500021
         XC    WCFIELD(TWO56),WCFIELD   CLEAR GOTTEN STG                14550021
*********************************************************************** 14600021
*     THIS CODE RESOLVES ADCONS IN GETMAIN AREA AND ISSUES ENQ        * 14650021
*********************************************************************** 14700021
         LA    PARMREG1,TWOFORTY(WORK5)      ADDR OF FIRST AVAIL WORD   14750021
         MVC   ZERO(FOUR,PARMREG1),NQCON     MOVE IN FLAGS FOR ENQ-DEQ  14800021
         LA    WORKREG,RESID                 FETCH ADDR OF QNAME        14850021
         ST    WORKREG,FOUR(PARMREG1)        STORE IN NEXT WORD         14900021
         LA    WORKREG,LOGREC                FETCH ADDR OF RNAME        14950021
         ST    WORKREG,EIGHT(PARMREG1)       STORE IN NEXT WORD         15000021
         SVC   ENQUEUE                       ISSUE ENQUEUE              15050021
*                                                                       15100021
*     THIS CODE RESOLVES ABSOLUTE MEMORY ADDRESS REFERENCES             15150021
*     WHICH WILL NOT BE RESOLVED BY THE LOADER.                         15200021
*                                                                       15250021
         MVC   CCWAREA(FIFTY6),HDRCCW   MOVE CHANNEL PROGRAM            15300021
         LA    WORKREG,CCWAREA          ADR OF FIRST CCW IN CHAIN       15350021
         ST    WORKREG,CCW8             STORE CCWAREA                   15400021
         MVI   CCW8,OCTO                SET COMM CODE IN CCW            15450021
         LA    WORKREG,SEEKADR2         RESOLVE ADDRESS                 15500021
         ST    WORKREG,CCWAREA          STORE BACK IFST CCW             15550021
         MVI   CCWAREA,FORTY9                                           15600021
         LA    WORKREG,HDRREC           RESOLVE HDRREC                  15650021
         ST    WORKREG,CCW16            STORE                           15700021
         MVI   CCW16,SIX                                                15750021
*                                                                       15800021
         EJECT                                                          15850021
*           PROGRAM  SETUP TO FETCH HEADER RECORD                       15900021
*                                                                       15950021
         L     WORK1,CVTDCB             LOAD ADDR OF SER DCB            16000021
         ST    WORK1,TPRIOB+IOBF3       STORE DCB ADDRESS IN IOB        16050021
         L     WORK1,DCBF0(WORK1)       LOAD ADDR OF SER DEB            16100021
         MVC   SEEKADR(SIX),DEBF4(WORK1) MOVE BBCCHH FROM DEB           16150021
         MVI   SEEKADR6,ONE             SET SEARCH FIELD TO ID ONE      16200021
         LA    WORK2,TPRECB             ECBADDRESS                      16250021
         ST    WORK2,TPRIOB+IOBF0       STORE ECB ADDR IN IOB           16300021
         LA    WORK2,CCWAREA            CCW ADDRESS                     16350021
         ST    WORK2,TPRIOB+IOBF2       ST CHAN PROG ADR IN IOB         16400021
         MVI   TPRIOB,X42               SET FLAG 1 FIELD IN IOB         16450021
         MVC   EXCPSEK1(SIX),SEEKADR    PLACE SEEK ADR FOLL IOB         16500021
         BAL   WORK1,ERR3B              GET HEADER RECORD               16550021
CMPLTOK  CLI   SFTYBYTS,XFF             COMPARE SAF BYTE IN HD          16600021
         BC    SEVEN,ERROR2             BR IF NOT ONE'S(INCORRECT)      16650021
*                                                                       16700021
***      ROUTINE TO PICK UP BUFFER & SET UP RECORD       *****          16750021
*                                                                       16800021
         STH   SIZEREG,CCW54            STORE COUNT IN CCW              16850021
         STH   SIZEREG,CTFLDDL          SAVE RECORD SIZE                16900021
         ST    RECADREG,CCW48           RECORD ADDR TO CCW              16950021
         EJECT                                                          17000021
*                                                                       17050021
*                                                                       17100021
*****  ROUTINE TO DETERMINE IF ENOUGH BYTES REMAINING ON TRACK          17150021
*                                                                       17200021
TRCKCAP  L     WORK1,CVTDCB             LOAD ADD OF SER'S DCB           17250021
         L     WORK1,DCBF0(WORK1)       LOAD ADD OF SER'S DEB           17300021
         L     WORK2,DEBF2(WORK1)       LOAD UCB ADDR FROM DEB          17350021
         SLR   WORK3,WORK3              CLEAR REGISTER                  17400021
         IC    WORK3,UCBF3B(WORK2)      EXTRACT DEVICE TYPE FROM UCB    17450021
         SLL   WORK3,ONE                POSITION FIELD FOR INDEX        17500021
         LH    WORK1,SUBCONST(WORK3)    LOAD SUBTR CONSTANT             17550021
         LH    LINKREG,CTFLDDL          GET SIZE OF RECORD              17600021
         N     LINKREG,ZEROFOX          MASK OUT TOP HALF      @SA70174 17620021
         AR    WORK1,LINKREG            ADD SIZE TO CONSTANT            17650021
         CLC   UPLIMIT(FOUR),LASTTR2    LAST TRACK?            @SA70174 17651021
         BC    SEVEN,CAPTRK             BR IF NOT EQUAL        @SA70174 17652021
         CLI   UCBF3B(WORK2),SEVEN      2305-II ?              @SA70174 17653021
         BC    SEVEN,CAPTRK             BR IF NO               @SA70174 17654021
         AH    WORK1,SUBCONST(WORK3)    ADD SUBTR              @SA70174 17655021
         LA    WORK1,ONE(WORK1)              CONST             @SA70174 17656021
CAPTRK   EQU   *                                               @SA70174 17657021
         CH    WORK1,TRKCAP             LENGTH EXCEED CAPACITY @SA64401 17660021
         LA    CODEREG,TWELVE           SET UP RCODE           @SA70174 17670021
         BH    RTRN                     EXIT                   @SA64401 17680021
         MVC   EXCPSEK7(ONE),LASTTR6    SET ID IN IOB SEEK FIELD        17700021
TPR50    LH    WORK2,BYTSREM            NO OF BYTES REM ON TRACK        17750021
         SLR   WORK2,WORK1              SUB APP VALUE FROM REM BYTES    17800021
         BC    ONE,TPR53                BR IF REC WILL FIT ON TRACK     17850021
         LH    WORK2,LASTTR4            LOAD LAST USED HEAD POSITION    17900021
         AL    WORK2,CONST1             ADD ONE TO HD POSITION          17950021
         SLR   WORK3,WORK3              CLEAR REGISTER                  18000021
         IC    WORK3,TRKSPER            LOAD NO OF TRACKS PER CYL       18050021
         SLL   WORK3,EIGHT              SHIFT LEFT EIGHT                18100021
         IC    WORK3,TRKSPER1           INSERT OTHER BYTE               18150021
         CLR   WORK3,WORK2              COMP HD CT TO TRACKS/CYL        18200021
         BL    TPR52                    BR IF END OF CYLINDER           18250021
TPR51    STH   WORK2,LASTTR4            SET UPDT HD CT IN HRD REC       18300021
         MVI   EXCPSEK7,ZERO            SET ID IN IOB SEEK FIELD TO 0   18350021
         MVI   LASTTR6,ZERO             SET REC ENTRY ID TO ZERO        18400021
         MVC   BYTSREM(TWO),TRKCAP      SET REMG BYTES ON TRK TO MAX    18450021
         B     TPR50                    REPEAT                          18500021
TPR52    SLR   WORK2,WORK2              CLEAR REG.(NEW TRACK NO)        18550021
         LH    WORK3,LASTTR2            LOAD LAST USED CYLINDER POS     18600021
         AL    WORK3,CONST1             UPDATE CYLINDER COUNT           18650021
         STH   WORK3,LASTTR2            STORE UPDT CYLINDER COUNT       18700021
         B     TPR51                    REPEAT                          18750021
TPR53    STH   WORK2,BYTSREM            STORE REMG BYTE COUNT           18800021
         CLC   UPLIMIT(FOUR),LASTTR2    COMPARE CCHH WITH EXTENT        18850021
         BC    FOUR,ERROR1              CURRENT CCHH IS ABOVE EXTENT    18900021
         BC    EQUAL,HERE               BR-DONT SET HD SWITCH READ      18950021
         MVI   FLAGS,XEIGHTY            SET EOF HEAD SWITCH READ        19000021
HERE     SLR   WORK1,WORK1              CLEAR REG                       19050021
         IC    WORK1,LASTTR6            LOAD ID OF LAST ID WRITTEN      19100021
         AL    WORK1,CONST1             ADD ONE TO ID FIELD             19150021
         STC   WORK1,LASTTR6            UPDATE LAST ID WRITTEN IN HRD   19200021
         MVC   CTFLDID(FIVE),LASTTR2    SET UP COUNT FIELD ID FOR RE    19250021
*                                                                       19300021
***    THIS CODE RESOLVES ABSOLUTE MEMORY ADDRESS REFERENCES            19350021
*          WHICH WILL NOT BE RESOLVED BY THE LOADER                     19400021
*                                                                       19450021
TPR34    LA    LINKREG,CCW24            ADD OF 1ST WRT CCW CHAIN        19500021
         ST    LINKREG,CCW32            RESOLVE TIC ADR                 19550021
         MVI   CCW32,OCTO               RESTORE CMD CODE                19600021
         LA    LINKREG,EXCPSEK3         RESOLVE SEEK ADR IN CCW         19650021
         ST    LINKREG,CCW24            STORE                           19700021
         MVI   CCW24,FORTY9             RESTORE CMD CODE IN CCW CHAIN   19750021
         LA    LINKREG,CTFIELD          RESOLVE RE ADR IN CCW           19800021
         ST    LINKREG,CCW40            STORE                           19850021
         MVI   CCW40,TWENTY9            RESTORE CMD CODE                19900021
*                                                                       19950021
****   ROUTINE TO SETUP AND WRITE THE COMPLETED RECORD ENTRY            20000021
*                                                                       20050021
         LA    WORK1,CCW24              ADR OF WRITE CCW CHAIN          20100021
         ST    WORK1,TPRIOB+IOBF2       STORE CCW ADD IN IOB            20150021
         MVC   EXCPSEK1(SIX),LASTTTR    PLACE SEEK ADDR FOLLOWING IOB   20200021
         BAL   WORK1,ERR3B              BRANCH TO EXCP                  20250021
*                                                                       20300021
****   ROUTINE TO SETUP AND WRITE AN END OF FILE                        20350021
*                                                                       20400021
         TM    FLAGS,X80                TEST IF HD SWITCHING READ       20450021
         BC    ONE,SWITCH               BR HEAD SWTNG REQUIRED          20500021
         MVC   EXCPSEK1(SEVEN),LASTTTR  MOVE SEEK ADDR TO IOB           20550021
         MVI   CTFLD4D,XFF              SET END OF FILE TD              20600021
         B     WRTEOF        ...   BR TO TERMINATION                    20650021
SWITCH   CLC   EXCPSEK1(SEVEN),RESTART  IS THIS THE 1ST ENTRY           20700021
         BNE   EWMSG                    NO- EOF HAS BEEN WRITTEN        20750021
         XC    EXCPSEK3(FIVE),EXCPSEK3  CLEAR SEEK ADDR                 20800021
         MVC   EXCPSEK3(FOUR),UPLIMIT   MOVE SEEK ADDR IN IOB           20850021
         MVI   CTFLD4D,XONE             SET END OF FILE ID              20900021
WRTEOF   MVC   CTFLDID(FOUR),EXCPSEK3   MOVE CCHH TO EOF RECORD         20950021
         XC    CTFLDKEY(THREE),CTFLDKEY CLEAR RECORD COUNT FIELD        21000021
         MVI   CCW44,XT20               RESTORE SILI BIT FOR INCCCT SIZ 21050021
         BAL   WORK1,ERR3B              BRANCH TO EXCP                  21100021
         EJECT                                                          21150021
*****  ROUTINE TO WRITE HEADER RECORD BACK TO SYS RES                   21200021
*                                                                       21250021
EWMSG    TM    EWMSW,X80                CK EARLY WARNING MESS ISSUED    21300021
         BO    BYEWM                    YES-BYPASS CK FOR EWM           21350021
         CLC   LASTTR2(FOUR),EWMTRK     CK 90% TRK REACHED              21400021
         BL    BYEWM                    NO-BYPASS                       21450021
         BH    WMSG                    TRK EXCEEDED GO WRT MSG          21500021
         CLC   BYTSREM(TWO),EWMCNT      CK 90% BYTE COUNT REACHED       21550021
         BH    BYEWM                    NO-BYPASS                       21600021
WMSG     OI    EWMSW,X80               SET EWM ISSUED SWITCH            21650021
         OI    FLAGS,XONE              SET EWM NEEDED SW                21700021
BYEWM    DS    0C                                                       21750021
         MVI   CCW16,FIVE               CMD CODE TO WRT HDR BACK        21800021
WRTHDR   LA    WORK1,CCWAREA            ADDR OF CCW'S TO WRT HDR        21850021
         ST    WORK1,TPRIOB+IOBF2       STORE CCW ADR IN IOB            21900021
         MVC   EXCPSEK1(SEVEN),SEEKADR  PLACE SEEK ADDR FOLLO IOB       21950021
         BAL   WORK1,ERR3B              BRANCH OT EXCP                  22000021
EXIT1B   SR    CODEREG,CODEREG          SET CONDITION CODE 00           22050021
RTRN     NI    ZERO(WORK4),XF7          RESET OBRINPGR FLAG             22100021
         LA    PARMREG1,TWOFORTY(WORK5)      ADDR OF FIRST AVAIL WORD   22150021
         SVC   DEQUEUE                       ISSUE DEQUEUE              22200021
         TM    FLAGS,EIGHT             TST FOR ERR ONE                  22250021
         BO    ERROR1A                 BR TO SET FOR ERROR              22300021
         TM    FLAGS,FOUR              TST FOR ERR TWO                  22350021
         BO    ERROR2A                 BR TO SET FOR ERROR              22400021
         TM    FLAGS,TWO               TST FOR ERR THREE                22450021
         BO    ERROR4A                 BR TO SET FOR ERROR              22500021
         TM    FLAGS,XONE              TST EWM NEEDED SW                22550021
         BO    MSGEW                   BR TO WRT MSG                    22600021
         LR    PARMREG1,WORK5           SET UP TO FREE STG              22650021
         FREEMAIN R,LV=TWO56,SP=TWO53,A=(1)                             22700021
RTRN1    BR    RETRNREG                 RETURN                          22750021
*                                                                       22800021
****       EXCP AND CHECK COMPLETION  CODE IN ECB        ****           22850021
*                                                                       22900021
ERR3B    XC    TPRECB(FOUR),TPRECB      CLEAR ECB                       22950021
         LA    LINKREG,TPRIOB           ADDRESS OF IOB                  23000021
         SVC   EXCP                     SUPERVISOR CALL TO EXCP         23050021
         WAIT  ONE,ECB=TPRECB                                           23100021
         CLI   TPRECB,INTCEPT           COMP COMPLETION CODE IN ECB     23150021
         BC    EIGHT,ERR3B              BR TO EXCP AGAIN                23200021
         CLI   TPRECB,NORMAL            COMPARE COMPLETION CODE IN ECB  23250021
         BCR   EIGHT,WORK1              BRANCH IF COMPLETED OK          23300021
         CLI   TPRECB,EXTENTNG          COMP COMPLETION CODE IN ECB     23350021
         BC    EIGHT,ERROR1             BR IF NOT WITHIN EXTENT         23400021
         B     ERROR4                   BRANCH I/O FAILURE              23450021
*                                                                       23500021
*                                                                       23550021
*                                                                       23600021
ERROR1A  LA    REG12,ZERO               SET R12 TO MESSAGE CODE         23650021
         B     EXITMSG                  EXIT TO MESSAGE MODULE          23700021
ERROR2A  LA    REG12,FOUR               SET R12 TO MESSAGE CODE         23750021
         B     EXITMSG                  EXIT TO MESSAGE MODULE          23800021
ERROR4A  LA    REG12,EIGHT              SET R12 TO MESSAGE CODE         23850021
         B     EXITMSG                  EXIT TO MESSAGE MODULE          23900021
MSGEW    LA    REG12,TWELVE             SET R12 TOM MESSAGE CODE        23950021
EXITMSG  LR    REG13,RETRNREG           SET UP RETURN                   24000021
         XC    XCTL(C16),XCTL           CLEAR XCTL AREA                 24050021
         MVC   XCTL+C8(C8),MSGMOD       MOVE NAME INTO SAVE             24100021
         B     MSGEXIT                  BR TO XCTL                      24150021
*    SET UP AND XCTL TO NXT LOAD OF SVC 76                              24200021
ERROR1   OI    FLAGS,EIGHT             SET FOR ERR ONE                  24250021
         B     RTRN                    BR TO DEQ                        24300021
ERROR2   OI    FLAGS,FOUR              SET FOR ERR TWO                  24350021
         B     RTRN                    BR TO DEQ                        24400021
ERROR4   OI    FLAGS,TWO               SET FOR ERR THREE                24450021
         B     RTRN                    BR TO DEQ                        24500021
*                                                                       24550021
EXITOTH  LR    REG13,RETRNREG           SET RETRN FOR NEXT LOAD         24600021
         LR    WORK3,ZEROREG            PASS PARM                       24650021
         XC    XCTL(C16),XCTL          CLEAR XCTL SAVE AREA             24700021
         MVC   XCTL+C8(C8),ENTRYPT      MOVE NAME INTO SAVE             24750021
MSGEXIT  LA    CODEREG,XCTL+C8          LOAD ENTRY POINT ADDRESS        24800021
         ST    CODEREG,XCTL             STORE ENTRY POINT ADDRESS       24850021
         LA    CODEREG,XCTL             LOAD ADDRESS OF SAVE AREA       24900021
         SVC   XCTLNO7                  FETCH AND PASS CONTROL          24950021
         EJECT                                                          25000021
*                                                                       25050021
*****     CONSTANTS AND CCW'S                                           25100021
*                                                                       25150021
*                                                                       25200021
HDRCCW   CCW   49,0,X'40',5        SEARCH ON ID                         25250021
TIC      CCW   8,0,X'40',1         TRANSFER IN CHANNEL                  25300021
TIC2     CCW   6,0,X'00',40             READ HDR RECORD                 25350021
         SPACE 2                                                        25400021
WRTCCW   CCW   49,0,X'40',5        SEARCH ON ID EQUAL                   25450021
         CCW   8,0,X'40',1         TRANSFER IN CHANNEL                  25500021
         CCW   29,0,X'80',8             WRT CKD 8 BYTES DATA CHAINED    25550021
         CCW   29,0,X'20',0        TO RECORD ENTRY                      25600021
         DS    0F                                                       25650021
WRKADR   DC    XL4'90'                  LOGOUT  AREA                    25700021
CONST1   DC    XL4'1'                   CONSTANT OF ONE                 25750021
SUBCONST DC    XL2'10'                  TABLE OF SUBTRACTION CONSTANTS  25800021
         DC    AL2(085)                 2311    SUBTRACT CONSTANT       25850021
         DC    AL2(133)                 2301    SUBTRACT CONSTANT       25900021
         DC    AL2(108)                 2303    SUBTRACT CONSTANT       25950021
         DC    AL2(085)                 2302    SUBTRACT CONSTANT       26000021
         DC    AL2(107)                 2321    SUBTRACT CONSTANT       26050021
         DC    AL2(432)                 2305-I  SUBTRACT CONSTANT       26100021
         DC    AL2(198)                 2305-II SUBTRACT CONSTANT       26150021
         DC    AL2(122)                 2314    SUBTRACT CONSTANT       26200021
         DC    AL2(135)                 3330    SUBTRACT CONSTANT       26250021
XTEN     DC    XL2'10'                  TEN                             26300021
NQCON    DC    X'FF080000'                                              26350021
RESID    DC    CL8'LOGREC  '                                            26400021
LOGREC   DC    CL8'RECORDER'                                            26450021
MAINTAB  DC    F'00000256'                   LENGTH                     26500021
         DC    F'0'                          ADDR OF ADDR LIST          26550021
         DC    X'20'                         E C MODE                   26600021
         DC    X'FD'                         SUBPOOL VALUE              26650021
         DC    F'0'                          ADDR OF GOTTEN CORE        26700021
ENTRYPT  DC    C'IGC0307F'              ENTRY POINT NXT LOAD 76         26750021
MSGMOD   DC    C'IGC0207F'              ENTRY POINT TO MSG MOD          26800021
ZEROFOX  DC    F'65535'                 CONST TO AND OUT HIGH ORDER     26850021
ENABLE   EQU   ZEROFOX+3                CONST OF 'FF' FO ENABLE ALL INT 26870021
PTCHAREA  DS    6F            PATCH AREA                       @1926    26900000
PATCHEND EQU   *                                               @21926   26920000
         END                                                            26950021
