         TITLE '              STATISTICS UPDATE TRANSIENT SVC ROUTINE'  00050021
*****************************************************************       00100021
* STATUS -     CHANGE LEVEL = 000 (MODULE SUPPORT CODE S21021)  *       00150021
*                                                               *       00200021
* FUNCTION -   TO CONTINUE THE IPL OR EOD RECORD PROCESSING     *       00250021
*              AFTER LOAD 2(IGC307F) DETERMINED THAT SUCH A     *       00300021
*              RECORD WAS TO BE PLACED ON SYS1.LOGREC.          *       00350021
*                                                               *       00400021
*                A.VIA A WTOR,INFORMATION IS GATHERED FROM      *       00450021
*                  THE OPERATOR TO ASSIST IN FORMULATING AN     *       00500021
*                  IPL RECORD. IF AN EOD IS THE TYPE REQUIRED   *       00550021
*                  CONSTRUCTION OF THE RECORD IS PERFORMED      *       00600021
*                  WITHOUT THE AID OF THE OPERATOR. THE         *       00650021
*                  OPERATOR'S REPLY TO THE SYSTEM IS CHECKED    *       00700021
*                  AND IF FOUND TO BE INVALID A MESSAGE IS      *       00750021
*                  ISSUED TO THAT EFFECT, AND THE INITIAL WTOR  *       00800021
*                  IS REISSUED.                                 *       00850021
*                                                               *       00900021
*                B.AFTER CONSTRUCTION OF THE RECORD(EOD OR IPL) *       00950021
*                  IS COMPLETED CONTROL IS PASSED TO LOAD 1     *       01000021
*                  (IGC0007F) VIA SVC 76 FOR RECORDING                  01050021
*                  OF THE RECORD.                               *       01100021
*                                                               *       01150021
* ENTRY POINT -IGC0107F                                         *       01200021
*                                                               *       01250021
* INPUT -      AT ENTRY -                                       *       01300021
*                REGISTER 3 - ADDRESS OF CVT                    *       01350021
*                REGISTER 2 - ADDRESS OF GOTTEN CORE            *       01400021
*              DURING WTOR PROCESSING -                         *       01450021
*                FOR THE PROPER REPLIES TO THE WTOR             *       01500021
*                CONSULT MESSAGE AND CODES SRL                  *       01550021
*                UNDER IFB010D.                                 *       01600021
*                                                               *       01650021
* OUTPUT -     AN EOD OR IPL RECORD BUILT IN GOTTEN CORE.       *       01700021
*                                                               *       01750021
* EXTERNAL REFERENCES- NOT APPLICABLE                                   01800021
*                                                               *       01850021
* EXITS,NORMAL - EXIT IS MADE TO CALLING PROGRAM VIA REG 14.    *       01900021
*                                                               *       01950021
* EXITS,ERROR - NOT APPLICABLE                                          02000021
*                                                                       02050021
* TABLES/WORK AREAS- 174 BYTES OF GOTTEN CORE IN SUBPOOL 253    *       02100021
*              WHICH WAS ACQUIRED IN LOAD 2 AND WHOSE           *       02150021
*              ADDRESS WAS PASSED IN REGISTER 2                 *       02200021
*                                                               *       02250021
* ATTRIBUTES - TYPE IV SVC,NON-RESIDENT,RE-ENTRANT,PRIVILEGED           02300021
*                                                               *       02350021
* CHARACTER CODE DEPENDENCY- THIS MODULE IS CHARACTER CODE DEPENDENT    02400021
*                            AND MUST BE REASSEMBLED IF MODE CHANGED    02450021
*                            FROM EBCDIC.                               02500021
*                                                                       02550021
* NOTES  - NOT APPLICABLE                                               02600021
*                                                                     * 02610021
* PUBLICATIONS:  I/O SUPERVISOR  GY28-6616                            * 02620021
*                                                                       02650021
         EJECT                                                          02700021
*                             IPL RECORD FORMAT                         02750021
*     *********************************************************         02800021
*     * REC  * OP   *                           * REC  *      *         02850021
* +0  * TYPE * SYS  *         SWITCHES          * CNT  *SPARE *         02900021
*     *      *      *                           *      *      *         02950021
*     *********************************************************         03000021
*     *                           *                           *         03050021
* +8  *           DATE            *         TIME              *         03100021
*     *                           *                           *         03150021
*     *********************************************************         03200021
*     *      *      CPU           *   MODEL     *    MAX      *         03250021
* +16 * RSVD *      SERIAL        *   NUMBER    *    MCEL     *         03300021
*     *      *      NUMBER        *             *    LENGTH   *         03350021
*     *********************************************************         03400021
*     *SUB-   *  CHANNEL UNIT      *   REASON     *  CHANNEL  *         03450021
* +24 *SYSTEM *   ADDRESS OF       *    FOR       *    MAP    *         03500021
*     *  ID   *  FAILING DEVICE    *    IPL       *           *         03550021
*     *********************************************************         03600021
*     *                                                       *         03650021
* +32 *            CHANNEL    TYPE    ASSIGNMENT              *         03700021
*     *                                                       *         03750021
*     *********************************************************         03800021
*     *                            *                          *         03850021
* +40 *        HIGHEST  ADDRESS    *      EXPANSION  BYTES    *         03900021
*     *             AT  IPL        *                          *         03950021
*     *********************************************************         04000021
         EJECT                                                          04050021
*                             EOD RECORD FORMAT                         04100021
*     *********************************************************         04150021
*     * REC  * OP   *                           * REC  *      *         04200021
* +0  * TYPE * SYS  *         SWITCHES          * CNT  *SPARE *         04250021
*     *      *      *                           *      *      *         04300021
*     *********************************************************         04350021
*     *                           *                           *         04400021
* +8  *           DATE            *         TIME              *         04450021
*     *                           *                           *         04500021
*     *********************************************************         04550021
*     *      *      CPU           *   MODEL     *    MAX      *         04600021
* +16 * RSVD *      SERIAL        *   NUMBER    *    MCEL     *         04650021
*     *      *      NUMBER        *             *    LENGTH   *         04700021
*     *********************************************************         04750021
         EJECT                                                          04800021
IGC0107F CSECT                                                          04850021
         USING WORKSTOR,STORADDR                                        04900021
WORKSTOR DSECT                                                          04950021
CCWAREA  DS    3D                       TO HOLD RECORD CCW'S            05000021
XCTL     EQU   CCWAREA                  XCTL SAVE AREA                  05050021
CONVERT  EQU   CCWAREA                  AREA TO ISSUE CVB FROM          05100021
WTOAREA  EQU   CCWAREA                  WTO MESSAGE AREA                05150021
WTOREPLY EQU   CCWAREA                  TO HOLD REPLY OF WTOR           05200021
WTORAREA EQU   CCWAREA+8                WTOR MESSAGE AREA               05250021
WTORLGTH EQU   WTORAREA                 LENGTH OF WTOR REPLY            05300021
WTORADDR EQU   WTORAREA                 ADDR OF WTOR REPLY BUFFER       05350021
WTORECB  EQU   WTORAREA+4               ADDR OF WTOR ECB                05400021
WTORMESS EQU   WTORAREA+8               BASIC STRUCTURE OF WTOR         05450021
* THE FOLLOWING IS THE COUNT FIELD AND IPL/EOD RECORD FORMAT            05500021
ALIGN    DS    CL2                      FOR ALIGNMENT OF RECORDS        05550021
CTFIELD  DS    CL8                      RECORD COUNT FLD -08BYTES       05600021
CTFLDID  EQU   CTFIELD+0                COUNT FIELD ID-CCHHR            05650021
CTFLDKEY EQU   CTFIELD+5                COUNT FIELD KEY LENGTH          05700021
CTFLDDL  EQU   CTFIELD+6                COUNT FIELD DATA LENGTH         05750021
KEY      DS    CL2                      KEY FIELD - 2 BYTES             05800021
RECORD   DS    CL46                     RECORD FORMAT AREA              05850021
SWITCHES EQU   RECORD+0                 USED FOR DATA REDUCTION         05900021
IDINFO   EQU   RECORD+14                START OF D-WORD OF STPID INFO   05950021
CPUID    EQU   RECORD+18                CPU ID                          06000021
CPUSERNO EQU   RECORD+15                CPU SERIAL NUMBER               06050021
DATE     EQU   RECORD+6                 DATE RECORD WAS MADE            06100021
TIME     EQU   RECORD+10                TIME RECORD WAS MADE            06150021
SUBSYSID EQU   RECORD+22                SUBSYSTEM ID                    06200021
CUADDR   EQU   RECORD+23                CUA                             06250021
REASON   EQU   RECORD+26                OPERATOR REASON FOR  IPL        06300021
CHANMAP  EQU   RECORD+28                CHANNELS ON LINE                06350021
CHANASSN EQU   RECORD+30                TYPE OF CHANNEL                 06400021
HIGHADDR EQU   RECORD+38                HIGHEST VALID ADDR AT IPL       06450021
SPARE    EQU   RECORD+42                EXTRA BYTES                     06500021
* THE FOLLOWING IS THE HEADER RECORD FORMAT ON SYS1.LOGREC              06550021
HDRREC   DS    CL38                     HEADER RECORD - 38 BYTES        06600021
LOWLIMIT EQU   HDRREC+0                 STARTING CCHH OF EXTENT         06650021
UPLIMIT  EQU   HDRREC+4                 LAST CCHH OF EXTENT             06700021
TRKSPER  EQU   HDRREC+8                 NO. TRACKS PER CYLINDER         06750021
RESTART  EQU   HDRREC+9                 1ST RECORD BBCCHHR              06800021
BYTSREM  EQU   HDRREC+16                REMAINING BYTES ON TRACK        06850021
TRKCAP   EQU   HDRREC+18                TOTAL TRACK CAPACITY            06900021
LASTTTR  EQU   HDRREC+20                LAST RECORD BBCCHHR USED        06950021
SFTYBYTS EQU   HDRREC+37                TO DETECT OVERRUN COND.         07000021
WORKECB  DS    1F                       ECB                             07050021
WORKIOB  DS    10F                      IOB                             07100021
IOBFLAGS EQU   WORKIOB                  IOB FLAG 1-2 FIELD              07150021
IOBECB   EQU   WORKIOB+4                EVENT CONTROL BLOCK             07200021
IOBSTART EQU   WORKIOB+16               CCW START ADDRESS               07250021
IOBDCB   EQU   WORKIOB+20               DCB ADDRESS                     07300021
IOBSEEK  EQU   WORKIOB+32               SEEK ADDRESS                    07350021
ERRSWTCH DS    0C                       MODEL AND ERROR SWITCH          07400021
RETURNAD DS    1F                       RETURN ADDR SAVE LOCATION       07450021
PARM     DS    1F                       EXIT PARM FROM IGC0007F         07500021
CONDCODE DS    1H                       EXIT CODE FROM IGC0007F         07550021
INPUPARM DS    1H                       REC. LENGTH FROM IGC0007F       07600021
SEEKADDR DS    CL6                      SAVE FOR LOGREC SEEK ADDR       07650021
IGC0107F CSECT                                                          07700021
* THE FOLLOWING ARE REGISTER EQUATES                                    07750021
PARMREG0 EQU   0                        INPUT PARAMETER REGISTER        07800021
PARMREG1 EQU   1                        PARAMETER REGISTER              07850021
STORADDR EQU   2                        ADDR OF GOTTEN STORAGE          07900021
CVTREG   EQU   3                        COMM. VECTOR TABLE ADDR.        07950021
WORK1    EQU   4                        WORK REGISTER                   08000021
XWORK1   EQU   WORK1                                                    08050021
WORK2    EQU   5                        WORK REGISTER                   08100021
WORK3    EQU   6                        WORK REGISTER                   08150021
WORK4    EQU   7                        WORK REGISTER                   08200021
WORK5    EQU   8                        WORK REGISTER                   08250021
LINKREG  EQU   9                        LINK REGISTER                   08300021
BASEREG  EQU   10                       BASE REGISTER                   08350021
RETRNREG EQU   14                       RETURN ADDR REGISTER            08400021
CODEREG  EQU   15                       COMPLETION CODE REGISTER        08450021
* THE FOLLOWING ARE SPECIFIC DISPLACEMENTS                              08500021
UCBDEV   EQU   19                       DEVICE TYPE ADDR IN UCB         08550021
DEBUCBPT EQU   32                       UCB ADDRESS FIELD IN DEB        08600021
DCBDEBPT EQU   44                       DEB ADDRESS FIELD IN DCB        08650021
CVTHIAD  EQU   164                      ADDR OF HIGHEST ADDRESS         08700021
* THE FOLLOWING ARE SVC EQUATES                                         08750021
WAIT     EQU   1                        WAIT                            08800021
XCTLNO7  EQU   7                        XCTL SVC                        08850021
WTO      EQU   35                       WRITE TO OPERATOR               08900021
WTOR     EQU   35                       WRITE TO OPERATOR W/REPLY       08950021
* THE FOLLOWING ARE SPECFIC IMMEDIATE OPERANDS                          09000021
U        EQU   B'11100100'              EBCDIC EQUAL OF LETTER'U'       09050021
TIMEBYTE EQU   X'08'                    TO SET TIME BIT IN RECORD       09100021
IPLTYPE  EQU   X'50'                    CODE FOR IPL RECORD             09150021
EODTYPE  EQU   X'80'                    CODE FOR EOD RECORD             09200021
TEST     EQU   X'FF'                    USE TO CHECK OUT SFTYBYTS       09250021
* THE FOLLOWING ARE CONSTANTS USED THROUGHOUT THE PROGRAM THAT          09300021
* REPRESENT DISPLACEMENT,NUMBER OF BYTES, OR IMMEDIATE OPERANDS.        09350021
C0       EQU   0                                                        09400021
C1       EQU   1                                                        09450021
C2       EQU   2                                                        09500021
C3       EQU   3                                                        09550021
C4       EQU   4                                                        09600021
C5       EQU   5                                                        09650021
C6       EQU   6                                                        09700021
C8       EQU   8                                                        09750021
C9       EQU   9                                                        09800021
C10      EQU   10                                                       09850021
C24      EQU   24                                                       09900021
C40      EQU   40                                                       09950021
C54      EQU   54                                                       10000021
ONE82    EQU   182                                                      10050021
TWO53    EQU   253                                                      10100021
EIGHT    EQU   8                                                        10150021
THIRTEEN EQU   13                                                       10200021
FOURTEEN EQU   14                                                       10250021
THIRTY2  EQU   32                                                       10300021
FORTY8   EQU   48                                                       10350021
FIFTY6   EQU   56                                                       10400021
HEX74    EQU   X'74'                                             S21108 10420021
SEVENTY6 EQU   76                                                       10450021
ONE16    EQU   116                                                      10500021
TWO87    EQU   287                                                      10550021
THREE29  EQU   329                                                      10600021
         EJECT                                                          10650021
*****************************************************************       10700021
*                                                               *       10750021
*              IPL / EOD  RECORD  MODULE                        *       10800021
*                                                               *       10850021
*****************************************************************       10900021
         BALR  BASEREG,C0               SET UP BASE REGISTER            10950021
         USING *,BASEREG                                                11000021
*****    PERFORM  INFORMATION  GATHERING  ROUTINE  FOR  RECORD          11050021
         CLI   INPUPARM+C1,THIRTY2      IS RECORD IPL OR EOD            11100021
         BE    MAKEREC                  BR RECORD IS EOD TYPE           11150021
REISSUE  MVC   WTORMESS(C54),INFOMSG    MOVE MESSAGE TO SAVE AREA       11200021
         LA    WORK1,WTOREPLY           LOAD ADDR OF REPLY AREA         11250021
         ST    WORK1,WTORADDR           ST ADDR IN WTOR STRUCTURE       11300021
         MVI   WTORLGTH,C5              ST LENGTH OF REPLY              11350021
         LA    WORK1,WORKECB            FETCH ECB ADDR                  11400021
         ST    WORK1,WTORECB            STORE IT                        11450021
         XC    WORKECB,WORKECB          CLEAR OUT ECB                   11500021
         LA    PARMREG1,WTORAREA        LOAD ADDRESS OF WTOR            11550021
         SVC   WTOR                     WRITE OPERATOR WITH REPLY       11600021
         WAIT  C1,ECB=WORKECB           WAIT FOR WTOR COMPLETION        11650021
FIRSTHF  LA    WORK1,THIRTEEN           SET UP FOR 13 BCT'S             11700021
         LA    WORK2,REPLYNM            ADDR OF 1ST VALID REPLY         11750021
RECHECK1 CLC   WTOREPLY(C2),C0(WORK2)   IS REPLY OF VALID ONES          11800021
         BE    SECONDHF                 BR-1ST HALF IS VALID            11850021
         LA    WORK2,C2(WORK2)          NO MATCH INDEX TO NEXT          11900021
         BCT   WORK1,RECHECK1           CHECK ALL 9 VALID REPLIES       11950021
         CLI   WTOREPLY,U               DID OPERATOR REPLY 'U'          12000021
         BNE   INFORM                        NO--INFORM OPERATOR        12050021
         XC    CTFIELD(FIFTY6),CTFIELD       CLEAR RECORD AREA          12100021
         MVC   REASON(C2),DEFAULT            MOVE IN DEFAULT CODE       12150021
         B     CONSTHDR                      BR TO CONSTRUCT HEADER     12200021
*****    INFORM  OPERATOR  AND  REISSUE  WTOR  ROUTINE                  12250021
INFORM   MVC   WTOAREA(C40),ERRMSG3     MOVE MESSAGE TO SAVE AREA       12300021
         LA    PARMREG1,WTOAREA         LOAD ADDRESS OF MESSAGE         12350021
         SVC   WTO                      WRITE TO OPERATOR               12400021
         B     REISSUE                  BR-TO REISSUE WTOR              12450021
SECONDHF LA    WORK1,FOURTEEN           SET UP FOR 14 BCT'S             12500021
         LA    WORK2,REPLY00            ADDR OF 1ST VALID REPLY         12550021
RECHECK2 CLC   WTOREPLY+C3(C2),C0(WORK2) IS REPLY OF VALID ONES         12600021
         BE    REPLYOK                  BR-TWO VALID REPLIES            12650021
         LA    WORK2,C3(WORK2)               NO MATCH- INDEX TO NEXT    12700021
         BCT   WORK1,RECHECK2           CHECK -10 VALID REPLIES         12750021
         B     INFORM                   BR-NO MATCH ON 2ND HALF         12800021
*****    CONSTRUCT IPL OR EOD RECORD FOR SYS1.LOGREC                    12850021
REPLYOK  XC    CTFIELD(FIFTY6),CTFIELD  CLEAR RECORD AREA               12900021
         MVC   REASON(C2),WTOREPLY      MOVE REASON INTO RECORD         12950021
         MVC   SUBSYSID(C1),C2(WORK2)        MOVE SS ID CODE            13000021
         B     CONSTHDR                 BR.TO CONSTRUCT HEADER          13050021
MAKEREC  XC    CTFIELD(FIFTY6),CTFIELD  CLEAR RECORD AREA               13100021
CONSTHDR TM    ERRSWTCH,C2              IS MODEL 195 OR NS              13150021
         BZ    NSTYPE                   BR - MODEL IS NS                13200021
         MVC   CPUID(C2),ID195          MOVE CPUID INTO RECORD          13250021
         L     WORK1,HEX74              GET MCHNPSW              S21108 13300021
         CLC   C0(C4,WORK1),DIAGNOSE    TEST FOR 370             S21108 13350021
         BNE   TIMETYPE                 NO-BRANCH AROUND         S21108 13400021
NSTYPE   STIDP IDSTOR                   STORE CPU ID ON 370      S21108 13450021
         MVC   IDINFO(C8),IDSTOR        MOVE ID INFORMATION             13500021
TIMETYPE OI    SWITCHES,TIMEBYTE        SET UP TIME TYPE IN REC.        13550021
         CLI   INPUPARM+C1,THIRTY2      IS RECORD IPL OR EOD            13600021
         BE    STORTYPE                 EOD IS THE TYPE OF RECORD       13650021
         OI    KEY,IPLTYPE              IPL IS TYPE OF RECORD           13700021
         B     RELNUM                   BR-TO FIND RELEASE NUMBER       13750021
STORTYPE OI    KEY,EODTYPE              INSERT EOD TYPE IN RECORD       13800021
RELNUM   LR    WORK1,CVTREG             LOAD ADDRESS OF CVT             13850021
         SH    WORK1,CONST4             ADDR OF CVT - FOUR              13900021
         MVC   SWITCHES+C3(C1),C3(WORK1) MOVE INCR RELEASE NO.          13920021
         PACK  CONVERT,C0(C2,WORK1)     PACK TWO BYTE REL.NUMBER        13950021
         CVB   WORK1,CONVERT            CONVERT REL. NUMBER             14000021
         STC   WORK1,KEY+C1             INSERT REL.NUMBER IN REC        14050021
         TIME  DEC                      TO ACQUIRE DATA AND TIME        14100021
         STM   C0,C1,CONVERT            STORE TIME AND DATE             14150021
         MVC   TIME(C4),CONVERT         MOVE TIME INTO RECORD           14200021
         MVC   DATE(C4),CONVERT+C4      MOVE  DATE INTO RECORD          14250021
         CLI   INPUPARM+C1,THIRTY2      IS RECORD IPL OR EOD            14300021
         BE    PREPARE                  BR-EOD IS HEADER ONLY REC       14350021
         LR    WORK1,CVTREG             LOAD ADDRESS OF CVT             14400021
         MVC   HIGHADDR(C4),CVTHIAD(WORK1) MOVE HIGH ADDR IN REC.       14450021
         L     WORK1,ONE16(WORK1)       GET SER DCB ADDRESS             14500021
         SH    WORK1,CONST8             ADDR OF SER DCB - EIGHT         14550021
         L     WORK1,C0(WORK1)          ADDR OF CHANNEL ASGN LIST       14600021
         MVC   CHANASSN(C8),C0(WORK1)   MOVE CHANASSN INTO RECORD       14650021
         LA    PARMREG0,FORTY8          SET LENGTH OF IPL RECORD        14700021
         B     IPL                      BR TO GET ADDR OF RECORD        14750021
PREPARE  LA    PARMREG0,C24             SET LENGTH OF EOD RECORD        14800021
IPL      LA    PARMREG1,KEY             SET ADDR OF RECORD              14850021
         LNR   PARMREG0,PARMREG0        SET LENGTH REG NEG              14900021
         SVC   SEVENTY6                 RECORD TO LOGREC                14950021
*****    BEGIN  EXIT  ROUTINE                                           15000021
EXIT     LR    PARMREG1,STORADDR        STOR ADDR TO BE RELEASED        15050021
         L     RETRNREG,RETURNAD        LOAD RETURN ADDRESS             15100021
         LH    CODEREG,CONDCODE         LOAD ERROR RETURN CODE          15150021
         L     WORK4,PARM               LOAD RD/WRT ERROR COUNT         15200021
         FREEMAIN R,LV=ONE82,SP=TWO53,A=(1)  FREE MAIN STORAGE          15250021
         LR    PARMREG1,WORK4           LOAD PARAMETER FOR EXIT         15300021
         BR    RETRNREG                 RETURN TO CALLER                15350021
*****    TEST FOR 370/195                                        S21108 15360021
DIAGNOSE DC    X'834F00A0'                                       S21108 15370021
*****    LIST  MESSAGES  TO  OPERATOR                                   15400021
ERRMSG3  DC    AL2(MSGEND3-*)                                           15450021
         DC    B'1000000000000000'      MCSFLAG FIELD                   15500021
         DC    C'IFB020I INVALID REPLY TO IFB010D'                      15550021
MSGEND3  EQU   *                                                        15600021
         DC    B'0001000000000000'      DESCRIPTOR CODE                 15650021
         DC    B'0100000000000000'      ROUTING CODE                    15700021
INFOMSG  DC    AL2(MSGEND4-*)                                           15750021
         DC    B'1000000000000000'      MCSFLAG FIELD                   15800021
         DC    C'IFB010D ENTER ''IPL REASON,SUBSYSTEM ID'' '            15850021
         DC    C'OR ''U'''                                              15900021
MSGEND4  EQU   *                                                        15950021
         DC    B'0100000000000000'      DESCRIPTOR CODE                 16000021
         DC    B'1000000000000000'      ROUTING CODE                    16050021
CONST1   DC    H'1'                     CONSTANT OF ONE                 16100021
CONST4   DC    H'4'                     TO DISPLACE OFF CVT             16150021
CONST8   DC    H'8'                     TO DISPLACE OFF SER DCB         16200021
ID195    DC    H'405'                   I/D FOR MODEL 195               16250021
SUBCONST DS    CL2                      FOR ALIGNMENT OF CONSTS.        16300021
         DC    XL2'55'                  SUBTRACT CONST. FOR 2311        16350021
         DC    XL2'85'                  SUBTRACT CONST. FOR 2301        16400021
         DC    XL2'6C'                  SUBTRACT CONST. FOR 2303        16450021
         DC    XL2'55'                  SUBTRACT CONST. FOR 2302        16500021
         DC    XL2'6B'                  SUBTRACT CONST. FOR 2321        16550021
         DC    XL2'C6'                  SUB CONST FOR 2305 I            16600021
         DC    XL2'C6'                  SUB CONST FOR 2305 II           16650021
         DC    XL2'7A'                  SUBTRACT CONST. FOR 2314        16700021
         DC    XL2'87'                  SUB CONST FOR 3330              16750021
* THE FOLLOWING IS A MATRIX OF VALID WTOR REASON REPLIES                16800021
REPLYNM  DC    C'NM'                    NORMAL                          16850021
REPLYUN  DC    C'UN'                    UNKNOWN                         16900021
REPLYIE  DC    C'IE'                    IBM HDW OR TYPE1 CODE           16950021
REPLYIM  DC    C'IM'                    SAME AS IE ACTION TAKEN         17000021
REPLYOP  DC    C'OP'                    OPERATIONAL PROBLEM             17050021
REPLYEN  DC    C'EN'                    ENVIRONMENTAL                   17100021
REPLYCE  DC    C'CE'                    CE/SE HAS SYSTEM CONTROL        17150021
REPLYUP  DC    C'UP'                    USER PROGRAM                    17200021
REPLYPP  DC    C'ME'                    MEDIA                           17250021
         DC    X'0000000000000000'      RESERVED FOR MORE REASONS       17300021
* THE FOLLOWING IS A MATRIX OF VALID WTOR SUBSYSTEM ID  REPLIES         17350021
REPLY00  DC    C'00'                    NOT KNOWN                       17400021
         DC    X'00'                                                    17450021
REPLY10  DC    C'10'                    PROCESSOR SUBSYSTEM             17500021
         DC    X'10'                                                    17550021
REPLY20  DC    C'20'                    DASD                            17600021
         DC    X'20'                                                    17650021
REPLY30  DC    C'30'                    DISK                            17700021
         DC    X'30'                                                    17750021
REPLY40  DC    C'40'                    TAPE                            17800021
         DC    X'40'                                                    17850021
REPLY50  DC    C'50'                    CARD MACHINE/PRINTER            17900021
         DC    X'50'                                                    17950021
REPLY51  DC    C'51'                              AUX CARD MACH/PRINTER 18000021
         DC    X'51'                                                    18050021
REPLY52  DC    C'52'                    PRINTER                         18100021
         DC    X'52'                                                    18150021
REPLY60  DC    C'60'                    DRUM                            18200021
         DC    X'60'                                                    18250021
REPLY70  DC    C'70'                    TELEPROCESSING                  18300021
         DC    X'70'                                                    18350021
REPLY80  DC    C'80'                    GRAPHICS                        18400021
         DC    X'80'                                                    18450021
REPLY90  DC    C'90'                    IBM PROGRAM                     18500021
         DC    X'90'                                                    18550021
REPLY91  DC    C'91'                    IBM PROGRAMING PRODUCT          18600021
         DC    X'91'                                                    18650021
REPLY92  DC    C'92'                                                    18700021
         DC    X'92'                                                    18750021
         DC    X'000000000000000000'                                    18800021
DEFAULT  DC    C'DF'                                                    18850021
IDSTOR   DC    D'0'                                                     18900021
PTCHAREA DC    10F'0'                                                   18950021
         END                                                            19000021
