         TITLE  'CENTRALIZED EXTRACTOR IFDOLT46'                        00100000
*********************************************************************** 00102000
*                                                                     * 00104000
*TITLE                                                                * 00106000
*    IFDOLT46 - CENTRALIZED EXTRACTOR                                 * 00108000
*                                                                     * 00110000
*STATUS                                                               * 00112000
*    CHANGE LEVEL 000                                                 * 00114000
*                                                                     * 00116000
* FUNCTION                                                            * 00118000
*    THIS MODULE PROVIDES THE FOLLOWING FUNCTIONS:                    * 00120000
*        1.READS RECORDS FROM THE RECORD ENTRY AREA OF SYS1.LOGREC    * 00122000
*          OR FROM A HISTORY DATA SET                                 * 00124000
*        2.READS RECORDS FROM THE SDR AREA OF SYS1.LOGREC             * 00126000
*        3.RESETS TO READ FROM THE BEGINNING OF THE DATA SET          * 00128000
*        4.PERFORMS AN END OF JOB FUNCTION                            * 00130000
*        5.PERFORMS A TEST TO DETERMINE IF MORE RECORDS WERE WRITTEN  * 00132000
*          ON THE SYS1.LOGREC DATA SET WHILE THAT SET WAS BEING       * 00134000
*          READ BY THE MODULE AND SETS TO READ THESE RECORD IF        * 00136000
*          REQUESTED TO DO SO                                         * 00138000
*                                                                     * 00140000
*ENTRY POINTS                                                         * 00142000
*    FROM IFDOLT26                                                    * 00144000
*                                                                     * 00146000
*INPUT                                                                * 00148000
*    WHEN THIS MODULE IS ENTERED REG 1 POINTS TO A PARAMETER LIST     * 00150000
*    WHICH IS SET UP AS FOLLOWS:                                      * 00152000
*        WORD1:  ADDRESS OF READ BUFFER                               * 00154000
*        WORD2:  BYTES 0-1  BYTE COUNT                                * 00156000
*                BYTE 2     RESERVED                                  * 00158000
*                BYTE 3     OPTION SWITCHES                           * 00160000
*        WORD3:  BYTE 0     RECORD TYPE                               * 00162000
*                BYTE 1     ADDITIONAL SEARCH KEY                     * 00164000
*                BYTES 2-3   NOT USED                                 * 00166000
*                                                                     * 00168000
*OUTPUT                                                               * 00170000
*    REGISTER 15 WILL CONTAIN A RETURN CODE DEPENDING ON THE STATUS   * 00172000
*    OF THE OPERATION                                                 * 00174000
*                                                                     * 00176000
*EXITS                                                                * 00178000
*    TO OPEN,CLOSE,ENQ,DEQ,READ,CHECK,EXCP MACROS                     * 00180000
*    RETURN TO IFDOLT26                                               * 00182000
*                                                                     * 00184000
*********************************************************************** 00186000
IFDOLT46 CSECT                                                          00200000
         ENTRY IFD46                                                    00300000
IFD46    DS    0F                                                       00400000
         USING *,XBASEREG                                               00500000
*********************************************************************** 00600000
*                                                                     * 00700000
*****                    TABLE OF EQUATES                         ***** 00800000
*                                                                     * 00900000
*********************************************************************** 01000000
R0       EQU   0                                                        01010000
R12      EQU   12                                                       01020000
R13      EQU   13                                                       01030000
R14      EQU   14                                                       01040000
R15      EQU   15                                                       01050000
         SPACE 2                                                        01100000
XMSGMODR EQU   15             CONDITION CODE RETURN REGISTER            01200000
XPARMREG EQU   1              PARAMETER REGISTER                        01300000
XWORK1   EQU   2              WORK REGISTER                             01400000
XWORK2   EQU   3              WORK REGISTER                             01500000
XWORK3   EQU   4              WORK REGISTER                             01600000
XWORK4   EQU   5              WORK REGISTER                             01700000
XWORK5   EQU   6              WORK REGISTER                             01800000
XWORK6   EQU   7              WORK REGISTER                             01900000
XWORK7   EQU   8              WORK REGISTER                             02000000
XWORK8   EQU   9              WORK REGISTER                             02100000
LINKNAME EQU   10             LINK NAME POINTER REGISTER                02200000
RETURNAD EQU   11             RETURN ADDR REGISTER TO MAIN CODE         02300000
XMISCREG EQU   0              MISCELLANEOUS                             02400000
XGRSAVE  EQU   13             GPR SAVE AREA ADDR REGISTER               02500000
XRETREG  EQU   14             RETURN ADDR REGISTER TO SUP               02600000
XBASEREG EQU   12             MODULE BASE REGISTER                      02700000
ZERO     EQU   0                                                        02800000
NORMAL   EQU   X'7F'                                                    02900000
INTCEPT  EQU   X'44'                                                    03000000
XFOXESX  EQU   X'FF'                                                    03100000
ONE      EQU   1                                                        03200000
TWO      EQU   2                                                        03300000
THREE    EQU   3                                                        03400000
FOUR     EQU   4                                                        03500000
FIVE     EQU   5                                                        03600000
SIX      EQU   6                                                        03700000
SEVEN    EQU   7                                                        03800000
EIGHT    EQU   8                                                        03900000
NINE     EQU   9                                                        04000000
TEN      EQU   10                                                       04100000
SIXTEEN  EQU   16                                                       04200000
NINETEEN EQU   19                                                       04300000
TWENTY   EQU   20                                                       04400000
TWENTY6  EQU   26                                                       04500000
TWENTY7  EQU   27                                                       04600000
TWENTY8  EQU   28                                                       04700000
THIRTY   EQU   30                                                       04800000
THIRTY7  EQU   37                                                       04900000
THIRTY8  EQU   38                                                       05000000
FORTY    EQU   40                                                       05100000
FORTY8   EQU   48                                                       05200000
FIFTY    EQU   50                                                       05300000
XTEN     EQU   X'10'                                                    05400000
CONCAT   EQU   X'08'                                                    05500000
HIST1ST  EQU   X'04'                                                    05600000
NOSELECT EQU   X'00'                                                    05700000
RECSELCT EQU   X'80'                                                    05800000
FULLKEY  EQU   X'40'                                                    05900000
INITSW   EQU   X'02'                                                    06000000
SYSFIRST EQU   X'20'                                                    06100000
XDCBF0   EQU   44                                                       06200000
XDEBF0   EQU   36                                                       06300000
XDCBF1   EQU   28                                                       06400000
EXTENTNG EQU   X'42'                                                    06500000
LOGFIRST EQU   X'20'                                                    06600000
HISFIRST EQU   X'04'                                                    06700000
HISTOFF  EQU   X'FB'                                                    06800000
UNITXCPT EQU   X'01'                                                    06900000
SYSDONE  EQU   X'10'                                                    07000000
LOGRECIN EQU   X'80'                                                    07100000
HISTIN   EQU   X'40'                                                    07200000
HISTDONE EQU   X'20'                                                    07300000
         EJECT                                                          07400000
*********************************************************************** 07500000
*                                                                     * 07600000
*****                   B R A N C H    T A B L E                  ***** 07700000
*                                                                     * 07800000
*********************************************************************** 07900000
         SPACE 2                                                        08000000
XREADENV B     RDENVREC            READ ENVIRONMENT RECORDS             08100000
XSTAGAIN B     RESTART             RESTART FROM BEGINNING OF DATA SET   08200000
XENDJOB  B     ENDOFJOB            PERFORM END OF JOB                   08300000
XCLEARSY B     XCLEARSY                 EREP USE ONLY                   08400000
XREADSDR B     XRDSDR              READ SDR RECORDS                     08500000
XWRITSDR B     XWRITSDR                 EREP USE ONLY                   08600000
XWRITREA B     XWRITREA                 EREP USE ONLY                   08700000
XMOREREC B     MOREREC             TEST FOR MORE RECORDS                08800000
EXSWITCH DC    X'00'                                                    08900000
         EJECT                                                          09000000
*********************************************************************** 09100000
*                                                                     * 09200000
*****                    INITIALIZATION                           ***** 09300000
*                                                                     * 09400000
*********************************************************************** 09500000
         SPACE 2                                                        09600000
INITIALZ TM    EXSWITCH,INITSW               Q/IS THIS INITIAL ENTRY    09700000
         BNO   INITLZ01                      YES--INITIALIZE            09800000
         BR    XWORK8                        NO--RETURN                 09900000
INITLZ01 MVI   EXSWITCH,INITSW               TURN ON INITIAL ENTRY SW.  10000000
         ST    XPARMREG,PARMSAVE             SAVE PARAMETER REG.        10100000
         MVC   XRDCCW+ONE(THREE),ONE(XPARMREG) READ BUFFER ADDR TO CCW  10200000
         MVC   XRDCCW+SIX(TWO),FOUR(XPARMREG)  BYTE COUNT TO CCW        10300000
         ENQ   (LOGREC,RESID,E,,STEP),RET=HAVE                          10400021
         RDJFCB (XDCB,INOUT)       READ THE JFCB FOR SERLOG             10420000
         CLC   JDSNAME(8),COMPNAME COMPERE DATASET NAME FOR NULLFILE    10440000
         BE    SKIPSYS1            DON'T OPEN SYS1.LOGREC               10460000
         OPEN  (XDCB,INOUT)                                             10500000
SKIPSYS1 OPEN  (ACCUMDCB,INPUT)        OPEN HISTORY                     10600000
         L     XPARMREG,PARMSAVE             RESTORE PARM REG           10700000
         TM    XDCB+FORTY8,XTEN              Q/ DID SYS1.LOGREC OPEN    10800000
         BNO   INITLZ02                      NO--CHECK HISTORY          10900000
         OI    EXSWITCH,LOGRECIN             TURN ON LOGREC INPUT SW    11000000
         TM    ACCUMDCB+FORTY8,XTEN          Q/ DID HISTORY OPEN        11100000
         BNO   INITLZ03                      NO--SYS1.LOGREC ONLY INPUT 11200000
         OI    EXSWITCH,HISTIN               TURN ON HISTORY INPUT SW   11300000
         OI    EXSWITCH,CONCAT               TURN ON CONCATENATION SW   11400000
         TM    SEVEN(XPARMREG),LOGFIRST      Q/ SYS1.LOGREC 1ST INPUT   11500000
         BO    INITLZ03                      YES--READ SYS1.LOGREC 1ST  11600000
         OI    EXSWITCH,HISFIRST             NO--TURN ON HISTORY 1ST SW 11700000
         B     INITLZ03                      PREPARE TO READ HISTORY    11800000
INITLZ02 TM    ACCUMDCB+FORTY8,XTEN          Q/ DID HISTORY OPEN        11900000
         BNO   INITERR                       NO--ERROR   RETURN         12000000
         OI    EXSWITCH,HISFIRST             TURN ON HISTORY 1ST SW     12100000
         B     INITLZ04                      PREPARE TO READ HISTORY    12200000
INITLZ03 MVC   XRDCCW+ONE(THREE),ONE(XPARMREG) READ BUFFER ADDR TO CCW  12300000
         MVC   XRDCCW+SIX(TWO),FOUR(XPARMREG) BYTE COUNT TO CCW         12400000
*        MOVE SEEK ADDRESS FROM DEB TO EXCP SEEK BUFFER                 12500000
         L     XWORK1,XDCB+XDCBF0            LOAD DEB POINTER           12600000
         MVC   XSEEKBUF+ONE(SIX),XDEBF0(XWORK1)   MOVE BBCCHH TO IOB    12700000
         MVI   XSEEKBUF+SEVEN,ZERO           SET ID FIELD IN SEEKBUF 0  12800000
*        STORE IOB ADDRESS IN DCB                                       12900000
         LA    XWORK1,XIOB                   ADDRESS OF IOB             13000000
         ST    XWORK1,XDCB+XDCBF1            STORE IOB ADDRESS IN DCB   13100000
*        BRANCH TO READ HEADER RECORD                                   13200000
         LA    XWORK6,XRCCWS                 ADDR OF CCW CHAIN          13300000
         BAL   RETURNAD,XRDAD                READ SYS1.LOGREC           13400000
         B     RDHDRERR                      EOD RETURN                 13500000
         B     RDHDRERR                      ERROR RETURN               13600000
         L     XPARMREG,PARMSAVE             LOAD PARMAMETER REG        13700000
         L     XWORK2,ZERO(XPARMREG)         GET READ BUFFER ADDRESS    13800000
         MVC   XHDRBUF(FIFTY),ZERO(XWORK2)   SAVE HEADER RECORD         13900000
         MVI   XRESTART+SIX,ZERO             RESTART ADDR ID TO 0       14000000
         MVC   UCBCNT(TWO),THIRTY7(XWORK2)   NO.OF SYSTEM UCB'S         14100000
*        VERIFY AUTHENTICITY OF HEADER RECORD                           14200000
         CLI   XSAFBYTE,XFOXESX              CHECK SAFETY BYTE          14300000
         BNE   RDHDRERR                                                 14400000
         BR    XWORK8                        RETURN TO CALLING ROUTINE  14500000
INITLZ04 BR    XWORK8                                                   14600000
INITERR  LA    R15,12                   BOTH OPENS FAILED               14700000
         B     COMRTRN                  COMMON RETURN                   14800000
RDHDRERR LA    R15,16                   READ HEADER ERROR               14900000
         B     COMRTRN                  COMMON RETURN                   15000000
*********************************************************************** 15200000
*****       READ FROM STATISTICAL DATA RECORDER ESDRN AREA        ***** 15300000
*                                                                     * 15400000
*                                                                     * 15500000
*********************************************************************** 15600000
         SPACE 2                                                        15700000
XRDSDR   SAVE  (14,12)                                                  15800000
         LR    RETURNAD,XGRSAVE        FOLLOW                           15900000
         ST    XGRSAVE,MYSAVE+FOUR       STANDARD                       16000000
         LA    XGRSAVE,MYSAVE             LINKAGE                       16100000
         ST    XGRSAVE,EIGHT(RETURNAD)     CONVENTIONS                  16200000
         BAL   XWORK8,INITIALZ               GO INITIALIZE              16300000
         L     XPARMREG,PARMSAVE             RESTORE PARAMETER REG      16400000
         L     XWORK2,ZERO(XPARMREG)         GET READ BUFFER ADDRESS    16500000
         TM    EXSWITCH,HISFIRST             Q/IS HISTORY INPUT         16600000
         BO    SDRERROR                      YES--ERROR                 16700000
         LA    XWORK6,XRCCWS                 ADDR OF CCW CHAIN          16800000
         BAL   RETURNAD,XRDAD                READ DISK                  16900000
         B     SDREADER                      EOD RETURN                 17000000
         B     SDREADER                      ERROR RETURN               17100000
         CLC   UCBCNT(TWO),EIGHT(XWORK2)     CHECK FOR EOD              17200000
         BE    SDREODAT                      YES- GIVE EOD RETURN       17300000
*        UPDATE SEEK ADDRESS                                            17400000
         B     NORMRTRN                      GIVE NORMAL RETURN         17500000
*        ERROR                                                          17600000
*        VPDATE SEEK                                                    17700000
         B     SDREADER                      GIVE SDR READ ERROR RETURN 17800000
SDREODAT LA    R15,8                    END OF DATA RETURN              17900000
         B     COMRTRN                  COMMON RETURN                   18000000
SDRERROR LA    R15,32                   SDR ERROR RETURN                18100000
         B     COMRTRN                  COMMON RETURN                   18200000
SDREADER LA    R15,24                   SDR READ ERROR RETURN           18300000
         B     COMRTRN                  COMMON RETURN                   18400000
         EJECT                                                          18500000
*********************************************************************** 18600000
*                                                                     * 18700000
*****               READ FROM RECORD ENTRY AREA                   ***** 18800000
*                                                                     * 18900000
*********************************************************************** 19000000
         SPACE 2                                                        19100000
RDENVREC SAVE  (14,12)                                                  19200000
         LR    RETURNAD,XGRSAVE        FOLLOW                           19300000
         ST    XGRSAVE,MYSAVE+FOUR       STANDARD                       19400000
         LA    XGRSAVE,MYSAVE             LINKAGE                       19500000
         ST    XGRSAVE,EIGHT(RETURNAD)     CONVENTIONS                  19600000
         TM    EXSWITCH,INITSW               Q/INITIAL ENTRY            19700000
         BO    RDBEGIN                       NO--CONTINUE               19800000
         BAL   XWORK8,INITIALZ               INITIALIZE                 19900000
         MVC   XSEEKBUF+ONE(SEVEN),XHDRBUF+NINETEEN YES-UPDATE SEEK     20000000
*                                                    ADDR TO START OF   20100000
*                                                     RECORD ENTRY AREA 20200000
RDBEGIN  L     XPARMREG,PARMSAVE             RESTORE PARM REG           20300000
         LH    XWORK4,FOUR(XPARMREG)    SAVE COUNT               S21052 20350021
         L     XWORK2,ZERO(XPARMREG)         GET READ BUFFER ADDRESS    20400000
         TM    EXSWITCH,HISFIRST             Q/IS HISTORY 1ST ON        20500000
         BNO   READSYS1                      NO--GO READ SYS1.LOGREC    20600000
RDENVR02 BAL   XWORK8,XACCINPT               GO READ HISTORY            20900000
         B     NORMRTRN                      EQUAL NORMAL RETURN        22300000
READSYS1 L     XPARMREG,PARMSAVE             RESTORE PARM REG           22400000
         L     XWORK2,ZERO(XPARMREG)         RESTORE BUFFER REG         22500000
         CLC   XHDRBUF+THIRTY(SEVEN),XSEEKBUF+ONE  CHECK FOR EOD        22600000
         BNE   READTYPE                      NO-- CHK TYPE OF READ      22700000
RDSYS001 OI    EXSWITCH,SYSDONE              TURN ON LOGREC READ SW     22800000
         TM    EXSWITCH,CONCAT               Q/CONCATENATION            22900000
         BNO   ENDDATA                       NO--GIVE END OF DATA RETRN 23000000
         NI    EXSWITCH,HISTOFF              TURN OFF HISTORY 1ST SW    23100000
         TM    EXSWITCH,HISTDONE             Q/HAS HISTORY BEEN READ    23200000
         BO    ENDDATA                       YES--GIVE EOD  RETURN      23300000
         B     RDENVR02                 NO--GO READ HISTORY             23400000
READTYPE TM    SEVEN(XPARMREG),RECSELCT      Q/ SELECT BY RECORD TYPE   23500000
         BNO   READALL                       NO-- SET TO READ ALL REC.  23600000
         TM    SEVEN(XPARMREG),FULLKEY       Q/ SELECT BY FULL KEY      23700000
         BO    PARMERR                       YES--PARAMETER ERROR       23800000
READALL  LA    XWORK6,XRCCWS                 ADDR OF CCW CHAIN          24300000
         MVC   XRDCCW+ONE(THREE),ONE(XPARMREG) READ BUFFER ADDR TO CCW  24400000
         MVC   XRDCCW+SIX(TWO),FOUR(XPARMREG)  COUNT TO CCW             24500000
RDSYS002 BAL   RETURNAD,XRDAD                READ SYS1.LOGREC           28000000
         B     RDSYS001                      EOD RETURN                 28100000
         B     DISKERR                       ERROR RETURN               28200000
         B     NORMRTRN                      MORMAL RETURN              28300000
** TAPE EOD RETURN                                                      28400000
HISTEOD  OI    EXSWITCH,HISTDONE             TURN ON HISTORY READ SW    28500000
         TM    EXSWITCH,CONCAT               Q/CONCATENATION            28600000
         BNO   ENDDATA                       NO--GIVE EOD RETURN        28700000
         NI    EXSWITCH,HISTOFF              YES--TURN OFF HIST 1ST SW  28800000
         TM    EXSWITCH,SYSDONE              Q/HAS LOGREC BEEN READ     28900000
         BO    ENDDATA                       YES-- GIVE EOD RETURN      29000000
         B     READSYS1                                                 29100000
DISKERR  LA    R15,20                   DISK READ ERROR RETURN          29170000
         B     COMRTRN                  COMMON RETURN                   29240000
NORMRTRN LA    R15,0                    NORMAL RETURN                   29310000
COMRTRN  L     XGRSAVE,FOUR(XGRSAVE)    RESTORE REG 13                  29380000
         L     R14,12(R13)              RESTORE REG 14                  29450000
         LM    R0,R12,20(R13)           RESTORE REGS                    29520000
         MVI   12(R13),X'FF'            RETURN INDICATION               29590000
         BR    14                       RETURN                          29660000
ENDDATA  LA    R15,4                    END OF DATA FOR SDR             29730000
         B     COMRTRN                  COMMON RETURN                   29800000
*ERROR  TAPE                                                            29870000
TAPERRTN LA    R15,28                   TAPE ERROR RETURN               29940000
         B     COMRTRN                  COMMON RETURN                   30010000
PARMERR  LA    R15,52                   PARM FIELD ERROR                30080000
         B     COMRTRN                  COMMON RETURN                   30150000
         EJECT                                                          30300000
*********************************************************************** 30400000
*                                                                     * 30500000
*****               RESTART FROM BEGINNING OF DATA SET            ***** 30600000
*                                                                     * 30700000
*********************************************************************** 30800000
         SPACE 2                                                        30900000
RESTART  SAVE  (14,12)                                                  31000000
         LR    RETURNAD,XGRSAVE        FOLLOW                           31100000
         ST    XGRSAVE,MYSAVE+FOUR       STANDARD                       31200000
         LA    XGRSAVE,MYSAVE             LINKAGE                       31300000
         ST    XGRSAVE,EIGHT(RETURNAD)     CONVENTIONS                  31400000
         TM    ACCUMDCB+FORTY8,XTEN          Q/ WAS HISTORY INPUT       31500000
         BNO   RESTART1                       NO/- BRANCH               31600000
         CLOSE (ACCUMDCB,REREAD),TYPE=T      ISSUE TEMP CLOSE           31700000
         NI    EXSWITCH,X'DF'  TURN OFF HISTORY READ SWITCH             31800000
RESTART1 TM    XDCB+FORTY8,XTEN              Q/ WASSYS1.LOGREC INPUT    31900000
         BNO   RESRTRN                        NO/RETURN                 32000000
         CLOSE (XDCB,REREAD),TYPE=T          ISSUE TEMP CLOSE           32100000
         NI    EXSWITCH,X'EF'  TURN OFF LOGREC READ SWITCH              32200000
         MVC   XSEEKBUF+ONE(SEVEN),XHDRBUF+NINETEEN                     32300000
         MVI   XSEEKBUF+SEVEN,ZERO           SET ID FIELD TO ZERO       32400000
RESRTRN  B    NORMRTRN             NORMAL RETURN                        32500000
         EJECT                                                          32700000
*********************************************************************** 32800000
*                                                                     * 32900000
*****               CHECK FOR ADDITIONAL RECORDS                      * 33000000
*                                                                     * 33100000
*********************************************************************** 33200000
         SPACE 2                                                        33300000
MOREREC  SAVE  (14,12)                                                  33400000
         LR    RETURNAD,XGRSAVE        FOLLOW                           33500000
         ST    XGRSAVE,MYSAVE+FOUR       STANDARD                       33600000
         LA    XGRSAVE,MYSAVE             LINKAGE                       33700000
         ST    XGRSAVE,EIGHT(RETURNAD)     CONVENTIONS                  33800000
         TM    EXSWITCH,INITSW               Q/IS THIS INITIAL ENTRY    33900000
         BNO   MORERROR                      YES--INDICATE ERROR        34000000
         TM    XDCB+FORTY8,XTEN              Q/IS LOGREC OPEN           34100000
         BNO   MORERROR                                                 34200000
         L     XWORK2,ZERO(XPARMREG)         GET READ BUFFER ADDRESS    34300000
         MVC   XSEEKBUF+THREE(FIVE),ZERO(XWORK2) UPDATE SEEK            34400000
         MVC   XSAVEBUF(FORTY),XHDRBUF+TEN   SAVE DATA FIELD OF HDR     34500000
         BAL   XWORK8,INITLZ03               RE-READ HDR RECORD         34600000
         CLC   XSAVEBUF+TWENTY(SEVEN),XHDRBUF+THIRTY  COMPARE HDR RECS  34700000
         BE    NORMRTRN                 NORMAL RETURN                   34800000
* HDR RECORDS UNEQUAL--UPDATE SEEK ADDRESS                              34900000
         LA    R15,48                   MORE RECORD RETURN              35000000
         B     COMRTRN                  COMMON RETURN                   35100000
MORERROR B     PARMERR                  PARM ERROR                      35200000
         EJECT                                                          35600000
*********************************************************************** 35700000
*                                                                     * 35800000
*****               ROUTINE TO READ SYS1.LOGREC (DISK)            ***** 35900000
*                                                                     * 36000000
*********************************************************************** 36100000
         SPACE 2                                                        36200000
XRDAD    STM   XMISCREG,XMSGMODR,XGREGSAV    SAVE GPRS                  36300000
         LR    XWORK1,XWORK6                 ADDR OF CCW CHAIN          36400000
*                                             WILL BE ALTERED BY        36500000
*                                              READ REA ROUTINE         36600000
         ST    XWORK1,XIOBCCW                STORE IN IOB               36700000
         MVC   XIOBSEEK(8),XSEEKBUF          MOVE SEEK ADDR TO IOB      36800000
XRDAD01  XC    XRWECB(4),XRWECB              CLEAR ECB                  36900000
         L     XWORK2,ZERO(XPARMREG)         GET READ BUFFER ADDRESS    37000000
         LA    XPARMREG,XIOB                 ADDRESS OF IOB             37100000
         SVC   EXCP                          EXECUTE CHANNEL PROGRAM    37200000
         WAIT  1,ECB=XRWECB                                             37300000
         CLI   XRWECB,NORMAL                 CHECK FOR NORMAL           37400000
         BE    XRDADOK                        BRANCH IF READ OK         37500000
         CLI   XRWECB,INTCEPT                CHECK FOR INTERCEPT        37600000
         BE    XRDAD01                        TRY AGAIN                 37700000
         CLI   XRWECB,EXTENTNG               CHECK FOR OUT OF EXTENT    37800000
         BE    XRDADND                        BRANCH ON OUT OF EXTENT   37900000
         TM    XIOBCSW+4,UNITXCPT            TEST FOR UNIT EXCEPTION    38000000
         BNO   XRDADNG                        BRANCH NOT EOF            38100000
*EOD CONDITION                                                          38200000
XRDADND  XC    XDADBUF(EIGHT),XDADBUF        CLEAR DATA BUFFER ON EOF   38300000
         LM    XMISCREG,XMSGMODR,XGREGSAV    RESTORE REGS               38400000
         BR    RETURNAD                      RETURN TO EOD RETURN       38500000
*READ OK                                                                38600000
XRDADOK  MVC   XSEEKBUF+THREE(FIVE),ZERO(XWORK2) UPDATE SEEK ADDR       38700000
         LM    XMISCREG,XMSGMODR,XGREGSAV    RESTORE REGS               38800000
         LA    RETURNAD,EIGHT(RETURNAD)      INCREMENT LINK REG         38900000
         BR    RETURNAD                      READ OK RETURN             39000000
XRDADNG  MVC   XSEEKBUF+THREE(FIVE),ZERO(XWORK2) UPDATE SEEK ADDR       39100000
         LM    XMISCREG,XMSGMODR,XGREGSAV    RESTORE REGS               39200000
         LA    RETURNAD,FOUR(RETURNAD)       INCREMENT LINK REG         39300000
         BR    RETURNAD                      READ ERROR RETURN          39400000
         EJECT                                                          39500000
*********************************************************************** 39600000
*                                                                     * 39700000
*****               ROUTINE TO READ FROM HISTORY TAPE             ***** 39800000
*                                                                     * 39900000
*********************************************************************** 40000000
         SPACE                                                          40100000
XACCINPT READ  INPDECB,SF,ACCUMDCB,(XWORK2),(XWORK4) READ TAPE   S21052 40200021
         CHECK INPDECB                                                  40300000
         BR    XWORK8                                                   40400000
       EJECT                                                            40500000
*********************************************************************** 40600000
*                                                                     * 40700000
*****               WRITE HEADER RECORD (CLEAR SYS1.LOGREC)       ***** 40800000
*                                                                     * 40900000
*********************************************************************** 41000000
         SPACE 2                                                        41100000
       EJECT                                                            43600000
*********************************************************************** 43700000
*                                                                     * 43800000
*****               WRITE INTO RECORD ENTRY AREA                  ***** 43900000
*                                                                     * 44000000
*********************************************************************** 44100000
         SPACE 2                                                        44200000
       EJECT                                                            46500000
*********************************************************************** 46600000
*                                                                     * 46700000
*****                    WRITE INTO SDR AREA                      ***** 46800000
*                                                                     * 46900000
*********************************************************************** 47000000
         SPACE 2                                                        47100000
       EJECT                                                            49400000
*********************************************************************** 49500000
*                                                                     * 49600000
*****               ROUTINE TO WRITE SYS1.LOGREC (DISK)           ***** 49700000
*                                                                     * 49800000
*********************************************************************** 49900000
         SPACE                                                          50000000
         EJECT                                                          52200000
*********************************************************************** 52300000
*                                                                     * 52400000
*****                   END OF JOB ROUTINE                            * 52500000
*                                                                     * 52600000
*********************************************************************** 52700000
         SPACE 2                                                        52800000
ENDOFJOB SAVE  (14,12)                                                  52900000
         LR    RETURNAD,XGRSAVE        FOLLOW                           53000000
         ST    XGRSAVE,MYSAVE+FOUR       STANDARD                       53100000
         LA    XGRSAVE,MYSAVE             LINKAGE                       53200000
         ST    XGRSAVE,EIGHT(RETURNAD)     CONVENTIONS                  53300000
         TM    EXSWITCH,INITSW               Q/IS THIS INITIAL ENTRY    53400000
         BNO   PARMERR                  PARM ERROR                      53500000
         DEQ   (LOGREC,RESID,,STEP)                                     53600000
         TM    EXSWITCH,CONCAT               Q/IS THIS CONCATENATION    53700000
         BNO   EOJ001                        NO--SEE WHICH IS INPUT     53800000
         CLOSE (ACCUMDCB,REREAD)                                 SM2412 53900000
EOJ002   CLOSE (XDCB,LEAVE)                                             54000000
EOJ003   L     XPARMREG,PARMSAVE             RESTORE PARM REG           54100000
         MVI   EXSWITCH,0                    TURN OFF MY SWITCHES       54200000
         B     NORMRTRN                 NORMAL RETURN                   54300000
EOJ001   TM    XDCB+FORTY8,XTEN              Q/ WAS LOGREC INPUT        54400000
         BO    EOJ002                        YES--GO CLOSE SYS1.LOGREC  54500000
         CLOSE (ACCUMDCB,REREAD)                                 SM2412 54600000
         B     EOJ003                                                   54700000
         EJECT                                                          55100000
*********************************************************************** 55200000
*                                                                     * 55300000
*****          EVENT CONTROL BLOCK AND I/O BLOCK FOR SYS1.LOGREC  ***** 55400000
*                                                                     * 55500000
*********************************************************************** 55600000
         SPACE 2                                                        55700000
XRWECB   DC    1F'0'               EVENT CONTROL BLOCK                  55800000
         SPACE                                                          55900000
XIOB     DC    X'42000000'         IOB FLAGS                            56000000
XIOBECB  DC    AL4(XRWECB)         ADDRESS OF ECB                       56100000
XIOBCSW  DC    2F'0'               CSW IN IOB                           56200000
XIOBCCW  DC    AL4(XRCCWS)         FIRST CCW ADDRESS IN IOB             56300000
XIOBDCB  DC    AL4(XDCB)           DCB ADDRESS                          56400000
XIOBRA   DC    1F'0'               RESTART ADDRESS                      56500000
XIOBBCEC DC    1F'0'               BLOCK COUNT-ERROR COUNT              56600000
XIOBSEEK DC    2F'0'               SEEK ADDRESS                         56700000
         EJECT                                                          56800000
*********************************************************************** 56900000
*                                                                     * 57000000
*****          DATA CONTROL BLOCK FOR SYS1.LOGREC                 ***** 57100000
*                                                                     * 57200000
*********************************************************************** 57300000
         SPACE 2                                                        57400000
XDCB     DCB   DDNAME=SERLOG,                                          C57500000
               DSORG=PS,                                               C57600000
               MACRF=(R,W),                                            C57700000
               RECFM=U,                                                C57800000
               BLKSIZE=80,                                             C57900000
               NCP=1,                                                  C58000000
               DEVD=DA,                                                C58060000
               EXLST=JFCBXLST                                           58120000
         EJECT                                                          58200000
*********************************************************************** 58300000
*                                                                     * 58400000
*****          DATA CONTROL BLOCK FOR HISTORY DEVICE              ***** 58500000
*                                                                     * 58600000
*********************************************************************** 58700000
         SPACE 2                                                        58800000
ACCUMDCB DCB   DDNAME=ACCIN,                                           C58900000
               DSORG=PS,                                               C59000000
               MACRF=(R),                                              C59100000
               RECFM=U,                                                C59200000
               BLKSIZE=1576,                                           C59300000
               EODAD=HISTEOD,                                          C59400000
               SYNAD=TAPERRTN                                           59500000
         EJECT                                                          59600000
*********************************************************************** 59700000
*                                                                     * 59800000
*****          CHANNEL COMMAND WORDS USED BY EXCP                 ***** 59900000
*                                                                     * 60000000
*********************************************************************** 60100000
         SPACE 2                                                        60200000
EXCP     EQU   0                                                        60300000
SIDE     EQU   X'31'                                                    60400000
TIC      EQU   X'08'                                                    60500000
RCKDMT   EQU   X'9E'                                                    60600000
WDATA    EQU   X'05'                                                    60700000
WKD      EQU   X'0D'                                                    60800000
RKD      EQU   X'8E'                                                    60900000
RCT      EQU   X'92'                                                    61000000
CC       EQU   X'40'                                                    61100000
SILI     EQU   X'20'                                                    61200000
SKE      EQU   X'29'                                                    61300000
RR0      EQU   X'16'                                                    61400000
ALL      EQU   X'70'                                                    61500000
CCSILI   EQU   X'60'                                                    61600000
         SPACE 2                                                        61700000
XRCCWS   CCW   SIDE,XSEEKBUF+3,CC,5     SEARCH ID EQUAL                 61800000
         CCW   TIC,XRCCWS,CC,1          TJL                             61900000
XRDCCW   CCW   RCKDMT,XCNTBUF,SILI,1586 READ COUNT,KEY,DATA-MULTI TRACK 62000000
       SPACE                                                            62100000
       EJECT                                                            63900000
TEMPADDR DC    F'0'                                                     64000000
PARMSAVE DC    F'0'                                                     64100000
MYSAVE   DC    18F'0'                                                   64200000
SEARCHKY DC    X'0'                                                     64300000
XSEEKBUF DC    XL8'0'                                                   64400000
XHDRBUF  DC    5XL8'0'                                                  64500000
XHDRBUFX DC    2XL8'0'                                                  64600000
RECDTYPE DC    X'0000'                                                  64700000
XCNTBUF  DC    5XL8'0'                                                  64800000
UCBCNT   DC    X'0000'                                                  64900000
XGREGSAV DC    16F'0'                                                   65000000
XSAVEBUF DC    5XL8'0'                                                  65100000
TEMP     DC    F'0'                                                     65200000
SRCHON2  DC    X'0002'                                                  65300000
SRCHON1  DC    X'0001'                                                  65400000
TAPEINP  DC    C'HISTORY'                                               65500000
LOGREC   DC    CL8'SERLOG'                                              65600000
RESID    DC    C'SYS1.LOGREC'                                           65700000
ACCUM    DC    CL8'ACCIN'                                               65800000
XDADBUF  DC    5XL8'00'                                                 65900000
SRCHKEY  DC    X'0000'                                                  66000000
JFCBXLST DS    0F                                                       66010000
         DC    X'07'                                                    66020000
         DC    AL3(JFCBAREA)                                            66030000
JFCBAREA DS    0F                                                       66040000
JDSNAME  DS    CL8                                                      66050000
         DS    CL168                                                    66060000
COMPNAME DC    C'NULLFILE'                                              66070000
XRESTART EQU   XHDRBUF+11          RECORD ENTRY START AREA              66100000
XSAFBYTE EQU   XHDRBUF+47                                               66200000
HDRSAVE  EQU   XHDRBUF                                                  66300000
PATCH46  DC    20XL2'0700'              PATCH AREA               S21052 66350021
         END                                                            66400000
