         TITLE 'IGC0405I - OLTEP SVC FUNCTIONS'                         00200000
IGC0405I CSECT                     LOAD MODULE OF SVC 59                00400000
*********************************************************************** 00600000
*                                                                     * 00800000
*STATUS: CHANGE LEVEL 0                                               * 01000000
*                                                                     * 01200000
*                             FUNCTION 32                             * 01400000
*                             ***********                             * 01600000
*                                                                     * 01800000
*  0080 IN REGISTER 1 WILL RESULT IN A SEARCH ON THE CHANNEL REQUESTED* 02000000
*  FOR TESTING. THE SEARCH WILL INCLUDE THE FOLLOWING CHECKS:         * 02200000
*     A- TO ASSURE THAT THERE ARE NO REQUIRED SYSTEM DATA SETS ON THE * 02400000
*        CHANNEL.                                                     * 02600000
*     B- TO ASSURE THAT JOBLIB'S ASSIGNED TO OLTEP ARE NOT ON THE     * 02800000
*        CHANNEL.                                                     * 03000000
*     C- TO ASSURE THAT DEVICE'S REQUIRED TO OPERATE THE SYSTEM ARE   * 03200000
*        NOT ASSIGNED TO THE CHANNEL...EXAMPLE - SYSOUT,SYSIN AND     * 03400000
*        PRIMARY CONCOLE.                                             * 03600000
*                                                                     * 03800000
*  ENTRY POINTS:                                                      * 04000000
*                                                                     * 04200000
*        IGC00059 - DIAGNOSTIC SVC.  LA   R0,PARAM LIST POINTER       * 04400000
*                                    LA   R1,DESIRED FUNCTION CODE    * 04600000
*                                    SVC  DIAG                        * 04800000
*                                                                     * 05000000
*  THE ABOVE ENTRY AND CALLING SEQUENCE IS THE ONLY ENTRY.            * 05200000
*                                                                     * 05400000
*  INPUT  NA                                                          * 05600000
*                                                                     * 05800000
*  OUTPUT NA                                                          * 06000000
*                                                                     * 06200000
*  EXTERNAL ROUTINES : NONE                                           * 06400000
*                                                                     * 06600000
*********************************************************************** 06800000
 EJECT                                                                  07000000
*********************************************************************** 07200000
*                             EQUATS                                  * 07400000
*********************************************************************** 07600000
 SPACE 2                                                                07800000
REG0     EQU   0                   REGISTER 0                           08000000
R1       EQU   1                   REGISTER 1                           08200000
R5       EQU   5                                                        08400000
R8       EQU   8                                                        08600000
D0       EQU   0                                                        08800000
D1       EQU   1                                                        09000000
D2       EQU   2                                                        09200000
D3       EQU   3                                                        09400000
D4       EQU   4                                                        09600000
D5       EQU   5                                                        09800000
D6       EQU   6                                                        10000000
D8       EQU   8                                                        10200000
D12      EQU   12                                                       10400000
D13      EQU   13                                                       10600000
D18      EQU   18                                                       10800000
D24      EQU   24                                                       11000000
D28      EQU   28                                                       11200000
L1       EQU   1                                                        11400000
L2       EQU   2                                                        11600000
L3       EQU   3                                                        11800000
L6       EQU   6                                                        12000000
L8       EQU   8                                                        12200000
L13      EQU   13                                                       12400000
HEX00    EQU   X'00'                                                    12600000
HEX02    EQU   X'02'                                                    12800000
HEX10    EQU   X'10'                                                    13000000
HEX14    EQU   X'14'                                                    13200000
HEX18    EQU   X'18'                                                    13400000
HEX1C    EQU   X'1C'                                                    13600000
HEX20    EQU   X'20'                                                    13800000
HEX24    EQU   X'24'                                                    14000000
HEX28    EQU   X'28'                                                    14200000
HEX2C    EQU   X'2C'                                                    14400000
HEX30    EQU   X'30'                                                    14600000
HEX34    EQU   X'34'                                                    14800000
HEX38    EQU   X'38'                                                    15000000
HEX3C    EQU   X'3C'                                                    15200000
HEX40    EQU   X'40'                                                    15400000
HEX80    EQU   X'80'                                                    15600000
SHIFT2   EQU   2                                                        15800000
SHIFT24  EQU   24                                                       16000000
BZ       EQU   8                   BRANCH ON CONDITION ZERO             16200000
ARLKREG  EQU   2                   ALTERNATE PATH RESULT LINK REG.      16400000
ARCNTREG EQU   5                   ALTERNATE PATH COUNT REG.            16600000
STOREG   EQU   10                  CONTENTS OF REG 10 IS SAVED IN REG 0 16800000
APWKREG  EQU   11                  ADDRESS OF ALTERNATE PATH WORK AREA  17000000
SUBREG   EQU   10                                                       17200000
PARMREG  EQU   9                   REGISTER 9 CONTAINS ADDRESS OF       17400000
*                                  PARAMETER LIST                       17600000
TCBREG   EQU   4                   REGISTER 4 CONTAINS ADDRESS OF TCB   17800000
RETURN   EQU   14                  REGISTER 14 CONTAINS RETURN ADDRESS  18000000
RTNDVREG EQU   1                   REGISTER CONTAINING UNIT NAME OF     18200000
*                                  DEVICE HOLDING UP CHANNEL TEST       18400000
DEBREG   EQU   6                   REGISTER - ADDRESS OF DEB            18600000
DCBDEBAD EQU   44                  OFFSET IN DCB TO DEB ADDRESS         18800000
DEBUCBAD EQU   32                  OFFSET IN DEB TO UCB ADDRESS         19000000
TIOTREG  EQU   13                  ADDRESS OF JOBLIB TIOT               19200000
TCBTIO   EQU   12                                                       19400000
INCMNT   EQU   16                                                       19600000
UCBLKREG EQU   6                   ADDRESS OF UCB LOOKUP TABLE          19800000
CNTREG   EQU   15                  REGISTER USED AS A COUNTER           20000000
MAINREG  EQU   15                  CONTAINS ADDRESS OF GETMAIN AREA     20200000
DSCNTREG EQU   13                  INDEX FOR LOCATE BRANCH TABLE        20400000
DSLIBREG EQU   7                   ADDRESS OF LOCATE AREA               20600000
RCREG    EQU   15                  REGISTER 15 CONTAINS RETURN CODE     20800000
BASEREG  EQU   12                  SVC BASE REGISTER 12                 21000000
DCBREG   EQU   7                   REGISTER 7 ADDRESS OF DCB            21200000
CVTREG   EQU   3                   REGISTER 3 ADDRESS OF CVT            21400000
WORKREG2 EQU   2                   REGISTER 2 WHEN USED AS A WORK REG.  21600000
UCBREG   EQU   8                                                        21800000
CALLREG1 EQU   1                   REGISTER 1 CONTAINS CALLING CODE OF  22000000
*                                  CALLING CODE MINUS CONTROL BIT 16    22200000
CALLREG2 EQU   6                   REGISTER 6 CONTAINS DUPLICATE OF     22400000
*                                  REQUESTED FUNCTION.                  22600000
POOLREG  EQU   13                  REGISTER CONTAINS ADDRESS OF 16      22800000
*                                  GETMAIN BYTES IN SUBPOOL 254         23000000
SAVEREG  EQU   10                  REGISTER CONTAINING BACKUP OF CALL   23200000
*                                  CODE                                 23400000
LOCREG   EQU   10                  REGISTER CONTAINS ADDRESS OF LOCATE  23600000
*                                  AREA.                                23800000
 EJECT                                                                  24000000
         BALR  BASEREG,REG0        SET BASE REGISTER                    24200000
         USING *,BASEREG           INDICATE BASE REGISTER BEING USED    24400000
         USING SVCCVT4,CVTREG                                           24600000
         LR    CALLREG1,POOLREG    SET SUBPOOL ADDRESS FOR FREEMAIN     24800000
         L     REG0,SUBPOOL        SET SUBPOOL PARAMETER FOR FREEMAIN   25000000
         FREEMAIN   R,LV=(0),A=(1)                                      25200000
         SR    RCREG,RCREG         CLEAR RETURN CODE REGISTER           25600000
 EJECT                                                                  25800000
*********************************************************************** 26000000
*                             FUNCTION 32                             * 26200000
*********************************************************************** 26400000
 SPACE 2                                                                26600000
FUNC32   L     REG0,SPL18          SET SUBPOOL PARAMETER FOR GETMAIN    26800000
         GETMAIN  R,LV=(0)                                              27000000
         L     UCBREG,CVTSYSAD          LOAD ADDRESS OF THE PRIMARY     27200000
*                                       SYSTEM RESIDENT UCB             27400000
         CLC   D3(L1,PARMREG),D13(UCBREG)    IS PRIMARY SYSTEM RESIDENT 27600000
*                                            DEVICE ON CHANNEL BEING    27800000
*                                            TESTED.                    28000000
         BNE   SVCLIB              NO-BRANCH TO SYS1.SVCLIB SEARCH      28200000
         LA    RCREG,HEX14         INDICATE SYSRES DEVICE IS ON CHANNEL 29000000
         B     ERRORRTN            BEING TESTED & BRANCH TO RETURN      29200000
SVCLIB   L     DCBREG,CVTSVDCB          LOAD ADDRESS OF SYS1.SVCLIB DCB 29400000
         L     DEBREG,DCBDEBAD(DCBREG)  LOAD ADDRESS OF SYS1.SVCLIB DEB 29600000
         L     UCBREG,DEBUCBAD(DEBREG)  LOAD ADDRESS OF SYS1.SVCLIB UCB 29800000
         CLC   D3(L1,PARMREG),D13(UCBREG)    IS SYS1.SVCLIB ON CHANNEL  30000000
*                                            BEING TESTED.              30200000
         BNE   LOGREC              NO-BRANCH TO SYS1.LOGREC SEARCH      30400000
         BAL   ARLKREG,ALTRSLT     LINK TO ALTERNATE PATH RESULT RTN    30600000
         LTR   ARCNTREG,ARCNTREG   ARE ALTERNATE PATHES AVAILABLE       30800000
         BP    LOGREC              ALTERNATE PATH CONTINUE SEARCH       31000000
         LA    RCREG,HEX18         INDICATE SYS1.SVCLIB IS ON CHANNEL   31200000
         B     ERRORRTN            BEING TESTED & BRANCH TO RETURN      31400000
LOGREC   L     DCBREG,CVTDCB            LOAD ADDRESS OF SYS1.LOGREC DCB 31600000
         L     DEBREG,DCBDEBAD(DCBREG)  LOAD ADDRESS OF SYS1.LOGREC DEB 31800000
         L     UCBREG,DEBUCBAD(DEBREG)  LOAD ADDRESS OF SYS1.LOGREC UCB 32000000
         CLC   D3(L1,PARMREG),D13(UCBREG)    IS SYS1.LOGREC ON CHANNEL  32200000
*                                            BEING TESTED               32400000
         BNE   LINKLIB             NO-BRANCH TO SYS1.LINKLIB SEARCH     32600000
         BAL   ARLKREG,ALTRSLT     LINK TO ALTERNATE PATH RESULT RTN    32800000
         LTR   ARCNTREG,ARCNTREG   ARE ALTERNATE PATHES AVAILABLE       33000000
         BP    LINKLIB             ALTERNATE PATH CONTINUE SEARCH       33200000
         LA    RCREG,HEX1C         INDICATE SYS1.LOGREC IS ON CHANNEL   33400000
         B     ERRORRTN            BEING TESTED & BRANCH TO RETURN      33600000
LINKLIB  L     DCBREG,CVTLINK           LOAD ADDRESS OF SYS1.LINKLIB    33800000
*                                       DCB                             34000000
         L     DEBREG,DCBDEBAD(DCBREG)  LOAD ADDRESS OF SYS1.LINKLIB    34200000
*                                       DEB                             34400000
*                                            BEING TESTED.              34600000
         L     UCBREG,DEBUCBAD(DEBREG)  LOAD ADDRESS OF SYS1.LINKLIB    34800000
*                                       UCB                             35000000
         CLC   D3(L1,PARMREG),D13(UCBREG)    IS SYS1.LINKLIB ON CHANNEL 35200000
         BNE   DDCARDS             NO-BRANCH TO CHECK DD ENTRIES        35400000
         BAL   ARLKREG,ALTRSLT     LINK TO ALTERNATE PATH RESULT RTN    35600000
         LTR   ARCNTREG,ARCNTREG   ARE ALTERNATE PATHES AVAILABLE       35800000
         BP    DDCARDS             ALTERNATE PATH CONTINUE SEARCH       36000000
         LA    RCREG,HEX20         INDICATE SYS1.LINKLIB IS ON CHANNEL  36200000
         B     ERRORRTN            BEING TESTED & BRANCH TO RETURN      36400000
DDCARDS  LA    SUBREG,INCMNT       SET WORK REGISTER TO 16              36600000
         L     TIOTREG,TCBTIO(TCBREG)   LOAD ADDRESS OF TASK I/O TABLE  36800000
         LA    TIOTREG,D24(TIOTREG)     SET TIOT PTR TO DD ENTRIES      37000000
NEXTDD   L     CNTREG,D0(TIOTREG)       LOAD DD ENTRY                   37200000
         LTR   CNTREG,CNTREG       IS THIS THE END OF TABLE             37400000
         BZ    CHUCBTST            YES-BRANCH TO CONTINUE WITH CHANNEL  37600000
*                                  UCB VALIDITY CHECKING                37800000
         SRL   CNTREG,SHIFT24      ISOLATE LENGTH OF DD ENTRY           38000000
         SR    CNTREG,SUBREG       SET COUNTER TO THE NUMBER OF DEVICES 38200000
         SRL   CNTREG,SHIFT2       ALLOCATED PER DD ENTRY               38400000
         AR    TIOTREG,SUBREG      SET TIOT ADDRESS TO UCB ENTRY        38600000
NEXTUCB  L     UCBREG,D0(TIOTREG)  LOAD UCB ADDRESS                     38800000
         CLC   D3(L1,PARMREG),D13(UCBREG)    IS OLT DATA SET ON CHANNEL 39000000
*                                            BEING TESTING              39200000
         BNE   DSCHECK             YES-BRANCH TO SET RETURN CODE        39400000
         BAL   ARLKREG,ALTRSLT     LINK TO ALTERNATE PATH RESULT RTN    39600000
         LTR   ARCNTREG,ARCNTREG   ARE ALTERNATE PATHES AVAILABLE       39800000
         BP    DSCHECK             ALTERNATE PATH CONTINUE SEARCH       40000000
         LA    RCREG,HEX2C         INDICATE JOBLIB IS ON CHANNEL        40200000
         B     ERRORRTN            BEING TESTED & BRANCH TO RETURN      40400000
DSCHECK  LA    TIOTREG,D4(TIOTREG) SET POINTER TO NEXT UCB ENTRY        40600000
         BCT   CNTREG,NEXTUCB      BRANCH TO PICKUP NEXT UCB ADDRESS    40800000
         B     NEXTDD              BRANCH TO PICKUP NEXT DD ENTRY       41000000
CHUCBTST L     UCBLKREG,CVTILK2         LOAD ADDRESS OF UCB LOOKUP TAB. 41200000
TSTUCBAD CLC   D0(L2,UCBLKREG),NOUCB    IS UCB ADDRESS IN TABLE ZERO    41400000
         BNE   CHECKEND            NO-BRANCH TO CHECK FOR END OF TABLE  41600000
NXTUCB   LA    UCBLKREG,D2(UCBLKREG)    YES-SET POINTER TO NEXT UCB     41800000
         B     TSTUCBAD                 ADDRESS IN TABLE AND CONTINUE   42000000
*                                       WITH TEST ON NEXT UCB           42200000
CHECKEND CLC   D0(L2,UCBLKREG),UCBTBEND IS THIS THE END OF TABLE        42400000
         BE    QUIESCE             YES-BRANCH TO QUIESCE PROCEDURE      42600000
         LH    UCBREG,D0(UCBLKREG) LOAD ADDRESS OF UCB                  42800000
         CLC   D3(L1,PARMREG),D13(UCBREG)    IS UCB ON CHANNEL BEING    43000000
*                                            TESTED                     43200000
         BE    CHECKUCB            YES-BRANCH TO CHECK OUT DEVICE       43400000
         B     NXTUCB              NO-BRANCH TO CONTINUE WITH TEST      43600000
*                                  ON NEXT UCB.                         43800000
CHECKUCB TM    D3(UCBREG),HEX80    IS UCB ON-LINE                       44000000
         BNO   NXTUCB              NO-BRANCH TO CONTINUE TEST ON NEXT   44200000
*                                  UCB.                                 44400000
         TM    D12(UCBREG),HEX80   IS SYSIN DEVICE ON CHANNEL BEING     44600000
*                                  TESTED                               44800000
         BZ    SYSOUT              NO-BRANCH TO CHECK FOR SYSOUT DEVICE 45000000
         BAL   ARLKREG,ALTRSLT     LINK TO ALTERNATE PATH RESULT RTN    45200000
         LTR   ARCNTREG,ARCNTREG   ARE ALTERNATE PATHES AVAILABLE       45400000
         BP    SYSOUT              ALTERNATE PATH CONTINUE SEARCH       45600000
         LA    RCREG,HEX30         INDICATE SYSIN DEVICE IS ON CHANNEL  45800000
         B     ERRORRTN            BEING TESTED & BRANCH TO RETURN      46000000
SYSOUT   TM    D12(UCBREG),HEX40   IS SYSOUT DEVICE ON CHANNEL BEING    46200000
*                                  TESTED                               46400000
         BZ    DIRACC              NO-BRANCH TO CHECK DIRECT ACCESS     46600000
         BAL   ARLKREG,ALTRSLT     LINK TO ALTERNATE PATH RESULT RTN    46800000
         LTR   ARCNTREG,ARCNTREG   ARE ALTERNATE PATHES AVAILABLE       47000000
         BP    DIRACC              ALTERNATE PATH CONTINUE SEARCH       47200000
         LA    RCREG,HEX34         INDICATE SYSOUT DEVICE IS ON CHANNEL 47400000
         B     ERRORRTN            BEING TESTED & BRANCH TO RETURN      47600000
DIRACC   TM    D18(UCBREG),HEX20   IS DEVICE DIRECT ACCESS STORAGE      47800000
         BO    PARMLIB             YES-BRANCH TO CHECK FOR SYS1.PARMLIB 48000000
         TM    D3(UCBREG),HEX02    IS THIS THE PRIMARY CONSOLE          48200000
         BZ    NXTUCB              NO - BRANCH TO NEXT UCB ADDRESS      48400000
         LA    RCREG,HEX38         INDICATE CONSOLE IS ON CHANNEL       49200000
         B     ERRORRTN            BEING TESTED & BRANCH TO RETURN      49400000
PARMLIB  XR    DSCNTREG,DSCNTREG   SET DATA SET COUNT TO ZERO           49600000
         L     LOCREG,D4(PARMREG)  LOAD ADDRESS OF LOAATE ADDRESS TABLE 49800000
*                                  FOR-SYS1.PARMLIB, SYS1.SYSJOBQE AND  50000000
*                                  SYS1.PROCLIB                         50200000
CHECKNXT L     DSLIBREG,D0(LOCREG) LOAD ADDRESS FOR LOCATE TABLE        50400000
         LTR   DSLIBREG,DSLIBREG   END OF TABLE                         50600000
         BZ    NXTUCB              YES-CHECK NEXT UCB                   50800000
         LA    DSCNTREG,D4(DSCNTREG)    NO-INCREMENT CNT OF BRANCH TAB. 51000000
         LH    CNTREG,D0(DSLIBREG) LOAD NUMBER OF DATA SETS CONTAINING  51200000
*                                  SYSTEM LIBRARIES                     51400000
         LTR   CNTREG,CNTREG       IS COUNT ZERO                        51600000
         BNZ   CHVOLSER            NO-CHECK VOLUME SERIAL NUMBER OF     51800000
*                                  DATA SET                             52000000
RESETDS  LA    LOCREG,D4(LOCREG)   YES-RESET POINTER FOR NEXT DATA SET  52200000
         B     CHECKNXT                                                 52400000
CHVOLSER CLC   D6(L6,DSLIBREG),D28(UCBREG)   IS DATA SET ON CHANNEL     52600000
         BE    VOLCKERR            YES-BRANCH TO SET RETURN CODE        52800000
CONTINUE LA    DSLIBREG,D12(DSLIBREG)   RESET POINTER TO NEXT VOLUME    53000000
         BCT   CNTREG,CHVOLSER     CHECK NEXT VOL SER NUMBER            53200000
         B     RESETDS             YES-BRANCH TO CHECK NEXT DATA SET    53400000
VOLCKERR BAL   ARLKREG,ALTRSLT     LINK TO ALTERNATE PATH RESULT RTN    53600000
         LTR   ARCNTREG,ARCNTREG   ARE ALTERNATE PATHES AVAILABLE       53800000
         BP    CONTINUE            ALTERNATE PATH CONTINUE SEARCH       54000000
         B     *+D0(DSCNTREG)      BRANCH TO SET PROPER RETURN CODE     54200000
         B     PARMERR             BRANCH TO PARMLIB RETURN             54400000
         B     JQRC                BRANCH TO JOBQE RETURN               54600000
         LA    RCREG,HEX28         SET RETURN CODE FOR SYS1.PROCLIB     54800000
         B     ERRORRTN            BRANCH ERROR RETURN                  55000000
JQRC     LA    RCREG,HEX24         SET RETURN CODE FOR SYS1.SYSJOBQE    55200000
         B     ERRORRTN            BRANCH ERROR RETURN                  55400000
PARMERR  LA    RCREG,HEX3C         INDICATE SYS1.PARMLIB IS ON CHANNEL  55600000
ERRORRTN L     REG0,SPL18          SET SUBPOOL PARAMETER FOR FREEMAIN   55800000
         LR    R5,RCREG            SAVE RETURN CODE                     56000000
         FREEMAIN  R,LV=(0),A=(1)                                       56200000
         LR    RCREG,R5            RESTORE RETURN CODE                  56400000
         L     RTNDVREG,D12(UCBREG)     LOAD UNIT NAME BEING RETURNED   56600000
         BR    RETURN              BRANCH REGISTER 14 TO CALLER.        56800000
ALTRSLT  LR    REG0,STOREG         SAVE LINK REGISTER                   57000000
         LR    APWKREG,R1          SET WORK AREA ADDRESS                57200000
         BAL   STOREG,ALTPATH      LINK TO ALTERNATE PATH ROUTINE       57400000
         LR    STOREG,REG0         RESTORE LINK REG.                    57600000
         XR    ARCNTREG,ARCNTREG   CLEAR COUNT REG.                     57800000
NEXTENTY TM    D0(APWKREG),HEX10   LAST ENTRY                           58000000
         BO    LASTENTY            YES GO TO LAST ENTRY ROUTINE         58200000
         TM    D0(APWKREG),HEX20   PATH OFF-LINE                        58400000
         LA    APWKREG,D2(APWKREG) SET POINTER TO NEXT ENTRY            58600000
         BZ    UPCNT               ON-LINE GO TO COUNT ROUTINE          58800000
         B     NEXTENTY            GO CHECK NEXT ENTRY                  59000000
UPCNT    LA    ARCNTREG,D1(ARCNTREG)    INCREMENT COUNT                 59200000
         B     NEXTENTY                 GO CHECK NEXT ENTRY             59400000
LASTENTY TM    D0(APWKREG),HEX20   LAST ENTRY OFF-LINE                  59600000
         BCR   BZ,ARLKREG          NO-RETURN TO CALLING ROUTINE         59800000
         BCTR  ARCNTREG,REG0       SUBTRACT ONE FROM PATH COUNT         60000000
         BR    ARLKREG             RETURN TO CALLING ROUTINE            60200000
ALTPATH  DS    0H                                                       60400000
         IOSGEN  MAP,11,(8,3,4,2,6,7,5),0,AUTH=IGC0405I,LINKR=10        60600000
QUIESCE  L     REG0,SPL18         SET SUBPOOL PARAMETER FOR FREEMAIN    60900000
         FREEMAIN  R,LV=(0),A=(1)                                       61200000
         L     PARMREG,D8(PARMREG) LOAD ADDRESS OF CHANNEL QUIESCE      61400000
*                                  PARAMETER LIST                       61600000
         L     REG0,SUBPOOL        SET SUBPOOL PARAMETER FOR GETMAIN    61800000
         GETMAIN    R,LV=(0)                                            62000000
         LR    POOLREG,R1          SET SUBPOOL ADDRESS FOR TRANSFER     62200000
         LR    MAINREG,R1          SETUP ADDRESS OF REMOTE PARMLIST     62400000
         L     DCBREG,CVTSVDCB          SET DCB ADDRESS FOR XCTL        62600000
         ST    DCBREG,D4(MAINREG)  STORE DCB ADDRESS IN SWP.PARAMLIST   62800000
         MVI   D4(MAINREG),HEX00   CLEAR HIGH ORDER BYTE                63000000
         LA    WORKREG2,IGC01      LOAD ADDRESS OF CONSTANT IGC0105I    63200000
         MVC   D8(L8,MAINREG),D0(WORKREG2)   MOVE MODULE NAME INTO THE  63400000
*                                  REMOTE CONTROL PROGRAM PARAMETER LST 63600000
         ST    WORKREG2,D0(MAINREG)     STORE ADDRESS OF MODULE NAME    63800000
         LA    CALLREG1,HEX30      SET CALLING CODE PARAMETER FOR       64000000
*                                  CHANNEL QUIESCE FUNCTION             64200000
         XCTL  SF=(E,(15))                                              64400000
 EJECT                                                                  64600000
 EJECT                                                                  64800000
*********************************************************************** 65000000
*                             CONSTANTS                               * 65200000
*********************************************************************** 65400000
 SPACE 2                                                                65600000
         DS    0F                                                       65800000
SUBPOOL  DC    X'FE000010'                                              66000000
SPL18    DC    X'FE000048'                                        M1005 66200000
IGC01    DC    CL8'IGC0305I'       EP PARAMETER                         66400000
UCBTBEND DC    X'FFFF'                                                  66600000
NOUCB    DC    X'0000'                                                  66800000
PTCHAREA DS    15F                 IGC0405I'S PATCH AREA                67000000
 EJECT                                                                  67200000
         DS    0D                                                       67400000
SVCCVT4  DSECT                                                          67600000
         CVT                                                            67800000
         END                                                            68000000
