IGC0605I CSECT                                                          00300020
*********************************************************************** 00600020
*                                                                     * 00900020
*  STATUS:  CHANGE LEVEL 1                                            * 01200020
*                                                                     * 01500020
* APAR #59673                                                   S59673* 01550021
*C310000,A310000,C322000,A333000                                        01800020
* APAR # 59679 FOR PICKING UP UCB FOR DATALINK                 SA59679  01850021
* APAR # 61006 FIX FOR BTAM OWNED DEV AND BIT SETTING FOR SAME SA61006  01900021
* APAR # 61998 GUARANTEE RETAIN DEB REMOVED FROM DEB CHAIN     SA61998* 01960000
* APAR # 64258 ALLOWS RUNNING OFFLINE 3270 DEV CLASS&TYPE  1009SA64258* 02020000
*                                                                     * 02100020
*                            FUNCTION 15                              * 02400020
*                            ***********                              * 02700020
*  003C IN REGISTER 1 WILL TEST A SPECIFIED UCB IN PROTECTED MEMORY   * 03000020
*  TO HAVE ITS OFF-LINE BIT IN THE STATUS BYTE SET TO ONE. ALSO THE   * 03300020
*  UCB IS TESTED TO BE VALID AND HAVE THE EXPECTED CONTROL UNIT AND   * 03600020
*  UNIT ADDRESS THEREIN. A CODE IS RETURNED IN REGISTER 15, HEX 'FF'  * 03900020
*  IF THE TESTED UCB IS INVALID AND HEX 'F0' IF THE UCB IS ON-LINE.   * 04200020
*                                                                     * 04500020
*  803C IN REGISTER 1 DOES AN IDENTICAL OPERATION AS THE PRECEEDING   * 04800020
*  PARAGRAPH, EXCEPT FOR MOVING THE VOLUME SERIAL NUMBER OF THE       * 05100020
*  REQUESTED UCB INTO THE OLTEP AREA SPECIFIED. THIS FUNCTION WILL    * 05400020
*  ONLY BE REQUESTED FOR DIRECT ACCESS DEVICES.                       * 05700020
*                                                                     * 06000020
*                            FUNCTION 16                              * 06300020
*                            **********                               * 06600020
*  0040 IN REGISTER 1 WILL RESULT IN A UCB LOOK-UP USING THE OS/360   * 06900021
*  IOS UCB LOOKUP ALGORITHM. IF THE DEVICE ADDRESS REQUESTED IS       * 07000021
*  VALID THE UCB ADDRESS WILL BE MOVED INTO THE APPROPRIATE           * 07100021
*  ENTRY IN THE DEVICE TABLE ENTRY OF OLTEPS DEVTAB. WHEN A VALID     * 07200021
*  UCB IS FOUND THE FOLLOWING CHECKS WILL BE MADE                     * 07300021
*                                                                     * 07400021
*       1. FOR REMOTE TERMINALS WHEN THE TERMINAL IS ALLOCATED        * 07500021
*          THE ON-LINE ID IN DEVTAB WILL BE SET TO 'ONE'. WHEN        * 07600021
*          TERMINAL IS NOT ALLOCATED THE UCBNALOC IN THE UCB          * 07700021
*          WILL BE SET TO 'ONE'.                                      * 07800021
*                                                                     * 07900021
*       2. FOR ZUES (2305 I AND 2305 II) DEVICES (MULTIPLE EXPOSURE)  * 08000021
*          THE BASE UCB ADDRESS WILL BE CALCULATED WITH THE           * 08100021
*          FOLLOWING FORMULA:   THE BASE EXPOSURE UCB ADDRESS =       * 08200021
*         (EXPOSURE UCB ADDR) LESS (UCB SIZE TIMES EXPOSURE #).       * 08300021
*                                                                     * 08400021
*       3. THE UCBNALOC BIT WILL BE SET FOR OFFLINE AND               * 08500021
*          READY DEVICES. ALSO THE DEVTAB ON/OFF LINE WILL BE         * 08600021
*          SET                                                        * 08700021
*                                                                     * 09000020
*                            FUNCTION 17                              * 09300020
*                            **********                               * 09600020
*  0044 IN REGISTER 1 WILL RESULT IN A GETMAIN BEING ISSUED FOR 64    * 09900020
*  BYTES IN SUBPOOL 254. IT WILL RETURN THE GETMAIN ADDRESS IN REG-   * 10200020
*  ISTER 0.                                                           * 10500020
*  THIS FUNCTION WILL MOVE INTO OLTEP THE SYSTEM ASSIGNMENTS FOR THE  * 10800020
*  FOLLOWING                                                          * 11100020
*     A. THE OPERATING SYSTEM (PCP,MFT,MVT)                           * 11400020
*     B. CPU MODULE NUMBER                                            * 11700020
*     C. THE CHANNEL ASSIGNMENTS                                      * 12000020
*  THIS FUNCTION ALSO PERFORMS A UCBLOOK UP WHICH WILL CHECK ALL      * 12300020
*  DEVICES ON THE SYSTEM FOR TP OR 1419 DEVICES.  IF SUCH DEVICES ARE * 12600020
*  PRESENT A FLAG WILL BE SET IN OLTEPS COMMON AREA                   * 12900020
*                                                                     * 13200020
*                             FUNCTION 21                             * 13500020
*                             ***********                             * 13800020
*  0054 IN REGISTER 1 TESTS THE NOT READY BIT IN THE UCB SPECIFIED.   * 14100020
*  IF THE NOT READY BIT IS ON. HEX 'FF' IS RETURNED IN REGISTER 15.   * 14400020
*                                                                     * 14700020
*                                                                     * 15000020
*  ENTRY POINT:  IGC0605I                                             * 15300020
*                                                                     * 15600020
*  INPUT:       NA                                                    * 15900020
*                                                                     * 16200020
*  OUTPUT       NA                                                    * 16500020
*                                                                     * 16800020
*  EXTERNAL REFERENCES:  NONE                                         * 17100020
*                                                                     * 17400020
*                                                                     * 17700020
*********************************************************************** 18000020
 EJECT                                                                  18300020
*********************************************************************** 18600020
*                               EQUATES                               * 18900020
*********************************************************************** 19200020
 SPACE 2                                                                19500020
REG0     EQU    0                                                       19800020
SP       EQU   0                   REGISTER 0 - ADDRESS OF PARAMETER    20100020
*                                  LIST PASSED TO SVC 59                20400020
R1       EQU   1                                                        20700020
CALLREG1 EQU   1                                                        21000020
WORKREG2 EQU   2                                                        21300020
WKREG2   EQU   7                                                        21600020
SVUCBREG EQU   2                   REGISTER CONTAINING BACKUP OF UCB    21900020
*                                  ADDRESS                              22200020
EBCDIC   EQU   1                   USED IN GETTING EXPOSURE      S21050 22270021
ZUESREG  EQU   15                  NUMBER DURING UCBLOOKUP  F-16 S21050 22340021
HEX40    EQU   X'40'                 SIZE OF ZUSE UCB                   22410021
CVTREG   EQU   3                                                        22500020
CALLREG2 EQU   6                                                        22800020
CONFREG  EQU   6                   REGISTER 6 ADDRESS IN COMMON AREA    23100020
*                                  CONTAINING SYSTEM ASSIGNMENTS        23400020
FLGADREG EQU   6                   REGISTER -CONTAINS ADDRESS OF FLAG   23700020
TABREG   EQU   7                   CONTAINS ADDRESS OF UCB LOOKUP TABLE 24000020
TCBREG   EQU   4                                                        24300020
FUNCREG8 EQU   8                                                        24600020
UCBREG   EQU   8                                                        24900020
DCBREG   EQU   7                   REGISTER 7 ADDRESS OF DCB            25200020
SERREG   EQU   8                   ADDRESS OF CHANNEL                   25500020
*                                  ASSIGNMENT TABLE                     25800020
PARMREG  EQU   9             PARAMETER LIST REGISTER                    26100020
SAVEREG  EQU   10                                                       26400020
UCBSREG  EQU   10                  UCB ADDRESS FOR STATUS LOOKUP        26700020
R10      EQU   10                                                       27000020
DEVREG   EQU   10                  REGISTER CONTAINING ADDR OF DEVTAB   27300020
UCBCNTRG EQU   11                  REGISTER CONTAINING THE NUMBER OF    27600020
VOLSEREG EQU   11                  ADDRESS RECEIVING VOL. SER. NUMBER   27900020
BASEREG  EQU   12                                                       28200020
POOLREG  EQU   13                                                       28500020
RETURN   EQU   14                                                       28800020
RCREG    EQU   15                                                       29100020
SHIFT16  EQU   16                                                       29400020
D0       EQU   0                                                        29700020
D1       EQU   1                                                        30000020
D2       EQU   2                                                        30300020
D3       EQU   3                                                        30600020
D4       EQU   4                                                        30900020
D5       EQU   5                                                 S21050 31000021
D8       EQU   8                                                        31200020
D12      EQU   12                                                       31500020
D13      EQU   13                                                       31800020
D16      EQU   16                                                       32100020
D18      EQU   18                                                       32400020
D19      EQU   19                                                       32700020
D20      EQU   20                                                       33000020
D28      EQU   28                                                       33300020
D31      EQU   31                                                S21050 33600021
D34      EQU   34                  DEVTAB HEX ADDR               S21050 33700021
D56      EQU   56                  SIZE OF EACH DEVTAB ENTRY     S21050 33800021
D64      EQU   64                                                       33900020
D84      EQU   84                                                       34200020
HEX01    EQU   X'01'                                             S21050 34300021
HEX02    EQU   X'02'                                                    34500020
HEX04    EQU   X'04'                                                    34800020
HEX06    EQU   X'06'               CLASS FOR ZUES I              S21050 34810021
HEX07    EQU   X'07'               CLASS FOR ZUES II             S21050 34820021
D41      EQU   41                                                       34830021
HEX10    EQU   X'10'                   COMMO EQUIP                      34840021
HEX09    EQU     X'09'                                                  34842021
HEX0A    EQU   X'0A'                                                    34844021
HEX0B    EQU   X'0B'                                                    34846021
D14      EQU   14                                                       34848021
D11      EQU   11                                                       34850021
HEX1C    EQU   X'1C'                                                    34860021
HEX82    EQU   X'82'                                                    34870021
D27      EQU   27                                                       34880021
ANRIRBRG EQU   15                                                       34890021
REG1     EQU   1                                                        34900021
D36      EQU   36                                                       34910021
D38      EQU   38                                                       34920021
D24      EQU   24                                                       34930021
REG15    EQU   15                                                       34940021
HEX42    EQU   X'42'                                                    34950021
HEX08    EQU   X'08'                                                    35100020
HEX14    EQU   X'14'                                                    35400020
HEX20    EQU   X'20'                                                    35700020
HEX80    EQU   X'80'                                                    36000020
HEX1E    EQU   X'1E'                                                    36300020
HEX1D    EQU   X'1D'                                                    36600020
HEX1F    EQU   X'1F'                                                    36900020
HEX4T    EQU   X'40'                                                    37200020
HEXBF    EQU   X'BF'                                                    37500020
HEXF0    EQU   X'F0'                                                    37800020
HEXFF    EQU   X'FF'                                                    38100020
L1       EQU   1                                                        38400020
L2       EQU   2                                                        38700020
L3       EQU   3                                                        39000020
L4       EQU   4                                                        39300020
L6       EQU   6                                                        39600020
L8       EQU   8                                                        39900020
D6       EQU   6                                                        40200020
COND8    EQU   8                                                        40500020
COND14   EQU   14                                                       40800020
 EJECT                                                                  41100020
         BALR  BASEREG,REG0        SET BASE REGISTER                    41400020
         USING *,BASEREG           INDICATE BASE REGISTER BEING USED    41700020
         USING SUCCVT2,CVTREG                                           42000020
         LR    CALLREG1,POOLREG    SET SUBPOOL ADDRESS FOR FREEMAIN     42300020
         L     REG0,SUBPOOL        SET SUBPOOL PARAMETER FOR FREEMAIN   42600020
         FREEMAIN   R,LV=(0),A=(1)                                      42900020
         LR    CALLREG1,SAVEREG    RESTORE CALLING CODE REGISTER        43200020
         SR    RCREG,RCREG         CLEAR RETURN CODE REGISTER           43500020
         LA    FUNCREG8,D84       GET CALL CODE FOR FUNC 21      S20203 43800020
         CR    FUNCREG8,CALLREG2  IS THIS CALL FOR FUNC 21       S20203 44100020
         BE    FUNC21             YES GO TO FUNC 21                     44400020
         LA    FUNCREG8,D64                                      S20203 44700020
         CR    CALLREG2,FUNCREG8  GET CONDITION CODE FOR TRANSFER       45000020
         BE     FUNC16            MOVE DEVICE DESCRIPTORS               45300020
         BH    FUNC17             GETMAIN SYS ASN UCB LOOKUP            45600020
 EJECT                                                                  45900020
*********************************************************************** 46200020
*                             FUNCTION 15                             * 46500020
*********************************************************************** 46800020
 SPACE 2                                                                47100020
FUNC15   LM    UCBSREG,VOLSEREG,D0(PARMREG)  LOAD UCB ADDRESS AND VOL-  47400020
*                                            SER-NUMBER RETURN ADDRESS  47700020
         TM    D3(UCBSREG),HEX80   IS UCB ON-LINE                       48000020
         BNO   UCBCK               NO-CHECK FOR VALID UCB REQUEST       48300020
         LA    RCREG,HEXF0         YES-INDICATE UCB IS ON-LINE          48600020
UCBCK    TM    D2(UCBSREG),HEXFF   IS UCB VALID                         48900020
         BO    CHKVSN              YES-CHECK FOR VOLUME SERIAL NUMBER   49200020
*                                  REQUEST                              49500020
         LA    RCREG,HEXFF         NO-INDICATE INVALID UCB              49800020
         BR    RETURN              BRANCH REGISTER 14 TO CALLER         50100020
CHKVSN   SLL   CALLREG1,SHIFT16    SETUP FOR NEXT REQUEST               50400020
         LTR   CALLREG1,CALLREG1   IS VOLUME SER NUMBER REQUESTED       50700020
         BNM   GOBAK               NO-BRANCH TO RETURN                  51000020
         MVC   D0(L6,VOLSEREG),D28(UCBSREG)  MOVE VOLUME SERIAL NUMBER  51300020
*                                            TO CALLER AREA.            51600020
GOBAK    BR    RETURN              BRANCH REGISTER 14 TO CALLER         51900020
 EJECT                                                                  52200020
*********************************************************************** 52500020
*                             FUNCTION 16                             * 52800020
*********************************************************************** 53100020
 SPACE 2                                                                53400020
FUNC16   LM    DEVREG,UCBCNTRG,D0(PARMREG)   LOAD ADDRESS OF DEVTAB AND 53700020
*                                  DEVICE COUNT FROM PARAMETER LIST.    54000020
         L     UCBREG,CVTILK2           LOAD UCB ADDRESS POINTER        54300020
         OI    D20(TCBREG),HEX02   TURNON CLEANUP BIT IN TCB     S20203 54600020
         LR    SVUCBREG,UCBREG     SAVE BEGINNING ADDRESS OF UCB TABLE  54900020
FUNC16A  CLC   D0(L2,UCBREG),UCBTBEND   IS THIS THE END OF TABLE        55200020
         BE    UCBLOOP             YES-UCB INVALID CHECK NEXT UCB       55500020
         CLC   D0(L2,UCBREG),NOUCB IS UCB ADDRESS ZERO                  55800020
         BNE   FUNC16C             NO-GO CHECK IT OUT                   56100020
FUNC16B  LA    UCBREG,D2(UCBREG)   YES-SET POINTER TO NEXT UCB ADDRESS  56400020
         B     FUNC16A             AND CONTINUE LOOKUP                  56700020
FUNC16C  LH    WKREG2,D0(UCBREG)   IS THIS THE UCB OF THE DEVICE        57000020
         N     WKREG2,NOUCB       CLEAR FIRST 16 BITS = 0000     S20203 57300020
         CLC   D13(L3,WKREG2),D5(DEVREG) IS THIS THE UCB FOR THISS21050 57600021
*                                        ENTRY OF DEVTAB         S21050 57630021
         BE    VALIDUCB                  YES GO TO THE VALID     S21050 57660021
*                                        UCB CHECK               S21050 57690021
         LH    ZUESREG,D4(WKREG2)        GET THE HEX DEVICE ADDR S21050 57720021
*                                        AND 'AND' OUT FIRST FOURS21050 57750021
         N     ZUESREG,ZAP4BITS          BITS                    S21050 57780021
         CH    ZUESREG,D34(DEVREG)       DO THE TWO MATCH. IF SO S21050 57810021
*                                        THIS IS A POSSIBLE ZUES S21050 57840021
*                                        DEVICE.                 S21050 57870021
         BNE   FUNC16B             NO-CHECK NEXT TABLE ENTRY            57900020
VALIDUCB EQU   *                         IS THIS A VALID UCB     S21050 58000021
         TM    D2(WKREG2),HEXFF    YES-CHECK UCB FOR VALID ID           58200020
         BNO   UCBLOOP             UCB OFF-LINE LOOKUP NEXT UCB REQUEST 58500020
         ST    WKREG2,D8(DEVREG)   YES-STORE UCB ADDRESS IN DEVTAB      58502021
         TM     D1(WKREG2),HEX04  IS UCBNALOC ON                S59673  58504021
         BNO   ALLOCK             IF NO, CONTINUE               S59673  58506021
         TM    D0(WKREG2),HEX08       DID OLTEP TURN IT IN              58506621
         BO    ALLOCK                YES, CONTINUE               S59673 58507221
         OI    D14(DEVREG),HEX08  SET NO GO SWITCH              S59673  58508021
         B     UCBLOOP            AND CONTINUE LOOKUP           S59673  58508421
ALLOCK   TM    D3(WKREG2),X'08'    IS DEVICE ALLOCATED          S59673  58510021
         BNO   REMOTE              NO CONTINUE CHECKS           S59673  58520021
         OI    D14(DEVREG),HEX04   TURN ON ALLOCATED TO SYS BIT S59673  58522021
         B     REMOTE             CHECK FOR REMOTE TERMINAL     S21050  59100021
TESTON   EQU   *                  TESY UCB FOR STATUS           S21050  59400021
         TM    D3(WKREG2),HEX80    CHECK FOR UCB OFF-LINE               59700020
         BNO   LOVE               GO SET THE NON ALLOCATE BIT    S21050 60000021
ONLINE   EQU   *                         A REMOTE TERMINAL-      S21050 60100021
         OI    D12(DEVREG),HEX80   INDICATE, IN DEVTAB, THAT UCB IS     60300020
*                                  ON-LINE                              60600020
LOVE     TM    D3(WKREG2),X'88'    IS DV ALL OR ONLINE           5176   60650021
         BZ    UCBNALOC           NO, GO SET UCBNALOC            5176   60750021
UCBLOOP  LA    DEVREG,D56(DEVREG)      SET PTR TO NEXT ENTRY     S21050 60900021
*                                      IN DEVTAB                 S21050 61000021
         LR    UCBREG,SVUCBREG     RESET UCB TABLE ADDRESS              61200020
         BCT   UCBCNTRG,FUNC16A    DECREMENT DEVICE REQUEST COUNTER     61500020
         XR    ZUESREG,ZUESREG         SET RETURN CODE TO ZEROOO S21050 61600021
         BR    RETURN              BRANCH ON REGISTER 14 TO CALLER      61800020
UCBNALOC EQU   *                                                 S59673 61850021
SETID    EQU   *                                                 S59673 62060021
         OI    D1(WKREG2),HEX04   TURN ON UCBNALOC (OFFLINE ID)  S20203 62100021
         OI    D0(WKREG2),HEX08                                  S59673 62150021
         B     UCBLOOP             CONTINUE PROCESS NEXT DEV     S20203 62400020
REMOTE   TM    D41(DEVREG),HEX01         IS THIS A REMOTE TERMIN-S21050 62402021
         BNO   ZUES                      AL, NO- GO CK FOR ZUES  S21050 62404021
         TM    D3(WKREG2),HEX80          IS THIS TERMINAL ONLINE S21050 62406021
         BNO   SETFALSE                  YES GO SET DEVTAB ONLINES21050 62408021
         OI    D12(DEVREG),HEX80 SET ONLINE BIT                  S59673 62408421
*                                        INDICATOR               S21050 62410021
         B     UCBLOOP            GO SET FALES EXPOSURE NO.      S21050 62412021
*                                 AND UCBNALOC                          62414021
ZUES     CLI   D18(WKREG2),HEX20       IS THIS A DASD            S21050 62416021
         BNE   SETFALSE                NO, CONTINUE LOOKUP       S21050 62418021
         CLI   D19(WKREG2),HEX06       IS THIS A ZUES I          S21050 62420021
         BE    EXPOSURE                YES, GO SET EXPOSURE #    S21050 62422021
         CLI   D19(WKREG2),HEX07       IS THIS A ZUES II         S21050 62424021
         BE    EXPOSURE                                          S21050 62426021
SETFALSE MVI   D31(DEVREG),HEXFF       SET FALSE EXPOSURE # IN   S21050 62428021
         B     ANRCHECK                GO CHECK FOR ANR DEVICE          62430021
EXPOSURE L     ZUESREG,D12(WKREG2)     GET THE UCB EBCDIC ADDR   S21050 62432021
         LA    ZUESREG,D0(ZUESREG)     ZAP-OUT HI-BYTE           S21050 62434021
         L     EBCDIC,D4(DEVREG)       GET DEVTAB  EBCDIC ADDR   S21050 62436021
         LA    EBCDIC,D0(EBCDIC)       ZAP-OUT HI-BYTE           S21050 62438021
         SR    EBCDIC,ZUESREG          SUBTRACT THE TWO          S21050 62440021
         STC   EBCDIC,D31(DEVREG)      STORE EXPOSURE # IN DEVTABS21050 62442021
         LA    ZUESREG,HEX40           GET SIZE OF ZUES UCB      S21050 62444021
         XR    REG0,REG0          CLEAR REG ZERO FOR MULTIP      S21050 62446021
         MR    REG0,ZUESREG            MULT EXP # TIMES SIZE     S21050 62448021
         LR    REG0,WKREG2        GET UCB ADDR                   S21050 62450021
         SR    REG0,EBCDIC             GET ADDR OF BASE EXPOSURE S21050 62452021
         ST    REG0,D8(DEVREG)         PLACE ADDR IN DEVTAB      S21050 62454021
         LR    UCBREG,REG0                                              62454821
         TM    D3(UCBREG),X'80'        IS BASE ON LINE                  62455621
         BO    ONLINE                  YES, SET BIT IN DEVTAB           62456421
         B     UCBNALOC           NO SET BIT IN NON BASE UCB            62457221
         EJECT                                                          62458021
*********************************************************************** 62460021
*                                                                     * 62462021
*  THIS SUBROUTINE WILL CHECK THE UCB GIVEN AS A PARAMETER            * 62464021
*  TO INSURE THE LOCAL ANR 3270 DEVICE MEETS THE FOLLOWING            * 62466021
*  RESTRICTIONS                                                       * 62468021
*             A. THE ATTENTION INDEX AT UCBATI (UCB +11) IS           * 62470021
*                FOR THE BASIC TELECOMMUNICATIONS ACCESS              * 62472021
*                METHOD, NAMELY HEX '1C'.                             * 62474021
*                                                                     * 62476021
*             B. THE UCB SHOWS THIS LOCAL ANR 3270 AS NOT             * 62478021
*                BEING AN ACTIVE OPERATORS CONSOLE. BOTH              * 62480021
*                BITS 0 AND 6 OF UCB +3 (SRTESTAT) WILL               * 62482021
*                BE ON.                                               * 62484021
*                                                                     * 62486021
*             C. THE DEVICE CLASS AND UNIT TYPE ARE INDEED            * 62488021
*                REPRESENTATIVE OF THE LOCAL ANR DEVICE.              * 62490021
*                THE DEVICE CLASS IS  HEX'10' AT UCB+17.              * 62492021
*                THE UNIT TYPE IS HEX09 X 0A, X0B                21003  62494021
*                AT UCB + 18                                            62495021
*                                                                     * 62496021
*                IF THE DEVICE IS OFF LINE NO ERROR CHK IS MADE         62498021
*                IN THE GRAPHICS CONTROL BYTE OF THE UCB ON.          * 62516021
*                THIS AT UCB + 27 AND IS SET TO HEX 80.               * 62518021
*                                                                     * 62520021
*             E. WHEN ONE OF THE ABOVE RESTRICTIONS IS VIOLATED       * 62522021
*                THIS MODULE WILL SET THE ERRENTRY BIT ON IN          * 62524021
*                THE DEVICE TABLE ENTRY AT DEVTAB + 18 = HEX'80'.     * 62526021
*                THIS BIT WILL BE RECOGNIZED BY THE DEVICE            * 62528021
*                DECODER MODULE  IFDOLT61 AND WILL DELETE THE         * 62530021
*                ENTRY.                                               * 62532021
*                                                                     * 62534021
*             F. IF THE DEVICE IS ONLINE IFDOLT61 WILL REQUEST        * 62536021
*                OPERATOR PERMISSION TO CONTINUE.                     * 62538021
*                                                                     * 62540021
*********************************************************************** 62542021
         SPACE 2                                                        62544021
ANRCHECK   EQU  *                                                21003  62546021
         CLI   D18(WKREG2),HEX10       IS THIS COMMO EQUIP        21003 62550021
         BNE   TESTON                  NO, STOP CHECK FOR ANR     21003 62554021
         CLI   D19(WKREG2),HEX09       IS THIS A 3277 DISPLAY     21003 62558021
         BL    TESTON                  NO, STOP CHECK FOR ANR     21003 62562021
         CLI   D19(WKREG2),HEX0B       IS THIW A 3284 OR A 2386   21003 62566021
         BH    TESTON                  NO, STOP CHECK FOR ANR     21003 62570021
         CLI   D3(WKREG2),HEX80        IS DEV ONLINE              21003 62574021
         BL    SETID                   YES,GO NEXT DEV          SA64258 62578000
         OI    D12(DEVREG),HEX80       SET ONLINE BIT ,CONTINUE   21003 62582021
ACTIVE   TM    D3(WKREG2),HEX82      IS THIS THE ACTIVE OP CONSOLE      62586021
*                                                                 21003 62590021
         BO    SETERRON                YES  ***ERROR *** NO TEST  21003 62594021
         CLI   D11(WKREG2),HEX1C       IS THIS DEV A BTAM DEV   SA61006 62596021
         BNE   SETERRON                NO, GO SET ERROR BIT     SA61006 62596421
         OI    D27(WKREG2),HEX80       SET OLTEP EXECUTING FLAG   21003 62598021
         B     SETID                CONTINUE TO NEXT DEVICE     SA61006 62602021
         SPACE 2                                                        62610021
SETERRON EQU   *                                                        62612021
         OI    D14(DEVREG),HEX80       SET ANR NO TEST SWITCH     21003 62614021
         B     UCBLOOP                   GO TO NEXT ENTRY               62616021
         EJECT                                                          62618021
 EJECT                                                                  62700020
*********************************************************************** 63000020
*                             FUNCTION 17                             * 63300020
*********************************************************************** 63600020
 SPACE 2                                                                63900020
FUNC17   L     SP,SPL192          SET REG ZERO  TO SUBPOOL       S20203 64200020
*                                 LENGTH FOR GETMAIN             S20203 64500020
         GETMAIN  R,LV=(0)         ASSIGN DEB AREA IN SUBPOOL 254.      64800020
         LR    SP,R1               PUT DEBAD IN REGISTER 0              65100020
         LA    WORKREG2,D8         SET DCB ADDRESS OFFSET               65400020
         OI    D20(TCBREG),HEX02       SET TCBOLTEP FLAG ON     SA61998 65500000
         LR    R10,CVTREG          LOAD ADDRESS OF CVT                  65700020
         SR    R10,WORKREG2        SUBTRACT DISPLACEMENT TO MODEL #     66000020
*                                  LOCATION OF CVT                      66300020
         L     CONFREG,D0(PARMREG) LOAD ADDRESS OF CONF AREA            66600020
*                                  FROM PARAMETER LIST.                 66900020
         MVC   D0(L1,CONFREG),OSCONF         MOVE OPSYS TO CALLER'S     67200020
*                                  AREA                                 67500020
         MVC   D2(L2,CONFREG),D2(R10)           MOVE SYSTEM MODEL # TO  67800020
*                                  CALLER'S AREA                        68100020
         L     DCBREG,OSCONF            LOAD ADDRESS OF DCB             68400020
         SR    DCBREG,WORKREG2     ADJUST DCB ADDRESS                   68700020
         L     SERREG,D0(DCBREG)   LOAD ADDRESS OF SER TABLE            69000020
         MVC   D4(L8,CONFREG),D0(SERREG)     MOVE CHANNEL ASSIGNMENTS   69300020
*                                  TO CALLER'S AREA                     69600020
         L     TABREG,CVTILK2      LOAD UCB ADDRESS POINTER             69900020
         L     FLGADREG,D4(PARMREG)     LOAD PARAMETER LIST CONTAINING  70200020
*                                       ADDRESS OF TP 1419 FLAG         70500020
NEXTTST  CLC   D0(L2,TABREG),UCBTBEND   IS THIS THE END OF THE UCB      70800020
*                                  LOOKUP TABLE.                        71100020
         BCR   COND8,RETURN       BRANCH TO CALLER                      71400020
         CLC   D0(L2,TABREG),NOUCB IS UCB ADDRESS ZERO                  71700020
         BNE   CHKDEVTP            NO-CHECK DEVICE FOR TP OR 1419       72000020
TRYAGAIN LA    TABREG,D2(TABREG)   YES-SET POINTER TO NEXT UCB ADDRESS  72300020
         B     NEXTTST             BRANCH TO TEST NEXT UCB ADDRESS      72600020
CHKDEVTP LH    UCBREG,D0(TABREG)   LOAD ADDRESS OF UCB                  72900020
         TM    D18(UCBREG),HEX4T     IS THIS TP                         73200020
         BO    TEST4014          GO TEST FOR 4014  FOR RAC       S20203 73500020
TESTCONT TM    D18(UCBREG),HEX08  IS THIS DEVICE A UNIT RECORD   S20203 73800020
         BNO   TRYAGAIN            NO-BRANCH TO TRY NEXT DEVICE         74100020
         TM    D19(UCBREG),HEX1D   IS THIS A 1419 READ CONTROL DEVICE   74400020
         BO    SETFLG              YES-BRANCH TO SET FLAG               74700020
         TM    D19(UCBREG),HEX1E   IS THIS A 1419 STACKER SELECT DEVICE 75000020
         BO    SETFLG              YES-BRANCH TO SET FLAG               75300020
         TM    D19(UCBREG),HEX1F   IS DEVICE A 1419 READING CONTROL     75600020
         BNO   TRYAGAIN            NO-BRANCH TO TRY NEXT DEVICE         75900020
SETFLG   OI    D0(FLGADREG),HEX04  SET FLAG INDECATING TP OR 1419       76200020
*                                  DEVICES ARE ATTACHED TO SYSTEM       76500020
         B     TRYAGAIN           TRY THE NEXT DEVICE                   76800020
TEST4014 OI    D0(FLGADREG),HEX04 SET FLG INDICATING TP OR 1419 DEVICES 77100020
*                                   ATTACHED TO SYSTEM                  77400020
         CLI   D19(UCBREG),HEX14  IS THIS A  4014 DEVICE        SA59679 77700021
         BE    ONLINECK           GO CHECK ONLINE STSTUS        SA59679 78000021
         B     TESTCONT           NO,  GO CONTINUE TESTING       S20203 78300020
ONLINECK TM    D3(UCBREG),HEX80   IS THIS DEV ON/OFF LINE        S20203 78600020
         BNO   TESTCONT           THIS UCB IS OFF LINE           S20203 78900020
SETADDR  LR    RCREG,UCBREG       SAVE ADDR FOR RAC              S20203 79200020
         OI    D0(FLGADREG),HEX04                                S20203 79500020
         BR    RETURN             RETURN TO CALLER                      79800020
  EJECT                                                                 80100020
*********************************************************************** 80400020
*                             FUNCTION 21                             * 80700020
*********************************************************************** 81000020
 SPACE 2                                                                81300020
FUNC21   L     UCBREG,D0(PARMREG)  LOAD UCB ADDRESS                     81600020
         TM    D4(PARMREG),HEX4T   IS THIS RESTORE A NOT-READY REQUEST  81900020
         BNO   BYPRES              NO - BYPASS NOT-READY BIT RESTORE    82200020
         OI    D6(UCBREG),HEX4T    RESTORE NOT-READY BIT                82500020
         BR    RETURN              BRANCH ON REGISTER 14 TO CALLER      82800020
BYPRES   TM    D6(UCBREG),HEX4T    IS NOT-READY BIT ON                  83100020
         BCR   COND14,RETURN      NO-  RETURN WITH  ZERO CODE           83400020
         LA    RCREG,HEXFF         IT'S ON SET RETURN CODE              83700020
         TM    D18(UCBREG),HEX80   IS THIS TAPE                   21937 84000021
         BCR   COND14,RETURN      NO-  GO TO EXIT                       84300020
         NI    D6(UCBREG),HEXBF    YES - RESET NOT READY BIT            84600020
DUN21    BR    RETURN              BRANCH ON REGISTER 14 TO CALLER      84900020
 EJECT                                                                  85200020
**********************************************************************  85500020
*          CONSTANTS                                                 *  85800020
**********************************************************************  86100020
         DS    0F                                                       86400020
SUBPOOL  DC    X'FE000010'                                              86700020
SPL192   DC    X'FE0000C0'        FOR SUBPOOL 292 BYTES          S20203 87000020
*  THE FOLLOWING TWO DC'S MUST APPEAR IN THIS ORDER AS THEY ARE         87300020
*  USED IN CONJUNCTION TO ONE ANOTHER  1)  NOUCB                        87600020
*                                      2) UCBTBEND                      87900020
NOUCB    DC    X'0000'                                                  88200020
UCBTBEND DC    X'FFFF'                                                  88500020
ZAP4BITS DC    X'00000FFF'             CONSTANT TO CLEAR SWITCH  S21050 88570021
SVC59    DC    C'SVC 06 PATCH AREA   ' DUMP IDENTIFICATION (TENP)       88640021
         DS    0H                                                       88710021
PATCH06  DC    26XL2'0700'        PATCH AREA FOR THIS MODULE            88800020
 EJECT                                                                  89100020
         DS      0D                                                     89400020
SUCCVT2  DSECT                                                          89700020
         CVT                                                            90000020
OSCONF   EQU   CVTSTB+4           DISP OF 116 INTO CVT                  90300020
*********************************************************************** 90600020
         END                                                            90900020
