IGC0008E CSECT                                                          00200021
*********************************************************************   00202021
*                                                                       00204021
* STATUS:                                                               00206021
*                                                                       00208021
*    RELEASE 21.8                                                       00210021
*                                                                       00212021
*                                                                       00214021
* FUNCTION:                                                             00216021
*                                                                       00218021
*    IGC0008E IS THE FIREST LOAD OF SVC 85. ON INITIAL ENTRY IT         00220021
*    ATTEMPTS TO ENSURE DEVICE ALLOCATION WILL NOT PROCESS              00222021
*    CONCURRENTLY WITH DDR. IT ALSO ENSURES THAT IF A TASK FOR          00224021
*    ALLOCATION IS SWAPPED OUT OF CORE UNDER TSO, THAT TASK WILL        00226021
*    NOT PROCESS CONCURRENTLY WITH DDR. IF THIS CANNOT BE ENSURED       00228021
*    DDR OPERATION FOR THE CURRENT REQUEST IS TERMINATED. OTHER-        00230021
*    WISE CONTROL IS ROUTED TO IGC0108E, IGC0208E OR IGC0408E,          00232021
*    ACCORDING TO AN INDEX CODE SET UP BY THE INVOKING MODULE           00234021
*    (IGF2503D OR IGE0660A).                                            00236021
*                                                                       00238021
*    WHEN DDR PROCESSING IS FINISHED, CONTROL IS RETURNED TO            00240021
*    THIS MODULE TO CLEAN UP AND RETURN TO THE RESIDENT ROUTINE         00242021
*    VIA SVC 3 UNLESS THERE IS ANOTHER RQE ON THE WAIT QUEUE. IN THIS   00244021
*    CASE, CONTROL GOES TO IGC0208E TO PROCESS THIS REQUEST.            00246021
*                                                                       00248021
*                                                                       00250021
* ENTRY POINT:                                                          00252021
*                                                                       00254021
*         IGC0008E - FIRST INSTRUCTION OF MODULE                        00256021
*                                                                       00258021
*                                                                       00260021
* INPUT:                                                                00262021
*                                                                       00264021
*    ON ENTRY FROM SVC INTERRUPT HANDLER - REG 3 = CVT ADDR, REG 4 =    00266021
*    ADDR OF IGFRMTCB, REG 5 = ADDR OF SVRB, DDRFLGSB CONTAINS A        00268021
*    ROUTING CODE OF ONE OF THE FOLLOWING:                              00270021
*    X'00' - SET BY IGF2503D FOR OPERATOR DASD OR UNIT RECORD SWAPS     00272021
*    X'04' - SET BY IGF2503D FOR OPERATOR TAPE SWAPS                    00274021
*    X'08' - SET BY IGE0660A FOR SYSTEM INITIATED SWAPS                 00276021
*                                                                       00278021
*    TO TERMINATE DDR, THIS MODULE CAN BE ENTERED FROM:                 00280021
*    IGC0108E, IGC0208E, IGC0308E, IGC0508E, IGC0608E                   00282021
*    IN ALL CASES THE FOLLOWING APPLY:                                  00284021
*    REG 1 = DDR RQE ADDR, REG 3 = CVT ADDR, REG 5 = XSA ADDR, REG 7 =  00286021
*    'FROM' DEVICE UCB ADDR, REG 8 = 'TO' UCB ADDR, REG 10 = DDR DEB    00288021
*    ADDR, REG 11 = IORMSCOM ADDR, REG 13 = DDR IOB ADDR. DDRFLGSC      00290021
*    WILL HAVE THE TERMNATE BIT ON.                                     00292021
*                                                                       00294021
*                                                                       00296021
* OUTPUT:                                                               00298021
*                                                                       00300021
*    FOR ALL EXITS, THE ABOVE REGISTERS REMAIN THE SAME. REG 2 = DDR    00302021
*    WAIT QUEUE ADDR. FOR XCTL TO IGC0808E DDRFLGSC WILL HAVE THE       00304021
*    TERMNATE BIT ON.                                                   00306021
*                                                                       00308021
*                                                                       00310021
* EXTERNAL REFERENCES:                                                  00312021
*                                                                       00314021
*         SVC 3, SVC 15, XCTL, ABEND, TSEVENT, POST (WITH TJID).        00316021
*                                                                       00318021
*                                                                       00320021
* EXITS-NORMAL:                                                         00322021
*                                                                       00324021
*         XCTL TO IGC 0108E, IGC0208E,IGC0408E,IGC0808E                 00326021
*         SVC 3 WHEN DDR HAS COMPLETED                                  00328021
*         ABEND 155, WHEN A TASK OTHER THAN DDR'S CALLS SVC 85          00330021
*                                                                       00332021
*                                                                       00334021
* EXITS-ERROR:                                                          00336021
*                                                                       00338021
*         NONE                                                          00340021
*                                                                       00342021
*                                                                       00344021
* TABLES/WORK AREAS:                                                    00346021
*                                                                       00348021
*         IORMSCOM - DDR'S COMMUNICATIONS AREA                          00350021
*                                                                       00352021
*                                                                       00354021
* ATTRIBUTES:                                                           00356021
*                                                                       00358021
*         ENTERED DISABLED. ENABLES AFTER SOME INITIAL PROCESSING       00360021
*         SERIAL REUSABLE.                                              00362021
*                                                                       00364021
*                                                                       00366021
* CHARACTER CODE DEPENDENCY:                                            00368021
*                                                                       00370021
*         NONE                                                          00372021
*                                                                       00374021
* UPDATE ACTIVITY                                              @S66538P 00374421
*                                                              @S66538P 00374821
*         APAR 66538 (FLIPPED RECORDS ON TAPE) 9/13/73         @S66538P 00375221
*        APAR 69365 (USER CANCELLED DURING REPOS. -- DDR ATTEMPTS       00375621
*                    TO RETRY -- UCBERR FLAG LEFT ON )     3/6/74       00375821
*        APAR 68347 (DDR WTO AFTER MAKING ALLOCATION NON-DSPCH) 3/7/74  00376021
*        CHANGES WERE MADE TO REDUCE SIZE OF MODULE             3/7/74  00377021
*          PTM 0028                                                     00377521
         SPACE 2                                                        00378021
         TITLE '   IGC0008E - INITIATOR/ROUTER/TERMINATOR'              00400021
         BALR  BASE,N0                  MODULE BASE REG                 00600021
         USING *,BASE                   MODULE ADDR                     00800021
         USING CVTDSECT,CVTREG          CVT ADDR                        01000021
         L     COMMPTR,CVTDCB           LOGREC DCB PTR                  01200021
         L     COMMPTR,N0(COMMPTR)      IORMSCOM PTR                    01400021
         USING IORMS,COMMPTR            IORMSCOM ADDR                   01600021
*                                                                       01650000
*        SET UP FOR DDR/TSO/ALLOCATION INTERFACE                        01700000
*                                                                       01750000
         L     WKREG2,N228(CVTREG)      TSCVT PTR                 55979 01800021
         LH    WKREG14,N26(WKREG2)      SIZE OF TJB               55979 02000021
         N     WKREG14,ZEROHIGH         CLEAR 2 HIGH ORDER BYTES        02200021
         MH    WKREG14,ALLOTJID         TJID X SIZE OF TJB,             02600021
         A     WKREG14,N0(WKREG2)       + TJB TAB PTR=ADDR OF TJB 55979 03000021
         USING TJB,WKREG14                                              03400021
         L     WQPTR,IOSVT              IOS/DDR VECTOR TABLE PTR        03600021
         L     WQPTR,N0(WQPTR)          WAIT Q PTR                      03800021
         TM    DDRFLGSC,CANCEL          WAS CANCEL MSG ISSUED           04000021
         BO    CHKWAITQ                 YES, GO CHECK WAIT Q            04200021
          XC     USRDCB+N1(N3),USRDCB+N1   CLEAR USRDCB ON DDR ENTRY    04205021
*   THERE IS A POSSIBILITY THAT PROBLEMS MAY ARISE IN CHANNEL END       04210021
*   APPENDAGE IF AN OLD DCB POINTER IS USED.  CHANNEL END APPENDAGE     04215021
*   MUST CHECK FOR ZERO.                                                04220021
          SPACE                                                         04225021
          SPACE                                                         04350021
         TM    DDRFLGSC,TERMNATE        IS DDR TO BE TERMINATED         04400021
         BO    ENDDDR                   YES, GO CLEAN UP                04600021
*                                                                       04800021
*        INITIAL ENTRY. IF THE RMS TCB DID NOT ISSUE SVC 85 - ABEND     04970000
*                                                                       04980000
         L     WKREG15,RMSTCB           IORMS TCB PTR                   05000021
         LA    WKREG15,N0(WKREG15)      CLEAR HIGH ORDER BYTE           05200021
         LA    OURTCB,N0(OURTCB)        CLEAR HIGH ORDER BYTE           05400021
         CR    OURTCB,WKREG15           DID IORMS TCB ISSUE SVC 85      05600021
         BNE   SINK                     NO, ABEND CALLER                05800021
*                                                                       05850000
         LH    FMUCB,DDRFMUCB           'FROM' UCB POINTER              05860000
         TM    N18(FMUCB),TAPE          IS SWAP FOR TAPE                05870000
         BZ    NOTAPE                   NO,BYPASS SEARCH                05872000
         L     WKREG15,CVTHEAD          HIGHEST TCB POINTER             05890000
         LA    WKREG15,N0(WKREG15)      CLEAR HIGH BYTE                 05892000
*                                                                       05894000
GETDEB   EQU   *                                                        05896000
         L     USERDEB,N8(WKREG15)      GET DEB ADDR, IF ANY            05898000
         LA    USERDEB,N0(USERDEB)      CLEAR HIGH BYTE                 05898400
         LTR   USERDEB,USERDEB          IS THIS ADDR ZERO               05898800
         BZ    NEXTTCB                  YES, GET NEXT TCB ADDR          05899200
*                                                                       05899600
COMPUCB  EQU   *                                                        05899700
         CR    WKREG15,OURTCB       IS THIS DDR TCB               51698 05903921
         BE    NEXTTCB                  YES, GET NEXT TCB               05905900
         CLC   N34(N2,USERDEB),DDRFMUCB DOES DEB UCB = FROM UCB         05908200
         BE    INITREGS                 YES, GO INIT REGISTERS          05912400
         L     USERDEB,N4(USERDEB)      GET NEXT DEB, IF ANY            05916600
         LA    USERDEB,N0(USERDEB)      CLEAR HIGH BYTE                 05926600
         LTR   USERDEB,USERDEB          IS THIS ADDR ZERO               05928600
         BNZ   COMPUCB                  NO, SEE IF UCB'S COMPARE        05930600
*                                                                       05932600
NEXTTCB  EQU   *                                                        05933000
         L     WKREG15,N116(WKREG15)    GET NEXT TCB, IF ANY            05933100
         LA    WKREG15,N0(WKREG15)      CLEAR HIGH BYTE                 05933200
         LTR   WKREG15,WKREG15          IS THIS ADDR ZERO               05938800
         BNZ   GETDEB                   NO, GET DEB(S)                  05940800
         B     ENDDDR                   YES, NO TCB FOUND,TERMINATE     05942800
*                                                                       05943200
*        INITALIZE REGISTERS FOR SUBSEQUENT LOADS OF SVC 85             05944400
*                                                                       05950000
INITREGS EQU   *                                                        05960000
         ST    WKREG15,USRTCB           SAVE USER'S TCB PTR             05970000
         L     USERDCB,N24(USERDEB)     USER'S DCB POINTER        51696 05980021
         ST    USERDCB,USRDCB           SAVE USER'S DCB POINTER   51696 05990021
*                                                                       05992000
NOTAPE   EQU   *                                                        05994000
         LA    SVRBPTR,N96(SVRBPTR)     EXTENDED SAVE AREA PTR          06000021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     06200021
         L     OURIOB,N4(RQEPTR)        DDR IOB PTR                     06400021
         L     OURDEB,N8(RQEPTR)        DDR DEB PTR                     06600021
         LH    FMUCB,DDRFMUCB           'FROM' UCB PTR                  06800021
         LH    TOUCB,DDRTOUCB           'TO' UCB PTR                    07000021
         TM    DDRFLGSD,SYSRESBR+DDRMSG IS CANCEL MSG WANTED            07200021
         BZ    CHKDAR                   NO, GO SEE IF DAR PROC. OCCURRD 07400021
*                                                                       07600021
CANCLREQ EQU   *                                                        07800021
         OI    DDRFLGSC,CANCEL          TO INDICATE CANCEL MSG          08000021
         MVC   N8(N8,SVRBPTR),MSGMOD2   LOAD NAME FOR XCTL              08200021
         MVC   DDRWORK+N12(N8),LOAD0    FOR RETURN CONTROL AFTER MSG    08400021
         B     GOXCTL                   GO PREPARE FOR XCTL             08600021
*                                                                       08800021
*        IF DAR BIT IS ON IN TCB, DDR ABENDED AND WILL GO THROUGH       08950000
*        TERMINATION PROCESSING.                                        08960000
*                                                                       08970000
CHKDAR   EQU   *                                                        09000021
         TM    N172(OURTCB),DARBIT      HAS DAR PROCESSING TAKEN PLACE  09200021
         BNZ   DARCODE                  YES, GO RE-INITIALIZE DDR       09400021
*                                                                       09600021
         NC    ALLOCTCB+N1(N3),ALLOCTCB+N1 IS ALLOCATION IN PROGRESS    09800021
         BNZ   CHKTSO                   YES, SEE IF TASK IS FOR TSO     10000021
*                                                                       10200021
*        DDR/TSO/ALLOCATION INTERFACE TO PREVENT CONCURRENT             10250000
*        PROCESSING BY DDR AND ALLOCATION.                              10300000
*                                                                       10350000
ZEROECB  EQU   *                                                        10400021
         MVI   ALLOCECB,ZERO            CLEAR ALLOCATION ECB            10600021
         B     GETCODE                  GO GET ROUTING CODE FOR XCTL    10800021
*                                                                       11000021
*        IF TASK IS FOR TSO, HE MUST BE IN STORAGE FOR DDR TO SET       11050000
*        HIM NON-DISPATHABLE. IF HE IS NOT, A BIT MUST BE SET TO HAVE   11100000
*        HIM RESTORED NON-DISP.                                         11150000
*                                                                       11160000
CHKTSO   EQU   *                                                        11200021
         LH    WKREG0,ALLOTJID          GET TJID, IF ANY                11260021
         N     WKREG0,ZEROHIGH          CLEAR HIGH ORDER BYTES          11320021
         BZ    CHKENQ                   NO, SEE IF THIS TASK HAS ENQ'D  11600021
         TM    N228(CVTREG),TSOREADY    IS TASK READY                   11800021
         BZ    ZEROECB                  NO, ZERO ALLOCATION ECB         12000021
         TM    TJBSTAT,TJBINCOR         IS TASK IN ATORAGE              12200021
         BO    SETNDISP                 YES, GO SET TASK NON-DISPATCH   12400021
         OI    TJBRSTOR,TJBDDRND        TO RESTORE TASK AS NON-DISPATCH 12600021
         B     SYSTMTYP                                                 12800021
*                                                                       13000021
*        TASK IS IN STORAGE SET NON-DISPATCHABLE                        13050000
*                                                                       13100000
SETNDISP EQU   *                                                        13200021
         L     WKREG15,ALLOCTCB         ADDR OF ALLOCATION TCB          13300021
         OI    N33(WKREG15),NDCTL       SET PRIMARY NON-DISP BIT IN TCB 13400021
         OI    N173(WKREG15),TCBDDRND   SET DDR NON-DISP BIT IN TCB     13600021
         TSEVENT ENQWAIT,TJID=(WKREG0)  TO SWAP OUT NOW                 13800021
         B     SYSTMTYP                                                 14000021
*                                                                       14200021
*        IF WTO HAS BEEN ENQUED BY ALLOCATION, DDR MUST TERMINATE       14250000
*        TO PREVENT INTERLOCK CONDITION, SINCE DDR USES WTO AND         14300000
*        HAS MARKED THE TCB IN ALLOCTCB NONDISPATCHABLE.                14350000
*                                                                       14360000
CHKENQ   EQU   *                                                        14400021
         L     WKREG15,ALLOCTCB         ADDR OF ALLOCATION TCB          14600021
         OI    N33(WKREG15),NDCTL       SET PRIMARY NON-DISP BIT IN TCB 14800021
         OI    N173(WKREG15),TCBDDRND   SET DDR NON-DISP BIT IN TCB     15000021
*                                                                       15200021
SYSTMTYP EQU   *                                                        15400021
         TM    CVTDCB,MFTSYSTM          IS THIS AN MFT SYSTEM           15600021
         BO    MFTQCB                   YES, MUST LOCATE QCBS DIFFERENT 15800021
         L     WKREG15,CVTABEND         ADDR OF SECONDARY CVT           16000021
         L     WKREG15,N20(WKREG15)     ADDR OF HEADER FOR MAJOR QCBS   16200021
         B     MAJORQCB                 GO GET ADDR OF FIRST MAJOR QCB  16400021
*                                                                       16600021
MFTQCB   EQU   *                                                        16800021
         L     WKREG15,CVTBTERM         ADDR OF ABTERM ROUTINE          17000021
         L     WKREG15,N12(WKREG15)     ADDR OF HEADER FOR MAJOR QCBS   17200021
*                                                                       17400021
MAJORQCB EQU   *                                                        17600021
         L     WKREG15,N0(WKREG15)      ADDR OF MAJOR QCB               17800021
CHKIEECT EQU   *                                                        18000021
         CLC   N12(N8,WKREG15),RESOURCE IS THIS MAJOR QCB NAME SYSIEECT 18200021
         BE    MINORQCB                 YES, SEARCH MINOR QCBS          18400021
         L     WKREG15,N0(WKREG15)      ADDR OF NEXT MAJOR QCB          18600021
         LTR   WKREG15,WKREG15          IS THIS ADDR ZERO               18800021
         BZ    GETCODE                  YES, SYSIEECT IS NOT ENQ'D,CONT 19000021
         B     CHKIEECT                 NO, GO CHECK THIS QCB NAME      19200021
*                                                                       19400021
MINORQCB EQU   *                                                        19600021
         L     WKREG15,N8(WKREG15)      ADDR OF MINOR QCB               19800021
CKIEEWQE EQU   *                                                        20000021
         CLC   N14(N6,WKREG15),IEEWQE   HAS IEEWQE BEEN ENQ'D           20200021
         BE    GETQEL                   YES, SEE IF DDR MARKED TCB NOND 20400021
         L     WKREG15,N8(WKREG15)      ADDR OF NEXT MINOR QCB          20600021
         LTR   WKREG15,WKREG15          IS THIS ADDR ZERO               20800021
         BZ    GETCODE                  YES, IEEWQE IS NOT ENQ'D, CONTU 21000021
         B     CKIEEWQE                 NO, GO CHECK THIS QCB NAME      21200021
*                                                                       21400021
GETQEL   EQU   *                                                        21600021
         L     WKREG15,N0(WKREG15)      ADDR OF QEL ASSOC WITH QCB      21800021
QELTCB   EQU   *                                                        22000021
         L     WKREG14,N8(WKREG15)      TCB ADDR IN QEL                 22200021
         LA    WKREG14,N0(WKREG14)      CLEAR HIGH-ORDER BYTE           22400021
          LH     WKREG0,ALLOTJID    RELOAD TJID, WAS DESTROYED BY       22600021
          N      WKREG0,ZEROHIGH    TSEVENT MACRO AND BY CODE AT        22620021
*                                   COMPTCB                             22640021
         BZ    COMPTCB                  YES, GO SEE IF TCB HAS ENQ'D    23000021
         TM    N8(WKREG15),NOTIN        IS TASK IN CORE                 23200021
         BZ    COMPTCB                  YES, GO SEE IF TASK HAS ENQ'D   23400021
         NI    N8(WKREG15),ALL-NOTIN    TURN OFF FOR COMPARE            23600021
         SR    WKREG4,WKREG4            CLEAR FOR COMPARE               23800021
         IC    WKREG4,N8(WKREG15)       FIRST PART OF TJID              24000021
         SLL   WKREG4,N8                SHIFT OVER 1 BYTE               24200021
         IC    WKREG4,N12(WKREG15)      SECOND HALF OF TJID             24400021
         CR    WKREG4,WKREG0            DO TJID'S MATCH                 24600021
         BZ    PREPNEXT                 NO, PREPARE TO GET NEXT QEL     24800021
         OI    N8(WKREG15),NOTIN        RESTORE OUTOF CORE BIT          25000021
*                                                                       25200021
COMPTCB  EQU   *                                                        25400021
         L     WKREG0,ALLOCTCB          ADDR IN ALLOC TCB               25600021
         CR    WKREG0,WKREG14           HAS ALLOC ENQD IEEWQE FOR TCB   25800021
*                                  WHICH DDR HAS MARKED NON-DISP        26000021
         BNE   NEXTQEL                  NO, GO GET NEXT QEL             26200021
         OI    DDRFLGSG,ALLOCENQ   SET IND.- TASK IN ALLOCATION  68347  26400021
*                                  IS ENQ'D ON WTO'S.            68347  26600021
         B     RESET               RESET DISPATCHABILITY BITS    68347  26800021
*                                                                       27000021
PREPNEXT EQU   *                                                        27200021
         OI    N8(WKREG15),NOTIN        RESTORE NOT IN CORE BIT         27400021
*                                                                       27600021
NEXTQEL  EQU   *                                                        27800021
         L     WKREG15,N0(WKREG15)      ADDR OF NEXT QEL                28000021
         LA    WKREG15,N0(WKREG15)      CLEAR HIGH ORDER BYTE           28200021
         LTR   WKREG15,WKREG15          IS THIS ADDR ZERO               28400021
         BNZ   QELTCB                   NO, GO CHECK TCB IN THIS QEL    28600021
         B     GETCODE                  YES, IEEWQE NOT ENQ'D           28800021
*                                                                       29000021
DARCODE  EQU   *                                                        29200021
         L     OURTCB,RMSTCB            RMS TCB PTR                     29400021
         LA    OURTCB,N0(OURTCB)        CLEAR HIGH ORDER BYTE           29600021
         NI    N172(OURTCB),ALL-DARBIT  TURN OFF DAR BIT IN TCB         29800021
*                                                                       30000021
*        THIS IS DDR'S TERMINATION ROUTINE. IF DDR'S WAIT QUEUE         30150000
*        HAS AN RQE IN IT, DDR IS RECYCLED. IF THE QUEUE IS EMPTY       30160000
*        DDR EXITS.                                                     30170000
*                                                                       30180000
ENDDDR   EQU   *                                                        30200021
*                                                                       30400021
         SSM   ZEROHIGH                 DISABLE BEFORE USING MACRO 0908 30450000
         LA    WKREG4,ALLOTJID          ADDR OF TJID FOR POST           30600021
         POST  ALLOCECB,TJID=(WKREG4)   ALLOW ALLOCATION TO CONTINUE    30900021
         LH    RQEPTR,OURRQE    RESTORE RQE PTR                   55098 30950021
         L     OURDEB,N8(RQEPTR)  GET OUR DEB ADDR                55098 31000021
         MVI   N32(OURDEB),ZERO    CLEAR DEB MODESET              55098 31050021
         L     WKREG15,ALLOCTCB         GET ALLO TCB ADDR, IF ANY       31200021
         LTR   WKREG15,WKREG15          IS THIS ADDR ZERO               31400021
         BZ    CHKRQE                   YES, GO CHECK USER'S RQE        31600021
         LH    WKREG4,ALLOTJID          ADDR OF TJID IF ANY             31700021
         N     WKREG4,ZEROHIGH          CLEAR 2 HIGH ORDER BYTES        31800021
         BZ    RESET                    YES, GO RESET NON-DISP BITS     32000021
         TM    TJBSTAT,TJBINCOR         IS TASK IN CORE                 32060021
         BO    RESET                    YES, GO SET DISPATCHABLE        32120021
         OI    TJBRSTOR,TJBDDRD         TO SET TASK DISP WHEN RESTORED  32200021
         TSEVENT USERRDY,TJID=(WKREG4)  USER MAY NOW BE RESTORED        32400021
         B     CHKRQE                   GO CHECK USER'S RQE             32600021
*                                                                       32800021
*        RESET NON-DISPATCHABILITY BITS IN TCB POINTED TO IN ALLOCTCB   32950000
*                                                                       32960000
RESET    EQU   *                                                        33000021
         L     WKREG14,ALLOCTCB         ALLOCATION TCB                  33100021
         NI    TCBNDSP1(WKREG14),ALL-TCBDDRND RESET DDR NON-DISP BIT    33200021
         NC    TCBNDSP(N3,WKREG14),TCBNDSP(WKREG14) IS TCB STILL NONDIS 33400021
         BNZ   CHKOP               YES - DO NOT RESET PRIM. BIT  68347  33600021
         NI    TCBFLGS5(WKREG14),ALL-NDCTL RESET PRIMARY NON-DISP BIT   33800021
CHKOP    TM    DDRFLGSG,ALLOCENQ   WAS TASK IN ALLOCATION ENQ'D  68347  33850021
*                                  ON WQE'S?                     68347  33900021
         BO    CANRQST             YES--CANCEL                   68347  33950021
*                                                                       34000021
CHKRQE   EQU   *                                                        34200021
         LH    RQEPTR,USRRQE            USER'S RQE PTR                  34400021
         LTR   RQEPTR,RQEPTR            IS THIS ADDR ZERO               34600021
         BZ    CHKWAITQ                 YES, GO CHECK WAIT Q FOR RQES   34800021
         CH    RQEPTR,N0(WQPTR)         IS RQE STILL ON WAIT QUE        35000021
         BNE   CHKWAITQ                 NO, GO CHECK WAIT Q FOR RQES    35200021
         TM    N4(WQPTR),PURGE          WAS THIS RQE PURGED PREVIOUSLY  35400021
         BZ    CANRQST                  NO, GO PREPARE TO CANCEL REQUST 35600021
         NI    N4(WQPTR),ALL-PURGE      RESET PURGE BIT                 35800021
         B     CHKWAITQ                 GO CHECK WAIT QUEUE             36000021
*                                                                       36200021
*        INITIALIZE DDR'S CONTROL BLOCKS TO CANCEL THE REQUEST.         36250000
*                                                                       36300000
CANRQST  EQU   *                                                        36400021
         LH    RQEPTR,OURRQE            DDR'S RQE PTR                   36600021
         L     OURDEB,N8(RQEPTR)        DDR'S DEB PTR                   36800021
         STH   FMUCB,N34(OURDEB)        'FROM' UCB PTR INTO DDR'S DEB   37000021
         STH   FMUCB,N2(RQEPTR)         'FROM' UCB PTR INTO DDR'S RQE   37200021
         L     OURIOB,N4(RQEPTR)        DDR'S IOB PTR                   37400021
         MVI   N0(OURIOB),UNRLTD        SET UNRELATED FLAG IN IOB       37600021
         OI    DDRFLGSC,CANCEL          TO CANCEL REQUEST               37800021
         SVC   ERREXCP                  GO TO APPDGE TO CANCEL          38000021
          TM     DDRFLGSA,OPINIT    IS SWAP OPERATOR INITIATED    67739 38060021
         BO    CANCLREQ            PREPARE FOR CANCEL MSG               38120021
*                                                                       38400021
*        ALL FLAGS ARE CLEANED UP AND IF THERE IS AN RQE ON DDR'S       38550000
*        WAIT QUEUE, DDR IS RECYCLED. IF THE QUEUE IS EMPTY DDR         38560000
*        EXITS.                                                         38570000
*                                                                       38580000
CHKWAITQ EQU   *                                                        38600021
         LH    FMUCB,DDRFMUCB      GET 'FROM' UCB              @S66538P 38610021
         TM    N6(FMUCB),UCBERR    IS UCBERR FLAG ON                    38620021
         BZ    NOCLEAR             NO -- NO ACTION REQUIRED             38622021
         CLC   UCBLTS(N2,FMUCB),OURRQE YES -- IS DDR'S RQE              38624021
*                                      STILL IN CONTROL                 38626021
         BNE   NOCLEAR             NO -- NO ACTION REQUIRED             38628021
         TM    DDRFLGSG,RETRIED    YES -- HAS A RETRY BEEN              38630021
*                                  INITIATED BY DDR                     38632021
         BO    NOCLEAR             YES -- DO NOT CLEAR FLAG             38634021
*                                  RETRY HAS NOT BEEN EFFECTED          38636021
         NI    N6(FMUCB),ALL-UCBERR TURN OFF UCBERR FLAG                38642021
NOCLEAR  EQU   *                                                        38644021
CLRTOUCB LH    TOUCB,DDRTOUCB      GET 'TO' UCB                @S66538P 38650021
         LTR   TOUCB,TOUCB         IS 'TO' THERE               @S66538P 38660021
         BZ    CLRFLAGS            NO, CLEAR FLAGS             @S66538P 38670021
         CR    TOUCB,FMUCB         SWAP TO SELF                @S66538P 38680021
         BE    CLRFLAGS            YES -- DO NOT CLEAR ERR FLAG         38690021
            NI    N6(TOUCB),ALL-UCBERR   TURN OFF UCBERR        66538   38695021
CLRFLAGS EQU   *                                               @S66538P 38700021
         NI    DDRFLGSA,TEMPFLGS        ZERO TEMP BITS IN FLAGS A       38800021
         MVI   DDRFLGSB,ZERO            CLEAR                           39000021
         MVI   DDRFLGSC,ZERO            ALL                             39200021
         MVI   DDRFLGSD,ZERO            DDR                             39400021
         MVI   DDRFLGSE,ZERO            FLGS                            39600021
         MVI   DDRFLGSF,ZERO                                            39800021
         MVI   DDRFLGSG,ZERO       CLEAR FLAG                    68347  39870021
CLEARUCB XC    DDRFMUCB(N4),DDRFMUCB    CLEAR UCB POINTERS         1030 39950021
         TM    N1(WQPTR),WQMT           IS WAIT QUE EMPTY               40000021
         BZ    GOLOAD2                  NO, GO PREPARE TO XCTL TO LOAD2 40200021
         MVI   DDRECB,ZERO              CLEAR DDR'S ECB                 40400021
         SVC   EXIT                     GET OUT. WAIT FOR NEXT DDR RQST 40600021
*                                                                       40800021
*        THIS IS THE ROUTER SECTION WHERE AN INDEX IS OBTAINED          40850000
*        FROM DDRFLGSB TO XCTL TO THE APPROPRIATE LOAD FOR              40900000
*        FURTHER PROCESSING.                                            40950000
*                                                                       40960000
GETCODE  EQU   *                                                        41000021
         SR    WKREG15,WKREG15          CLEAR REG FOR BRANCH INDEX      41200021
         IC    WKREG15,DDRFLGSB         BRANCH INDEX CODE IN INDEX REG  41400021
         LA    OURDCB,DDRDCB            DDR DCB PTR                     41600021
         MVC   N8(N8,SVRBPTR),LOAD0 MOVE BASIC MODULE NAME       SIZE   41700021
BRSTART  EQU   *                                                        41800021
         B     BRSTART+N4(WKREG15)      GO TO DESIRED LOAD OF DDR SVC   42000021
         B     GOLOAD1                  LOAD 1, OPERATOR DASD DDR       42200021
         B     GOLOAD4                  LOAD 4, OPERATOR TAPE DDR       42400021
         B     GOLOAD2                  LOAD 2, SYSTEM DDR              42600021
*                                                                       42800021
GOLOAD1  EQU   *                                                        43000021
         MVI   N12(SVRBPTR),LOAD1  LOAD NAME FOR XCTL            SIZE   43200021
         B     GOXCTL                   GO PREPARE FOR XCTL             43400021
*                                                                       43600021
GOLOAD4  EQU   *                                                        43800021
         MVI   N12(SVRBPTR),LOAD4  LOAD NAME FOR XCTL            SIZE   44100021
         B     GOXCTL                   GO PREPARE FOR XCTL             44200021
*                                                                       44400021
GOLOAD2  EQU   *                                                        44600021
         OI    DDRFLGSA,DDRBUSY    FLAG DDR AS STILL BUSY         58249 44650021
         MVC   N8(N8,SVRBPTR),LOAD0     LOAD NAME BASE           SIZE   44800021
         MVI   N12(SVRBPTR),LOAD2       LOAD NAME FOR XCTL              44900021
*                                                                       45000021
GOXCTL   EQU   *                                                        45200021
         MVI   DDRFLGSB,ZERO            CLEAR FLAGS B                   45400021
         SR    WKREG15,WKREG15          ZERO FOR SETUP                  45600021
         ST    WKREG15,N4(SVRBPTR)      ZERO SECOND WORD                45800021
         LA    WKREG15,N8(SVRBPTR)      ADDR OF LOCATION OF LOAD NAME   46000021
         ST    WKREG15,N0(SVRBPTR)      THAT ADDR IN FIRST WORD         46200021
         LR    WKREG15,SVRBPTR          SAVE AREA IN PARM REG           46400021
         XCTL  SF=(E,(15))                                              46600021
*                                                                       46800021
SINK     EQU   *                                                        47000021
         L     RQEPTR,COMPCODE     SET COMPLETION CODE           SIZE   47200021
         SVC   13                  ABEND                         SIZE   47400021
         SPACE 5                                                        47800021
*                                                                       48000021
***      REGISTER EQUATES                                               48200021
*                                                                       48400021
WKREG0   EQU   0                        WORK REGISTER                   48600021
RQEPTR   EQU   1                        RQE PTR                         48800021
WQPTR    EQU   2                        WAIT QUE PTR                    49000021
WKREG2   EQU   2                   WORK REGISTER                  55979 49050021
CVTREG   EQU   3                        CVT PTR                         49200021
OURTCB   EQU   4                        DDR TCB PTR                     49400021
WKREG4   EQU   4                        WORK REGISTER                   49600021
SVRBPTR  EQU   5                        EXTENDED SAVE AREA PTR          49800021
USERDEB  EQU   6                        USER'S DEB POINTER              49850000
FMUCB    EQU   7                        'FROM' UCB PTR                  50000021
WKREG7   EQU   7                        WORK REGISTER                   50200021
TOUCB    EQU   8                        'TO' UCB PTR                    50400021
OURDCB   EQU   9                        DDR DCB PTR                     50600021
USERDCB  EQU   9                   USER DCB PTR                   51696 50650021
OURDEB   EQU   10                       DDR DEB PTR                     50800021
COMMPTR  EQU   11                       IORMSCOM PTR                    51000021
BASE     EQU   12                       MODULE BASE REGISTER            51200021
OURIOB   EQU   13                       DDR IOB PTR                     51400021
WKREG14  EQU   14                       WORK REGISTER                   51600021
WKREG15  EQU   15                       WORK REGISTER                   51800021
         SPACE 3                                                        52000021
*                                                                       52200021
***      INTEGER EQUATES                                                52400021
*                                                                       52600021
N0       EQU   0                        DISPLACEMENT VALUE              52800021
N1       EQU   1                        DISPLACEMENT VALUE              53000021
N2       EQU   2                        DISPLACEMENT VALUE              53200021
N3       EQU   3                        DISPLACEMENT VALUE              53400021
N4       EQU   4                        DISPLACEMENT VALUE              53600021
N6       EQU   6                        DISPLACEMENT VALUE              53800021
N8       EQU   8                        DISPLACEMENT VALUE              54000021
N12      EQU   12                       DISPLACEMENT VALUE              54200021
N14      EQU   14                       DISPLACEMENT VALUE              54400021
N18      EQU   18                       DISPLACEMENT VALUE              54450000
N20      EQU   20                       DISPLACEMENT VALUE              54600021
N24      EQU   24                       DISPLACEMENT VALUE              54650000
N26      EQU   26                       DISPLACEMENT VALUE              54800021
N28      EQU   28                       DISPLACEMENT VALUE              55000021
N32      EQU   32                       DISPLACEMENT VALUE        55098 55050021
N33      EQU   33                       DISPLACEMENT VALUE              55200021
N34      EQU   34                       DISPLACEMENT VALUE              55400021
N96      EQU   96                       DISPLACEMENT VALUE              55600021
N116     EQU   116                      DISPLACEMENT VALUE              55650000
N172     EQU   172                      DISPLACEMENT VALUE              55800021
N173     EQU   173                      DISPLACEMENT VALUE              56000021
N228     EQU   228                      DISPLACEMENT VALUE              56200021
         SPACE 3                                                        56400021
*                                                                       56600021
***      GENERAL EQUATES                                                56800021
*                                                                       57000021
ALL      EQU   X'FF'                    MASK FOR 'AND' INSTRUCTIONS     57200021
UCBERR   EQU   X'01'                    ERR RTNE IN CTL FLAG      60100 57250021
UCBLTS   EQU   X'14'               LAST RQE IN UCB                      57320021
DARBIT   EQU   X'40'                    DAR PROCESSING INDICATOR        57600021
ERREXCP  EQU   15                       ERROR EXCP - SVC 15             57800021
EXIT     EQU   3                        EXIT - SVC 3                    58000021
MFTSYSTM EQU   X'20'                    MFT OPTION                      58200021
NDCTRL   EQU   X'01'                    PRIMARY NON-DISPATCH BIT        58400021
NDCTL    EQU   X'01'                    PRIMARY NON-DISPATCH BIT        58600021
NOTIN    EQU   X'80'                    TO INDICATE TASK IS NOT IN CORE 58800021
POSTCOMP EQU   X'40'                    EVENT COMPLETE INDICATOR        59000021
PURGE    EQU   X'80'                    PURGE INDICATOR IN WAIT Q       59200021
TAPE     EQU   X'80'                    UCB TYPE BIT FOR TAPE           59250000
TCBDDRND EQU   X'08'                    DDR NON-DISPATCH. BIT           59400021
TCBFLGS5 EQU   33                       FIFTH FLAGS FIELD IN TCB        59600021
TCBNDSP  EQU   173                      NON-DISPATCH FIELD IN TCB       59800021
TCBNDSP1 EQU   173                      NON-DISPATCH FIELD IN TCB       60000021
TEMPFLGS EQU   X'D2'                    TO CLEAR TEMPORARY FLGSA BITS   60200021
TSOREADY EQU   X'80'                    TSO READY BIT                   60800021
UNRLTD   EQU   X'02'                    UNRELATED BIT IN IOB FLAGS1     61000021
WQMT     EQU   X'01'                    MASK FOR CHECKING WAIT Q        61200021
ZERO     EQU   X'00'                    TO CLEAR VARIOUS FIELDS         61400021
LOAD1    EQU   X'F1'                    OPERATOR DASD MODULE     SIZE   61450021
LOAD2    EQU   X'F2'                    SYSTEM DDR MODULE        SIZE   61500021
LOAD4    EQU   X'F4'                    TAPE DDR MODULE          SIZE   61550021
         SPACE 3                                                        61600021
*                                                                       61800021
***      DEFINED CONSTANTS                                              62000021
*                                                                       62200021
         DS    0F                       FULL WORD BOUNDRY               62400021
MSGMOD2  DC    C'IGC0808E'              MSG. MODULE #2                  62600021
LOAD0    DC    C'IGC0008E'              INITIATOR/TERMINATOR MODULE     63000021
RESOURCE DC    C'SYSIEECT'                                              63800021
ZEROHIGH DC    X'0000FFFF'              MASK TO CLEAR 2 HIGHORDER BYTES 64000021
COMPCODE DC    X'80155000'              DDR ABEND COMP. CODE     SIZE   64100021
IEEWQE   DC    C'IEEWQE'                                                64200021
MAINT    DC    36X'40'                                                  64300021
         SPACE 3                                                        64400021
CVTDSECT DSECT                                                          64600021
         CVT                                                            64800021
         SPACE 3                                                        65000021
         IORMSCOM                                                       65200021
         SPACE 3                                                        65400021
         IKJTJB                                                         65600021
         END                                                            98700021
