IGC0108E CSECT                                                          00200021
*********************************************************************** 00202021
*                                                                       00204021
* STATUS:                                                               00206021
*                                                                       00208021
*    RELEASE 21 REPACKAGE                                               00210021
*                                                                       00212021
*                                                                       00214021
* FUNCTION:                                                             00216021
*                                                                       00218021
*    THIS MODULE RECEIVES CONTROL FROM IGC0008E TO PROCESS OPERATOR     00220021
*    REQUESTED DDR SWAPS FOR DIRECT ACCESS AND UNIT RECORD DEVICES.     00222021
*    THE SWAP MESSAGE IS ISSUED AND ITS REPLY IS PROCESSED. IF THE      00224021
*    REPLY IS 'YES' OR ANOTHER VALID CUA, THE DEVICES ARE TIED UP       00226021
*    IF THE SWAP IS FOR DASD AND THE UCB INFORMATION IS SWAPPED FOR     00228021
*    BOTH DASD AND UNIT RECORD DEVICES. THE PROCEED MESSAGE IS          00230021
*    ISSUED AND CONTROL IS RETURNED TO IGC0008E FOR TERMINATION.        00232021
*                                                                       00234021
*                                                                       00236021
* ENTRY POINT:                                                          00238021
*                                                                       00240021
*         IGC0108E - FIRST INSTRUCTION OF MODULE                        00242021
*                                                                       00244021
*                                                                       00246021
* INPUT:                                                                00248021
*                                                                       00250021
*    ON ENTRY FROM 1GC0008E, REG 1 = DDR RQE ADDR, REG 2 = DDR WAIT     00252021
*    QUEUE ADDR, REG 3 = CVT ADDR, REG 5 = XSA ADDR, REG 7 = 'FROM'     00254021
*    DEVICE UCB ADDR, REG 10 = DDR DEB ADDR, REG 11 = IORMSCOM ADDR     00256021
*    REG 13 = DDR IOB ADDR. DDRFLGSA WILL HAVE THE OPINIT BIT ON.       00258021
*                                                                       00260021
*    ON ENTRY FROM IGC0508E, THE ABOVE REGISTERS REMAIN THE SAME.       00262021
*    DDRFLGSB WILL HAVE THE SWAPMSG BIT ON, AND THE OPERATOR'S          00264021
*    REPLY WILL BE IN 'REPLYBUF' IN IORMSCOM.                           00266021
*                                                                       00268021
*    ON ENTRY FROM IGC0708E, THE ABOVE REGISTERS REMAIN THE SAME, AND   00270021
*    DDRFLGSB WILL HAVE THE READFROM OR RECRDING BIT ON.                00272021
*                                                                       00274021
*                                                                       00276021
* OUTPUT:                                                               00278021
*                                                                       00280021
*    FOR ALL EXITS, THE ABOVE REGISTERS REMAIN THE SAME AND REGISTER 8  00282021
*    = 'TO' DEVICE UCB ADDR.                                            00284021
*    FOR XCTL TO IGC0008E BY WAY OF IGC0808E, DDRFLGSB WILL HAVE THE    00286021
*    DDREND BIT ON AND DDRFLGSC WILL HAVE THE TERMNATE BIT ON.          00288021
*                                                                       00290021
*    FOR XCTL TO IGC0008E BY WAY OF IGC0508E, DDRFLGSB WILL HAVE THE    00292021
*    PROCEED BIT ON AND DDRFLGSC WILL HAVE THE TREMNATE BIT ON.         00294021
*                                                                       00296021
*    FOR XCTL TO IGC0508E, DDRFLGSB WILL HAVE THE SWAPMSG OR THE        00298021
*    INVALID OR THE SYSRES OR THE PROCEED BIT ON.                       00300021
*                                                                       00302021
*    FOR XCTL TO IGC0708E, DDRFLGSE WILL HAVE THE READFROM BIT ON.      00304021
*                                                                       00306021
*    FOR EXIT, DDRFLGSD WILL HAVE THE SYSRESBR AND DDRMSG BITS ON.      00308021
*                                                                       00310021
*                                                                       00312021
* EXTERNAL REFERENCES:                                                  00314021
*                                                                       00316021
*         XCTL, SVC 15, WAIT                                            00318021
*                                                                       00320021
*                                                                       00322021
* EXITS-NORMAL:                                                         00324021
*                                                                       00326021
*         TO IGC0508E AND IGC0808E FOR MESSAGES. TO IGC0708E FOR        00328021
*         RECORDING PROCESSING. EXIT TO GO TO RESIDENT ROUTINE          00330021
*         FOR SYSRES SWAP.                                              00332021
*                                                                       00334021
*                                                                       00336021
* TABLES/WORK AREAS:                                                    00338021
*                                                                       00340021
*         IORMSCOM - DDR COMMUNICATIONS AREA                            00342021
*                                                                       00344021
*                                                                       00346021
* ATTRIBUTES:                                                           00348021
*                                                                       00350021
*         ENABLED. SERIALLY REUSABLE                                    00352021
*                                                                       00354021
*                                                                       00356021
* CHARACTER CODE DEPENDENCY:                                            00358021
*                                                                       00360021
*         NONE                                                          00362021
*                                                                       00364021
********************************************************************    00366021
         SPACE 2                                                        00368021
         TITLE '  IGC0108E - OPERATOR DASD '                            00400021
         BALR  BASE,N0                  MODULE BASE REG                 00600021
         USING *,BASE                   MODULE ADDR                     00800021
         USING CVTDSECT,CVTREG          CVT ADDR                        01000021
         USING IORMS,COMMPTR            IORMS ADDR                      01200021
*                                                                       01400021
*        DETERMINE WHY ENTERED                                          01550021
*                                                                       01560021
         TM    DDRFLGSB,PROCEED         IS ENTRY AFTER PROCEED MSG      01600021
         BO    RCRDMERL                 YES, SEE IF RECORDING IS NEEDED 01800021
*                                                                       01810021
*        IF ENTRY IS FROM READING BUFFERED LOG, GO SWAP UCB INFORMATION 01850021
*        IF ENTRY IS FROM RECORDING THE SENSE INFO TERMINATE DDR        01900021
*                                                                       01950021
         TM    DDRFLGSE,READFROM        IS ENTRY FROM READING BUFRD LOG 02000021
         BZ    RCRDTEST                 NO, SEE IF ENTRY IS AFTER RECRD 02200021
         L     TOUCB,DDRWORK+N20        RESTORE 'TO' UCB PTR            02400021
         MVI   DDRWORK,NOOP             NO-OP COMMAND INTO CCW          02600021
         B     SWAPTHEM                 GO SWAP UCB INFO                02800021
*                                                                       03000021
RCRDTEST EQU   *                                                        03200021
         TM    DDRFLGSE,RECRDING        IS ENTRY AFTER RECORDING SENSE  03400021
         BZ    CHKSWAP                  NO, SEE IF ENTRY IS AFTER SWAP  03600021
         NI    DDRFLGSE,ALL-RECRDING    TURN OFF RECORDING BIT          03800021
         B     ENDDDR                   GO TERMINATE DDR                04000021
*                                                                       04200021
CHKSWAP  EQU   *                                                        04400021
         TM    DDRFLGSB,SWAPMSG         IS ENTRY AFTER SWAP MSG         04600021
         BO    CHKREPLY                 YES, GO CHECK OPERATOR'S REPLY  04800021
         TM    N3(FMUCB),SYSRESDV       IS 'FROM' DEVICE SYSRES         05000021
         BZ    SWAPON                   NO, GO PREPARE FOR SWAP MSG     05200021
         OI    DDRFLGSB,SYSRES          FOR SYSRES WARNING MSG IGF510I  05400021
         B     THISLOAD                 GO PREPARE FOR MSG MOD #1       05600021
*                                                                       05800021
*        PRPEARE FOR SWAP MESSAGE                                       05850021
*                                                                       05900021
SWAPON   EQU   *                                                        06000021
         OI    DDRFLGSB,SWAPMSG         FOR SWAP MSG                    06200021
THISLOAD EQU   *                                                        06400021
         MVC   DDRWORK+N12(N8),LOAD1    FOR RETURN CONTROL AFTER MSG.   06600021
DDRMSG1  EQU   *                                                        06800021
         MVC   N8(N8,SVRBPTR),MSGMOD1   LOAD NAME FOR XCTL              07000021
*                                                                       07200021
*        SET UP FOR ALL XCTL'S                                          07250021
*                                                                       07300021
GOXCTL   EQU   *                                                        07400021
         SR    WKREG15,WKREG15          ZERO FOR XCTL SET UP            07600021
         ST    WKREG15,N4(SVRBPTR)      ZERO SECOND WORD                07800021
         LA    WKREG15,N8(SVRBPTR)      ADDR OF LOCATION OF LOAD NAME   08000021
         ST    WKREG15,N0(SVRBPTR)      THAT ADDR INTO FIRST WORD       08200021
         LR    WKREG15,SVRBPTR          SAVE AREA ADDR INTO PARM REG    08400021
         XCTL  SF=(E,(WKREG15))         TRANSFER CONTROL                08600021
*                                                                       08800021
*        CHECK THE OPERATOR'S REPLY TO SWAP MESSAGE                     08850021
*                                                                       08900021
CHKREPLY EQU   *                                                        09000021
         TM    DDRFLGSA,VALIDATE        SHOULD REPLY BE VERIFIED   0909 09050021
         BZ    CKSYSRS                  NO,SEE IF THIS IS SYSRES   0909 09100021
         NI    DDRFLGSA,ALL-VALIDATE    TURN OFF VALIDATION BIT    0909 09150021
         LA    WKREG15,REPLYBUF         REPLY ADDR                      10000021
         LA    WKREG14,N3               COUNTER FOR CUA CHECK           10200021
*                                                                       10400021
*        DETERMINE IF REPLY WAS A VALID CUA                             10550021
*                                                                       10560021
CHKNUMBR EQU   *                                                        10600021
         TM    N0(WKREG15),NUMBER       IS REPLY NUMERIC                10800021
         BO    NXTDIGIT                 YES, GET NEXT DIGIT             11000021
         CLI   N0(WKREG15),F            IS DIGIT 'F' OR LOWER           11200021
         BH    BADDEV                   NO, GO PREPARE FOR INVALID MSG  11400021
         CLI   N0(WKREG15),A            IS DIGIT 'A' OR HIGHER          11600021
         BL    BADDEV                   NO, GO PREPARE FOR INVALID MSG  11800021
*                                                                       12000021
NXTDIGIT EQU   *                                                        12200021
         LA    WKREG15,N1(WKREG15)      GET NEXT DIGIT                  12400021
         BCT   WKREG14,CHKNUMBR         COUNTER FOR 3 DIGITS TESTED     12600021
*                                                                       12800021
         L     WKREG15,CVTILK2          UCB LIST PTR                    13000021
*                                                                       13200021
CKUCBEND EQU   *                                                        13400021
         CLC   N0(N2,WKREG15),FFFF      IS THIS END OF UCBS             13600021
         BE    BADDEV                   YES, GO PREPARE FOR INVALID MSG 13800021
         CLC   N0(N2,WKREG15),ZEROS     IS THIS UCB ZERO-NOT IN SYSTEM  14000021
         BE    NEXTUCB                  YES, GO CHECK NEXT UCB          14200021
         LH    TOUCB,N0(WKREG15)        'TO' UCB PTR                    14400021
         CLC   REPLYBUF(N3),N13(TOUCB)  DO CUA'A MATCH                  14600021
         BE    CKITSELF                 YES, GO CHECK IF SWAP TO ITSELF 14800021
*                                                                       15000021
NEXTUCB  EQU   *                                                        15200021
         LA    WKREG15,N2(WKREG15)      NEXT UCB PTR                    15400021
         B     CKUCBEND                 GO TEST UCB                     15600021
*                                                                       15800021
CKITSELF EQU   *                                                        16000021
         CLR   FMUCB,TOUCB              IS SWAP TO ITSELF               16200021
         BE    CKSYSRS                  YES, GO CHECK FOR SYSRES        16400021
         TM    CVTDCB,CVT4MPS           IS THIS MP                46458 16550021
         BZ    CKDEVICE                 NO, SEE IF DEVICE IS OK   46458 16560021
         LR    WKREG14,TOUCB            SAVE UCB POINTER          46458 16572021
         BCTR  WKREG14,0                SUBTRACT ONE FROM ADDR    46458 16574021
         TM    N0(WKREG14),NOPATHS      ARE THERE PATHS TO DEV    46458 16576021
         BO    TOINVAL                  NO, ISSUE INVALID MSG     46458 16592021
*                                                                       16594021
CKDEVICE EQU   *                                                        16596021
         TM    N3(TOUCB),PERMRES        IS 'TO' DEV PER RESIDENT        16600021
         BO    BADDEV         YES, INFORM OPERATOR OF BAD DEVICE        16800021
         TM    N3(TOUCB),SYSRESDV       IS 'TO' DEVICE SYSRES           17000021
         BO    BADDEV                   YES, GO PREPARE FOR INVALID MSG 17200021
         TM    N17(TOUCB),SHARED        IS 'TO' DEVICE SHARED           17400021
         BO    BADDEV                   YES, GO PREPARE FOR INVALID MSG 17600021
         CLC   N16(N4,TOUCB),N16(FMUCB) DO UCB TYPES MATCH              17800021
         BE    CKSYSRS                  YES, GO CHECK FOR SYSRES        18000021
*                                                                       18200021
*        PREPARE FOR INVALID DEVICE MESSAGE                             18350021
*                                                                       18360021
BADDEV   EQU   *                                                        18400021
         NI    DDRFLGSB,ALL-SWAPMSG     TURN OFF SWAP MSG INDICATOR     18600021
         OI    DDRFLGSB,INVALID+NOTOUCB  FOR INVALID MSG IGF513I        18950021
         B     THISLOAD                 GO PREPARE TO XCTL FOR MSG      19000021
*                                                                       19200021
*        IF THIS IS FOR SYSRES, SET BRANCH FLAGS FOR THE RESIDENT       19250021
*        ROUTINE AND EXIT.                                              19300021
*                                                                       19350021
CKSYSRS  EQU   *                                                        19400021
         NI    DDRFLGSB,ALL-SWAPMSG     TURN OFF MSG INDICATOR          19600021
         STH   TOUCB,DDRTOUCB           'TO' UCB PTR INTO IORMSCOM      19800021
         TM    N3(FMUCB),SYSRESDV       IS THIS A SYSRES SWAP           20000021
         BZ    INITBLKS                 NO, GO INITIALIZE DDR CTL BLKS  20200021
         OI    DDRFLGSD,SYSRESBR+DDRMSG SYSRES BRANCH FLAGS             20400021
         SVC   EXIT                     GET OUT                         20600021
*                                                                       20750021
*        INITIALIZE DDR'S CONTROL BLOCKS FOR IO                         20760021
*                                                                       20770021
INITBLKS EQU   *                                                        20800021
         OI    DDRFLGSB,FIRSTIO         FOR CONTROL OF DEVICES          21000021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     21200021
         STH   TOUCB,N2(RQEPTR)         'TO' UCB PTR INTO RQE           21400021
         STH   TOUCB,N34(OURDEB)        'TO' UCB PTR INTO DEB           21600021
         MVC   N33(N7,OURIOB),N49(TOUCB) SEEK ADDR INTO IOB             21800021
         MVC   N36(N6,OURDEB),N49(TOUCB)  START ADDR INTO DEB           22000021
         MVC   N42(N4,OURDEB),N51(TOUCB)  END ADDR INTO DEB             22200021
ZEROECB  EQU   *                                                        22400021
         MVI   IOSECB,ZERO              CLEAR ECB                       22600021
         MVI   N0(OURIOB),UNRLTD        UNRELATED BIT IN IOB FLAGS1     22800021
         XC    N9(N7,OURIOB),N9(OURIOB) CLEAR STATUS BITS IN IOB        23000021
         XC    N30(N2,OURIOB),N30(OURIOB) CLEAR ERROR COUNT             23200021
         CLI   N18(FMUCB),DASD          IS SWAP FOR DASD                23400021
         BE    DASDEXTN                 YES, GO SET DASD EXTENTS        23600021
         MVI   N28(OURDEB),UNRECEXT     SET UNIT RECORD EXTENTS         23800021
         NI    DDRFLGSB,ALL-FIRSTIO     RESET BIT, NO CONTROL NEEDED    24000021
         B     SWAPIT                   GO SET BIT TO SWAP INFO         24200021
*                                                                       24400021
DASDEXTN EQU   *                                                        24600021
         MVI   N28(OURDEB),DASDEXT      SET DASD EXTENT                 24800021
         MVI   N32(OURDEB),FILEMASK     SET UP FILE MASK                25000021
         MVC   DDRWORK(N8),NOPCCW       SET UP NO-OP CCW                25200021
         OI    DDRFLGSC,IONOCTRL        TO RE-EXCP WITHOUT CONTROL      25400021
         SVC   ERREXCP                  GO TO APPDGE - SVC 15           25600021
*                                                                       25800021
         WAIT  ECB=IOSECB               WAIT FOR COMPLETION             26000021
*                                                                       26200021
         TM    DDRFLGSC,ERROR           WAS PERM ERROR INDICATED        26400021
         BZ    CHKFIRST                 NO, GO SEE IF THIS IS FIRST IO  26600021
         TM    DDRFLGSB,FIRSTIO         IS ERROR ON 'TO' DEVICE         26800021
         BO    TOINVAL                  YES, SET UP TOUCB FOR INVAL MSG 27000021
         MVC   REPLYBUF(N3),N13(FMUCB)  SET 'FROM' DEVICE FOR INVAL MSG 27200021
         B     ERROROFF                 GO TURN OFF ERROR INDICATOR     27400021
*                                                                       27600021
TOINVAL  EQU   *                                                        27800021
         MVC   REPLYBUF(N3),N13(TOUCB)  SET 'TO' DEVICE FOR INVAL MSG   28000021
*                                                                       28200021
ERROROFF EQU   *                                                        28400021
         NI    DDRFLGSC,ALL-ERROR       TURN OFF ERROR INDICATOR        28600021
         B     BADDEV                   GO PREPARE FOR INVALID MSG      28800021
*                                                                       29000021
CHKFIRST EQU   *                                                        29200021
         TM    DDRFLGSB,FIRSTIO         IS THIS THE FIRST IO            29400021
         BZ    TSTCLASS                 NO, GO TEST DEVICE FOR MERLIN   29600021
         NI    DDRFLGSB,ALL-FIRSTIO     TURN OFF FIRST IO INDICATOR     29800021
         MVC   N33(N7,OURIOB),N49(FMUCB) SEEK ADDR INTO IOB             30000021
         MVC   N36(N6,OURDEB),N49(FMUCB)  START ADDR INTO DEB           30200021
         MVC   N42(N4,OURDEB),N51(FMUCB)  END ADDR INTO DEB             30400021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     30600021
         STH   FMUCB,N2(RQEPTR)         'FROM' UCB INTO RQE             30800021
         STH   FMUCB,N34(OURDEB)        'FROM' UCB INTO DEB             31000021
         B     ZEROECB                  GO SET UP FOR SECOND IO         31200021
*                                                                       31400021
*        IF THIS IS FOR 3330, GO READ THE BUFFERED LOG                  31550021
*                                                                       31560021
TSTCLASS EQU   *                                                        31600021
         CLI   N18(FMUCB),DASD          IS THIS A DASD SWAP             31800021
         BNE   SWAPIT                   NO, GO SWAP UCB INFO            32000021
         CLI   N19(FMUCB),MERLINDV      YES, IS IT MERLIN DEVICE        32200021
         BNE   SWAPTHEM                 NO, GO PREPARE TO SWAP UCB INFO 32400021
         ST    TOUCB,DDRWORK+N20        SAVE 'TO' UCB PTR               32600021
*                                                                       32800021
GOLOAD7  EQU   *                                                        33000021
         MVC   N8(N8,SVRBPTR),LOAD7     LOAD NAME FOR XCTL              33200021
         B     GOXCTL                   GO PREPARE FOR XCTL             33400021
*                                                                       33600021
*        SET UP TO SWAP UCB INFORMATION                                 33770021
*                                                                       33780021
SWAPTHEM EQU   *                                                        33800021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     34000021
         MVI   N0(OURIOB),UNRLTD        TURN ON UNRELATED BIT IN IOB    34200021
         XC    N9(N7,OURIOB),N9(OURIOB) CLEAR STATUS IN IOB             34400021
         XC    N30(N2,OURIOB),N30(OURIOB) CLEAR ERROR COUNT             34600021
*                                                                       34800021
SWAPIT   EQU   *                                                        35000021
         NI    DDRFLGSB,ALL-FIRSTIO     TURN OFF IO INDICATOR           35200021
         OI    DDRFLGSC,SWAPUCB         TO SWAP UCB INFO                35400021
*                                                                       35600021
         SVC   ERREXCP                  SWAP INFO                       35800021
*                                                                       36000021
         NI    DDRFLGSC,ALL-SWAPUCB     TURN OFF UCB SWAP INDICATOR     36200021
         OI    DDRFLGSB,PROCEED         FOR PROCEED MSG IGF502E         36400021
         B     THISLOAD                 GO PREPARE FOR XCTL FOR MSG     36600021
*                                                                       36800021
*        IF THIS IS FOR 3330, GO RECORD SENSE DATA. IF NOT, TERMINATE   36950021
*                                                                       36960021
RCRDMERL EQU   *                                                        37000021
         NI    DDRFLGSB,ALL-PROCEED     TURN OFF PROCEED BIT            37200021
         CLI   N18(FMUCB),DASD          IS DEVICE DASD                  37400021
         BNE   ENDDDR                   NO, GO TERMINATE DDR            37600021
         CLI   N19(FMUCB),MERLINDV      IS DEVICE MERLIN                37800021
         BNE   ENDDDR                   NO, GO TERMINATE DDR            38000021
         B     GOLOAD7                  GO XCTL TO RECORD SENSE         38200021
*                                                                       38400021
*        PREPARE TO TERMINATE DDR                                       38450021
*                                                                       38500021
ENDDDR   EQU   *                                                        38600021
         OI    DDRFLGSC,TERMNATE        TO TERMINATE DDR                38800021
         MVC   N8(N8,SVRBPTR),LOAD0     LOAD NAME FOR XCTL              39000021
         B     GOXCTL                                                   39200021
*                                                                       39400021
TERMDDR  EQU   *                                                        39600021
         MVC   DDRWORK+N12(N8),LOAD0    FOR CONTROL AFTER MSG           39800021
         MVC   N8(N8,SVRBPTR),MSGMOD2   LOAD NAME FOR XCTL              40000021
         OI    DDRFLGSB,DDREND          TO TERMINATE DDR                40200021
         B     GOXCTL                   GO PREPARE FOR XCTL             40400021
         SPACE 5                                                        40600021
*                                                                       40800021
***      REGISTER EQUATES                                               41000021
*                                                                       41200021
WKREG0   EQU   0                        WORK REGISTER                   41250021
RQEPTR   EQU   1                        RQE PTR                         41400021
CVTREG   EQU   3                        CVT PTR                         41600021
SVRBPTR  EQU   5                        EXTENDED SAVE AREA PTR          41800021
FMUCB    EQU   7                        'FROM' UCB PTR                  42000021
TOUCB    EQU   8                        'TO' UCB PTR                    42200021
WKREG9   EQU   9                        WORK REGISTER                   42400021
OURDEB   EQU   10                       DDR DEB PTR                     42600021
COMMPTR  EQU   11                       IORMSCOM PTR                    42800021
BASE     EQU   12                       MODULE BASE REG                 43000021
OURIOB   EQU   13                       DDR IOB PTR                     43200021
WKREG14  EQU   14                       WORK REGISTER                   43400021
WKREG15  EQU   15                       WORK REGISTER                   43600021
         SPACE 3                                                        43800021
*                                                                       44000021
***      INTEGER EQUATES                                                44200021
*                                                                       44400021
N0       EQU   0                        DISPLACEMENT VALUE              44600021
N1       EQU   1                        DISPLACEMENT VALUE              44800021
N2       EQU   2                        DISPLACEMENT VALUE              45000021
N3       EQU   3                        DISPLACEMENT VALUE              45200021
N4       EQU   4                        DISPLACEMENT VALUE              45400021
N6       EQU   6                        DISPLACEMENT VALUE              45600021
N7       EQU   7                        DISPLACEMENT VALUE              45800021
N8       EQU   8                        DISPLACEMENT VALUE              46000021
N9       EQU   9                        DISPLACEMENT VALUE              46200021
N12      EQU   12                       DISPLACEMENT VALUE              46400021
N13      EQU   13                       DISPLACEMENT VALUE              46600021
N16      EQU   16                       DISPLACEMENT VALUE              46800021
N17      EQU   17                       DISPLACEMENT VALUE              47000021
N18      EQU   18                       DISPLACEMENT VALUE              47200021
N19      EQU   19                       DISPLACEMENT VALUE              47400021
N20      EQU   20                       DISPLACEMENT VALUE              47600021
N28      EQU   28                       DISPLACEMENT VALUE              47800021
N30      EQU   30                       DISPLACEMENT VALUE              48000021
N32      EQU   32                       DISPLACEMENT VALUE              48200021
N33      EQU   33                       DISPLACEMENT VALUE              48400021
N34      EQU   34                       DISPLACEMENT VALUE              48600021
N36      EQU   36                       DISPLACEMENT VALUE              48800021
N42      EQU   42                       DISPLACEMENT VALUE              49000021
N49      EQU   49                       DISPLACEMENT VALUE              49200021
N51      EQU   51                       DISPLACEMENT VALUE              49400021
         SPACE 3                                                        49600021
*                                                                       49800021
***      GENERAL EQUATES                                                50000021
*                                                                       50200021
A        EQU   X'C1'                    LOWER BOUND FOR CUA DIGIT       50400021
ALL      EQU   X'FF'                    MASK FOR 'AND' INSTRUCTIONS     50600021
DASD     EQU   X'20'                    DASD DEVICE                     50800021
DASDEXT  EQU   X'04'                    DASD EXTENTS                    51000021
EXIT     EQU   3                        SVC 3 - EXIT                    51200021
F        EQU   X'C6'                    UPPER BOUND FOR CUA DIGIT       51400021
FILEMASK EQU   X'C0'                    FILE MASK FOR DASD              51600021
MERLINDV EQU   X'09'                    MERLIN DEVICE                   51800021
NOOP     EQU   X'03'                    NO-OP COMMAND                   52000021
NOPATHS  EQU   X'01'                    NO PATHS TO DEVICE BIT    46458 52050021
NUMBER   EQU   X'F0'                    NUMERIC MASK FOR CUA CHECKING   52200021
PERMRES  EQU   X'04'                    PERMANENT RESIDENT INDCATOR     52400021
SHARED   EQU   X'20'                    SHARED DASD                     52600021
SYSRESDV EQU   X'02'                    SYSRES DEVICE INDICATOR         52800021
UNRECEXT EQU   X'02'                    UNIT RECORD EXTENT              53000021
UNRLTD   EQU   X'02'                    UNRELATED BIT IN IOBFLAGS1      53200021
ZERO     EQU   X'00'                    ZERO MASK                       53400021
ERREXCP  EQU   15                       SVC 15 - ERROR EXCP             53600021
         SPACE 3                                                        53800021
*                                                                       54000021
***      CHANNEL PROGRAM AND DEFINED CONSTANTS                          54200021
*                                                                       54400021
         DS    0D                       DOUBLE WORD BOUNDRY             54600021
NOPCCW   DC    X'03'                    NO-OP COMMAND                   54800021
         DC    X'000000'                BUFFER ADDR FIELD               55000021
         DC    X'20'                    SUPRESS WRONG LENGTH            55200021
         DC    X'000005'                LENGTH INDICATOR                55400021
LOAD0    DC    C'IGC0008E'              INITIATOR/TERMINATOR MODULE     55600021
LOAD1    DC    C'IGC0108E'              THIS MODULE                     55800021
LOAD7    DC    C'IGC0708E'              RECORDING MODULE                56000021
MSGMOD1  DC    C'IGC0508E'              MSG MODULE #1                   56200021
MSGMOD2  DC    C'IGC0808E'              MSG MODULE #2                   56400021
FFFF     DC    X'FFFF'                  END OF UCB LIST INDICATOR       56600021
ZEROS    DC    X'0000'                  ZERO MASK FOR NO UCB IN SYSTEM  56800021
YES      DC    C'YES'                   YES REPLY                       57000021
NO       DC    C'NO'                    NO REPLY                        57200021
MAINT    DC    50X'40'                  SPACE FOR MAINT & TEMP PATCHES  57360021
         SPACE 3                                                        57400021
CVTDSECT DSECT                                                          57600021
         CVT                                                            57800021
         SPACE 3                                                        58000021
         IORMSCOM                                                       58200021
*/*IGC0108E:      CHART                                              */ 84604021
*/*IGC0108E:      E IGC0108E                                         */ 84608021
*/*               P ESTABLISH ALL ADDRESSABILITY                     */ 84612021
*/*               D (YES,,NO,RCRDTEST) IS ENTRY FROM READING BUFRD LO   84616021
*/*               G ?                                                */ 84620021
*/*               P RESTORE 'TO' UCB POINTER                         */ 84624021
*/*               P (,SWAPTHEM) PUT NOOP COMMAND IN CCW              */ 84628021
*/*RCRDTEST:      D (YES,,NO,CHKSWAP) IS ENTRY AFTER RECORDING SENSE */ 84632021
*/*               P (,ENDDDR) TURN OFF THE RECORDING BIT             */ 84636021
*/*CHKSWAP:       D (NO,,YES,RCRDMERL) IS ENTRY AFTER PROCEED MSG ?  */ 84640021
*/*               D (NO,,YES,CHKREPLY) IS ENTRY AFTER SWAP MSG ?     */ 84644021
*/*               D (YES,,NO,SWAPON) IS 'FROM' DEVICE SYSRES ?       */ 84648021
*/*               P (,THISLOAD) TURN SYSRES BIT ON                   */ 84652021
*/*SWAPON:        P TURN ON SWAPMSG BIT                              */ 84656021
*/*THISLOAD:      P PUT IGC0108E IN DDRWORK + 12 (RETURN AFTER XCTL) */ 84660021
*/*DDRMSG1:       P SET IGC0508E FOR XCTL                            */ 84664021
*/*GOXCTL:        L () - XCTL -                                      */ 84668021
*/*CHKREPLY:      D (NO,,YES,TERMDDR) IS REPLY 'NO' ?                */ 84672021
*/*               D (NO,,YES,CKSYSRS) IS REPLY 'YES' ?               */ 84676021
*/*CHKNUMBR:      D (YES,,NO,BADDEV) IS REPLY A VALID 'CUA' ?        */ 84680021
*/*NXTDIGIT:      P DO UCB SCAN                                      */ 84684021
*/*CKUCBEND:      D (NO,,YES,CKITSELF) UCB FOUND ?                   */ 84688021
*/*BADDEV:        P (,THISLOAD) TURN ON THE INVALID BIT              */ 84692021
*/*CKITSELF:      D (NO,,YES,CKSYSRS) IS 'TO' UCB SAME AS 'FROM' UCB */ 84696021
*/*               D (NO,,YES,BADDEV) IS 'TO' DEV. PERM. RESIDENT ?   */ 84700021
*/*               D (NO,,YES,BADDEV) IS 'TO' DEV. SYSRES ?           */ 84704021
*/*               D (NO,,YES,BADDEV) IS 'TO' DEV. SHARED ?           */ 84708021
*/*               D (YES,,NO,BADDEV) DO 'TO' & 'FROM' UCB TYPES MATCH   84712021
*/*                ?                                                 */ 84716021
*/*CKSYSRS:       P TURN OFF SWAPMSG BIT                             */ 84720021
*/*               P PUT 'TO' UCB @ IN IORMSCOM                       */ 84724021
*/*               D (YES,,NO,INITBLKS) IS THIS A SYSRES SWAP ?       */ 84728021
*/*               P TURN ON SYRESBR AND DDRMSG BITS                  */ 84732021
*/*               R - SVC 3- EXIT                                    */ 84736021
*/*TERMDDR:       P PUT IGC0008E IN DDRWORK + 12 (RETURN AFTER XCTL) */ 84740021
*/*               P SET IGC0808E FOR XCTL                            */ 84744021
*/*               P (,GOXCTL) TURN ON DDREND BIT                     */ 84748021
*/*GOLOAD7:       P (,GOXCTL) SET IGC0708E FOR XCTL                  */ 84752021
*/*RCRDMERL:      D (YES,,NO,ENDDDR) IS THIS A DASD DEVICE ?         */ 84756021
*/*               D (NO,,YES,GOLOAD7) IS SWAP FOR MERLIN ?           */ 84760021
*/*ENDDDR:        P TURN ON THE TERMINATE BIT                        */ 84764021
*/*               P (,GOXCTL) SET IGC0008E FOR XCTL                  */ 84768021
*/*INITBLKS:      P TURN ON FIRSTIO BIT                              */ 84772021
*/*               P INITIALIZE DDR CONTROL BLOCK FIELDS              */ 84776021
*/*ZEROECB:       P CLEAR IOS ECB                                    */ 84780021
*/*               P CLEAR STATUS BITS & ERROR COUNT BITS IN IOB      */ 84784021
*/*               D (NO,,YES,DASDEXTN) IS SWAP FOR DASD ?            */ 84788021
*/*               P (,SWAPIT) SET UNIT RECORD EXTENTS IN DDRDEB      */ 84792021
*/*DASDEXTN:      P SET DASD EXTENTS IN DDRDEB                       */ 84796021
*/*               P PUT NOOP COMMAND IN CCW                          */ 84800021
*/*               P TURN ON IONOCTRL BIT                             */ 84804021
*/*               L - SVC 15 - ERREXCP                               */ 84808021
*/*               L - WAIT - ECB = IOSECB                            */ 84812021
*/*               D (YES,,NO,CHKFIRST) IS THE ERROR BIT ON ?         */ 84816021
*/*               P (,BADDEV) TURN THE ERROR BIT OFF                 */ 84820021
*/*CHKFIRST:      D (YES,,NO,TSTCLASS) IS FIRSTIO BIT ON ?           */ 84824021
*/*               P TURN OFF FIRSTIO BIT                             */ 84828021
*/*               P (,ZEROECB) INIT. DDR CTRL. BLKS WITH 'FROM' UCB  */ 84832021
*/*TSTCLASS:      D (YES,,NO,SWAPIT) IS FMUCB A DASD DEVICE?         */ 84836021
*/*               D (YES,,NO,SWAPTHEM) IS SWAP FOR MERLIN ?          */ 84840021
*/*               P (,GOLOAD7) SAVE 'TO' UCB POINTER                 */ 84844021
*/*SWAPTHEM:      P INITIALIZE FIELDS IN IOB                         */ 84848021
*/*SWAPIT:        P TURN OFF FIRSTIO INDICATOR                       */ 84852021
*/*               P TURN ON SWAP UCB BIT                             */ 84856021
*/*               L - SVC 15 - ERREXCP (SWAP UCB INFO)               */ 84860021
*/*               P TURN OFF SWAP UCB BIT                            */ 84864021
*/*               P (,THISLOAD) TURN ON THE PROCEED BIT              */ 84868021
*/*IGC0108E:      END                                                */ 84872021
         END                                                            84900021
