IGC0308E CSECT                                                          00400021
**********************************************************************  00404021
*                                                                       00408021
* STATUS:                                                               00412021
*                                                                       00416021
*    RELEASE 21.8                                                       00420021
*                                                                       00424021
*                                                                       00428021
* FUNCTION:                                                             00432021
*                                                                       00436021
*    THIS MODULE GAINS CONTROL OF THE DEVICES INVOLVED WITH THE         00440021
*    SYSTEM INITIATED SWAP BY ISSUING A NOP TO DASD DEVICES OR A        00444021
*    REWIND-UNLOAD TO TAPE DEVICES. THE IO IS PERFORMED BY USING AN SVC 00448021
*    INTERFACE WITH IOS TO GIVE CONTROL TO DDR'S CHANNEL END APPENDAGE  00452021
*    WHICH IN TURN REQUESTS IOS TO PERFORM AN INDICATED FUNCTION. WHEN  00456021
*    CONTROL OF THE DEVICES HAS BEEN GAINED, THE UCB INFORMATION IS     00460021
*    IS SWAPPED USING THE SVC 15 INTERFACE. FOR DASD, THE PROCEED       00464021
*    MESSAGE IS ISSUED, SVC 15 IS CALLED TO RETRY THE FAILING           00468021
*    OPERATION AND CONTROL RETURNS TO IGC0008E FOR TERMINATION. FOR     00472021
*    TAPE, CONTROL GOES TO IGC0408E FOR REPOSITIONING OF THE TAPE PRIOR 00476021
*    TO THE RETRY OF THE FAILING OPERATION.                             00480021
*                                                                       00484021
*                                                                       00488021
* ENTRY POINT:                                                          00492021
*                                                                       00496021
*         IGC0308E - FIRST INSTRUCTION OF MODULE.                       00500021
*                                                                       00504021
*                                                                       00508021
* INPUT:                                                                00512021
*                                                                       00516021
*    ON ENTRY FROM IGC0208E, REG 1 = DDR RQE ADDR, REG 2 = DDR WAIT     00520021
*    QUEUE ADDR, REG 3 = CVT ADDR, REG 5 = XSA ADDR, REG 7 = 'FROM'     00524021
*    DEVICE UCB ADDR, REG 8 = 'TO' DEVICE UCB ADDR, REG 10 = DDR        00528021
*    DEB ADDR, REG 11 = IORMSCOM ADDR, REG 13 = DDR IOB ADDR. THE       00532021
*    UCB ADDRESSES OF THE 'FROM' AND 'TO' DEVICES ARE IN DDRFMUCB       00536021
*    AND DDRTOUCB IN IORMSCOM.                                          00540021
*    ON ENTRY FROM IGC0708E, THE ABOVE REGISTERS REMAIN THE SAME AND    00544021
*    DDRFLGSE WILL HAVE THE READFROM OR THE RECRDING BIT ON.            00548021
*    ON ENTRY FROM IGC0508E, THE ABOVE REGISTERS REMAIN THE SAME AND    00552021
*    DDRFLGSB WILL HAVE THE PROCEED BIT ON.                             00556021
*                                                                       00560021
*                                                                       00564021
* OUTPUT:                                                               00568021
*                                                                       00572021
*    FOR ALL EXITS, THE ABOVE REGISTERS REMAIN THE SAME.                00576021
*    ON XCTL TO IGC0008E, DDRFLGSC WILL HAVE THE TERMNATE BIT ON.       00580021
*    ON XCTL TO IGC0508E, DDRFLGSB WILL HAVE THE PROCEED BIT ON.        00584021
*    ON XCTL TO IGC0208E, DDRFLGSB WILL HAVE THE INVALID BIT ON.        00588021
*    ON XCTL TO IGC0408E, DDRFLGSB WILL HAVE THE PROCCED BIT ON.        00592021
*    ON XCTL TO IGC0808E, DDRFLGSB WILL HAVE THE DDREND BIT ON.         00596021
*                                                                       00600021
*                                                                       00604021
* EXTERNAL REFERENCES:                                                  00608021
*                                                                       00612021
*    XCTL. SVC 15. WAIT.                                                00616021
*                                                                       00620021
*                                                                       00624021
* EXITS-NORMAL:                                                         00628021
*                                                                       00632021
*         TO IGC0008E TO TERMINATE DDR.                                 00636021
*         TO IGC0208E BY WAY OF IGC0508E FOR SWAP MESSAGE AFTER INVALID 00640021
*    MESSAGE.                                                           00644021
*         TO IGC0408E TO CONTINUE TAPE PROCESSING.                      00648021
*         TO IGC0508E FOR MESSAGES.                                     00652021
*         TO IGC0708E FOR 3330 RECORDING PROCESSING.                    00656021
*         TO IGC0808E FOR MESSAGES.                                     00660021
*                                                                       00664021
*                                                                       00668021
* EXITS-ERROR:                                                          00672021
*                                                                       00676021
*         NONE.                                                         00680021
*                                                                       00684021
*                                                                       00688021
* TABLES/WORK AREAS:                                                    00692021
*                                                                       00696021
*    IORMSCOM - THE DDR COMMUNICATIONS AREA.                            00700021
*                                                                       00704021
*                                                                       00708021
* ATTRIBUTES:                                                           00712021
*                                                                       00716021
*         ENABLED. SERIALLY REUSABLE.                                   00720021
*                                                                       00724021
*                                                                       00728021
* CHARCTER CODE DEPENDENCY:                                             00732021
*                                                                       00736021
*         NONE.                                                         00740021
*  UPDATE ACTIVITY                                             @SA70773 00741021
*     APAR 70773 (FILEMASK NOT MOVED FOR DASD)                 @SA70773 00742021
*                                                                       00744021
**********************************************************************  00748021
         SPACE 2                                                        00752021
         TITLE '   IGC0308E - SYSTEM SWAP NUMBER 2 '                    00800021
         BALR  BASE,N0                  MODULE BASE REG                 01200021
         USING *,BASE                   MODULE ADDR                     01600021
         USING CVTDSECT,CVTREG          CVT ADDR                        02000021
         USING IORMS,COMMPTR            IORMSCOM,ADDR                   02400021
*                                                                       02800021
*        DETERMINE WHY ENTERED. INITIALLY THIS MODULE IS ENTERED WHEN   03050000
*        THE OPERATOR HAS REPLIED 'YES' OR A VALID DEVICE TO THE SWAP   03100000
*        MESSAGE.                                                       03150000
*                                                                       03160000
         TM    DDRFLGSB,PROCEED         IS ENTRY AFTER PROCEED MSG      03200021
         BO    CHKMERL                  YES, GO PREPARE FOR RETRY       03600021
         TM    DDRFLGSE,READFROM        IS ENTRY AFTER BUFFERED LOG RED 04000021
         BZ    TSTRECRD                 NO, SEE IF SENSE WAS RECORDED   04400021
         MVI   DDRWORK,NOOP             NO-OP COMMAND IN CCW            04800021
         B     SWAPTHEM                 GO PREPARE TO SWAP UCB INFO     05200021
*                                                                       05600021
TSTRECRD EQU   *                                                        06000021
         TM    DDRFLGSE,RECRDING        IS ENTRY AFTER RECORDING SENSE  06400021
         BZ    PREPIO                   NO, GO PREPARE FOR IO           06800021
         NI    DDRFLGSE,ALL-RECRDING    TURN OFF RECORDING BIT          07200021
         B     SETRETRY                 GO PREPARE TO RETRY USER        07600021
*                                                                       07850000
*        PREPARE TO GAIN CONTROL OF THE DEVICES                         07900000
*                                                                       07950000
PREPIO   EQU   *                                                        08000021
         OI    DDRFLGSB,FIRSTIO         FOR FIRST IO TO TAPE DEVICES    08400021
         BAL   WKREG15,PURGECHK         GO SEE IF RQE IS STILL ON WAITQ 08800021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     09200021
         STH   TOUCB,N34(OURDEB)        'TO' UCB PTR INTO DEB           09600021
         STH   TOUCB,N2(RQEPTR)         'TO' UCB PTR INTO RQE           10000021
*                                                                       10250000
*        INITAIALIZE CONTROL BLOCKS FOR IO                              10300000
*                                                                       10350000
INITBLKS EQU   *                                                        10360000
         XC    N30(N2,OURIOB),N30(OURIOB) CLEAR ERROR COUNT IN IOB      10370000
         XC    N9(N7,OURIOB),N9(OURIOB) CLEAR STATUS IN IOB             10800021
         NI    N44(OURDCB),ALL-NOERP    ALLOW USE OF ERP                11200021
         MVI   IOSECB,ZERO              CLEAR ECB USED BY IOS           11600021
         MVI   N0(OURIOB),UNRLTD        UNRELATED BIT IN IOB FLAGS1     12000021
         OI    DDRFLGSC,IONOCTRL        TO EXCP WITHOUT CONTROL         12400021
         CLI   N18(FMUCB),DASD          IS THIS A DASD SWAP             12800021
         BE    PREPDASD                 YES, GO PREPARE FOR DASD IO     13200021
*                                                                       13600021
*        TAPE INITIALIZATION                                            13850000
*                                                                       13900000
         LH    RQEPTR,OURRQE            RESTORE DDR RQE PTR INTO REG 1  14000021
         MVI   N32(OURDEB),RUNMODE      MODE SET INTO DEB               14400021
         MVI   N28(OURDEB),TAPEXTNT     EXTENT SCALE INTO DEB           14800021
         MVC   DDRWORK(N16),RUNCCW      REWIND-UNLOAD COMMAND           15200021
         B     IO                       GO DO IO                        15600021
*                                                                       15950000
*        DASD INITIALIZATION                                            15952000
*                                                                       15954000
PREPDASD EQU   *                                                        15960000
         MVC   N33(N7,OURIOB),N49(TOUCB) SEEK ADDR INTO IOB             16800021
         MVC   N36(N6,OURDEB),N49(TOUCB) SEEK ADDR INTO DEB             17200021
         MVC   N42(N4,OURDEB),N51(TOUCB) END ADDR INTO DEB              17600021
         MVI   N28(OURDEB),DASDXTNT     EXTENT SCALE INTO DEB           18000021
         MVI   N32(OURDEB),DASDFMSK  MOVE FILEMASK INTO DEB    @SA70773 18020021
         NI    DDRFLGSB,ALL-FIRSTIO     ONLY 1 IO NEEDED FOR DASD 63065 18050021
         CR    FMUCB,TOUCB              IS SWAP TO ITESLF         58242 18450021
         BE    TESTMERL                 YES, TEST FOR MERLIN      58242 18500021
NOOPIO   EQU   *                                                        18800021
         MVC   DDRWORK(N8),NOOPCCW      NO-OP CCW                       19200021
IO       EQU   *                                                        19600021
*                                                                       20000021
         SVC   ERREXCP                  GO DO IO                        20400021
*                                                                       20800021
         WAIT  ECB=IOSECB               WAIT FOR IO                     21200021
*                                                                       21600021
         TM    DDRFLGSC,ERROR           IS PERM ERROR INDICATE          22000021
         BZ    TSTFIRST                 NO, GO SEE IF MORE IO IS NEEDED 22400021
         NI    DDRFLGSC,ALL-ERROR       TURN OFF ERROR INDICATOR        22800021
         TM    DDRFLGSB,FIRSTIO         WAS ERROR ON 'TO' DEVICE        23200021
         BZ    TERMDDR                  NO, GO TERMINATE DDR            23600021
         OI    DDRFLGSB,INVALID+NOTOUCB FOR INVALID MSG IGF513I         24000021
         MVC   DDRWORK+N12(N8),LOAD2    FOR CONTROL AFTER MSG           24400021
*                                                                       24800021
DDRMSG1  EQU   *                                                        25200021
         MVC   N8(N8,SVRBPTR),MSGMOD1   LOAD NAME FOR XCTL              25600021
*                                                                       26000021
*        SET UP FOR XCTL'S                                              26150000
*                                                                       26200000
GOXCTL   EQU   *                                                        26400021
         SR    WKREG15,WKREG15          ZERO FOR XCTL SET UP            26800021
         ST    WKREG15,N4(SVRBPTR)      ZERO SECOND WORD                27200021
         LA    WKREG15,N8(SVRBPTR)      ADDR OF LOCATION OF LOAD NAME   27600021
         ST    WKREG15,N0(SVRBPTR)      THAT ADDR INTO FIRST WORD       28000021
         LR    WKREG15,SVRBPTR          SAVE AREA ADDR INTO PARM REG    28400021
         XCTL  SF=(E,(WKREG15))         TRANSFER CONTROL                28800021
*                                                                       29200021
*        PREPARATION TO TERMINATE DDR                                   29450000
*                                                                       29500000
TERMDDR  EQU   *                                                        29600021
         OI    DDRFLGSB,DDREND          FOR TERMINATE MSG               30000021
         OI    DDRFLGSC,TERMNATE        TO TERMINATE DDR                30400021
         MVC   DDRWORK+N12(N8),LOAD0    FOR CONTROL AFTER MSG           30800021
         MVC   N8(N8,SVRBPTR),MSGMOD2   LOAD NAME FOR XCTL              31200021
         B     GOXCTL                   GO PREPARE FOR XCTL             31600021
*                                                                       32000021
*        IF FIRSTIO BIT IS ON, INITIALIZE CONTROL BLOCKS FOR 'FROM'     32150000
*        DEVICE AND LOOP BACK FOR IO. IF BIT IS NOT ON, SEE IF SWAP     32200000
*        IS FOR A 3330 DEVICE.                                          32250000
*                                                                       32300000
TSTFIRST EQU   *                                                        32400021
         TM    DDRFLGSB,FIRSTIO         IS IO TO 'FROM' DEVICE NEEDED   32800021
         BZ    TESTMERL                 NO, GO CHECK FOR MERLIN         33200021
         NI    DDRFLGSB,ALL-FIRSTIO     TURN OFF FIRST DEVICE IO BIT    33600021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     34000021
         STH   FMUCB,N2(RQEPTR)         'FROM' UCB PTR INTO RQE         34400021
         STH   FMUCB,N34(OURDEB)        'FROM' UCB PTR INTO DEB         34800021
         CLI   N18(FMUCB),DASD          IS THIS A DASD SWAP             35200021
         BE    NOOPIO                   YES, NO IO NEEDED JUST CONTROL  35600021
*                                                                       35650000
*        FOR ALL TAPE SWAPS SENSE DATA IS RECORDED VIA SVC 91.          35700000
*                                                                       35750000
         LA    WKREG0,DDRDCB            DDR DCB PTR INTO REG 0    21048 36000000
         LA    RQEPTR,N50               DDR INDICATOR INTO REG 1  21048 36400021
         SVC   91                       GO RECORD                 21048 36800021
         B     INITBLKS                 GO DO IO TO SECOND DEVICE       37200021
*                                                                       37600021
*        IF SWAP IS FOR 3330, GO TO IGC0708E TO READ THE BUFFERED LOG   37850000
*                                                                       37900000
TESTMERL EQU   *                                                        37950021
         CLI   N18(FMUCB),DASD          IS THIS A DASD SWAP             38000021
         BNE   SWAPTHEM                 NO, GO SWAP UCB INFO            38400021
         CLI   N19(FMUCB),MERLINDV      IS THIS A MERLIN DEVICE         38800021
         BNE   SWAPTHEM                 NO, GO SWAP UCB INFO            39200021
*                                                                       39600021
GOLOAD7  EQU   *                                                        40000021
         NI    DDRFLGSC,ALL-IONOCTRL  ALL I/O IN 708E IS W/CNTRL  59125 40050021
         MVC   N8(N8,SVRBPTR),LOAD7     LOAD NAME FOR XCTL              40400021
         B     GOXCTL                   GO PREPARE FOR XCTL             40800021
*                                                                       41200021
*        PREPARATION TO SWAP UCB INFORMATION                            41450000
*                                                                       41500000
SWAPTHEM EQU   *                                                        41600021
         NI    DDRFLGSC,ALL-IONOCTRL    TURN OFF IO INDICATOR           42000021
         OI    DDRFLGSC,SWAPUCB         TO SWAP UCB INFO                42400021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     42800021
         MVI   N0(OURIOB),UNRLTD        UNRELATED BIT IN IOB FLAGS 1    43200021
         XC    N9(N7,OURIOB),N9(OURIOB) CLEAR STATUS IN IOB             43600021
         XC    N30(N2,OURIOB),N30(OURIOB) CLEAR ERROR COUNT IN IOB      44000021
         SVC   ERREXCP                  GO SWAP INFO                    44400021
*                                                                       44800021
*                                                                       45200021
         NI    DDRFLGSC,ALL-SWAPUCB     TURN OFF SWAP INDICATOR         45600021
         OI    DDRFLGSB,PROCEED         FOR PROCEED MSG IGF502E         46000021
         CLI   N18(FMUCB),DASD          IS THIS DASD                    46400021
         BNE   RTRNTAPE                 NO, SET UP FOR MSG RETRN TO TAP 46800021
         MVC   DDRWORK+N12(N8),LOAD3    FOR RETURN CONTROL AFTER MSG    47200021
         B     DDRMSG1                  GO PREPARE FOR MSG              47600021
*                                                                       48000021
*        FOR TAPE, CONTROL IS PASSED TO IGC0608E FROM THE MESSAGE       48350000
*        MODULE AFTER THE PROCEED MESSAGE                               48360000
*                                                                       48370000
RTRNTAPE EQU   *                                                        48400021
         LH    RQEPTR,USRRQE            USER'S RQE PTR                  48650000
         L     WKREG14,N4(RQEPTR)       USER'S IOB PTR                  48700000
         LA    WKREG14,N0(WKREG14)      CLEAR HIGH BYTE                 48750000
         TM    N28(WKREG14),NEGINCR     IS IOB INCREMENT NEG            48760000
         BZ    LOADSIX                  NO, PREPARE FOR MSG AND LOAD 6  48770000
         OI    DDRFLGSF,NEGCOUNT        YES, INDICATE NEG INIT          48798800
*                                                                       48799200
LOADSIX  EQU   *                                                        48799600
         MVC   DDRWORK+N12(N8),LOAD6    FOR CONTROL AFTER MSG - TAPE    48800021
         B     DDRMSG1                  GO PREPARE FOR MSG              49200021
*                                                                       49600021
*        FOR 3330, AFTER UCB INFO IS SWAPPED, CONTROL IS PASSED TO      49850000
*        IGC0708E TO RECORD THE SENSE DATA                              49900000
*                                                                       49950000
CHKMERL  EQU   *                                                        50000021
         NI    DDRFLGSB,ALL-PROCEED     TURN OFF PROCEED INDICATOR 1633 50200000
         CLI   N18(FMUCB),DASD          IS THIS DASD                    50400021
         BNE   SETRETRY                 NO, PREPARE FOR RETRY USER      50800021
         CLI   N19(FMUCB),MERLINDV      IS THIS MERLIN                  51200021
         BE    GOLOAD7                  YES, GO TO RECORD SENSE         51600021
*                                                                       52000021
*        RETRY THE FAILING RQE                                          52050000
*                                                                       52100000
SETRETRY EQU   *                                                        52400021
         BAL   WKREG15,PURGECHK         GO SEE IF RQE IS STILL ON WAITQ 52800021
         OI    DDRFLGSE,RETRY           TO RETRY USER RQE               53200021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     53600021
         XC    N9(N7,OURIOB),N9(OURIOB) CLEAR STATUS IN IOB             54000021
         XC    N30(N2,OURIOB),N30(OURIOB) CLEAR ERROR COUNT IN IOB      54400021
         MVI   N0(OURIOB),UNRLTD        UNRELATED BIT IN IOB FLAGS 1    54800021
         SVC   ERREXCP                  GO RETRY USER RQE               55200021
*                                                                       55550000
*        END DDR PROCESSING                                             55560000
*                                                                       55570000
ENDDDR   EQU   *                                                        55600021
         NI    DDRFLGSE,ALL-RETRY       TURN OFF RETRY INDICATOR        56000021
         OI    DDRFLGSC,TERMNATE        TO TERMINATE DDR                56400021
         MVC   N8(N8,SVRBPTR),LOAD0     LOAD NAME FOR XCTL              56800021
         B     GOXCTL                   GO PREPARE FOR XCTL             57200021
*                                                                       57600021
*        THIS IS A CHECK TO SEE IF THE USER'S RQE HAS BEEN PURGED       57950000
*        DURING DDR PROCESSING                                          57960000
*                                                                       57970000
PURGECHK EQU   *                                                        58000021
         LH    RQEPTR,USRRQE            USER RQE PTR                    58400021
         CH    RQEPTR,N0(WQPTR)         IS RQE STILL ON WAIT Q          58800021
         BNE   ENDDDR                   NO GO TERMINATE DDR             59200021
         TM    N4(WQPTR),PURGE          WAS THIS RQE PURGED PREVIOUSLY  59600021
         BO    ENDDDR                   YES, GO TERMINATE DDR           60000021
         BR    WKREG15                  RETURN TO MAINLINE              60400021
         SPACE 5                                                        60800021
*                                                                       61200021
***      REGISTER EQUATES                                               61600021
*                                                                       62000021
WKREG0   EQU   0                        WORK REGISTER                   62400021
RQEPTR   EQU   1                        RQE PTR                         62800021
WQPTR    EQU   2                        WAIT QUE PTR                    63200021
CVTREG   EQU   3                        CVT PTR                         63600021
SVRBPTR  EQU   5                        EXTENDED SAVE AREA PTR          64000021
FMUCB    EQU   7                        'FROM' UCB PTR                  64400021
TOUCB    EQU   8                        'TO' UCB PTR                    64800021
OURDCB   EQU   9                        DDR DCB PTR                     65200021
WKREG9   EQU   9                        WORK REGISTER                   65600021
OURDEB   EQU   10                       DDR DEB PTR                     66000021
COMMPTR  EQU   11                       IORMSCOM PTR                    66400021
BASE     EQU   12                       MODULE BASE REG                 66800021
OURIOB   EQU   13                       DDR IOB PTR                     67200021
WKREG14  EQU   14                       WORK REGISTER                   67600021
WKREG15  EQU   15                       WORK REGISTER                   68000021
*                                                                       68400021
***      INTEGER EQUATES                                                68800021
*                                                                       69200021
N0       EQU   0                        DISPLACEMENT VALUE              69600021
N2       EQU   2                        DISPLACEMENT VALUE              70000021
N4       EQU   4                        DISPLACEMENT VALUE              70400021
N6       EQU   6                        DISPLACEMENT VALUE              70800021
N7       EQU   7                        DISPLACEMENT VALUE              71200021
N8       EQU   8                        DISPLACEMENT VALUE              71600021
N9       EQU   9                        DISPLACEMENT VALUE              72000021
N12      EQU   12                       DISPLACEMENT VALUE              72400021
N16      EQU   16                       DISPLACEMENT VALUE              72800021
N18      EQU   18                       DISPLACEMENT VALUE              73200021
N19      EQU   19                       DISPLACEMENT VALUE              73600021
N28      EQU   28                       DISPLACEMENT VALUE              74000021
N30      EQU   30                       DISPLACEMENT VALUE              74400021
N32      EQU   32                       DISPLACEMENT VALUE              74800021
N33      EQU   33                       DISPLACEMENT VALUE              75200021
N34      EQU   34                       DISPLACEMENT VALUE              75600021
N36      EQU   36                       DISPLACEMENT VALUE              76000021
N42      EQU   42                       DISPLACEMENT VALUE              76400021
N44      EQU   44                       DISPLACEMENT VALUE              76800021
N49      EQU   49                       DISPLACEMENT VALUE              77200021
N50      EQU   50                       DDR INDICATOR FOR SVC 91        77600021
N51      EQU   51                       DISPLACEMENT VALUE              78000021
         SPACE 3                                                        78400021
*                                                                       78800021
***      GENERAL EQUATES                                                79200021
*                                                                       79600021
ALL      EQU   X'FF'                    MASK FOR 'AND' INSTRUCTIONS     80000021
DASD     EQU   X'20'                    DASD INDICATOR                  80400021
DASDXTNT EQU   X'04'                    DASD EXTENT SCALE               80800021
DASDFMSK EQU   X'C0'             DASD FILE MASK                @SA70773 81000021
ERREXCP  EQU   15                       SVC 15 - ERROR EXCP             81200021
MERLINDV EQU   X'09'                    MERLIN DEVICE ID                81600021
NEGINCR  EQU   X'80'                    TO CHECK FOR NEG IOB INCREMENT  81950000
NOERP    EQU   X'0C'                    NEVER USE IOS ERROR ROUTINE     82000021
NOOP     EQU   X'03'                    NO-OP COMMAND                   82400021
PURGE    EQU   X'80'                    PURGE INDICATOR FOR WAIT Q      82800021
READBACK EQU   X'0C'                    READ BACKWARD COMMAND           83150000
RUNMODE  EQU   X'0F'                    REWIND-UNLOAD MODE SET          83200021
TAPEXTNT EQU   X'02'                    TAPE EXTENT SCALE               83600021
UNRLTD   EQU   X'02'                    UNRELATED BIT IN IOS FLAGS 1    84000021
ZERO     EQU   X'00'                    ZERO MASK                       84400021
         SPACE 3                                                        84800021
*                                                                       85200021
***      CHANNEL PROGRAMS AND DEFINED CONSTANTS                         85600021
*                                                                       86000021
         DS    0D                       DOUBLE WORD BOUNDRY             86400021
RUNCCW   DC    X'0F'                    REWIND-UNLOAD COMMAND           86800021
         DC    X'000000'                BUFFER ADDR FIELD               87200021
         DC    X'60'                    COMMAND CHAINING & SILLY BIT    87600021
         DC    X'000005'                LENGTH                          88000021
NOOPCCW  DC    X'03'                    NO-OP COMMAND                   88400021
         DC    X'000000'                BUFFER ADDR FIELD               88800021
         DC    X'20'                    SUPPRESS WRONG LENGTH           89200021
         DC    X'000005'                LENGTH                          89600021
*                                                                       90000021
LOAD0    DC    C'IGC0008E'              INITIATOR/TERMINATOR MODULE     90400021
LOAD2    DC    C'IGC0208E'              SYSTEM DDR MODULE #1            90800021
LOAD3    DC    C'IGC0308E'              THIS MODULE                     91200021
LOAD6    DC    C'IGC0608E'              TAPE DDR MODULE #2              91600021
LOAD7    DC    C'IGC0708E'              RECORDING MODULE                92000021
MSGMOD1  DC    C'IGC0508E'              MSG MODULE #1                   92400021
MSGMOD2  DC    C'IGC0808E'              MSG MODULE #2                   92800021
EIGHT    DC    H'8'                     USED TO GET ACTUAL COMMAND      92810000
MAINT    DC    50X'40'                  SPACE FOR MAINT & TEMP PATCHES  92850000
         SPACE 3                                                        93200021
CVTDSECT DSECT                                                          93600021
         CVT                                                            94000021
         SPACE 3                                                        94400021
         IORMSCOM                                                       94800021
         SPACE 3                                                        95200021
         SPACE 3                                                        95600021
*/*IGC0308E:      CHART                                              */ 95605000
*/*IGC0308E:      E IGC0308E                                         */ 95610000
*/*               P ESTABLISH ALL ADDRESSABILITY                     */ 95615000
*/*               D (NO,,YES,CHKMERL) IS ENTRY AFTER PROCEED MSG ?   */ 95620000
*/*               D (YES,,NO,TSTRECRD) IS ENTRY AFTER READING           95625000
*/*               BUFFERRED LOG ?                                    */ 95630000
*/*               P (,SWAPTHEM) PUT NOOP COMMAND IN CCW              */ 95635000
*/*TSTRECRD:      D (YES,,NO,PREPIO) IS ENTRY AFTER RECORDING SENSE     95640000
*/*               INFO. ?                                            */ 95645000
*/*               P (,SETRETRY) TURN OFF THE RECORDING BIT           */ 95650000
*/*PREPIO:        P TURN ON FIRSTIO BIT                              */ 95655000
*/*               S -PURGECHK-:SEE IF RQE IS STILL ON THE WAIT QUEUE */ 95660000
*/*               P INITIALIZE DDR CONTROL BLOCKS WITH 'TO' UCB      */ 95665000
*/*INITBLKS:      P CLEAR ERROR COUNT AND STATUS FIELDS IN IOB       */ 95670000
*/*               P TURN OFF NO ERROR BIT (ALLOW ERP'S)              */ 95675000
*/*               P CLEAR IOSECB                                     */ 95680000
*/*               P TURN ON  IONOCTRL BIT                            */ 95685000
*/*               D (NO,,YES,PREPDASD) IS 'FROM' DEVICE DASD ?       */ 95690000
*/*               L - SVC 91 - RECORDING SVC                         */ 95695000
*/*IO:            L - SVC 15 - ERREXCP                               */ 95700000
*/*               L - WAIT -                                         */ 95705000
*/*               D (YES,,NO,TSTFIRST) IS ERROR BIT ON ?             */ 95710000
*/*               P TURN OFF ERROR BIT                               */ 95715000
*/*               D (YES,,NO,TERMDDR) IS FIRSTIO BIT ON ?            */ 95720000
*/*               P TURN ON INVALID BIT                              */ 95725000
*/*               P PUT IGC0208E IN DDRWORK + 12 (RETURN AFTER XCTL) */ 95730000
*/*DDRMSG1:       P SET IGC0508E @ UP FOR XCTL                       */ 95735000
*/*GOXCTL:        L () - XCTL -                                      */ 95740000
*/*TERMDDR:       P TURN ON DDREND AND TERMINATE BITS                */ 95745000
*/*               P PUT IGC0008E IN DDRWORK + 12 (RETURN AFTER XCTL) */ 95750000
*/*               P (,GOXCTL) SET IGC0808E @ UP FOR XCTL             */ 95755000
*/*PREPDASD:      D (NO,,YES,SWAPTHEM) IS THIS A SWAP TO ITSELF ?    */ 95760000
*/*               P TURN OFF FIRSTIO BIT                             */ 95765000
*/*NOOPIO:        P (,IO) PUT NOOP COMMAND IN CCW                    */ 95770000
*/*SWAPTHEM:      P TURN OFF IONOCTRL BIT                            */ 95775000
*/*               P TURN ON SWAPUCB BIT                              */ 95780000
*/*               P CLEAR ERROR COUNT AND STATUS FIELDS IN IOB       */ 95785000
*/*               L - SVC 15 - SWAP UCB INFORMATION                  */ 95790000
*/*               P TURN OFF SWAP UCB BIT                            */ 95795000
*/*               P TURN ON PROCEED BIT                              */ 95800000
*/*               D (YES,,NO,RTRNTAPE) IS SWAP FOR DASD ?            */ 95805000
*/*               P (,DDRMSG1) PUT IGC0308E IN DDRWORK + 12 (RETURN     95810000
*/*               AFTER XCTL)                                        */ 95815000
*/*RTRNTAPE:      P (,DDRMSG1) PUT IGC0608E IN DDRWORK + 12 (RETURN     95820000
*/*               AFTER XCTL)                                        */ 95825000
*/*TSTFIRST:      D (YES,,NO,TESTMERL) IS FIRSTIO BIT ON ?           */ 95830000
*/*               P TURN OFF FIRSTIO BIT                             */ 95835000
*/*               P INITIALIZE DDR CONTROL BLOCKS WITH 'FROM' UCB    */ 95840000
*/*               D (NO,INITBLKS,YES,NOOPIO) IS SWAP FOR DASD ?      */ 95845000
*/*TESTMERL:      D (YES,,NO,SWAPTHEM) IS IT A DASD SWAP ?           */ 95850000
*/*               D (NO,SWAPTHEM,YES,GOLOAD7) IS SWAP FOR MERLIN ?   */ 95855000
*/*CHKMERL:       D (YES,,NO,SETRETRY) IS SWAP FOR DASD ?            */ 95860000
*/*               D (YES,,NO,GOLOAD7) IS SWAP FOR MERLIN ?           */ 95865000
*/*SETRETRY:      S -PURGECHK-:SEE IF RQE IS STILL ON THE WAIT QUEUE */ 95870000
*/*               P TURN ON RETRY BIT                                */ 95875000
*/*               L - SVC 15 - GO RETRY USER RQE                     */ 95880000
*/*ENDDDR:        P TURN OFF RETRY BIT                               */ 95885000
*/*               P TURN ON TERMINATE BIT                            */ 95890000
*/*               P (,GOXCTL) SET IGC0008E @ UP FOR XCTL             */ 95895000
*/*GOLOAD7:       P (,GOXCTL) SET IGC0708E @ UP FOR XCTL             */ 95900000
*/*PURGECHK:      E ENTRY                                            */ 95905000
*/*               P GET USER RQE                                     */ 95910000
*/*               D (YES,,NO,ENDDDR) IS RQE ON WAIT QUEUE ?          */ 95915000
*/*               D (NO,,YES,ENDDDR) WAS RQE PREVIOUSLY PURGED ?     */ 95920000
*/*               R -BR 15- RETURN TO MAINLINE                       */ 95925000
*/*IGC0308E:      END                                                */ 95930000
         END                                                            96000021
