IGC0408E CSECT                                                          00200021
**********************************************************************  00202000
*                                                                       00204000
* STATUS:                                                               00206000
*                                                                       00208000
*    RELEASE 21.8                                                       00210021
*                                                                       00212000
*                                                                       00214000
* FUNCTION:                                                             00216000
*                                                                       00218000
*    THIS MODULE RECEIVES CONTROL INITIALLY FROM EITHER IGC0008E FOR    00220000
*    OPERATOR SWAPS, OR FROM IGC0308E (VIA IGC0508E) FOR AN ERROR       00222000
*    CONDITION TO REPOSITION THE TAPE. FOR OPERATOR SWAPS THIS MODULE   00224000
*    CAUSES THE SWAP AND PROCEED MESSAGES TO BE ISSUED. THEREAFTER      00226000
*    PROCESSING IS THE SAME FOR OPERATOR OR ERROR SWAPS. CONTROL IS     00228000
*    PASSED TO IGC0608E FOR LABEL PROCESSING AND RECEIVED AGAIN TO      00230000
*    POSITION THE TAPE USING THE FILE COUNT IN THE UCB AND BLOCK        00232000
*    COUNT IN THE USER'S DCB.                                           00234000
*                                                                       00236000
*                                                                       00238000
* ENTRY POINT:                                                          00240000
*                                                                       00242000
*         IGC0408E   - FIRST INSTRUCTION OF MODULE.                     00244000
*                                                                       00246000
*                                                                       00248000
* INPUT:                                                                00250000
*                                                                       00252000
*    FOR ALL ENTRIES, REG 1 = DDR RQE ADDR, REG 2 = DDR WAIT QUEUE ADDR 00254000
*    REG 3 = CVT ADDR, REG 5 = XSA ADDR, REG 7 = 'FROM' DEVICE UCB ADDR 00256000
*    REG 8 = 'TO' DEVICE UCB ADDR, REG 10 = DDR DEB ADDR, REG 11 =      00258000
*    IORMSCOM ADDR, REG 13 = DDR IOB ADDR.                              00260000
*    ON ENTRY FROM IGC0008E, DDRFLGSA WILL HAVE THE OPINIT BIT ON.      00262000
*    ON ENTRY FROM IGC0308E, DDRFLGSB WILL HAVE THE PROCEED BIT ON.     00264000
*    ON ENTRY FROM IGC0508E, DDRFLGSB WILL HAVE THE SWAPMSG BIT ON.     00266000
*    ON ENTRY FROM IGC0608E, DDRFLGSC WILL HAVE THE REPOSITN BIT ON,    00268000
*    AND DDRFLGSD MAY HAVE THE STDLABEL OR THE READ BIT ON.             00270000
*    ON ENTRY FROM IGF2503D, REG 0 = 0 FOR A VALID CUA OR REG 0 = 4     00272000
*    FOR AN INVALID CUA. DDRFLGSA WILL HAVE THE VALIDATE BIT ON AND     00274000
*    THE NEW 'TO' DEVICE UCB ADDR WILL BE IN DDRTOUCB IN IORMSCOM.      00276000
*    ON ENTRY FROM NSLREPOS, DDRFLGSA WILL HAVE THE NSLUSER BIT ON.     00278000
*                                                                       00280000
*                                                                       00282000
* OUTPUT:                                                               00284000
*                                                                       00286000
*    FOR ALL EXITS THE ABOVE REGISTERS REMAIN THE SAME.                 00288000
*    ON XCTL TO IGC2503D, DDRFLGSA WILL HAVE THE VALIDATE BIT ON.       00290000
*    REG 0 WILL HAVE THE ADDR OF REPLY BUF LOCATED IN IORMSCOM WHICH    00292000
*    WILL HAVE THE OPERATORS REPLY TO THE SWAP MSG.                     00294000
*    ON XCTL TO IGC0608E, DDRFLGSB WILL HAVE THE PROCEED BIT ON OR      00296000
*    DDRFLGSA WILL HAVE THE NSLUSER BIT ON.                             00298000
*    ON XCTL TO IGC0508E, DDRFLGSB WILL HAVE EITHER THE SWAPMSG BIT OR  00300000
*    THE INVALID BIT ON, OR DDRFLGSC WILL HAVE THE ERROR BIT ON.        00302000
*    ON XCTL TO IGC0808E, DDRFLGSB MAY HAVE THE DDREND BIT ON OR        00304000
*    DDRFLGSC MAY  ERPINPRO BIT ON, OR DDRFLGSF WILL HAVE THE COMPLETE  00306000
*    BIT ON.                                                            00308000
*                                                                       00310000
*                                                                       00312000
* EXTERNAL REFERENCES:                                                  00314000
*                                                                       00316000
*         XCTL. SVC 15. WAIT. SVC 91.                                   00318000
*                                                                       00320000
*                                                                       00322000
* EXITS-NORMAL:                                                         00324000
*                                                                       00326000
*         TO IGC2503D TO VERIFY OPERATOR'S REPLY.                       00328000
*         TO IGC0608E FOR LABEL PROCESSING.                             00330000
*         TO IGC0508E FOR MESSAGES.                                     00332000
*         TO IGC0808E FOR MESSAGES.                                     00334000
*                                                                       00336000
*                                                                       00338000
* EXITS-ERROR:                                                          00340000
*                                                                       00342000
*         NONE.                                                         00344000
*                                                                       00346000
*                                                                       00348000
* TABLES/WORK AREAS:                                                    00350000
*                                                                       00352000
*         IORMSCOM - THE DDR COMMUNICATIONS AREA.                       00354000
*                                                                       00356000
*                                                                       00358000
* ATTRIBUTES:                                                           00360000
*                                                                       00362000
*         ENTERED ENABLED. DISABLES PRIOR TO ISSUING SVC 15.            00364000
*         SERIALLY REUSABLE.                                            00366000
*                                                                       00368000
*                                                                       00370000
* CHARACTER CODE DEPENDENCY:                                            00372000
*                                                                       00374000
*         NONE.                                                         00376000
*                                                                       00378000
* UPDATE ACTIVITY                                                       00378421
*                                                                       00378821
*        APAR 66517 (INCORRECT POSITIONING)  9/12/73                    00379221
*         APAR 67031  (FLIPPED FROM AND TO )  2/20/74                   00379321
*         APAR 69049 (CAN'T READ FORWARD ONCE TAPE READ BACKWARD) 2/74  00379421
*        APAR 69365 (USER CANCELLED DURING REPOS. -- DDR ATTEMPTS       00379521
*            TO RETRY -- UCBERR FLAG LEFT ON ) 3/74                     00379621
*          PTM 0028                                                     00380021
         SPACE 2                                                        00382000
         TITLE '   IGC0408E - TAPE REPOSITION NUMBER 1 '                00400021
         BALR  BASE,N0                  MODULE BASE REG                 00600021
         USING *,BASE                   MODULE ADDR                     00800021
         USING CVTDSECT,CVTREG          CVT ADDR                        01000021
         USING IORMS,COMMPTR            IORMSCOM ADDR                   01200021
*                                                                       01400021
*        DETERMINE WHY ENTERED.                                         01450000
*                                                                       01500000
         TM    DDRFLGSF,COMPLETE        IS ENTRY AFTER REPOSITIONING    01552000
         BO    CHKOPER                  YES, GO SEE IF THIS IS OP SWAP  01560000
         TM    DDRFLGSB,SWAPMSG         IS ENTRY AFTER SWAP MSG         01600021
         BO    CHKCODE                  YES, SEE IF REPLY WAS VAL  0909 01850000
         TM    DDRFLGSC,REPOSITN        IS ENTRY TO REPOSITION TAPE     02000021
         BO    CHKFILE                  YES, GO REPOSITION TAPE         02200021
         TM    DDRFLGSA,NSLUSER         IS ENTRY FROM AN NSL USER       02400021
         BO    GOLOAD6                  YES, GO TO LOAD 6 AND CHK CODE  02600021
*                                                                       03200021
*        INITIAL ENTRY - DETERMINE IF OPERATOR OR SYSTEM SWAP           03250000
*                                                                       03300000
         TM    DDRFLGSA,OPINIT          IS THIS AN OPERATOR SWAP        03800021
         BZ    GOLOAD6                  NO, GO INIT CTL BLKS WITH 'FROM 04000021
         TM    N34(FMUCB),ASCII    IS TAPE ASCII LABEL            62162 04150021
         BO    PROCTAPE            YES,DDR WILL HANDLE            62162 04160021
         TM    N8(USERDEB),NONSTL  IS TAPE NON STANDARD LABEL     62162 04170021
         BO    PROCTAPE            YES,DDR WILL HANDLE            62162 04180021
         TM    N3(FMUCB),SL        IS TAPE STANDARD LABEL         62162 04190021
         BO    PROCTAPE            YES,DDR WILL HANDLE            62162 04192021
         TM    N8(USERDEB),NEWDISP  IS TAPE NL, DISP=NEW          M5293 04192421
         BO    PROCTAPE            YES, GO HANDLE IT              M5293 04192821
         TM    N8(USERDEB),MODDISP IS TAPE NL,DISP=MOD            62162 04194021
         BO    ENDDDR              YES, CANT HANDLE IT            62162 04196021
PROCTAPE OI    DDRFLGSB,SWAPMSG         FOR SWAP MSG              62162 04200021
*                                                                       04400021
*        PREPARE FOR SWAP MESSAGE                                       04450000
*                                                                       04500000
THISLOAD EQU   *                                                        04600021
         MVI   DDRWORK+N16,LOAD4        FOR RETURN AFTER MSG            04800021
*                                                                       05000021
DDRMSG1  EQU   *                                                        05200021
         MVI   N12(SVRBPTR),MSGMOD1     LOAD NAME FOR XCTL              05400021
*                                                                       07800021
*        THIS SECTION SETS UP FOR ALL XCTL'S                            07850000
*                                                                       07900000
GOXCTL   EQU   *                                                        08000021
        MVC   DDRWORK+N12(N4),LOAD0   COMPLETE MODULE NAMES    @SM0028K 08040021
        MVC   DDRWORK+N17(N3),LOAD0+5                          @SM0028K 08080021
        MVC   N8(N4,SVRBPTR),LOAD0                             @SM0028K 08120021
        MVC   N13(N3,SVRBPTR),LOAD0+5                          @SM0028K 08160021
         SR    WKREG15,WKREG15          ZERO FOR XCTL SET UP            08200021
         ST    WKREG15,N4(SVRBPTR)      ZERO SECOND WORD                08400021
         LA    WKREG15,N8(SVRBPTR)      ADDR OF LOCATION OF LOAD NAME   08600021
         ST    WKREG15,N0(SVRBPTR)      THAT ADDR IN FIRST WORD         08800021
         LR    WKREG15,SVRBPTR          SAVE AREA ADDR INTO PARM REG    09000021
         XCTL SF=(E,(15))                                               09200021
*                                                                       09400021
*        CHECK RETURN CODE FROM IGC2503D AFTER REPLY VALIDATION         09450000
*                                                                       09500000
CHKCODE  EQU   *                                                        09600021
         NI    DDRFLGSB,ALL-SWAPMSG     TURN OFF MSG INDICATOR     0909 09650000
         TM    DDRFLGSA,VALIDATE        IS ENTRY AFTER VALIDATION  0909 09700000
         BZ    CHKNSL                   NO, CHECK FOR NSL TAPE     0909 09760000
*                                                                       09800000
         NI    DDRFLGSA,ALL-VALIDATE    TURN OFF VALIDATION BIT         09850000
         LH    TOUCB,DDRTOUCB           'TO' UCB POINTER                09900000
         LTR   WKREG0,WKREG0            IS RETURN CODE ZERO             09950000
         BZ    CHKNSL                   NO, CHECK FOR NSL TAPE          10010000
*                                                                       10050000
INVALON  EQU   *                                                        10100000
         OI    DDRFLGSB,INVALID+NOTOUCB  FOR INVALID MSG IGF513I        10160000
         B     THISLOAD                 GO PREPARE FOR MSG              10200000
*                                                                       16800021
*        SET UP TO TERMINATE DDR PROCESSING                             16850000
*                                                                       16900000
ENDDDR   EQU   *                                                        17000021
         OI    DDRFLGSB,DDREND          FOR TERMINATE MSG               17200021
         NI    DDRFLGSC,ALL-ERPINPRO    TO ELIMINATE ERP MSG       1079 17250000
*                                                                       17400021
DDRMSG2  EQU   *                                                        17600021
        MVI   DDRWORK+N16,X'F0'                                @SM0028K 17800021
         MVI   N12(SVRBPTR),MSGMOD2     LOAD NAME FOR XCTL              18000021
         B     GOXCTL                   GO PREPARE FOR XCTL             18200021
*                                                                       18400021
*        THIS SECTION CHECKS USER'S SOFTWARE CONFIGURATION TO           18450000
*        DETERMINE IF REPOSITIONING IS POSIBLE.                         18500000
*                                                                       18550000
CHKNSL   EQU   *                                                  41726 18600021
         TM    DDRFLGSC,ERROR           IS REPLY AFTER AN ERROR   42805 18650000
         BO    CHKERR                   YES, GO RESET TAPE DRIVE  59071 18700021
         TM    DDRFLGSD,DUMPTAPE        IS 'FROM' THE DAR DUMP TAPE     18750000
         BO    INITBLKS                 YES, INIT DDR CONTROL BLOCKS    18760000
         TM    N8(USERDEB),NONSTL       IS THIS NSL               41726 18800021
         BZ    CHKOPEN                  NO, SEE IF OPEN IS ACTIVE 41726 19000021
         TM    DDRFLGSA,NSLAVAIL        IS NSL RTNE AVAILABLE     41726 19200021
         BZ    ENDDDR                   NO, GO TERMINATE DDR      41726 19400021
*                                                                       21600021
CHKOPEN  EQU   *                                                        21800021
         TM    N48(USERDCB),IOSUPORT    IS OPEN OR CLOSE OR EOV IN PROC 22000021
         BO    ENDDDR                   YES, GO TERMINATE DDR           22200021
         TM    N42(USERDCB),CNTRL       IS USER USING CNTRL MACRO       22400021
         BO    CHKCOUNT                 YES, GO CHECK COUNT             22600021
         TM    N43(USERDCB),CNTRL       IS USER USING CNGRL MACRO       22800021
         BZ    CHKEXCP                  NO,IS USER USING EXCP           22850021
CHKCOUNT SR    WKREG15,WKREG15          CLEAR REG                       23200021
         C     WKREG15,N12(USERDCB)     IS USER BLOCK COUNT ZERO        23400021
         BE    ENDDDR                   YES, GO TERMINATE DDR           23600021
*                                                                       23650021
CHKEXCP  EQU   *                                                        23700021
         L     USERDCB,USRDCB      RE-INIT USER'S DCB PTR               23710021
         TM    N42(USERDCB),EXCPUSR     IS USER USING EXCP              23750021
         BO    CHKBLKCT                 YES,CHECK FOR ZERO BLK-CT       23760021
         TM    N61(USERDCB),CFEOV       NO,IS CLOSE/FEOV ACTIV    53388 23770021
         BO    ENDDDR                   YES,END DDR               53388 23780021
         B     INITBLKS                 NO,INITIALIZE DDR CTRL BLKS     23790021
*                                                                       23792021
CHKBLKCT EQU   *                                                        23794021
         TM    N42(USERDCB),BLKCT       DID USER INDICATE GOOD BLK-CT   23796021
         BZ    ENDDDR                   NO,END DDR                      23798021
*                                                                       23800021
*        INITIALIZE DDR'S CONTROL BLOCKS FOR IO                         23850000
*                                                                       23900000
INITBLKS EQU   *                                                        24000021
         TM    DDRFLGSA,OPINIT          IS THIS AN OPERATOR SWAP        24200021
         BO    INITTO                   YES, GO INIT CTL BLKS W/'FROM'  24400021
         TM    DDRFLGSF,LABELERR        WAS ERROR DURING LABEL PROC     24600021
         BZ    CHKERR                   NO, SEE IF ERROR DURING REPOS   24800021
         NI    DDRFLGSF,ALL-LABELERR    TURN OFF ERROR INDICATOR        25000021
         B     INITTO                   GO INIT CTL BLOCKS WITH 'TO'    25200021
*                                                                       25400021
CHKERR   EQU   *                                                        25600021
         TM    DDRFLGSC,ERROR           WAS ERROR DURING REPOS          25800021
         BZ    INITFM                   NO GO INIT BLKS WITH 'FROM'     26000021
         NI    DDRFLGSC,ALL-ERROR       TURN OFF ERROR INDICATOR        26200021
*                                                                       26400021
INITTO   EQU   *                                                        26600021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     26800021
         L     OURDEB,N8(RQEPTR)        DDR DEB PTR                     26850000
         MVC   N32(N1,OURDEB),N32(USERDEB) USER'S MODE SET INTO DDR DEB 27000021
         MVI   N28(OURDEB),EXTENT       EXTENT SCALE INTO DDR DEB       27200021
         STH   TOUCB,N2(RQEPTR)         'TO' UCB PTR INTO RQE           27400021
         STH   TOUCB,N34(OURDEB)        'TO' UCB PTR INTO DEB           27600021
*                                                                       27800021
*        REWIND - UNLOAD 'TO' AND 'FROM' TAPES                          27850000
*                                                                       27900000
IOTAPE   EQU   *                                                        28000021
         LA    OURDCB,DDRDCB            DDR'S DCB PTR                   28200021
         XC    N12(N4,OURDCB),N12(OURDCB) CLEAR DDR BLOCK COUNT         28400021
         LA    WKREG14,DDRWORK+N16      ADDR OF BUFFER AREA             28600021
         ST    WKREG14,RUNCCW           THAT ADDR INTO CCW              28800021
         MVI   RUNCCW,RUN               REWIND-UNLOAD COMMAND           29000021
         MVC   DDRWORK(N16),RUNCCW      CCW INTO DDRWORK                29200021
         OI    DDRFLGSB,FIRSTIO         FOR FIRST IO IN GAINING CTL     29400021
*                                                                       29600021
NOCTRL   EQU   *                                                        29800021
         OI    DDRFLGSC,IONOCTRL        TO RE-EXCP WITHOUT CONTROL      30000021
*                                                                       30200021
         BAL   WKREG14,IOSETUP          GO SET UP FOR ERROR EXCP        30400021
*                                                                       30600021
         TM    DDRFLGSF,OPCANCEL        IS OPERATOR SWAP CANCELED  1030 30650000
         BZ    TESTERR                  NO, SEE IF ERROR OCCURRED  1030 30700000
         OI    DDRFLGSC,CANCEL          FOR CANCEL MSG             1030 30750000
         B     DDRMSG2                  GO ISSUE MSG               1030 30760000
*                                                                       30770000
TESTERR  EQU   *                                                        30780000
         TM    DDRFLGSC,ERROR           DID PERM ERROR OCCUR            30800021
         BZ    TSTFIRST                 NO, SEE IF THIS WAS IO TO FIRST 31000021
         NI    DDRFLGSC,ALL-ERROR       TURN OFF ERROR INDICATOR        31200021
         TM    DDRFLGSB,FIRSTIO         DID ERROR OCCUR ON 'TO' DEVICE  31400021
         BZ    ENDDDR                   NO, GO TERMINATE DDR            31600021
         NI    N6(TOUCB),ALL-UCBERR     FREE INVALID DEVICE   JE A64640 31650021
         B     INVALON                  YES, GO PREPARE FOR INVALID MSG 31800021
*                                                                       32000021
TSTFIRST EQU   *                                                        32200021
         TM    DDRFLGSB,FIRSTIO         WAS IO ON 'TO' DEVICE           32400021
         BZ    SWAPTHEM                 NO, PREPARE TO SWAP UCB INFO    32600021
         NI    DDRFLGSB,ALL-FIRSTIO     TURN OFF IO INDICATOR           32800021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     32850000
         STH   FMUCB,N2(RQEPTR)         'FROM' UCB PTR INTO RQE         32900000
         STH   FMUCB,N34(OURDEB)        'FROM' UCB PTR INTO DEB         32950000
         B     NOCTRL                  GO PREPARE FOR I/O         51738 32952021
*                                                                       32954021
*                                                                       32960000
*        THIS SECTION SETS UP THE CALLING SEQUENCE TO             21048 32970000
*        RECORD SENSE DATA VIA SVC 91.                            21048 32980000
*        AND SWAP THE UCB INFO                                          32982021
*                                                                       32990000
SWAPTHEM EQU   *                                                        32992021
         LA    OURDCB,DDRDCB      DDR DCB PTR                     53388 32994021
         LR    WKREG0,OURDCB            DDR DCB PTR INTO REG 0    21048 33000021
         LA    RQEPTR,N50               DDR INDICATOR INTO REG 1  21048 33200021
         SVC   91                       GO RECORD                 21048 33250000
*                                                                       34400021
*        PREPARE TO GO TO IOS TO SWAP THE USB INFORMATION               34450000
*                                                                       34500000
         NI    DDRFLGSC,ALL-ERROR       TURN OFF ERROR INDICATOR  42805 34650000
          TM    DDRFLGSC,ERPINPRO   IS ERP IN PROGRESS                  34750021
          BO    DDRMSG2             YES. GO PREPARE FOR MESSAGE         34850021
         OI    DDRFLGSF,DDRCNTRL        TO INDICATE CONTRL OF UCB  1030 35100000
         OI    DDRFLGSC,SWAPUCB         TO SWAP UCB INFO                35200021
         MVC   DDRWORK(N8),NOPCCW       NO-OP CCW INTO WORK AREA        35600021
         BAL   WKREG14,IOSETUP          GO SET UP FOR ERROR EXCP        35650000
*                                                                       36400021
         NI    DDRFLGSC,ALL-SWAPUCB     TURN OFF SWAP UCB INFO BIT      36600021
          TM    DDRFLGSC,ERPINPRO   IS ERP IN PROGRESS            67031 36660021
          BO    DDRMSG2             YES. GO PREPARE FOR MESSAGE   67031 36720021
         OI    DDRFLGSB,PROCEED         FOR PROCEED MSG IGF502E         36800021
         MVI   DDRWORK+N16,LOAD6        FOR CONTROL AFTER MSG           37000021
         B     DDRMSG1                  GO PREPARE FOR MSG AND XCTL     37200021
*                                                                       37400021
INITFM   EQU   *                                                        37600021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     37800021
         STH   FMUCB,N2(RQEPTR)         'FROM' UCB PTR INTO RQE         38000021
         STH   FMUCB,N34(OURDEB)        'FROM' UCB PTR INTO DEB         38200021
*                                                                       38400021
GOLOAD6  EQU   *                                                        38600021
         MVI   N12(SVRBPTR),LOAD6       LOAD NAME FOR XCTL              38800021
         B     GOXCTL                   GO PREPARE FOR XCTL             39000021
*                                                                       39200021
*        THIS SECTION INITIALIZES FOR REPOSITIONING BY FINDING THE      39250000
*        FILE COUNT IN THE UCB AND THE BLOCK COUNT IN THE USER'S DCB.   39300000
*                                                                       39350000
CHKFILE  EQU   *                                                        39400021
         NI    DDRFLGSC,ALL-REPOSITN    TURN OFF REPOSITION INDICATOR   39600021
         MVC   N32(N1,OURDEB),N32(USERDEB) RESET USER'S MODE SET  39961 39800021
         L     USERDCB,USRDCB           USER'S DCB PTR                  40000021
         TM    N12(USERDCB),NEGBLK      IS BLOCK COUNT NEGATIVE         40200021
         BZ    INCRMNT1                 NO, GO INIT. INCREMENT CNT TO 1 40400021
         MVC   N28(N2,OURIOB),NEGONE    PUT -1 INTO INCREMENT FIELD     40600021
         B     CHKREAD                  GO SEE IF RECORD IS TO BE READ  40800021
*                                                                       41000021
INCRMNT1 EQU   *                                                        41200021
         LA    WKREG0,N1                FOR IOB INCREMENT               41400021
          STH   WKREG0,N28(OURIOB)  INIT INCR. COUNT TO ONE       69049 41600021
*                                                                       41800021
CHKREAD  EQU   *                                                        42000021
         TM    DDRFLGSD,READ            IS RECORD TO BE READ            42200021
         BO    READIO                   YES, GO READ A RECORD           42400021
         MVC   DDRWORK(N8),RUNCCW       CCW INTO DDRWORK                42800021
         MVI   DDRWORK+N4,SUPRESS       TURN ON SILLY BIT               43000021
         LA    WKREG0,N16(SVRBPTR)      ADDR OF BUFFER FOR IO           43200021
         ST    WKREG0,DDRWORK           BUFFER ADDR INTO CCW            43400021
         TM    DDRFLGSD,UNLABELD        IS TAPE UNLABELED               43600021
         BZ    CHKSTD                   NO, GO SEE IF IT'S STD LABEL    43800021
*                                                                       44000021
         TM    N12(USERDCB),NEGBLK      IS USER BLOCK COUNT NEGATIVE    44200021
         BZ    INITONE                  NO, GO INIT COUNT TO 1          44400021
         XC    FILECNT(N2),FILECNT      INIT FILE COUNT TO ZERO         44600021
         B     COMPFILE                 NO COMPARE FILE                 44800021
*                                                                       45000021
CHKSTD   EQU   *                                                        45200021
         TM    DDRFLGSD,STDLABEL        IS TAPE STANDARD LABEL          45400021
         BZ    INITONE                  NO, GO INIT COUNT TO 1          45600021
         LH    WKREG15,N36(FMUCB)       FILE COUNT FROM UCB       63472 45800021
         N     WKREG15,ZEROHIGH         CLEAR 2 HIGH ORDER BYTES        46000021
         LR    WKREG14,WKREG15          SAVE FILE COUNT                 46200021
         LA    WKREG0,N1                TO CALCULATE NUMBER OF SKIPS    46400021
         SR    WKREG14,WKREG0           SUBTRACT 1 FROM FILE COUNT      46600021
         BZ    INITONE                  YES, GO INIT FILE COUNT TO 1    47000021
         MH    WKREG14,THREE            MULTIPLY REMAINDER BY 3         47200021
         SR    WKREG14,WKREG15          SUBTRACT FILE CNT FROM REMAINDR 47400021
         LNR   WKREG14,WKREG14          NEGATE FOR NUMBER OF DDR SKIPS  47600021
         STH   WKREG14,FILECNT          NOW HAVE NUMBER OF SKIP FILES   47800021
         B     COMPFILE                 GO FORWARD SPACE FILE           48000021
*                                                                       48200021
INITONE  EQU   *                                                        48400021
         LA    WKREG0,N1                TO INIT FILE COUNT              48600021
         STH   WKREG0,FILECNT           INIT FILE COUNT TO 1            48800021
*                                                                       49000021
COMPFILE EQU   *                                                        49200021
         CLC   N36(N2,FMUCB),FILECNT    ARE FILE COUNTS EQUAL     63472 49400021
         BE    READON                   YES, GO PREPARE TO READ         49600021
         OI    DDRFLGSD,FORSPACE        TO INDICATE FSF                 49800021
         MVI   DDRWORK,FORFILE          FORWARD SPACE FILE COMMAND      50000021
         B     IO                       GO DO IO                        50200021
*                                                                       50400021
READON   EQU   *                                                        50600021
         OI    DDRFLGSD,READ            TO INDICATE READ A RECORD       50800021
READIO   EQU   *                                                        51000021
         MVI   DDRWORK,READDATA         READ COMMAND                    51200021
         LA    WKREG0,N1                TO INIT BLOCK COUNT             51250000
         TM    DDRFLGSF,NEGCOUNT        IS COUNT TO BE -1               51300000
         BZ    INITZERO                 NO, INIT COUNT TO ZERO          51350000
         LNR   WKREG0,WKREG0            NEGATIVE 1 FOR INITIALIZATION   51360000
         ST    WKREG0,DDRDCB+N12        INIT BLK COUNT TO -1            51370000
         B     IO                       GO DO IO                        51380000
*                                                                       51390000
INITZERO EQU   *                                                        51392000
         XC    DDRDCB+N12(N4),DDRDCB+N12 CLEAR DDR BLOCK COUNT          51400021
         TM    DDRFLGSA,OPINIT          IS THIS OPERATOR SWAP           51600021
         BO    IO                       YES, COUNT IS INIT TO ZERO.     51800021
         LH    RQEPTR,USRRQE       GET USER RQE                   66517 51880021
         L     OURIOB,N4(RQEPTR)   GET USER IOB                   66517 51960021
         TM    N12(OURIOB),DEVICEND  DEVICE END PRESENT           66517 52040021
         BZ    IO                  NO, INIT COUNT TO ZERO         66517 52120021
         ST    WKREG0,DDRDCB+N12        INIT DDR BLK COUNT TO ONE       52200021
*                                                                       52400021
IO       EQU   *                                                        52600021
         BAL   WKREG14,IOSETUP          GO DO IO                        52800021
*                                                                       53000021
*        AT THIS POINT EITHER REPOSITIONING IS COMPLETE OR THERE WAS    53050000
*        A PERMANENT IO ERROR DURING REPOSITIONING. IF IT WAS COMPLETE  53100000
*        CONTROL WILL GO TO THE MESSAGE MODULE FOR THE COMPLETE MSG.    53150000
*        FOR SYSTEM SWAPS, THE FAILING RQE WOULD BE RETRIED.            53160000
*        IF THERE WAS AN ERROR, THE TAPE WILL BE REWOUND-UNLOADED AND   53170000
*        CONTROL WILL GO TO THE MESSAGE MODULE FOR A NEW DEVICE OR      53180000
*        CANCELLATION OF THE SWAP.                                      53190000
*                                                                       53192000
         TM    DDRFLGSC,ERROR           WAS THERE PERM ERROR            53200021
         BO    ERRORRUN                 YES, GO RUN FOR ERROR           53400021
         TM    DDRFLGSC,ERPINPRO        IS USER DCB BAD            1079 53410000
         BO    ENDDDR                   YES, TERMINATE             1079 53420000
*                                                                       53450000
CHKOPER  EQU   *                                                        53500000
         TM    DDRFLGSA,OPINIT          IS THIS OPERATOR SWAP           53600021
         BZ    RETRYIT                  NO, GO PREPARE TO RETRY USER    53800021
*                                                                       54000021
CMPLETIT EQU   *                                                        54200021
         OI    DDRFLGSF,COMPLETE        FOR COMPLETED MSG IGF505I       54400021
         B     DDRMSG2                  GO PREPARE FOR MSG AND XCTL     54600021
*                                                                       54800021
RETRYIT  EQU   *                                                        55000021
         NI    DDRFLGSF,ALL-COMPLETE    RESET FLAG                69365 55030021
         TM    DDRFLGSG,WTQPURGD        WAS WAIT Q PURGED         69365 55060021
*                                       DURING REPOSITIONING      69365 55090021
         BO    ENDDDR                   YES - TERMINATE SWAP      69365 55120021
CONRTRY  EQU   *                                                        55150021
         OI    DDRFLGSE,RETRY           TO INDICATE RETRY USER          55200021
         NI    DDRFLGSD,ALL-READ        TURN OFF READ INDICATOR         55400021
         MVI   DDRWORK,NOOP             NO-OP COMMAND INTO CCW          55600021
         BAL   WKREG14,IOSETUP          GO SET UP FOR ERROR EXCP        55810000
         B     CMPLETIT                 GO PREPARE FOR COMPLETE MSG     56600021
*                                                                       56800021
ERRORRUN EQU   *                                                        57000021
         NI    DDRFLGSD,ALL-READ        TURN OFF READ INIDICATOR        57050000
         MVC   DDRWORK(N16),RUNCCW      CCW INTO WORK AREA              57350000
         OI    DDRFLGSD,IOCONTRL        TO RE-EXCP WITH CONTROL         57400021
         BAL   WKREG14,IOSETUP          GO DO IO                        57600021
         B     THISLOAD                 GO PREPARE FOR XCTL             57800021
*                                                                       58000021
*        INITIALIZATION FOR DDR/IOS INTERFACE                           58050000
*                                                                       58100000
IOSETUP  EQU   *                                                        58200021
         SSM   DISABLE                                                  58400021
         LH    RQEPTR,OURRQE            DDR RQE PTR                     58600021
         L     OURIOB,N4(RQEPTR)        DDR IOB PTR                     58650000
         MVI   IOSECB,ZERO              CLEAR IOS ECB                   58800021
         XC    N9(N7,OURIOB),N9(OURIOB) CLEAR STATUS                    59000021
         MVI   N0(OURIOB),UNRLTD        UNRELATED BIT IN IOB FLAGS 1    59200021
         SVC   ERREXCP                  SVC 15                          59400021
         TM    DDRFLGSC,SWAPUCB         IS SVC 15 TO SWAP UCB INFO      59450000
         BCR   N1,WKREG14               YES, RETURN TO MAINLINE         59500000
         TM    DDRFLGSE,RETRY           IS SVC 15 TO RETRY FAILING RQE  59550000
         BCR   N1,WKREG14               YES, RETURN TO MAINLINE         59560000
         WAIT  ECB=IOSECB               WAIT FOR IO TO COMPLETE         59600021
*                                                                       59800021
         SSM   DISABLE                                                  60000021
         BR    WKREG14                  RETURN TO MAINLINE CODE         60200021
*                                                                       60400021
***      REGISTER EQUATES                                               60600021
*                                                                       60800021
WKREG0   EQU   0                        WORK REGISTER                   61000021
RQEPTR   EQU   1                        RQE PTR                         61200021
WQPTR    EQU   2                        WAIT Q PTR                      61300021
CVTREG   EQU   3                        CVT PTR                         61400021
OURDCB   EQU   4                        DDR DCB PTR                     61600021
SVRBPTR  EQU   5                        EXTENDED SAVE AREA PTR          61800021
USERDEB  EQU   6                        USER DEB PTR                    62000021
FMUCB    EQU   7                        'FROM' UCB PTR                  62200021
TOUCB    EQU   8                        'TO' UCB PTR                    62400021
USERDCB  EQU   9                        USER DCB PTR                    62600021
OURDEB   EQU   10                       DDR DEB PTR                     62800021
COMMPTR  EQU   11                       IORMSCOM PTR                    63000021
BASE     EQU   12                       MODULE BASE REGISTER            63200021
OURIOB   EQU   13                       DDR IOB PTR                     63400021
WKREG14  EQU   14                       WORK REGISTER                   63600021
WKREG15  EQU   15                       WORK REGISTER                   63800021
         SPACE 3                                                        64000021
*                                                                       64200021
***      INTEGER EQUATES                                                64400021
*                                                                       64600021
N0       EQU   0                        DISPLACEMENT VALUE              64800021
N1       EQU   1                        DISPLACEMENT VALUE              65000021
N2       EQU   2                        DISPLACEMENT VALUE              65200021
N3       EQU   3                        DISPLACEMENT VALUE              65400021
N4       EQU   4                        DISPLACEMENT VALUE              65600021
N6       EQU   6                                                        65700021
N7       EQU   7                        DISPLACEMENT VALUE              65800021
N8       EQU   8                        DISPLACEMENT VALUE              66000021
N9       EQU   9                        DISPLACEMENT VALUE              66200021
N12      EQU   12                       DISPLACEMENT VALUE              66400021
N13     EQU   13                                                        66460021
N17     EQU   17                                                        66520021
N16      EQU   16                       DISPLACEMENT VALUE              66600021
N24      EQU   24                       DISPLACEMENT VALUE              66800021
N28      EQU   28                       DISPLACEMENT VALUE              67000021
N29      EQU   29                       DISPLACEMENT VALUE              67200021
N32      EQU   32                       DISPLACEMENT VALUE              67400021
N34      EQU   34                       DISPLACEMENT VALUE              67600021
N36      EQU   36                  DISPLACEMENT VALUE             63472 67650021
N38      EQU   38                       DISPLACEMENT VALUE              67800021
N42      EQU   42                       DISPLACEMENT VALUE              68000021
N43      EQU   43                       DISPLACEMENT VALUE              68200021
N48      EQU   48                       DISPLACEMENT VALUE              68400021
N50      EQU   50                       DISPLACEMENT VALUE              68600021
N61      EQU   61      DCB DISP FOR CFEOV FLAGS                         68650021
N116     EQU   116                      DISPLACEMENT CONSTANT           68800021
         SPACE 3                                                        69000021
*                                                                       69200021
***      GENERAL EQUATES                                                69400021
*                                                                       69600021
ALL      EQU   X'FF'                    MASK FOR 'AND' INSTRUCTIONS     69800021
BLKCT    EQU   X'04'                    BIT IN USER DCB FOR VALID BLKCT 70000021
CNTRL    EQU   X'02'                    BIT INDICATING USE OF CONTROL   70200021
EXCPUSR  EQU   X'80'                    BIT IN USER DCB FOR EXCP        70400021
CFEOV    EQU   X'22'   CLOSE/FEOV FLAGS IN DCB                          70450021
EXTENT   EQU   X'02'                    DDR DEB EXTENT                  70600021
FORFILE  EQU   X'3F'                    COMMAND TO FORWARD SPACE FILE   70800021
IOSUPORT EQU   X'01'                    BIT IN DCB FOR OPEN,CLOSE,EOV   71000021
NEGBLK   EQU   X'80'                    MASK FOR NEGATIVE INCREMENT     71200021
NONSTL   EQU   X'02'                    NON-STANDARD LABEL INDICATOR    71250000
NOOP     EQU   X'03'                    COMMAND TO NO-OP                71400021
READDATA EQU   X'02'                    COMMAND TO READ                 71600021
RUN      EQU   X'0F'                    COMMAND TO REWIND-UNLOAD        71800021
SUPRESS  EQU   X'20'                    TO SUPRESS WRONG LENGTH RECORDS 72000021
UNRLTD   EQU   X'02'                    UNRELATED BIT IN IOB FLAGS 1    72200021
ZERO     EQU   X'00'                    ZERO MASK                       72400021
SL       EQU   X'01'               STANDARD LABEL INDICATOR       62162 72450021
ASCII    EQU   X'04'               ASCII LABEL INDICATOR          62162 72500021
MODDISP  EQU   X'80'               DISP=MOD DEB INDICATOR         62162 72550021
NEWDISP  EQU   X'C0'               DISP=NEW DEB INDICATOR         M5293 72560021
ERREXCP  EQU   15                       ERROR EXCP - SVC 15             72600021
UCBERR   EQU   X'01'               UCB ERROR MASK             JE A64640 72650021
DEVICEND EQU   X'04'               DEVICE END INDICATOR           66517 72720021
PURGE    EQU   X'80'                    PURGE IND.,WT. Q                72760021
         SPACE 3                                                        72800021
*                                                                       73000021
***      CHANNEL PROGRAMS AND DEFINED CONSTANTS                         73200021
*                                                                       73400021
         DS    0D                       DOUBLE WORD BOUNDRY             73600021
RUNCCW   DC    X'0F'                    REWIND-UNLOAD COMMAND           73800021
         DC    X'000000'                BUFFER ADDR. FIELD              74000021
         DC    X'60'                    COMMAND CHAINING & SILLY BIT    74200021
         DC    X'00000C'                LENGTH                          74400021
NOPCCW   DC    X'03'                    NO-OP COMMAND                   74600021
         DC    X'000000'                BUFFER ADDR FIELD               74800021
         DC    X'20'                    SUPRESS WRONG LENGTH            75000021
         DC    X'00000C'                LENGTH                          75200021
ZEROHIGH DC    X'0000FFFF'              MASK TO CLEAR 2 HIGH ORDER BYTS 75600021
LOAD0    DC    C'IGC0008E'              INITIATOR/TERMINATOR MODULE     75800021
LOAD4    EQU   X'F4'                    THIS MODULE                     76000021
LOAD6    EQU   X'F6'                    TAPE DDR MODULE #2              76200021
MSGMOD1  EQU   X'F5'                    MSG MODULE #1                   76400021
MSGMOD2  EQU   X'F8'                    MSG MODULE #2                   76600021
NEGONE   DC    X'FFFF'                  NEG. ONE FOR IOB INCREMENT      77000021
THREE    DC    H'3'                     CONSTANT                        77200021
DISABLE  DC    X'00'                                                    77800021
MAINT   DC    50X'40'                                                   77900021
*                                                                       77950000
*                                                                       77960000
CVTDSECT DSECT                                                          78000021
         CVT                                                            78200021
*                                                                       78250000
*                                                                       78300000
         IORMSCOM                                                       78400021
*/*IGC0408E:      CHART                                              */ 78401000
*/*IGC0408E:      E IGC0408E                                         */ 78402000
*/*               P ESTABLISH ALL ADDRESSABILITY                     */ 78403000
*/*               D (NO,,YES,CHKREPLY) IS ENTRY AFTER SWAP MSG ?     */ 78404000
*/*               D (NO,,YES,CHKFILE) IS ENTRY AFTER TAPE REPO. ?    */ 78405000
*/*               D (NO,,YES,GOLOAD6) IS THE NSLUSER BIT ON ?        */ 78406000
*/*               D (NO,,YES,CHKCODE)  ENTRY AFTER TAPE VALIDATION ? */ 78407000
*/*               P ZERO DDRFLGSB IN IORMSCOM                        */ 78409000
*/*               D (YES,,NO,GOLOAD6) IS THIS AN OPINIT SWAP ?       */ 78410000
*/*               P TURN THE SWAP MSG BIT ON                         */ 78411000
*/*THISLOAD:      P PUT IGC0408E @ IN DDRWORK + 12 (RETURN AFTER XCTL)  78412000
*/*                                                                  */ 78413000
*/*DDRMSG1:       P SET IGC0508E @  UP FOR XCTL                      */ 78414000
*/*GOXCTL:        L () - XCTL -                                      */ 78415000
*/*CHKREPLY:      P TURN SWAPMSG BIT OFF                             */ 78416000
*/*               D (NO,,YES,ENDDDR) IS REPLY 'NO' ?                 */ 78417000
*/*               D (NO,,YES,GETTCB) IS REPLY 'YES' ?                */ 78418000
*/*               P TURN VALIDATE BIT ON                             */ 78419000
*/*               P (,GOXCTL) SET IGC2503D @ UP FOR XCTL ?           */ 78420000
*/*GETTCB:        D (NO,,YES,INVALON) IS THE ERROR BIT ON ?          */ 78421000
*/*               D (NO,,YES,INITBLKS) IS 'FROM' DEV. DUMP TAPE ?    */ 78422000
*/*               P GET TCB @ (FOUND IN CVTHEAD)                     */ 78423000
*/*GETDEB:        P GET DEBQUE ADDRESS                               */ 78424000
*/*               D (NO,,YES,NEXTTCB) IS THIS ADDRESS ZERO ?         */ 78425000
*/*COMPUCB:       D (NO,,YES,CHKEXCP) DDRFMUCB @ = DEBUCB @ ?        */ 78426000
*/*               P GET NEXT DEB ADDRESS                             */ 78427000
*/*               D (NO,COMPUCB,YES,NEXTTCB) IS THIS ADDRESS ZERO ?  */ 78428000
*/*NEXTTCB:       P GET NEXT TCB ADDRESS                             */ 78429000
*/*               D (YES,,NO,GETDEB) IS THIS ADDRESS ZERO ?          */ 78430000
*/*ENDDDR:        P TURN THE DDREND BIT ON                           */ 78431000
*/*DDRMSG2:       P PUT IGC0008E @ IN DDRWORK + 12 (RETURN AFTER XCTL)  78432000
*/*                                                                  */ 78433000
*/*               P (,GOXCTL) SET IGC0808E @ UP FOR XCTL             */ 78434000
*/*INITFM:        P PLACE 'FROM' UCB POINTER IN RQE AND DEB          */ 78435000
*/*GOLOAD6:       P (,GOXCTL:BB) SET IGC0608E @ UP FOR XCTL          */ 78436000
*/*CHKCODE:       P TURN VALIDATE BIT OFF                            */ 78437000
*/*               D (NO,,YES,GETTCB) IS THE RETURN CODE ZERO ?       */ 78438000
*/*INVALON:       P (,THISLOAD) TURN INVALID BIT ON                  */ 78439000
*/*CHKEXCP:       P SAVE USER TCB AND DCB @'S IN IORMSCOM            */ 78440000
*/*               D (YES,,NO,CHKOPEN) IS USER AT EXCP LEVEL ?        */ 78441000
*/*               D (YES,,NO,ENDDDR) IS 'GOOD BLKCOUNT' BIT ON ?     */ 78442000
*/*CHKOPEN:       D (NO,,YES,ENDDDR) IS OPEN CLOSE OR EOV IN PROCESS */ 78443000
*/*               D (YES,,NO,INITBLKS) IS USER USING CNTRL MACRO ?   */ 78444000
*/*               D (NO,,YES,ENDDDR) IS USER BLKCOUNT ZERO ?         */ 78445000
*/*INITBLKS:      D (NO,,YES,INITTO) OP INIT SWAP ?                  */ 78446000
*/*               D (YES,,NO,CHKERR)  ERROR  WHILE PROCESSING LABEL  */ 78447000
*/*               P (,INITTO) TURN LABELERR BIT OFF                  */ 78449000
*/*CHKERR:        D (YES,,NO,INITFM) WAS ERROR DURING TAPE REPO. ?   */ 78450000
*/*               P TURN ERROR INDICATOR OFF                         */ 78451000
*/*INITTO:        P INITIALIZE DDR CONTROL BLOCKS WITH 'TO' UCB      */ 78452000
*/*IOTAPE:        P SET CCW UP FOR REWIND AND UNLOAD                 */ 78453000
*/*               P TURN FIRSTIO BIT ON                              */ 78454000
*/*NOCTRL:        P TURN IONCTRL BIT ON                              */ 78455000
*/*               L - SVC 91 -                                       */ 78456000
*/*               S -IOSETUP-: SET UP FOR ERREXCP                    */ 78457000
*/*               D (YES,,NO,TSTFIRST) IS ERROR BIT ON ?             */ 78458000
*/*               P TURN ERROR BIT OFF                               */ 78459000
*/*               D (NO,ENDDDR,YES,INVALON) IS FIRSTIO BIT ON ?      */ 78460000
*/*TSTFIRST:      D (YES,,NO,SWAPTHEM) IS FIRSTIO BIT ON ?           */ 78461000
*/*               P TURN FIRSTIO BIT OFF                             */ 78462000
*/*               P (,NOCTRL) INITIALIZE DDR CONTROL BLOCKS WITH 'FROM' 78463000
*/*                 UCB                                              */ 78464000
*/*SWAPTHEM:      D (NO,,YES,DDRMSG2) IS ERP IN PROGRESS ?           */ 78465000
*/*               P TURN SWAPUCB BIT ON                              */ 78466000
*/*               L - SVC 15 - ERREXCP                               */ 78467000
*/*               P TURN SWAPUCB BIT OFF, PROCEED BIT ON             */ 78468000
*/*               P (,DDRMSG1) PUT IGC0608E IN DDRWORK + 12 (RETURN     78469000
*/*                 AFTER XCTL)                                      */ 78470000
*/*CHKFILE:       P TURN REPOSITION BIT ON                           */ 78471000
*/*               P RESET USER'S MODESET IN DEB                      */ 78472000
*/*               D (NO,INCRMNT1,YES,) IS BLOCKCOUNT NEG ?           */ 78473000
*/*               P (,CHKREAD:RT) SET IOB INCREMENT COUNT TO -1      */ 78474000
*/*INCRMNT1:      P ADD 1 TO IOB INCREMENT COUNT                     */ 78475000
*/*CHKREAD:       D (NO,,YES,READIO) IS RECORD TO BE READ ?          */ 78476000
*/*               P SET CCW UP FOR REWIND AND UNLOAD (SLI BIT ON)    */ 78477000
*/*               D (YES,,NO,CHKSTD) IS UNLABEL. TAPE BIT ON ?       */ 78478000
*/*               D (YES,,NO,INITONE) IS USER BLKCNT NEG. ?          */ 78479000
*/*               P (,COMPFILE) INIT. DDR FILE COUNT TO ZERO         */ 78480000
*/*CHKSTD:        D (YES,,NO,INITONE) IS TAPE STD. LABEL ?           */ 78481000
*/*               P GET USER FILE COUNT FROM UCB AND SUBTRACT 1      */ 78482000
*/*               D (NO,,YES,INITONE) IS REMAINDER ZERO ?            */ 78483000
*/*               P COMPUTE NUMBER OF FILES TO BE FRWD. SPACED       */ 78484000
*/*               P (,COMPFILE) SAVE NUMBER IN FILECNT FIELD IN         78485000
*/*                 IORMSCOM                                         */ 78486000
*/*INITONE:       P SET DDR FILECNT TO 1                             */ 78487000
*/*COMPFILE:      D (NO,,YES,READON) DDRFILECNT = USERFILECNT        */ 78488000
*/*               P TURN FWDSPACE BIT ON                             */ 78489000
*/*               P SET CCW UP FOR FSF                               */ 78490000
*/*IO:            S -IOSETUP-: SET UP FOR ERREXCP                    */ 78491000
*/*               D (NO,,YES,ERRORRUN) IS ERROR BIT ON ?             */ 78492000
*/*               D (YES,,NO,RETRYIT) OP. INIT. SWAP ?               */ 78493000
*/*CMPLETIT:      P (,DDRMSG2) TURN COMPLETE BIT ON                  */ 78494000
*/*RETRYIT:       P TURN RETRY BIT ON, READ BIT OFF                  */ 78495000
*/*               P SET CCW UP FOR NOOP                              */ 78496000
*/*               P CLEAR STATUS AND UNRELATED BITS IN IOB           */ 78497000
*/*               L (,CMPLETIT) - SVC 15 - ERREXCP                   */ 78498000
*/*READON:        P TURN READ BIT ON                                 */ 78499000
*/*READIO:        P SET CCW UP FOR READ COMMAND                      */ 78500000
*/*               P CLEAR DDR BLKCOUNT FIELD                         */ 78501000
*/*               D (NO,,YES,IO) OP. INIT. SWAP ?                    */ 78502000
*/*               P (,IO) INIT. DDR BLKCNT TO ONE                    */ 78503000
*/*ERRORRUN:      P SET CCW UP FOR REWIND AND UNLOAD                 */ 78504000
*/*               P TURN IONOCTRL BIT ON                             */ 78505000
*/*               S -IOSETUP-: SET UP FOR ERREXCP                    */ 78506000
*/*               L (,THISLOAD) - WAIT -                             */ 78507000
*/*IOSETUP:       E ENTRY                                            */ 78508000
*/*               L - MODESET - DISSABLE INTERRUPTS                  */ 78509000
*/*               P CLEAR IOSECB, STATUS FLAGS IN IOB                */ 78510000
*/*               L - SVC 15 - ERREXCP                               */ 78511000
*/*               L - WAIT -                                         */ 78512000
*/*               L - MODESET - DISSABLE INTERRUPTS                  */ 78513000
*/*               R RETURN TO MAINLINE VIA R14                       */ 78514000
*/*IGC0408E:      END                                                */ 78515000
         END                                                            78600021
