IGC0608E CSECT                                                          00300021
*******************************************************************     00303021
*                                                                       00306021
* STATUS:                                                               00309021
*                                                                       00312021
*    RELEASE 21.8                                                       00315021
*                                                                       00318021
*                                                                       00321021
* FUNCTION:                                                             00324021
*                                                                       00327021
*    THIS MODULE PERFORMS TAPE LABEL VERIFICATION FOR THE TAPE TO BE    00330021
*    REPOSITIONED. PROCESSING IS DONE FOR STANDARD LABELS, NON-STANDARD 00333021
*    LABELS AND ASCII LABELS. FOR STANDARD LABELS AND ASCII LABELS, THE 00336021
*    LABEL ON THE TAPE IS READ AND COMPARED TO THE VOLUME ID IN THE     00339021
*    UCB. FOR NON-STANDARD LABELS, THE LABEL IS READ AND CONTROL IS     00342021
*    PASSED TO 'NSLREPOS', A USER WRITTEN ROUTINE TO VERIFY THE LABEL.  00345021
*    IF THE LABEL IS INCORRECT, THE WRONG VOLUME MESSAGE IS ISSUED AND  00348021
*    THE TAPE IS REWOUND AND UNLOADED. WHEN THE LABEL IS VERIFIED,      00351021
*    CONTROL IS PASSED TO IGC0408E FOR REPOSITIONING.                   00354021
*                                                                       00357021
*                                                                       00360021
* ENTRY POINT:                                                          00363021
*                                                                       00366021
*         IGC0608E - FIRST INSTRUCTION OF MODULE.                       00369021
*                                                                       00372021
*                                                                       00375021
* INPUT:                                                                00378021
*                                                                       00381021
*    FOR ALL ENTRIES, REG 1 = DDR RQE ADDR, REG 2 = DDR WAIT QUEUE      00384021
*    ADDR, REG 3 = CVT ADDR, REG 5 = XSA ADDR, REG 7 = 'FROM'           00387021
*    DEVICE UCB ADDR, REG 8 = 'TO' DEVICE UCB ADDR, REG 6 = USER'S      00390021
*    DEB ADDR, REG 9 = USER'S DCB ADDR, REG 10 = DDR DEB ADDR, REG      00393021
*    11 = IORMSCOM ADDR, REG 13 = DDR IOB ADDR.                         00396021
*    ON ENTRY FROM IGC0408E, THE NSLUSER BIT IN DDRFLGSA WILL BE ON.    00399021
*    ON ENTRY FROM IGC0408E BY WAY OF IGC0508E, DDRFLGSA MAY HAVE       00402021
*    THE OPINIT BIT ON AND DDRFLGSB WILL HAVE THE PROCEED BIT ON.       00405021
*    ON ENTRY FROM IGC0808E, DDRFLGSE WILL HAVE THE WRONGVOL BIT ON.    00408021
*    ON ENTRY FROM NSLREPOS BY WAY OF IGC0408E, REGISTER 0 WILL CONTAIN 00411021
*    A CODE TO DETERMINE THE PATH OF PROCESSING.                        00414021
*    CODE 0 = VOLUME VERIFICATION COMPLETE, TAPE IS TO BE FOWARD SPACED 00417021
*    PAST THE TAPE MARK.                                                00420021
*    CODE 4 = MORE INFORMATION IS NEEDED, READ ANOTHER RECORD.          00423021
*    CODE 8 = WRONG VOLUME MOUNTED.                                     00426021
*    CODE 12 = VOLUME VERIFICATION COMPLETE, DO NOT REINITIALIZE THE    00429021
*    BLOCK COUNT.                                                       00432021
*    CODE 16 = VOLUME VERIFICATION COMPLETE, REINITIALIZE THE BLOCK     00435021
*    COUNT.                                                             00438021
*                                                                       00441021
*                                                                       00444021
* OUTPUT:                                                               00447021
*                                                                       00450021
*    FOR ALL EXITS THE ABOVE REGISTERS REMAIN THE SAME.                 00453021
*    ON XCTL TO IGC0008E, DDRFLGSC WILL HAVE THE TERMNATE BIT ON.       00456021
*    ON XCTL TO IGC0408E, DDRFLGSB MAY HAVE THE SWAPMSG BIT ON, OR      00459021
*    DDRFLGSC MAY HAVE THE REPOSITN OR THE ERROR BIT ON OR DDRFLGSD     00462021
*    MAY HAVE THE FORSPACE OR READ BIT ON.                              00465021
*    ON XCTL TO IGC0808E, DDRFLGSE WILL HAVE THE WRONGVOL BIT ON.       00468021
*                                                                       00471021
*                                                                       00474021
* EXTERNAL REFERENCES:                                                  00477021
*                                                                       00480021
*         XCTL. SVC 15. WAIT. XLATE.                                    00483021
*                                                                       00486021
*                                                                       00489021
* EXITS-NORMAL:                                                         00492021
*                                                                       00495021
*         TO IGC0008E TO TERMINATE DDR.                                 00498021
*         TO IGC0408E TO REPOSITION THE TAPE.                           00501021
*         TO IGC0508E FOR MESSAGES.                                     00504021
*         TO IGC0808E FOR MESSAGES.                                     00507021
*         TO NSLREPOS FOR NSL VOLUME VERIFICATION.                      00510021
*                                                                       00513021
*                                                                       00516021
* EXITS-ERROR:                                                          00519021
*                                                                       00522021
*         NONE.                                                         00525021
* TABLES/WORK AREAS:                                                    00528021
*                                                                       00531021
*         IORMSCOM - THE DDR COMMUNICATIONS AREA.                       00534021
*         XSA FOR NSL LABEL PROCESSING.                                 00537021
*                                                                       00540021
*                                                                       00543021
* ATTRIBUTES;                                                           00546021
*                                                                       00549021
*         DISABLED. SERIALLY REUSABLE.                                  00552021
*                                                                       00555021
*                                                                       00558021
* CHARACTER CODE DEPENDENCY:                                            00561021
*                                                                       00564021
*         NONE.                                                         00567021
*                                                                       00570021
* UPDATE ACTIVITY                                                       00570621
*                                                                       00571221
*         APAR 66517 (INCORRECT POSITIONING)  9/12/73                   00571821
*          APAR 69049 (CAN'T READ FORWARD ONCE TAPE READ BACKWARD) 2/74 00572121
*        APAR 69365 (USER CANCELLED DURING REPOS.-- DDR ATTEMPTS        00572221
*                    TO RETRY -- UCBERR FLAG LEFT ON)       3/6/74      00572421
*     APAR 70440 (FORSPACE FLAG NOT TURNED OFF )               @SA70440 00572721
****************************************************************        00573021
         SPACE 2                                                        00576021
         TITLE '   IGC0608E - TAPE REPOSITION NUMBER 2 '                00600021
         BALR  BASEREG,N0               MODULE BASE REG                 00900021
         USING *,BASEREG                THIS MODULE ADDR                01200021
         USING CVTDSECT,CVTREG          CVT ADDR                        01500021
         USING IORMS,COMMREG            IORMSCOM ADDR                   01800021
*                                                                       02100021
         TM    DDRFLGSE,WRONGVOL        IS ENTRY AFTER WRONG VOLUME MSG 02400021
         BO    SETRUN                   YES, GO PREPARE TO REWIND TAPE  02700021
         TM    DDRFLGSA,NSLUSER         IS ENTRY AFTER NSL USER VERIFY  03000021
         BO    CHKCODE                  YES, GO CHECK RETURN CODE       03300021
         TM    DDRFLGSD,DUMPTAPE        IS THIS FOR DUMP TAPE     20048 03600021
         BZ    CHKTCB                   NO, GO CHECK TCB          44002 03650000
*                                                                       03700000
ENDDDR   EQU   *                                                        03750000
         OI    DDRFLGSC,TERMNATE        TO TERMINATE DDR                04200021
         MVC   N8(N8,SVRBPTR),LOAD0     LOAD NAME FOR XCTL              04500021
         B     GOXCTL                   GO PREPARE FOR XCTL             04800021
*                                                                       05100021
*        THIS SECTION DETERMINES THE TYPE OF LABEL ON THE TAPE, IF ANY, 05150000
*        AND WILL READ THE LABEL TO VERIFY THE VOLUME.                  05200000
*                                                                       05250000
CHKTCB   EQU   *                                                        05450000
         L     WKREG15,CVTHEAD          HIGHEST READY TCB         44002 05510000
         L     WKREG14,USRTCB           USER'S TCB POINTER        44002 05550000
         LA    WKREG14,N0(WKREG14)      CLEAR HIGH ORDER BYTE     44002 05600000
*                                                                       05650000
COMPTCB  EQU   *                                                        05660000
         CR    WKREG15,WKREG14          IS USER TCB STILL ON QUE  44002 05672000
         BE    CHKLABEL                 YES, DO LABEL PROCESSING  44002 05680000
         L     WKREG15,N116(WKREG15)    GET NEXT TCB IF ANY       44002 05690400
         LTR   WKREG15,WKREG15          IS THIS ADDRESS ZERO      44002 05690800
         BNZ   COMPTCB                  NO, SEE IF ITS USER TCB   44002 05694000
*                                                                       05696000
CANCLDDR EQU   *                                                        05696421
         TM    DDRFLGSA,OPINIT          IS THIS OPERATOR SWAP     44002 05698000
         BO    TERMDDR                  YES,PREPARE TO TERMINATE  44002 05698500
         OI    DDRFLGSC,CANCEL          FOR CANCEL DDR            44002 05698800
         LH    RQEREG,OURRQE            DDR RQE PTR               44002 05699200
         MVI   N0(OURIOB),UNRLTD        UNRELATED BIT IN IOB      44002 05699600
         SVC   ERREXCP                  ERROR EXCP SVC 15         44002 05699700
*                                                                       05699800
TERMDDR  EQU   *                                                        05699900
         MVC   DDRWORK+N12(N8),LOAD0    FOR CONTROL AFTER MSG     44002 05703200
         NI    DDRFLGSC,ALL-CANCEL      TURN OFF CANCEL INDICATOR 44002 05706700
         OI    DDRFLGSB,DDREND          FOR TERMINATE MSG         44002 05710000
         B     DDRMSG2                  GO PREPARE FOR MSG        44002 05720000
*                                                                       05759900
CHKLABEL EQU   *                                                        05769900
         NI    DDRFLGSB,ALL-PROCEED     TURN OFF PROCEED BIT            05799900
         L     USERDCB,USRDCB           RE-INITIALIZE USER DCB PTR      05849900
         MVC   BLKCNT(N4),N12(USERDCB)  SAVE USER BLK CNT          1078 05859900
* SAVE INFORMATION WHICH MAY BE REQUIRED DURING REPOSITIONING.  IF      05860921
* USER IS CANCELLED OR TIMES OUT DURING DDR REPOSITIONING, DDR SHOULD   05861921
* COMPLETE REPOSITIONING (BUT NOT RETRY THE FAILING RQE.) SINCE DDR     05862921
* NEEDS INFO. FROM USER CONTROL BLOCKS DURING REPOS, THIS INFO. WILL    05863921
* BE SAVED NOW, TO AVOID DDR ACCESSING CONTROL BLOCKS WHICH HAVE BEEN   05864921
* DELETED.                                                              05865921
         NI    DDRFLGSG,ALL-NEGBLKCT-DVCEND  SET BITS TO ZERO           05866921
         TM    N12(USERDCB),NEGBLOCK    DCB CNTN NEG BLK CT?            05867921
         BZ    NONEGBLK                 NO--FLAG SET TO 0               05868921
         OI    DDRFLGSG,NEGBLKCT        YES - SET FLAG                  05869921
NONEGBLK EQU   *                                                        05870921
         TM    DDRFLGSA,OPINIT          TEST FOR OPINIT --(NO           05871921
*                                       USER RQE ON OPINIT)             05872921
         BO    NODVCEND                 YES -- DO NOT TEST              05873921
         LH    WKREG2,USRRQE            GET USER RQE                    05874921
         L     WKREG2,N4(WKREG2)        GET USER IOB                    05875921
         TM    N12(WKREG2),DEVICEND     DEVICE END PRESENT?             05876921
         BZ    NODVCEND                 NO -- FLAG SET TO 0             05877921
         OI    DDRFLGSG,DVCEND          YES -- SET FLAG                 05878921
NODVCEND EQU   *                                                        05879921
         LH    RQEREG,OURRQE            DDR'S RQE PTR                   05899900
         L     OURDEB,N8(RQEREG)        RE-INITIALIZE DDR DEB PTR       05949900
         MVC   N32(N1,OURDEB),N32(USERDEB) USER'S MODE SET INTO DDR DEB 06000000
         TM    N34(FMUCBREG),ASCII      IS TAPE IN USASCII        20038 06300021
         BO    IO                       YES, GO PREPARE TO READ LABEL   06600021
         TM    N3(FMUCBREG),SL          DOES TAPE HAVE STANDARD LABEL   06900021
         BZ    CHKNSL                   NO, GO SEE IF IT HAS NSL        07200021
         OI    DDRFLGSD,STDLABEL        TO INDICATE STANDARD LABEL TAPE 07500021
*                                                                       07800021
READLAB  EQU   *                                                        08100021
         OI    N6(FMUCB),NOTREADY       TURN ON NOT READY BIT FOR CONTL 08400021
         TM    N17(FMUCB),SEVNTRCK      IS TAPE 7-TRACK                 08700021
         BZ    IO                       NO, GO DO IO                    09000021
         MVI   N32(OURDEB),EVENPAR      EVEN PARITY MODE SET      39961 09300021
*                                                                       09600021
IO       EQU   *                                                        09900021
         OI    DDRFLGSD,IOCONTRL        TO RE-EXCP WITH CONTROL         10200021
         OI    DDRFLGSE,LABLPROC        TO INDICATE LABEL PROCESSING    10500021
         MVC   DDRWORK(N8),RUNCCW       MOVE CCW INTO WORK AREA         10800021
         ST    SVRBPTR,DDRWORK          BUFFER ADDR INTO CCW            11100021
         MVI   DDRWORK,READDATA         READ COMMAND INTO CCW           11400021
         MVI   DDRWORK+N4,SUPRESS       CHANGE TO NO CHAINING           11700021
         BAL   WKREG2,IOSETUP           GO DO IO                        12000021
*                                                                       12300021
*        THIS SECTION WILL VERIFY THE LABEL BY EITHER COMPARING AGAINST 12350000
*        THE VOLUME ID IN THE UCB OR WILL GO TO 'NSLREPOS' FOR USER     12400000
*        VERIFICATION.                                                  12450000
*                                                                       12500000
         TM    DDRFLGSC,ERROR           WAS THERE AN ERR FOR LABEL PROC 12600021
         BO    SETRUN                   YES, GO PREPARE TO REWIND TAPE  12900021
         TM    N34(FMUCBREG),ASCII      IS TAPE IN ASCII          20038 13200021
         BZ    TESTNSL                  NO SEE IF TAPE HAS NSL    20038 13500021
         XLATE (SVRBPTR),N10,TO=E       TRANSLATE FIRST 10 BYTES  20038 13800021
         B     COMPLABL                 GO VERIFY THE LABEL       20038 14100021
*                                                                       14400021
TESTNSL  EQU   *                                                        14700021
         TM    DDRFLGSA,NSLUSER         TAPE NSL                        15000021
         BZ    COMPLABL                 NO, GO VERIFY STD LABEL         15300021
*        IF TAPE IS NSL, DETERMINE IF USER IS ON QUEUE BEFORE XCTL'ING  15310021
*        TO USERS NSL ROUTINE (NSLREPOS)...IF NOT ON QUEUE, DDR MAY     15320021
*        ABEND AS DESCRIBED BY APAR 63485                               15330021
         L     WKREG15,CVTHEAD          HIGHEST READY TCB         63485 15350021
         L     WKREG14,USRTCB           USER'S TCB POINTER        63485 15400021
         LA    WKREG14,N0(WKREG14)      CLEAR HIGH ORDER BYTE     63485 15450021
NSLTCB   EQU   *                                                  63485 15550021
         CR    WKREG15,WKREG14          IS USER TCB STILL ON QUE  63485 15600021
         BE    NSLSETUP                 YES, SETUP  FOR NSLREPOS  63485 15650021
         L     WKREG15,N116(WKREG15)    GET NEXT TCB IF ANY       63485 15700021
         LTR   WKREG15,WKREG15          IS THIS ADDRESS ZERO      63485 15750021
         BNZ   NSLTCB                   NO, SEE IF ITS USER TCB   63485 15800021
         B     CANCLDDR             YES, TERMINATE DDR-USER GONE  63485 15850021
NSLSETUP MVC   DDRWORK+N20(N8),NSLRTNE  LOAD NAME FOR XCTL              16500021
*                                                                       16800021
         MVC   XCTLLIST(N16),RTRNXCTL   XCTL LIST TO RES. CORE    46409 16850000
         LA    WKREG2,XCTLLIST+N8       ADDR OD LOC OF LOAD NAME  46409 16900000
         ST    WKREG2,XCTLLIST          THAT ADDR INTO FIRST WORD 46409 16950000
         LA    WKREG2,XCTLLIST          ADDR OF LIST FOR USER     46409 17000000
*                                                                       17070000
GOXCTL1  EQU   *                                                        17100021
         SR    WKREG15,WKREG15          ZERO FOR XCTL SETUP             17400021
         ST    WKREG15,DDRWORK+N16      PUT THOSE ZEROS IN SECOND WORD  17700021
         LA    WKREG15,DDRWORK+N20      ADDR OF LOCATION OF LOAD NAME   18000021
         ST    WKREG15,DDRWORK+N12      PUT THAT ADDR IN FIRST WORD     18300021
         LA    WKREG15,DDRWORK+N12      FIRST WORD ADDR INTO PARM REG   18600021
         XCTL  SF=(E,(WKREG15))         GO TO NSL USER                  18900021
*                                                                       19200021
COMPLABL EQU   *                                                        19500021
         CLC   N0(N3,SVRBPTR),VOL       IS 'VOL' FIRST 3 CHARS ON LABEL 19800021
         BNE   WRONGONE                 NO, GO PREPARE FOR WRONGVOL MSG 20100021
         OC    N28(N6,FMUCB),N28(FMUCB)  IS UCB FLD = 0                 20400021
         BZ    CANCLDDR                 YES, QUIT                       20700021
         CLC   N4(N6,SVRBPTR),N28(FMUCB)  ARE LABELS EQUAL        52727 20750021
         BE    MOVETAPE                YES,PREPARE TO MOVE TAPE   52727 20800021
*                                                                       21000021
WRONGONE EQU   *                                                        21300021
         NI    DDRFLGSE,ALL-LABLPROC    TURN OFF LABEL PROCESSING BOI   21600021
         OI    DDRFLGSE,WRONGVOL        FOR WRONG VOLUME MSG            21900021
         MVC   DDRWORK+N12(N8),LOAD6    FOR CONTROL AFTER MSG           22200021
*                                                                       22500021
DDRMSG2  EQU   *                                                        22800021
         MVC   N8(N8,SVRBPTR),MSGMOD2   LOAD NAME FOR XCTL              23100021
*                                                                       23400021
GOXCTL   EQU   *                                                        23700021
         SR    WKREG15,WKREG15          ZERO FOR XCTL SETUP             24000021
         ST    WKREG15,N4(SVRBPTR)      PUT THOSE ZEROS IN SECOND WORD  24300021
         LA    WKREG15,N8(SVRBPTR)      ADDR OF LOCATION OF LOAD NAME   24600021
         ST    WKREG15,N0(SVRBPTR)      THAT ADDR INTO FIRST WORD       24900021
         LR    WKREG15,SVRBPTR          ADDR OF SAVE AREA IN PARM REG   25200021
         XCTL  SF=(E,(WKREG15))         GIVE UP CONTROL                 25500021
*                                                                       25800021
*        THIS SECTION STARTS THE REPOSITIONING PROCESS FOR STANDARD     26050000
*        LABEL TAPES AND NSL TAPES WHOSE LABELS ARE FORMATTED SIMILAR   26060000
*        TO THAT OF A STANDARD LABEL (LABEL,HDR-TM-DATA).               26070000
*                                                                       26080000
MOVETAPE NI    DDRFLGSE,ALL-LABLPROC    TURN OFF LABEL PROCESSING BIT   26100021
         OI    DDRFLGSC,REPOSITN        TO REPOSITION TAPE              26400021
         OI    DDRFLGSD,IOCONTRL        TO RE-EXCP WITH CONTROL         26700021
*                                                                       26750000
FOWARD   EQU   *                                                        26800000
         MVI   DDRWORK,FORFILE          CHANGE COMMAND TO FORWARD SPACE 27000021
         BAL   WKREG2,IOSETUP           GO DO IO                        27300021
*                                                                       27600021
         TM    DDRFLGSC,ERROR           WAS THERE A PERM ERR DOING FSF  27900021
         BZ    TAPEMOD1            NO -- CONTINUE              @SA70440 28200021
         NI    DDRFLGSD,ALL-FORSPACE TURN OFF FLAG             @SA70440 28300021
         B     SETRUN              PREPARE TO REWIND TAPE      @SA70440 28400021
*                                                                       28500021
TAPEMOD1 EQU   *                                                        28800021
         MVC   N8(N8,SVRBPTR),LOAD4     LOAD NAME FOR XCTL              29100021
         B     GOXCTL                   GO PREPARE TO XCTL              29400021
*                                                                       29700021
SETRUN   EQU   *                                                        30000021
         MVC   DDRWORK(N16),RUNCCW      REWIND-UNLOAD CCW               30300021
         OI    DDRFLGSD,IOCONTRL        TO RE-EXCP WITH CONTROL         30600021
         BAL   WKREG2,IOSETUP           GO DO IO                        30900021
*                                                                       31200021
         TM    DDRFLGSE,WRONGVOL        IS THIS RUN BECAUSE OF WRONGVOL 31500021
         BZ    ERRON                    NO, TURN ON ERROR INDICATOR     31800021
         NI    DDRFLGSE,ALL-WRONGVOL    TURN OFF WRONG VOLUME INDICATOR 32100021
         B     READLAB                  GO READ THE LABEL AGAIN         32400021
ERRON    EQU   *                                                        32700021
         OI    DDRFLGSF,LABELERR        TO INDICATE ERROR IN LABEL PROC 33000021
         NI    DDRFLGSE,ALL-LABLPROC    TURN OFF LABEL PROC   JE A64640 33050021
*                                                                       33300021
DDRMSG1  EQU   *                                                        33600021
         MVC   DDRWORK+N12(N8),LOAD4    FOR CONTROL AFTER MSG           33900021
         MVC   N8(N8,SVRBPTR),MSGMOD1   LOAD NAME FOR XCTL              34200021
         B     GOXCTL                   GO PREPARE TO XCTL              34500021
*                                                                       34800021
*        THIS SECTION CHECKS THE RETURN CODE FRON 'NSLREPOS' AND ACTS   34850000
*        ACCORDING TO THE CODES DESCRIBED IN THE 'INPUT' PART OF THE    34900000
*        PROLOGUE AT THE BEGINING OF THIS MODULE.                       34950000
*                                                                       35000000
CHKCODE  EQU   *                                                        35100021
         MVC   BLKCNT(N4),N12(USERDCB)  SAVE USER'S BLOCK COUNT         35150000
         LA    WKREG15,N4               TO COMPARE AGAINST RETURN CODE  35400021
         CLR   WKREG0,WKREG15           IS RETURN CODE 4                35700021
         BE    IO                       YES, GO READ MORE DATA          36000021
         BH    COMPMORE                 CODE IS HIGHER, COMPARE MORE    36300021
         OI    DDRFLGSD,FORSPACE        TO FORWARD SPACE FILE           36600021
         NI    DDRFLGSA,ALL-NSLUSER     TURN OFF NSL USER INDICATOR     36900021
         NI    DDRFLGSE,ALL-LABLPROC    TURN OFF LABEL PROC INDICATOR   37200021
         MVC   FILECNT(N2),NEGONE       INIT DDR FILE COUNT TO -1       37500021
         LA    WKREG0,N1                FOR IOB INCREMENT               37850000
          STH   WKREG0,N28(OURIOB)  INIT IOB INCR TO ONE          69049 37900021
         B     FOWARD                   GO FOWARD SPACE TAPE            37950000
*                                                                       38400021
COMPMORE EQU   *                                                        38700021
         LA    WKREG15,N12              TO COMPARE AGAINST RETURN CODE  39000021
         CLR   WKREG0,WKREG15           IS RETURN CODE 12               39300021
         BL    WRONGONE                 NO, CODE IS 8, WRONG VOLUME ON  39600021
         BE    READON                   YES, GO PREPARE TO KEEP READING 39900021
*                                                                       40200021
         LA    WKREG15,N16              TO COMPARE AGAINST RETURN CODE  40500021
         CLR   WKREG0,WKREG15           IS RETURN CODE 16               40800021
         BNE   WRONGONE                 NO, CODE IS HIGHER, NOT VALID   41100021
         TM    DDRFLGSA,OPINIT          IS THIS OPERATOR SWAP           41400021
         BO    INITNEG                  YES, INIT BLK CNT TO -1         41700021
         XC    DDRDCB+N12(N4),DDRDCB+N12 CLEAR DDR'S BLOCK COUNT        42000021
         B     READON                   GO PREPARE TO KEEP READING      42300021
*                                                                       42600021
INITNEG  MVC   DDRDCB+N12(N4),NEGONE    INIT BLK CNT TO -1              42900021
READON   OI    DDRFLGSD,READ            TO READ RECORDS                 43200021
GOPOSITN OI    DDRFLGSC,REPOSITN        TO REPOSITION TAPE              43500021
         NI    DDRFLGSA,ALL-NSLUSER     TURN OFF NSL USER INDICATOR     44100021
         B     TAPEMOD1                 GO PREPARE TO XCTL              44400021
*                                                                       44700021
CHKNSL   TM    N8(USERDEB),NONSTL       IS NSL INDICATED                45000021
         BO    NSLON                    YES, GO TURN ON NSL INDICATOR   45300021
         OI    DDRFLGSD,UNLABELD        TO INDICATE UNLABELED TAPE      45600021
         B     GOPOSITN                 GO PREPARE TO REPOSITION TAPE   45900021
*                                                                       46200021
NSLON    OI    DDRFLGSA,NSLUSER         TO INDICATE NSL                 46500021
         XC    DDRDCB+N12(N4),DDRDCB+N12  CLEAR DDR BLKCNT        66517 46800021
         TM    DDRFLGSA,OPINIT     IS THIS AN OPERATOR SWAP       66517 46900021
         BO    READLAB             YES, GO SET NRDY BIT           66517 47000021
         TM    DDRFLGSG,DVCEND          DEVICE END PRESENT?             47100021
         BZ    IO                  NO, INIT ZERO                  66517 47400021
*                                                                       48000021
INIT1    EQU   *                                                        48300021
         LA    WKREG15,N1               TO INIT DDR BLK CNT TO 1        48600021
         ST    WKREG15,DDRDCB+N12       INIT CFU5T T6-1                 48900021
         B     IO                       GO DO IO                        49200021
*                                                                       49250000
*        THIS SECTION IS THE INITIALIZATION NEEDED FOR THE IOS/DDR      49300000
*        INTERFACE.                                                     49350000
*                                                                       49400000
IOSETUP  EQU   *                                                        49800021
         SSM   DISABLE                                                  50100021
         LH    RQEREG,OURRQE            DDR'S RQE PTR                   50400021
         XC    IOSECB(N4),IOSECB        CLEAR IOS ECB                   50700021
         XC    N9(N7,OURIOB),N9(OURIOB) CLEAR STATUS IN IOB             51000021
         MVI   N0(OURIOB),UNRLTD        UNRELATED BIT IN IOB FLAGS 1    51300021
         SVC   ERREXCP                  SVC 15                          51600021
         WAIT  ECB=IOSECB                                               51900021
         SSM   DISABLE                                                  52200021
         BR    WKREG2                   RETURN TO MAINLINE              52500021
         SPACE 5                                                        52800021
*                                                                       53100021
***      REGISTER EQUATES                                               53400021
*                                                                       53700021
WKREG0   EQU   0                        WORK REGISTER                   54000021
RQEREG   EQU   1                        RQE PTR                         54300021
WKREG2   EQU   2                        WORK REGISTER                   54600021
CVTREG   EQU   3                        CVT PTR                         54900021
SVRBPTR  EQU   5                        EXTENDE SAVE AREA PTR           55200021
USERDEB  EQU   6                        USER DEB PTR                    55500021
FMUCB    EQU   7                        'FROM' UCB PTR                  55800021
FMUCBREG EQU   7                        'FROM' UCB PTR                  56100021
USERDCB  EQU   9                        USER DCB PTR                    56700021
OURDEB   EQU   10                       DDR DEB PTR                     57000021
COMMREG  EQU   11                       IORMSCOM PTR                    57300021
BASEREG  EQU   12                       MODULE BASE REG                 57600021
OURIOB   EQU   13                       DDR IOB PTR                     57900021
WKREG14  EQU   14                       WORK REGISTER                   58200021
WKREG15  EQU   15                       WORK REGISTER                   58500021
         SPACE 3                                                        58800021
*                                                                       59100021
***      GENERAL EQUATES                                                59400021
*                                                                       59700021
ALL      EQU   X'FF'                    MASK FOR 'AND' INSTRUCTIONS     60000021
ASCII    EQU   X'04'                    INDICATOR FOR ASCII             60300021
ERREXCP  EQU   15                       SVC 15 - ERROR EXCP             60600021
EVENPAR  EQU   X'AB'                    EVEN PARITY MODE SET      59235 60900021
FLGSOFF  EQU   X'02'                    MASK FOR TURNING OFF IOB FLAGS  61200021
FORFILE  EQU   X'3F'                    COMMAND TO FORWARD SPACE FILE   61500021
NONSTL   EQU   X'02'                    NON-STANDARD LABEL FLAG         61800021
NOTREADY EQU   X'40'                    NOT READY BIT IN UCB            62100021
READDATA EQU   X'02'                    COMMAND TO READ A RECORD        62400021
SEVNTRCK EQU   X'80'                    7-TRACK TAPE INDICATOR    39961 62700021
SL       EQU   X'01'                    INDICATOR FOR STD LABEL         63000021
SUPRESS  EQU   X'20'                    TO SUPRESS WRONG LENGTH RECORD  63300021
UNRLTD   EQU   X'02'                    UNRELATED BIT IN IOB FLAGS 1    63600021
DEVICEND EQU   X'04'               DEVICE END INDICATOR           66517 63700021
NEGBLOCK EQU   X'80'                    MASK -- NEG. BLK. CT.           63800021
         SPACE 3                                                        63900021
*                                                                       64200021
***      INTEGER EQUATES                                                64250000
*                                                                       64800021
N0       EQU   0                        DISPLACEMENT VALUE              65100021
N1       EQU   1                        DISPLACEMENT VALUE              65400021
N2       EQU   2                        DISPLACEMENT VALUE              65700021
N3       EQU   3                        DISPLACEMENT VALUE              66000021
N4       EQU   4                        DISPLACEMENT VALUE              66300021
N6       EQU   6                        DISPLACEMENT VALUE              66600021
N7       EQU   7                        DISPLACEMENT VALUE              66900021
N8       EQU   8                        DISPLACEMENT VALUE              67200021
N9       EQU   9                        DISPLACEMENT VALUE              67500021
N10      EQU   10                       DISPLACEMENT VALUE              67800021
N12      EQU   12                       DISPLACEMENT VALUE              68100021
N16      EQU   16                       DISPLACEMENT VALUE              68400021
N17      EQU   17                       DISPLACEMENT VALUE        39961 68700021
N20      EQU   20                       DISPLACEMENT VALUE              69000021
N29      EQU   29                       DISPLACEMENT VALUE              69050000
N32      EQU   32                       DISPLACEMENT VALUE              69300021
N28      EQU   28                       DISPLACEMENT VALUE              69600021
N34      EQU   34                       DISPLACEMENT VALUE              69900021
N40      EQU   40                       DISPLACEMENT VALUE              69910000
N116     EQU   116                      DISPLACEMENT VALUE              69950000
         SPACE 3                                                        70200021
*                                                                       70500021
***      CHANNEL PROGRAMS AND DEFINED CONSTATNS                         70800021
*                                                                       71100021
RTRNXCTL XCTL  SF=L,EP=IGC0408E                                         71150000
*                                                                       71200000
         DS    0D                       DOUBLE WORD BOUNDRY             71400021
RUNCCW   DC    X'0F'                    COMMAND TO REWIND-UNLOAD        71700021
         DC    X'000000'                BUFFER ADDRESS FIELD            72000021
         DC    X'60'                    COMMAND CHAINING AND SILLY BITS 72300021
         DC    X'000030'                LENGTH OF BUFFER AREA           72600021
NOPCCW   DC    X'03'                    COMMAND FOR NO-OP               72900021
         DC    X'000000'                BUFFER ADDRESS FIELD            73200021
         DC    X'20'                    SUPRESS WRONG LENGTH RECORD     73500021
         DC    X'00000C'                LENGTH OF DATA TO BE PROCESSED  73800021
LOAD0    DC    C'IGC0008E'              INITIATOR/TERMINATOR MODULE     74100021
LOAD4    DC    C'IGC0408E'              TAPE MODULE #1                  74400021
MSGMOD1  DC    C'IGC0508E'              MESSAGE MODULE #1               74700021
LOAD6    DC    C'IGC0608E'              THIS MODULE                     75000021
MSGMOD2  DC    C'IGC0808E'              MESSAGE MODULE #2               75300021
NSLRTNE  DC    C'NSLREPOS'              USER NSL MODULE                 75600021
NEGONE   DC    X'FFFFFFFF'              TO INIT COUNT TO -1             75900021
VOL      DC    CL3'VOL'                 MASK FOR STANDARD LABELS        76200021
ENABLE   DC    X'FF'                                                    76500021
DISABLE  DC    X'00'                                                    76800021
MAINT    DC    50X'40'                  SPACE FOR MAINT & TEMP PATCHES  76950000
CVTDSECT DSECT                                                          77100021
         CVT                                                            77400021
         IORMSCOM                                                       77700021
         END                                                            78000021
