IGC0708E CSECT                                                          00300021
******************************************************************      00304021
*                                                                       00308021
* STATUS:                                                               00312021
*                                                                       00316021
*    RELEASE 21.7                                                       00320021
*                                                                       00324021
*                                                                       00328021
* FUNCTION:                                                             00332021
*                                                                       00336021
*    THIS MODULE BUILDS A RECORD, USING THE AR-149 FORMAT FOR THE       00340021
*    HEADER, READS THE BUFFERED LOG FOR A 3330, AND RECORDS THIS        00344021
*    SENSE INFORMATION USING SVC 76.                                    00348021
*                                                                       00352021
*                                                                       00356021
* ENTRY POINT:                                                          00360021
*                                                                       00364021
*         IGC0708E - FIRST INSTRUCTION OF MODULE.                       00368021
*                                                                       00372021
*                                                                       00376021
* INPUT:                                                                00380021
*                                                                       00384021
*    FOR ALL ENTRIES, REG 1 = DDR RQE ADDR, REG 2 = DDR WAIT QUEUE      00388021
*    ADDR, REG 3 = CVT ADDR, REG 5 = XSA ADDR, REG 7 = 'FROM' DEVICE    00392021
*    UCB ADDR, REG 8 = 'TO' DEVICE UCB ADD, REG 11 = IORMSCOM ADDR.     00396021
*    ON ENTRY FROM IGC0108E OR IGC0308E, DDRFLGSE WILL HAVE THE         00400021
*    READFROM BIT ON AND ALSO FROM IGC0108E, DDRFLGSA WILL HAVE THE     00404021
*    OPINIT BIT ON.                                                     00408021
*                                                                       00412021
*                                                                       00416021
* OUTPUT:                                                               00420021
*                                                                       00424021
*    FOR ALL EXITS THE ABOVE REGISTERS REMAIN THE SAME.                 00428021
*    FOR XCTL TO IGC0108E OR IGC0308E, THE READFROM AND/OR RECRDING     00432021
*    BITS IN DDRFLGSE WILL BE ON.                                       00436021
*                                                                       00440021
*                                                                       00444021
* EXTERNAL REFERENCES:                                                  00448021
*                                                                       00452021
*         GETMAIN. FREEMAIN. TIME. SVC 15. WAIT. SVC 76.                00456021
*                                                                       00460021
*                                                                       00464021
* EXITS-NORMAL:                                                         00468021
*                                                                       00472021
*         XCTL TO IGC0108E TO CONTINUE OPERATOR DDR.                    00476021
*         XCTL TO IGC0308E TO CONTINUE SYSTEM DDR.                      00480021
*                                                                       00484021
*                                                                       00488021
* EXITS-ERROR:                                                          00492021
*                                                                       00496021
*         NONE.                                                         00500021
*                                                                       00504021
*                                                                       00508021
* TABLES/WORK AREAS:                                                    00512021
*                                                                       00516021
*         IORMSCOM - THE DDR COMMUNICATIONS AREA.                       00520021
*         THE AREA OBTAINED FROM GETMAIN TO BUILD THE RECORD.           00524021
*                                                                       00528021
*                                                                       00532021
* ATTRIBUTES:                                                           00536021
*                                                                       00540021
*         ENABLED SERIALLY REUSABLE.                                    00544021
*                                                                       00548021
*                                                                       00552021
* CHARACTER CODE DEPENDENCY:                                            00556021
*                                                                       00560021
*         NONE.                                                         00564021
*                                                                       00568021
***************************************************************         00572021
         SPACE 2                                                        00576021
         TITLE '   IGC0708E - RECORDING MODULE '                        00600021
         BALR  BASE,N0                  MODULE BASE REG                 00900021
         USING *,BASE                   MODULE ADDR                     01200021
         USING CVTDSECT,CVTREG          CVT ADDR                        01500021
         USING IORMS,COMMPTR            IORMSCOM PTR                    01800021
         LA    WKREG14,COREADDR         ADDR OF PTR TO OBTAINED CORE    02100021
*                                                                       02400021
*        TEST FLAG TO DETERMINE IF A READ OPERATION SHOULD BE PERFORMED 02650000
*        ON THE DEVICES INVOLVED WITH THE SWAP.                         02660000
*        IF YES, SET FLAG ON AND OBTAIN STORAGE TO BUILD THE RECORD.    02670000
*        IF NO, SET FLAG OFF AND TEST TO SEE IF RECORDING IS NEEDED.    02680000
*                                                                       02690000
         TM    DDRFLGSE,READFROM        IS 'FROM' DEV READ BIT ON       02700021
         BO    RECORDNG                 YES, GO SEE IF RECORDING IS ON  03000021
         OI    DDRFLGSE,READFROM        TO INDICATE READING OCCURRED    03300021
         GETMAIN EC,LV=80,A=(WKREG14),SP=255 REQUEST MAIN CORE          03600021
         LTR   WKREG15,WKREG15          WAS CORE ALLOCATED              03900021
         BNZ   GETOUT                   NO, GET OUT                     04200021
*                                                                       04500021
*        STORAGE OBTAINED. INDICATE RECORDING WILL BE REQUIRED.         04650000
*                                                                       04700000
         OI    DDRFLGSE,RECRDING        TO INDICATE RECORDING NEEDED    04800021
*                                                                       05100021
*        BUILD DDR RECORD WITH AR-149 HEADER FORMAT.                    05250000
*                                                                       05300000
         L     HEADER,COREADDR          ADDR OF OBTAINED STORAGE        05400021
         USING RECORD,HEADER            RECORD DSECT ADDR               05700021
         MVI   KEY,NINETY               KEY FOR T-TYPE RECORD           06000021
         LA    WKREG0,N4                TO GET NEGATIVE DISPLACEMENT    06300021
         LR    WKREG14,CVTREG           ADDR OF CVT IN WORK REG         06600021
         SR    WKREG14,WKREG0           TO GET RELEASE LEVEL            06900021
         PACK  DDRWORK(N8),N0(N2,WKREG14) PACK FOR CVB                  07200021
         CVB   WKREG0,DDRWORK           CONVERT TO BINARY               07500021
         STC   WKREG0,RELEASE           PUT REL. LEVEL INTO RECORD      07800021
         MVI   RECORDID,MERLINID        MERLIN ID IN RECORD             08100021
         XC    SPARE1(N2),SPARE1        ZERO SPARE BYTES                08250000
         XC    SPARE2(N2),SPARE2        ZERO SPARE BYTES                08300000
         OI    SPARE1,TIMERBIT          TO INDICATE TIME MACRO IS USED  08350000
         MVI   RECENTRY,TTYPE           INDICATE T-TYPE RECORD          08400021
         TIME                                                           08700021
         ST    WKREG1,DATE              DATE INTO RECORD                09000021
         ST    WKREG0,TIME              TIME INTO RECORD                09300021
         XC    ZERO1(N2),ZERO1          FIRST ZERO FIELD                09600021
         XC    ZERO2(N2),ZERO2          SECOND ZERO FIELD               09900021
         LR    WKREG14,CVTREG           ADDR OF CVT IN WORK REG         10200021
         LA    WKREG0,N6                TO GET CPU ID                   10500021
         SR    WKREG14,WKREG0           ADDR OF CPU ID                  10800021
         MVC   CPUID(N2),N0(WKREG14)    CPU ID INTO RECORD              11100021
         XC    ZERO3(N2),ZERO3          THIRD ZERO FIELD                11400021
         MVC   CUA(N2),N4(FMUCB)        'FROM' CUA INTO RECORD          11700021
         MVC   VOLSER(N6),N28(FMUCB)    'FROM' VOL SERIAL INTO RECORD   12000021
*                                                                       12300021
*        INITALIZE CONTROL BLOCKS FOR IO.                               12450000
*                                                                       12500000
         LH    RQEPTR,OURRQE            DDR'S RQE PTR                   12900021
         STH   FMUCB,N2(RQEPTR)         'FROM' UCB PTR INTO DDR RQE     13200021
         STH   FMUCB,N34(OURDEB)        'FROM' UCB PTR INTO DDR DEB     13500021
         LA    WKREG14,N32(HEADER)      DATA ADDR FOR CCW               13800021
*                                                                       14100021
         L     OURIOB,N4(RQEPTR)        DDR'S IOB PTR                   14400021
*                                                                       14650000
*        INITIALIZATION FOR DDR/IOS INTERFACE VIA SVC 15.               14660000
*                                                                       14670000
IOSETUP  EQU   *                                                        14680000
         XC    N9(N7,OURIOB),N9(OURIOB) CLEAR STATUS                    14690000
         XC    N30(N2,OURIOB),N30(OURIOB) CLEAR ERROR COUNT             15000021
         XC    IOSECB(N4),IOSECB        CLEAR IOS ECB                   15300021
         MVI   N0(OURIOB),UNRLTD    CLEAR ALL BUT UNRLTD FLAG     53045 15600021
*                                                                       15900021
         MVC   DDRWORK(N8),RBLCCW       CCW INTO WORK AREA              16500021
         ST    WKREG14,DDRWORK          BUFFER ADDRESS INTO CCW         16800021
         MVI   DDRWORK,RBLCOMND         COMMAND TO READ BUFFERED LOG    17100021
         LA    WKREG0,DDRWORK           ADDR OF CCW                     17400021
         ST    WKREG0,N16(OURIOB)       THAT ADDR INTO DDR'S IOB        17700021
         OI    DDRFLGSD,IOCONTRL        TO RE-EXCP WITH CONTROL         18000021
         SVC   ERREXCP                  SVC 15                          18300021
         WAIT  ECB=IOSECB               WAIT FOR IO TO COMPLETE         18600021
*                                                                       18900021
*        IF THERE WAS A PERMANENT IO ERROR IN TRYING TO READ THE        19050000
*        BUFFERED LOG A TEST IS MADE TO DETERMINE IF IT WAS FOR         19100000
*        THE 'FROM' OR 'TO' DEVICE SO RECORDING WILL NOT BE             19150000
*        ATTEMPTED FOR THAT DEVICE.                                     19160000
*                                                                       19170000
         TM    DDRFLGSC,ERROR           WAS THERE A PERM. TO IO ERROR   19200021
         BZ    RETRNRQE                 NO, GO RESTORE USER RQE IN UCB  19500021
         NI    DDRFLGSC,ALL-ERROR       TURN OFF ERROR INDICATOR        19800021
         CH    FMUCB,N34(OURDEB)        IS ERROR ON 'FROM' DEVICE       20100021
         BE    ERRORFM                  YES, GO TURN ON INDICATOR       20400021
         OI    DDRFLGSE,TOERROR         TO INDICATE ERROR ON 'TO' DEVCE 20700021
         B     RETRNRQE                 GO RESTORE USER RQE IN UCB      21000021
*                                                                       21250000
ERRORFM  EQU   *                                                        21260000
         OI    DDRFLGSE,FMERROR         TO INDICATE ERROR ON 'FROM' DEV 21270000
*                                                                       21320000
RETRNRQE EQU   *                                                        21370000
         LH    RQEPTR,OURRQE       DDR RQE PTR                    53045 21420021
         TM    DDRFLGSE,READTO          WAS 'TO' BUFFER READ            21900021
         BO    GETOUT                   YES, GET OUT                    22200021
         CLR   FMUCB,TOUCB              IS SWAP TO ITSELF               22500021
         BE    GETOUT                   YES, GET OUT                    22800021
         TM    N3(TOUCB),ONLINE         IS 'TO' DEVICE ONLINE           23100021
         BZ    GETOUT                   NO, GET OUT                     23400021
*                                                                       23700021
*        PREPARE TO READ THE BUFFERED LOG FOR THE 'TO' DEVICE           23850000
*                                                                       23900000
         STH   TOUCB,N34(OURDEB)        'TO' UCB PTR INTO DEB           24300021
         STH   TOUCB,N2(RQEPTR)         'TO' UCB PTR INTO RQE           24600021
         LA    WKREG14,N56(HEADER)      BUFFER ADDR FOR'TO' SENSE DATA  24900021
         OI    DDRFLGSE,READTO          TO READ 'TO' DEVICE             25200021
         B     IOSETUP                  GO DO IO                        25500021
*                                                                       25800021
*        MODULE HAS BEEN ENTERED PREVIOUSLY FOR READ OPERATIONS. IF     26050000
*        RECRDING BIT IS SET, TEST TO SEE IF RECORDING IS NEEDED FOR    26060000
*        BOTH DEVICES. IF BIT IS NOT ON, TURN IT ON AND GET OUT.        26070000
*                                                                       26080000
RECORDNG EQU   *                                                        26090000
         NI    DDRFLGSE,ALL-READFROM    TURN OFF READ INDICATOR         26092000
         TM    DDRFLGSE,RECRDING        IS RECORDING INDICATOR ON       26400021
         BO    BUFRPTR                  YES, GO RECORD SENSE DATA       26700021
         OI    DDRFLGSE,RECRDING        TO INDICATE RECORDING NEEDED    27000021
         B     GETOUT                   EXIT                            27300021
*                                                                       27600021
*        INSERT THE CUA OF THE DEVICE INTO THE RECORD.                  27850000
*                                                                       27860000
BUFRPTR  EQU   *                                                        27900021
         L     HEADER,COREADDR          ADDR OF RECORD HEADER           28200021
         LR    WKREG15,TOUCB            SAVE UCB PTR                    28500021
*                                                                       28800021
MOVECUA  EQU   *                                                        29100021
         MVC   CUA(N2),N4(TOUCB)   ORIGINAL 'FROM' DEVICE CUA           29400021
         NI    CUA,X'0F'           INTO HEADER AND CLEAR FIRST CHAR     29450021
*                                                                       30300021
*        THE ACTUAL PHYSICAL ADDR OF THE DEVICE MUST ALSO BE INCLUDED   30450000
*        IN THE RECORD.                                                 30500000
*                                                                       30550000
SETTABCT EQU   *                                                        30600021
         LA    WKREG15,N16              FOR LOOP CONTROL                30900021
         LA    WKREG14,PHYSDRID         PHYSICAL DRIVE TABLE PTR        31200021
         MVC   DDRWORK(N1),SENSE1+N4    GET BYTE 4 OF SENSE DATA        31500021
         NI    DDRWORK,CUMASK           CLEAR CHANNEL UNIT BITS         31800021
*                                                                       32100021
TESTSENS EQU   *                                                        32400021
         CLC   DDRWORK(N1),N0(WKREG14)  DOES SENSE MATCH TABLE ENTRY    32700021
         BE    MASKDRYV                 YES, MASK DRIVE ID INTO CUA     33000021
         LA    WKREG14,N2(WKREG14)      NO, UPDATE PTR                  33300021
         BCT   WKREG15,TESTSENS         GO LOOK AT NEXT TABLE ENTRY     33600021
         B     RECORDFM                 END OF TABLE, NO MARCH FOUND    33900021
*                                                                       34200021
MASKDRYV EQU   *                                                        34500021
         NI    CUA+N1,DRYVMASK          MASK OUT LOGICAL DR FROM CUA    34800021
         OC    CUA+N1(N1),N1(WKREG14)   MASK IN DRIVE ID FROM TABLE     35100021
*                                                                       35400021
*        IF THERE WAS AN ERROR READING THE LOG FOR THE 'FROM' DEVICE    35450000
*        NO RECORDING FOR THAT DEVICE WILL TAKE PLACE.                  35500000
*                                                                       35550000
RECORDFM TM    DDRFLGSE,FMERROR         WAS THERE AN ERR READING 'FROM' 35700021
         BZ    RECORDIT                 NO, GO RECORD 'FROM' SENSE      36000021
         NI    DDRFLGSE,ALL-FMERROR     TURN OFF ERROR INDICATOR        36300021
         B     CHKTO                    GO CHECK IF 'TO' DEV WAS READ   36600021
*                                                                       36900021
*        RECORD THE SENSE DATA VIA SVC 76.                              37050000
*                                                                       37100000
RECORDIT LR    WKREG1,HEADER            ADDR OF RECORD TO BE RECORDED   37200021
         LA    WKREG0,N56               RECORD LENGTH             57547 37800021
         LNR   WKREG0,WKREG0            NEGATE LENGTH                   38100021
         SVC   SEVENSIX                 SVC 76, RECORD INTO SYS1.LOGREC 38400021
*                                                                       38700021
*        IF THERE WAS AN ERROR READING THE LOG FOR THE 'TO' DEVICE      38960000
*        NO RECORDING WILL TAKE PLACE. IF RECORDING HAS TAKEN PLACE     38970000
*        CONTROL IS PASSED BACK TO THE APPROPIATE MODULES.              38980000
*                                                                       38990000
CHKTO    EQU   *                                                        39000021
         TM    DDRFLGSE,READTO          WAS 'TO' DEVICE READ            39300021
         BZ    FREECORE                 NO, GO FREE STORAGE AND GET OUT 39600021
         NI    DDRFLGSE,ALL-READTO      TURN OFF READ INDICTOR          39900021
         TM    DDRFLGSE,TOERROR         WAS THERE AN ERROR READING 'TO' 40200021
         BZ    RECORDTO                 NO, GO RECORD 'TO' SENSE        40500021
         NI    DDRFLGSE,ALL-TOERROR     TURN OFF ERROR INDICATOR        40800021
         B     FREECORE                 GO FREE STORAGE AND GET OUT     41100021
*                                                                       41400021
RECORDTO EQU   *                                                        41700021
         LR    WKREG15,FMUCB            SAVE UCB PTR                    42000021
         MVC   N32(N24,HEADER),N56(HEADER) PUT 'TO' DATA INTO RECORD    42300021
         MVC   VOLSER(N6),N28(TOUCB)    VOL SERIAL INTO RECORD          42600021
         B     MOVECUA                  GO CONVERT CUA ID               42900021
*                                                                       43200021
FREECORE EQU   *                                                        43500021
         SSM   RBLCCW                   DISABLE BEFORE USING MACRO      43650000
         LA    WKREG14,COREADDR         ADDR OF PTR TO OBTAINED CORE    43800021
         FREEMAIN  E,LV=N80,A=(WKREG14),SP=255   FREE OBTAINED CORE     44100021
*                                                                       44400021
GETOUT   TM    DDRFLGSA,OPINIT          IS THIS OPERATOR SWAP           44700021
         BO    GOLOAD1                  YES, GET OPERATOR SWAP MODULE   45000021
         MVC   N8(N8,SVRBPTR),LOAD3     LOAD NAME FOR XCTL              45300021
         B     GOXCTL                   GO PREPARE FOR XCTL             45600021
GOLOAD1  MVC   N8(N8,SVRBPTR),LOAD1     LOAD NAME FOR XCTL              45900021
*                                                                       46200021
GOXCTL   SR    WKREG15,WKREG15          ZERO FOR XCTL SET UP            46500021
         ST    WKREG15,N4(SVRBPTR)      ZERO SECOND WORD                46800021
         LA    WKREG15,N8(SVRBPTR)      ADDR OF LOCATION OF LOAD NAME   47100021
         ST    WKREG15,N0(SVRBPTR)      THAT ADDR INTO FIRST WORD       47400021
         LR    WKREG15,SVRBPTR          ADDR OF SAVE AREA IN PARM REG   47700021
         XCTL  SF=(E,(WKREG15))         GIVE UP CONTROL                 48000021
         SPACE 5                                                        48300021
*                                                                       48600021
***      REGISTER EQUATES                                               48900021
*                                                                       49200021
WKREG0   EQU   0                        WORK REGISTER                   49500021
WKREG1   EQU   1                        WORK REGISTER                   49800021
RQEPTR   EQU   1                        RQE PTR                         50100021
CVTREG   EQU   3                        CVT PTR                         50400021
HEADER   EQU   4                        RECORD PTR                      50700021
SVRBPTR  EQU   5                        EXTENDED SAVE AREA PTR          51000021
FMUCB    EQU   7                        'FROM' UCB PTR                  51300021
TOUCB    EQU   8                        'TO' UCB PTR                    51600021
OURDEB   EQU   10                       DDR DEB PTR                     51900021
COMMPTR  EQU   11                       IORMSCOM PTR                    52200021
BASE     EQU   12                       MODULE BASE REGISTER            52500021
OURIOB   EQU   13                       DDR IOB PTR                     52800021
WKREG14  EQU   14                       WORK REGISTER                   53100021
WKREG15  EQU   15                       WORK REGISTER                   53400021
         SPACE 3                                                        53700021
*                                                                       54000021
***      INTEGER EQUATES                                                54450000
*                                                                       54600021
N0       EQU   0                        DISPLACEMENT VALUE              54900021
N1       EQU   1                        DISPLACEMENT VALUE              55200021
N2       EQU   2                        DISPLACEMENT VALUE              55500021
N3       EQU   3                        DISPLACEMENT VALUE              55800021
N4       EQU   4                        DISPLACEMENT VALUE              56100021
N6       EQU   6                        DISPLACEMENT VALUE              56400021
N7       EQU   7                        DISPLACEMENT VALUE              56700021
N8       EQU   8                        DISPLACEMENT VALUE              57000021
N9       EQU   9                        DISPLACEMENT VALUE              57300021
N13      EQU   13                       DISPLACEMENT VALUE              57600021
N16      EQU   16                       DISPLACEMENT VALUE              57900021
N20      EQU   20                       DISPLACEMENT VALUE              58200021
N24      EQU   24                       DISPLACEMENT VALUE              58500021
N28      EQU   28                       DISPLACEMENT VALUE              58800021
N30      EQU   30                       DISPLACEMENT VALUE              59100021
N32      EQU   32                       DISPLACEMENT VALUE              59400021
N34      EQU   34                       DISPLACEMENT VALUE              59700021
N55      EQU   55                       DISPLACEMENT VALUE              60000021
N56      EQU   56                       DISPLACEMENT VALUE              60300021
N80      EQU   80                       DISPLACEMENT VALUE              60600021
         SPACE 3                                                        60900021
*                                                                       61200021
***      GENERAL EQUATES                                                61500021
*                                                                       61800021
ALL      EQU   X'FF'                    MASK FOR 'AND' INSTRUCTIONS     62100021
CUMASK   EQU   X'3F'                                                    62400021
DRYVMASK EQU   X'F0'                    3330 DRIVE MASK                 62700021
ERREXCP  EQU   15                       SVC 15                          63000021
MERLINID EQU   X'01'                    MERLIN ID IN AR149 FORMAT RECRD 63300021
NINETY   EQU   X'90'                    RECORD KEY                      63600021
ONLINE   EQU   X'80'                    DEVICE ON-LINE INDICATOR        63900021
RBLCOMND EQU   X'A4'                    READ BUFFERED LOG COMMAND       64200021
SEVENSIX EQU   76                       SVC 76                          64500021
TIMERBIT EQU   X'08'                    TIME MACRO INDICATOR            64650000
TTYPE    EQU   C'T'                     RECORD TYPE IDENTIFIER          64800021
UNRLTD   EQU   X'02'                    UNRELATED BIT IN IOB FLAGS 1    65100021
         SPACE 3                                                        65400021
*                                                                       65700021
***      CHANNEL PROGRAM AND DEFINED CONSTANTS                          66000021
*                                                                       66300021
         DS    0D                       DOUBLE WORD BOUNDRY             66600021
RBLCCW   DC    X'00'                    COMMAND FIELD                   66900021
         DC    X'000000'                BUFFER ADDRESS FIELD            67200021
         DC    X'20'                    SUPRESS WRONG LENGTH BIT        67500021
         DC    X'000018'                BYTE COUNT                      67800021
*                                                                       68100021
LOAD1    DC    C'IGC0108E'              OPERATOR DASD MODULE            68400021
LOAD3    DC    C'IGC0308E'              SYSTEM SWAP MODULE              68700021
         SPACE 3                                                        69000021
*                                                                       69250000
***      PHYSICAL DRIVE ID'S                                            69260000
*                                                                       69270000
PHYSDRID EQU   *                                                        69280000
         DC    X'3800'                  DRIVE 0                         69290000
         DC    X'3101'                  DRIVE 1                         69292000
         DC    X'2A02'                  DRIVE 2                         69294000
         DC    X'2303'                  DRIVE 3                         69296000
         DC    X'1C04'                  DRIVE 4                         69298000
         DC    X'1505'                  DRIVE 5                         69298400
         DC    X'0E06'                  DRIVE 6                         69298800
         DC    X'0707'                  DRIVE 7                         69299200
         DC    X'1908'                  DRIVE 8                         69299600
         DC    X'2909'                  DRIVE 9                         69299700
         DC    X'130A'                  DRIVE 10                        69299800
         DC    X'1A0B'                  DRIVE 11                        69299900
         DC    X'250C'                  DRIVE 12                        69350000
         DC    X'2C0D'                  DRIVE 13                        69360000
         DC    X'160E'                  DRIVE 14                        69370000
         DC    X'260F'                  DRIVE 15                        69380000
*                                                                       69390000
MAINT    DC    50X'40'                  SPACE FOR MAINT & TEMP PATCHES  69392000
*                                                                       69400000
***      AR-149 RECORD FORMAT                                           69600021
*                                                                       69900021
RECORD   DSECT                                                          70200021
KEY      DS    CL1                      RECORD KEY                      70500021
RELEASE  DS    CL1                      RELEASE NO                      70800021
ZERO1    DS    CL2                      ZERO FIELD                      71100021
RECORDID DS    CL1                      RECORD ID                       71400021
SPARE1   DS    CL2                      SPARE                           71700021
RECENTRY DS    CL1                      RECORD ENTRY                    72000021
DATE     DS    CL4                      DATE                            72300021
TIME     DS    CL4                      TIME OF DAY                     72600021
SPARE2   DS    CL2                      UNUSED                          72900021
ZERO2    DS    CL2                      ZERO FIELD                      73200021
CPUID    DS    CL2                      CPU ID                          73500021
ZERO3    DS    CL2                      ZERO FIELD                      73800021
CUA      DS    CL2                      CHANNEL UNIT ADDRESS            74100021
VOLSER   DS    CL6                      VOL. SER. ID                    74400021
SENSE1   DS    CL24                     'FROM' SENSE FIELD              74700021
SENSE2   DS    CL24                     'TO' SENSE FIELD                75000021
         SPACE 3                                                        75300021
CVTDSECT DSECT                                                          81300021
         CVT                                                            81600021
         IORMSCOM                                                       81900021
*/*IGC0708E:      CHART                                              */ 87650000
*/*IGC0708E:      E IGC0708E                                         */ 87700000
*/*               P ESTABLISH ALL ADDRESSABILITY                     */ 87750000
*/*               D (NO,,YES,RECORDNG)  IS THE READFROM BIT ON ?     */ 87800000
*/*               P TURN ON READFROM BIT                             */ 87850000
*/*               L  - GETMAIN - REQUEST 80 BYTES OF  CORE           */ 87900000
*/*               D (YES,,NO,GETOUT) WAS STORAGE OBTAINED ?          */ 87950000
*/*               P TURN ON THE RECORDING BIT                        */ 87960000
*/*               P BUILD DDR RECORD HEADER. (AR-149 FORMAT)         */ 87970000
*/*               L - TIME -                                         */ 87980000
*/*               P INITIALIZE DDR CONTROL BLOCKS WITH 'FROM' UCB    */ 87990000
*/*               P SET CCW FOR READ BUFFERED LOG                    */ 87992000
*/*IOSETUP:       P TURN ON IOCONTRL BIT                             */ 87994000
*/*               L - SVC15 - ERREXCP                                */ 87996000
*/*               L - WAIT -                                         */ 87998000
*/*               D (YES,,NO,RETRNRQE) IS ERROR BIT ON ?             */ 87998400
*/*               P TURN ERROR BIT OFF                               */ 87998800
*/*               D (NO,,YES,ERRORFM) UCB = DDRFMUCB ?               */ 87999200
*/*               P (,RETRNRQE) TURN ON TOERROR BIT                  */ 87999600
*/*ERRORFM:       P (,RETRNRQE) TURN ON FMERROR BIT                  */ 87999700
*/*RETRNRQE:      P RESTORE USER RQE POINTER IN UCB                  */ 87999800
*/*               D (NO,,YES,GETOUT) IS READTO BIT ON ?              */ 87999900
*/*               D (NO,,YES,GETOUT) IS THIS A SWAP TO ITSELF ?      */ 88049900
*/*               D (YES,,NO,GETOUT) IS 'TO' DEVICE ONLINE           */ 88059900
*/*               P INITIALIZE DDR CONTROL BLOCKS WITH 'TO' UCB      */ 88069900
*/*               P (,IOSETUP) TURN ON READTO BIT                    */ 88079900
*/*GETOUT:        D (NO,,YES,GOLOAD1) IS THIS AN OPERATOR SWAP ?     */ 88089900
*/*               P SET IGC0308E FOR XCTL                            */ 88091900
*/*GOXCTL:        L () - XCTL - TO IGC0308E OR IGC0108E              */ 88093900
*/*GOLOAD1:       P (,GOXCTL) SET IGC0108E FOR XCTL                  */ 88095900
*/*RECORDNG:      P TURN OFF READFROM INDICATOR BIT                  */ 88097900
*/*               D (NO,,YES,RECORDFM) IS THE RECORDING BIT ON ?     */ 88098300
*/*               P (,GETOUT) TURN RECORDING BIT ON                  */ 88098700
*/*RECORDFM:      D (YES,,NO,RECORDIT) IS THE FMERROR BIT ON ?       */ 88099100
*/*               P (,CHKTO) TURN OFF THE FMERROR BIT                */ 88099500
*/*RECORDIT:      P INITIALIZE RECORD HEADER TO RECORD FROM/TO SENSE */ 88099600
*/*               L SVC 76 - RECORD INTO SYS1.LOGREC                 */ 88099700
*/*CHKTO:         D (YES,,NO,FREECORE) IS READTO BIT ON ?            */ 88099800
*/*               P TURN OFF READTO INDICATOR BIT                    */ 88149800
*/*               D (YES,,NO,RECORDTO) IS TOERROR BIT ON ?           */ 88159800
*/*               P (,FREECORE) TURN OFF THE TOERROR INDICATOR BIT   */ 88169800
*/*RECORDTO:      P (,RECORDIT:RT) INITIALIZE RECORD HEADER TO RECORD   88179800
*/*                'TO' SENSE                                        */ 88189800
*/*FREECORE:      L (,GETOUT) FREEMAIN - RELEASE GETMAINED CORE      */ 88191800
*/*IGC0708E:      END                                                */ 88193800
         END                                                            88199800
