IGE0660A CSECT                                                          00200021
         TITLE 'IGE0660A'                                               00400021
         SPACE 2                                                        00600021
*********************************************************************** 00800021
*                                                                       01000021
*                        INTRODUCTORY COMMENTS                          01200021
*                                                                       01400021
*STATUS -- RELEASE 21.8                                                 01600021
*                                                                       01800021
*FUNCTION --  THIS MODULE GAINS CONTROL FROM THE OBR/SDR MODULES WHEN   02000021
*    A PERMANENT I/O ERROR CONDITION EXITS.  IT PERFORMS EXTENSIVE      02200021
*    CHECKING TO INSURE THAT DDR MAY TAKE PLACE.  IF DDR IS TO BE INI-  02400021
*    INIATED, THE FAILING RQE IS QUEUED TO THE IOS/DDR WAIT QUEUE.  IF  02600021
*    THE DDR TASK IS NOT ACTIVE, THE DDR ECB IN THE I/O COMM AREA IS    02800021
*    POSTED, TAKING THE DDR TASK OUT OF A WAIT STATE.  OTHERWISE, AN    03000021
*    SVC 3 EXIT IS MADE WITHOUT POSTING THE DDR ECB.                    03200021
*    IF DDR CANNOT BE PERFORMED, THE FAILING RQE IS RETURNED TO IOS VIA 03400021
*    SVC 15 AND THEN THE MODULE IS EXITED.                              03600021
*                                                                       03800021
*ENTRY POINTS --                                                        04000021
*        IGE0660A  (I.E., THE FIRST INSTRUCTION)                        04200021
*                                                                       04400021
*INPUT --  REGISTER 1 CONTAINS THE ADDRESS OF THE FAILING RQE.          04600021
*                                                                       04800021
*OUTPUT --  NONE                                                        05000021
*                                                                       05200021
*EXTERNAL REFERENCES --  1.  THE I/O RMS COMMUNICATIONS AREA, THE FIRST 05400021
*    WORD OF THE SYS1.LOGREC DCB POINTS TO THIS AREA.                   05600021
*    2.  THE RQE AND ASSOCIATED I/O CONTROL BLOCKS OF THE FAILING RE-   05800021
*    QUEST.                                                             06000021
*    3.  THE UCB OF THE FAILING DEVICE                                  06200021
*                                                                       06400021
*EXITS -- NORMAL                                                        06600021
*        SVC 3                                                          06800021
*                                                                       07000021
*EXITS -- ERROR                                                         07200021
*        NONE                                                           07400021
*                                                                       07600021
*TABLES/WORK AREAS -- NONE                                              07800021
*                                                                       08000021
*ATTRIBUTES --  REFRESHABLE, DISABLED                                   08200021
*                                                                       08400021
*NOTES --  THIS MODUE USES THE RPIVATE MACRO 'IORMSCOM' TO MAP THE I/O  08600021
*    COMMUNICATIONS AREA.  THERE IS NO CHARACTER CODE DEPENDENCE.       08800021
*                                                                       09000021
* UPDATE ACTIVITY                                                       09030021
*                                                                       09060021
*        APAR 67009  IGE0660A DOES NOT CHECK FOR MISSING ADDRESS  67009 09090021
*                    MARKER ON DASD SWAP                          67009 09120021
*        APAR 69709 (CHECK FOR DDR NON-DSPCH BEFORE POSTING)  3/74      09130021
*                                                                       09150021
*********************************************************************** 09200021
         SPACE 2                                                        09400021
******                                                                  09600021
****                                                                    09800021
**             GENERAL REGISTER USAGE DEFINITIONS                       10000021
****                                                                    10200021
******                                                                  10400021
RQEREG   EQU   1                        CONTAINS ASSOC RQE ADDRESS      10600021
WQREG    EQU   2                        POINTER TO DDR WAIT QUEUE       10800021
CVTREG   EQU   3                        POINTER TO CVT                  11000021
IOBREG   EQU   4                        POINTER TO IOB                  11200021
DEBREG   EQU   5                        POINTER TO DEB                  11400021
WKREGA   EQU   6                        GENERAL WORK REGISTER           11600021
UCBREG   EQU   7                        CONTAINS UCB ADDRESS            11800021
WKREGB   EQU   8                        GENERAL WORK REGISTER           12000021
COMREG   EQU   9                        CONTAINS I/O COMMO AREA ADDRESS 12200021
LINKREG  EQU   10                       GENERAL LINKAGE REGISTER        12400021
WKREGC   EQU   11                       GENERAL WORK REGISTER           12600021
BASEREG  EQU   12                       MODULE BASE REGISTER            12800021
TIOREG   EQU   13                       CONTAINS TIOT ADDRESS           13000021
RETREG   EQU   14                       RETURN ADDRESS AFTER BRANCH-LNK 13200021
CODERG   EQU   15                       RETURN CODE REGISTER            13400021
******                                                                  13600021
****                                                                    13800021
**             GENERAL EQUATES                                          14000021
****                                                                    14200021
******                                                                  14400021
ERREXCP  EQU   15                       SVC 15 CALL NUMBER              14600021
ZERO     EQU   0                        OFFSET VALUE                    14800021
EXIT     EQU   3                        EXIT SVC INSTRUCTION            15000021
N0       EQU   0                        OFFSET VALUE                    15200021
N1       EQU   1                        OFFSET VALUE                    15400021
N4       EQU   4                        OFFSET VALUE                    15600021
N5       EQU   5                        OFFSET VALUE                    15800021
N2       EQU   2                        CHARACTER STRING LENGTH         16000021
N3       EQU   3                        CHARACTER STRING LENGTH         16200021
N8       EQU   8                        INDEX FOR BRANCH TABLE          16400021
N34      EQU   34                  UCB OFFSET FOR ASCII BIT       62162 16410021
N35      EQU   35                  MOUNT PENDING INDICATOR        58404 16450021
CHENDAPP EQU   12                       OFFSET TO CHAN END APP ADDRESS  16600021
DEBAPPAD EQU   28                       POINTER TO NEGATIVE DEB OFFSET  16800021
DEBOFLGS EQU   8                        DEB FLAGS DISPLACEMENT          17000021
ASCII    EQU   X'04'               ASCII LABEL INDICATOR          62162 17010021
SL       EQU   X'01'               STANDARD LABEL INDICATOR       62162 17020021
MODDISP  EQU   X'80'               DISP=MOD BIT SETTING           62162 17030021
NEWDISP  EQU   X'C0'                DISP=NEW BIT SETTING                17040021
MNTMSG   EQU   X'80'               MOUNT PENDING INDICATOR        58404 17050021
DEBNSL   EQU   X'02'                                                    17200021
EMULATOR EQU   X'10'                     BIT SET IN DEB BY EMULATOR     17400021
DCBADDR  EQU   24                       DCB ADDR DISPLACEMENT IN DEB    17600021
DEBUCBAD EQU   34                       UCB DISPLACEMENT IN DEB         17800021
DCBMACR  EQU   42                       DCB ACCESS METHOD OPTIONS BYTE  18000021
DCBEXCP  EQU   X'80'                    EXCP INDICATOR IN DCB           18200021
ACRCT    EQU   X'04'                    ACCURATE BLKCT INDICATOR IN DCB 18400021
ALL      EQU   X'FF'                    'AND IMMEDIATE' MASK            18600021
PERMRES  EQU   X'04'                    PERM RESIDENT INDICATOR         18650000
TCBNDSP1 EQU   173                 OFFSET OF NON-DSPCH FLAGS            18700021
PNONDPCH EQU   X'40'               PERM NON-DISPATCHABLE                18750021
******                                                                  18800021
****                                                                    19000021
**             EQUATES FOR THE RQE                                      19200021
****                                                                    19400021
******                                                                  19600021
UCBDISPL EQU   2                        UCB ADDR DISPLACEMENT IN RQE    19800021
IOBDISPL EQU   4                        IOB ADDR DISPLACEMENT IN RQE    20000021
******                                                                  20200021
****                                                                    20400021
**             EQUATES FOR THE UCB                                      20600021
****                                                                    20800021
******                                                                  21000021
SRTESTAT EQU   3                        STATUS BYTE A                   21200021
DEVONLIN EQU   X'80'                    ONLINE INDICATOR                21400021
UCBFLGS1 EQU   6                        FLAGS 1 OFFSET INTO UCB         21600021
DEVCL    EQU   18                       DEVICE CLASS DISPLACEMENT       21800021
TAPEDEV  EQU   X'80'                    TAPE DEVICE INDICATOR IN UCB    22000021
DASD     EQU   X'20'                    DIRECT ACCESS DEVICE INDICATOR  22200021
UCBTYP2  EQU   17                       UCB TYPE DISPLACEMENT           22400021
SHARED   EQU   X'20'                    SHARED DASD INDICATOR           22600021
TYPE     EQU   19                       DEVICE TYPE DISPLACEMENT        22800021
T2400    EQU   X'01'                    2400 SERIES TAPE DEVICE INDICTR 23000021
T3400    EQU   X'03'                    3400 TAPE INDICATOR       21048 23200021
DSK11    EQU   X'01'                    2311 DRIVE INDICATOR            23400021
DCD21    EQU   X'05'                   2321 DRIVE INDICATOR             23600021
D2314    EQU   X'08'                    2314 DRIVE INDICATOR            23800021
SYSTMRES EQU   X'02'                    SYS RES INDICATOR               24000021
******                                                                  24200021
****                                                                    24400021
**       EQUATES FOR THE IOB                                            24600021
****                                                                    24800021
******                                                                  25000021
IOBECB   EQU   4                        LOCATION OF ECB IN IOB          25200021
INTCEPT  EQU   X'7E'                    INTERCEPT COMPLETION CODE       25400021
IOBCSW   EQU   8                        LOCATION OF CSW                 25600021
CSWCCC   EQU   X'04'                    CHAN CTL CHECK INDICATOR IN CSW 25800021
CSWICC   EQU   X'02'                    INTRFACE CTL CK INDICTOR IN CSW 26000021
CSWCDC   EQU   X'08'                    CHAN DATA CHECK INDICTOR IN CSW 26200021
CHAINCK  EQU   X'01'                    CHAINING CHECK INDICATOR IN CSW 26400021
CSWUCK   EQU   X'02'                    UNIT CHECK INDICATOR IN CSW     26600021
IOBSNS   EQU   2                        LOCATION OF SENSE INFO IN IOB   26800021
SNSCMDRJ  EQU    X'80'               COMMAND REJECT IN IOBSNS0    67009 26900021
SNSBOCK  EQU   X'20'                    BUS-OUT CK INDICATOR IN SENSE   27000021
SNSEQCK  EQU   X'10'                    EQUIPMENT CK INDICATOR IN SENSE 27200021
SNSDCK   EQU   X'08'                    DATA CHECK INDICATOR IN SENSE   27400021
SNSOVR   EQU   X'04'                    OVER RUN INDICATOR IN SENSE     27600021
SNSMAM    EQU    X'02'               MISSING ADDRESS MARKER IN    67009 27650021
*                                    IOBSNS0                            27700021
SNSSKCK   EQU    X'01'               SEEK CHECK IN IOBSNS0        67009 27750021
INCDISPL EQU   28                       LOCATION OF INCREMENT VALUE     27800021
         BALR  BASEREG,ZERO             ESTABLISH ADDRESSABILITY        28000021
         USING *,BASEREG                    FOR THIS MODULE             28200021
         USING CVTDSECT,CVTREG          ESTABLISH CVT ADDRESSABILITY    28400021
         L     CVTREG,CVTPTR            INITIALIZE CVT BASE REGISTER    28600021
         L     COMREG,CVTDCB            POINT TO SYS1.LOGREC DCB        28800021
         L     COMREG,ZERO(COMREG)      POINT TO I/O RMS COMMO AREA     29000021
         USING IORMS,COMREG             ESTABLISH I/O COMMO AREA ADDR   29200021
         L     WQREG,IOSVT              POINT TO DDR/IOS VECTOR TABLE   29400021
         L     WQREG,ZERO(WQREG)        POINT TO DDR WAIT QUEUE         29600021
         LH    UCBREG,UCBDISPL(RQEREG)  GET ASSOC UCB ADDRESS           29800021
         LM    IOBREG,DEBREG,IOBDISPL(RQEREG) GET ASSOC IOB, DEB ADDR   30000021
         LA    LINKREG,DDRENQ           SET WAIT QUEUE ENQUEUE CODE ADR 30200021
         CH    RQEREG,OURRQE            IS THE DDR RQE INVOLVED         30400021
         BE    DDR01                    YES, DO NOT SET UP FOR DDR      30600021
         SPACE 2                                                        30800021
****                                                                    31000021
*        THE FOLLOWING TEST DETERMINES IF THE FAILING DEVICE IS BEING   31200021
*        USED BY OLTEP. IF YES, DDR WILL NOT BE ATTEMPTED.              31400021
****                                                                    31600021
         TM    SRTESTAT(UCBREG),DEVONLIN  IS FALING DEVICE ONLINE       31800021
         BZ    DDR01                    NO, ASSUME DEVICE USED BY OLTEP 32000021
****                                                                    32200021
*        THE FOLLOWING CODE DETERMINES IF THE FAILING DEVICE IS         32400021
*        SUPPORTED BY DDR. IN GENERAL, DDR SUPPORTS NON-SYSRES DEVICES  32600021
*        WITH MOVABLE VOLUMES.                                          32800021
****                                                                    33000021
         TM    N35(UCBREG),MNTMSG  IS A MOUNT OUTSTANDING         58404 33050021
         BO    DDR01               YES, DO NOT HANDLE ERROR       58404 33100021
         CLI   DEVCL(UCBREG),TAPEDEV    IS THIS A TAPE DEVICE           33200021
         BE    DDR02                    YES, CONTINUE DDR PROCESSING    33400021
         CLI   DEVCL(UCBREG),DASD       IS THIS A DIRECT ACCESS DEVICE  33600021
         BNE   DDR01                    NO, DEVICE NOT SUPPORTED BY DDR 33800021
         TM    N3(UCBREG),PERMRES       IS DEVICE MARKED PERM RES       33950000
         BO    DDR01                    YES, DEVICE NOT SUPPORTED       33960000
         CLI   TYPE(UCBREG),DSK11       IS THIS A 2311 DISK DRIVE       34000021
         BE    DDR03                    YES, CONTINUE DDR PROCESSING    34200021
         CLI   TYPE(UCBREG),DCD21      IS THIS A  2321 DRIVE      52239 34400021
         BE    DDR03                    YES, CONTINUE WITH DDR          34600021
         CLI   TYPE(UCBREG),D2314      IS TI A 2314 OR 3330       52239 34650021
         BNL   DDR03                   YES,CONTINUE W/DDR         52239 34700021
DDR01    DS    0H                       BRANCH ENTRY POINT              34800021
         CLI   DEVCL(UCBREG),DASD       IS THIS A DIRECT ACCESS DEVICE  35000021
         BNE   PERREXIT                 NO, SKIP RESETTING UCBERR FLAG  35200021
         IOSGEN UCBFL1,UCBREG,OFF,UCBERR,AUTH=IGE0660A                  35400021
PERREXIT DS    0H                       BRANCH ENTRY POINT              35600021
         SVC   ERREXCP                  RETURN TO IOS WITH PERM ERROR   35800021
         SVC   EXIT                     EXIT MODULE                     36000021
DDR02    EQU   *                                                        36200021
         CLI   TYPE(UCBREG),T2400       IS THIS A 2400 SERIES TAPE UNIT 36400021
         BE    DDR03                    YES-CONTINUE PROCESSING   21048 36600021
         CLI   TYPE(UCBREG),T3400       IS THIS A 3400 TAPE       21048 36800021
         BNE   DDR01                    NO, GO TO POST PERMANENT ERROR  37000021
DDR03    EQU   *                                                        37200021
         TM    SRTESTAT(UCBREG),SYSTMRES IS FAILING DEV SYS RES         37400021
         BO    DDR01                    YES, DO NOT APPLY DDR, POST ERR 37600021
         SPACE 2                                                        37800021
****                                                                    38000021
*        THE TESTS BELOW SCREEN OUT THOSE ERRORS FOR WHICH DDR WILL NOT 38200021
*        PROVIDE RECOVERY.  DDR MAY ASSIST TO BY-PASS THE FOLLOWING     38400021
*        ERRORS---OVERRUN CONDITIONS, MISSING ADDRESS MARKER, CHANNEL   38600021
*        DATA, CHANNEL CONTROL, INTERFACE CONTROL, CHAINING, BUSOUT,    38800021
*        EQUIPMENT, DATA, AND SEEK CHECKS.                              39000021
DDR03A   EQU   *                                                        39200021
         CLI   IOBECB(IOBREG),INTCEPT   IS THIS IOB INTERCEPT CONDITION 39400021
         BE    DDR01                    YES, DDR CANNOT HANDLE          39600021
         TM    IOBCSW+N5(IOBREG),CSWCCC+CSWICC+CSWCDC+CHAINCK  IS ERRORX39800021
                                        TYPE RECOVERABLE                40000021
         BM    DDR04                    YES, CONTINUE DDR PROCESSING    40200021
         TM    IOBCSW+N4(IOBREG),CSWUCK IS THIS A UNIT CHECK            40400021
         BZ    DDR01                   CHECK IF UCBERR TO BE RESET      40600021
         TM    IOBSNS(IOBREG),SNSBOCK+SNSEQCK+SNSDCK+SNSOVR  RECOV ERR  40800021
          BZ     TESTDASD            NO, TEST DASD                67009 41000021
SNSBYTE0  TM     IOBSNS(IOBREG),SNSCMDRJ     IS COMMAND REJECT    67009 41010021
*                                    ON IN IOBSNS0                67009 41020021
          BO     DDR01               YES, DDR CANNOT HANDLE       67009 41030021
          B      DDR04               NO, CONTINUE TESTING         67009 41040021
          SPACE                                                         41050021
TESTDASD  CLI    DEVCL(UCBREG),DASD IS THIS DASD DEVICE           67009 41060021
          BNE    DDR01               NO, DDR CANNOT HANDLE        67009 41070021
          TM     IOBSNS(IOBREG),SNSSKCK  IS SEEK CHECK ON         67009 41080021
          BO     SNSBYTE0            YES, SEE IF COMMAND REJECT   67009 41090021
*                                    IS ON                        67009 41100021
SNSBYTE1  TM     IOBSNS+N1(IOBREG),SNSMAM  IS MISSING ADDR MARKER 67009 41110021
*                                    ON IN IOBSNS1                      41120021
          BZ     DDR01             NO, TESTS SHOW NO RECOVERABLE  67009 41130021
*                                  ERRORS.  DDR CANNOT HANDLE     67009 41140021
          B      SNSBYTE0          YES, SEE IF COMMAND REJECT IS  67009 41150021
*                                  ON IN IOB                            41160021
          SPACE                                                         41170021
         SPACE 2                                                        41200021
****                                                                    41400021
*        ERRORS ON A TAPE DEVICE REQUIRE TAPE REPOSITIONING BY DDR.     41600021
*        HENCE, IF THE FOLLOWING TEST INDICATES TAPE, THE SUBSEQUENT    41800021
*        ADDITIONAL TESTS DETERMINE IF THE NECESSARY INFORMATION FOR    42000021
*        REPOSITIONING IS AVAILABLE                                     42200021
****                                                                    42400021
DDR04    CLI   DEVCL(UCBREG),TAPEDEV    IS THIS A TAPE DEVICE           42600021
         BNE   DDR06                    NO, SKIP THE FOLLOWING TESTS    42800021
         NC    INCDISPL(N2,IOBREG),INCDISPL(IOBREG)   IS IOB INCR ZERO  43000021
         BZ    DDR01                    YES, GO POST PERMANENT ERROR    43200021
         NC    N1(N3,DEBREG),N1(DEBREG)  IS THE TCB POINTER ZERO        43400021
         BZ    DDR01                    YES, GO POST PERMANENT ERROR    43600021
         TM    DEBOFLGS(DEBREG),EMULATOR  IS THIS A NATIVE MODE TAPE    43800021
         BO    DDR01                    YES, LET IT BE POSTED AS ERROR  44000021
         TM    N34(UCBREG),ASCII   IS LABEL ASCII                 62162 44010021
         BO    DDR05               YES, CONTINUE                  62162 44020021
         TM    N3(UCBREG),SL       IS LABEL STANDARD              62162 44030021
         BO    DDR05               YES,CONTINUE                   62162 44040021
         TM    DEBOFLGS(DEBREG),DEBNSL IS LABEL NON-STNDRD        62162 44042021
         BO    CHKNSL              YES,CONTINUE                   62162 44044021
         TM    DEBOFLGS(DEBREG),NEWDISP  IS TAPE NL,NEW           M5293 44044421
         BO    DDR05                YES, DDR WILL HANDLE          M5293 44044821
         TM    DEBOFLGS(DEBREG),MODDISP  IS TAPE NL,DISP=MOD      62162 44046021
         BO    DDR01               YES,CANT HANDLE                62162 44048021
         B     DDR05               NO,ITS JUST NL AND OK          62162 44048421
CHKNSL   TM    DDRFLGSA,NSLAVAIL        HAS USER PROVIDED A NSL ROUTINE 44600021
         BZ    DDR01                    NO, GO POST PERMANENT ERROR     44800021
DDR05    L     WKREGB,DCBADDR(DEBREG)   POINT TO ASSOC DATA CTL BLOCK   45000021
         TM    DCBMACR(WKREGB),DCBEXCP  IS USER USING EXCP-LEVEL I/O    45200021
         BZ    DDR06                    NO, SKIP BLKCNT ACCURACY CHECK  45400021
         TM    DCBMACR(WKREGB),ACRCT    IS USER KEEPING ACCURATE BLKCNT 45600021
         BZ    DDR01                    NO, GO POST PERMANENT ERROR     45800021
DDR06    TM    DDRFLGSA,DDRBUSY         IS A  PREVIOUS DDR RQST ACTIVE  46000021
         BO    DDR07                    YES, GO QUEUE RQE TO WAIT       46200021
         OI    DDRFLGSA,DDRBUSY         SET DDR IN PROGRESS INDICATOR   46400021
         SPACE 2                                                        46600021
****                                                                    46800021
*        THE FOLLOWING BRANCH AND LINK INSTRUCTION WILL PASS THE RQE    47000021
*        TO IOS TO PLACE IT ON THE WAIT QUEUE.                          47200021
****                                                                    47400021
         BALR  RETREG,LINKREG           GO TO ENQUEUE RQE               47600021
         STH   UCBREG,DDRFMUCB          SAVE 'FROM' UCB PTR             47800021
         LA    WKREGB,N8               GET BRANCH INDEX                 48000021
         STC   WKREGB,DDRFLGSB         PLACE INDEX INTO COMMO AREA      48200021
****                                                                    48400021
         SPACE 2                                                        48600021
*        THE NEXT INSTRUCTION WILL TAKE THE DDR ROUTINE OPERATING UNDER 48800021
*        THE I/O RMS TCB OUT OF THE WAIT STATE                          49000021
****                                                                    49200021
         POST  DDRECB                   MAKE I/O RMS TCB READY          49400021
         SVC   EXIT                     EXIT ROUTINE                    49600021
         SPACE 2                                                        49800021
****                                                                    50000021
*        THE CODE BELOW WILL QUEUE THE USER'S RQE REPRESENTING THE FAIL 50200021
*        ING REQUEST ON THE DDR WAIT QUEUE IN IOS.  THE RQE WILL REMAIN 50400021
*        THERE UNTIL DDR INITIATES A RETRY OF THE FAILING REQUEST, OR   50600021
*        INDICATES THAT NO RETRY IS TO BE ATTEMPTED.  THE RQE CAN,ALSO, 50800021
*        BE PURGED FROM THIS QUEUE.                                     51000021
****                                                                    51200021
         SPACE 1                                                        51400021
DDRENQ   DS    0H                       BRANCH ENTRY POINT              51600021
         L     WKREGA,RMSTCB       GET DDR TCB PTR             @SA69709 51640021
         TM    TCBNDSP1(WKREGA),PNONDPCH TEST TCB FOR PERM NON @SA69709 51680021
*                                        DISPATCHABLE          @SA69709 51720021
         BO    DDR01               IF DDR NOT DSPCH, DO NOT ENQ         51760021
         SPACE 1                                                        51800021
         IOSGEN  ENQUE,WQREG,(RQEREG,WKREGA),AUTH=IGE0660A              52000021
         BR    RETREG                   HA, YOU'RE BACK, GO TO MAINLINE 52200021
DDR07    EQU   *                                                        52400021
         CH    UCBREG,DDRTOUCB          IS FAILING DEV USED AS TO-DEV   52600021
         BE    DDR01                    YES, GO POST USER WITH PERM ERR 52800021
         CH    UCBREG,DDRFMUCB          IS FAILING DEV USED AS FROM-DEV 53000021
         BNE   DDR08                    NO, CONTINUE WITH DDR      1030 53150000
         CLI   DEVCL(UCBREG),TAPEDEV    IS FAILURE ON TAPE         1030 53200000
         BNE   DDR01                    NO,POST USER PERM ERROR    1030 53250000
         TM    DDRFLGSF,DDRCNTRL        DOES DDR HAVE CONTROL      1030 53300000
         BO    DDR01                    YES, POST WITH PERM ERROR  1030 53352000
         OI    DDRFLGSF,OPCANCEL        TO INDICATE CANCEL OP DDR  1030 53360000
         BAL   RETREG,DDRENQ            GO ENQ FAILING RQE         1030 53370000
         SVC   EXIT                     GET OUT                    1030 53380000
         SPACE 2                                                        53400021
****                                                                    53600021
*        THE FOLLOWING BRANCH AND LINK INSTRUCTION WILL PASS THE RQE TO 53800021
*        TO IOS TO PLACE IT ON THE WAIT QUEUE.                          54000021
****                                                                    54200021
DDR08    EQU   *                                                        54400021
         BALR  RETREG,LINKREG           GO TO ENQUEUE RQE               54600021
         SVC   EXIT                 WELCOME BACK, YOU CAN'T STAY, EXIT  54800021
CVTDSECT DSECT                                                          55000021
         CVT                                                            55200021
         IORMSCOM                                                       55400021
*/*IGE0660A:      CHART                                              */ 82206000
*/*IGE0660A:      E IGE0660A                                         */ 82212000
*/*               P ESTABLISH ALL ADDRESSABILITY                     */ 82218000
*/*               D (YES,,NO,%A) DOES ERROR INVOLVE DDR RQE ?        */ 82224000
*/*DDR01:         D (YES,,NO,PERREXIT) IS ERROR ON DASD DEV. ?       */ 82230000
*/*               L - IOSGEN - RESET UCBERR FLAG                     */ 82236000
*/*PERREXIT:      L - SVC 15 - ERREXCP RETURN TO IOS WITH PERM. ERROR.  82242000
*/*                                                                  */ 82248000
*/*               R - SVC 3 - EXIT                                   */ 82254000
*/*%A:            D (YES,,NO,DDR01) IS FAILING DEV. ONLINE ?         */ 82260000
*/*               D (YES,,NO,%B) IS FAILING DEV. TAPE ?              */ 82266000
*/*DDR02:         D (YES,DDR03,NO,DDR01) IS 2400 TYPE TAPE ?         */ 82272000
*/*%B:            D (YES,,NO,DDR01) IS FAILING DEV. DASD ?           */ 82278000
*/*               D (NO,,YES,DDR03) IS 2311 TYPE DASD ?              */ 82284000
*/*               D (YES,,NO,DDR01) IS 2314 OR 2321 TYPE ?           */ 82290000
*/*DDR03:         D (NO,,YES,DDR01) IS FAILING DEV. SYSRES ?         */ 82296000
*/*DDR03A:        D (NO,,YES,DDR01) IS THIS IOB INTERCEPT COND. ?    */ 82302000
*/*               D (NO,,YES,DDR04) IS ERROR OF RECOVERABLE TYPE ?   */ 82308000
*/*               D (NO,,YES,DDR01) IS UNIT CHECK INDICATED ?        */ 82314000
*/*               D (YES,,NO,DDR01) DOES IOBSNS SHOW A RECOVERABLE      82320000
*/*                 ERROR ?                                          */ 82326000
*/*DDR04:         D (YES,,NO,DDR06) IS IT A TAPE DEVICE ?            */ 82332000
*/*               D (NO,,YES,DDR01) IS THE IOB INCREMENT 0 ?         */ 82338000
*/*               D (NO,,YES,DDR01) IS THE TCB POINTER 0 ?           */ 82344000
*/*               D (NO,,YES,DDR01) IS IT A NATIVE MODE TAPE ?       */ 82350000
*/*               D (YES,,NO,DDR05) IS IT A NSL TAPE ?               */ 82356000
*/*               D (YES,,NO,DDR01) HAS USER PROVIDED AN NSL RTNE ?  */ 82362000
*/*DDR05:         P GET DCB ADDRESS                                  */ 82368000
*/*               D (YES,,NO,DDR06) IS USER USING EXCP I/O LEVEL ?   */ 82374000
*/*               D (YES,,NO,DDR01) IS USER KEEPING ACCURATE BLKCNT ?*/ 82380000
*/*DDR06:         D (NO,,YES,DDR07) IS A PREVIOUS DDR REQ. ACTIVE ?  */ 82386000
*/*               P TURN ON DDR IN PROGRESS BIT                      */ 82392000
*/*               S - DDRENQ -: ENQUEUE THE RQE ON WAIT QUEUE        */ 82398000
*/*               P SAVE 'FROM' UCB POINTER                          */ 82404000
*/*               P STORE BRANCH INDEX (08) IN COMM. AREA            */ 82410000
*/*               L - POST - DDRECB. (MAKE IORMS TCB READY)          */ 82416000
*/*               R - SVC 3 - EXIT                                   */ 82422000
*/*DDR07:         D (NO,,YES,DDR01) IS FAILING DEV. USED AS 'TO' DEV. ? 82428000
*/*                                                                  */ 82434000
*/*               D (NO,,YES,DDR01) IS FAILING DEV. USED AS 'FROM'      82440000
*/*                 DEV. ?                                           */ 82446000
*/*               S - DDRENQ -: ENQUEUE THE RQE ON WAIT QUEUE        */ 82452000
*/*               R - SVC 3 - EXIT                                   */ 82458000
*/*DDRENQ:        E  DDRENQ                                          */ 82464000
*/*               L - IOSGEN - PUT RQE ON THE WAIT QUEUE             */ 82470000
*/*               R RETURN TO MAINLINE                               */ 82476000
*/*IGE0660A:      END                                                */ 82482000
         END                                                            82500021
