         LCLA  &LEV,&REL                                                00060021
&LEV     SETA  20                                                       00120021
&REL     SETA  21                                                       00180021
&REL&LEV TITLE 'IGF13501 LEVEL &LEV RECOVERY COMMAND - MODE'            00240021
IGF13501 CSECT                                                          00600021
*********************************************************************** 00900021
*                                                                     * 01200021
*TITLE   IGF13501   RECOVERY COMMAND - MODE                           * 01500021
*                                                                     * 01800021
*STATUS  LEVEL=00     00/00/71                                        * 02100021
*                                                                     * 02400021
*FUNCTION  ACCEPTS THE PARAMETERS OF THE MODE COMMAND AND             * 02700021
*   PROCEEDS AS FOLLOWS, IF STATUS IS SPECIFIED, OUTPUT PRESENT       * 03000021
*   MACHINE STATUS TO OPERATOR CONSOLE.  IF RECORD IS SPECIFIED,      * 03300021
*  MODIFY CONTROL REGISTER 14 AND ISSUE DIAGNOSE INSTRUCTION TO ALLOW * 03800021
*  RECOVERY REPORTS                                                   * 04300021
*                                                                     * 04800021
*ENTRY POINT   IGF13501  FROM MODE COMMAND ROUTER,IGF2603D            * 05100021
*                                                                     * 05400021
*ATTRIBUTES   REENTRANT,TRANSIENT,READ ONLY AND SELF-RELOCATABLE      * 05700021
*                                                                     * 06000021
*APPLICABILITY   MODEL 135 ONLY                                       * 06300021
*                                                                     * 06600021
*EXTERNAL REFERENCES  MASTER SCHEDULER RESIDENT AREA, USING THE       * 06900021
*   MACRO IEEBASE1, EXTENDED SAVE AREA(XSA), USING THE MACRO IEEXSA,  * 07200021
*   COMMUNICATIONS VECTOR TABLE, USING THE MACRO CVT.                 * 07500021
*                                                                     * 07800021
*MACROS  XCTL, IEEBASE1, IEEXSA, WTO, CVT, GETMAIN, AND FREEMAIN      * 08100021
*                                                                     * 08400021
*INPUT  REGISTER 2 POINTS TO XSA WHICH MUST HAVE IN XAR, POINTER      * 08700021
*   TO COMMAND BUFFER, IN XAL, POINTER TO PARAMETER LIST.             * 09000021
*                                                                     * 09300021
*OUTPUT WHEN STATUS WAS SPECIFIED, THE MACHINE STATUS IS DISPLAYED    * 09600021
*   TO THE OPERATOR VIA WTO.                                          * 09900021
*        WHEN AN ERROR IN THE COMMAND INPUT IS DETECTED, AN EXIT      * 10200021
*   TO IEE050D, THE MESSAGE ASSEMBLER, IS MADE WITH REGISTER 2        * 10500021
*   POINTING TO THE EXTENDED SAVE AREA WHICH CONTAINS IN XAE, THE     * 10800021
*   MESSAGE CODE (SEE ERROR MESSAGES BELOW) AND IN XAV, THE VERB IN   * 11100021
*   EBCDIC, LEFT ADJUSTED WITH BLANKS.                                * 11400021
*                                                                     * 11700021
*EXITS  NORMAL SVC 3                                                  * 12000021
*        ERROR XCTL TO MESSAGE ASSEMBLY MODULE (IEE0503D)             * 12300021
*                                                                     * 12600021
*ERROR MESSAGES THE FOLLOWING CONDITIONS GENERATE THE INDICATED MSGS  * 12900021
*        1. FAILURE TO FIND BLANK OR END OF BUFFER AFTER PARAMETER    * 13200021
*           'IEE008I MODE TERM LENGTH ERROR'                 (CODE=8) * 13500021
*        2. NO RECORD, QUIET, ENABLE, OR STATUS PARAMETER             * 13800021
*           'IEE010I MODE KEYWORD MISSING'                   (CODE=10)* 14100021
*        3. ATTEMPTED TO PUT ECC IN RECORD MODE WHILE HIR             * 14170021
*           IS IN QUIET MODE                                          * 14240021
*           'IEE305I MODE COMMAND INVALID'                  (CODE=5)  * 14310021
*                                                                     * 14400021
*OPERATION                                                            * 14700021
*                                                                     * 15000021
*TABLES/WORKAREAS   THE XSA IS MAPPED AS FOLLOWS                      * 15300021
*                                                                     * 15600021
*        ***************************************************          * 15900021
*        *XAP                      *XAD                    *          * 16200021
*        *SAVE AREA FOR PTR TO     *                       *          * 16500021
*        * END OF COMMAND BUFFER.  *                       *          * 16800021
*        ***************************************************          * 17100021
*        *XAX                      *XAX+4                  *          * 17400021
*        *SAVE AREA FOR UCB OF     *SAVE AREA FOR UCB OF   *          * 17700021
*        * INPUT WORK QUEUE.       * PROCEDURE LIBRARY.    *          * 18000021
*        ***************************************************          * 18300021
*        *XAE  *XAE+1 *            *XAL                    *          * 18600021
*        *ERROR *PAR ID*           *SAVE AREA FOR CURRENT  *          * 18900021
*        *CODE *MASK  *            * PARAMETER POINTER.    *          * 19200021
*        ***************************************************          * 19500021
*        *XAV                      *XAV+4                  *          * 19800021
*        *                         * DATE IN PACKED        *          * 20100021
*        *                         *     DECIMAL           *          * 20400021
*        ***************************************************          * 20700021
*        *XAS                      *XAS+4                  *          * 21000021
*        *                         * TIME IN PACKED        *          * 21300021
*        *                         *     DECIMAL.          *          * 21600021
*        ***************************************************          * 21900021
*                                                                     * 22200021
*    NOTES  MAINTENANCE AREA OF 50 BYTES IS LOCATED AT LABEL MAINT      22500021
*********************************************************************** 22800021
          EJECT                                                         23100021
*********************************************************************** 23400021
********                                                       ******** 23700021
********                   E Q U A T E S                       ******** 24000021
********                                                       ******** 24300021
*********************************************************************** 24600021
R0       EQU   0                   GENERAL REGISTER 0                   24900021
R1       EQU   1                   GENERAL REGISTER 1                   25200021
XSABASE  EQU   2                   BASE REGISTER FOR XSA                25500021
R3       EQU   3                   GENERAL REGISTER 3                   25800021
MSBBASE  EQU   4                   BASE FOR MACHINE STATUS BLOCK (MSB)  26100021
R5       EQU   5                                                        26400021
WORK     EQU   5                   GENERAL WORK REGISTER                26700021
COUNT    EQU   5                   CONTAINS DEC. BINARY COUNT VALUES    27000021
R6       EQU   6                   GENERAL REGISTER 6                   27300021
R7       EQU   7                   GENERAL REGISTER 7                   27600021
MSERBASE EQU   8                   BASE REGISTER FOR MS RES. DATA AREA  27900021
CVTBASE  EQU   9                   BASE REGISTER FOR CVT                28200021
SAVEPTR  EQU   10                                                       28500021
BUFPTR   EQU   11                                                       28800021
MODBASE  EQU   12                  MODULE BASE REGISTER                 29100021
R14      EQU   14                  CONTROL REGISTER 14                  29400021
R15      EQU   15                  GENERAL REGISTER 15                  29700021
N0       EQU   0                   DECIMAL VALUE  0                     30000021
N1       EQU   1                   DECIMAL VALUE  1                     30300021
N2       EQU   2                   DECIMAL VALUE  2                     30600021
N3       EQU   3                   DECIMAL VALUE  3                     30900021
N5       EQU   5                   DECIMAL VALUE  5                     31200021
N6       EQU   6                   DECIMAL VALUE  6                     31500021
N7       EQU   7                   DECIMAL VALUE  7                     31800021
N8       EQU   8                   DECIMAL VALUE  8                     32100021
N60      EQU   60                  DECIMAL VALUE 60                     32200021
N80      EQU   80                  DECIMAL VALUE 80                     32400021
N128     EQU   128                 *                                    32700021
N255     EQU   255                 DECIMAL VALUE 255                    33000021
XF0      EQU   X'F0'               HEXADECIMAL VALUE F0                 33300021
X0F      EQU   X'0F'               HEXADECIMAL VALUE 0F                 33600021
XDF      EQU   X'DF'               HEXADECIMAL VALUE DF                 33900021
XBF      EQU   X'BF'               HEXADECIMAL VALUE BF                 34200021
X00      EQU   X'00'               HEXADECIMAL VALUE 00                 34500021
XFF      EQU   X'FF'               HEXADECIMAL VALUE FF                 34800021
F0       EQU   C'0'                CHARACTER VALUE 0                    35100021
BLANK    EQU   C' '                CHARACTER BLANK FOR DELIMITER TEST   35400021
ENABSOFT EQU   X'08'               RECOVERY REP. MASK IN CR 14          35700021
RECRDE   EQU   X'40'               ECC RECORD MODE INDICATOR            36000021
RECRDH   EQU   X'80'               HIR RECORD MODE INDICATOR            36300021
MODSTAT  EQU   X'C0'               MODE INTERROGATION MASK              36600021
STATLEN  EQU   6                   LENGTH OF CHARS 'STATUS'             36900021
ERR05    EQU   5                   ERROR TYPE CODE FOR MSG MODULE       37000021
ERR08    EQU   8                   ERROR TYPE CODE FOR MSG MODULE       37200021
ERR10    EQU   10                  ERROR TYPE CODE FOR MSG MODULE       37500021
         EJECT                                                          37800021
         BALR  MODBASE,N0          ESTABLISH                            38100021
         USING START,MODBASE       ADDRESSABILITY                       38400021
         USING XSADSECT,XSABASE    BASE FOR XSA                         38700021
         USING CVT,CVTBASE         BASE FOR CVT                         39000021
         USING BASE,MSERBASE       BASE FOR MS RESIDENT DATA AREA       39300021
START    EQU   *                                                        39600021
         L     CVTBASE,CVTPTR      GET PTR TO CVT                       39900021
         L     MSERBASE,CVTMSER    GET PTR TO MS RESIDENT DATA AREA     40200021
         L     MSBBASE,CVTRMS      GET PTR TO MACHINE STATUS BLOCK      40500021
         USING MSB,MSBBASE         ESTABLISH ADDRESSABILITY             40800021
         L     BUFPTR,XAL          GET PTR TO PARAMETER                 41100021
         LA    BUFPTR,N0(BUFPTR)   CLEAR HI-ORDER BYTE                  41400021
         LTR   BUFPTR,BUFPTR       IS PTR ZERO                          41700021
         BZ    MODERR10            YES, PARAMETER IS MISSING            42000021
         L     R7,XAR              LOAD PTR TO BUFFER                   42300021
         LA    R7,N0(R7)           CONTAINING COMMAND                   42600021
         LH    R6,N0(R7)           LOAD BUFFER LENGTH                   42900021
         N     R6,CLEARFS          CLEAR POSSIBLE GARBAGE               43200021
         AR    R7,R6               COMPUTE END OF BUFFER                43500021
         ST    R7,XAP              SAVE IN XSA                          43800021
         NI    XAE+N1,X00          CLEAR ID MASK AREA                   44100021
         EJECT                                                          44400021
*        EXAMINE  PARAMETER                                             44700021
         USING MODEPARM,BUFPTR                                          45000021
EXAMIN   EQU   *                                                        45300021
         CLC   COMMAND(STATLEN),STATUS TEST FOR STATUS                  45600021
         BNE   EXAMIN2             NOT STATUS - TEST OTHERS             45900021
         CLI   COMMAND+STATLEN,BLANK TEST FOR BLANK                     46200021
         BNE   MODERR08            ERROR - DELIMITER IS MISSING         46500021
         GETMAIN R,LV=N80,SP=N255  GET BUFFER SPACE                     46800021
         LR    SAVEPTR,R1          SAVE PTR TO GOTTEN AREA              47100021
         USING GMAREA,SAVEPTR      ESTABLISH ADDRESSABILITY             47400021
         L     COUNT,MSBTHRLD      GET DEFAULT THR VALUE                47700021
         BAL   R3,CONVERT          CONVERT                              48000021
         STH   COUNT,THRESH        STORE THRESHOLD VALUE                48300021
         L     COUNT,MSBCOUNT      GET COUNT OF SOFT ERRORS             48600021
         BAL   R3,CONVERT          CONVERT                              48900021
         MVC   GMAREA(WTOLEN),WTO  MOVE WTO INFO TO WORK AREA           49200021
         MVC   GMTHRFLD(N2),THRESH SET HIR ERROR THRESHOLD IN MESSAGE   49300021
         STC   COUNT,GMCNTFLD+N1   STORE 2ND BYTE IN COUNTER            49400021
         SRL   COUNT,N8            POSITION 1ST BYTE                    49500021
         STC   COUNT,GMCNTFLD      STORE 1ST BYTE OF COUNTER            49600021
         LA    R3,RECORD           INITIATE POINTER TO RECORD LIST      49700021
* DETERMINE MODE STATUS,POSSIBLE CONDITIONS ARE:                        49720021
*        HIR RECORD,ECC RECORD                                          49740021
*        HIR QUIET,ECC QUIET                                            49760021
*        HIR RECORD,ECC QUIET                                           49780021
         TM    MSBMODE,MODSTAT     DETERMINE MODE STATUS                49800021
         BO    HRER                HIR RECORD,ECC RECORD                49900021
         BZ    HQEQ                HIR QUIET,ECC QUIET                  50000021
* HIR RECORD AND ECC QUIET                                              50100021
         MVC   GMSTAFL2(N6),N0(R3) SET HIR RECORD MODE IN MESSAGE       50200021
         LA    R3,QUIET            INITIATE POINTER TO QUIET TEXT       50300021
         MVC   GMSTAFL1(N6),N0(R3) SET ECC QUIET MODE IN MESSAGE        50400021
         B     SKIPOVLY            GO SET-UP FOR MESSAGE OUTPUT         50500021
HRER     EQU   *                                                        50600021
         MVC   GMSTAFL1(N6),N0(R3) SET HIR RECORD MODE IN MESSAGE       50700021
         MVC   GMSTAFL2(N6),N0(R3) SET ECC RECORD MODE IN MESSAGE       50800021
         B     SKIPOVLY            GO SET-UP FOR MESSAGE OUTPUT         50900021
HQEQ     EQU   *                                                        51000021
         LA    R3,QUIET            INITIATE POINTER TO QUIET TEXT       51100021
         MVC   GMSTAFL1(N6),N0(R3) SET HIR QUIET MODE IN MESSAGE        51200021
         MVC   GMSTAFL2(N6),N0(R3) SET ECC QUIET MODE IN MESSAGE        51300021
SKIPOVLY EQU   *                                                        53400021
          SR   R0,R0          CLEAR REGISTER 0                          53700021
          IC   R0,XAU              GET CONSOLE ID                       54000021
         WTO   ,MF=(E,(SAVEPTR))   ISSUE MESSAGE TO CONSOLE             54300021
         LR    R1,SAVEPTR          GET PTR TO GOTTEN AREA               54600021
         FREEMAIN R,LV=N80,A=(R1),SP=N255 FREE BUFFER SPACE             54900021
         B     EXIT                GO TO EXIT MODULE          IC  21961 55300021
CONVERT  EQU   *                                                        55800021
         CVD   COUNT,GMAREA        CONVERT ERROR CNT TO DEC.            56100021
         UNPK  GMAREA+N2(N2),GMAREA+N6(N2) PREPARE FOR                  56400021
         OI    GMAREA+N3,F0                                             56700021
         L     COUNT,GMAREA        SAVE FOR MSG BUILD                   57000021
         BR    R3                  RETURN TO STATUS PARAMETER           57300021
         EJECT                                                          57600021
EXAMIN2  EQU   *                                                        57900021
         CLC   COMMAND(N6),HRCORD  IS HIR RECORD SPECIFIED              58200021
         BNE   EXAMIN3             NO,GO TEST FOR ECC RECORD            58600021
         DC    X'B6EE',S(MSBCR14)  STORE CONTROL REGISTER               59400021
         OI    MSBCR14,ENABSOFT    ENABLE RECOVERY REPORTS              59700021
         OI    MSBMODE,RECRDH      INDICATE HIR RECORD MODE IN MSB      60000021
         SR    WORK,WORK           RESET THE CURRENT SOFT               60300021
         ST    WORK,MSBCOUNT       ERROR COUNT IN THE MSB               60600021
         DC    X'B7EE',S(MSBCR14)  LOAD CONTROL REGISTER 14             61200021
         B     MODEMSG             BRANCH TO OUTPUT MESSAGE             61500021
EXAMIN3  EQU   *                                                        61800021
         CLC   COMMAND(N6),ERCORD   IS ECC RECORD SPECIFIED             62100021
         BNE   MODERR08            ERROR - NO VALID PARAMETER           62400021
         TM    MSBMODE,RECRDH      IS HIR IN QUIET MODE                 62800021
         BZ    MODERR05            YES,ECCRECORD REQUEST NOT VALID      63200021
         DC    X'83000F14'         PUT ECC IN RECORD MODE               63600021
         OI    MSBMODE,RECRDE      INDICATE ECC RECORD MODE IN MSB      64000021
MODEMSG  EQU   *                   LABEL                                64060021
         GETMAIN R,LV=N60,SP=N255  GET BUFFER SPACE                     64120021
         LR    SAVEPTR,R1          SAVE POINTER TO GOTTEN AREA          64180021
         MVC   N0(WTOLEN1,SAVEPTR),WTO1 MOVE WTO INFO TO GOTTEN AREA    64240021
         SR    R0,R0               CLEAR REGISTER                       64300021
         IC    R0,XAU              GET CONSOLE ID                       64360021
         WTO   ,MF=(E,(SAVEPTR))   ISSUE MESSAGE TO CONSOLE             64420021
         LR    R1,SAVEPTR          GET POINTER TO GOTTEN AREA           64480021
         FREEMAIN R,LV=N60,A=(R1),SP=N255 FREE BUFFER SPACE             64540021
EXIT     EQU   *                   LABEL                                64600021
         SVC   N3                  EXIT                                 64660021
         EJECT                                                          64800021
         EJECT                                                          74100021
*********************************************************************** 74400021
*                                                                     * 74700021
*   THIS SECTION SETS UP INFO. FOR THE MESSAGE ASSEMBLY MODULE AND    * 75000021
* XCTLS TO IT.                                                        * 75300021
MODERR05 EQU   *                                                        75370021
         MVI   XAE,ERR05           SETUP ERROR CODE                     75440021
         B     MODERR              GO TO COMMON ROUTINE                 75510021
MODERR08 EQU   *                                                        75600021
         MVI   XAE,ERR08           SETUP ERROR CODE                     75900021
         B     MODERR              GO TO COMMON ROUTINE                 76200021
MODERR10 EQU   *                                                        76500021
         MVI   XAE,ERR10           SETUP ERROR CODE                     76800021
MODERR   EQU   *                                                        77100021
         MVC   XAV(N8),MODECHAR    MOVE VERB TO XSA                     77400021
         MVC   XAX(N8),XCTLNAME    MOVE MODULE NAME FOR XCTL            77700021
         SR    R15,R15             DCB PTR                              78000021
         ST    R15,XAD                     TO ZERO                      78300021
         LA    R15,XAX             PTR TO NAME                          78600021
         ST    R15,XAP                         IN LIST                  78900021
         XCTL  SF=(E,(XSABASE))    PASS CONTROL TO ASSEMBLY MODULE      79200021
         EJECT                                                          79500021
         DS    0F                                                       79800021
CLEARFS  DC    X'0000FFFF'         USED TO ZERO HI HALF OF REG          80100021
WTO      WTO   'IGF053I MODE STATUS-ECC XXXXXX  HIR XXXXXX COUNT-NN THRC80400021
               ESHOLD-NN',DESC=(5),MCSFLAG=(REG0),MF=L                  80700021
WTOEND   EQU   *                   END OF WTO DATA                      81000021
WTOLEN   EQU   WTOEND-WTO          LENGTH OF WTO DATA                   81300021
WTO1     WTO   'IGF061I MODE SWITCH COMPLETE',DESC=(5),MCSFLAG=(REG0), C81360021
               MF=L                                                     81420021
WTOEND1  EQU   *                   END OF WTO DATA                      81480021
WTOLEN1  EQU   WTOEND1-WTO1        LENGTH OF WTO DATA                   81540021
STATUS   DC    C'STATUS'           CHARS FOR PARAMETER COMPARE          81600021
RECORD   DC    C'RECORD'           CHARS FOR MSG, AND PARAM COMPARE     81900021
QUIET    DC    C'QUIET '           CHARS FOR MSG, AND PARAM COMPARE     82200021
HRCORD   DC    C'HIR RE'           PARAMETER COMPARE                    82300021
ERCORD   DC    C'ECC RE'           PARAMETER COMPARE                    82400021
THRESH   DS    H                   IBM DEFAULT THRESHOLD                83100021
MODECHAR DC    C'MODE     '        COMMAND VERB PADDED TO 8 CHARACTERS  83400021
XCTLNAME DC    C'IGC0503D'         NAME OF MSTR SCHED MSG ASM MODULE    83700021
MAINTID  DC    CL8'IGF13501'       CORE IDENTIFICATION                  83800021
MAINT    DC    S(*)                MODULE DISPLACEMENT                  83900021
         DC    15CL4'&REL&LEV'     ADDITIONAL SPACE                     84000021
         EJECT                                                          84300021
         DS    0D                  FORCE DBLWD ALIGNMENT                84600021
XSADSECT DSECT                                                          84900021
         IEEXSA                                                         85200021
         EJECT                                                          85500021
CVT      DSECT                                                          85800021
         CVT                                                            86100021
         EJECT                                                          86400021
         IEEBASEA                                                       86700021
         EJECT                                                          87000021
MSBDSECT DSECT                                                          87300021
         RMSMSB MOD=53                                                  87600021
GMAREA   DSECT                                                          87900021
GMTEXT   EQU   GMAREA+4                                                 88200021
GMSTAFL1 EQU   GMTEXT+24                                                88500021
GMSTAFL2 EQU   GMTEXT+36                                                88800021
GMCNTFLD EQU   GMTEXT+49                                                89100021
GMTHRFLD EQU   GMTEXT+62                                                89400021
MODEPARM DSECT                     FOR REFERENCING MODE PARAMETERS      89700021
COMMAND  EQU   *                   POSITION OF 1ST PARAMETER            90000021
         END                                                            91200021
