         TITLE  'IGF2403D'                                              00100019
IGF2403D  CSECT                                                         00300019
*********************************************************************** 00306019
*                                                                     * 00312019
*                       INTRODUCTORY COMMENTS                         * 00318019
*                                                                     * 00324019
*STATUS -- RELEASE 19                                                 * 00330019
*                                                                     * 00336019
*FUNCTION -- THIS MODULE PROCESSES THE VARY PATH COMMAND FOR THE UNI- * 00342019
*   PROCESSING SYSTEM- MVT OR MFTII. IT VERIFIES THE COMMAND FORMAT   * 00348019
*   AND SETS UP A PARAMETER LIST FOR IOSGEN.                          * 00354019
*   IOSGEN, A PRIVATE MACRO, VERIFIES THE PATHS, ACCESSES THE CHANNEL * 00360019
*   ERROR BLOCKS, AND SETS THE PATH BITS IN THE UCBWGT FIELD (UCB+12) * 00366019
*   FOR A VALID COMMAND. IT SETS UP A RETURN CODE FOR THE ACTION      * 00372019
*   TAKEN. (I.E., RETURN CODE=0 FOR PATH VARIED SUCCESSFUL,  RETURN   * 00378019
*   CODE=12 FOR NON-EXISTENT PATH)                                    * 00384019
*   THE MODULE SETS UP A MESSAGE ACCORDING TO THE RETURN CODE FROM    * 00390019
*   IOSGEN AND XCTL'S TO A MESSAGE MODULE (IGC0503D OR IGG2103D).     * 00396019
*                                                                     * 00402019
*ENTRY POINTS --                                                      * 00408019
*        IGF2403D -- FIRST INSTRUCTION                                * 00414019
*                                                                     * 00420019
*INPUT -- AT ENTRY, REGISTER 2 CONTAINS THE ADDRESS OF THE SVRB       * 00426019
*   EXTENDED SAVE AREA                                                * 00432019
*                                                                     * 00438019
*OUTPUT -- REGISTER 2 REMAINS UNCHANGED                               * 00444019
*                                                                     * 00450019
*EXTERNAL REFERENCES -- THE CHANNEL ERROR BLOCKS ARE CHECKED FOR APR  * 00456019
*   INTERACTION. THE ADDRESS OF THE FIRST CHANNEL ERROR BLOCK IS AT A * 00462019
*   DISPLACEMENT OF 24 FROM THE IOS FREELIST. CVT + 124 POINTS TO THE * 00468019
*   IOS FREELIST                                                      * 00474019
*                                                                     * 00480019
*EXITS,NORMAL --                                                      * 00486019
*        IGC0503D                                                     * 00492019
*        IGG2103D                                                     * 00498019
*                                                                     * 00504019
*EXITS ERROR --                                                       * 00510019
*        NONE                                                         * 00516019
*                                                                     * 00522019
*TABLES/WORK AREAS -- EXTENDED SAVE AREA OF SVRB, CHANNEL ERROR BLOCKS* 00528019
*                                                                     * 00534019
*ATTRIBUTES -- REFESHABLE                                             * 00540019
*                                                                     * 00546019
*NOTES -- THIS MODULE USES A PRIVATE MACRO, IOSGEN. THERE IS NO       * 00552019
*   CHARACTER CODE DEPENDENCE.                                        * 00558019
*                                                                     * 00564019
*********************************************************************** 00570019
***   GENERAL REGISTER EQUATES   ***                                    00600019
**                                                                      00900019
R0       EQU   0              NON-ADDRESSING REG FOR IOSGEN             01000019
R1       EQU   1             ADDRESS OF PARM LIST                       01200019
R2       EQU   2             ADDRESS OF XSA                             01500019
R3       EQU   3             ADDRESS OF CVT                             01800019
R4       EQU   4             WORK REGISTER                              02100019
R5       EQU   5             ADDRESS OF FIRST OPERAND IN COMMAND        02400019
R6       EQU   6             WORK REGISTER                              02700019
R7       EQU   7             WORK REGISTER                              03000019
R8       EQU   8             REGISTER SAVED FOR STAE IMPLEMENTATION     03300019
R9       EQU   9             WORK REGISTER                              03600019
R10      EQU   10            WORK REGISTER                              03900019
R11      EQU   11            WORK REGISTER                              04200019
BASE     EQU   12            ROUTINE BASE ADDRESS                       04500019
R13      EQU   13            WORK REG                                   04550019
R14      EQU   14            DO NOT CHANGE--- USED FOR EXIT FROM MSG   X04600019
                                       MODULES IGC0503D AND IGG2103D    04700019
R15      EQU   15            WORK REGISTER                              04800019
***   EQUATES FOR MCS CHECK   ***                                       05100019
*                                                                       05400019
MCS      EQU   X'02'          MCS IN SYSTEM                             05700019
INPSTR   EQU   X'80'          INPUT STREAM COMMAND                      06000019
INTERNL  EQU   X'00'          INTERNAL COMMAND                          06300019
IOAUTH2  EQU   X'40'          I/O AUTHORITY CODE                        06600019
***   EQUATES FOR CUA VALIDITION   ***                                  06900019
*                                                                       07200019
NUMERIC  EQU   X'F0'         NUMERIC MASK FOR CUA DIGITS                07500019
A        EQU   X'C1'          NON-NUMERIC BOUNDS                        07800019
F        EQU   X'C6'                             FOR VALID CUA DIGITS   08100019
C        EQU   C'C'          LOW BOUND FOR SUBSELECTOR CHANNEL ADDR     08200019
COMMA    EQU   C','           COMMA DELIMITER IN COMMAND                08400019
BLANK    EQU   C' '           BLANK                                     08700019
***   OTHER EQUATES   ***                                               09000019
MSG02    EQU   02            MESSAGE NUMBER                             09600019
MSG03    EQU   03            MESSAGE NUMBER                             09900019
MSG13    EQU   13            MESSAGE NUMBER                             10200019
MSG07    EQU   7             MESSAGE NUMBER                             10500019
MSG09    EQU   9              MESSAGE NUMBER                            10800019
MSG41    EQU   41             MESSAGE NUMBER                            11100019
MSG46    EQU   46            MESSAGE NUMBER                             11400019
MSG47    EQU   47            MESSAGE NUMBER                             11700019
MSG48    EQU   48            MESSAGE NUMBER                             12000019
MSG49    EQU   49            MESSAGE NUMBER                             12300019
ZERO     EQU   0             DISPLACEMENT VALUE                         12600019
ONE      EQU   1             DISPLACEMENT VALUE                         12900019
TWO      EQU   2             DISPLACEMENT VALUE                         13200019
THREE    EQU   3             DISPLACEMENT VALUE                         13500019
FOUR     EQU   4             DISPLACEMENT VALUE                         13800019
FIVE     EQU   5             DISPLACEMENT VALUE                         14100019
SIX      EQU   6              DISPLACEMENT VALUE                        14400019
SEVEN    EQU   7              DISPLACEMENT VALUE                        14700019
EIGHT    EQU   8             DISPLACEMENT VALUE                         15000019
NINE     EQU   9             VALUE DISPLACEMENT                         15300019
TEN      EQU   10            DISPLACEMENT VALUE                         15400019
ELEVEN   EQU   11             DISPLACEMENT VALUE                        15500019
TWELVE   EQU   12            VALUE DISPLACEMENT                         15600019
THIRTN   EQU   13            VALUE DISPLACEMENT                         15900019
NINETN   EQU   19        DISPLACEMENT VALUE                             16200019
TWENTY   EQU   20        DISPLACEMENT VALUE                             16500019
*                                                                       16800019
         BALR  BASE,ZERO           ESTABLISH -                          17100019
         USING *,BASE                     ADDRESSABILITY                17400019
         USING XSADS,R2      SET UP XSA BASE                            17700019
         USING SETCVT,R3      SET ADDRESSABILITY FOR CVT                17800019
         L     R3,CVTPTR     GET ADDRESS  OF CVT                        18000019
********************************************************************    18600019
*                         MCS AUTHORITY CHECK                      *    18900019
*    THIS ROUTINE WILL CAUSE THE COMMAND TO BE REJECTED UNLESS     *    19200019
*    IT COMES THROUGH A CONSOLE AUTHORIZED FOR I/O COMMAND,        *    19500019
*    OR THE INPUT STREAM                                           *    19800019
********************************************************************    20100019
         L     R4,CVTCUCB    GET ADDRESS OF UCM BASE                    20400019
         USING UCMDS,R4      SET ADDRESSABILITY FOR UCM BASE            20700019
         TM    UCMMODE,MCS    IS MCS IN SYSTEM                          21000019
         BNO   VPATH00        NO                                        21300019
         TM    XAU,INPSTR     IS COMMAND FROM INPUT STREAM              21600019
         BO    VPATH00        YES, ALLOW                                21900019
         CLI   XAU,INTERNL    IS COMMAND INTERNAL                       22200019
         BE    VPMSG03       YES, REJECT COMMAND                        22500019
         SR    R9,R9          CLEAR REGISTER                            22800019
         IC    R9,XAU         GET UCM ENTRY INDICATOR AND               23100019
         BCTR  R9,ZERO       SUBTRACT ONE                               23400019
         L     R7,UCMVEZ      GET SIZE OF UCM ENTRIES                   23700019
         MR    R6,R9          FIND UCM ENTRY DISPLACEMENT AND           24000019
         A     R7,UCMVEA      ADD TO FIRST ENTRY ADDRESS                24300019
         DROP  R4                                                       24600019
         USING UCMDS,R7      SET ADDRESSABILITY FOR UCM ENTRY           24900019
         TM    UCMAUTH,IOAUTH2 IS CONSOLE AUTHORIZED                    25200019
         BNO   VPMSG03        NO, REJECT  COMMAND                       25500019
VPATH00  EQU   *                                                        25800019
*******************************************************************     26400019
*     IEE3203D ALREADY HAS SCANNED FOR THE TWO DELIMITORS AND KEY-*     26500019
*     ' PATH,' BEFORE PASSING CONTROL TO IGF2403D.                    * 26600019
*     THE COMMAND IS CHECKED FOR PROPER FORMAT, AND IF THERE IS   *     26700019
*     A SYNTAX ERROR, A MESSAGE IS SET UP                         *     27000019
*******************************************************************     27300019
      L   R5,XAL                  PTR TO FIRST OPERAND                  27600019
         L     R7,XAR         POINT TO                                  28200019
         LA    R7,ZERO(R7)    COMMAND BUFFER                            28500019
         AH    R7,ZERO(R7)    COMPUTE END OF BUFFER                     28800019
         CLI   TWELVE(R5),COMMA  IS LAST COMMA PRESENT                  30300019
         BNE   VPMSG01       NO,GO SET UP ERROR MSG                     31200019
VPATH01  CLC   THIRTN(SIX,R5),ONLINE I0 VARY FOR ONLINE                 31500019
         BNE   VPATH02       NO, GO CHECK OFFLINE                       31800019
         LA    R6,ON          GET ONLINE INDICATOR                      32100019
         LA    R11,NINETN(R5)  POINT TO BUFFER END                      32400019
         B     VPATH03        GO CHECK END OF BUFFER                    32700019
VPATH02  CLC   THIRTN(SEVEN,R5),OFFLINE IS VARY FOR OFFLINE             33000019
         BNE   VPMSG02        NO,SET UP KEYWORD MISSPELLED MESSAGE      33300019
         SR    R6,R6          GET OFFLINE INDICATOR                     33600019
         LA    R11,TWENTY(R5)  POINT TO END OF BUFFER                   33900019
VPATH03  CLI   ZERO(R11),BLANK DOES BLANK DELIMIT LAST OPERAND          34200019
         BE    VPATH04       YES, GO FILL PARAMETER LIST                34500019
         CLR   R7,R11         IS BUFFER END THE DELIMITER               34800019
         BNE   VPMSG02       NO,SET UP KEYWORD MISSPELLED MSG           35100019
*******************************************************************     35400019
*     THE IOSGEN PARAMETER LIST IS SET UP IN THE XSA AS FOLLOWS-  *     35700019
*      1. THE PATH TO BE VARIED IS VALIDATED,CONVERTED TO HEX,    *     36000019
*         AND FILLED IN                                           *     36300019
*      2. THE ONLINE/OFFLINE INDICATOR IS FILLED IN               *     36600019
*      4. THE PRIMARY PATH(EBCDIC) IS FILLED IN                   *     36900019
*     THE ADDRESS OF THE PARAMETER LIST IS LOADED INTO REGISTER 1 *     37200019
*     AND THEN IOSGEN MACRO IS ISSUED                             *     37500019
*******************************************************************     37800019
VPATH04  LA    R9,XAWORK      POINT TO WORK AREA FOR CUA CONVERSION     38100019
         MVC   XAWORK(THREE),NINE(R5)  MOVE PATH TO WORK AREA           38400019
         LA    R4,THREE       SET UP CONTROL REG                        38700019
VPATH05  TM   ZERO(R9),NUMERIC    IS IT NUMERIC                         39000019
         BO    VPATH06            YES   INSPECT NEXT BYTE               39300019
         CLI   ZERO(R9),A     IS IT AN A OR GREATER                     39600019
         BL    VPMSG08       NO, GO SET ERROR MSG                       39900019
         CLI   ZERO(R9),F     IS IT F OR LESS                           40200019
         BH    VPMSG08       NO, GO SET ERROR MSG                       40500019
VPATH05A IC    R11,ZERO(R9)   CONVERT DIGITFROM                         40800019
         LA    R11,NINE(R11)          ALPHABETIC-                       41100019
         STC   R11,ZERO(R9)               TO HEX                        41400019
VPATH06  LA    R9,ONE(R9)     UP POINTER TO NEXT DIGIT IN WORK AREA     41700019
         BCT   R4,VPATH05    IF CUA NOT CHECKED, GO TEST NEXT CHAR      42000019
         PACK  XAVARYP(THREE),XAWORK(FOUR) CONVERT PATH TO HEX          42010019
         CLC   TWO(ONE,R5),ELEVEN(R5)  DO UNIT ADDRS MATCH              42020019
         BNE   VPMSG08        NO, GO SET UP PATH DOES NOT EXIST MSG     42040019
         CLC   ONE(ONE,R5),TEN(R5) DO CONTROL UNIT ADDRS MATCH          42060019
         BE    VPATH06A       YES, GO FINISH PARAMETER LIST             42080019
* CHECK  FOR VALID SUBSELECTOR PATHS                                    42100019
         CLC   ZERO(ONE,R5),NINE(R5) DO CHANNEL ADDRS MATCH             42120019
         BNE   VPMSG08        NO, GO SET UP PATH DOES NOT EXIST MSG     42160019
*   THE VARY PATH SUBSELECTOR CHANNEL ADDR IS CHECKED BY IOSGEN         42230019
         CLI   ONE(R5),C     IS PRIMARY PATH'S                          42300019
         BL    VPMSG08       SUBSELECTOR                                42370019
         CLI   ONE(R5),F     CHANNEL ADDR                               42440019
         BH    VPMSG08       VALID                                      42510019
VPATH06A MVC   XAPRIMEP(THREE),ZERO(R5) PUT PRIMARY PATH IN PARAMETER  *42610019
                                                                 LIST   42710019
         STC   R6,XAONOFF     SET ONLINE/OFFLINE INDICATOR              42900019
         MVI   MT,ZERO       ZERO MP BYTE                               43100019
         MVI   NOTUSED,NUMERIC PUT 'F0' BEFORE PRIMARY PATH             43300019
         LA    R1,XAVARYP         GET ADDR OF PARMS IN REG              43500019
         SSM   DISABLE       ALLOW NO INTERRUPTS FOR IOSGEN PROCESSING  43600019
         IOSGEN VARY,(R1,R3,R0),(R15,R4,R6,R7,R9,R10,R11,R13),0,       X43700019
               AUTH=IGF2403D                                            43800019
*******************************************************************     44100019
*     THE FOLLOWING BRANCH TABLE INDICATES THE ACTION TAKEN BY    *     44400019
*     THE IOSGEN MACRO                                            *     44700019
*******************************************************************     45000019
         B     *+FOUR(R15)         USE CODE FOR ENTRY TO BRANCH TABLE   45300019
         B     VPATH07             ZERO. OPERATION SUCCESSFUL           45600019
         B     VPMSG07             FOUR. CANNOT VARY TELEPROC. OFFLINE  45900019
         B     VPMSG06             EIGHT. CANNOT VARY LAST PATH OFFLINE 46200019
         B     VPMSG08        TWELVE.XXX PATH NONEXISTENT               46500019
         B     VPMSG09        SIXTEEN. ZZZ UCB NOT FOUND                46800019
         B     VPMSG10       TWENTY. CAN NOT VARY,RESERVED SHARED DASD  47100019
         B     VPMSG06A      TWENTYFOUR. ONLY ONE PATH                  47400019
VPATH07  CLI   XAONOFF,ON          IS IT ONLINE                         47700019
         BE    VPMSG04       YES, SET UP ONLINE MSG                     48000019
         B     VPMSG05       NO, GO SET UP OFFLINE MSG                  48300019
********************************************************************    48600019
*   THE FOLLOWING INSTRUCTIONS PASS A DESIGNATED INDEX CODE TO     *    48900019
*   THE MESSAGE-SETUP SUBROUTINE, SETUPMSG , IN REGISTER EIGHT.    *    49200019
********************************************************************    49500019
**                                                                      49800019
VPMSG01  BAL   R15,VPATH21    DELIMITOR ERROR MSG                       50100019
         DC    AL1(MSG07)    MESSAGE INDEX CODE                         50400019
**                                                                      50700019
VPMSG02  BAL   R15,VPATH21    KEYWORD MISSPELLED MSG                    51000019
         DC    AL1(MSG09)     INDEX CODE                                51300019
**                                                                      51600019
VPMSG03  BAL   R15,VPATH21    INVALID                                   51900019
         DC    AL1(MSG41)             AUTHORITY CODE                    52200019
**                                                                      52500019
VPMSG04  BAL   R15,VPATH20   PATH NOW                                   52800019
         DC    AL1(MSG02)             ONLINE MSG                        53100019
**                                                                      53400019
VPMSG05  BAL   R15,VPATH20   PATH NOW                                   53700019
         DC    AL1(MSG03)             OFFLINE MSG                       54000019
**                                                                      54300019
VPMSG06A MVC   NINE(THREE,R5),ZERO(R5)     SET UP MSG                   54600019
VPMSG06  BAL   R15,VPATH20   LAST PATH NOT                              54900019
         DC    AL1(MSG46)                  VARIED MSG                   55200019
**                                                                      55500019
VPMSG07  BAL   R15,VPATH20   TP PATH NOT                                55800019
         DC    AL1(MSG47)               VARIED MSG                      56100019
**                                                                      56400019
VPMSG08  BAL   R15,VPATH20    PATH XXX INVALID                          56700019
         DC    AL1(MSG48)                     MESSAGE                   57000019
**                                                                      57300019
VPMSG09  MVC   XAV(THREE),ZERO(R5) UNIT                                 57600019
         MVI   XAV+FOUR,BLANK          REFERENCE                        57900019
         BAL   R15,VPATH21                       INVALID                58200019
         DC    AL1(MSG13)                                      MSG      58500019
**                                                                      58800019
VPMSG10  BAL   R15,VPATH20   RESERVED SHARED                            59100019
         DC    AL1(MSG49)                     DASD MSG                  59400019
**                                                                      59700019
**                                                                      60000019
*******************************************************************     60300019
*     THE FOLLOWING ROUTINE SETS UP THE XSA FOR MESSAGE MODULES    *    60600019
*     IGC0503D AND IGC2503D. THE VARIABLE MESSAGE TEXT(XAV),MES-   *    60900019
*     SAGE INDEX CODE(XAE), AND XCTL NAME ARE FILLED, AND AN XCTL  *    61200019
*     IS ISSUED TO THE PROPER MESSAGE MODULE.                      *    61500019
*******************************************************************     61800019
VPATH20  MVC   XAV(FOUR),PATH   PUT PATH                                62100019
         MVC   XAV+FOUR(THREE),NINE(R5)  AND ADDRESS IN MESSAGE         62400019
VPATH21  MVC   XAE(ONE),ZERO(R15) INSERT MSG CODE INDEX NUMBER          62700019
         CLI   ZERO(R15),MSG13 IS MSG FOR IGC0503D                      63000019
         BNH   VPATH23       YES, GO GET MODULE NAME                    63300019
         MVC   XAX(EIGHT),XCTLNAME SET UP FOR XCRL                      63600019
VPATH22  SR    R6,R6          SET DCB PTR                               63900019
         ST    R6,XAD                    TO ZERO                        64200019
         LA    R6,XAX              PUT PTR TO-                          64500019
         ST    R6,XAP                  NAME IN LIST                     64800019
         XCTL  SF=(E,(R2))        PASS CONTROL TO MSG MODULE            65200019
VPATH23  MVC   XAX(EIGHT),XCTLNAM2  FILL IN MESSAGE MODULE NAME         65700019
         B     VPATH22        CONTINUE WITH MSG SETUP                   66000019
***   CONSTANTS   ***                                                   66300019
     DS  0F                                                             66600019
XCTLNAME DC    C'IGG2103D'   NAME OF MESSAGE MODULE                     67200019
XCTLNAM2 DC    C'IGC0503D'   NAME OF MESSAGE MODULE                     67500019
PATH     DC    C'PATH'        'PATH' FOR MSG SET UPS                    67800019
ONLINE   DC    CL6'ONLINE'    ONLINE KEYWORD                            68100019
OFFLINE  DC    CL7'OFFLINE'   OFFLINE KEYWORD                           68400019
DISABLE  DC    X'00'          DISABLED SYSTEM MASK FOR IOSGEN           68500019
XSADS    DSECT                                                          68700019
         IEEXSA                                                         69000019
         ORG   XSA            RESET ORIGIN TO ZERO                      69300019
* PARAMETER LIST FOR IOSGEN MACRO                                       69600019
XAVARYP  DS    CL2            HEX ADDRESS OF PATH TO BE VARIED(ZZZ)     69900019
XAONOFF  DS    CL1            ONLINE/OFFLINE INDICATOR                  70200019
OFF      EQU   X'00'         OFFLINE INDICATOR                          70500019
ON       EQU   X'04'         ONLINE INDICATOR                           70800019
MT       DS    CL1           MP USE ONLY                                71100019
NOTUSED  DS    CL1           'FO' BEFORE PRIMARY PATH                   71400019
XAPRIMEP DS    CL3            EBCDIC ADDRESS OF PRIMARY PATH(XXX)       71700019
*  END OF PARM LIST                                                     72000019
XAWORK   DS    CL4            WORK AREA                                 72300019
UCMDS    DSECT                                                          72600019
**  DISPLACEMENTS FOR UCM BASE                                          72900019
         DS    17F            GET DISPLACEMENT TO UCMMODE               73200000
UCMMODE  DS    F             MODE FOR CONSOLES--MCS                     73500019
UCMVEA   DS    F             FIRST UCM ENTRY                            73800019
UCMVEZ   DS    F             ENTRY SIZE FOR UCM                         74100019
**  DISPLACEMENTS FOR UCM ENTRY                                         74400019
         ORG   UCMDS          RESET ORIGIN TO ZERO                      74700019
         DS    10F            GET DISPLACEMENT TO UCMAUTH               75000019
UCMAUTH  DS    CL1           COMMAND CODE AUTHORIZATION                 75300019
SETCVT   DSECT                                                          75600019
         CVT                                                            75900019
   END                                                                  76200019
